SL/Controller/Order.pm

   1 package SL::Controller::Order;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use SL::Helper::Flash;
   7 use SL::Presenter;
   8 use SL::Locale::String;
   9 use SL::SessionFile::Random;
  10 use SL::PriceSource;
  11 use SL::Form;
  12 use SL::Webdav;
  13
  14 use SL::DB::Order;
  15 use SL::DB::Customer;
  16 use SL::DB::Vendor;
  17 use SL::DB::TaxZone;
  18 use SL::DB::Employee;
  19 use SL::DB::Project;
  20 use SL::DB::Default;
  21 use SL::DB::Unit;
  22 use SL::DB::Price;
  23 use SL::DB::Part;
  24
  25 use SL::Helper::DateTime;
  26 use SL::Helper::CreatePDF qw(:all);
  27
  28 use SL::Controller::Helper::GetModels;
  29
  30 use List::Util qw(max first);
  31 use List::MoreUtils qw(none pairwise first_index);
  32 use English qw(-no_match_vars);
  33 use File::Spec;
  34
  35 use Rose::Object::MakeMethods::Generic
  36 (
  37  'scalar --get_set_init' => [ qw(order valid_types type cv p multi_items_models) ],
  38 );
  39
  40
  41 # safety
  42 __PACKAGE__->run_before('_check_auth');
  43
  44 __PACKAGE__->run_before('_recalc',
  45                         only => [ qw(edit update save save_and_delivery_order create_pdf send_email) ]);
  46
  47 __PACKAGE__->run_before('_get_unalterable_data',
  48                         only => [ qw(save save_and_delivery_order create_pdf send_email) ]);
  49
  50 #
  51 # actions
  52 #
  53
  54 sub action_add {
  55   my ($self) = @_;
  56
  57   $self->order->transdate(DateTime->now_local());
  58   $self->order->reqdate(DateTime->today_local->next_workday) if !$self->order->reqdate;
  59
  60   $self->_pre_render();
  61   $self->render(
  62     'order/form',
  63     title => $self->type eq _sales_order_type()    ? $::locale->text('Add Sales Order')
  64            : $self->type eq _purchase_order_type() ? $::locale->text('Add Purchase Order')
  65            : '',
  66     %{$self->{template_args}}
  67   );
  68 }
  69
  70 sub action_edit {
  71   my ($self) = @_;
  72
  73   $self->_pre_render();
  74   $self->render(
  75     'order/form',
  76     title => $self->type eq _sales_order_type()    ? $::locale->text('Edit Sales Order')
  77            : $self->type eq _purchase_order_type() ? $::locale->text('Edit Purchase Order')
  78            : '',
  79     %{$self->{template_args}}
  80   );
  81 }
  82
  83 sub action_update {
  84   my ($self) = @_;
  85
  86   $self->_pre_render();
  87   $self->render(
  88     'order/form',
  89     title => $self->type eq _sales_order_type()    ? $::locale->text('Edit Sales Order')
  90            : $self->type eq _purchase_order_type() ? $::locale->text('Edit Purchase Order')
  91            : '',
  92     %{$self->{template_args}}
  93   );
  94 }
  95
  96 sub action_delete {
  97   my ($self) = @_;
  98
  99   my $errors = $self->_delete();
 100
 101   if (scalar @{ $errors }) {
 102     $self->js->flash('error', $_) foreach @{ $errors };
 103     return $self->js->render();
 104   }
 105
 106   flash_later('info', $::locale->text('The order has been deleted'));
 107   my @redirect_params = (
 108     action => 'edit',
 109     type   => $self->type,
 110   );
 111
 112   $self->redirect_to(@redirect_params);
 113 }
 114
 115 sub action_save {
 116   my ($self) = @_;
 117
 118   my $errors = $self->_save();
 119
 120   if (scalar @{ $errors }) {
 121     $self->js->flash('error', $_) foreach @{ $errors };
 122     return $self->js->render();
 123   }
 124
 125   flash_later('info', $::locale->text('The order has been saved'));
 126   my @redirect_params = (
 127     action => 'edit',
 128     type   => $self->type,
 129     id     => $self->order->id,
 130   );
 131
 132   $self->redirect_to(@redirect_params);
 133 }
 134
 135 sub action_create_pdf {
 136   my ($self) = @_;
 137
 138   my $pdf;
 139   my @errors = _create_pdf($self->order, \$pdf);
 140   if (scalar @errors) {
 141     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render($self);
 142   }
 143
 144   my $sfile = SL::SessionFile::Random->new(mode => "w");
 145   $sfile->fh->print($pdf);
 146   $sfile->fh->close;
 147
 148   my $key = join('_', Time::HiRes::gettimeofday(), int rand 1000000000000);
 149   $::auth->set_session_value("Order::create_pdf-${key}" => $sfile->file_name);
 150
 151   my $form = Form->new;
 152   $form->{ordnumber} = $self->order->ordnumber;
 153   $form->{formname}  = $self->type;
 154   $form->{type}      = $self->type;
 155   $form->{language}  = 'de';
 156   $form->{format}    = 'pdf';
 157
 158   my $pdf_filename = $form->generate_attachment_filename();
 159
 160   # copy file to webdav folder
 161   if ($self->order->ordnumber && $::instance_conf->get_webdav_documents) {
 162     my $webdav = SL::Webdav->new(
 163       type     => $self->type,
 164       number   => $self->order->ordnumber,
 165     );
 166     my $webdav_file = SL::Webdav::File->new(
 167       webdav   => $webdav,
 168       filename => $pdf_filename,
 169     );
 170     eval {
 171       $webdav_file->store(data => \$pdf);
 172       1;
 173     } or do {
 174       $self->js->flash('error', t8('Storing PDF to webdav folder failed: #1', $@));
 175     }
 176   }
 177
 178   $self->js
 179     ->run('download_pdf', $pdf_filename, $key)
 180     ->flash('info', t8('The PDF has been created'))->render($self);
 181 }
 182
 183 sub action_download_pdf {
 184   my ($self) = @_;
 185
 186   my $key = $::form->{key};
 187   my $tmp_filename = $::auth->get_session_value("Order::create_pdf-${key}");
 188   return $self->send_file(
 189     $tmp_filename,
 190     type => 'application/pdf',
 191     name => $::form->{pdf_filename},
 192   );
 193 }
 194
 195 sub action_show_email_dialog {
 196   my ($self) = @_;
 197
 198   my $cv_method = $self->cv;
 199
 200   if (!$self->order->$cv_method) {
 201     return $self->js->flash('error', $self->cv eq 'customer' ? t8('Cannot send E-mail without customer given') : t8('Cannot send E-mail without vendor given'))
 202                     ->render($self);
 203   }
 204
 205   $self->{email}->{to}   = $self->order->contact->cp_email if $self->order->contact;
 206   $self->{email}->{to} ||= $self->order->$cv_method->email;
 207   $self->{email}->{cc}   = $self->order->$cv_method->cc;
 208   $self->{email}->{bcc}  = join ', ', grep $_, $self->order->$cv_method->bcc, SL::DB::Default->get->global_bcc;
 209   # Todo: get addresses from shipto, if any
 210
 211   my $form = Form->new;
 212   $form->{ordnumber} = $self->order->ordnumber;
 213   $form->{formname}  = $self->type;
 214   $form->{type}      = $self->type;
 215   $form->{language} = 'de';
 216   $form->{format}   = 'pdf';
 217
 218   $self->{email}->{subject}             = $form->generate_email_subject();
 219   $self->{email}->{attachment_filename} = $form->generate_attachment_filename();
 220   $self->{email}->{message}             = $form->create_email_signature();
 221
 222   my $dialog_html = $self->render('order/tabs/_email_dialog', { output => 0 });
 223   $self->js
 224       ->run('show_email_dialog', $dialog_html)
 225       ->reinit_widgets
 226       ->render($self);
 227 }
 228
 229 # Todo: handling error messages: flash is not displayed in dialog, but in the main form
 230 sub action_send_email {
 231   my ($self) = @_;
 232
 233   my $mail      = Mailer->new;
 234   $mail->{from} = qq|"$::myconfig{name}" <$::myconfig{email}>|;
 235   $mail->{$_}   = $::form->{email}->{$_} for qw(to cc bcc subject message);
 236
 237   my $pdf;
 238   my @errors = _create_pdf($self->order, \$pdf, {media => 'email'});
 239   if (scalar @errors) {
 240     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render($self);
 241   }
 242
 243   $mail->{attachments} = [{ "content" => $pdf,
 244                             "name"    => $::form->{email}->{attachment_filename} }];
 245
 246   if (my $err = $mail->send) {
 247     return $self->js->flash('error', t8('Sending E-mail: ') . $err)
 248                     ->render($self);
 249   }
 250
 251   # internal notes
 252   my $intnotes = $self->order->intnotes;
 253   $intnotes   .= "\n\n" if $self->order->intnotes;
 254   $intnotes   .= t8('[email]')                                                                                        . "\n";
 255   $intnotes   .= t8('Date')       . ": " . $::locale->format_date_object(DateTime->now_local, precision => 'seconds') . "\n";
 256   $intnotes   .= t8('To (email)') . ": " . $mail->{to}                                                                . "\n";
 257   $intnotes   .= t8('Cc')         . ": " . $mail->{cc}                                                                . "\n"    if $mail->{cc};
 258   $intnotes   .= t8('Bcc')        . ": " . $mail->{bcc}                                                               . "\n"    if $mail->{bcc};
 259   $intnotes   .= t8('Subject')    . ": " . $mail->{subject}                                                           . "\n\n";
 260   $intnotes   .= t8('Message')    . ": " . $mail->{message};
 261
 262   $self->js
 263       ->val('#order_intnotes', $intnotes)
 264       ->run('close_email_dialog')
 265       ->render($self);
 266 }
 267
 268 sub action_save_and_delivery_order {
 269   my ($self) = @_;
 270
 271   my $errors = $self->_save();
 272
 273   if (scalar @{ $errors }) {
 274     $self->js->flash('error', $_) foreach @{ $errors };
 275     return $self->js->render();
 276   }
 277   flash_later('info', $::locale->text('The order has been saved'));
 278
 279   my @redirect_params = (
 280     controller => 'oe.pl',
 281     action     => 'oe_delivery_order_from_order',
 282     id         => $self->order->id,
 283   );
 284
 285   $self->redirect_to(@redirect_params);
 286 }
 287
 288 sub action_customer_vendor_changed {
 289   my ($self) = @_;
 290
 291   my $cv_method = $self->cv;
 292
 293   if ($self->order->$cv_method->contacts && scalar @{ $self->order->$cv_method->contacts } > 0) {
 294     $self->js->show('#cp_row');
 295   } else {
 296     $self->js->hide('#cp_row');
 297   }
 298
 299   if ($self->order->$cv_method->shipto && scalar @{ $self->order->$cv_method->shipto } > 0) {
 300     $self->js->show('#shipto_row');
 301   } else {
 302     $self->js->hide('#shipto_row');
 303   }
 304
 305   $self->order->taxzone_id($self->order->$cv_method->taxzone_id);
 306
 307   if ($self->order->is_sales) {
 308     $self->order->taxincluded(defined($self->order->$cv_method->taxincluded_checked)
 309                               ? $self->order->$cv_method->taxincluded_checked
 310                               : $::myconfig{taxincluded_checked});
 311   }
 312
 313   $self->order->payment_id($self->order->$cv_method->payment_id);
 314   $self->order->delivery_term_id($self->order->$cv_method->delivery_term_id);
 315
 316   $self->_recalc();
 317
 318   $self->js
 319     ->replaceWith('#order_cp_id',            $self->build_contact_select)
 320     ->replaceWith('#order_shipto_id',        $self->build_shipto_select)
 321     ->val(        '#order_taxzone_id',       $self->order->taxzone_id)
 322     ->val(        '#order_taxincluded',      $self->order->taxincluded)
 323     ->val(        '#order_payment_id',       $self->order->payment_id)
 324     ->val(        '#order_delivery_term_id', $self->order->delivery_term_id)
 325     ->val(        '#order_intnotes',         $self->order->$cv_method->notes)
 326     ->focus(      '#order_' . $self->cv . '_id');
 327
 328   $self->_js_redisplay_amounts_and_taxes;
 329   $self->js->render();
 330 }
 331
 332 sub action_unit_changed {
 333   my ($self) = @_;
 334
 335   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 336   my $item = $self->order->items->[$idx];
 337
 338   my $old_unit_obj = SL::DB::Unit->new(name => $::form->{old_unit})->load;
 339   $item->sellprice($item->unit_obj->convert_to($item->sellprice, $old_unit_obj));
 340
 341   $self->_recalc();
 342
 343   $self->js
 344     ->run('update_sellprice', $::form->{item_id}, $item->sellprice_as_number);
 345   $self->_js_redisplay_linetotals;
 346   $self->_js_redisplay_amounts_and_taxes;
 347   $self->js->render();
 348 }
 349
 350 sub action_add_item {
 351   my ($self) = @_;
 352
 353   my $form_attr = $::form->{add_item};
 354
 355   return unless $form_attr->{parts_id};
 356
 357   my $item = _make_item($self->order, $form_attr);
 358   $self->order->add_items($item);
 359
 360   $self->_recalc();
 361
 362   my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 363   my $row_as_html = $self->p->render('order/tabs/_row', ITEM => $item, ID => $item_id);
 364
 365   $self->js
 366     ->append('#row_table_id', $row_as_html)
 367     ->val('.add_item_input', '')
 368     ->run('row_table_scroll_down')
 369     ->run('row_set_keyboard_events_by_id', $item_id)
 370     ->run('set_unit_change_with_oldval_by_id', $item_id)
 371     ->on('.recalc', 'change', 'recalc_amounts_and_taxes')
 372     ->on('.reformat_number', 'change', 'reformat_number')
 373     ->focus('#add_item_parts_id_name');
 374
 375   $self->_js_redisplay_amounts_and_taxes;
 376   $self->js->render();
 377 }
 378
 379 sub action_show_multi_items_dialog {
 380   require SL::DB::PartsGroup;
 381   $_[0]->render('order/tabs/_multi_items_dialog', { layout => 0 },
 382                 all_partsgroups => SL::DB::Manager::PartsGroup->get_all);
 383 }
 384
 385 sub action_multi_items_update_result {
 386   my $max_count = 100;
 387   my $count = $_[0]->multi_items_models->count;
 388
 389   if ($count == 0) {
 390     my $text = SL::Presenter::EscapedText->new(text => $::locale->text('No results.'));
 391     $_[0]->render($text, { layout => 0 });
 392   } elsif ($count > $max_count) {
 393     my $text = SL::Presenter::EscapedText->new(text => $::locale->text('Too many results (#1 from #2).', $count, $max_count));
 394     $_[0]->render($text, { layout => 0 });
 395   } else {
 396     my $multi_items = $_[0]->multi_items_models->get;
 397     $_[0]->render('order/tabs/_multi_items_result', { layout => 0 },
 398                   multi_items => $multi_items);
 399   }
 400 }
 401
 402 sub action_add_multi_items {
 403   my ($self) = @_;
 404
 405   my @form_attr = grep { $_->{qty_as_number} } @{ $::form->{add_multi_items} };
 406   return $self->js->render() unless scalar @form_attr;
 407
 408   my @items;
 409   foreach my $attr (@form_attr) {
 410     push @items, _make_item($self->order, $attr);
 411   }
 412   $self->order->add_items(@items);
 413
 414   $self->_recalc();
 415
 416   foreach my $item (@items) {
 417     my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 418     my $row_as_html = $self->p->render('order/tabs/_row', ITEM => $item, ID => $item_id);
 419
 420     $self->js
 421         ->append('#row_table_id', $row_as_html)
 422         ->run('row_set_keyboard_events_by_id', $item_id)
 423         ->run('set_unit_change_with_oldval_by_id', $item_id);
 424   }
 425
 426   $self->js
 427     ->run('close_multi_items_dialog')
 428     ->run('row_table_scroll_down')
 429     ->on('.recalc', 'change', 'recalc_amounts_and_taxes')
 430     ->on('.reformat_number', 'change', 'reformat_number')
 431     ->focus('#add_item_parts_id_name');
 432
 433   $self->_js_redisplay_amounts_and_taxes;
 434   $self->js->render();
 435 }
 436
 437 sub action_recalc_amounts_and_taxes {
 438   my ($self) = @_;
 439
 440   $self->_recalc();
 441
 442   $self->_js_redisplay_linetotals;
 443   $self->_js_redisplay_amounts_and_taxes;
 444   $self->js->render();
 445 }
 446
 447 sub action_price_popup {
 448   my ($self) = @_;
 449
 450   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 451   my $item = $self->order->items->[$idx];
 452
 453   $self->render_price_dialog($item);
 454 }
 455
 456 sub _js_redisplay_linetotals {
 457   my ($self) = @_;
 458
 459   my @data = map {$::form->format_amount(\%::myconfig, $_->{linetotal}, 2, 0)} @{ $self->order->items };
 460   $self->js
 461     ->run('redisplay_linetotals', \@data);
 462 }
 463
 464 sub _js_redisplay_amounts_and_taxes {
 465   my ($self) = @_;
 466
 467   if (scalar @{ $self->{taxes} }) {
 468     $self->js->show('#taxincluded_row_id');
 469   } else {
 470     $self->js->hide('#taxincluded_row_id');
 471   }
 472
 473   if ($self->order->taxincluded) {
 474     $self->js->hide('#subtotal_row_id');
 475   } else {
 476     $self->js->show('#subtotal_row_id');
 477   }
 478
 479   $self->js
 480     ->html('#netamount_id', $::form->format_amount(\%::myconfig, $self->order->netamount, -2))
 481     ->html('#amount_id',    $::form->format_amount(\%::myconfig, $self->order->amount,    -2))
 482     ->remove('.tax_row')
 483     ->insertBefore($self->build_tax_rows, '#amount_row_id');
 484 }
 485
 486 #
 487 # helpers
 488 #
 489
 490 sub init_valid_types {
 491   [ _sales_order_type(), _purchase_order_type() ];
 492 }
 493
 494 sub init_type {
 495   my ($self) = @_;
 496
 497   if (none { $::form->{type} eq $_ } @{$self->valid_types}) {
 498     die "Not a valid type for order";
 499   }
 500
 501   $self->type($::form->{type});
 502 }
 503
 504 sub init_cv {
 505   my ($self) = @_;
 506
 507   my $cv = $self->type eq _sales_order_type()    ? 'customer'
 508          : $self->type eq _purchase_order_type() ? 'vendor'
 509          : die "Not a valid type for order";
 510
 511   return $cv;
 512 }
 513
 514 sub init_p {
 515   SL::Presenter->get;
 516 }
 517
 518 sub init_order {
 519   _make_order();
 520 }
 521
 522 sub init_multi_items_models {
 523   SL::Controller::Helper::GetModels->new(
 524     controller     => $_[0],
 525     model          => 'Part',
 526     with_objects   => [ qw(unit_obj) ],
 527     disable_plugin => 'paginated',
 528     source         => $::form->{multi_items},
 529     sorted         => {
 530       _default    => {
 531         by  => 'partnumber',
 532         dir => 1,
 533       },
 534       partnumber  => t8('Partnumber'),
 535       description => t8('Description')}
 536   );
 537 }
 538
 539 sub _check_auth {
 540   my ($self) = @_;
 541
 542   my $right_for = { map { $_ => $_.'_edit' } @{$self->valid_types} };
 543
 544   my $right   = $right_for->{ $self->type };
 545   $right    ||= 'DOES_NOT_EXIST';
 546
 547   $::auth->assert($right);
 548 }
 549
 550 sub build_contact_select {
 551   my ($self) = @_;
 552
 553   $self->p->select_tag('order.cp_id', [ $self->order->{$self->cv}->contacts ],
 554                        value_key  => 'cp_id',
 555                        title_key  => 'full_name_dep',
 556                        default    => $self->order->cp_id,
 557                        with_empty => 1,
 558                        style      => 'width: 300px',
 559   );
 560 }
 561
 562 sub build_shipto_select {
 563   my ($self) = @_;
 564
 565   $self->p->select_tag('order.shipto_id', [ $self->order->{$self->cv}->shipto ],
 566                        value_key  => 'shipto_id',
 567                        title_key  => 'displayable_id',
 568                        default    => $self->order->shipto_id,
 569                        with_empty => 1,
 570                        style      => 'width: 300px',
 571   );
 572 }
 573
 574 sub build_tax_rows {
 575   my ($self) = @_;
 576
 577   my $rows_as_html;
 578   foreach my $tax (sort { $a->{tax}->rate cmp $b->{tax}->rate } @{ $self->{taxes} }) {
 579     $rows_as_html .= $self->p->render('order/tabs/_tax_row', TAX => $tax, TAXINCLUDED => $self->order->taxincluded);
 580   }
 581   return $rows_as_html;
 582 }
 583
 584
 585 sub render_price_dialog {
 586   my ($self, $record_item) = @_;
 587
 588   my $price_source = SL::PriceSource->new(record_item => $record_item, record => $self->order);
 589
 590   $self->js
 591     ->run(
 592       'kivi.io.price_chooser_dialog',
 593       t8('Available Prices'),
 594       $self->render('order/tabs/_price_sources_dialog', { output => 0 }, price_source => $price_source)
 595     )
 596     ->reinit_widgets;
 597
 598 #   if (@errors) {
 599 #     $self->js->text('#dialog_flash_error_content', join ' ', @errors);
 600 #     $self->js->show('#dialog_flash_error');
 601 #   }
 602
 603   $self->js->render;
 604 }
 605
 606 sub _make_order {
 607   my ($self) = @_;
 608
 609   # add_items adds items to an order with no items for saving, but they cannot
 610   # be retrieved via items until the order is saved. Adding empty items to new
 611   # order here solves this problem.
 612   my $order;
 613   $order   = SL::DB::Manager::Order->find_by(id => $::form->{id}) if $::form->{id};
 614   $order ||= SL::DB::Order->new(orderitems => []);
 615
 616   $order->assign_attributes(%{$::form->{order}});
 617
 618   return $order;
 619 }
 620
 621 sub _make_item {
 622   my ($record, $attr) = @_;
 623
 624   my $item = SL::DB::OrderItem->new;
 625   $item->assign_attributes(%$attr);
 626
 627   my $part         = SL::DB::Part->new(id => $attr->{parts_id})->load;
 628   my $price_source = SL::PriceSource->new(record_item => $item, record => $record);
 629
 630   $item->unit($part->unit) if !$item->unit;
 631
 632   my $price_src;
 633   if ($item->sellprice) {
 634     $price_src = $price_source->price_from_source("");
 635     $price_src->price($item->sellprice);
 636   } else {
 637     $price_src = $price_source->best_price
 638            ? $price_source->best_price
 639            : $price_source->price_from_source("");
 640     $price_src->price(0) if !$price_source->best_price;
 641   }
 642
 643   my $discount_src;
 644   if ($item->discount) {
 645     $discount_src = $price_source->discount_from_source("");
 646     $discount_src->discount($item->discount);
 647   } else {
 648     $discount_src = $price_source->best_discount
 649                   ? $price_source->best_discount
 650                   : $price_source->discount_from_source("");
 651     $discount_src->discount(0) if !$price_source->best_discount;
 652   }
 653
 654   my %new_attr;
 655   $new_attr{part}                   = $part;
 656   $new_attr{description}            = $part->description if ! $item->description;
 657   $new_attr{qty}                    = 1.0                if ! $item->qty;
 658   $new_attr{sellprice}              = $price_src->price;
 659   $new_attr{discount}               = $discount_src->discount;
 660   $new_attr{active_price_source}    = $price_src;
 661   $new_attr{active_discount_source} = $discount_src;
 662
 663   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
 664   # they cannot be retrieved via custom_variables until the order/orderitem is
 665   # saved. Adding empty custom_variables to new orderitem here solves this problem.
 666   $new_attr{custom_variables} = [];
 667
 668   $item->assign_attributes(%new_attr);
 669
 670   return $item;
 671 }
 672
 673 sub _recalc {
 674   my ($self) = @_;
 675
 676   # bb: todo: currency later
 677   $self->order->currency_id($::instance_conf->get_currency_id());
 678
 679   my %pat = $self->order->calculate_prices_and_taxes();
 680   $self->{taxes} = [];
 681   foreach my $tax_chart_id (keys %{ $pat{taxes} }) {
 682     my $tax = SL::DB::Manager::Tax->find_by(chart_id => $tax_chart_id);
 683
 684     my @amount_keys = grep { $pat{amounts}->{$_}->{tax_id} == $tax->id } keys %{ $pat{amounts} };
 685     push(@{ $self->{taxes} }, { amount    => $pat{taxes}->{$tax_chart_id},
 686                                 netamount => $pat{amounts}->{$amount_keys[0]}->{amount},
 687                                 tax       => $tax });
 688   }
 689
 690   pairwise { $a->{linetotal} = $b->{linetotal} } @{$self->order->items}, @{$pat{items}};
 691 }
 692
 693
 694 sub _get_unalterable_data {
 695   my ($self) = @_;
 696
 697   foreach my $item (@{ $self->order->items }) {
 698     if ($item->id) {
 699       # load data from orderitems (db)
 700       my $db_item = SL::DB::OrderItem->new(id => $item->id)->load;
 701       $item->$_($db_item->$_) for qw(longdescription);
 702     } else {
 703       # set data from part (or other sources)
 704       $item->longdescription($item->part->notes);
 705     }
 706
 707     # autovivify all cvars that are not in the form (cvars_by_config can do it).
 708     # workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
 709     foreach my $var (@{ $item->cvars_by_config }) {
 710       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
 711     }
 712     $item->parse_custom_variable_values;
 713   }
 714 }
 715
 716
 717 sub _delete {
 718   my ($self) = @_;
 719
 720   my $errors = [];
 721   my $db = $self->order->db;
 722
 723   $db->do_transaction(
 724     sub {
 725       my @spoolfiles = grep { $_ } map { $_->spoolfile } @{ SL::DB::Manager::Status->get_all(where => [ trans_id => $self->order->id ]) };
 726       $self->order->delete;
 727       my $spool = $::lx_office_conf{paths}->{spool};
 728       unlink map { "$spool/$_" } @spoolfiles if $spool;
 729
 730       1;
 731   }) || push(@{$errors}, $db->error);
 732
 733   return $errors;
 734 }
 735
 736
 737 sub _save {
 738   my ($self) = @_;
 739
 740   my $errors = [];
 741   my $db = $self->order->db;
 742
 743   $db->do_transaction(
 744     sub {
 745       $self->order->save();
 746   }) || push(@{$errors}, $db->error);
 747
 748   return $errors;
 749 }
 750
 751
 752 sub _pre_render {
 753   my ($self) = @_;
 754
 755   $self->{all_taxzones}        = SL::DB::Manager::TaxZone->get_all_sorted();
 756   $self->{all_departments}     = SL::DB::Manager::Department->get_all_sorted();
 757   $self->{all_employees}       = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->employee_id,
 758                                                                                        deleted => 0 ] ],
 759                                                                     sort_by => 'name');
 760   $self->{all_salesmen}        = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->salesman_id,
 761                                                                                        deleted => 0 ] ],
 762                                                                     sort_by => 'name');
 763   $self->{all_projects}        = SL::DB::Manager::Project->get_all(where => [ or => [ id => $self->order->globalproject_id,
 764                                                                                       active => 1 ] ],
 765                                                                    sort_by => 'projectnumber');
 766   $self->{all_payment_terms}   = SL::DB::Manager::PaymentTerm->get_all_sorted();
 767   $self->{all_delivery_terms}  = SL::DB::Manager::DeliveryTerm->get_all_sorted();
 768
 769   $self->{current_employee_id} = SL::DB::Manager::Employee->current->id;
 770
 771   foreach  my $item (@{$self->order->items}) {
 772     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
 773     $item->active_price_source(   $price_source->price_from_source(   $item->active_price_source   ));
 774     $item->active_discount_source($price_source->discount_from_source($item->active_discount_source));
 775
 776   }
 777
 778   if ($self->order->ordnumber && $::instance_conf->get_webdav) {
 779     my $webdav = SL::Webdav->new(
 780       type     => $self->type,
 781       number   => $self->order->ordnumber,
 782     );
 783     my $webdav_path = $webdav->webdav_path;
 784     my @all_objects = $webdav->get_all_objects;
 785     @{ $self->{template_args}->{WEBDAV} } = map { { name => $_->filename,
 786                                                     type => t8('File'),
 787                                                     link => File::Spec->catdir($webdav_path, $_->filename),
 788                                                 } } @all_objects;
 789   }
 790
 791   $::request->{layout}->use_javascript("${_}.js")  for qw(ckeditor/ckeditor ckeditor/adapters/jquery);
 792 }
 793
 794 sub _create_pdf {
 795   my ($order, $pdf_ref, $params) = @_;
 796
 797   my $print_form = Form->new('');
 798   $print_form->{type}     = $order->type;
 799   $print_form->{formname} = $order->type;
 800   $print_form->{format}   = $params->{format} || 'pdf',
 801   $print_form->{media}    = $params->{media}  || 'file';
 802
 803   $order->flatten_to_form($print_form, format_amounts => 1);
 804   # flatten_to_form sets payment_terms from customer/vendor - we do not want that here
 805   delete $print_form->{payment_terms} if !$print_form->{payment_id};
 806
 807   my @errors = ();
 808   $print_form->throw_on_error(sub {
 809     eval {
 810       $print_form->prepare_for_printing;
 811
 812       $$pdf_ref = SL::Helper::CreatePDF->create_pdf(
 813         template  => SL::Helper::CreatePDF->find_template(name => $print_form->{formname}),
 814         variables => $print_form,
 815         variable_content_types => {
 816           longdescription => 'html',
 817           partnotes       => 'html',
 818           notes           => 'html',
 819         },
 820       );
 821       1;
 822     } || push @errors, ref($EVAL_ERROR) eq 'SL::X::FormError' ? $EVAL_ERROR->getMessage : $EVAL_ERROR;
 823   });
 824
 825   return @errors;
 826 }
 827
 828 sub _sales_order_type {
 829   'sales_order';
 830 }
 831
 832 sub _purchase_order_type {
 833   'purchase_order';
 834 }
 835
 836 1;