SL/Controller/Order.pm

   1 package SL::Controller::Order;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use SL::Helper::Flash;
   7 use SL::Presenter;
   8 use SL::Locale::String;
   9 use SL::SessionFile::Random;
  10 use SL::PriceSource;
  11 use SL::Form;
  12 use SL::Webdav;
  13
  14 use SL::DB::Order;
  15 use SL::DB::Customer;
  16 use SL::DB::Vendor;
  17 use SL::DB::TaxZone;
  18 use SL::DB::Employee;
  19 use SL::DB::Project;
  20 use SL::DB::Default;
  21 use SL::DB::Unit;
  22 use SL::DB::Price;
  23 use SL::DB::Part;
  24
  25 use SL::Helper::DateTime;
  26 use SL::Helper::CreatePDF qw(:all);
  27
  28 use SL::Controller::Helper::GetModels;
  29
  30 use List::Util qw(max first);
  31 use List::MoreUtils qw(none pairwise first_index);
  32 use English qw(-no_match_vars);
  33 use File::Spec;
  34
  35 use Rose::Object::MakeMethods::Generic
  36 (
  37  'scalar --get_set_init' => [ qw(order valid_types type cv p multi_items_models) ],
  38 );
  39
  40
  41 # safety
  42 __PACKAGE__->run_before('_check_auth');
  43
  44 __PACKAGE__->run_before('_recalc',
  45                         only => [ qw(edit update save save_and_delivery_order create_pdf send_email) ]);
  46
  47 __PACKAGE__->run_before('_get_unalterable_data',
  48                         only => [ qw(save save_and_delivery_order create_pdf send_email) ]);
  49
  50 #
  51 # actions
  52 #
  53
  54 sub action_add {
  55   my ($self) = @_;
  56
  57   $self->order->transdate(DateTime->now_local());
  58   $self->order->reqdate(DateTime->today_local->next_workday) if !$self->order->reqdate;
  59
  60   $self->_pre_render();
  61   $self->render(
  62     'order/form',
  63     title => $self->type eq _sales_order_type()    ? $::locale->text('Add Sales Order')
  64            : $self->type eq _purchase_order_type() ? $::locale->text('Add Purchase Order')
  65            : '',
  66     %{$self->{template_args}}
  67   );
  68 }
  69
  70 sub action_edit {
  71   my ($self) = @_;
  72
  73   $self->_pre_render();
  74   $self->render(
  75     'order/form',
  76     title => $self->type eq _sales_order_type()    ? $::locale->text('Edit Sales Order')
  77            : $self->type eq _purchase_order_type() ? $::locale->text('Edit Purchase Order')
  78            : '',
  79     %{$self->{template_args}}
  80   );
  81 }
  82
  83 sub action_update {
  84   my ($self) = @_;
  85
  86   $self->_pre_render();
  87   $self->render(
  88     'order/form',
  89     title => $self->type eq _sales_order_type()    ? $::locale->text('Edit Sales Order')
  90            : $self->type eq _purchase_order_type() ? $::locale->text('Edit Purchase Order')
  91            : '',
  92     %{$self->{template_args}}
  93   );
  94 }
  95
  96 sub action_delete {
  97   my ($self) = @_;
  98
  99   my $errors = $self->_delete();
 100
 101   if (scalar @{ $errors }) {
 102     $self->js->flash('error', $_) foreach @{ $errors };
 103     return $self->js->render();
 104   }
 105
 106   flash_later('info', $::locale->text('The order has been deleted'));
 107   my @redirect_params = (
 108     action => 'edit',
 109     type   => $self->type,
 110   );
 111
 112   $self->redirect_to(@redirect_params);
 113 }
 114
 115 sub action_save {
 116   my ($self) = @_;
 117
 118   my $errors = $self->_save();
 119
 120   if (scalar @{ $errors }) {
 121     $self->js->flash('error', $_) foreach @{ $errors };
 122     return $self->js->render();
 123   }
 124
 125   flash_later('info', $::locale->text('The order has been saved'));
 126   my @redirect_params = (
 127     action => 'edit',
 128     type   => $self->type,
 129     id     => $self->order->id,
 130   );
 131
 132   $self->redirect_to(@redirect_params);
 133 }
 134
 135 sub action_create_pdf {
 136   my ($self) = @_;
 137
 138   my $pdf;
 139   my @errors = _create_pdf($self->order, \$pdf);
 140   if (scalar @errors) {
 141     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render($self);
 142   }
 143
 144   my $sfile = SL::SessionFile::Random->new(mode => "w");
 145   $sfile->fh->print($pdf);
 146   $sfile->fh->close;
 147
 148   my $key = join('_', Time::HiRes::gettimeofday(), int rand 1000000000000);
 149   $::auth->set_session_value("Order::create_pdf-${key}" => $sfile->file_name);
 150
 151   my $form = Form->new;
 152   $form->{ordnumber} = $self->order->ordnumber;
 153   $form->{formname}  = $self->type;
 154   $form->{type}      = $self->type;
 155   $form->{language}  = 'de';
 156   $form->{format}    = 'pdf';
 157
 158   my $pdf_filename = $form->generate_attachment_filename();
 159
 160   # copy file to webdav folder
 161   if ($self->order->ordnumber && $::instance_conf->get_webdav_documents) {
 162     my $webdav = SL::Webdav->new(
 163       type     => $self->type,
 164       number   => $self->order->ordnumber,
 165     );
 166     my $webdav_file = SL::Webdav::File->new(
 167       webdav   => $webdav,
 168       filename => $pdf_filename,
 169     );
 170     eval {
 171       $webdav_file->store(data => \$pdf);
 172       1;
 173     } or do {
 174       $self->js->flash('error', t8('Storing PDF to webdav folder failed: #1', $@));
 175     }
 176   }
 177
 178   $self->js
 179     ->run('download_pdf', $pdf_filename, $key)
 180     ->flash('info', t8('The PDF has been created'))->render($self);
 181 }
 182
 183 sub action_download_pdf {
 184   my ($self) = @_;
 185
 186   my $key = $::form->{key};
 187   my $tmp_filename = $::auth->get_session_value("Order::create_pdf-${key}");
 188   return $self->send_file(
 189     $tmp_filename,
 190     type => 'application/pdf',
 191     name => $::form->{pdf_filename},
 192   );
 193 }
 194
 195 sub action_show_email_dialog {
 196   my ($self) = @_;
 197
 198   my $cv_method = $self->cv;
 199
 200   if (!$self->order->$cv_method) {
 201     return $self->js->flash('error', $self->cv eq 'customer' ? t8('Cannot send E-mail without customer given') : t8('Cannot send E-mail without vendor given'))
 202                     ->render($self);
 203   }
 204
 205   $self->{email}->{to}   = $self->order->contact->cp_email if $self->order->contact;
 206   $self->{email}->{to} ||= $self->order->$cv_method->email;
 207   $self->{email}->{cc}   = $self->order->$cv_method->cc;
 208   $self->{email}->{bcc}  = join ', ', grep $_, $self->order->$cv_method->bcc, SL::DB::Default->get->global_bcc;
 209   # Todo: get addresses from shipto, if any
 210
 211   my $form = Form->new;
 212   $form->{ordnumber} = $self->order->ordnumber;
 213   $form->{formname}  = $self->type;
 214   $form->{type}      = $self->type;
 215   $form->{language} = 'de';
 216   $form->{format}   = 'pdf';
 217
 218   $self->{email}->{subject}             = $form->generate_email_subject();
 219   $self->{email}->{attachment_filename} = $form->generate_attachment_filename();
 220   $self->{email}->{message}             = $form->create_email_signature();
 221
 222   my $dialog_html = $self->render('order/tabs/_email_dialog', { output => 0 });
 223   $self->js
 224       ->run('show_email_dialog', $dialog_html)
 225       ->reinit_widgets
 226       ->render($self);
 227 }
 228
 229 # Todo: handling error messages: flash is not displayed in dialog, but in the main form
 230 sub action_send_email {
 231   my ($self) = @_;
 232
 233   my $mail      = Mailer->new;
 234   $mail->{from} = qq|"$::myconfig{name}" <$::myconfig{email}>|;
 235   $mail->{$_}   = $::form->{email}->{$_} for qw(to cc bcc subject message);
 236
 237   my $pdf;
 238   my @errors = _create_pdf($self->order, \$pdf, {media => 'email'});
 239   if (scalar @errors) {
 240     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render($self);
 241   }
 242
 243   $mail->{attachments} = [{ "content" => $pdf,
 244                             "name"    => $::form->{email}->{attachment_filename} }];
 245
 246   if (my $err = $mail->send) {
 247     return $self->js->flash('error', t8('Sending E-mail: ') . $err)
 248                     ->render($self);
 249   }
 250
 251   # internal notes
 252   my $intnotes = $self->order->intnotes;
 253   $intnotes   .= "\n\n" if $self->order->intnotes;
 254   $intnotes   .= t8('[email]')                                                                                        . "\n";
 255   $intnotes   .= t8('Date')       . ": " . $::locale->format_date_object(DateTime->now_local, precision => 'seconds') . "\n";
 256   $intnotes   .= t8('To (email)') . ": " . $mail->{to}                                                                . "\n";
 257   $intnotes   .= t8('Cc')         . ": " . $mail->{cc}                                                                . "\n"    if $mail->{cc};
 258   $intnotes   .= t8('Bcc')        . ": " . $mail->{bcc}                                                               . "\n"    if $mail->{bcc};
 259   $intnotes   .= t8('Subject')    . ": " . $mail->{subject}                                                           . "\n\n";
 260   $intnotes   .= t8('Message')    . ": " . $mail->{message};
 261
 262   $self->js
 263       ->val('#order_intnotes', $intnotes)
 264       ->run('close_email_dialog')
 265       ->render($self);
 266 }
 267
 268 sub action_save_and_delivery_order {
 269   my ($self) = @_;
 270
 271   my $errors = $self->_save();
 272
 273   if (scalar @{ $errors }) {
 274     $self->js->flash('error', $_) foreach @{ $errors };
 275     return $self->js->render();
 276   }
 277   flash_later('info', $::locale->text('The order has been saved'));
 278
 279   my @redirect_params = (
 280     controller => 'oe.pl',
 281     action     => 'oe_delivery_order_from_order',
 282     id         => $self->order->id,
 283   );
 284
 285   $self->redirect_to(@redirect_params);
 286 }
 287
 288 sub action_customer_vendor_changed {
 289   my ($self) = @_;
 290
 291   my $cv_method = $self->cv;
 292
 293   if ($self->order->$cv_method->contacts && scalar @{ $self->order->$cv_method->contacts } > 0) {
 294     $self->js->show('#cp_row');
 295   } else {
 296     $self->js->hide('#cp_row');
 297   }
 298
 299   if ($self->order->$cv_method->shipto && scalar @{ $self->order->$cv_method->shipto } > 0) {
 300     $self->js->show('#shipto_row');
 301   } else {
 302     $self->js->hide('#shipto_row');
 303   }
 304
 305   $self->order->taxzone_id($self->order->$cv_method->taxzone_id);
 306
 307   if ($self->order->is_sales) {
 308     $self->order->taxincluded(defined($self->order->$cv_method->taxincluded_checked)
 309                               ? $self->order->$cv_method->taxincluded_checked
 310                               : $::myconfig{taxincluded_checked});
 311   }
 312
 313   $self->order->payment_id($self->order->$cv_method->payment_id);
 314   $self->order->delivery_term_id($self->order->$cv_method->delivery_term_id);
 315
 316   $self->_recalc();
 317
 318   $self->js
 319     ->replaceWith('#order_cp_id',            $self->build_contact_select)
 320     ->replaceWith('#order_shipto_id',        $self->build_shipto_select)
 321     ->val(        '#order_taxzone_id',       $self->order->taxzone_id)
 322     ->val(        '#order_taxincluded',      $self->order->taxincluded)
 323     ->val(        '#order_payment_id',       $self->order->payment_id)
 324     ->val(        '#order_delivery_term_id', $self->order->delivery_term_id)
 325     ->val(        '#order_intnotes',         $self->order->$cv_method->notes)
 326     ->focus(      '#order_' . $self->cv . '_id');
 327
 328   $self->_js_redisplay_amounts_and_taxes;
 329   $self->js->render();
 330 }
 331
 332 sub action_add_item {
 333   my ($self) = @_;
 334
 335   my $form_attr = $::form->{add_item};
 336
 337   return unless $form_attr->{parts_id};
 338
 339   my $item = _make_item($self->order, $form_attr);
 340   $self->order->add_items($item);
 341
 342   $self->_recalc();
 343
 344   my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 345   my $row_as_html = $self->p->render('order/tabs/_row', ITEM => $item, ID => $item_id);
 346
 347   $self->js
 348     ->append('#row_table_id', $row_as_html)
 349     ->val('.add_item_input', '')
 350     ->run('row_table_scroll_down')
 351     ->run('row_set_keyboard_events_by_id', $item_id)
 352     ->on('.recalc', 'change', 'recalc_amounts_and_taxes')
 353     ->on('.reformat_number', 'change', 'reformat_number')
 354     ->focus('#add_item_parts_id_name');
 355
 356   $self->_js_redisplay_amounts_and_taxes;
 357   $self->js->render();
 358 }
 359
 360 sub action_show_multi_items_dialog {
 361   require SL::DB::PartsGroup;
 362   $_[0]->render('order/tabs/_multi_items_dialog', { layout => 0 },
 363                 all_partsgroups => SL::DB::Manager::PartsGroup->get_all);
 364 }
 365
 366 sub action_multi_items_update_result {
 367   my $max_count = 100;
 368   my $count = $_[0]->multi_items_models->count;
 369
 370   if ($count == 0) {
 371     my $text = SL::Presenter::EscapedText->new(text => $::locale->text('No results.'));
 372     $_[0]->render($text, { layout => 0 });
 373   } elsif ($count > $max_count) {
 374     my $text = SL::Presenter::EscapedText->new(text => $::locale->text('Too many results (#1 from #2).', $count, $max_count));
 375     $_[0]->render($text, { layout => 0 });
 376   } else {
 377     my $multi_items = $_[0]->multi_items_models->get;
 378     $_[0]->render('order/tabs/_multi_items_result', { layout => 0 },
 379                   multi_items => $multi_items);
 380   }
 381 }
 382
 383 sub action_add_multi_items {
 384   my ($self) = @_;
 385
 386   my @form_attr = grep { $_->{qty_as_number} } @{ $::form->{add_multi_items} };
 387   return $self->js->render() unless scalar @form_attr;
 388
 389   my @items;
 390   foreach my $attr (@form_attr) {
 391     push @items, _make_item($self->order, $attr);
 392   }
 393   $self->order->add_items(@items);
 394
 395   $self->_recalc();
 396
 397   foreach my $item (@items) {
 398     my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 399     my $row_as_html = $self->p->render('order/tabs/_row', ITEM => $item, ID => $item_id);
 400
 401     $self->js
 402         ->append('#row_table_id', $row_as_html)
 403         ->run('row_set_keyboard_events_by_id', $item_id);
 404   }
 405
 406   $self->js
 407     ->run('close_multi_items_dialog')
 408     ->run('row_table_scroll_down')
 409     ->on('.recalc', 'change', 'recalc_amounts_and_taxes')
 410     ->on('.reformat_number', 'change', 'reformat_number')
 411     ->focus('#add_item_parts_id_name');
 412
 413   $self->_js_redisplay_amounts_and_taxes;
 414   $self->js->render();
 415 }
 416
 417 sub action_recalc_amounts_and_taxes {
 418   my ($self) = @_;
 419
 420   $self->_recalc();
 421
 422   $self->_js_redisplay_linetotals;
 423   $self->_js_redisplay_amounts_and_taxes;
 424   $self->js->render();
 425 }
 426
 427 sub action_price_popup {
 428   my ($self) = @_;
 429
 430   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 431   my $item = $self->order->items->[$idx];
 432
 433   $self->render_price_dialog($item);
 434 }
 435
 436 sub _js_redisplay_linetotals {
 437   my ($self) = @_;
 438
 439   my @data = map {$::form->format_amount(\%::myconfig, $_->{linetotal}, 2, 0)} @{ $self->order->items };
 440   $self->js
 441     ->run('redisplay_linetotals', \@data);
 442 }
 443
 444 sub _js_redisplay_amounts_and_taxes {
 445   my ($self) = @_;
 446
 447   if (scalar @{ $self->{taxes} }) {
 448     $self->js->show('#taxincluded_row_id');
 449   } else {
 450     $self->js->hide('#taxincluded_row_id');
 451   }
 452
 453   if ($self->order->taxincluded) {
 454     $self->js->hide('#subtotal_row_id');
 455   } else {
 456     $self->js->show('#subtotal_row_id');
 457   }
 458
 459   $self->js
 460     ->html('#netamount_id', $::form->format_amount(\%::myconfig, $self->order->netamount, -2))
 461     ->html('#amount_id',    $::form->format_amount(\%::myconfig, $self->order->amount,    -2))
 462     ->remove('.tax_row')
 463     ->insertBefore($self->build_tax_rows, '#amount_row_id');
 464 }
 465
 466 #
 467 # helpers
 468 #
 469
 470 sub init_valid_types {
 471   [ _sales_order_type(), _purchase_order_type() ];
 472 }
 473
 474 sub init_type {
 475   my ($self) = @_;
 476
 477   if (none { $::form->{type} eq $_ } @{$self->valid_types}) {
 478     die "Not a valid type for order";
 479   }
 480
 481   $self->type($::form->{type});
 482 }
 483
 484 sub init_cv {
 485   my ($self) = @_;
 486
 487   my $cv = $self->type eq _sales_order_type()    ? 'customer'
 488          : $self->type eq _purchase_order_type() ? 'vendor'
 489          : die "Not a valid type for order";
 490
 491   return $cv;
 492 }
 493
 494 sub init_p {
 495   SL::Presenter->get;
 496 }
 497
 498 sub init_order {
 499   _make_order();
 500 }
 501
 502 sub init_multi_items_models {
 503   SL::Controller::Helper::GetModels->new(
 504     controller     => $_[0],
 505     model          => 'Part',
 506     with_objects   => [ qw(unit_obj) ],
 507     disable_plugin => 'paginated',
 508     source         => $::form->{multi_items},
 509     sorted         => {
 510       _default    => {
 511         by  => 'partnumber',
 512         dir => 1,
 513       },
 514       partnumber  => t8('Partnumber'),
 515       description => t8('Description')}
 516   );
 517 }
 518
 519 sub _check_auth {
 520   my ($self) = @_;
 521
 522   my $right_for = { map { $_ => $_.'_edit' } @{$self->valid_types} };
 523
 524   my $right   = $right_for->{ $self->type };
 525   $right    ||= 'DOES_NOT_EXIST';
 526
 527   $::auth->assert($right);
 528 }
 529
 530 sub build_contact_select {
 531   my ($self) = @_;
 532
 533   $self->p->select_tag('order.cp_id', [ $self->order->{$self->cv}->contacts ],
 534                        value_key  => 'cp_id',
 535                        title_key  => 'full_name_dep',
 536                        default    => $self->order->cp_id,
 537                        with_empty => 1,
 538                        style      => 'width: 300px',
 539   );
 540 }
 541
 542 sub build_shipto_select {
 543   my ($self) = @_;
 544
 545   $self->p->select_tag('order.shipto_id', [ $self->order->{$self->cv}->shipto ],
 546                        value_key  => 'shipto_id',
 547                        title_key  => 'displayable_id',
 548                        default    => $self->order->shipto_id,
 549                        with_empty => 1,
 550                        style      => 'width: 300px',
 551   );
 552 }
 553
 554 sub build_tax_rows {
 555   my ($self) = @_;
 556
 557   my $rows_as_html;
 558   foreach my $tax (sort { $a->{tax}->rate cmp $b->{tax}->rate } @{ $self->{taxes} }) {
 559     $rows_as_html .= $self->p->render('order/tabs/_tax_row', TAX => $tax, TAXINCLUDED => $self->order->taxincluded);
 560   }
 561   return $rows_as_html;
 562 }
 563
 564
 565 sub render_price_dialog {
 566   my ($self, $record_item) = @_;
 567
 568   my $price_source = SL::PriceSource->new(record_item => $record_item, record => $self->order);
 569
 570   $self->js
 571     ->run(
 572       'kivi.io.price_chooser_dialog',
 573       t8('Available Prices'),
 574       $self->render('order/tabs/_price_sources_dialog', { output => 0 }, price_source => $price_source)
 575     )
 576     ->reinit_widgets;
 577
 578 #   if (@errors) {
 579 #     $self->js->text('#dialog_flash_error_content', join ' ', @errors);
 580 #     $self->js->show('#dialog_flash_error');
 581 #   }
 582
 583   $self->js->render;
 584 }
 585
 586 sub _make_order {
 587   my ($self) = @_;
 588
 589   # add_items adds items to an order with no items for saving, but they cannot
 590   # be retrieved via items until the order is saved. Adding empty items to new
 591   # order here solves this problem.
 592   my $order;
 593   $order   = SL::DB::Manager::Order->find_by(id => $::form->{id}) if $::form->{id};
 594   $order ||= SL::DB::Order->new(orderitems => []);
 595
 596   $order->assign_attributes(%{$::form->{order}});
 597
 598   return $order;
 599 }
 600
 601 sub _make_item {
 602   my ($record, $attr) = @_;
 603
 604   my $item = SL::DB::OrderItem->new;
 605   $item->assign_attributes(%$attr);
 606
 607   my $part         = SL::DB::Part->new(id => $attr->{parts_id})->load;
 608   my $price_source = SL::PriceSource->new(record_item => $item, record => $record);
 609
 610   $item->unit($part->unit) if !$item->unit;
 611
 612   my $price_src;
 613   if ($item->sellprice) {
 614     $price_src = $price_source->price_from_source("");
 615     $price_src->price($item->sellprice);
 616   } else {
 617     $price_src = $price_source->best_price
 618            ? $price_source->best_price
 619            : $price_source->price_from_source("");
 620     $price_src->price(0) if !$price_source->best_price;
 621   }
 622
 623   my $discount_src;
 624   if ($item->discount) {
 625     $discount_src = $price_source->discount_from_source("");
 626     $discount_src->discount($item->discount);
 627   } else {
 628     $discount_src = $price_source->best_discount
 629                   ? $price_source->best_discount
 630                   : $price_source->discount_from_source("");
 631     $discount_src->discount(0) if !$price_source->best_discount;
 632   }
 633
 634   my %new_attr;
 635   $new_attr{part}                   = $part;
 636   $new_attr{description}            = $part->description if ! $item->description;
 637   $new_attr{qty}                    = 1.0                if ! $item->qty;
 638   $new_attr{sellprice}              = $price_src->price;
 639   $new_attr{discount}               = $discount_src->discount;
 640   $new_attr{active_price_source}    = $price_src;
 641   $new_attr{active_discount_source} = $discount_src;
 642
 643   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
 644   # they cannot be retrieved via custom_variables until the order/orderitem is
 645   # saved. Adding empty custom_variables to new orderitem here solves this problem.
 646   $new_attr{custom_variables} = [];
 647
 648   $item->assign_attributes(%new_attr);
 649
 650   return $item;
 651 }
 652
 653 sub _recalc {
 654   my ($self) = @_;
 655
 656   # bb: todo: currency later
 657   $self->order->currency_id($::instance_conf->get_currency_id());
 658
 659   my %pat = $self->order->calculate_prices_and_taxes();
 660   $self->{taxes} = [];
 661   foreach my $tax_chart_id (keys %{ $pat{taxes} }) {
 662     my $tax = SL::DB::Manager::Tax->find_by(chart_id => $tax_chart_id);
 663
 664     my @amount_keys = grep { $pat{amounts}->{$_}->{tax_id} == $tax->id } keys %{ $pat{amounts} };
 665     push(@{ $self->{taxes} }, { amount    => $pat{taxes}->{$tax_chart_id},
 666                                 netamount => $pat{amounts}->{$amount_keys[0]}->{amount},
 667                                 tax       => $tax });
 668   }
 669
 670   pairwise { $a->{linetotal} = $b->{linetotal} } @{$self->order->items}, @{$pat{items}};
 671 }
 672
 673
 674 sub _get_unalterable_data {
 675   my ($self) = @_;
 676
 677   foreach my $item (@{ $self->order->items }) {
 678     if ($item->id) {
 679       # load data from orderitems (db)
 680       my $db_item = SL::DB::OrderItem->new(id => $item->id)->load;
 681       $item->$_($db_item->$_) for qw(longdescription);
 682     } else {
 683       # set data from part (or other sources)
 684       $item->longdescription($item->part->notes);
 685     }
 686
 687     # autovivify all cvars that are not in the form (cvars_by_config can do it).
 688     # workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
 689     foreach my $var (@{ $item->cvars_by_config }) {
 690       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
 691     }
 692     $item->parse_custom_variable_values;
 693   }
 694 }
 695
 696
 697 sub _delete {
 698   my ($self) = @_;
 699
 700   my $errors = [];
 701   my $db = $self->order->db;
 702
 703   $db->do_transaction(
 704     sub {
 705       my @spoolfiles = grep { $_ } map { $_->spoolfile } @{ SL::DB::Manager::Status->get_all(where => [ trans_id => $self->order->id ]) };
 706       $self->order->delete;
 707       my $spool = $::lx_office_conf{paths}->{spool};
 708       unlink map { "$spool/$_" } @spoolfiles if $spool;
 709
 710       1;
 711   }) || push(@{$errors}, $db->error);
 712
 713   return $errors;
 714 }
 715
 716
 717 sub _save {
 718   my ($self) = @_;
 719
 720   my $errors = [];
 721   my $db = $self->order->db;
 722
 723   $db->do_transaction(
 724     sub {
 725       $self->order->save();
 726   }) || push(@{$errors}, $db->error);
 727
 728   return $errors;
 729 }
 730
 731
 732 sub _pre_render {
 733   my ($self) = @_;
 734
 735   $self->{all_taxzones}        = SL::DB::Manager::TaxZone->get_all_sorted();
 736   $self->{all_departments}     = SL::DB::Manager::Department->get_all_sorted();
 737   $self->{all_employees}       = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->employee_id,
 738                                                                                        deleted => 0 ] ],
 739                                                                     sort_by => 'name');
 740   $self->{all_salesmen}        = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->salesman_id,
 741                                                                                        deleted => 0 ] ],
 742                                                                     sort_by => 'name');
 743   $self->{all_projects}        = SL::DB::Manager::Project->get_all(where => [ or => [ id => $self->order->globalproject_id,
 744                                                                                       active => 1 ] ],
 745                                                                    sort_by => 'projectnumber');
 746   $self->{all_payment_terms}   = SL::DB::Manager::PaymentTerm->get_all_sorted();
 747   $self->{all_delivery_terms}  = SL::DB::Manager::DeliveryTerm->get_all_sorted();
 748
 749   $self->{current_employee_id} = SL::DB::Manager::Employee->current->id;
 750
 751   foreach  my $item (@{$self->order->items}) {
 752     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
 753     $item->active_price_source(   $price_source->price_from_source(   $item->active_price_source   ));
 754     $item->active_discount_source($price_source->discount_from_source($item->active_discount_source));
 755
 756   }
 757
 758   if ($self->order->ordnumber && $::instance_conf->get_webdav) {
 759     my $webdav = SL::Webdav->new(
 760       type     => $self->type,
 761       number   => $self->order->ordnumber,
 762     );
 763     my $webdav_path = $webdav->webdav_path;
 764     my @all_objects = $webdav->get_all_objects;
 765     @{ $self->{template_args}->{WEBDAV} } = map { { name => $_->filename,
 766                                                     type => t8('File'),
 767                                                     link => File::Spec->catdir($webdav_path, $_->filename),
 768                                                 } } @all_objects;
 769   }
 770
 771   $::request->{layout}->use_javascript("${_}.js")  for qw(ckeditor/ckeditor ckeditor/adapters/jquery);
 772 }
 773
 774 sub _create_pdf {
 775   my ($order, $pdf_ref, $params) = @_;
 776
 777   my $print_form = Form->new('');
 778   $print_form->{type}     = $order->type;
 779   $print_form->{formname} = $order->type;
 780   $print_form->{format}   = $params->{format} || 'pdf',
 781   $print_form->{media}    = $params->{media}  || 'file';
 782
 783   $order->flatten_to_form($print_form, format_amounts => 1);
 784   # flatten_to_form sets payment_terms from customer/vendor - we do not want that here
 785   delete $print_form->{payment_terms} if !$print_form->{payment_id};
 786
 787   my @errors = ();
 788   $print_form->throw_on_error(sub {
 789     eval {
 790       $print_form->prepare_for_printing;
 791
 792       $$pdf_ref = SL::Helper::CreatePDF->create_pdf(
 793         template  => SL::Helper::CreatePDF->find_template(name => $print_form->{formname}),
 794         variables => $print_form,
 795         variable_content_types => {
 796           longdescription => 'html',
 797           partnotes       => 'html',
 798           notes           => 'html',
 799         },
 800       );
 801       1;
 802     } || push @errors, ref($EVAL_ERROR) eq 'SL::X::FormError' ? $EVAL_ERROR->getMessage : $EVAL_ERROR;
 803   });
 804
 805   return @errors;
 806 }
 807
 808 sub _sales_order_type {
 809   'sales_order';
 810 }
 811
 812 sub _purchase_order_type {
 813   'purchase_order';
 814 }
 815
 816 1;