SL/Controller/Order.pm

   1 package SL::Controller::Order;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use SL::Helper::Flash;
   7 use SL::Presenter;
   8 use SL::Locale::String;
   9 use SL::SessionFile::Random;
  10 use SL::PriceSource;
  11 use SL::Form;
  12 use SL::Webdav;
  13
  14 use SL::DB::Order;
  15 use SL::DB::Customer;
  16 use SL::DB::Vendor;
  17 use SL::DB::TaxZone;
  18 use SL::DB::Employee;
  19 use SL::DB::Project;
  20 use SL::DB::Default;
  21 use SL::DB::Unit;
  22 use SL::DB::Price;
  23 use SL::DB::Part;
  24
  25 use SL::Helper::DateTime;
  26 use SL::Helper::CreatePDF qw(:all);
  27
  28 use SL::Controller::Helper::GetModels;
  29
  30 use List::Util qw(max first);
  31 use List::MoreUtils qw(none pairwise first_index);
  32 use English qw(-no_match_vars);
  33 use File::Spec;
  34
  35 use Rose::Object::MakeMethods::Generic
  36 (
  37  'scalar --get_set_init' => [ qw(order valid_types type cv p multi_items_models) ],
  38 );
  39
  40
  41 # safety
  42 __PACKAGE__->run_before('_check_auth');
  43
  44 __PACKAGE__->run_before('_recalc',
  45                         only => [ qw(edit update save save_and_delivery_order create_pdf send_email) ]);
  46
  47 __PACKAGE__->run_before('_get_unalterable_data',
  48                         only => [ qw(save save_and_delivery_order create_pdf send_email) ]);
  49
  50 #
  51 # actions
  52 #
  53
  54 sub action_add {
  55   my ($self) = @_;
  56
  57   $self->order->transdate(DateTime->now_local());
  58   $self->order->reqdate(DateTime->today_local->next_workday) if !$self->order->reqdate;
  59
  60   $self->_pre_render();
  61   $self->render(
  62     'order/form',
  63     title => $self->type eq _sales_order_type()    ? $::locale->text('Add Sales Order')
  64            : $self->type eq _purchase_order_type() ? $::locale->text('Add Purchase Order')
  65            : '',
  66     %{$self->{template_args}}
  67   );
  68 }
  69
  70 sub action_edit {
  71   my ($self) = @_;
  72
  73   $self->_pre_render();
  74   $self->render(
  75     'order/form',
  76     title => $self->type eq _sales_order_type()    ? $::locale->text('Edit Sales Order')
  77            : $self->type eq _purchase_order_type() ? $::locale->text('Edit Purchase Order')
  78            : '',
  79     %{$self->{template_args}}
  80   );
  81 }
  82
  83 sub action_update {
  84   my ($self) = @_;
  85
  86   $self->_pre_render();
  87   $self->render(
  88     'order/form',
  89     title => $self->type eq _sales_order_type()    ? $::locale->text('Edit Sales Order')
  90            : $self->type eq _purchase_order_type() ? $::locale->text('Edit Purchase Order')
  91            : '',
  92     %{$self->{template_args}}
  93   );
  94 }
  95
  96 sub action_save {
  97   my ($self) = @_;
  98
  99   my $errors = $self->_save();
 100
 101   if (scalar @{ $errors }) {
 102     $self->js->flash('error', $_) foreach @{ $errors };
 103     return $self->js->render();
 104   }
 105
 106   flash_later('info', $::locale->text('The order has been saved'));
 107   my @redirect_params = (
 108     action => 'edit',
 109     type   => $self->type,
 110     id     => $self->order->id,
 111   );
 112
 113   $self->redirect_to(@redirect_params);
 114 }
 115
 116 sub action_create_pdf {
 117   my ($self) = @_;
 118
 119   my $pdf;
 120   my @errors = _create_pdf($self->order, \$pdf);
 121   if (scalar @errors) {
 122     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render($self);
 123   }
 124
 125   my $sfile = SL::SessionFile::Random->new(mode => "w");
 126   $sfile->fh->print($pdf);
 127   $sfile->fh->close;
 128
 129   my $key = join('_', Time::HiRes::gettimeofday(), int rand 1000000000000);
 130   $::auth->set_session_value("Order::create_pdf-${key}" => $sfile->file_name);
 131
 132   my $form = Form->new;
 133   $form->{ordnumber} = $self->order->ordnumber;
 134   $form->{formname}  = $self->type;
 135   $form->{type}      = $self->type;
 136   $form->{language}  = 'de';
 137   $form->{format}    = 'pdf';
 138
 139   my $pdf_filename = $form->generate_attachment_filename();
 140
 141   # copy file to webdav folder
 142   if ($self->order->ordnumber && $::instance_conf->get_webdav_documents) {
 143     my $webdav = SL::Webdav->new(
 144       type     => $self->type,
 145       number   => $self->order->ordnumber,
 146     );
 147     my $webdav_file = SL::Webdav::File->new(
 148       webdav   => $webdav,
 149       filename => $pdf_filename,
 150     );
 151     eval {
 152       $webdav_file->store(data => \$pdf);
 153       1;
 154     } or do {
 155       $self->js->flash('error', t8('Storing PDF to webdav folder failed: #1', $@));
 156     }
 157   }
 158
 159   $self->js
 160     ->run('download_pdf', $pdf_filename, $key)
 161     ->flash('info', t8('The PDF has been created'))->render($self);
 162 }
 163
 164 sub action_download_pdf {
 165   my ($self) = @_;
 166
 167   my $key = $::form->{key};
 168   my $tmp_filename = $::auth->get_session_value("Order::create_pdf-${key}");
 169   return $self->send_file(
 170     $tmp_filename,
 171     type => 'application/pdf',
 172     name => $::form->{pdf_filename},
 173   );
 174 }
 175
 176 sub action_show_email_dialog {
 177   my ($self) = @_;
 178
 179   my $cv_method = $self->cv;
 180
 181   if (!$self->order->$cv_method) {
 182     return $self->js->flash('error', t8('Cannot send E-mail without ' . $self->cv))
 183                     ->render($self);
 184   }
 185
 186   $self->{email}->{to}   = $self->order->contact->cp_email if $self->order->contact;
 187   $self->{email}->{to} ||= $self->order->$cv_method->email;
 188   $self->{email}->{cc}   = $self->order->$cv_method->cc;
 189   $self->{email}->{bcc}  = join ', ', grep $_, $self->order->$cv_method->bcc, SL::DB::Default->get->global_bcc;
 190   # Todo: get addresses from shipto, if any
 191
 192   my $form = Form->new;
 193   $form->{ordnumber} = $self->order->ordnumber;
 194   $form->{formname}  = $self->type;
 195   $form->{type}      = $self->type;
 196   $form->{language} = 'de';
 197   $form->{format}   = 'pdf';
 198
 199   $self->{email}->{subject}             = $form->generate_email_subject();
 200   $self->{email}->{attachment_filename} = $form->generate_attachment_filename();
 201   $self->{email}->{message}             = $form->create_email_signature();
 202
 203   my $dialog_html = $self->render('order/tabs/_email_dialog', { output => 0 });
 204   $self->js
 205       ->run('show_email_dialog', $dialog_html)
 206       ->reinit_widgets
 207       ->render($self);
 208 }
 209
 210 # Todo: handling error messages: flash is not displayed in dialog, but in the main form
 211 sub action_send_email {
 212   my ($self) = @_;
 213
 214   my $mail      = Mailer->new;
 215   $mail->{from} = qq|"$::myconfig{name}" <$::myconfig{email}>|;
 216   $mail->{$_}   = $::form->{email}->{$_} for qw(to cc bcc subject message);
 217
 218   my $pdf;
 219   my @errors = _create_pdf($self->order, \$pdf, {media => 'email'});
 220   if (scalar @errors) {
 221     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render($self);
 222   }
 223
 224   $mail->{attachments} = [{ "content" => $pdf,
 225                             "name"    => $::form->{email}->{attachment_filename} }];
 226
 227   if (my $err = $mail->send) {
 228     return $self->js->flash('error', t8('Sending E-mail: ') . $err)
 229                     ->render($self);
 230   }
 231
 232   # internal notes
 233   my $intnotes = $self->order->intnotes;
 234   $intnotes   .= "\n\n" if $self->order->intnotes;
 235   $intnotes   .= t8('[email]')                                                                                        . "\n";
 236   $intnotes   .= t8('Date')       . ": " . $::locale->format_date_object(DateTime->now_local, precision => 'seconds') . "\n";
 237   $intnotes   .= t8('To (email)') . ": " . $mail->{to}                                                                . "\n";
 238   $intnotes   .= t8('Cc')         . ": " . $mail->{cc}                                                                . "\n"    if $mail->{cc};
 239   $intnotes   .= t8('Bcc')        . ": " . $mail->{bcc}                                                               . "\n"    if $mail->{bcc};
 240   $intnotes   .= t8('Subject')    . ": " . $mail->{subject}                                                           . "\n\n";
 241   $intnotes   .= t8('Message')    . ": " . $mail->{message};
 242
 243   $self->js
 244       ->val('#order_intnotes', $intnotes)
 245       ->run('close_email_dialog')
 246       ->render($self);
 247 }
 248
 249 sub action_save_and_delivery_order {
 250   my ($self) = @_;
 251
 252   my $errors = $self->_save();
 253
 254   if (scalar @{ $errors }) {
 255     $self->js->flash('error', $_) foreach @{ $errors };
 256     return $self->js->render();
 257   }
 258
 259   my $delivery_order = $self->order->convert_to_delivery_order($self->order);
 260
 261   flash_later('info', $::locale->text('The order has been saved'));
 262   my @redirect_params = (
 263     controller => 'do.pl',
 264     action     => 'edit',
 265     type       => $delivery_order->type,
 266     id         => $delivery_order->id,
 267     vc         => $delivery_order->is_sales ? 'customer' : 'vendor',
 268   );
 269
 270   $self->redirect_to(@redirect_params);
 271 }
 272
 273 sub action_customer_vendor_changed {
 274   my ($self) = @_;
 275
 276   my $cv_method = $self->cv;
 277
 278   if ($self->order->$cv_method->contacts && scalar @{ $self->order->$cv_method->contacts } > 0) {
 279     $self->js->show('#cp_row');
 280   } else {
 281     $self->js->hide('#cp_row');
 282   }
 283
 284   if ($self->order->$cv_method->shipto && scalar @{ $self->order->$cv_method->shipto } > 0) {
 285     $self->js->show('#shipto_row');
 286   } else {
 287     $self->js->hide('#shipto_row');
 288   }
 289
 290   $self->order->taxzone_id($self->order->$cv_method->taxzone_id);
 291
 292   if ($self->order->is_sales) {
 293     $self->order->taxincluded(defined($self->order->$cv_method->taxincluded_checked)
 294                               ? $self->order->$cv_method->taxincluded_checked
 295                               : $::myconfig{taxincluded_checked});
 296   }
 297
 298   $self->order->payment_id($self->order->$cv_method->payment_id);
 299   $self->order->delivery_term_id($self->order->$cv_method->delivery_term_id);
 300
 301   $self->_recalc();
 302
 303   $self->js
 304     ->replaceWith('#order_cp_id',            $self->build_contact_select)
 305     ->replaceWith('#order_shipto_id',        $self->build_shipto_select)
 306     ->val(        '#order_taxzone_id',       $self->order->taxzone_id)
 307     ->val(        '#order_taxincluded',      $self->order->taxincluded)
 308     ->val(        '#order_payment_id',       $self->order->payment_id)
 309     ->val(        '#order_delivery_term_id', $self->order->delivery_term_id)
 310     ->focus(      '#order_' . $self->cv . '_id');
 311
 312   $self->_js_redisplay_amounts_and_taxes;
 313   $self->js->render();
 314 }
 315
 316 sub action_add_item {
 317   my ($self) = @_;
 318
 319   my $form_attr = $::form->{add_item};
 320
 321   return unless $form_attr->{parts_id};
 322
 323   my $item = _make_item($self->order, $form_attr);
 324   $self->order->add_items($item);
 325
 326   $self->_recalc();
 327
 328   my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 329   my $row_as_html = $self->p->render('order/tabs/_row', ITEM => $item, ID => $item_id);
 330
 331   $self->js
 332     ->append('#row_table_id', $row_as_html)
 333     ->val('#add_item_parts_id', '')
 334     ->val('#add_item_parts_id_name', '')
 335     ->val('#add_item_description', '')
 336     ->val('#add_item_qty_as_number', '')
 337     ->val('#add_item_sellprice_as_number', '')
 338     ->val('#add_item_discount_as_percent', '')
 339     ->run('row_table_scroll_down')
 340     ->run('row_set_keyboard_events_by_id', $item_id)
 341     ->on('.recalc', 'change', 'recalc_amounts_and_taxes')
 342     ->on('.reformat_number', 'change', 'reformat_number')
 343     ->focus('#add_item_parts_id_name');
 344
 345   $self->_js_redisplay_amounts_and_taxes;
 346   $self->js->render();
 347 }
 348
 349 sub action_show_multi_items_dialog {
 350   require SL::DB::PartsGroup;
 351   $_[0]->render('order/tabs/_multi_items_dialog', { layout => 0 },
 352                 all_partsgroups => SL::DB::Manager::PartsGroup->get_all);
 353 }
 354
 355 sub action_multi_items_update_result {
 356   my $max_count = 100;
 357   my $count = $_[0]->multi_items_models->count;
 358
 359   if ($count == 0) {
 360     my $text = SL::Presenter::EscapedText->new(text => $::locale->text('No results.'));
 361     $_[0]->render($text, { layout => 0 });
 362   } elsif ($count > $max_count) {
 363     my $text = SL::Presenter::EscapedText->new(text => $::locale->text('Too much results (#1 from #2).', $count, $max_count));
 364     $_[0]->render($text, { layout => 0 });
 365   } else {
 366     my $multi_items = $_[0]->multi_items_models->get;
 367     $_[0]->render('order/tabs/_multi_items_result', { layout => 0 },
 368                   multi_items => $multi_items);
 369   }
 370 }
 371
 372 sub action_add_multi_items {
 373   my ($self) = @_;
 374
 375   my @form_attr = grep { $_->{qty_as_number} } @{ $::form->{add_multi_items} };
 376   return $self->js->render() unless scalar @form_attr;
 377
 378   my @items;
 379   foreach my $attr (@form_attr) {
 380     push @items, _make_item($self->order, $attr);
 381   }
 382   $self->order->add_items(@items);
 383
 384   $self->_recalc();
 385
 386   foreach my $item (@items) {
 387     my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 388     my $row_as_html = $self->p->render('order/tabs/_row', ITEM => $item, ID => $item_id);
 389
 390     $self->js
 391         ->append('#row_table_id', $row_as_html)
 392         ->run('row_set_keyboard_events_by_id', $item_id);
 393   }
 394
 395   $self->js
 396     ->run('close_multi_items_dialog')
 397     ->run('row_table_scroll_down')
 398     ->on('.recalc', 'change', 'recalc_amounts_and_taxes')
 399     ->on('.reformat_number', 'change', 'reformat_number')
 400     ->focus('#add_item_parts_id_name');
 401
 402   $self->_js_redisplay_amounts_and_taxes;
 403   $self->js->render();
 404 }
 405
 406 sub action_recalc_amounts_and_taxes {
 407   my ($self) = @_;
 408
 409   $self->_recalc();
 410
 411   $self->_js_redisplay_linetotals;
 412   $self->_js_redisplay_amounts_and_taxes;
 413   $self->js->render();
 414 }
 415
 416 sub action_price_popup {
 417   my ($self) = @_;
 418
 419   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 420   my $item = $self->order->items->[$idx];
 421
 422   $self->render_price_dialog($item);
 423 }
 424
 425 sub _js_redisplay_linetotals {
 426   my ($self) = @_;
 427
 428   my @data = map {$::form->format_amount(\%::myconfig, $_->{linetotal}, 2, 0)} @{ $self->order->items };
 429   $self->js
 430     ->run('redisplay_linetotals', \@data);
 431 }
 432
 433 sub _js_redisplay_amounts_and_taxes {
 434   my ($self) = @_;
 435
 436   if (scalar @{ $self->{taxes} }) {
 437     $self->js->show('#taxincluded_row_id');
 438   } else {
 439     $self->js->hide('#taxincluded_row_id');
 440   }
 441
 442   if ($self->order->taxincluded) {
 443     $self->js->hide('#subtotal_row_id');
 444   } else {
 445     $self->js->show('#subtotal_row_id');
 446   }
 447
 448   $self->js
 449     ->html('#netamount_id', $::form->format_amount(\%::myconfig, $self->order->netamount, -2))
 450     ->html('#amount_id',    $::form->format_amount(\%::myconfig, $self->order->amount,    -2))
 451     ->remove('.tax_row')
 452     ->insertBefore($self->build_tax_rows, '#amount_row_id');
 453 }
 454
 455 #
 456 # helpers
 457 #
 458
 459 sub init_valid_types {
 460   [ _sales_order_type(), _purchase_order_type() ];
 461 }
 462
 463 sub init_type {
 464   my ($self) = @_;
 465
 466   if (none { $::form->{type} eq $_ } @{$self->valid_types}) {
 467     die "Not a valid type for order";
 468   }
 469
 470   $self->type($::form->{type});
 471 }
 472
 473 sub init_cv {
 474   my ($self) = @_;
 475
 476   my $cv = $self->type eq _sales_order_type()    ? 'customer'
 477          : $self->type eq _purchase_order_type() ? 'vendor'
 478          : die "Not a valid type for order";
 479
 480   return $cv;
 481 }
 482
 483 sub init_p {
 484   SL::Presenter->get;
 485 }
 486
 487 sub init_order {
 488   _make_order();
 489 }
 490
 491 sub init_multi_items_models {
 492   SL::Controller::Helper::GetModels->new(
 493     controller     => $_[0],
 494     model          => 'Part',
 495     with_objects   => [ qw(unit_obj) ],
 496     disable_plugin => 'paginated',
 497     source         => $::form->{multi_items},
 498     sorted         => {
 499       _default    => {
 500         by  => 'partnumber',
 501         dir => 1,
 502       },
 503       partnumber  => t8('Partnumber'),
 504       description => t8('Description')}
 505   );
 506 }
 507
 508 sub _check_auth {
 509   my ($self) = @_;
 510
 511   my $right_for = { map { $_ => $_.'_edit' } @{$self->valid_types} };
 512
 513   my $right   = $right_for->{ $self->type };
 514   $right    ||= 'DOES_NOT_EXIST';
 515
 516   $::auth->assert($right);
 517 }
 518
 519 sub build_contact_select {
 520   my ($self) = @_;
 521
 522   $self->p->select_tag('order.cp_id', [ $self->order->{$self->cv}->contacts ],
 523                        value_key  => 'cp_id',
 524                        title_key  => 'full_name_dep',
 525                        default    => $self->order->cp_id,
 526                        with_empty => 1,
 527                        style      => 'width: 300px',
 528   );
 529 }
 530
 531 sub build_shipto_select {
 532   my ($self) = @_;
 533
 534   $self->p->select_tag('order.shipto_id', [ $self->order->{$self->cv}->shipto ],
 535                        value_key  => 'shipto_id',
 536                        title_key  => 'displayable_id',
 537                        default    => $self->order->shipto_id,
 538                        with_empty => 1,
 539                        style      => 'width: 300px',
 540   );
 541 }
 542
 543 sub build_tax_rows {
 544   my ($self) = @_;
 545
 546   my $rows_as_html;
 547   foreach my $tax (sort { $a->{tax}->rate cmp $b->{tax}->rate } @{ $self->{taxes} }) {
 548     $rows_as_html .= $self->p->render('order/tabs/_tax_row', TAX => $tax, TAXINCLUDED => $self->order->taxincluded);
 549   }
 550   return $rows_as_html;
 551 }
 552
 553
 554 sub render_price_dialog {
 555   my ($self, $record_item) = @_;
 556
 557   my $price_source = SL::PriceSource->new(record_item => $record_item, record => $self->order);
 558
 559   $self->js
 560     ->run(
 561       'kivi.io.price_chooser_dialog',
 562       t8('Available Prices'),
 563       $self->render('order/tabs/_price_sources_dialog', { output => 0 }, price_source => $price_source)
 564     )
 565     ->reinit_widgets;
 566
 567 #   if (@errors) {
 568 #     $self->js->text('#dialog_flash_error_content', join ' ', @errors);
 569 #     $self->js->show('#dialog_flash_error');
 570 #   }
 571
 572   $self->js->render;
 573 }
 574
 575 sub _make_order {
 576   my ($self) = @_;
 577
 578   # add_items adds items to an order with no items for saving, but they cannot
 579   # be retrieved via items until the order is saved. Adding empty items to new
 580   # order here solves this problem.
 581   my $order;
 582   $order   = SL::DB::Manager::Order->find_by(id => $::form->{id}) if $::form->{id};
 583   $order ||= SL::DB::Order->new(orderitems => []);
 584
 585   $order->assign_attributes(%{$::form->{order}});
 586
 587   return $order;
 588 }
 589
 590 sub _make_item {
 591   my ($record, $attr) = @_;
 592
 593   my $item = SL::DB::OrderItem->new;
 594   $item->assign_attributes(%$attr);
 595
 596   my $part         = SL::DB::Part->new(id => $attr->{parts_id})->load;
 597   my $price_source = SL::PriceSource->new(record_item => $item, record => $record);
 598
 599   $item->unit($part->unit) if !$item->unit;
 600
 601   my $price_src;
 602   if ($item->sellprice) {
 603     $price_src = $price_source->price_from_source("");
 604     $price_src->price($item->sellprice);
 605   } else {
 606     $price_src = $price_source->best_price
 607            ? $price_source->best_price
 608            : $price_source->price_from_source("");
 609     $price_src->price(0) if !$price_source->best_price;
 610   }
 611
 612   my $discount_src;
 613   if ($item->discount) {
 614     $discount_src = $price_source->discount_from_source("");
 615     $discount_src->discount($item->discount);
 616   } else {
 617     $discount_src = $price_source->best_discount
 618                   ? $price_source->best_discount
 619                   : $price_source->discount_from_source("");
 620     $discount_src->discount(0) if !$price_source->best_discount;
 621   }
 622
 623   my %new_attr;
 624   $new_attr{part}                   = $part;
 625   $new_attr{description}            = $part->description if ! $item->description;
 626   $new_attr{qty}                    = 1.0                if ! $item->qty;
 627   $new_attr{sellprice}              = $price_src->price;
 628   $new_attr{discount}               = $discount_src->discount;
 629   $new_attr{active_price_source}    = $price_src;
 630   $new_attr{active_discount_source} = $discount_src;
 631
 632   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
 633   # they cannot be retrieved via custom_variables until the order/orderitem is
 634   # saved. Adding empty custom_variables to new orderitem here solves this problem.
 635   $new_attr{custom_variables} = [];
 636
 637   $item->assign_attributes(%new_attr);
 638
 639   return $item;
 640 }
 641
 642 sub _recalc {
 643   my ($self) = @_;
 644
 645   # bb: todo: currency later
 646   $self->order->currency_id($::instance_conf->get_currency_id());
 647
 648   my %pat = $self->order->calculate_prices_and_taxes();
 649   $self->{taxes} = [];
 650   foreach my $tax_chart_id (keys %{ $pat{taxes} }) {
 651     my $tax = SL::DB::Manager::Tax->find_by(chart_id => $tax_chart_id);
 652
 653     my @amount_keys = grep { $pat{amounts}->{$_}->{tax_id} == $tax->id } keys %{ $pat{amounts} };
 654     push(@{ $self->{taxes} }, { amount    => $pat{taxes}->{$tax_chart_id},
 655                                 netamount => $pat{amounts}->{$amount_keys[0]}->{amount},
 656                                 tax       => $tax });
 657   }
 658
 659   pairwise { $a->{linetotal} = $b->{linetotal} } @{$self->order->items}, @{$pat{items}};
 660 }
 661
 662
 663 sub _get_unalterable_data {
 664   my ($self) = @_;
 665
 666   foreach my $item (@{ $self->order->items }) {
 667     if ($item->id) {
 668       # load data from orderitems (db)
 669       my $db_item = SL::DB::OrderItem->new(id => $item->id)->load;
 670       $item->$_($db_item->$_) for qw(longdescription);
 671     } else {
 672       # set data from part (or other sources)
 673       $item->longdescription($item->part->notes);
 674     }
 675
 676     # autovivify all cvars that are not in the form (cvars_by_config can do it).
 677     # workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
 678     foreach my $var (@{ $item->cvars_by_config }) {
 679       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
 680     }
 681     $item->parse_custom_variable_values;
 682   }
 683 }
 684
 685
 686 sub _save {
 687   my ($self) = @_;
 688
 689   my $errors = [];
 690   my $db = $self->order->db;
 691
 692   $db->do_transaction(
 693     sub {
 694       $self->order->save();
 695   }) || push(@{$errors}, $db->error);
 696
 697   return $errors;
 698 }
 699
 700
 701 sub _pre_render {
 702   my ($self) = @_;
 703
 704   $self->{all_taxzones}        = SL::DB::Manager::TaxZone->get_all_sorted();
 705   $self->{all_departments}     = SL::DB::Manager::Department->get_all_sorted();
 706   $self->{all_employees}       = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->employee_id,
 707                                                                                        deleted => 0 ] ],
 708                                                                     sort_by => 'name');
 709   $self->{all_salesmen}        = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->salesman_id,
 710                                                                                        deleted => 0 ] ],
 711                                                                     sort_by => 'name');
 712   $self->{all_projects}        = SL::DB::Manager::Project->get_all(where => [ or => [ id => $self->order->globalproject_id,
 713                                                                                       active => 1 ] ],
 714                                                                    sort_by => 'projectnumber');
 715   $self->{all_payment_terms}   = SL::DB::Manager::PaymentTerm->get_all_sorted();
 716   $self->{all_delivery_terms}  = SL::DB::Manager::DeliveryTerm->get_all_sorted();
 717
 718   $self->{current_employee_id} = SL::DB::Manager::Employee->current->id;
 719
 720   foreach  my $item (@{$self->order->items}) {
 721     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
 722     $item->active_price_source(   $price_source->price_from_source(   $item->active_price_source   ));
 723     $item->active_discount_source($price_source->discount_from_source($item->active_discount_source));
 724
 725   }
 726
 727   if ($self->order->ordnumber && $::instance_conf->get_webdav) {
 728     my $webdav = SL::Webdav->new(
 729       type     => $self->type,
 730       number   => $self->order->ordnumber,
 731     );
 732     my $webdav_path = $webdav->webdav_path;
 733     my @all_objects = $webdav->get_all_objects;
 734     @{ $self->{template_args}->{WEBDAV} } = map { { name => $_->filename,
 735                                                     type => t8('File'),
 736                                                     link => File::Spec->catdir($webdav_path, $_->filename),
 737                                                 } } @all_objects;
 738   }
 739
 740   $::request->{layout}->use_javascript("${_}.js")  for qw(ckeditor/ckeditor ckeditor/adapters/jquery);
 741 }
 742
 743 sub _create_pdf {
 744   my ($order, $pdf_ref, $params) = @_;
 745
 746   my $print_form = Form->new('');
 747   $print_form->{type}     = $order->type;
 748   $print_form->{formname} = $order->type;
 749   $print_form->{format}   = $params->{format} || 'pdf',
 750   $print_form->{media}    = $params->{media}  || 'file';
 751
 752   $order->flatten_to_form($print_form, format_amounts => 1);
 753   # flatten_to_form sets payment_terms from customer/vendor - we do not want that here
 754   delete $print_form->{payment_terms} if !$print_form->{payment_id};
 755
 756   my @errors = ();
 757   $print_form->throw_on_error(sub {
 758     eval {
 759       $print_form->prepare_for_printing;
 760
 761       $$pdf_ref = SL::Helper::CreatePDF->create_pdf(
 762         template  => SL::Helper::CreatePDF->find_template(name => $print_form->{formname}),
 763         variables => $print_form,
 764         variable_content_types => {
 765           longdescription => 'html',
 766           partnotes       => 'html',
 767           notes           => 'html',
 768         },
 769       );
 770       1;
 771     } || push @errors, ref($EVAL_ERROR) eq 'SL::X::FormError' ? $EVAL_ERROR->getMessage : $EVAL_ERROR;
 772   });
 773
 774   return @errors;
 775 }
 776
 777 sub _sales_order_type {
 778   'sales_order';
 779 }
 780
 781 sub _purchase_order_type {
 782   'purchase_order';
 783 }
 784
 785 1;
 786
 787 __END__
 788
 789 =encoding utf-8
 790
 791 =head1 NAME
 792
 793 SL::Controller::Order - controller for orders
 794
 795 =head1 TODO
 796
 797 Testing, PriceSources, pricefactor, units, currency, delivered, delivery order created, ...
 798
 799 =head1 AUTHOR
 800
 801 Bernd Bleßmann E<lt>bernd@kivitendo-premium.deE<gt>
 802
 803 =cut
 804