SL/Controller/Order.pm

   1 package SL::Controller::Order;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use SL::Helper::Flash;
   7 use SL::Presenter;
   8 use SL::Locale::String;
   9 use SL::SessionFile::Random;
  10 use SL::PriceSource;
  11 use SL::Form;
  12
  13 use SL::DB::Order;
  14 use SL::DB::Customer;
  15 use SL::DB::Vendor;
  16 use SL::DB::TaxZone;
  17 use SL::DB::Employee;
  18 use SL::DB::Project;
  19 use SL::DB::Default;
  20 use SL::DB::Unit;
  21 use SL::DB::Price;
  22
  23 use SL::Helper::DateTime;
  24 use SL::Helper::CreatePDF qw(:all);
  25
  26 use List::Util qw(max first);
  27 use List::MoreUtils qw(none pairwise);
  28 use English qw(-no_match_vars);
  29 use File::Spec;
  30
  31 use Rose::Object::MakeMethods::Generic
  32 (
  33  'scalar --get_set_init' => [ qw(order valid_types type cv p) ],
  34 );
  35
  36
  37 # safety
  38 __PACKAGE__->run_before('_check_auth');
  39
  40 __PACKAGE__->run_before('_recalc',
  41                         only => [ qw(edit update save save_and_delivery_order create_pdf send_email) ]);
  42
  43 __PACKAGE__->run_before('_get_unalterable_data',
  44                         only => [ qw(save save_and_delivery_order create_pdf send_email) ]);
  45
  46 #
  47 # actions
  48 #
  49
  50 sub action_add {
  51   my ($self) = @_;
  52
  53   $self->order->transdate(DateTime->now_local());
  54
  55   $self->_pre_render();
  56   $self->render(
  57     'order/form',
  58     title => $self->type eq _sales_order_type()    ? $::locale->text('Add Sales Order')
  59            : $self->type eq _purchase_order_type() ? $::locale->text('Add Purchase Order')
  60            : '',
  61     %{$self->{template_args}}
  62   );
  63 }
  64
  65 sub action_edit {
  66   my ($self) = @_;
  67
  68   $self->_pre_render();
  69   $self->render(
  70     'order/form',
  71     title => $self->type eq _sales_order_type()    ? $::locale->text('Edit Sales Order')
  72            : $self->type eq _purchase_order_type() ? $::locale->text('Edit Purchase Order')
  73            : '',
  74     %{$self->{template_args}}
  75   );
  76 }
  77
  78 sub action_update {
  79   my ($self) = @_;
  80
  81   $self->_pre_render();
  82   $self->render(
  83     'order/form',
  84     title => $self->type eq _sales_order_type()    ? $::locale->text('Edit Sales Order')
  85            : $self->type eq _purchase_order_type() ? $::locale->text('Edit Purchase Order')
  86            : '',
  87     %{$self->{template_args}}
  88   );
  89 }
  90
  91 sub action_save {
  92   my ($self) = @_;
  93
  94   my $errors = $self->_save();
  95
  96   if (scalar @{ $errors }) {
  97     $self->js->flash('error', $_) foreach @{ $errors };
  98     return $self->js->render();
  99   }
 100
 101   flash_later('info', $::locale->text('The order has been saved'));
 102   my @redirect_params = (
 103     action => 'edit',
 104     type   => $self->type,
 105     id     => $self->order->id,
 106   );
 107
 108   $self->redirect_to(@redirect_params);
 109 }
 110
 111 sub action_create_pdf {
 112   my ($self) = @_;
 113
 114   my $pdf;
 115   my @errors = _create_pdf($self->order, \$pdf);
 116   if (scalar @errors) {
 117     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render($self);
 118   }
 119
 120   my $sfile = SL::SessionFile::Random->new(mode => "w");
 121   $sfile->fh->print($pdf);
 122   $sfile->fh->close;
 123
 124   my $key = join('_', Time::HiRes::gettimeofday(), int rand 1000000000000);
 125   $::auth->set_session_value("Order::create_pdf-${key}" => $sfile->file_name);
 126
 127   my $pdf_filename =  t8('Sales Order') . '_' . $self->order->ordnumber . '.pdf';
 128
 129   $self->js
 130     ->run('download_pdf', $pdf_filename, $key)
 131     ->flash('info', t8('The PDF has been created'))->render($self);
 132 }
 133
 134 sub action_download_pdf {
 135   my ($self) = @_;
 136
 137   my $key = $::form->{key};
 138   my $tmp_filename = $::auth->get_session_value("Order::create_pdf-${key}");
 139   return $self->send_file(
 140     $tmp_filename,
 141     type => 'application/pdf',
 142     name => $::form->{pdf_filename},
 143   );
 144 }
 145
 146 sub action_show_email_dialog {
 147   my ($self) = @_;
 148
 149   my $cv_method = $self->cv;
 150
 151   if (!$self->order->$cv_method) {
 152     return $self->js->flash('error', t8('Cannot send E-mail without ' . $self->cv))
 153                     ->render($self);
 154   }
 155
 156   $self->{email}->{to}   = $self->order->contact->cp_email if $self->order->contact;
 157   $self->{email}->{to} ||= $self->order->$cv_method->email;
 158   $self->{email}->{cc}   = $self->order->$cv_method->cc;
 159   $self->{email}->{bcc}  = join ', ', grep $_, $self->order->$cv_method->bcc, SL::DB::Default->get->global_bcc;
 160   # Todo: get addresses from shipto, if any
 161
 162   my $form = Form->new;
 163   $form->{ordnumber} = $self->order->ordnumber;
 164   $form->{formname}  = $self->type;
 165   $form->{type}      = $self->type;
 166   $form->{language} = 'de';
 167   $form->{format}   = 'pdf';
 168
 169   $self->{email}->{subject}             = $form->generate_email_subject();
 170   $self->{email}->{attachment_filename} = $form->generate_attachment_filename();
 171   $self->{email}->{message}             = $form->create_email_signature();
 172
 173   my $dialog_html = $self->render('order/tabs/_email_dialog', { output => 0 });
 174   $self->js
 175       ->run('show_email_dialog', $dialog_html)
 176       ->reinit_widgets
 177       ->render($self);
 178 }
 179
 180 # Todo: handling error messages: flash is not displayed in dialog, but in the main form
 181 sub action_send_email {
 182   my ($self) = @_;
 183
 184   my $mail      = Mailer->new;
 185   $mail->{from} = qq|"$::myconfig{name}" <$::myconfig{email}>|;
 186   $mail->{$_}   = $::form->{email}->{$_} for qw(to cc bcc subject message);
 187
 188   my $pdf;
 189   my @errors = _create_pdf($self->order, \$pdf, {media => 'email'});
 190   if (scalar @errors) {
 191     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render($self);
 192   }
 193
 194   $mail->{attachments} = [{ "content" => $pdf,
 195                             "name"    => $::form->{email}->{attachment_filename} }];
 196
 197   if (my $err = $mail->send) {
 198     return $self->js->flash('error', t8('Sending E-mail: ') . $err)
 199                     ->render($self);
 200   }
 201
 202   # internal notes
 203   my $intnotes = $self->order->intnotes;
 204   $intnotes   .= "\n\n" if $self->order->intnotes;
 205   $intnotes   .= t8('[email]')                                                                                        . "\n";
 206   $intnotes   .= t8('Date')       . ": " . $::locale->format_date_object(DateTime->now_local, precision => 'seconds') . "\n";
 207   $intnotes   .= t8('To (email)') . ": " . $mail->{to}                                                                . "\n";
 208   $intnotes   .= t8('Cc')         . ": " . $mail->{cc}                                                                . "\n"    if $mail->{cc};
 209   $intnotes   .= t8('Bcc')        . ": " . $mail->{bcc}                                                               . "\n"    if $mail->{bcc};
 210   $intnotes   .= t8('Subject')    . ": " . $mail->{subject}                                                           . "\n\n";
 211   $intnotes   .= t8('Message')    . ": " . $mail->{message};
 212
 213   $self->js
 214       ->val('#order_intnotes', $intnotes)
 215       ->run('close_email_dialog')
 216       ->render($self);
 217 }
 218
 219 sub action_save_and_delivery_order {
 220   my ($self) = @_;
 221
 222   my $errors = $self->_save();
 223
 224   if (scalar @{ $errors }) {
 225     $self->js->flash('error', $_) foreach @{ $errors };
 226     return $self->js->render();
 227   }
 228
 229   my $delivery_order = $self->order->convert_to_delivery_order($self->order);
 230
 231   flash_later('info', $::locale->text('The order has been saved'));
 232   my @redirect_params = (
 233     controller => 'do.pl',
 234     action     => 'edit',
 235     type       => $delivery_order->type,
 236     id         => $delivery_order->id,
 237     vc         => $delivery_order->is_sales ? 'customer' : 'vendor',
 238   );
 239
 240   $self->redirect_to(@redirect_params);
 241 }
 242
 243 sub action_customer_vendor_changed {
 244   my ($self) = @_;
 245
 246   my $cv_method = $self->cv;
 247
 248   if ($self->order->$cv_method->contacts && scalar @{ $self->order->$cv_method->contacts } > 0) {
 249     $self->js->show('#cp_row');
 250   } else {
 251     $self->js->hide('#cp_row');
 252   }
 253
 254   if ($self->order->$cv_method->shipto && scalar @{ $self->order->$cv_method->shipto } > 0) {
 255     $self->js->show('#shipto_row');
 256   } else {
 257     $self->js->hide('#shipto_row');
 258   }
 259
 260   $self->order->taxzone_id($self->order->$cv_method->taxzone_id);
 261
 262   if ($self->order->is_sales) {
 263     $self->order->taxincluded(defined($self->order->$cv_method->taxincluded_checked)
 264                               ? $self->order->$cv_method->taxincluded_checked
 265                               : $::myconfig{taxincluded_checked});
 266   }
 267
 268   $self->_recalc();
 269
 270   $self->js
 271     ->replaceWith('#order_cp_id',       $self->build_contact_select)
 272     ->replaceWith('#order_shipto_id',   $self->build_shipto_select)
 273     ->val(        '#order_taxzone_id',  $self->order->taxzone_id)
 274     ->val(        '#order_taxincluded', $self->order->taxincluded)
 275     ->focus(      '#order_' . $self->cv . '_id');
 276
 277   $self->_js_redisplay_amounts_and_taxes;
 278   $self->js->render();
 279 }
 280
 281 sub action_add_item {
 282   my ($self) = @_;
 283
 284   my $form_attr = $::form->{add_item};
 285
 286   return unless $form_attr->{parts_id};
 287
 288   my $item = SL::DB::OrderItem->new;
 289   $item->assign_attributes(%$form_attr);
 290
 291   my $part        = SL::DB::Part->new(id => $form_attr->{parts_id})->load;
 292   my $cv_method   = $self->cv;
 293   my $cv_discount = $self->order->$cv_method? $self->order->$cv_method->discount : 0.0;
 294
 295   my $price = $item->sellprice;
 296   $price  ||= ($self->order->$cv_method && $self->order->$cv_method->klass)
 297             ? (SL::DB::Manager::Price->find_by(parts_id => $part->id, pricegroup_id => $self->order->$cv_method->klass)->price || $part->sellprice)
 298             : $part->sellprice;
 299
 300   my %new_attr;
 301   $new_attr{part}        = $part;
 302   $new_attr{description} = $part->description if ! $item->description;
 303   $new_attr{qty}         = 1.0                if ! $item->qty;
 304   $new_attr{unit}        = $part->unit;
 305   $new_attr{sellprice}   = $price;
 306   $new_attr{discount}    = $cv_discount       if ! $item->discount;
 307
 308   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
 309   # they cannot be retrieved via custom_variables until the order/orderitem is
 310   # saved. Adding empty custom_variables to new orderitem here solves this problem.
 311   $new_attr{custom_variables} = [];
 312
 313   $item->assign_attributes(%new_attr);
 314
 315   $self->order->add_items($item);
 316
 317   $self->_recalc();
 318
 319   my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 320   my $row_as_html = $self->p->render('order/tabs/_row', ITEM => $item, ID => $item_id);
 321
 322   $self->js
 323     ->append('#row_table_id', $row_as_html)
 324     ->val('#add_item_parts_id', '')
 325     ->val('#add_item_parts_id_name', '')
 326     ->val('#add_item_description', '')
 327     ->val('#add_item_qty_as_number', '')
 328     ->val('#add_item_sellprice_as_number', '')
 329     ->val('#add_item_discount_as_percent', '')
 330     ->run('row_table_scroll_down')
 331     ->run('row_set_keyboard_events_by_id', $item_id)
 332     ->on('.recalc', 'change', 'recalc_amounts_and_taxes')
 333     ->focus('#add_item_parts_id_name');
 334
 335   $self->_js_redisplay_amounts_and_taxes;
 336   $self->js->render();
 337 }
 338
 339 sub action_recalc_amounts_and_taxes {
 340   my ($self) = @_;
 341
 342   $self->_recalc();
 343
 344   $self->_js_redisplay_linetotals;
 345   $self->_js_redisplay_amounts_and_taxes;
 346   $self->js->render();
 347 }
 348
 349 sub _js_redisplay_linetotals {
 350   my ($self) = @_;
 351
 352   my @data = map {$::form->format_amount(\%::myconfig, $_->{linetotal}, 2, 0)} @{ $self->order->items };
 353   $self->js
 354     ->run('redisplay_linetotals', \@data);
 355 }
 356
 357 sub _js_redisplay_amounts_and_taxes {
 358   my ($self) = @_;
 359
 360   if (scalar @{ $self->{taxes} }) {
 361     $self->js->show('#taxincluded_row_id');
 362   } else {
 363     $self->js->hide('#taxincluded_row_id');
 364   }
 365
 366   if ($self->order->taxincluded) {
 367     $self->js->hide('#subtotal_row_id');
 368   } else {
 369     $self->js->show('#subtotal_row_id');
 370   }
 371
 372   $self->js
 373     ->html('#netamount_id', $::form->format_amount(\%::myconfig, $self->order->netamount, -2))
 374     ->html('#amount_id',    $::form->format_amount(\%::myconfig, $self->order->amount,    -2))
 375     ->remove('.tax_row')
 376     ->insertBefore($self->build_tax_rows, '#amount_row_id');
 377 }
 378
 379 #
 380 # helpers
 381 #
 382
 383 sub init_valid_types {
 384   [ _sales_order_type(), _purchase_order_type() ];
 385 }
 386
 387 sub init_type {
 388   my ($self) = @_;
 389
 390   if (none { $::form->{type} eq $_ } @{$self->valid_types}) {
 391     die "Not a valid type for order";
 392   }
 393
 394   $self->type($::form->{type});
 395 }
 396
 397 sub init_cv {
 398   my ($self) = @_;
 399
 400   my $cv = $self->type eq _sales_order_type()    ? 'customer'
 401          : $self->type eq _purchase_order_type() ? 'vendor'
 402          : die "Not a valid type for order";
 403
 404   return $cv;
 405 }
 406
 407 sub init_p {
 408   SL::Presenter->get;
 409 }
 410
 411 sub init_order {
 412   _make_order();
 413 }
 414
 415 sub _check_auth {
 416   my ($self) = @_;
 417
 418   my $right_for = { map { $_ => $_.'_edit' } @{$self->valid_types} };
 419
 420   my $right   = $right_for->{ $self->type };
 421   $right    ||= 'DOES_NOT_EXIST';
 422
 423   $::auth->assert($right);
 424 }
 425
 426 sub build_contact_select {
 427   my ($self) = @_;
 428
 429   $self->p->select_tag('order.cp_id', [ $self->order->{$self->cv}->contacts ],
 430                        value_key  => 'cp_id',
 431                        title_key  => 'full_name_dep',
 432                        default    => $self->order->cp_id,
 433                        with_empty => 1,
 434                        style      => 'width: 300px',
 435   );
 436 }
 437
 438 sub build_shipto_select {
 439   my ($self) = @_;
 440
 441   $self->p->select_tag('order.shipto_id', [ $self->order->{$self->cv}->shipto ],
 442                        value_key  => 'shipto_id',
 443                        title_key  => 'displayable_id',
 444                        default    => $self->order->shipto_id,
 445                        with_empty => 1,
 446                        style      => 'width: 300px',
 447   );
 448 }
 449
 450 sub build_tax_rows {
 451   my ($self) = @_;
 452
 453   my $rows_as_html;
 454   foreach my $tax (@{ $self->{taxes} }) {
 455     $rows_as_html .= $self->p->render('order/tabs/_tax_row', TAX => $tax, TAXINCLUDED => $self->order->taxincluded);
 456   }
 457   return $rows_as_html;
 458 }
 459
 460
 461 sub _make_order {
 462   my ($self) = @_;
 463
 464   # add_items adds items to an order with no items for saving, but they cannot
 465   # be retrieved via items until the order is saved. Adding empty items to new
 466   # order here solves this problem.
 467   my $order;
 468   $order   = SL::DB::Manager::Order->find_by(id => $::form->{id}) if $::form->{id};
 469   $order ||= SL::DB::Order->new(orderitems => []);
 470
 471   $order->assign_attributes(%{$::form->{order}});
 472
 473   return $order;
 474 }
 475
 476
 477 sub _recalc {
 478   my ($self) = @_;
 479
 480   # bb: todo: currency later
 481   $self->order->currency_id($::instance_conf->get_currency_id());
 482
 483   my %pat = $self->order->calculate_prices_and_taxes();
 484   $self->{taxes} = [];
 485   foreach my $tax_chart_id (keys %{ $pat{taxes} }) {
 486     my $tax = SL::DB::Manager::Tax->find_by(chart_id => $tax_chart_id);
 487
 488     my @amount_keys = grep { $pat{amounts}->{$_}->{tax_id} == $tax->id } keys %{ $pat{amounts} };
 489     push(@{ $self->{taxes} }, { amount    => $pat{taxes}->{$tax_chart_id},
 490                                 netamount => $pat{amounts}->{$amount_keys[0]}->{amount},
 491                                 tax       => $tax });
 492   }
 493
 494   pairwise { $a->{linetotal} = $b->{linetotal} } @{$self->order->items}, @{$pat{items}};
 495 }
 496
 497
 498 sub _get_unalterable_data {
 499   my ($self) = @_;
 500
 501   foreach my $item (@{ $self->order->items }) {
 502     if ($item->id) {
 503       # load data from orderitems (db)
 504       my $db_item = SL::DB::OrderItem->new(id => $item->id)->load;
 505       $item->$_($db_item->$_) for qw(active_discount_source active_price_source longdescription);
 506     } else {
 507       # set data from part (or other sources)
 508       $item->longdescription($item->part->notes);
 509       #$item->active_price_source('');
 510       #$item->active_discount_source('');
 511     }
 512
 513     # autovivify all cvars that are not in the form (cvars_by_config can do it).
 514     # workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
 515     foreach my $var (@{ $item->cvars_by_config }) {
 516       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
 517     }
 518     $item->parse_custom_variable_values;
 519   }
 520 }
 521
 522
 523 sub _save {
 524   my ($self) = @_;
 525
 526   my $errors = [];
 527   my $db = $self->order->db;
 528
 529   $db->do_transaction(
 530     sub {
 531       $self->order->save();
 532   }) || push(@{$errors}, $db->error);
 533
 534   return $errors;
 535 }
 536
 537
 538 sub _pre_render {
 539   my ($self) = @_;
 540
 541   $self->{all_taxzones}        = SL::DB::Manager::TaxZone->get_all_sorted();
 542   $self->{all_employees}       = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->employee_id,
 543                                                                                        deleted => 0 ] ],
 544                                                                     sort_by => 'name');
 545   $self->{all_salesmen}        = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->salesman_id,
 546                                                                                        deleted => 0 ] ],
 547                                                                     sort_by => 'name');
 548   $self->{all_projects}        = SL::DB::Manager::Project->get_all(where => [ or => [ id => $self->order->globalproject_id,
 549                                                                                       active => 1 ] ],
 550                                                                    sort_by => 'projectnumber');
 551   $self->{all_payment_terms}   = SL::DB::Manager::PaymentTerm->get_all_sorted();
 552   $self->{all_delivery_terms}  = SL::DB::Manager::DeliveryTerm->get_all_sorted();
 553
 554   $self->{current_employee_id} = SL::DB::Manager::Employee->current->id;
 555
 556   $::request->{layout}->use_javascript("${_}.js")  for qw(ckeditor/ckeditor ckeditor/adapters/jquery);
 557 }
 558
 559 sub _create_pdf {
 560   my ($order, $pdf_ref, $params) = @_;
 561
 562   my $print_form = Form->new('');
 563   $print_form->{type}     = 'sales_order';
 564   $print_form->{formname} = 'sales_order',
 565   $print_form->{format}   = $params->{format} || 'pdf',
 566   $print_form->{media}    = $params->{media}  || 'file';
 567
 568   $order->flatten_to_form($print_form, format_amounts => 1);
 569   # flatten_to_form sets payment_terms from customer/vendor - we do not want that here
 570   delete $print_form->{payment_terms} if !$print_form->{payment_id};
 571
 572   my @errors = ();
 573   $print_form->throw_on_error(sub {
 574     eval {
 575       $print_form->prepare_for_printing;
 576
 577       $$pdf_ref = SL::Helper::CreatePDF->create_pdf(
 578         template  => SL::Helper::CreatePDF->find_template(name => $print_form->{formname}),
 579         variables => $print_form,
 580         variable_content_types => {
 581           longdescription => 'html',
 582           partnotes       => 'html',
 583           notes           => 'html',
 584         },
 585       );
 586       1;
 587     } || push @errors, ref($EVAL_ERROR) eq 'SL::X::FormError' ? $EVAL_ERROR->getMessage : $EVAL_ERROR;
 588   });
 589
 590   return @errors;
 591 }
 592
 593 sub _sales_order_type {
 594   'sales_order';
 595 }
 596
 597 sub _purchase_order_type {
 598   'purchase_order';
 599 }
 600
 601 1;
 602
 603 __END__
 604
 605 =encoding utf-8
 606
 607 =head1 NAME
 608
 609 SL::Controller::Order - controller for orders
 610
 611 =head1 TODO
 612
 613 Testing, PriceSources, pricefactor, units, currency, delivered, delivery order created, ...
 614
 615 =head1 AUTHOR
 616
 617 Bernd Bleßmann E<lt>bernd@kivitendo-premium.deE<gt>
 618
 619 =cut
 620