SL/Controller/Order.pm

   1 package SL::Controller::Order;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use SL::Helper::Flash qw(flash_later);
   7 use SL::Presenter::Tag qw(select_tag hidden_tag);
   8 use SL::Locale::String qw(t8);
   9 use SL::SessionFile::Random;
  10 use SL::PriceSource;
  11 use SL::Webdav;
  12 use SL::File;
  13 use SL::Util qw(trim);
  14 use SL::DB::Order;
  15 use SL::DB::Default;
  16 use SL::DB::Unit;
  17 use SL::DB::Part;
  18 use SL::DB::PartsGroup;
  19 use SL::DB::Printer;
  20 use SL::DB::Language;
  21 use SL::DB::RecordLink;
  22
  23 use SL::Helper::CreatePDF qw(:all);
  24 use SL::Helper::PrintOptions;
  25 use SL::Helper::ShippedQty;
  26
  27 use SL::Controller::Helper::GetModels;
  28
  29 use List::Util qw(first);
  30 use List::UtilsBy qw(sort_by uniq_by);
  31 use List::MoreUtils qw(any none pairwise first_index);
  32 use English qw(-no_match_vars);
  33 use File::Spec;
  34 use Cwd;
  35 use Sort::Naturally;
  36
  37 use Rose::Object::MakeMethods::Generic
  38 (
  39  scalar => [ qw(item_ids_to_delete) ],
  40  'scalar --get_set_init' => [ qw(order valid_types type cv p multi_items_models all_price_factors) ],
  41 );
  42
  43
  44 # safety
  45 __PACKAGE__->run_before('check_auth');
  46
  47 __PACKAGE__->run_before('recalc',
  48                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice print send_email) ]);
  49
  50 __PACKAGE__->run_before('get_unalterable_data',
  51                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice print send_email) ]);
  52
  53 #
  54 # actions
  55 #
  56
  57 # add a new order
  58 sub action_add {
  59   my ($self) = @_;
  60
  61   $self->order->transdate(DateTime->now_local());
  62   my $extra_days = $self->{type} eq 'sales_quotation' ? $::instance_conf->get_reqdate_interval       :
  63                    $self->{type} eq 'sales_order'     ? $::instance_conf->get_delivery_date_interval : 1;
  64   $self->order->reqdate(DateTime->today_local->next_workday(extra_days => $extra_days)) if !$self->order->reqdate;
  65
  66
  67   $self->pre_render();
  68   $self->render(
  69     'order/form',
  70     title => $self->get_title_for('add'),
  71     %{$self->{template_args}}
  72   );
  73 }
  74
  75 # edit an existing order
  76 sub action_edit {
  77   my ($self) = @_;
  78
  79   if ($::form->{id}) {
  80     $self->load_order;
  81
  82   } else {
  83     # this is to edit an order from an unsaved order object
  84
  85     # set item ids to new fake id, to identify them as new items
  86     foreach my $item (@{$self->order->items_sorted}) {
  87       $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
  88     }
  89     # trigger rendering values for second row/longdescription as hidden,
  90     # because they are loaded only on demand. So we need to keep the values
  91     # from the source.
  92     $_->{render_second_row}      = 1 for @{ $self->order->items_sorted };
  93     $_->{render_longdescription} = 1 for @{ $self->order->items_sorted };
  94   }
  95
  96   $self->recalc();
  97   $self->pre_render();
  98   $self->render(
  99     'order/form',
 100     title => $self->get_title_for('edit'),
 101     %{$self->{template_args}}
 102   );
 103 }
 104
 105 # edit a collective order (consisting of one or more existing orders)
 106 sub action_edit_collective {
 107   my ($self) = @_;
 108
 109   # collect order ids
 110   my @multi_ids = map {
 111     $_ =~ m{^multi_id_(\d+)$} && $::form->{'multi_id_' . $1} && $::form->{'trans_id_' . $1} && $::form->{'trans_id_' . $1}
 112   } grep { $_ =~ m{^multi_id_\d+$} } keys %$::form;
 113
 114   # fall back to add if no ids are given
 115   if (scalar @multi_ids == 0) {
 116     $self->action_add();
 117     return;
 118   }
 119
 120   # fall back to save as new if only one id is given
 121   if (scalar @multi_ids == 1) {
 122     $self->order(SL::DB::Order->new(id => $multi_ids[0])->load);
 123     $self->action_save_as_new();
 124     return;
 125   }
 126
 127   # make new order from given orders
 128   my @multi_orders = map { SL::DB::Order->new(id => $_)->load } @multi_ids;
 129   $self->{converted_from_oe_id} = join ' ', map { $_->id } @multi_orders;
 130   $self->order(SL::DB::Order->new_from_multi(\@multi_orders, sort_sources_by => 'transdate'));
 131
 132   $self->action_edit();
 133 }
 134
 135 # delete the order
 136 sub action_delete {
 137   my ($self) = @_;
 138
 139   my $errors = $self->delete();
 140
 141   if (scalar @{ $errors }) {
 142     $self->js->flash('error', $_) foreach @{ $errors };
 143     return $self->js->render();
 144   }
 145
 146   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been deleted')
 147            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been deleted')
 148            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been deleted')
 149            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been deleted')
 150            : '';
 151   flash_later('info', $text);
 152
 153   my @redirect_params = (
 154     action => 'add',
 155     type   => $self->type,
 156   );
 157
 158   $self->redirect_to(@redirect_params);
 159 }
 160
 161 # save the order
 162 sub action_save {
 163   my ($self) = @_;
 164
 165   my $errors = $self->save();
 166
 167   if (scalar @{ $errors }) {
 168     $self->js->flash('error', $_) foreach @{ $errors };
 169     return $self->js->render();
 170   }
 171
 172   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
 173            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
 174            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
 175            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
 176            : '';
 177   flash_later('info', $text);
 178
 179   my @redirect_params = (
 180     action => 'edit',
 181     type   => $self->type,
 182     id     => $self->order->id,
 183   );
 184
 185   $self->redirect_to(@redirect_params);
 186 }
 187
 188 # save the order as new document an open it for edit
 189 sub action_save_as_new {
 190   my ($self) = @_;
 191
 192   my $order = $self->order;
 193
 194   if (!$order->id) {
 195     $self->js->flash('error', t8('This object has not been saved yet.'));
 196     return $self->js->render();
 197   }
 198
 199   # load order from db to check if values changed
 200   my $saved_order = SL::DB::Order->new(id => $order->id)->load;
 201
 202   my %new_attrs;
 203   # Lets assign a new number if the user hasn't changed the previous one.
 204   # If it has been changed manually then use it as-is.
 205   $new_attrs{number}    = (trim($order->number) eq $saved_order->number)
 206                         ? ''
 207                         : trim($order->number);
 208
 209   # Clear transdate unless changed
 210   $new_attrs{transdate} = ($order->transdate == $saved_order->transdate)
 211                         ? DateTime->today_local
 212                         : $order->transdate;
 213
 214   # Set new reqdate unless changed
 215   if ($order->reqdate == $saved_order->reqdate) {
 216     my $extra_days = $self->{type} eq 'sales_quotation' ? $::instance_conf->get_reqdate_interval       :
 217                      $self->{type} eq 'sales_order'     ? $::instance_conf->get_delivery_date_interval : 1;
 218     $new_attrs{reqdate} = DateTime->today_local->next_workday(extra_days => $extra_days);
 219   } else {
 220     $new_attrs{reqdate} = $order->reqdate;
 221   }
 222
 223   # Update employee
 224   $new_attrs{employee}  = SL::DB::Manager::Employee->current;
 225
 226   # Create new record from current one
 227   $self->order(SL::DB::Order->new_from($order, destination_type => $order->type, attributes => \%new_attrs));
 228
 229   # no linked records on save as new
 230   delete $::form->{$_} for qw(converted_from_oe_id converted_from_orderitems_ids);
 231
 232   # save
 233   $self->action_save();
 234 }
 235
 236 # print the order
 237 #
 238 # This is called if "print" is pressed in the print dialog.
 239 # If PDF creation was requested and succeeded, the pdf is stored in a session
 240 # file and the filename is stored as session value with an unique key. A
 241 # javascript function with this key is then called. This function calls the
 242 # download action below (action_download_pdf), which offers the file for
 243 # download.
 244 sub action_print {
 245   my ($self) = @_;
 246
 247   my $errors = $self->save();
 248
 249   if (scalar @{ $errors }) {
 250     $self->js->flash('error', $_) foreach @{ $errors };
 251     return $self->js->render();
 252   }
 253
 254   $self->js->val('#id', $self->order->id)
 255            ->val('#order_' . $self->nr_key(), $self->order->number);
 256
 257   my $format      = $::form->{print_options}->{format};
 258   my $media       = $::form->{print_options}->{media};
 259   my $formname    = $::form->{print_options}->{formname};
 260   my $copies      = $::form->{print_options}->{copies};
 261   my $groupitems  = $::form->{print_options}->{groupitems};
 262
 263   # only pdf and opendocument by now
 264   if (none { $format eq $_ } qw(pdf opendocument opendocument_pdf)) {
 265     return $self->js->flash('error', t8('Format \'#1\' is not supported yet/anymore.', $format))->render;
 266   }
 267
 268   # only screen or printer by now
 269   if (none { $media eq $_ } qw(screen printer)) {
 270     return $self->js->flash('error', t8('Media \'#1\' is not supported yet/anymore.', $media))->render;
 271   }
 272
 273   my $language;
 274   $language = SL::DB::Language->new(id => $::form->{print_options}->{language_id})->load if $::form->{print_options}->{language_id};
 275
 276   # create a form for generate_attachment_filename
 277   my $form   = Form->new;
 278   $form->{$self->nr_key()}  = $self->order->number;
 279   $form->{type}             = $self->type;
 280   $form->{format}           = $format;
 281   $form->{formname}         = $formname;
 282   $form->{language}         = '_' . $language->template_code if $language;
 283   my $pdf_filename          = $form->generate_attachment_filename();
 284
 285   my $pdf;
 286   my @errors = generate_pdf($self->order, \$pdf, { format     => $format,
 287                                                    formname   => $formname,
 288                                                    language   => $language,
 289                                                    groupitems => $groupitems });
 290   if (scalar @errors) {
 291     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render;
 292   }
 293
 294   if ($media eq 'screen') {
 295     # screen/download
 296     my $sfile = SL::SessionFile::Random->new(mode => "w");
 297     $sfile->fh->print($pdf);
 298     $sfile->fh->close;
 299
 300     my $key = join('_', Time::HiRes::gettimeofday(), int rand 1000000000000);
 301     $::auth->set_session_value("Order::print-${key}" => $sfile->file_name);
 302
 303     $self->js
 304     ->run('kivi.Order.download_pdf', $pdf_filename, $key)
 305     ->flash('info', t8('The PDF has been created'));
 306
 307   } elsif ($media eq 'printer') {
 308     # printer
 309     my $printer_id = $::form->{print_options}->{printer_id};
 310     SL::DB::Printer->new(id => $printer_id)->load->print_document(
 311       copies  => $copies,
 312       content => $pdf,
 313     );
 314
 315     $self->js->flash('info', t8('The PDF has been printed'));
 316   }
 317
 318   # copy file to webdav folder
 319   if ($self->order->number && $::instance_conf->get_webdav_documents) {
 320     my $webdav = SL::Webdav->new(
 321       type     => $self->type,
 322       number   => $self->order->number,
 323     );
 324     my $webdav_file = SL::Webdav::File->new(
 325       webdav   => $webdav,
 326       filename => $pdf_filename,
 327     );
 328     eval {
 329       $webdav_file->store(data => \$pdf);
 330       1;
 331     } or do {
 332       $self->js->flash('error', t8('Storing PDF to webdav folder failed: #1', $@));
 333     }
 334   }
 335   if ($self->order->number && $::instance_conf->get_doc_storage) {
 336     eval {
 337       SL::File->save(object_id     => $self->order->id,
 338                      object_type   => $self->type,
 339                      mime_type     => 'application/pdf',
 340                      source        => 'created',
 341                      file_type     => 'document',
 342                      file_name     => $pdf_filename,
 343                      file_contents => $pdf);
 344       1;
 345     } or do {
 346       $self->js->flash('error', t8('Storing PDF in storage backend failed: #1', $@));
 347     }
 348   }
 349   $self->js->render;
 350 }
 351
 352 # offer pdf for download
 353 #
 354 # It needs to get the key for the session value to get the pdf file.
 355 sub action_download_pdf {
 356   my ($self) = @_;
 357
 358   my $key = $::form->{key};
 359   my $tmp_filename = $::auth->get_session_value("Order::print-${key}");
 360   return $self->send_file(
 361     $tmp_filename,
 362     type => 'application/pdf',
 363     name => $::form->{pdf_filename},
 364   );
 365 }
 366
 367 # open the email dialog
 368 sub action_show_email_dialog {
 369   my ($self) = @_;
 370
 371   my $cv_method = $self->cv;
 372
 373   if (!$self->order->$cv_method) {
 374     return $self->js->flash('error', $self->cv eq 'customer' ? t8('Cannot send E-mail without customer given') : t8('Cannot send E-mail without vendor given'))
 375                     ->render($self);
 376   }
 377
 378   my $email_form;
 379   $email_form->{to}   = $self->order->contact->cp_email if $self->order->contact;
 380   $email_form->{to} ||= $self->order->$cv_method->email;
 381   $email_form->{cc}   = $self->order->$cv_method->cc;
 382   $email_form->{bcc}  = join ', ', grep $_, $self->order->$cv_method->bcc, SL::DB::Default->get->global_bcc;
 383   # Todo: get addresses from shipto, if any
 384
 385   my $form = Form->new;
 386   $form->{$self->nr_key()}  = $self->order->number;
 387   $form->{formname}         = $self->type;
 388   $form->{type}             = $self->type;
 389   $form->{language}         = 'de';
 390   $form->{format}           = 'pdf';
 391
 392   $email_form->{subject}             = $form->generate_email_subject();
 393   $email_form->{attachment_filename} = $form->generate_attachment_filename();
 394   $email_form->{message}             = $form->generate_email_body();
 395   $email_form->{js_send_function}    = 'kivi.Order.send_email()';
 396
 397   my %files = $self->get_files_for_email_dialog();
 398   my $dialog_html = $self->render('common/_send_email_dialog', { output => 0 },
 399                                   email_form  => $email_form,
 400                                   show_bcc    => $::auth->assert('email_bcc', 'may fail'),
 401                                   FILES       => \%files,
 402                                   is_customer => $self->cv eq 'customer',
 403   );
 404
 405   $self->js
 406       ->run('kivi.Order.show_email_dialog', $dialog_html)
 407       ->reinit_widgets
 408       ->render($self);
 409 }
 410
 411 # send email
 412 #
 413 # Todo: handling error messages: flash is not displayed in dialog, but in the main form
 414 sub action_send_email {
 415   my ($self) = @_;
 416
 417   my $errors = $self->save();
 418
 419   if (scalar @{ $errors }) {
 420     $self->js->run('kivi.Order.close_email_dialog');
 421     $self->js->flash('error', $_) foreach @{ $errors };
 422     return $self->js->render();
 423   }
 424
 425   $self->js->val('#id', $self->order->id)
 426            ->val('#order_' . $self->nr_key(), $self->order->number);
 427
 428   my $email_form  = delete $::form->{email_form};
 429   my %field_names = (to => 'email');
 430
 431   $::form->{ $field_names{$_} // $_ } = $email_form->{$_} for keys %{ $email_form };
 432
 433   # for Form::cleanup which may be called in Form::send_email
 434   $::form->{cwd}    = getcwd();
 435   $::form->{tmpdir} = $::lx_office_conf{paths}->{userspath};
 436
 437   $::form->{$_}     = $::form->{print_options}->{$_} for keys %{ $::form->{print_options} };
 438   $::form->{media}  = 'email';
 439
 440   if (($::form->{attachment_policy} // '') !~ m{^(?:old_file|no_file)$}) {
 441     my $language;
 442     $language = SL::DB::Language->new(id => $::form->{print_options}->{language_id})->load if $::form->{print_options}->{language_id};
 443
 444     my $pdf;
 445     my @errors = generate_pdf($self->order, \$pdf, {media      => $::form->{media},
 446                                                     format     => $::form->{print_options}->{format},
 447                                                     formname   => $::form->{print_options}->{formname},
 448                                                     language   => $language,
 449                                                     groupitems => $::form->{print_options}->{groupitems}});
 450     if (scalar @errors) {
 451       return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render($self);
 452     }
 453
 454     my $sfile = SL::SessionFile::Random->new(mode => "w");
 455     $sfile->fh->print($pdf);
 456     $sfile->fh->close;
 457
 458     $::form->{tmpfile} = $sfile->file_name;
 459     $::form->{tmpdir}  = $sfile->get_path; # for Form::cleanup which may be called in Form::send_email
 460   }
 461
 462   $::form->send_email(\%::myconfig, 'pdf');
 463
 464   # internal notes
 465   my $intnotes = $self->order->intnotes;
 466   $intnotes   .= "\n\n" if $self->order->intnotes;
 467   $intnotes   .= t8('[email]')                                                                                        . "\n";
 468   $intnotes   .= t8('Date')       . ": " . $::locale->format_date_object(DateTime->now_local, precision => 'seconds') . "\n";
 469   $intnotes   .= t8('To (email)') . ": " . $::form->{email}                                                           . "\n";
 470   $intnotes   .= t8('Cc')         . ": " . $::form->{cc}                                                              . "\n"    if $::form->{cc};
 471   $intnotes   .= t8('Bcc')        . ": " . $::form->{bcc}                                                             . "\n"    if $::form->{bcc};
 472   $intnotes   .= t8('Subject')    . ": " . $::form->{subject}                                                         . "\n\n";
 473   $intnotes   .= t8('Message')    . ": " . $::form->{message};
 474
 475   $self->order->update_attributes(intnotes => $intnotes);
 476
 477   $self->js
 478       ->val('#order_intnotes', $intnotes)
 479       ->run('kivi.Order.close_email_dialog')
 480       ->flash('info', t8('The email has been sent.'))
 481       ->render($self);
 482 }
 483
 484 # open the periodic invoices config dialog
 485 #
 486 # If there are values in the form (i.e. dialog was opened before),
 487 # then use this values. Create new ones, else.
 488 sub action_show_periodic_invoices_config_dialog {
 489   my ($self) = @_;
 490
 491   my $config = make_periodic_invoices_config_from_yaml(delete $::form->{config});
 492   $config  ||= SL::DB::Manager::PeriodicInvoicesConfig->find_by(oe_id => $::form->{id}) if $::form->{id};
 493   $config  ||= SL::DB::PeriodicInvoicesConfig->new(periodicity             => 'm',
 494                                                    order_value_periodicity => 'p', # = same as periodicity
 495                                                    start_date_as_date      => $::form->{transdate_as_date} || $::form->current_date,
 496                                                    extend_automatically_by => 12,
 497                                                    active                  => 1,
 498                                                    email_subject           => GenericTranslations->get(
 499                                                                                 language_id      => $::form->{language_id},
 500                                                                                 translation_type =>"preset_text_periodic_invoices_email_subject"),
 501                                                    email_body              => GenericTranslations->get(
 502                                                                                 language_id      => $::form->{language_id},
 503                                                                                 translation_type =>"preset_text_periodic_invoices_email_body"),
 504   );
 505   $config->periodicity('m')             if none { $_ eq $config->periodicity             }       @SL::DB::PeriodicInvoicesConfig::PERIODICITIES;
 506   $config->order_value_periodicity('p') if none { $_ eq $config->order_value_periodicity } ('p', @SL::DB::PeriodicInvoicesConfig::ORDER_VALUE_PERIODICITIES);
 507
 508   $::form->get_lists(printers => "ALL_PRINTERS",
 509                      charts   => { key       => 'ALL_CHARTS',
 510                                    transdate => 'current_date' });
 511
 512   $::form->{AR} = [ grep { $_->{link} =~ m/(?:^|:)AR(?::|$)/ } @{ $::form->{ALL_CHARTS} } ];
 513
 514   if ($::form->{customer_id}) {
 515     $::form->{ALL_CONTACTS} = SL::DB::Manager::Contact->get_all_sorted(where => [ cp_cv_id => $::form->{customer_id} ]);
 516     $::form->{email_recipient_invoice_address} = SL::DB::Manager::Customer->find_by(id => $::form->{customer_id})->invoice_mail;
 517   }
 518
 519   $self->render('oe/edit_periodic_invoices_config', { layout => 0 },
 520                 popup_dialog             => 1,
 521                 popup_js_close_function  => 'kivi.Order.close_periodic_invoices_config_dialog()',
 522                 popup_js_assign_function => 'kivi.Order.assign_periodic_invoices_config()',
 523                 config                   => $config,
 524                 %$::form);
 525 }
 526
 527 # assign the values of the periodic invoices config dialog
 528 # as yaml in the hidden tag and set the status.
 529 sub action_assign_periodic_invoices_config {
 530   my ($self) = @_;
 531
 532   $::form->isblank('start_date_as_date', $::locale->text('The start date is missing.'));
 533
 534   my $config = { active                     => $::form->{active}       ? 1 : 0,
 535                  terminated                 => $::form->{terminated}   ? 1 : 0,
 536                  direct_debit               => $::form->{direct_debit} ? 1 : 0,
 537                  periodicity                => (any { $_ eq $::form->{periodicity}             }       @SL::DB::PeriodicInvoicesConfig::PERIODICITIES)              ? $::form->{periodicity}             : 'm',
 538                  order_value_periodicity    => (any { $_ eq $::form->{order_value_periodicity} } ('p', @SL::DB::PeriodicInvoicesConfig::ORDER_VALUE_PERIODICITIES)) ? $::form->{order_value_periodicity} : 'p',
 539                  start_date_as_date         => $::form->{start_date_as_date},
 540                  end_date_as_date           => $::form->{end_date_as_date},
 541                  first_billing_date_as_date => $::form->{first_billing_date_as_date},
 542                  print                      => $::form->{print}      ? 1                         : 0,
 543                  printer_id                 => $::form->{print}      ? $::form->{printer_id} * 1 : undef,
 544                  copies                     => $::form->{copies} * 1 ? $::form->{copies}         : 1,
 545                  extend_automatically_by    => $::form->{extend_automatically_by}    * 1 || undef,
 546                  ar_chart_id                => $::form->{ar_chart_id} * 1,
 547                  send_email                 => $::form->{send_email} ? 1 : 0,
 548                  email_recipient_contact_id => $::form->{email_recipient_contact_id} * 1 || undef,
 549                  email_recipient_address    => $::form->{email_recipient_address},
 550                  email_sender               => $::form->{email_sender},
 551                  email_subject              => $::form->{email_subject},
 552                  email_body                 => $::form->{email_body},
 553                };
 554
 555   my $periodic_invoices_config = YAML::Dump($config);
 556
 557   my $status = $self->get_periodic_invoices_status($config);
 558
 559   $self->js
 560     ->remove('#order_periodic_invoices_config')
 561     ->insertAfter(hidden_tag('order.periodic_invoices_config', $periodic_invoices_config), '#periodic_invoices_status')
 562     ->run('kivi.Order.close_periodic_invoices_config_dialog')
 563     ->html('#periodic_invoices_status', $status)
 564     ->flash('info', t8('The periodic invoices config has been assigned.'))
 565     ->render($self);
 566 }
 567
 568 sub action_get_has_active_periodic_invoices {
 569   my ($self) = @_;
 570
 571   my $config = make_periodic_invoices_config_from_yaml(delete $::form->{config});
 572   $config  ||= SL::DB::Manager::PeriodicInvoicesConfig->find_by(oe_id => $::form->{id}) if $::form->{id};
 573
 574   my $has_active_periodic_invoices =
 575        $self->type eq sales_order_type()
 576     && $config
 577     && $config->active
 578     && (!$config->end_date || ($config->end_date > DateTime->today_local))
 579     && $config->get_previous_billed_period_start_date;
 580
 581   $_[0]->render(\ !!$has_active_periodic_invoices, { type => 'text' });
 582 }
 583
 584 # save the order and redirect to the frontend subroutine for a new
 585 # delivery order
 586 sub action_save_and_delivery_order {
 587   my ($self) = @_;
 588
 589   my $errors = $self->save();
 590
 591   if (scalar @{ $errors }) {
 592     $self->js->flash('error', $_) foreach @{ $errors };
 593     return $self->js->render();
 594   }
 595
 596   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
 597            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
 598            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
 599            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
 600            : '';
 601   flash_later('info', $text);
 602
 603   my @redirect_params = (
 604     controller => 'oe.pl',
 605     action     => 'oe_delivery_order_from_order',
 606     id         => $self->order->id,
 607   );
 608
 609   $self->redirect_to(@redirect_params);
 610 }
 611
 612 # save the order and redirect to the frontend subroutine for a new
 613 # invoice
 614 sub action_save_and_invoice {
 615   my ($self) = @_;
 616
 617   my $errors = $self->save();
 618
 619   if (scalar @{ $errors }) {
 620     $self->js->flash('error', $_) foreach @{ $errors };
 621     return $self->js->render();
 622   }
 623
 624   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
 625            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
 626            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
 627            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
 628            : '';
 629   flash_later('info', $text);
 630
 631   my @redirect_params = (
 632     controller => 'oe.pl',
 633     action     => 'oe_invoice_from_order',
 634     id         => $self->order->id,
 635   );
 636
 637   $self->redirect_to(@redirect_params);
 638 }
 639
 640 # workflow from sales quotation to sales order
 641 sub action_sales_order {
 642   $_[0]->workflow_sales_or_purchase_order();
 643 }
 644
 645 # workflow from rfq to purchase order
 646 sub action_purchase_order {
 647   $_[0]->workflow_sales_or_purchase_order();
 648 }
 649
 650 # set form elements in respect to a changed customer or vendor
 651 #
 652 # This action is called on an change of the customer/vendor picker.
 653 sub action_customer_vendor_changed {
 654   my ($self) = @_;
 655
 656   setup_order_from_cv($self->order);
 657   $self->recalc();
 658
 659   my $cv_method = $self->cv;
 660
 661   if ($self->order->$cv_method->contacts && scalar @{ $self->order->$cv_method->contacts } > 0) {
 662     $self->js->show('#cp_row');
 663   } else {
 664     $self->js->hide('#cp_row');
 665   }
 666
 667   if ($self->order->$cv_method->shipto && scalar @{ $self->order->$cv_method->shipto } > 0) {
 668     $self->js->show('#shipto_row');
 669   } else {
 670     $self->js->hide('#shipto_row');
 671   }
 672
 673   $self->js->val( '#order_salesman_id',      $self->order->salesman_id)        if $self->order->is_sales;
 674
 675   $self->js
 676     ->replaceWith('#order_cp_id',            $self->build_contact_select)
 677     ->replaceWith('#order_shipto_id',        $self->build_shipto_select)
 678     ->replaceWith('#business_info_row',      $self->build_business_info_row)
 679     ->val(        '#order_taxzone_id',       $self->order->taxzone_id)
 680     ->val(        '#order_taxincluded',      $self->order->taxincluded)
 681     ->val(        '#order_payment_id',       $self->order->payment_id)
 682     ->val(        '#order_delivery_term_id', $self->order->delivery_term_id)
 683     ->val(        '#order_intnotes',         $self->order->intnotes)
 684     ->val(        '#language_id',            $self->order->$cv_method->language_id)
 685     ->focus(      '#order_' . $self->cv . '_id');
 686
 687   $self->js_redisplay_amounts_and_taxes;
 688   $self->js->render();
 689 }
 690
 691 # open the dialog for customer/vendor details
 692 sub action_show_customer_vendor_details_dialog {
 693   my ($self) = @_;
 694
 695   my $is_customer = 'customer' eq $::form->{vc};
 696   my $cv;
 697   if ($is_customer) {
 698     $cv = SL::DB::Customer->new(id => $::form->{vc_id})->load;
 699   } else {
 700     $cv = SL::DB::Vendor->new(id => $::form->{vc_id})->load;
 701   }
 702
 703   my %details = map { $_ => $cv->$_ } @{$cv->meta->columns};
 704   $details{discount_as_percent} = $cv->discount_as_percent;
 705   $details{creditlimt}          = $cv->creditlimit_as_number;
 706   $details{business}            = $cv->business->description      if $cv->business;
 707   $details{language}            = $cv->language_obj->description  if $cv->language_obj;
 708   $details{delivery_terms}      = $cv->delivery_term->description if $cv->delivery_term;
 709   $details{payment_terms}       = $cv->payment->description       if $cv->payment;
 710   $details{pricegroup}          = $cv->pricegroup->pricegroup     if $is_customer && $cv->pricegroup;
 711
 712   foreach my $entry (@{ $cv->shipto }) {
 713     push @{ $details{SHIPTO} },   { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 714   }
 715   foreach my $entry (@{ $cv->contacts }) {
 716     push @{ $details{CONTACTS} }, { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 717   }
 718
 719   $_[0]->render('common/show_vc_details', { layout => 0 },
 720                 is_customer => $is_customer,
 721                 %details);
 722
 723 }
 724
 725 # called if a unit in an existing item row is changed
 726 sub action_unit_changed {
 727   my ($self) = @_;
 728
 729   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 730   my $item = $self->order->items_sorted->[$idx];
 731
 732   my $old_unit_obj = SL::DB::Unit->new(name => $::form->{old_unit})->load;
 733   $item->sellprice($item->unit_obj->convert_to($item->sellprice, $old_unit_obj));
 734
 735   $self->recalc();
 736
 737   $self->js
 738     ->run('kivi.Order.update_sellprice', $::form->{item_id}, $item->sellprice_as_number);
 739   $self->js_redisplay_line_values;
 740   $self->js_redisplay_amounts_and_taxes;
 741   $self->js->render();
 742 }
 743
 744 # add an item row for a new item entered in the input row
 745 sub action_add_item {
 746   my ($self) = @_;
 747
 748   my $form_attr = $::form->{add_item};
 749
 750   return unless $form_attr->{parts_id};
 751
 752   my $item = new_item($self->order, $form_attr);
 753
 754   $self->order->add_items($item);
 755
 756   $self->recalc();
 757
 758   my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 759   my $row_as_html = $self->p->render('order/tabs/_row',
 760                                      ITEM              => $item,
 761                                      ID                => $item_id,
 762                                      TYPE              => $self->type,
 763                                      ALL_PRICE_FACTORS => $self->all_price_factors
 764   );
 765
 766   $self->js
 767     ->append('#row_table_id', $row_as_html);
 768
 769   if ( $item->part->is_assortment ) {
 770     $form_attr->{qty_as_number} = 1 unless $form_attr->{qty_as_number};
 771     foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 772       my $attr = { parts_id => $assortment_item->parts_id,
 773                    qty      => $assortment_item->qty * $::form->parse_amount(\%::myconfig, $form_attr->{qty_as_number}), # TODO $form_attr->{unit}
 774                    unit     => $assortment_item->unit,
 775                    description => $assortment_item->part->description,
 776                  };
 777       my $item = new_item($self->order, $attr);
 778
 779       # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 780       $item->discount(1) unless $assortment_item->charge;
 781
 782       $self->order->add_items( $item );
 783       $self->recalc();
 784       my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 785       my $row_as_html = $self->p->render('order/tabs/_row',
 786                                          ITEM              => $item,
 787                                          ID                => $item_id,
 788                                          TYPE              => $self->type,
 789                                          ALL_PRICE_FACTORS => $self->all_price_factors
 790       );
 791       $self->js
 792         ->append('#row_table_id', $row_as_html);
 793     };
 794   };
 795
 796   $self->js
 797     ->val('.add_item_input', '')
 798     ->run('kivi.Order.init_row_handlers')
 799     ->run('kivi.Order.row_table_scroll_down')
 800     ->run('kivi.Order.renumber_positions')
 801     ->focus('#add_item_parts_id_name');
 802
 803   $self->js_redisplay_amounts_and_taxes;
 804   $self->js->render();
 805 }
 806
 807 # open the dialog for entering multiple items at once
 808 sub action_show_multi_items_dialog {
 809   $_[0]->render('order/tabs/_multi_items_dialog', { layout => 0 },
 810                 all_partsgroups => SL::DB::Manager::PartsGroup->get_all);
 811 }
 812
 813 # update the filter results in the multi item dialog
 814 sub action_multi_items_update_result {
 815   my $max_count = 100;
 816
 817   $::form->{multi_items}->{filter}->{obsolete} = 0;
 818
 819   my $count = $_[0]->multi_items_models->count;
 820
 821   if ($count == 0) {
 822     my $text = SL::Presenter::EscapedText->new(text => $::locale->text('No results.'));
 823     $_[0]->render($text, { layout => 0 });
 824   } elsif ($count > $max_count) {
 825     my $text = SL::Presenter::EscapedText->new(text => $::locale->text('Too many results (#1 from #2).', $count, $max_count));
 826     $_[0]->render($text, { layout => 0 });
 827   } else {
 828     my $multi_items = $_[0]->multi_items_models->get;
 829     $_[0]->render('order/tabs/_multi_items_result', { layout => 0 },
 830                   multi_items => $multi_items);
 831   }
 832 }
 833
 834 # add item rows for multiple items at once
 835 sub action_add_multi_items {
 836   my ($self) = @_;
 837
 838   my @form_attr = grep { $_->{qty_as_number} } @{ $::form->{add_multi_items} };
 839   return $self->js->render() unless scalar @form_attr;
 840
 841   my @items;
 842   foreach my $attr (@form_attr) {
 843     my $item = new_item($self->order, $attr);
 844     push @items, $item;
 845     if ( $item->part->is_assortment ) {
 846       foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 847         my $attr = { parts_id => $assortment_item->parts_id,
 848                      qty      => $assortment_item->qty * $item->qty, # TODO $form_attr->{unit}
 849                      unit     => $assortment_item->unit,
 850                      description => $assortment_item->part->description,
 851                    };
 852         my $item = new_item($self->order, $attr);
 853
 854         # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 855         $item->discount(1) unless $assortment_item->charge;
 856         push @items, $item;
 857       }
 858     }
 859   }
 860   $self->order->add_items(@items);
 861
 862   $self->recalc();
 863
 864   foreach my $item (@items) {
 865     my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 866     my $row_as_html = $self->p->render('order/tabs/_row',
 867                                        ITEM              => $item,
 868                                        ID                => $item_id,
 869                                        TYPE              => $self->type,
 870                                        ALL_PRICE_FACTORS => $self->all_price_factors
 871     );
 872
 873     $self->js->append('#row_table_id', $row_as_html);
 874   }
 875
 876   $self->js
 877     ->run('kivi.Order.close_multi_items_dialog')
 878     ->run('kivi.Order.init_row_handlers')
 879     ->run('kivi.Order.row_table_scroll_down')
 880     ->run('kivi.Order.renumber_positions')
 881     ->focus('#add_item_parts_id_name');
 882
 883   $self->js_redisplay_amounts_and_taxes;
 884   $self->js->render();
 885 }
 886
 887 # recalculate all linetotals, amounts and taxes and redisplay them
 888 sub action_recalc_amounts_and_taxes {
 889   my ($self) = @_;
 890
 891   $self->recalc();
 892
 893   $self->js_redisplay_line_values;
 894   $self->js_redisplay_amounts_and_taxes;
 895   $self->js->render();
 896 }
 897
 898 # redisplay item rows if they are sorted by an attribute
 899 sub action_reorder_items {
 900   my ($self) = @_;
 901
 902   my %sort_keys = (
 903     partnumber  => sub { $_[0]->part->partnumber },
 904     description => sub { $_[0]->description },
 905     qty         => sub { $_[0]->qty },
 906     sellprice   => sub { $_[0]->sellprice },
 907     discount    => sub { $_[0]->discount },
 908   );
 909
 910   my $method = $sort_keys{$::form->{order_by}};
 911   my @to_sort = map { { old_pos => $_->position, order_by => $method->($_) } } @{ $self->order->items_sorted };
 912   if ($::form->{sort_dir}) {
 913     @to_sort = sort { Sort::Naturally::ncmp($a->{order_by}, $b->{order_by} ) } @to_sort;
 914   } else {
 915     @to_sort = sort { Sort::Naturally::ncmp($b->{order_by}, $a->{order_by} ) } @to_sort;
 916   }
 917   $self->js
 918     ->run('kivi.Order.redisplay_items', \@to_sort)
 919     ->render;
 920 }
 921
 922 # show the popup to choose a price/discount source
 923 sub action_price_popup {
 924   my ($self) = @_;
 925
 926   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 927   my $item = $self->order->items_sorted->[$idx];
 928
 929   $self->render_price_dialog($item);
 930 }
 931
 932 # get the longdescription for an item if the dialog to enter/change the
 933 # longdescription was opened and the longdescription is empty
 934 #
 935 # If this item is new, get the longdescription from Part.
 936 # Otherwise get it from OrderItem.
 937 sub action_get_item_longdescription {
 938   my $longdescription;
 939
 940   if ($::form->{item_id}) {
 941     $longdescription = SL::DB::OrderItem->new(id => $::form->{item_id})->load->longdescription;
 942   } elsif ($::form->{parts_id}) {
 943     $longdescription = SL::DB::Part->new(id => $::form->{parts_id})->load->notes;
 944   }
 945   $_[0]->render(\ $longdescription, { type => 'text' });
 946 }
 947
 948 # load the second row for one or more items
 949 #
 950 # This action gets the html code for all items second rows by rendering a template for
 951 # the second row and sets the html code via client js.
 952 sub action_load_second_rows {
 953   my ($self) = @_;
 954
 955   $self->recalc() if $self->order->is_sales; # for margin calculation
 956
 957   foreach my $item_id (@{ $::form->{item_ids} }) {
 958     my $idx  = first_index { $_ eq $item_id } @{ $::form->{orderitem_ids} };
 959     my $item = $self->order->items_sorted->[$idx];
 960
 961     $self->js_load_second_row($item, $item_id, 0);
 962   }
 963
 964   $self->js->run('kivi.Order.init_row_handlers') if $self->order->is_sales; # for lastcosts change-callback
 965
 966   $self->js->render();
 967 }
 968
 969 sub js_load_second_row {
 970   my ($self, $item, $item_id, $do_parse) = @_;
 971
 972   if ($do_parse) {
 973     # Parse values from form (they are formated while rendering (template)).
 974     # Workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
 975     # This parsing is not necessary at all, if we assure that the second row/cvars are only loaded once.
 976     foreach my $var (@{ $item->cvars_by_config }) {
 977       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
 978     }
 979     $item->parse_custom_variable_values;
 980   }
 981
 982   my $row_as_html = $self->p->render('order/tabs/_second_row', ITEM => $item, TYPE => $self->type);
 983
 984   $self->js
 985     ->html('#second_row_' . $item_id, $row_as_html)
 986     ->data('#second_row_' . $item_id, 'loaded', 1);
 987 }
 988
 989 sub js_redisplay_line_values {
 990   my ($self) = @_;
 991
 992   my $is_sales = $self->order->is_sales;
 993
 994   # sales orders with margins
 995   my @data;
 996   if ($is_sales) {
 997     @data = map {
 998       [
 999        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
1000        $::form->format_amount(\%::myconfig, $_->{marge_total},   2, 0),
1001        $::form->format_amount(\%::myconfig, $_->{marge_percent}, 2, 0),
1002       ]} @{ $self->order->items_sorted };
1003   } else {
1004     @data = map {
1005       [
1006        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
1007       ]} @{ $self->order->items_sorted };
1008   }
1009
1010   $self->js
1011     ->run('kivi.Order.redisplay_line_values', $is_sales, \@data);
1012 }
1013
1014 sub js_redisplay_amounts_and_taxes {
1015   my ($self) = @_;
1016
1017   if (scalar @{ $self->{taxes} }) {
1018     $self->js->show('#taxincluded_row_id');
1019   } else {
1020     $self->js->hide('#taxincluded_row_id');
1021   }
1022
1023   if ($self->order->taxincluded) {
1024     $self->js->hide('#subtotal_row_id');
1025   } else {
1026     $self->js->show('#subtotal_row_id');
1027   }
1028
1029   if ($self->order->is_sales) {
1030     my $is_neg = $self->order->marge_total < 0;
1031     $self->js
1032       ->html('#marge_total_id',   $::form->format_amount(\%::myconfig, $self->order->marge_total,   2))
1033       ->html('#marge_percent_id', $::form->format_amount(\%::myconfig, $self->order->marge_percent, 2))
1034       ->action_if( $is_neg, 'addClass',    '#marge_total_id',        'plus0')
1035       ->action_if( $is_neg, 'addClass',    '#marge_percent_id',      'plus0')
1036       ->action_if( $is_neg, 'addClass',    '#marge_percent_sign_id', 'plus0')
1037       ->action_if(!$is_neg, 'removeClass', '#marge_total_id',        'plus0')
1038       ->action_if(!$is_neg, 'removeClass', '#marge_percent_id',      'plus0')
1039       ->action_if(!$is_neg, 'removeClass', '#marge_percent_sign_id', 'plus0');
1040   }
1041
1042   $self->js
1043     ->html('#netamount_id', $::form->format_amount(\%::myconfig, $self->order->netamount, -2))
1044     ->html('#amount_id',    $::form->format_amount(\%::myconfig, $self->order->amount,    -2))
1045     ->remove('.tax_row')
1046     ->insertBefore($self->build_tax_rows, '#amount_row_id');
1047 }
1048
1049 #
1050 # helpers
1051 #
1052
1053 sub init_valid_types {
1054   [ sales_order_type(), purchase_order_type(), sales_quotation_type(), request_quotation_type() ];
1055 }
1056
1057 sub init_type {
1058   my ($self) = @_;
1059
1060   if (none { $::form->{type} eq $_ } @{$self->valid_types}) {
1061     die "Not a valid type for order";
1062   }
1063
1064   $self->type($::form->{type});
1065 }
1066
1067 sub init_cv {
1068   my ($self) = @_;
1069
1070   my $cv = (any { $self->type eq $_ } (sales_order_type(),    sales_quotation_type()))   ? 'customer'
1071          : (any { $self->type eq $_ } (purchase_order_type(), request_quotation_type())) ? 'vendor'
1072          : die "Not a valid type for order";
1073
1074   return $cv;
1075 }
1076
1077 sub init_p {
1078   SL::Presenter->get;
1079 }
1080
1081 sub init_order {
1082   $_[0]->make_order;
1083 }
1084
1085 # model used to filter/display the parts in the multi-items dialog
1086 sub init_multi_items_models {
1087   SL::Controller::Helper::GetModels->new(
1088     controller     => $_[0],
1089     model          => 'Part',
1090     with_objects   => [ qw(unit_obj) ],
1091     disable_plugin => 'paginated',
1092     source         => $::form->{multi_items},
1093     sorted         => {
1094       _default    => {
1095         by  => 'partnumber',
1096         dir => 1,
1097       },
1098       partnumber  => t8('Partnumber'),
1099       description => t8('Description')}
1100   );
1101 }
1102
1103 sub init_all_price_factors {
1104   SL::DB::Manager::PriceFactor->get_all;
1105 }
1106
1107 sub check_auth {
1108   my ($self) = @_;
1109
1110   my $right_for = { map { $_ => $_.'_edit' } @{$self->valid_types} };
1111
1112   my $right   = $right_for->{ $self->type };
1113   $right    ||= 'DOES_NOT_EXIST';
1114
1115   $::auth->assert($right);
1116 }
1117
1118 # build the selection box for contacts
1119 #
1120 # Needed, if customer/vendor changed.
1121 sub build_contact_select {
1122   my ($self) = @_;
1123
1124   select_tag('order.cp_id', [ $self->order->{$self->cv}->contacts ],
1125     value_key  => 'cp_id',
1126     title_key  => 'full_name_dep',
1127     default    => $self->order->cp_id,
1128     with_empty => 1,
1129     style      => 'width: 300px',
1130   );
1131 }
1132
1133 # build the selection box for shiptos
1134 #
1135 # Needed, if customer/vendor changed.
1136 sub build_shipto_select {
1137   my ($self) = @_;
1138
1139   select_tag('order.shipto_id', [ $self->order->{$self->cv}->shipto ],
1140     value_key  => 'shipto_id',
1141     title_key  => 'displayable_id',
1142     default    => $self->order->shipto_id,
1143     with_empty => 1,
1144     style      => 'width: 300px',
1145   );
1146 }
1147
1148 # render the info line for business
1149 #
1150 # Needed, if customer/vendor changed.
1151 sub build_business_info_row
1152 {
1153   $_[0]->p->render('order/tabs/_business_info_row', SELF => $_[0]);
1154 }
1155
1156 # build the rows for displaying taxes
1157 #
1158 # Called if amounts where recalculated and redisplayed.
1159 sub build_tax_rows {
1160   my ($self) = @_;
1161
1162   my $rows_as_html;
1163   foreach my $tax (sort { $a->{tax}->rate cmp $b->{tax}->rate } @{ $self->{taxes} }) {
1164     $rows_as_html .= $self->p->render('order/tabs/_tax_row', TAX => $tax, TAXINCLUDED => $self->order->taxincluded);
1165   }
1166   return $rows_as_html;
1167 }
1168
1169
1170 sub render_price_dialog {
1171   my ($self, $record_item) = @_;
1172
1173   my $price_source = SL::PriceSource->new(record_item => $record_item, record => $self->order);
1174
1175   $self->js
1176     ->run(
1177       'kivi.io.price_chooser_dialog',
1178       t8('Available Prices'),
1179       $self->render('order/tabs/_price_sources_dialog', { output => 0 }, price_source => $price_source)
1180     )
1181     ->reinit_widgets;
1182
1183 #   if (@errors) {
1184 #     $self->js->text('#dialog_flash_error_content', join ' ', @errors);
1185 #     $self->js->show('#dialog_flash_error');
1186 #   }
1187
1188   $self->js->render;
1189 }
1190
1191 sub load_order {
1192   my ($self) = @_;
1193
1194   return if !$::form->{id};
1195
1196   $self->order(SL::DB::Order->new(id => $::form->{id})->load);
1197 }
1198
1199 # load or create a new order object
1200 #
1201 # And assign changes from the form to this object.
1202 # If the order is loaded from db, check if items are deleted in the form,
1203 # remove them form the object and collect them for removing from db on saving.
1204 # Then create/update items from form (via make_item) and add them.
1205 sub make_order {
1206   my ($self) = @_;
1207
1208   # add_items adds items to an order with no items for saving, but they cannot
1209   # be retrieved via items until the order is saved. Adding empty items to new
1210   # order here solves this problem.
1211   my $order;
1212   $order   = SL::DB::Order->new(id => $::form->{id})->load(with => [ 'orderitems', 'orderitems.part' ]) if $::form->{id};
1213   $order ||= SL::DB::Order->new(orderitems => [],
1214                                 quotation  => (any { $self->type eq $_ } (sales_quotation_type(), request_quotation_type())));
1215
1216   my $cv_id_method = $self->cv . '_id';
1217   if (!$::form->{id} && $::form->{$cv_id_method}) {
1218     $order->$cv_id_method($::form->{$cv_id_method});
1219     setup_order_from_cv($order);
1220   }
1221
1222   my $form_orderitems               = delete $::form->{order}->{orderitems};
1223   my $form_periodic_invoices_config = delete $::form->{order}->{periodic_invoices_config};
1224
1225   $order->assign_attributes(%{$::form->{order}});
1226
1227   if (my $periodic_invoices_config_attrs = $form_periodic_invoices_config ? YAML::Load($form_periodic_invoices_config) : undef) {
1228     my $periodic_invoices_config = $order->periodic_invoices_config || $order->periodic_invoices_config(SL::DB::PeriodicInvoicesConfig->new);
1229     $periodic_invoices_config->assign_attributes(%$periodic_invoices_config_attrs);
1230   }
1231
1232   # remove deleted items
1233   $self->item_ids_to_delete([]);
1234   foreach my $idx (reverse 0..$#{$order->orderitems}) {
1235     my $item = $order->orderitems->[$idx];
1236     if (none { $item->id == $_->{id} } @{$form_orderitems}) {
1237       splice @{$order->orderitems}, $idx, 1;
1238       push @{$self->item_ids_to_delete}, $item->id;
1239     }
1240   }
1241
1242   my @items;
1243   my $pos = 1;
1244   foreach my $form_attr (@{$form_orderitems}) {
1245     my $item = make_item($order, $form_attr);
1246     $item->position($pos);
1247     push @items, $item;
1248     $pos++;
1249   }
1250   $order->add_items(grep {!$_->id} @items);
1251
1252   return $order;
1253 }
1254
1255 # create or update items from form
1256 #
1257 # Make item objects from form values. For items already existing read from db.
1258 # Create a new item else. And assign attributes.
1259 sub make_item {
1260   my ($record, $attr) = @_;
1261
1262   my $item;
1263   $item = first { $_->id == $attr->{id} } @{$record->items} if $attr->{id};
1264
1265   my $is_new = !$item;
1266
1267   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1268   # they cannot be retrieved via custom_variables until the order/orderitem is
1269   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1270   $item ||= SL::DB::OrderItem->new(custom_variables => []);
1271
1272   $item->assign_attributes(%$attr);
1273   $item->longdescription($item->part->notes)                     if $is_new && !defined $attr->{longdescription};
1274   $item->project_id($record->globalproject_id)                   if $is_new && !defined $attr->{project_id};
1275   $item->lastcost($record->is_sales ? $item->part->lastcost : 0) if $is_new && !defined $attr->{lastcost_as_number};
1276
1277   return $item;
1278 }
1279
1280 # create a new item
1281 #
1282 # This is used to add one item
1283 sub new_item {
1284   my ($record, $attr) = @_;
1285
1286   my $item = SL::DB::OrderItem->new;
1287
1288   # Remove attributes where the user left or set the inputs empty.
1289   # So these attributes will be undefined and we can distinguish them
1290   # from zero later on.
1291   for (qw(qty_as_number sellprice_as_number discount_as_percent)) {
1292     delete $attr->{$_} if $attr->{$_} eq '';
1293   }
1294
1295   $item->assign_attributes(%$attr);
1296
1297   my $part         = SL::DB::Part->new(id => $attr->{parts_id})->load;
1298   my $price_source = SL::PriceSource->new(record_item => $item, record => $record);
1299
1300   $item->unit($part->unit) if !$item->unit;
1301
1302   my $price_src;
1303   if ( $part->is_assortment ) {
1304     # add assortment items with price 0, as the components carry the price
1305     $price_src = $price_source->price_from_source("");
1306     $price_src->price(0);
1307   } elsif (defined $item->sellprice) {
1308     $price_src = $price_source->price_from_source("");
1309     $price_src->price($item->sellprice);
1310   } else {
1311     $price_src = $price_source->best_price
1312            ? $price_source->best_price
1313            : $price_source->price_from_source("");
1314     $price_src->price(0) if !$price_source->best_price;
1315   }
1316
1317   my $discount_src;
1318   if (defined $item->discount) {
1319     $discount_src = $price_source->discount_from_source("");
1320     $discount_src->discount($item->discount);
1321   } else {
1322     $discount_src = $price_source->best_discount
1323                   ? $price_source->best_discount
1324                   : $price_source->discount_from_source("");
1325     $discount_src->discount(0) if !$price_source->best_discount;
1326   }
1327
1328   my %new_attr;
1329   $new_attr{part}                   = $part;
1330   $new_attr{description}            = $part->description     if ! $item->description;
1331   $new_attr{qty}                    = 1.0                    if ! $item->qty;
1332   $new_attr{price_factor_id}        = $part->price_factor_id if ! $item->price_factor_id;
1333   $new_attr{sellprice}              = $price_src->price;
1334   $new_attr{discount}               = $discount_src->discount;
1335   $new_attr{active_price_source}    = $price_src;
1336   $new_attr{active_discount_source} = $discount_src;
1337   $new_attr{longdescription}        = $part->notes           if ! defined $attr->{longdescription};
1338   $new_attr{project_id}             = $record->globalproject_id;
1339   $new_attr{lastcost}               = $record->is_sales ? $part->lastcost : 0;
1340
1341   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1342   # they cannot be retrieved via custom_variables until the order/orderitem is
1343   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1344   $new_attr{custom_variables} = [];
1345
1346   $item->assign_attributes(%new_attr);
1347
1348   return $item;
1349 }
1350
1351 sub setup_order_from_cv {
1352   my ($order) = @_;
1353
1354   $order->$_($order->customervendor->$_) for (qw(taxzone_id payment_id delivery_term_id));
1355
1356   $order->intnotes($order->customervendor->notes);
1357
1358   if ($order->is_sales) {
1359     $order->salesman_id($order->customer->salesman_id || SL::DB::Manager::Employee->current->id);
1360     $order->taxincluded(defined($order->customer->taxincluded_checked)
1361                         ? $order->customer->taxincluded_checked
1362                         : $::myconfig{taxincluded_checked});
1363   }
1364
1365 }
1366
1367 # recalculate prices and taxes
1368 #
1369 # Using the PriceTaxCalculator. Store linetotals in the item objects.
1370 sub recalc {
1371   my ($self) = @_;
1372
1373   # bb: todo: currency later
1374   $self->order->currency_id($::instance_conf->get_currency_id());
1375
1376   my %pat = $self->order->calculate_prices_and_taxes();
1377   $self->{taxes} = [];
1378   foreach my $tax_chart_id (keys %{ $pat{taxes} }) {
1379     my $tax = SL::DB::Manager::Tax->find_by(chart_id => $tax_chart_id);
1380
1381     my @amount_keys = grep { $pat{amounts}->{$_}->{tax_id} == $tax->id } keys %{ $pat{amounts} };
1382     push(@{ $self->{taxes} }, { amount    => $pat{taxes}->{$tax_chart_id},
1383                                 netamount => $pat{amounts}->{$amount_keys[0]}->{amount},
1384                                 tax       => $tax });
1385   }
1386
1387   pairwise { $a->{linetotal} = $b->{linetotal} } @{$self->order->items_sorted}, @{$pat{items}};
1388 }
1389
1390 # get data for saving, printing, ..., that is not changed in the form
1391 #
1392 # Only cvars for now.
1393 sub get_unalterable_data {
1394   my ($self) = @_;
1395
1396   foreach my $item (@{ $self->order->items }) {
1397     # autovivify all cvars that are not in the form (cvars_by_config can do it).
1398     # workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
1399     foreach my $var (@{ $item->cvars_by_config }) {
1400       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
1401     }
1402     $item->parse_custom_variable_values;
1403   }
1404 }
1405
1406 # delete the order
1407 #
1408 # And remove related files in the spool directory
1409 sub delete {
1410   my ($self) = @_;
1411
1412   my $errors = [];
1413   my $db     = $self->order->db;
1414
1415   $db->with_transaction(
1416     sub {
1417       my @spoolfiles = grep { $_ } map { $_->spoolfile } @{ SL::DB::Manager::Status->get_all(where => [ trans_id => $self->order->id ]) };
1418       $self->order->delete;
1419       my $spool = $::lx_office_conf{paths}->{spool};
1420       unlink map { "$spool/$_" } @spoolfiles if $spool;
1421
1422       1;
1423   }) || push(@{$errors}, $db->error);
1424
1425   return $errors;
1426 }
1427
1428 # save the order
1429 #
1430 # And delete items that are deleted in the form.
1431 sub save {
1432   my ($self) = @_;
1433
1434   my $errors = [];
1435   my $db     = $self->order->db;
1436
1437   $db->with_transaction(sub {
1438     SL::DB::OrderItem->new(id => $_)->delete for @{$self->item_ids_to_delete || []};
1439     $self->order->save(cascade => 1);
1440
1441     # link records
1442     if ($::form->{converted_from_oe_id}) {
1443       my @converted_from_oe_ids = split ' ', $::form->{converted_from_oe_id};
1444       foreach my $converted_from_oe_id (@converted_from_oe_ids) {
1445         my $src = SL::DB::Order->new(id => $converted_from_oe_id)->load;
1446         $src->update_attributes(closed => 1) if $src->type =~ /_quotation$/;
1447         $src->link_to_record($self->order);
1448       }
1449       if (scalar @{ $::form->{converted_from_orderitems_ids} || [] }) {
1450         my $idx = 0;
1451         foreach (@{ $self->order->items_sorted }) {
1452           my $from_id = $::form->{converted_from_orderitems_ids}->[$idx];
1453           next if !$from_id;
1454           SL::DB::RecordLink->new(from_table => 'orderitems',
1455                                   from_id    => $from_id,
1456                                   to_table   => 'orderitems',
1457                                   to_id      => $_->id
1458           )->save;
1459           $idx++;
1460         }
1461       }
1462     }
1463     1;
1464   }) || push(@{$errors}, $db->error);
1465
1466   return $errors;
1467 }
1468
1469 sub workflow_sales_or_purchase_order {
1470   my ($self) = @_;
1471   # always save
1472   my $errors = $self->save();
1473
1474   if (scalar @{ $errors }) {
1475     $self->js->flash('error', $_) foreach @{ $errors };
1476     return $self->js->render();
1477   }
1478
1479
1480   my $destination_type = $::form->{type} eq sales_quotation_type()   ? sales_order_type()
1481                        : $::form->{type} eq request_quotation_type() ? purchase_order_type()
1482                        : $::form->{type} eq purchase_order_type()    ? sales_order_type()
1483                        : $::form->{type} eq sales_order_type()       ? purchase_order_type()
1484                        : '';
1485
1486   $self->order(SL::DB::Order->new_from($self->order, destination_type => $destination_type));
1487   $self->{converted_from_oe_id} = delete $::form->{id};
1488
1489   # set item ids to new fake id, to identify them as new items
1490   foreach my $item (@{$self->order->items_sorted}) {
1491     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1492   }
1493
1494   # change form type
1495   $::form->{type} = $destination_type;
1496   $self->type($self->init_type);
1497   $self->cv  ($self->init_cv);
1498   $self->check_auth;
1499
1500   $self->recalc();
1501   $self->get_unalterable_data();
1502   $self->pre_render();
1503
1504   # trigger rendering values for second row/longdescription as hidden,
1505   # because they are loaded only on demand. So we need to keep the values
1506   # from the source.
1507   $_->{render_second_row}      = 1 for @{ $self->order->items_sorted };
1508   $_->{render_longdescription} = 1 for @{ $self->order->items_sorted };
1509
1510   $self->render(
1511     'order/form',
1512     title => $self->get_title_for('edit'),
1513     %{$self->{template_args}}
1514   );
1515 }
1516
1517
1518 sub pre_render {
1519   my ($self) = @_;
1520
1521   $self->{all_taxzones}             = SL::DB::Manager::TaxZone->get_all_sorted();
1522   $self->{all_departments}          = SL::DB::Manager::Department->get_all_sorted();
1523   $self->{all_employees}            = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->employee_id,
1524                                                                                             deleted => 0 ] ],
1525                                                                          sort_by => 'name');
1526   $self->{all_salesmen}             = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->salesman_id,
1527                                                                                             deleted => 0 ] ],
1528                                                                          sort_by => 'name');
1529   $self->{all_payment_terms}        = SL::DB::Manager::PaymentTerm->get_all_sorted(where => [ or => [ id => $self->order->payment_id,
1530                                                                                                       obsolete => 0 ] ]);
1531   $self->{all_delivery_terms}       = SL::DB::Manager::DeliveryTerm->get_all_sorted();
1532   $self->{current_employee_id}      = SL::DB::Manager::Employee->current->id;
1533   $self->{periodic_invoices_status} = $self->get_periodic_invoices_status($self->order->periodic_invoices_config);
1534   $self->{order_probabilities}      = [ map { { title => ($_ * 10) . '%', id => $_ * 10 } } (0..10) ];
1535
1536   my $print_form = Form->new('');
1537   $print_form->{type}      = $self->type;
1538   $print_form->{printers}  = SL::DB::Manager::Printer->get_all_sorted;
1539   $print_form->{languages} = SL::DB::Manager::Language->get_all_sorted;
1540   $self->{print_options}   = SL::Helper::PrintOptions->get_print_options(
1541     form => $print_form,
1542     options => {dialog_name_prefix => 'print_options.',
1543                 show_headers       => 1,
1544                 no_queue           => 1,
1545                 no_postscript      => 1,
1546                 no_opendocument    => 0,
1547                 no_html            => 1},
1548   );
1549
1550   foreach my $item (@{$self->order->orderitems}) {
1551     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
1552     $item->active_price_source(   $price_source->price_from_source(   $item->active_price_source   ));
1553     $item->active_discount_source($price_source->discount_from_source($item->active_discount_source));
1554   }
1555
1556   if (any { $self->type eq $_ } (sales_order_type(), purchase_order_type())) {
1557     # calculate shipped qtys here to prevent calling calculate for every item via the items method
1558     SL::Helper::ShippedQty->new->calculate($self->order)->write_to_objects;
1559   }
1560
1561   if ($self->order->number && $::instance_conf->get_webdav) {
1562     my $webdav = SL::Webdav->new(
1563       type     => $self->type,
1564       number   => $self->order->number,
1565     );
1566     my @all_objects = $webdav->get_all_objects;
1567     @{ $self->{template_args}->{WEBDAV} } = map { { name => $_->filename,
1568                                                     type => t8('File'),
1569                                                     link => File::Spec->catfile($_->full_filedescriptor),
1570                                                 } } @all_objects;
1571   }
1572
1573   $::request->{layout}->use_javascript("${_}.js") for qw(kivi.SalesPurchase kivi.Order kivi.File ckeditor/ckeditor ckeditor/adapters/jquery edit_periodic_invoices_config calculate_qty);
1574   $self->setup_edit_action_bar;
1575 }
1576
1577 sub setup_edit_action_bar {
1578   my ($self, %params) = @_;
1579
1580   my $deletion_allowed = (any { $self->type eq $_ } (sales_quotation_type(), request_quotation_type()))
1581                       || (($self->type eq sales_order_type())    && $::instance_conf->get_sales_order_show_delete)
1582                       || (($self->type eq purchase_order_type()) && $::instance_conf->get_purchase_order_show_delete);
1583
1584   for my $bar ($::request->layout->get('actionbar')) {
1585     $bar->add(
1586       combobox => [
1587         action => [
1588           t8('Save'),
1589           call      => [ 'kivi.Order.save', 'save', $::instance_conf->get_order_warn_duplicate_parts,
1590                                                     $::instance_conf->get_order_warn_no_deliverydate,
1591                                                                                                       ],
1592           checks    => [ 'kivi.Order.check_save_active_periodic_invoices' ],
1593         ],
1594         action => [
1595           t8('Save as new'),
1596           call      => [ 'kivi.Order.save', 'save_as_new', $::instance_conf->get_order_warn_duplicate_parts ],
1597           checks    => [ 'kivi.Order.check_save_active_periodic_invoices' ],
1598           disabled  => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1599         ],
1600       ], # end of combobox "Save"
1601
1602       combobox => [
1603         action => [
1604           t8('Workflow'),
1605         ],
1606         action => [
1607           t8('Save and Sales Order'),
1608           submit   => [ '#order_form', { action => "Order/sales_order" } ],
1609           only_if  => (any { $self->type eq $_ } (sales_quotation_type(), purchase_order_type())),
1610           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1611         ],
1612         action => [
1613           t8('Save and Purchase Order'),
1614           submit   => [ '#order_form', { action => "Order/purchase_order" } ],
1615           only_if  => (any { $self->type eq $_ } (sales_order_type(), request_quotation_type())),
1616           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1617         ],
1618         action => [
1619           t8('Save and Delivery Order'),
1620           call      => [ 'kivi.Order.save', 'save_and_delivery_order', $::instance_conf->get_order_warn_duplicate_parts,
1621                                                                        $::instance_conf->get_order_warn_no_deliverydate,
1622                                                                                                                         ],
1623           checks    => [ 'kivi.Order.check_save_active_periodic_invoices' ],
1624           only_if   => (any { $self->type eq $_ } (sales_order_type(), purchase_order_type()))
1625         ],
1626         action => [
1627           t8('Save and Invoice'),
1628           call      => [ 'kivi.Order.save', 'save_and_invoice', $::instance_conf->get_order_warn_duplicate_parts ],
1629           checks    => [ 'kivi.Order.check_save_active_periodic_invoices' ],
1630         ],
1631       ], # end of combobox "Workflow"
1632
1633       combobox => [
1634         action => [
1635           t8('Export'),
1636         ],
1637         action => [
1638           t8('Save and print'),
1639           call => [ 'kivi.Order.show_print_options', $::instance_conf->get_order_warn_duplicate_parts ],
1640         ],
1641         action => [
1642           t8('Save and E-mail'),
1643           call => [ 'kivi.Order.email', $::instance_conf->get_order_warn_duplicate_parts ],
1644         ],
1645         action => [
1646           t8('Download attachments of all parts'),
1647           call     => [ 'kivi.File.downloadOrderitemsFiles', $::form->{type}, $::form->{id} ],
1648           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1649           only_if  => $::instance_conf->get_doc_storage,
1650         ],
1651       ], # end of combobox "Export"
1652
1653       action => [
1654         t8('Delete'),
1655         call     => [ 'kivi.Order.delete_order' ],
1656         confirm  => $::locale->text('Do you really want to delete this object?'),
1657         disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1658         only_if  => $deletion_allowed,
1659       ],
1660     );
1661   }
1662 }
1663
1664 sub generate_pdf {
1665   my ($order, $pdf_ref, $params) = @_;
1666
1667   my @errors = ();
1668
1669   my $print_form = Form->new('');
1670   $print_form->{type}        = $order->type;
1671   $print_form->{formname}    = $params->{formname} || $order->type;
1672   $print_form->{format}      = $params->{format}   || 'pdf';
1673   $print_form->{media}       = $params->{media}    || 'file';
1674   $print_form->{groupitems}  = $params->{groupitems};
1675   $print_form->{media}       = 'file'                             if $print_form->{media} eq 'screen';
1676
1677   $order->language($params->{language});
1678   $order->flatten_to_form($print_form, format_amounts => 1);
1679
1680   my $template_ext;
1681   my $template_type;
1682   if ($print_form->{format} =~ /(opendocument|oasis)/i) {
1683     $template_ext  = 'odt';
1684     $template_type = 'OpenDocument';
1685   }
1686
1687   # search for the template
1688   my ($template_file, @template_files) = SL::Helper::CreatePDF->find_template(
1689     name        => $print_form->{formname},
1690     extension   => $template_ext,
1691     email       => $print_form->{media} eq 'email',
1692     language    => $params->{language},
1693     printer_id  => $print_form->{printer_id},  # todo
1694   );
1695
1696   if (!defined $template_file) {
1697     push @errors, $::locale->text('Cannot find matching template for this print request. Please contact your template maintainer. I tried these: #1.', join ', ', map { "'$_'"} @template_files);
1698   }
1699
1700   return @errors if scalar @errors;
1701
1702   $print_form->throw_on_error(sub {
1703     eval {
1704       $print_form->prepare_for_printing;
1705
1706       $$pdf_ref = SL::Helper::CreatePDF->create_pdf(
1707         format        => $print_form->{format},
1708         template_type => $template_type,
1709         template      => $template_file,
1710         variables     => $print_form,
1711         variable_content_types => {
1712           longdescription => 'html',
1713           partnotes       => 'html',
1714           notes           => 'html',
1715         },
1716       );
1717       1;
1718     } || push @errors, ref($EVAL_ERROR) eq 'SL::X::FormError' ? $EVAL_ERROR->getMessage : $EVAL_ERROR;
1719   });
1720
1721   return @errors;
1722 }
1723
1724 sub get_files_for_email_dialog {
1725   my ($self) = @_;
1726
1727   my %files = map { ($_ => []) } qw(versions files vc_files part_files);
1728
1729   return %files if !$::instance_conf->get_doc_storage;
1730
1731   if ($self->order->id) {
1732     $files{versions} = [ SL::File->get_all_versions(object_id => $self->order->id,              object_type => $self->order->type, file_type => 'document') ];
1733     $files{files}    = [ SL::File->get_all(         object_id => $self->order->id,              object_type => $self->order->type, file_type => 'attachment') ];
1734     $files{vc_files} = [ SL::File->get_all(         object_id => $self->order->{$self->cv}->id, object_type => $self->cv,          file_type => 'attachment') ];
1735   }
1736
1737   my @parts =
1738     uniq_by { $_->{id} }
1739     map {
1740       +{ id         => $_->part->id,
1741          partnumber => $_->part->partnumber }
1742     } @{$self->order->items_sorted};
1743
1744   foreach my $part (@parts) {
1745     my @pfiles = SL::File->get_all(object_id => $part->{id}, object_type => 'part');
1746     push @{ $files{part_files} }, map { +{ %{ $_ }, partnumber => $part->{partnumber} } } @pfiles;
1747   }
1748
1749   foreach my $key (keys %files) {
1750     $files{$key} = [ sort_by { lc $_->{db_file}->{file_name} } @{ $files{$key} } ];
1751   }
1752
1753   return %files;
1754 }
1755
1756 sub make_periodic_invoices_config_from_yaml {
1757   my ($yaml_config) = @_;
1758
1759   return if !$yaml_config;
1760   my $attr = YAML::Load($yaml_config);
1761   return if 'HASH' ne ref $attr;
1762   return SL::DB::PeriodicInvoicesConfig->new(%$attr);
1763 }
1764
1765
1766 sub get_periodic_invoices_status {
1767   my ($self, $config) = @_;
1768
1769   return                      if $self->type ne sales_order_type();
1770   return t8('not configured') if !$config;
1771
1772   my $active = ('HASH' eq ref $config)                           ? $config->{active}
1773              : ('SL::DB::PeriodicInvoicesConfig' eq ref $config) ? $config->active
1774              :                                                     die "Cannot get status of periodic invoices config";
1775
1776   return $active ? t8('active') : t8('inactive');
1777 }
1778
1779 sub get_title_for {
1780   my ($self, $action) = @_;
1781
1782   return '' if none { lc($action)} qw(add edit);
1783
1784   # for locales:
1785   # $::locale->text("Add Sales Order");
1786   # $::locale->text("Add Purchase Order");
1787   # $::locale->text("Add Quotation");
1788   # $::locale->text("Add Request for Quotation");
1789   # $::locale->text("Edit Sales Order");
1790   # $::locale->text("Edit Purchase Order");
1791   # $::locale->text("Edit Quotation");
1792   # $::locale->text("Edit Request for Quotation");
1793
1794   $action = ucfirst(lc($action));
1795   return $self->type eq sales_order_type()       ? $::locale->text("$action Sales Order")
1796        : $self->type eq purchase_order_type()    ? $::locale->text("$action Purchase Order")
1797        : $self->type eq sales_quotation_type()   ? $::locale->text("$action Quotation")
1798        : $self->type eq request_quotation_type() ? $::locale->text("$action Request for Quotation")
1799        : '';
1800 }
1801
1802 sub sales_order_type {
1803   'sales_order';
1804 }
1805
1806 sub purchase_order_type {
1807   'purchase_order';
1808 }
1809
1810 sub sales_quotation_type {
1811   'sales_quotation';
1812 }
1813
1814 sub request_quotation_type {
1815   'request_quotation';
1816 }
1817
1818 sub nr_key {
1819   return $_[0]->type eq sales_order_type()       ? 'ordnumber'
1820        : $_[0]->type eq purchase_order_type()    ? 'ordnumber'
1821        : $_[0]->type eq sales_quotation_type()   ? 'quonumber'
1822        : $_[0]->type eq request_quotation_type() ? 'quonumber'
1823        : '';
1824 }
1825
1826 1;
1827
1828 __END__
1829
1830 =encoding utf-8
1831
1832 =head1 NAME
1833
1834 SL::Controller::Order - controller for orders
1835
1836 =head1 SYNOPSIS
1837
1838 This is a new form to enter orders, completely rewritten with the use
1839 of controller and java script techniques.
1840
1841 The aim is to provide the user a better expirience and a faster flow
1842 of work. Also the code should be more readable, more reliable and
1843 better to maintain.
1844
1845 =head2 Key Features
1846
1847 =over 4
1848
1849 =item *
1850
1851 One input row, so that input happens every time at the same place.
1852
1853 =item *
1854
1855 Use of pickers where possible.
1856
1857 =item *
1858
1859 Possibility to enter more than one item at once.
1860
1861 =item *
1862
1863 Item list in a scrollable area, so that the workflow buttons stay at
1864 the bottom.
1865
1866 =item *
1867
1868 Reordering item rows with drag and drop is possible. Sorting item rows is
1869 possible (by partnumber, description, qty, sellprice and discount for now).
1870
1871 =item *
1872
1873 No C<update> is necessary. All entries and calculations are managed
1874 with ajax-calls and the page does only reload on C<save>.
1875
1876 =item *
1877
1878 User can see changes immediately, because of the use of java script
1879 and ajax.
1880
1881 =back
1882
1883 =head1 CODE
1884
1885 =head2 Layout
1886
1887 =over 4
1888
1889 =item * C<SL/Controller/Order.pm>
1890
1891 the controller
1892
1893 =item * C<template/webpages/order/form.html>
1894
1895 main form
1896
1897 =item * C<template/webpages/order/tabs/basic_data.html>
1898
1899 Main tab for basic_data.
1900
1901 This is the only tab here for now. "linked records" and "webdav" tabs are
1902 reused from generic code.
1903
1904 =over 4
1905
1906 =item * C<template/webpages/order/tabs/_business_info_row.html>
1907
1908 For displaying information on business type
1909
1910 =item * C<template/webpages/order/tabs/_item_input.html>
1911
1912 The input line for items
1913
1914 =item * C<template/webpages/order/tabs/_row.html>
1915
1916 One row for already entered items
1917
1918 =item * C<template/webpages/order/tabs/_tax_row.html>
1919
1920 Displaying tax information
1921
1922 =item * C<template/webpages/order/tabs/_multi_items_dialog.html>
1923
1924 Dialog for entering more than one item at once
1925
1926 =item * C<template/webpages/order/tabs/_multi_items_result.html>
1927
1928 Results for the filter in the multi items dialog
1929
1930 =item * C<template/webpages/order/tabs/_price_sources_dialog.html>
1931
1932 Dialog for selecting price and discount sources
1933
1934 =back
1935
1936 =item * C<js/kivi.Order.js>
1937
1938 java script functions
1939
1940 =back
1941
1942 =head1 TODO
1943
1944 =over 4
1945
1946 =item * testing
1947
1948 =item * currency
1949
1950 =item * credit limit
1951
1952 =item * more workflows (quotation, rfq)
1953
1954 =item * price sources: little symbols showing better price / better discount
1955
1956 =item * select units in input row?
1957
1958 =item * custom shipto address
1959
1960 =item * check for direct delivery (workflow sales order -> purchase order)
1961
1962 =item * language / part translations
1963
1964 =item * access rights
1965
1966 =item * display weights
1967
1968 =item * history
1969
1970 =item * mtime check
1971
1972 =item * optional client/user behaviour
1973
1974 (transactions has to be set - department has to be set -
1975  force project if enabled in client config - transport cost reminder)
1976
1977 =back
1978
1979 =head1 KNOWN BUGS AND CAVEATS
1980
1981 =over 4
1982
1983 =item *
1984
1985 Customer discount is not displayed as a valid discount in price source popup
1986 (this might be a bug in price sources)
1987
1988 (I cannot reproduce this (Bernd))
1989
1990 =item *
1991
1992 No indication that <shift>-up/down expands/collapses second row.
1993
1994 =item *
1995
1996 Inline creation of parts is not currently supported
1997
1998 =item *
1999
2000 Table header is not sticky in the scrolling area.
2001
2002 =item *
2003
2004 Sorting does not include C<position>, neither does reordering.
2005
2006 This behavior was implemented intentionally. But we can discuss, which behavior
2007 should be implemented.
2008
2009 =item *
2010
2011 C<show_multi_items_dialog> does not use the currently inserted string for
2012 filtering.
2013
2014 =item *
2015
2016 The language selected in print or email dialog is not saved when the order is saved.
2017
2018 =back
2019
2020 =head1 To discuss / Nice to have
2021
2022 =over 4
2023
2024 =item *
2025
2026 How to expand/collapse second row. Now it can be done clicking the icon or
2027 <shift>-up/down.
2028
2029 =item *
2030
2031 Possibility to change longdescription in input row?
2032
2033 =item *
2034
2035 Possibility to select PriceSources in input row?
2036
2037 =item *
2038
2039 This controller uses a (changed) copy of the template for the PriceSource
2040 dialog. Maybe there could be used one code source.
2041
2042 =item *
2043
2044 Rounding-differences between this controller (PriceTaxCalculator) and the old
2045 form. This is not only a problem here, but also in all parts using the PTC.
2046 There exists a ticket and a patch. This patch should be testet.
2047
2048 =item *
2049
2050 An indicator, if the actual inputs are saved (like in an
2051 editor or on text processing application).
2052
2053 =item *
2054
2055 A warning when leaving the page without saveing unchanged inputs.
2056
2057
2058 =back
2059
2060 =head1 AUTHOR
2061
2062 Bernd Bleßmann E<lt>bernd@kivitendo-premium.deE<gt>
2063
2064 =cut