SL/Controller/Order.pm

   1 package SL::Controller::Order;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use SL::Helper::Flash qw(flash_later);
   7 use SL::HTML::Util;
   8 use SL::Presenter::Tag qw(select_tag hidden_tag div_tag);
   9 use SL::Locale::String qw(t8);
  10 use SL::SessionFile::Random;
  11 use SL::PriceSource;
  12 use SL::Webdav;
  13 use SL::File;
  14 use SL::MIME;
  15 use SL::Util qw(trim);
  16 use SL::YAML;
  17 use SL::DB::AdditionalBillingAddress;
  18 use SL::DB::AuthUser;
  19 use SL::DB::History;
  20 use SL::DB::Order;
  21 use SL::DB::Default;
  22 use SL::DB::Unit;
  23 use SL::DB::Part;
  24 use SL::DB::PartClassification;
  25 use SL::DB::PartsGroup;
  26 use SL::DB::Printer;
  27 use SL::DB::Language;
  28 use SL::DB::RecordLink;
  29 use SL::DB::RequirementSpec;
  30 use SL::DB::Shipto;
  31 use SL::DB::Translation;
  32
  33 use SL::Helper::CreatePDF qw(:all);
  34 use SL::Helper::PrintOptions;
  35 use SL::Helper::ShippedQty;
  36 use SL::Helper::UserPreferences::PositionsScrollbar;
  37 use SL::Helper::UserPreferences::UpdatePositions;
  38
  39 use SL::Controller::Helper::GetModels;
  40
  41 use List::Util qw(first sum0);
  42 use List::UtilsBy qw(sort_by uniq_by);
  43 use List::MoreUtils qw(any none pairwise first_index);
  44 use English qw(-no_match_vars);
  45 use File::Spec;
  46 use Cwd;
  47 use Sort::Naturally;
  48
  49 use Rose::Object::MakeMethods::Generic
  50 (
  51  scalar => [ qw(item_ids_to_delete is_custom_shipto_to_delete) ],
  52  'scalar --get_set_init' => [ qw(order valid_types type cv p all_price_factors search_cvpartnumber show_update_button part_picker_classification_ids) ],
  53 );
  54
  55
  56 # safety
  57 __PACKAGE__->run_before('check_auth');
  58
  59 __PACKAGE__->run_before('recalc',
  60                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice save_and_invoice_for_advance_payment save_and_final_invoice save_and_ap_transaction
  61                                      print send_email) ]);
  62
  63 __PACKAGE__->run_before('get_unalterable_data',
  64                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice save_and_invoice_for_advance_payment save_and_final_invoice save_and_ap_transaction
  65                                      print send_email) ]);
  66
  67 #
  68 # actions
  69 #
  70
  71 # add a new order
  72 sub action_add {
  73   my ($self) = @_;
  74
  75   $self->order->transdate(DateTime->now_local());
  76   my $extra_days = $self->type eq sales_quotation_type() ? $::instance_conf->get_reqdate_interval       :
  77                    $self->type eq sales_order_type()     ? $::instance_conf->get_delivery_date_interval : 1;
  78
  79   if (   ($self->type eq sales_order_type()     &&  $::instance_conf->get_deliverydate_on)
  80       || ($self->type eq sales_quotation_type() &&  $::instance_conf->get_reqdate_on)
  81       && (!$self->order->reqdate)) {
  82     $self->order->reqdate(DateTime->today_local->next_workday(extra_days => $extra_days));
  83   }
  84
  85
  86   $self->pre_render();
  87   $self->render(
  88     'order/form',
  89     title => $self->get_title_for('add'),
  90     %{$self->{template_args}}
  91   );
  92 }
  93
  94 # edit an existing order
  95 sub action_edit {
  96   my ($self) = @_;
  97
  98   if ($::form->{id}) {
  99     $self->load_order;
 100
 101   } else {
 102     # this is to edit an order from an unsaved order object
 103
 104     # set item ids to new fake id, to identify them as new items
 105     foreach my $item (@{$self->order->items_sorted}) {
 106       $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 107     }
 108     # trigger rendering values for second row as hidden, because they
 109     # are loaded only on demand. So we need to keep the values from
 110     # the source.
 111     $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
 112   }
 113
 114   $self->recalc();
 115   $self->pre_render();
 116   $self->render(
 117     'order/form',
 118     title => $self->get_title_for('edit'),
 119     %{$self->{template_args}}
 120   );
 121 }
 122
 123 # edit a collective order (consisting of one or more existing orders)
 124 sub action_edit_collective {
 125   my ($self) = @_;
 126
 127   # collect order ids
 128   my @multi_ids = map {
 129     $_ =~ m{^multi_id_(\d+)$} && $::form->{'multi_id_' . $1} && $::form->{'trans_id_' . $1} && $::form->{'trans_id_' . $1}
 130   } grep { $_ =~ m{^multi_id_\d+$} } keys %$::form;
 131
 132   # fall back to add if no ids are given
 133   if (scalar @multi_ids == 0) {
 134     $self->action_add();
 135     return;
 136   }
 137
 138   # fall back to save as new if only one id is given
 139   if (scalar @multi_ids == 1) {
 140     $self->order(SL::DB::Order->new(id => $multi_ids[0])->load);
 141     $self->action_save_as_new();
 142     return;
 143   }
 144
 145   # make new order from given orders
 146   my @multi_orders = map { SL::DB::Order->new(id => $_)->load } @multi_ids;
 147   $self->{converted_from_oe_id} = join ' ', map { $_->id } @multi_orders;
 148   $self->order(SL::DB::Order->new_from_multi(\@multi_orders, sort_sources_by => 'transdate'));
 149
 150   $self->action_edit();
 151 }
 152
 153 # delete the order
 154 sub action_delete {
 155   my ($self) = @_;
 156
 157   my $errors = $self->delete();
 158
 159   if (scalar @{ $errors }) {
 160     $self->js->flash('error', $_) foreach @{ $errors };
 161     return $self->js->render();
 162   }
 163
 164   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been deleted')
 165            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been deleted')
 166            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been deleted')
 167            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been deleted')
 168            : '';
 169   flash_later('info', $text);
 170
 171   my @redirect_params = (
 172     action => 'add',
 173     type   => $self->type,
 174   );
 175
 176   $self->redirect_to(@redirect_params);
 177 }
 178
 179 # save the order
 180 sub action_save {
 181   my ($self) = @_;
 182
 183   my $errors = $self->save();
 184
 185   if (scalar @{ $errors }) {
 186     $self->js->flash('error', $_) foreach @{ $errors };
 187     return $self->js->render();
 188   }
 189
 190   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
 191            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
 192            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
 193            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
 194            : '';
 195   flash_later('info', $text);
 196
 197   my @redirect_params = (
 198     action => 'edit',
 199     type   => $self->type,
 200     id     => $self->order->id,
 201   );
 202
 203   $self->redirect_to(@redirect_params);
 204 }
 205
 206 # save the order as new document an open it for edit
 207 sub action_save_as_new {
 208   my ($self) = @_;
 209
 210   my $order = $self->order;
 211
 212   if (!$order->id) {
 213     $self->js->flash('error', t8('This object has not been saved yet.'));
 214     return $self->js->render();
 215   }
 216
 217   # load order from db to check if values changed
 218   my $saved_order = SL::DB::Order->new(id => $order->id)->load;
 219
 220   my %new_attrs;
 221   # Lets assign a new number if the user hasn't changed the previous one.
 222   # If it has been changed manually then use it as-is.
 223   $new_attrs{number}    = (trim($order->number) eq $saved_order->number)
 224                         ? ''
 225                         : trim($order->number);
 226
 227   # Clear transdate unless changed
 228   $new_attrs{transdate} = ($order->transdate == $saved_order->transdate)
 229                         ? DateTime->today_local
 230                         : $order->transdate;
 231
 232   # Set new reqdate unless changed if it is enabled in client config
 233   if ($order->reqdate == $saved_order->reqdate) {
 234     my $extra_days = $self->type eq sales_quotation_type() ? $::instance_conf->get_reqdate_interval       :
 235                      $self->type eq sales_order_type()     ? $::instance_conf->get_delivery_date_interval : 1;
 236
 237     if (   ($self->type eq sales_order_type()     &&  !$::instance_conf->get_deliverydate_on)
 238         || ($self->type eq sales_quotation_type() &&  !$::instance_conf->get_reqdate_on)) {
 239       $new_attrs{reqdate} = '';
 240     } else {
 241       $new_attrs{reqdate} = DateTime->today_local->next_workday(extra_days => $extra_days);
 242     }
 243   } else {
 244     $new_attrs{reqdate} = $order->reqdate;
 245   }
 246
 247   # Update employee
 248   $new_attrs{employee}  = SL::DB::Manager::Employee->current;
 249
 250   # Create new record from current one
 251   $self->order(SL::DB::Order->new_from($order, destination_type => $order->type, attributes => \%new_attrs));
 252
 253   # no linked records on save as new
 254   delete $::form->{$_} for qw(converted_from_oe_id converted_from_orderitems_ids);
 255
 256   # save
 257   $self->action_save();
 258 }
 259
 260 # print the order
 261 #
 262 # This is called if "print" is pressed in the print dialog.
 263 # If PDF creation was requested and succeeded, the pdf is offered for download
 264 # via send_file (which uses ajax in this case).
 265 sub action_print {
 266   my ($self) = @_;
 267
 268   my $errors = $self->save();
 269
 270   if (scalar @{ $errors }) {
 271     $self->js->flash('error', $_) foreach @{ $errors };
 272     return $self->js->render();
 273   }
 274
 275   $self->js_reset_order_and_item_ids_after_save;
 276
 277   my $format      = $::form->{print_options}->{format};
 278   my $media       = $::form->{print_options}->{media};
 279   my $formname    = $::form->{print_options}->{formname};
 280   my $copies      = $::form->{print_options}->{copies};
 281   my $groupitems  = $::form->{print_options}->{groupitems};
 282   my $printer_id  = $::form->{print_options}->{printer_id};
 283
 284   # only PDF, OpenDocument & HTML for now
 285   if (none { $format eq $_ } qw(pdf opendocument opendocument_pdf html)) {
 286     return $self->js->flash('error', t8('Format \'#1\' is not supported yet/anymore.', $format))->render;
 287   }
 288
 289   # only screen or printer by now
 290   if (none { $media eq $_ } qw(screen printer)) {
 291     return $self->js->flash('error', t8('Media \'#1\' is not supported yet/anymore.', $media))->render;
 292   }
 293
 294   # create a form for generate_attachment_filename
 295   my $form   = Form->new;
 296   $form->{$self->nr_key()}  = $self->order->number;
 297   $form->{type}             = $self->type;
 298   $form->{format}           = $format;
 299   $form->{formname}         = $formname;
 300   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 301   my $doc_filename          = $form->generate_attachment_filename();
 302
 303   my $doc;
 304   my @errors = $self->generate_doc(\$doc, { media      => $media,
 305                                             format     => $format,
 306                                             formname   => $formname,
 307                                             language   => $self->order->language,
 308                                             printer_id => $printer_id,
 309                                             groupitems => $groupitems });
 310   if (scalar @errors) {
 311     return $self->js->flash('error', t8('Generating the document failed: #1', $errors[0]))->render;
 312   }
 313
 314   if ($media eq 'screen') {
 315     # screen/download
 316     $self->js->flash('info', t8('The document has been created.'));
 317     $self->send_file(
 318       \$doc,
 319       type         => SL::MIME->mime_type_from_ext($doc_filename),
 320       name         => $doc_filename,
 321       js_no_render => 1,
 322     );
 323
 324   } elsif ($media eq 'printer') {
 325     # printer
 326     my $printer_id = $::form->{print_options}->{printer_id};
 327     SL::DB::Printer->new(id => $printer_id)->load->print_document(
 328       copies  => $copies,
 329       content => $doc,
 330     );
 331
 332     $self->js->flash('info', t8('The document has been printed.'));
 333   }
 334
 335   my @warnings = $self->store_doc_to_webdav_and_filemanagement($doc, $doc_filename, $formname);
 336   if (scalar @warnings) {
 337     $self->js->flash('warning', $_) for @warnings;
 338   }
 339
 340   $self->save_history('PRINTED');
 341
 342   $self->js
 343     ->run('kivi.ActionBar.setEnabled', '#save_and_email_action')
 344     ->render;
 345 }
 346 sub action_preview_pdf {
 347   my ($self) = @_;
 348
 349   my $errors = $self->save();
 350   if (scalar @{ $errors }) {
 351     $self->js->flash('error', $_) foreach @{ $errors };
 352     return $self->js->render();
 353   }
 354
 355   $self->js_reset_order_and_item_ids_after_save;
 356
 357   my $format      = 'pdf';
 358   my $media       = 'screen';
 359   my $formname    = $self->type;
 360
 361   # only pdf
 362   # create a form for generate_attachment_filename
 363   my $form   = Form->new;
 364   $form->{$self->nr_key()}  = $self->order->number;
 365   $form->{type}             = $self->type;
 366   $form->{format}           = $format;
 367   $form->{formname}         = $formname;
 368   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 369   my $pdf_filename          = $form->generate_attachment_filename();
 370
 371   my $pdf;
 372   my @errors = $self->generate_doc(\$pdf, { media      => $media,
 373                                             format     => $format,
 374                                             formname   => $formname,
 375                                             language   => $self->order->language,
 376                                           });
 377   if (scalar @errors) {
 378     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render;
 379   }
 380   $self->save_history('PREVIEWED');
 381   $self->js->flash('info', t8('The PDF has been previewed'));
 382   # screen/download
 383   $self->send_file(
 384     \$pdf,
 385     type         => SL::MIME->mime_type_from_ext($pdf_filename),
 386     name         => $pdf_filename,
 387     js_no_render => 0,
 388   );
 389 }
 390
 391 # open the email dialog
 392 sub action_save_and_show_email_dialog {
 393   my ($self) = @_;
 394
 395   my $errors = $self->save();
 396
 397   if (scalar @{ $errors }) {
 398     $self->js->flash('error', $_) foreach @{ $errors };
 399     return $self->js->render();
 400   }
 401
 402   my $cv_method = $self->cv;
 403
 404   if (!$self->order->$cv_method) {
 405     return $self->js->flash('error', $self->cv eq 'customer' ? t8('Cannot send E-mail without customer given') : t8('Cannot send E-mail without vendor given'))
 406                     ->render($self);
 407   }
 408
 409   my $email_form;
 410   $email_form->{to}   = $self->order->contact->cp_email if $self->order->contact;
 411   $email_form->{to} ||= $self->order->$cv_method->email;
 412   $email_form->{cc}   = $self->order->$cv_method->cc;
 413   $email_form->{bcc}  = join ', ', grep $_, $self->order->$cv_method->bcc, SL::DB::Default->get->global_bcc;
 414   # Todo: get addresses from shipto, if any
 415
 416   my $form = Form->new;
 417   $form->{$self->nr_key()}  = $self->order->number;
 418   $form->{cusordnumber}     = $self->order->cusordnumber;
 419   $form->{formname}         = $self->type;
 420   $form->{type}             = $self->type;
 421   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 422   $form->{language_id}      = $self->order->language->id                  if $self->order->language;
 423   $form->{format}           = 'pdf';
 424   $form->{cp_id}            = $self->order->contact->cp_id if $self->order->contact;
 425
 426   $email_form->{subject}             = $form->generate_email_subject();
 427   $email_form->{attachment_filename} = $form->generate_attachment_filename();
 428   $email_form->{message}             = $form->generate_email_body();
 429   $email_form->{js_send_function}    = 'kivi.Order.send_email()';
 430
 431   my %files = $self->get_files_for_email_dialog();
 432
 433   my @employees_with_email = grep {
 434     my $user = SL::DB::Manager::AuthUser->find_by(login => $_->login);
 435     $user && !!trim($user->get_config_value('email'));
 436   } @{ SL::DB::Manager::Employee->get_all_sorted(query => [ deleted => 0 ]) };
 437
 438   my $dialog_html = $self->render('common/_send_email_dialog', { output => 0 },
 439                                   email_form    => $email_form,
 440                                   show_bcc      => $::auth->assert('email_bcc', 'may fail'),
 441                                   FILES         => \%files,
 442                                   is_customer   => $self->cv eq 'customer',
 443                                   ALL_EMPLOYEES => \@employees_with_email,
 444   );
 445
 446   $self->js
 447       ->run('kivi.Order.show_email_dialog', $dialog_html)
 448       ->reinit_widgets
 449       ->render($self);
 450 }
 451
 452 # send email
 453 #
 454 # Todo: handling error messages: flash is not displayed in dialog, but in the main form
 455 sub action_send_email {
 456   my ($self) = @_;
 457
 458   my $errors = $self->save();
 459
 460   if (scalar @{ $errors }) {
 461     $self->js->run('kivi.Order.close_email_dialog');
 462     $self->js->flash('error', $_) foreach @{ $errors };
 463     return $self->js->render();
 464   }
 465
 466   $self->js_reset_order_and_item_ids_after_save;
 467
 468   my $email_form  = delete $::form->{email_form};
 469   my %field_names = (to => 'email');
 470
 471   $::form->{ $field_names{$_} // $_ } = $email_form->{$_} for keys %{ $email_form };
 472
 473   # for Form::cleanup which may be called in Form::send_email
 474   $::form->{cwd}    = getcwd();
 475   $::form->{tmpdir} = $::lx_office_conf{paths}->{userspath};
 476
 477   $::form->{$_}     = $::form->{print_options}->{$_} for keys %{ $::form->{print_options} };
 478   $::form->{media}  = 'email';
 479
 480   $::form->{attachment_policy} //= '';
 481
 482   # Is an old file version available?
 483   my $attfile;
 484   if ($::form->{attachment_policy} eq 'old_file') {
 485     $attfile = SL::File->get_all(object_id     => $self->order->id,
 486                                  object_type   => $self->type,
 487                                  file_type     => 'document',
 488                                  print_variant => $::form->{formname});
 489   }
 490
 491   if ($::form->{attachment_policy} ne 'no_file' && !($::form->{attachment_policy} eq 'old_file' && $attfile)) {
 492     my $doc;
 493     my @errors = $self->generate_doc(\$doc, {media      => $::form->{media},
 494                                              format     => $::form->{print_options}->{format},
 495                                              formname   => $::form->{print_options}->{formname},
 496                                              language   => $self->order->language,
 497                                              printer_id => $::form->{print_options}->{printer_id},
 498                                              groupitems => $::form->{print_options}->{groupitems}});
 499     if (scalar @errors) {
 500       return $self->js->flash('error', t8('Generating the document failed: #1', $errors[0]))->render($self);
 501     }
 502
 503     my @warnings = $self->store_doc_to_webdav_and_filemanagement($doc, $::form->{attachment_filename}, $::form->{formname});
 504     if (scalar @warnings) {
 505       flash_later('warning', $_) for @warnings;
 506     }
 507
 508     my $sfile = SL::SessionFile::Random->new(mode => "w");
 509     $sfile->fh->print($doc);
 510     $sfile->fh->close;
 511
 512     $::form->{tmpfile} = $sfile->file_name;
 513     $::form->{tmpdir}  = $sfile->get_path; # for Form::cleanup which may be called in Form::send_email
 514   }
 515
 516   $::form->{id} = $self->order->id; # this is used in SL::Mailer to create a linked record to the mail
 517   $::form->send_email(\%::myconfig, $::form->{print_options}->{format});
 518
 519   # internal notes
 520   my $intnotes = $self->order->intnotes;
 521   $intnotes   .= "\n\n" if $self->order->intnotes;
 522   $intnotes   .= t8('[email]')                                                                                        . "\n";
 523   $intnotes   .= t8('Date')       . ": " . $::locale->format_date_object(DateTime->now_local, precision => 'seconds') . "\n";
 524   $intnotes   .= t8('To (email)') . ": " . $::form->{email}                                                           . "\n";
 525   $intnotes   .= t8('Cc')         . ": " . $::form->{cc}                                                              . "\n"    if $::form->{cc};
 526   $intnotes   .= t8('Bcc')        . ": " . $::form->{bcc}                                                             . "\n"    if $::form->{bcc};
 527   $intnotes   .= t8('Subject')    . ": " . $::form->{subject}                                                         . "\n\n";
 528   $intnotes   .= t8('Message')    . ": " . SL::HTML::Util->strip($::form->{message});
 529
 530   $self->order->update_attributes(intnotes => $intnotes);
 531
 532   $self->save_history('MAILED');
 533
 534   flash_later('info', t8('The email has been sent.'));
 535
 536   my @redirect_params = (
 537     action => 'edit',
 538     type   => $self->type,
 539     id     => $self->order->id,
 540   );
 541
 542   $self->redirect_to(@redirect_params);
 543 }
 544
 545 # open the periodic invoices config dialog
 546 #
 547 # If there are values in the form (i.e. dialog was opened before),
 548 # then use this values. Create new ones, else.
 549 sub action_show_periodic_invoices_config_dialog {
 550   my ($self) = @_;
 551
 552   my $config = make_periodic_invoices_config_from_yaml(delete $::form->{config});
 553   $config  ||= SL::DB::Manager::PeriodicInvoicesConfig->find_by(oe_id => $::form->{id}) if $::form->{id};
 554   $config  ||= SL::DB::PeriodicInvoicesConfig->new(periodicity             => 'm',
 555                                                    order_value_periodicity => 'p', # = same as periodicity
 556                                                    start_date_as_date      => $::form->{transdate_as_date} || $::form->current_date,
 557                                                    extend_automatically_by => 12,
 558                                                    active                  => 1,
 559                                                    email_subject           => GenericTranslations->get(
 560                                                                                 language_id      => $::form->{language_id},
 561                                                                                 translation_type =>"preset_text_periodic_invoices_email_subject"),
 562                                                    email_body              => GenericTranslations->get(
 563                                                                                 language_id      => $::form->{language_id},
 564                                                                                 translation_type => "salutation_general")
 565                                                                             . GenericTranslations->get(
 566                                                                                 language_id      => $::form->{language_id},
 567                                                                                 translation_type => "salutation_punctuation_mark") . "\n\n"
 568                                                                             . GenericTranslations->get(
 569                                                                                 language_id      => $::form->{language_id},
 570                                                                                 translation_type =>"preset_text_periodic_invoices_email_body"),
 571   );
 572   # for older configs, replace email preset text if not yet set.
 573   $config->email_subject(GenericTranslations->get(
 574                                               language_id      => $::form->{language_id},
 575                                               translation_type =>"preset_text_periodic_invoices_email_subject")
 576                         ) unless $config->email_subject;
 577
 578   $config->email_body(GenericTranslations->get(
 579                                               language_id      => $::form->{language_id},
 580                                               translation_type => "salutation_general")
 581                     . GenericTranslations->get(
 582                                               language_id      => $::form->{language_id},
 583                                               translation_type => "salutation_punctuation_mark") . "\n\n"
 584                     . GenericTranslations->get(
 585                                               language_id      => $::form->{language_id},
 586                                               translation_type =>"preset_text_periodic_invoices_email_body")
 587                      ) unless $config->email_body;
 588
 589   $config->periodicity('m')             if none { $_ eq $config->periodicity             }       @SL::DB::PeriodicInvoicesConfig::PERIODICITIES;
 590   $config->order_value_periodicity('p') if none { $_ eq $config->order_value_periodicity } ('p', @SL::DB::PeriodicInvoicesConfig::ORDER_VALUE_PERIODICITIES);
 591
 592   $::form->get_lists(printers => "ALL_PRINTERS",
 593                      charts   => { key       => 'ALL_CHARTS',
 594                                    transdate => 'current_date' });
 595
 596   $::form->{AR} = [ grep { $_->{link} =~ m/(?:^|:)AR(?::|$)/ } @{ $::form->{ALL_CHARTS} } ];
 597
 598   if ($::form->{customer_id}) {
 599     $::form->{ALL_CONTACTS} = SL::DB::Manager::Contact->get_all_sorted(where => [ cp_cv_id => $::form->{customer_id} ]);
 600     my $customer_object = SL::DB::Manager::Customer->find_by(id => $::form->{customer_id});
 601     $::form->{postal_invoice}                  = $customer_object->postal_invoice;
 602     $::form->{email_recipient_invoice_address} = $::form->{postal_invoice} ? '' : $customer_object->invoice_mail;
 603     $config->send_email(0) if $::form->{postal_invoice};
 604   }
 605
 606   $self->render('oe/edit_periodic_invoices_config', { layout => 0 },
 607                 popup_dialog             => 1,
 608                 popup_js_close_function  => 'kivi.Order.close_periodic_invoices_config_dialog()',
 609                 popup_js_assign_function => 'kivi.Order.assign_periodic_invoices_config()',
 610                 config                   => $config,
 611                 %$::form);
 612 }
 613
 614 # assign the values of the periodic invoices config dialog
 615 # as yaml in the hidden tag and set the status.
 616 sub action_assign_periodic_invoices_config {
 617   my ($self) = @_;
 618
 619   $::form->isblank('start_date_as_date', $::locale->text('The start date is missing.'));
 620
 621   my $config = { active                     => $::form->{active}       ? 1 : 0,
 622                  terminated                 => $::form->{terminated}   ? 1 : 0,
 623                  direct_debit               => $::form->{direct_debit} ? 1 : 0,
 624                  periodicity                => (any { $_ eq $::form->{periodicity}             }       @SL::DB::PeriodicInvoicesConfig::PERIODICITIES)              ? $::form->{periodicity}             : 'm',
 625                  order_value_periodicity    => (any { $_ eq $::form->{order_value_periodicity} } ('p', @SL::DB::PeriodicInvoicesConfig::ORDER_VALUE_PERIODICITIES)) ? $::form->{order_value_periodicity} : 'p',
 626                  start_date_as_date         => $::form->{start_date_as_date},
 627                  end_date_as_date           => $::form->{end_date_as_date},
 628                  first_billing_date_as_date => $::form->{first_billing_date_as_date},
 629                  print                      => $::form->{print}      ? 1                         : 0,
 630                  printer_id                 => $::form->{print}      ? $::form->{printer_id} * 1 : undef,
 631                  copies                     => $::form->{copies} * 1 ? $::form->{copies}         : 1,
 632                  extend_automatically_by    => $::form->{extend_automatically_by}    * 1 || undef,
 633                  ar_chart_id                => $::form->{ar_chart_id} * 1,
 634                  send_email                 => $::form->{send_email} ? 1 : 0,
 635                  email_recipient_contact_id => $::form->{email_recipient_contact_id} * 1 || undef,
 636                  email_recipient_address    => $::form->{email_recipient_address},
 637                  email_sender               => $::form->{email_sender},
 638                  email_subject              => $::form->{email_subject},
 639                  email_body                 => $::form->{email_body},
 640                };
 641
 642   my $periodic_invoices_config = SL::YAML::Dump($config);
 643
 644   my $status = $self->get_periodic_invoices_status($config);
 645
 646   $self->js
 647     ->remove('#order_periodic_invoices_config')
 648     ->insertAfter(hidden_tag('order.periodic_invoices_config', $periodic_invoices_config), '#periodic_invoices_status')
 649     ->run('kivi.Order.close_periodic_invoices_config_dialog')
 650     ->html('#periodic_invoices_status', $status)
 651     ->flash('info', t8('The periodic invoices config has been assigned.'))
 652     ->render($self);
 653 }
 654
 655 sub action_get_has_active_periodic_invoices {
 656   my ($self) = @_;
 657
 658   my $config = make_periodic_invoices_config_from_yaml(delete $::form->{config});
 659   $config  ||= SL::DB::Manager::PeriodicInvoicesConfig->find_by(oe_id => $::form->{id}) if $::form->{id};
 660
 661   my $has_active_periodic_invoices =
 662        $self->type eq sales_order_type()
 663     && $config
 664     && $config->active
 665     && (!$config->end_date || ($config->end_date > DateTime->today_local))
 666     && $config->get_previous_billed_period_start_date;
 667
 668   $_[0]->render(\ !!$has_active_periodic_invoices, { type => 'text' });
 669 }
 670
 671 # save the order and redirect to the frontend subroutine for a new
 672 # delivery order
 673 sub action_save_and_delivery_order {
 674   my ($self) = @_;
 675
 676   $self->save_and_redirect_to(
 677     controller => 'oe.pl',
 678     action     => 'oe_delivery_order_from_order',
 679   );
 680 }
 681
 682 sub action_save_and_supplier_delivery_order {
 683   my ($self) = @_;
 684
 685   $self->save_and_redirect_to(
 686     controller => 'controller.pl',
 687     action     => 'DeliveryOrder/add_from_order',
 688     type       => 'supplier_delivery_order',
 689   );
 690 }
 691
 692 # save the order and redirect to the frontend subroutine for a new
 693 # invoice
 694 sub action_save_and_invoice {
 695   my ($self) = @_;
 696
 697   $self->save_and_redirect_to(
 698     controller => 'oe.pl',
 699     action     => 'oe_invoice_from_order',
 700   );
 701 }
 702
 703 sub action_save_and_invoice_for_advance_payment {
 704   my ($self) = @_;
 705
 706   $self->save_and_redirect_to(
 707     controller       => 'oe.pl',
 708     action           => 'oe_invoice_from_order',
 709     new_invoice_type => 'invoice_for_advance_payment',
 710   );
 711 }
 712
 713 sub action_save_and_final_invoice {
 714   my ($self) = @_;
 715
 716   $self->save_and_redirect_to(
 717     controller       => 'oe.pl',
 718     action           => 'oe_invoice_from_order',
 719     new_invoice_type => 'final_invoice',
 720   );
 721 }
 722
 723 # workflow from sales order to sales quotation
 724 sub action_sales_quotation {
 725   $_[0]->workflow_sales_or_request_for_quotation();
 726 }
 727
 728 # workflow from sales order to sales quotation
 729 sub action_request_for_quotation {
 730   $_[0]->workflow_sales_or_request_for_quotation();
 731 }
 732
 733 # workflow from sales quotation to sales order
 734 sub action_sales_order {
 735   $_[0]->workflow_sales_or_purchase_order();
 736 }
 737
 738 # workflow from rfq to purchase order
 739 sub action_purchase_order {
 740   $_[0]->workflow_sales_or_purchase_order();
 741 }
 742
 743 # workflow from purchase order to ap transaction
 744 sub action_save_and_ap_transaction {
 745   my ($self) = @_;
 746
 747   $self->save_and_redirect_to(
 748     controller => 'ap.pl',
 749     action     => 'add_from_purchase_order',
 750   );
 751 }
 752
 753 # set form elements in respect to a changed customer or vendor
 754 #
 755 # This action is called on an change of the customer/vendor picker.
 756 sub action_customer_vendor_changed {
 757   my ($self) = @_;
 758
 759   setup_order_from_cv($self->order);
 760   $self->recalc();
 761
 762   my $cv_method = $self->cv;
 763
 764   if ($self->order->$cv_method->contacts && scalar @{ $self->order->$cv_method->contacts } > 0) {
 765     $self->js->show('#cp_row');
 766   } else {
 767     $self->js->hide('#cp_row');
 768   }
 769
 770   if ($self->order->$cv_method->shipto && scalar @{ $self->order->$cv_method->shipto } > 0) {
 771     $self->js->show('#shipto_selection');
 772   } else {
 773     $self->js->hide('#shipto_selection');
 774   }
 775
 776   if ($cv_method eq 'customer') {
 777     my $show_hide = scalar @{ $self->order->customer->additional_billing_addresses } > 0 ? 'show' : 'hide';
 778     $self->js->$show_hide('#billing_address_row');
 779   }
 780
 781   $self->js->val( '#order_salesman_id',      $self->order->salesman_id)        if $self->order->is_sales;
 782
 783   $self->js
 784     ->replaceWith('#order_cp_id',              $self->build_contact_select)
 785     ->replaceWith('#order_shipto_id',          $self->build_shipto_select)
 786     ->replaceWith('#shipto_inputs  ',          $self->build_shipto_inputs)
 787     ->replaceWith('#order_billing_address_id', $self->build_billing_address_select)
 788     ->replaceWith('#business_info_row',        $self->build_business_info_row)
 789     ->val(        '#order_taxzone_id',         $self->order->taxzone_id)
 790     ->val(        '#order_taxincluded',        $self->order->taxincluded)
 791     ->val(        '#order_currency_id',        $self->order->currency_id)
 792     ->val(        '#order_payment_id',         $self->order->payment_id)
 793     ->val(        '#order_delivery_term_id',   $self->order->delivery_term_id)
 794     ->val(        '#order_intnotes',           $self->order->intnotes)
 795     ->val(        '#order_language_id',        $self->order->$cv_method->language_id)
 796     ->focus(      '#order_' . $self->cv . '_id')
 797     ->run('kivi.Order.update_exchangerate');
 798
 799   $self->js_redisplay_amounts_and_taxes;
 800   $self->js_redisplay_cvpartnumbers;
 801   $self->js->render();
 802 }
 803
 804 # open the dialog for customer/vendor details
 805 sub action_show_customer_vendor_details_dialog {
 806   my ($self) = @_;
 807
 808   my $is_customer = 'customer' eq $::form->{vc};
 809   my $cv;
 810   if ($is_customer) {
 811     $cv = SL::DB::Customer->new(id => $::form->{vc_id})->load;
 812   } else {
 813     $cv = SL::DB::Vendor->new(id => $::form->{vc_id})->load;
 814   }
 815
 816   my %details = map { $_ => $cv->$_ } @{$cv->meta->columns};
 817   $details{discount_as_percent} = $cv->discount_as_percent;
 818   $details{creditlimt}          = $cv->creditlimit_as_number;
 819   $details{business}            = $cv->business->description      if $cv->business;
 820   $details{language}            = $cv->language_obj->description  if $cv->language_obj;
 821   $details{delivery_terms}      = $cv->delivery_term->description if $cv->delivery_term;
 822   $details{payment_terms}       = $cv->payment->description       if $cv->payment;
 823   $details{pricegroup}          = $cv->pricegroup->pricegroup     if $is_customer && $cv->pricegroup;
 824
 825   if ($is_customer) {
 826     foreach my $entry (@{ $cv->additional_billing_addresses }) {
 827       push @{ $details{ADDITIONAL_BILLING_ADDRESSES} },   { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 828     }
 829   }
 830   foreach my $entry (@{ $cv->shipto }) {
 831     push @{ $details{SHIPTO} },   { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 832   }
 833   foreach my $entry (@{ $cv->contacts }) {
 834     push @{ $details{CONTACTS} }, { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 835   }
 836
 837   $_[0]->render('common/show_vc_details', { layout => 0 },
 838                 is_customer => $is_customer,
 839                 %details);
 840
 841 }
 842
 843 # called if a unit in an existing item row is changed
 844 sub action_unit_changed {
 845   my ($self) = @_;
 846
 847   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 848   my $item = $self->order->items_sorted->[$idx];
 849
 850   my $old_unit_obj = SL::DB::Unit->new(name => $::form->{old_unit})->load;
 851   $item->sellprice($item->unit_obj->convert_to($item->sellprice, $old_unit_obj));
 852
 853   $self->recalc();
 854
 855   $self->js
 856     ->run('kivi.Order.update_sellprice', $::form->{item_id}, $item->sellprice_as_number);
 857   $self->js_redisplay_line_values;
 858   $self->js_redisplay_amounts_and_taxes;
 859   $self->js->render();
 860 }
 861
 862 # add an item row for a new item entered in the input row
 863 sub action_add_item {
 864   my ($self) = @_;
 865
 866   delete $::form->{add_item}->{create_part_type};
 867
 868   my $form_attr = $::form->{add_item};
 869
 870   return unless $form_attr->{parts_id};
 871
 872   my $item = new_item($self->order, $form_attr);
 873
 874   $self->order->add_items($item);
 875
 876   $self->recalc();
 877
 878   $self->get_item_cvpartnumber($item);
 879
 880   my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 881   my $row_as_html = $self->p->render('order/tabs/_row',
 882                                      ITEM => $item,
 883                                      ID   => $item_id,
 884                                      SELF => $self,
 885   );
 886
 887   if ($::form->{insert_before_item_id}) {
 888     $self->js
 889       ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 890   } else {
 891     $self->js
 892       ->append('#row_table_id', $row_as_html);
 893   }
 894
 895   if ( $item->part->is_assortment ) {
 896     $form_attr->{qty_as_number} = 1 unless $form_attr->{qty_as_number};
 897     foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 898       my $attr = { parts_id => $assortment_item->parts_id,
 899                    qty      => $assortment_item->qty * $::form->parse_amount(\%::myconfig, $form_attr->{qty_as_number}), # TODO $form_attr->{unit}
 900                    unit     => $assortment_item->unit,
 901                    description => $assortment_item->part->description,
 902                  };
 903       my $item = new_item($self->order, $attr);
 904
 905       # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 906       $item->discount(1) unless $assortment_item->charge;
 907
 908       $self->order->add_items( $item );
 909       $self->recalc();
 910       $self->get_item_cvpartnumber($item);
 911       my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 912       my $row_as_html = $self->p->render('order/tabs/_row',
 913                                          ITEM => $item,
 914                                          ID   => $item_id,
 915                                          SELF => $self,
 916       );
 917       if ($::form->{insert_before_item_id}) {
 918         $self->js
 919           ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 920       } else {
 921         $self->js
 922           ->append('#row_table_id', $row_as_html);
 923       }
 924     };
 925   };
 926
 927   $self->js
 928     ->val('.add_item_input', '')
 929     ->run('kivi.Order.init_row_handlers')
 930     ->run('kivi.Order.renumber_positions')
 931     ->focus('#add_item_parts_id_name');
 932
 933   $self->js->run('kivi.Order.row_table_scroll_down') if !$::form->{insert_before_item_id};
 934
 935   $self->js_redisplay_amounts_and_taxes;
 936   $self->js->render();
 937 }
 938
 939 # add item rows for multiple items at once
 940 sub action_add_multi_items {
 941   my ($self) = @_;
 942
 943   my @form_attr = grep { $_->{qty_as_number} } @{ $::form->{add_items} };
 944   return $self->js->render() unless scalar @form_attr;
 945
 946   my @items;
 947   foreach my $attr (@form_attr) {
 948     my $item = new_item($self->order, $attr);
 949     push @items, $item;
 950     if ( $item->part->is_assortment ) {
 951       foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 952         my $attr = { parts_id => $assortment_item->parts_id,
 953                      qty      => $assortment_item->qty * $item->qty, # TODO $form_attr->{unit}
 954                      unit     => $assortment_item->unit,
 955                      description => $assortment_item->part->description,
 956                    };
 957         my $item = new_item($self->order, $attr);
 958
 959         # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 960         $item->discount(1) unless $assortment_item->charge;
 961         push @items, $item;
 962       }
 963     }
 964   }
 965   $self->order->add_items(@items);
 966
 967   $self->recalc();
 968
 969   foreach my $item (@items) {
 970     $self->get_item_cvpartnumber($item);
 971     my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 972     my $row_as_html = $self->p->render('order/tabs/_row',
 973                                        ITEM => $item,
 974                                        ID   => $item_id,
 975                                        SELF => $self,
 976     );
 977
 978     if ($::form->{insert_before_item_id}) {
 979       $self->js
 980         ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 981     } else {
 982       $self->js
 983         ->append('#row_table_id', $row_as_html);
 984     }
 985   }
 986
 987   $self->js
 988     ->run('kivi.Part.close_picker_dialogs')
 989     ->run('kivi.Order.init_row_handlers')
 990     ->run('kivi.Order.renumber_positions')
 991     ->focus('#add_item_parts_id_name');
 992
 993   $self->js->run('kivi.Order.row_table_scroll_down') if !$::form->{insert_before_item_id};
 994
 995   $self->js_redisplay_amounts_and_taxes;
 996   $self->js->render();
 997 }
 998
 999 # recalculate all linetotals, amounts and taxes and redisplay them
1000 sub action_recalc_amounts_and_taxes {
1001   my ($self) = @_;
1002
1003   $self->recalc();
1004
1005   $self->js_redisplay_line_values;
1006   $self->js_redisplay_amounts_and_taxes;
1007   $self->js->render();
1008 }
1009
1010 sub action_update_exchangerate {
1011   my ($self) = @_;
1012
1013   my $data = {
1014     is_standard   => $self->order->currency_id == $::instance_conf->get_currency_id,
1015     currency_name => $self->order->currency->name,
1016     exchangerate  => $self->order->daily_exchangerate_as_null_number,
1017   };
1018
1019   $self->render(\SL::JSON::to_json($data), { type => 'json', process => 0 });
1020 }
1021
1022 # redisplay item rows if they are sorted by an attribute
1023 sub action_reorder_items {
1024   my ($self) = @_;
1025
1026   my %sort_keys = (
1027     partnumber   => sub { $_[0]->part->partnumber },
1028     description  => sub { $_[0]->description },
1029     qty          => sub { $_[0]->qty },
1030     sellprice    => sub { $_[0]->sellprice },
1031     discount     => sub { $_[0]->discount },
1032     cvpartnumber => sub { $_[0]->{cvpartnumber} },
1033   );
1034
1035   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
1036
1037   my $method = $sort_keys{$::form->{order_by}};
1038   my @to_sort = map { { old_pos => $_->position, order_by => $method->($_) } } @{ $self->order->items_sorted };
1039   if ($::form->{sort_dir}) {
1040     if ( $::form->{order_by} =~ m/qty|sellprice|discount/ ){
1041       @to_sort = sort { $a->{order_by} <=> $b->{order_by} } @to_sort;
1042     } else {
1043       @to_sort = sort { $a->{order_by} cmp $b->{order_by} } @to_sort;
1044     }
1045   } else {
1046     if ( $::form->{order_by} =~ m/qty|sellprice|discount/ ){
1047       @to_sort = sort { $b->{order_by} <=> $a->{order_by} } @to_sort;
1048     } else {
1049       @to_sort = sort { $b->{order_by} cmp $a->{order_by} } @to_sort;
1050     }
1051   }
1052   $self->js
1053     ->run('kivi.Order.redisplay_items', \@to_sort)
1054     ->render;
1055 }
1056
1057 # show the popup to choose a price/discount source
1058 sub action_price_popup {
1059   my ($self) = @_;
1060
1061   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
1062   my $item = $self->order->items_sorted->[$idx];
1063
1064   $self->render_price_dialog($item);
1065 }
1066
1067 # save the order in a session variable and redirect to the part controller
1068 sub action_create_part {
1069   my ($self) = @_;
1070
1071   my $previousform = $::auth->save_form_in_session(non_scalars => 1);
1072
1073   my $callback     = $self->url_for(
1074     action       => 'return_from_create_part',
1075     type         => $self->type, # type is needed for check_auth on return
1076     previousform => $previousform,
1077   );
1078
1079   flash_later('info', t8('You are adding a new part while you are editing another document. You will be redirected to your document when saving the new part or aborting this form.'));
1080
1081   my @redirect_params = (
1082     controller => 'Part',
1083     action     => 'add',
1084     part_type  => $::form->{add_item}->{create_part_type},
1085     callback   => $callback,
1086     show_abort => 1,
1087   );
1088
1089   $self->redirect_to(@redirect_params);
1090 }
1091
1092 sub action_return_from_create_part {
1093   my ($self) = @_;
1094
1095   $self->{created_part} = SL::DB::Part->new(id => delete $::form->{new_parts_id})->load if $::form->{new_parts_id};
1096
1097   $::auth->restore_form_from_session(delete $::form->{previousform});
1098
1099   # set item ids to new fake id, to identify them as new items
1100   foreach my $item (@{$self->order->items_sorted}) {
1101     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1102   }
1103
1104   $self->recalc();
1105   $self->get_unalterable_data();
1106   $self->pre_render();
1107
1108   # trigger rendering values for second row/longdescription as hidden,
1109   # because they are loaded only on demand. So we need to keep the values
1110   # from the source.
1111   $_->{render_second_row}      = 1 for @{ $self->order->items_sorted };
1112   $_->{render_longdescription} = 1 for @{ $self->order->items_sorted };
1113
1114   $self->render(
1115     'order/form',
1116     title => $self->get_title_for('edit'),
1117     %{$self->{template_args}}
1118   );
1119
1120 }
1121
1122 # load the second row for one or more items
1123 #
1124 # This action gets the html code for all items second rows by rendering a template for
1125 # the second row and sets the html code via client js.
1126 sub action_load_second_rows {
1127   my ($self) = @_;
1128
1129   $self->recalc() if $self->order->is_sales; # for margin calculation
1130
1131   foreach my $item_id (@{ $::form->{item_ids} }) {
1132     my $idx  = first_index { $_ eq $item_id } @{ $::form->{orderitem_ids} };
1133     my $item = $self->order->items_sorted->[$idx];
1134
1135     $self->js_load_second_row($item, $item_id, 0);
1136   }
1137
1138   $self->js->run('kivi.Order.init_row_handlers') if $self->order->is_sales; # for lastcosts change-callback
1139
1140   $self->js->render();
1141 }
1142
1143 # update description, notes and sellprice from master data
1144 sub action_update_row_from_master_data {
1145   my ($self) = @_;
1146
1147   foreach my $item_id (@{ $::form->{item_ids} }) {
1148     my $idx   = first_index { $_ eq $item_id } @{ $::form->{orderitem_ids} };
1149     my $item  = $self->order->items_sorted->[$idx];
1150     my $texts = get_part_texts($item->part, $self->order->language_id);
1151
1152     $item->description($texts->{description});
1153     $item->longdescription($texts->{longdescription});
1154
1155     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
1156
1157     my $price_src;
1158     if ($item->part->is_assortment) {
1159     # add assortment items with price 0, as the components carry the price
1160       $price_src = $price_source->price_from_source("");
1161       $price_src->price(0);
1162     } else {
1163       $price_src = $price_source->best_price
1164                  ? $price_source->best_price
1165                  : $price_source->price_from_source("");
1166       $price_src->price($::form->round_amount($price_src->price / $self->order->exchangerate, 5)) if $self->order->exchangerate;
1167       $price_src->price(0) if !$price_source->best_price;
1168     }
1169
1170
1171     $item->sellprice($price_src->price);
1172     $item->active_price_source($price_src);
1173
1174     $self->js
1175       ->run('kivi.Order.update_sellprice', $item_id, $item->sellprice_as_number)
1176       ->html('.row_entry:has(#item_' . $item_id . ') [name = "partnumber"] a', $item->part->partnumber)
1177       ->val ('.row_entry:has(#item_' . $item_id . ') [name = "order.orderitems[].description"]', $item->description)
1178       ->val ('.row_entry:has(#item_' . $item_id . ') [name = "order.orderitems[].longdescription"]', $item->longdescription);
1179
1180     if ($self->search_cvpartnumber) {
1181       $self->get_item_cvpartnumber($item);
1182       $self->js->html('.row_entry:has(#item_' . $item_id . ') [name = "cvpartnumber"]', $item->{cvpartnumber});
1183     }
1184   }
1185
1186   $self->recalc();
1187   $self->js_redisplay_line_values;
1188   $self->js_redisplay_amounts_and_taxes;
1189
1190   $self->js->render();
1191 }
1192
1193 sub js_load_second_row {
1194   my ($self, $item, $item_id, $do_parse) = @_;
1195
1196   if ($do_parse) {
1197     # Parse values from form (they are formated while rendering (template)).
1198     # Workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
1199     # This parsing is not necessary at all, if we assure that the second row/cvars are only loaded once.
1200     foreach my $var (@{ $item->cvars_by_config }) {
1201       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
1202     }
1203     $item->parse_custom_variable_values;
1204   }
1205
1206   my $row_as_html = $self->p->render('order/tabs/_second_row', ITEM => $item, TYPE => $self->type);
1207
1208   $self->js
1209     ->html('#second_row_' . $item_id, $row_as_html)
1210     ->data('#second_row_' . $item_id, 'loaded', 1);
1211 }
1212
1213 sub js_redisplay_line_values {
1214   my ($self) = @_;
1215
1216   my $is_sales = $self->order->is_sales;
1217
1218   # sales orders with margins
1219   my @data;
1220   if ($is_sales) {
1221     @data = map {
1222       [
1223        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
1224        $::form->format_amount(\%::myconfig, $_->{marge_total},   2, 0),
1225        $::form->format_amount(\%::myconfig, $_->{marge_percent}, 2, 0),
1226       ]} @{ $self->order->items_sorted };
1227   } else {
1228     @data = map {
1229       [
1230        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
1231       ]} @{ $self->order->items_sorted };
1232   }
1233
1234   $self->js
1235     ->run('kivi.Order.redisplay_line_values', $is_sales, \@data);
1236 }
1237
1238 sub js_redisplay_amounts_and_taxes {
1239   my ($self) = @_;
1240
1241   if (scalar @{ $self->{taxes} }) {
1242     $self->js->show('#taxincluded_row_id');
1243   } else {
1244     $self->js->hide('#taxincluded_row_id');
1245   }
1246
1247   if ($self->order->taxincluded) {
1248     $self->js->hide('#subtotal_row_id');
1249   } else {
1250     $self->js->show('#subtotal_row_id');
1251   }
1252
1253   if ($self->order->is_sales) {
1254     my $is_neg = $self->order->marge_total < 0;
1255     $self->js
1256       ->html('#marge_total_id',   $::form->format_amount(\%::myconfig, $self->order->marge_total,   2))
1257       ->html('#marge_percent_id', $::form->format_amount(\%::myconfig, $self->order->marge_percent, 2))
1258       ->action_if( $is_neg, 'addClass',    '#marge_total_id',        'plus0')
1259       ->action_if( $is_neg, 'addClass',    '#marge_percent_id',      'plus0')
1260       ->action_if( $is_neg, 'addClass',    '#marge_percent_sign_id', 'plus0')
1261       ->action_if(!$is_neg, 'removeClass', '#marge_total_id',        'plus0')
1262       ->action_if(!$is_neg, 'removeClass', '#marge_percent_id',      'plus0')
1263       ->action_if(!$is_neg, 'removeClass', '#marge_percent_sign_id', 'plus0');
1264   }
1265
1266   $self->js
1267     ->html('#netamount_id', $::form->format_amount(\%::myconfig, $self->order->netamount, -2))
1268     ->html('#amount_id',    $::form->format_amount(\%::myconfig, $self->order->amount,    -2))
1269     ->remove('.tax_row')
1270     ->insertBefore($self->build_tax_rows, '#amount_row_id');
1271 }
1272
1273 sub js_redisplay_cvpartnumbers {
1274   my ($self) = @_;
1275
1276   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
1277
1278   my @data = map {[$_->{cvpartnumber}]} @{ $self->order->items_sorted };
1279
1280   $self->js
1281     ->run('kivi.Order.redisplay_cvpartnumbers', \@data);
1282 }
1283
1284 sub js_reset_order_and_item_ids_after_save {
1285   my ($self) = @_;
1286
1287   $self->js
1288     ->val('#id', $self->order->id)
1289     ->val('#converted_from_oe_id', '')
1290     ->val('#order_' . $self->nr_key(), $self->order->number);
1291
1292   my $idx = 0;
1293   foreach my $form_item_id (@{ $::form->{orderitem_ids} }) {
1294     next if !$self->order->items_sorted->[$idx]->id;
1295     next if $form_item_id !~ m{^new};
1296     $self->js
1297       ->val ('[name="orderitem_ids[+]"][value="' . $form_item_id . '"]', $self->order->items_sorted->[$idx]->id)
1298       ->val ('#item_' . $form_item_id, $self->order->items_sorted->[$idx]->id)
1299       ->attr('#item_' . $form_item_id, "id", 'item_' . $self->order->items_sorted->[$idx]->id);
1300   } continue {
1301     $idx++;
1302   }
1303   $self->js->val('[name="converted_from_orderitems_ids[+]"]', '');
1304 }
1305
1306 #
1307 # helpers
1308 #
1309
1310 sub init_valid_types {
1311   [ sales_order_type(), purchase_order_type(), sales_quotation_type(), request_quotation_type() ];
1312 }
1313
1314 sub init_type {
1315   my ($self) = @_;
1316
1317   if (none { $::form->{type} eq $_ } @{$self->valid_types}) {
1318     die "Not a valid type for order";
1319   }
1320
1321   $self->type($::form->{type});
1322 }
1323
1324 sub init_cv {
1325   my ($self) = @_;
1326
1327   my $cv = (any { $self->type eq $_ } (sales_order_type(),    sales_quotation_type()))   ? 'customer'
1328          : (any { $self->type eq $_ } (purchase_order_type(), request_quotation_type())) ? 'vendor'
1329          : die "Not a valid type for order";
1330
1331   return $cv;
1332 }
1333
1334 sub init_search_cvpartnumber {
1335   my ($self) = @_;
1336
1337   my $user_prefs = SL::Helper::UserPreferences::PartPickerSearch->new();
1338   my $search_cvpartnumber;
1339   $search_cvpartnumber = !!$user_prefs->get_sales_search_customer_partnumber() if $self->cv eq 'customer';
1340   $search_cvpartnumber = !!$user_prefs->get_purchase_search_makemodel()        if $self->cv eq 'vendor';
1341
1342   return $search_cvpartnumber;
1343 }
1344
1345 sub init_show_update_button {
1346   my ($self) = @_;
1347
1348   !!SL::Helper::UserPreferences::UpdatePositions->new()->get_show_update_button();
1349 }
1350
1351 sub init_p {
1352   SL::Presenter->get;
1353 }
1354
1355 sub init_order {
1356   $_[0]->make_order;
1357 }
1358
1359 sub init_all_price_factors {
1360   SL::DB::Manager::PriceFactor->get_all;
1361 }
1362
1363 sub init_part_picker_classification_ids {
1364   my ($self)    = @_;
1365   my $attribute = 'used_for_' . ($self->type =~ m{sales} ? 'sale' : 'purchase');
1366
1367   return [ map { $_->id } @{ SL::DB::Manager::PartClassification->get_all(where => [ $attribute => 1 ]) } ];
1368 }
1369
1370 sub check_auth {
1371   my ($self) = @_;
1372
1373   my $right_for = { map { $_ => $_.'_edit' } @{$self->valid_types} };
1374
1375   my $right   = $right_for->{ $self->type };
1376   $right    ||= 'DOES_NOT_EXIST';
1377
1378   $::auth->assert($right);
1379 }
1380
1381 # build the selection box for contacts
1382 #
1383 # Needed, if customer/vendor changed.
1384 sub build_contact_select {
1385   my ($self) = @_;
1386
1387   select_tag('order.cp_id', [ $self->order->{$self->cv}->contacts ],
1388     value_key  => 'cp_id',
1389     title_key  => 'full_name_dep',
1390     default    => $self->order->cp_id,
1391     with_empty => 1,
1392     style      => 'width: 300px',
1393   );
1394 }
1395
1396 # build the selection box for the additional billing address
1397 #
1398 # Needed, if customer/vendor changed.
1399 sub build_billing_address_select {
1400   my ($self) = @_;
1401
1402   return '' if $self->cv ne 'customer';
1403
1404   select_tag('order.billing_address_id',
1405              [ {displayable_id => '', id => ''}, $self->order->{$self->cv}->additional_billing_addresses ],
1406              value_key  => 'id',
1407              title_key  => 'displayable_id',
1408              default    => $self->order->billing_address_id,
1409              with_empty => 0,
1410              style      => 'width: 300px',
1411   );
1412 }
1413
1414 # build the selection box for shiptos
1415 #
1416 # Needed, if customer/vendor changed.
1417 sub build_shipto_select {
1418   my ($self) = @_;
1419
1420   select_tag('order.shipto_id',
1421              [ {displayable_id => t8("No/individual shipping address"), shipto_id => ''}, $self->order->{$self->cv}->shipto ],
1422              value_key  => 'shipto_id',
1423              title_key  => 'displayable_id',
1424              default    => $self->order->shipto_id,
1425              with_empty => 0,
1426              style      => 'width: 300px',
1427   );
1428 }
1429
1430 # build the inputs for the cusom shipto dialog
1431 #
1432 # Needed, if customer/vendor changed.
1433 sub build_shipto_inputs {
1434   my ($self) = @_;
1435
1436   my $content = $self->p->render('common/_ship_to_dialog',
1437                                  vc_obj      => $self->order->customervendor,
1438                                  cs_obj      => $self->order->custom_shipto,
1439                                  cvars       => $self->order->custom_shipto->cvars_by_config,
1440                                  id_selector => '#order_shipto_id');
1441
1442   div_tag($content, id => 'shipto_inputs');
1443 }
1444
1445 # render the info line for business
1446 #
1447 # Needed, if customer/vendor changed.
1448 sub build_business_info_row
1449 {
1450   $_[0]->p->render('order/tabs/_business_info_row', SELF => $_[0]);
1451 }
1452
1453 # build the rows for displaying taxes
1454 #
1455 # Called if amounts where recalculated and redisplayed.
1456 sub build_tax_rows {
1457   my ($self) = @_;
1458
1459   my $rows_as_html;
1460   foreach my $tax (sort { $a->{tax}->rate cmp $b->{tax}->rate } @{ $self->{taxes} }) {
1461     $rows_as_html .= $self->p->render('order/tabs/_tax_row', TAX => $tax, TAXINCLUDED => $self->order->taxincluded);
1462   }
1463   return $rows_as_html;
1464 }
1465
1466
1467 sub render_price_dialog {
1468   my ($self, $record_item) = @_;
1469
1470   my $price_source = SL::PriceSource->new(record_item => $record_item, record => $self->order);
1471
1472   $self->js
1473     ->run(
1474       'kivi.io.price_chooser_dialog',
1475       t8('Available Prices'),
1476       $self->render('order/tabs/_price_sources_dialog', { output => 0 }, price_source => $price_source)
1477     )
1478     ->reinit_widgets;
1479
1480 #   if (@errors) {
1481 #     $self->js->text('#dialog_flash_error_content', join ' ', @errors);
1482 #     $self->js->show('#dialog_flash_error');
1483 #   }
1484
1485   $self->js->render;
1486 }
1487
1488 sub load_order {
1489   my ($self) = @_;
1490
1491   return if !$::form->{id};
1492
1493   $self->order(SL::DB::Order->new(id => $::form->{id})->load);
1494
1495   # Add an empty custom shipto to the order, so that the dialog can render the cvar inputs.
1496   # You need a custom shipto object to call cvars_by_config to get the cvars.
1497   $self->order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => [])) if !$self->order->custom_shipto;
1498
1499   return $self->order;
1500 }
1501
1502 # load or create a new order object
1503 #
1504 # And assign changes from the form to this object.
1505 # If the order is loaded from db, check if items are deleted in the form,
1506 # remove them form the object and collect them for removing from db on saving.
1507 # Then create/update items from form (via make_item) and add them.
1508 sub make_order {
1509   my ($self) = @_;
1510
1511   # add_items adds items to an order with no items for saving, but they cannot
1512   # be retrieved via items until the order is saved. Adding empty items to new
1513   # order here solves this problem.
1514   my $order;
1515   $order   = SL::DB::Order->new(id => $::form->{id})->load(with => [ 'orderitems', 'orderitems.part' ]) if $::form->{id};
1516   $order ||= SL::DB::Order->new(orderitems  => [],
1517                                 quotation   => (any { $self->type eq $_ } (sales_quotation_type(), request_quotation_type())),
1518                                 currency_id => $::instance_conf->get_currency_id(),);
1519
1520   my $cv_id_method = $self->cv . '_id';
1521   if (!$::form->{id} && $::form->{$cv_id_method}) {
1522     $order->$cv_id_method($::form->{$cv_id_method});
1523     setup_order_from_cv($order);
1524   }
1525
1526   my $form_orderitems                  = delete $::form->{order}->{orderitems};
1527   my $form_periodic_invoices_config    = delete $::form->{order}->{periodic_invoices_config};
1528
1529   $order->assign_attributes(%{$::form->{order}});
1530
1531   $self->setup_custom_shipto_from_form($order, $::form);
1532
1533   if (my $periodic_invoices_config_attrs = $form_periodic_invoices_config ? SL::YAML::Load($form_periodic_invoices_config) : undef) {
1534     my $periodic_invoices_config = $order->periodic_invoices_config || $order->periodic_invoices_config(SL::DB::PeriodicInvoicesConfig->new);
1535     $periodic_invoices_config->assign_attributes(%$periodic_invoices_config_attrs);
1536   }
1537
1538   # remove deleted items
1539   $self->item_ids_to_delete([]);
1540   foreach my $idx (reverse 0..$#{$order->orderitems}) {
1541     my $item = $order->orderitems->[$idx];
1542     if (none { $item->id == $_->{id} } @{$form_orderitems}) {
1543       splice @{$order->orderitems}, $idx, 1;
1544       push @{$self->item_ids_to_delete}, $item->id;
1545     }
1546   }
1547
1548   my @items;
1549   my $pos = 1;
1550   foreach my $form_attr (@{$form_orderitems}) {
1551     my $item = make_item($order, $form_attr);
1552     $item->position($pos);
1553     push @items, $item;
1554     $pos++;
1555   }
1556   $order->add_items(grep {!$_->id} @items);
1557
1558   return $order;
1559 }
1560
1561 # create or update items from form
1562 #
1563 # Make item objects from form values. For items already existing read from db.
1564 # Create a new item else. And assign attributes.
1565 sub make_item {
1566   my ($record, $attr) = @_;
1567
1568   my $item;
1569   $item = first { $_->id == $attr->{id} } @{$record->items} if $attr->{id};
1570
1571   my $is_new = !$item;
1572
1573   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1574   # they cannot be retrieved via custom_variables until the order/orderitem is
1575   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1576   $item ||= SL::DB::OrderItem->new(custom_variables => []);
1577
1578   $item->assign_attributes(%$attr);
1579
1580   if ($is_new) {
1581     my $texts = get_part_texts($item->part, $record->language_id);
1582     $item->longdescription($texts->{longdescription})              if !defined $attr->{longdescription};
1583     $item->project_id($record->globalproject_id)                   if !defined $attr->{project_id};
1584     $item->lastcost($record->is_sales ? $item->part->lastcost : 0) if !defined $attr->{lastcost_as_number};
1585   }
1586
1587   return $item;
1588 }
1589
1590 # create a new item
1591 #
1592 # This is used to add one item
1593 sub new_item {
1594   my ($record, $attr) = @_;
1595
1596   my $item = SL::DB::OrderItem->new;
1597
1598   # Remove attributes where the user left or set the inputs empty.
1599   # So these attributes will be undefined and we can distinguish them
1600   # from zero later on.
1601   for (qw(qty_as_number sellprice_as_number discount_as_percent)) {
1602     delete $attr->{$_} if $attr->{$_} eq '';
1603   }
1604
1605   $item->assign_attributes(%$attr);
1606
1607   my $part         = SL::DB::Part->new(id => $attr->{parts_id})->load;
1608   my $price_source = SL::PriceSource->new(record_item => $item, record => $record);
1609
1610   $item->unit($part->unit) if !$item->unit;
1611
1612   my $price_src;
1613   if ( $part->is_assortment ) {
1614     # add assortment items with price 0, as the components carry the price
1615     $price_src = $price_source->price_from_source("");
1616     $price_src->price(0);
1617   } elsif (defined $item->sellprice) {
1618     $price_src = $price_source->price_from_source("");
1619     $price_src->price($item->sellprice);
1620   } else {
1621     $price_src = $price_source->best_price
1622                ? $price_source->best_price
1623                : $price_source->price_from_source("");
1624     $price_src->price($::form->round_amount($price_src->price / $record->exchangerate, 5)) if $record->exchangerate;
1625     $price_src->price(0) if !$price_source->best_price;
1626   }
1627
1628   my $discount_src;
1629   if (defined $item->discount) {
1630     $discount_src = $price_source->discount_from_source("");
1631     $discount_src->discount($item->discount);
1632   } else {
1633     $discount_src = $price_source->best_discount
1634                   ? $price_source->best_discount
1635                   : $price_source->discount_from_source("");
1636     $discount_src->discount(0) if !$price_source->best_discount;
1637   }
1638
1639   my %new_attr;
1640   $new_attr{part}                   = $part;
1641   $new_attr{description}            = $part->description     if ! $item->description;
1642   $new_attr{qty}                    = 1.0                    if ! $item->qty;
1643   $new_attr{price_factor_id}        = $part->price_factor_id if ! $item->price_factor_id;
1644   $new_attr{sellprice}              = $price_src->price;
1645   $new_attr{discount}               = $discount_src->discount;
1646   $new_attr{active_price_source}    = $price_src;
1647   $new_attr{active_discount_source} = $discount_src;
1648   $new_attr{longdescription}        = $part->notes           if ! defined $attr->{longdescription};
1649   $new_attr{project_id}             = $record->globalproject_id;
1650   $new_attr{lastcost}               = $record->is_sales ? $part->lastcost : 0;
1651
1652   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1653   # they cannot be retrieved via custom_variables until the order/orderitem is
1654   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1655   $new_attr{custom_variables} = [];
1656
1657   my $texts = get_part_texts($part, $record->language_id, description => $new_attr{description}, longdescription => $new_attr{longdescription});
1658
1659   $item->assign_attributes(%new_attr, %{ $texts });
1660
1661   return $item;
1662 }
1663
1664 sub setup_order_from_cv {
1665   my ($order) = @_;
1666
1667   $order->$_($order->customervendor->$_) for (qw(taxzone_id payment_id delivery_term_id currency_id));
1668
1669   $order->intnotes($order->customervendor->notes);
1670
1671   return if !$order->is_sales;
1672
1673   $order->salesman_id($order->customer->salesman_id || SL::DB::Manager::Employee->current->id);
1674   $order->taxincluded(defined($order->customer->taxincluded_checked)
1675                       ? $order->customer->taxincluded_checked
1676                       : $::myconfig{taxincluded_checked});
1677
1678   my $address = $order->customer->default_billing_address;;
1679   $order->billing_address_id($address ? $address->id : undef);
1680 }
1681
1682 # setup custom shipto from form
1683 #
1684 # The dialog returns form variables starting with 'shipto' and cvars starting
1685 # with 'shiptocvar_'.
1686 # Mark it to be deleted if a shipto from master data is selected
1687 # (i.e. order has a shipto).
1688 # Else, update or create a new custom shipto. If the fields are empty, it
1689 # will not be saved on save.
1690 sub setup_custom_shipto_from_form {
1691   my ($self, $order, $form) = @_;
1692
1693   if ($order->shipto) {
1694     $self->is_custom_shipto_to_delete(1);
1695   } else {
1696     my $custom_shipto = $order->custom_shipto || $order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => []));
1697
1698     my $shipto_cvars  = {map { my ($key) = m{^shiptocvar_(.+)}; $key => delete $form->{$_}} grep { m{^shiptocvar_} } keys %$form};
1699     my $shipto_attrs  = {map {                                  $_   => delete $form->{$_}} grep { m{^shipto}      } keys %$form};
1700
1701     $custom_shipto->assign_attributes(%$shipto_attrs);
1702     $custom_shipto->cvar_by_name($_)->value($shipto_cvars->{$_}) for keys %$shipto_cvars;
1703   }
1704 }
1705
1706 # recalculate prices and taxes
1707 #
1708 # Using the PriceTaxCalculator. Store linetotals in the item objects.
1709 sub recalc {
1710   my ($self) = @_;
1711
1712   my %pat = $self->order->calculate_prices_and_taxes();
1713
1714   $self->{taxes} = [];
1715   foreach my $tax_id (keys %{ $pat{taxes_by_tax_id} }) {
1716     my $netamount = sum0 map { $pat{amounts}->{$_}->{amount} } grep { $pat{amounts}->{$_}->{tax_id} == $tax_id } keys %{ $pat{amounts} };
1717
1718     push(@{ $self->{taxes} }, { amount    => $pat{taxes_by_tax_id}->{$tax_id},
1719                                 netamount => $netamount,
1720                                 tax       => SL::DB::Tax->new(id => $tax_id)->load });
1721   }
1722   pairwise { $a->{linetotal} = $b->{linetotal} } @{$self->order->items_sorted}, @{$pat{items}};
1723 }
1724
1725 # get data for saving, printing, ..., that is not changed in the form
1726 #
1727 # Only cvars for now.
1728 sub get_unalterable_data {
1729   my ($self) = @_;
1730
1731   foreach my $item (@{ $self->order->items }) {
1732     # autovivify all cvars that are not in the form (cvars_by_config can do it).
1733     # workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
1734     foreach my $var (@{ $item->cvars_by_config }) {
1735       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
1736     }
1737     $item->parse_custom_variable_values;
1738   }
1739 }
1740
1741 # delete the order
1742 #
1743 # And remove related files in the spool directory
1744 sub delete {
1745   my ($self) = @_;
1746
1747   my $errors = [];
1748   my $db     = $self->order->db;
1749
1750   $db->with_transaction(
1751     sub {
1752       my @spoolfiles = grep { $_ } map { $_->spoolfile } @{ SL::DB::Manager::Status->get_all(where => [ trans_id => $self->order->id ]) };
1753       $self->order->delete;
1754       my $spool = $::lx_office_conf{paths}->{spool};
1755       unlink map { "$spool/$_" } @spoolfiles if $spool;
1756
1757       $self->save_history('DELETED');
1758
1759       1;
1760   }) || push(@{$errors}, $db->error);
1761
1762   return $errors;
1763 }
1764
1765 # save the order
1766 #
1767 # And delete items that are deleted in the form.
1768 sub save {
1769   my ($self) = @_;
1770
1771   my $errors = [];
1772   my $db     = $self->order->db;
1773
1774   $db->with_transaction(sub {
1775     # delete custom shipto if it is to be deleted or if it is empty
1776     if ($self->order->custom_shipto && ($self->is_custom_shipto_to_delete || $self->order->custom_shipto->is_empty)) {
1777       $self->order->custom_shipto->delete if $self->order->custom_shipto->shipto_id;
1778       $self->order->custom_shipto(undef);
1779     }
1780
1781     SL::DB::OrderItem->new(id => $_)->delete for @{$self->item_ids_to_delete || []};
1782     $self->order->save(cascade => 1);
1783
1784     # link records
1785     if ($::form->{converted_from_oe_id}) {
1786       my @converted_from_oe_ids = split ' ', $::form->{converted_from_oe_id};
1787
1788       foreach my $converted_from_oe_id (@converted_from_oe_ids) {
1789         my $src = SL::DB::Order->new(id => $converted_from_oe_id)->load;
1790         $src->update_attributes(closed => 1) if $src->type =~ /_quotation$/;
1791         $src->link_to_record($self->order);
1792       }
1793       if (scalar @{ $::form->{converted_from_orderitems_ids} || [] }) {
1794         my $idx = 0;
1795         foreach (@{ $self->order->items_sorted }) {
1796           my $from_id = $::form->{converted_from_orderitems_ids}->[$idx];
1797           next if !$from_id;
1798           SL::DB::RecordLink->new(from_table => 'orderitems',
1799                                   from_id    => $from_id,
1800                                   to_table   => 'orderitems',
1801                                   to_id      => $_->id
1802           )->save;
1803           $idx++;
1804         }
1805       }
1806
1807       $self->link_requirement_specs_linking_to_created_from_objects(@converted_from_oe_ids);
1808     }
1809
1810     $self->set_project_in_linked_requirement_specs if $self->order->globalproject_id;
1811
1812     $self->save_history('SAVED');
1813
1814     1;
1815   }) || push(@{$errors}, $db->error);
1816
1817   return $errors;
1818 }
1819
1820 sub workflow_sales_or_request_for_quotation {
1821   my ($self) = @_;
1822
1823   # always save
1824   my $errors = $self->save();
1825
1826   if (scalar @{ $errors }) {
1827     $self->js->flash('error', $_) for @{ $errors };
1828     return $self->js->render();
1829   }
1830
1831   my $destination_type = $::form->{type} eq sales_order_type() ? sales_quotation_type() : request_quotation_type();
1832
1833   $self->order(SL::DB::Order->new_from($self->order, destination_type => $destination_type));
1834   $self->{converted_from_oe_id} = delete $::form->{id};
1835
1836   # set item ids to new fake id, to identify them as new items
1837   foreach my $item (@{$self->order->items_sorted}) {
1838     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1839   }
1840
1841   # change form type
1842   $::form->{type} = $destination_type;
1843   $self->type($self->init_type);
1844   $self->cv  ($self->init_cv);
1845   $self->check_auth;
1846
1847   $self->recalc();
1848   $self->get_unalterable_data();
1849   $self->pre_render();
1850
1851   # trigger rendering values for second row as hidden, because they
1852   # are loaded only on demand. So we need to keep the values from the
1853   # source.
1854   $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
1855
1856   $self->render(
1857     'order/form',
1858     title => $self->get_title_for('edit'),
1859     %{$self->{template_args}}
1860   );
1861 }
1862
1863 sub workflow_sales_or_purchase_order {
1864   my ($self) = @_;
1865
1866   # always save
1867   my $errors = $self->save();
1868
1869   if (scalar @{ $errors }) {
1870     $self->js->flash('error', $_) foreach @{ $errors };
1871     return $self->js->render();
1872   }
1873
1874   my $destination_type = $::form->{type} eq sales_quotation_type()   ? sales_order_type()
1875                        : $::form->{type} eq request_quotation_type() ? purchase_order_type()
1876                        : $::form->{type} eq purchase_order_type()    ? sales_order_type()
1877                        : $::form->{type} eq sales_order_type()       ? purchase_order_type()
1878                        : '';
1879
1880   # check for direct delivery
1881   # copy shipto in custom shipto (custom shipto will be copied by new_from() in case)
1882   my $custom_shipto;
1883   if (   $::form->{type} eq sales_order_type() && $destination_type eq purchase_order_type()
1884       && $::form->{use_shipto} && $self->order->shipto) {
1885     $custom_shipto = $self->order->shipto->clone('SL::DB::Order');
1886   }
1887
1888   $self->order(SL::DB::Order->new_from($self->order, destination_type => $destination_type));
1889   $self->{converted_from_oe_id} = delete $::form->{id};
1890
1891   # set item ids to new fake id, to identify them as new items
1892   foreach my $item (@{$self->order->items_sorted}) {
1893     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1894   }
1895
1896   if ($::form->{type} eq sales_order_type() && $destination_type eq purchase_order_type()) {
1897     if ($::form->{use_shipto}) {
1898       $self->order->custom_shipto($custom_shipto) if $custom_shipto;
1899     } else {
1900       # remove any custom shipto if not wanted
1901       $self->order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => []));
1902     }
1903   }
1904
1905   # change form type
1906   $::form->{type} = $destination_type;
1907   $self->type($self->init_type);
1908   $self->cv  ($self->init_cv);
1909   $self->check_auth;
1910
1911   $self->recalc();
1912   $self->get_unalterable_data();
1913   $self->pre_render();
1914
1915   # trigger rendering values for second row as hidden, because they
1916   # are loaded only on demand. So we need to keep the values from the
1917   # source.
1918   $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
1919
1920   $self->render(
1921     'order/form',
1922     title => $self->get_title_for('edit'),
1923     %{$self->{template_args}}
1924   );
1925 }
1926
1927
1928 sub pre_render {
1929   my ($self) = @_;
1930
1931   $self->{all_taxzones}               = SL::DB::Manager::TaxZone->get_all_sorted();
1932   $self->{all_currencies}             = SL::DB::Manager::Currency->get_all_sorted();
1933   $self->{all_departments}            = SL::DB::Manager::Department->get_all_sorted();
1934   $self->{all_languages}              = SL::DB::Manager::Language->get_all_sorted();
1935   $self->{all_employees}              = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->employee_id,
1936                                                                                               deleted => 0 ] ],
1937                                                                            sort_by => 'name');
1938   $self->{all_salesmen}               = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->salesman_id,
1939                                                                                               deleted => 0 ] ],
1940                                                                            sort_by => 'name');
1941   $self->{all_payment_terms}          = SL::DB::Manager::PaymentTerm->get_all_sorted(where => [ or => [ id => $self->order->payment_id,
1942                                                                                                         obsolete => 0 ] ]);
1943   $self->{all_delivery_terms}         = SL::DB::Manager::DeliveryTerm->get_all_sorted();
1944   $self->{current_employee_id}        = SL::DB::Manager::Employee->current->id;
1945   $self->{periodic_invoices_status}   = $self->get_periodic_invoices_status($self->order->periodic_invoices_config);
1946   $self->{order_probabilities}        = [ map { { title => ($_ * 10) . '%', id => $_ * 10 } } (0..10) ];
1947   $self->{positions_scrollbar_height} = SL::Helper::UserPreferences::PositionsScrollbar->new()->get_height();
1948
1949   my $print_form = Form->new('');
1950   $print_form->{type}        = $self->type;
1951   $print_form->{printers}    = SL::DB::Manager::Printer->get_all_sorted;
1952   $self->{print_options}     = SL::Helper::PrintOptions->get_print_options(
1953     form => $print_form,
1954     options => {dialog_name_prefix => 'print_options.',
1955                 show_headers       => 1,
1956                 no_queue           => 1,
1957                 no_postscript      => 1,
1958                 no_opendocument    => 0,
1959                 no_html            => 0},
1960   );
1961
1962   foreach my $item (@{$self->order->orderitems}) {
1963     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
1964     $item->active_price_source(   $price_source->price_from_source(   $item->active_price_source   ));
1965     $item->active_discount_source($price_source->discount_from_source($item->active_discount_source));
1966   }
1967
1968   if (any { $self->type eq $_ } (sales_order_type(), purchase_order_type())) {
1969     # Calculate shipped qtys here to prevent calling calculate for every item via the items method.
1970     # Do not use write_to_objects to prevent order->delivered to be set, because this should be
1971     # the value from db, which can be set manually or is set when linked delivery orders are saved.
1972     SL::Helper::ShippedQty->new->calculate($self->order)->write_to(\@{$self->order->items});
1973   }
1974
1975   if ($self->order->number && $::instance_conf->get_webdav) {
1976     my $webdav = SL::Webdav->new(
1977       type     => $self->type,
1978       number   => $self->order->number,
1979     );
1980     my @all_objects = $webdav->get_all_objects;
1981     @{ $self->{template_args}->{WEBDAV} } = map { { name => $_->filename,
1982                                                     type => t8('File'),
1983                                                     link => File::Spec->catfile($_->full_filedescriptor),
1984                                                 } } @all_objects;
1985   }
1986
1987   if (   (any { $self->type eq $_ } (sales_quotation_type(), sales_order_type()))
1988       && $::instance_conf->get_transport_cost_reminder_article_number_id ) {
1989     $self->{template_args}->{transport_cost_reminder_article} = SL::DB::Part->new(id => $::instance_conf->get_transport_cost_reminder_article_number_id)->load;
1990   }
1991
1992   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
1993
1994   $::request->{layout}->use_javascript("${_}.js") for qw(kivi.Validator kivi.SalesPurchase kivi.Order kivi.File ckeditor/ckeditor ckeditor/adapters/jquery
1995                                                          edit_periodic_invoices_config calculate_qty follow_up show_history);
1996   $self->setup_edit_action_bar;
1997 }
1998
1999 sub setup_edit_action_bar {
2000   my ($self, %params) = @_;
2001
2002   my $deletion_allowed = (any { $self->type eq $_ } (sales_quotation_type(), request_quotation_type()))
2003                       || (($self->type eq sales_order_type())    && $::instance_conf->get_sales_order_show_delete)
2004                       || (($self->type eq purchase_order_type()) && $::instance_conf->get_purchase_order_show_delete);
2005
2006   my @req_trans_cost_art = qw(kivi.Order.check_transport_cost_article_presence) x!!$::instance_conf->get_transport_cost_reminder_article_number_id;
2007   my @req_cusordnumber   = qw(kivi.Order.check_cusordnumber_presence)           x($self->type eq sales_order_type() && $::instance_conf->get_order_warn_no_cusordnumber);
2008
2009   my $has_invoice_for_advance_payment;
2010   if ($self->order->id && $self->type eq sales_order_type()) {
2011     my $lr = $self->order->linked_records(direction => 'to', to => ['Invoice']);
2012     $has_invoice_for_advance_payment = any {'SL::DB::Invoice' eq ref $_ && "invoice_for_advance_payment" eq $_->type} @$lr;
2013   }
2014
2015   my $has_final_invoice;
2016   if ($self->order->id && $self->type eq sales_order_type()) {
2017     my $lr = $self->order->linked_records(direction => 'to', to => ['Invoice']);
2018     $has_final_invoice               = any {'SL::DB::Invoice' eq ref $_ && "final_invoice" eq $_->type} @$lr;
2019   }
2020
2021   for my $bar ($::request->layout->get('actionbar')) {
2022     $bar->add(
2023       combobox => [
2024         action => [
2025           t8('Save'),
2026           call      => [ 'kivi.Order.save', 'save', $::instance_conf->get_order_warn_duplicate_parts,
2027                                                     $::instance_conf->get_order_warn_no_deliverydate,
2028           ],
2029           checks    => [ 'kivi.Order.check_save_active_periodic_invoices', ['kivi.validate_form','#order_form'],
2030                          @req_trans_cost_art, @req_cusordnumber,
2031           ],
2032         ],
2033         action => [
2034           t8('Save as new'),
2035           call      => [ 'kivi.Order.save', 'save_as_new', $::instance_conf->get_order_warn_duplicate_parts ],
2036           checks    => [ 'kivi.Order.check_save_active_periodic_invoices',
2037                          @req_trans_cost_art, @req_cusordnumber,
2038           ],
2039           disabled  => !$self->order->id ? t8('This object has not been saved yet.') : undef,
2040         ],
2041       ], # end of combobox "Save"
2042
2043       combobox => [
2044         action => [
2045           t8('Workflow'),
2046         ],
2047         action => [
2048           t8('Save and Quotation'),
2049           submit   => [ '#order_form', { action => "Order/sales_quotation" } ],
2050           checks   => [ @req_trans_cost_art, @req_cusordnumber ],
2051           only_if  => (any { $self->type eq $_ } (sales_order_type())),
2052         ],
2053         action => [
2054           t8('Save and RFQ'),
2055           submit   => [ '#order_form', { action => "Order/request_for_quotation" } ],
2056           only_if  => (any { $self->type eq $_ } (purchase_order_type())),
2057         ],
2058         action => [
2059           t8('Save and Sales Order'),
2060           submit   => [ '#order_form', { action => "Order/sales_order" } ],
2061           checks   => [ @req_trans_cost_art ],
2062           only_if  => (any { $self->type eq $_ } (sales_quotation_type(), purchase_order_type())),
2063         ],
2064         action => [
2065           t8('Save and Purchase Order'),
2066           call      => [ 'kivi.Order.purchase_order_check_for_direct_delivery' ],
2067           checks    => [ @req_trans_cost_art, @req_cusordnumber ],
2068           only_if   => (any { $self->type eq $_ } (sales_order_type(), request_quotation_type())),
2069         ],
2070         action => [
2071           t8('Save and Delivery Order'),
2072           call      => [ 'kivi.Order.save', 'save_and_delivery_order', $::instance_conf->get_order_warn_duplicate_parts,
2073                                                                        $::instance_conf->get_order_warn_no_deliverydate,
2074                                                                                                                         ],
2075           checks    => [ 'kivi.Order.check_save_active_periodic_invoices',
2076                          @req_trans_cost_art, @req_cusordnumber,
2077           ],
2078           only_if   => (any { $self->type eq $_ } (sales_order_type(), purchase_order_type()))
2079         ],
2080         action => [
2081           t8('Save and Supplier Delivery Order'),
2082           call      => [ 'kivi.Order.save', 'save_and_supplier_delivery_order', $::instance_conf->get_order_warn_duplicate_parts,
2083                                                                        $::instance_conf->get_order_warn_no_deliverydate,
2084                                                                                                                         ],
2085           checks    => [ 'kivi.Order.check_save_active_periodic_invoices',
2086                          @req_trans_cost_art, @req_cusordnumber,
2087           ],
2088           only_if   => (any { $self->type eq $_ } (purchase_order_type()))
2089         ],
2090         action => [
2091           t8('Save and Invoice'),
2092           call      => [ 'kivi.Order.save', 'save_and_invoice', $::instance_conf->get_order_warn_duplicate_parts ],
2093           checks    => [ 'kivi.Order.check_save_active_periodic_invoices',
2094                          @req_trans_cost_art, @req_cusordnumber,
2095           ],
2096         ],
2097         action => [
2098           ($has_invoice_for_advance_payment ? t8('Save and Further Invoice for Advance Payment') : t8('Save and Invoice for Advance Payment')),
2099           call      => [ 'kivi.Order.save', 'save_and_invoice_for_advance_payment', $::instance_conf->get_order_warn_duplicate_parts ],
2100           checks    => [ 'kivi.Order.check_save_active_periodic_invoices',
2101                          @req_trans_cost_art, @req_cusordnumber,
2102           ],
2103           disabled  => $has_final_invoice ? t8('This order has already a final invoice.')
2104                                           : undef,
2105           only_if   => (any { $self->type eq $_ } (sales_order_type())),
2106         ],
2107         action => [
2108           t8('Save and Final Invoice'),
2109           call      => [ 'kivi.Order.save', 'save_and_final_invoice', $::instance_conf->get_order_warn_duplicate_parts ],
2110           checks    => [ 'kivi.Order.check_save_active_periodic_invoices',
2111                          @req_trans_cost_art, @req_cusordnumber,
2112           ],
2113           disabled  => $has_final_invoice ? t8('This order has already a final invoice.')
2114                                           : undef,
2115           only_if   => (any { $self->type eq $_ } (sales_order_type())) && $has_invoice_for_advance_payment,
2116         ],
2117         action => [
2118           t8('Save and AP Transaction'),
2119           call      => [ 'kivi.Order.save', 'save_and_ap_transaction', $::instance_conf->get_order_warn_duplicate_parts ],
2120           only_if   => (any { $self->type eq $_ } (purchase_order_type()))
2121         ],
2122
2123       ], # end of combobox "Workflow"
2124
2125       combobox => [
2126         action => [
2127           t8('Export'),
2128         ],
2129         action => [
2130           t8('Save and preview PDF'),
2131           call   => [ 'kivi.Order.save', 'preview_pdf', $::instance_conf->get_order_warn_duplicate_parts,
2132                                                         $::instance_conf->get_order_warn_no_deliverydate,
2133                     ],
2134           checks => [ @req_trans_cost_art, @req_cusordnumber ],
2135         ],
2136         action => [
2137           t8('Save and print'),
2138           call   => [ 'kivi.Order.show_print_options', $::instance_conf->get_order_warn_duplicate_parts,
2139                                                        $::instance_conf->get_order_warn_no_deliverydate,
2140                     ],
2141           checks => [ @req_trans_cost_art, @req_cusordnumber ],
2142         ],
2143         action => [
2144           t8('Save and E-mail'),
2145           id   => 'save_and_email_action',
2146           call => [ 'kivi.Order.save', 'save_and_show_email_dialog', $::instance_conf->get_order_warn_duplicate_parts,
2147                                                                      $::instance_conf->get_order_warn_no_deliverydate,
2148                   ],
2149           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
2150         ],
2151         action => [
2152           t8('Download attachments of all parts'),
2153           call     => [ 'kivi.File.downloadOrderitemsFiles', $::form->{type}, $::form->{id} ],
2154           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
2155           only_if  => $::instance_conf->get_doc_storage,
2156         ],
2157       ], # end of combobox "Export"
2158
2159       action => [
2160         t8('Delete'),
2161         call     => [ 'kivi.Order.delete_order' ],
2162         confirm  => $::locale->text('Do you really want to delete this object?'),
2163         disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
2164         only_if  => $deletion_allowed,
2165       ],
2166
2167       combobox => [
2168         action => [
2169           t8('more')
2170         ],
2171         action => [
2172           t8('History'),
2173           call     => [ 'set_history_window', $self->order->id, 'id' ],
2174           disabled => !$self->order->id ? t8('This record has not been saved yet.') : undef,
2175         ],
2176         action => [
2177           t8('Follow-Up'),
2178           call     => [ 'kivi.Order.follow_up_window' ],
2179           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
2180           only_if  => $::auth->assert('productivity', 1),
2181         ],
2182       ], # end of combobox "more"
2183     );
2184   }
2185 }
2186
2187 sub generate_doc {
2188   my ($self, $doc_ref, $params) = @_;
2189
2190   my $order  = $self->order;
2191   my @errors = ();
2192
2193   my $print_form = Form->new('');
2194   $print_form->{type}        = $order->type;
2195   $print_form->{formname}    = $params->{formname} || $order->type;
2196   $print_form->{format}      = $params->{format}   || 'pdf';
2197   $print_form->{media}       = $params->{media}    || 'file';
2198   $print_form->{groupitems}  = $params->{groupitems};
2199   $print_form->{printer_id}  = $params->{printer_id};
2200   $print_form->{media}       = 'file'                             if $print_form->{media} eq 'screen';
2201
2202   $order->language($params->{language});
2203   $order->flatten_to_form($print_form, format_amounts => 1);
2204
2205   my $template_ext;
2206   my $template_type;
2207   if ($print_form->{format} =~ /(opendocument|oasis)/i) {
2208     $template_ext  = 'odt';
2209     $template_type = 'OpenDocument';
2210   } elsif ($print_form->{format} =~ m{html}i) {
2211     $template_ext  = 'html';
2212     $template_type = 'HTML';
2213   }
2214
2215   # search for the template
2216   my ($template_file, @template_files) = SL::Helper::CreatePDF->find_template(
2217     name        => $print_form->{formname},
2218     extension   => $template_ext,
2219     email       => $print_form->{media} eq 'email',
2220     language    => $params->{language},
2221     printer_id  => $print_form->{printer_id},
2222   );
2223
2224   if (!defined $template_file) {
2225     push @errors, $::locale->text('Cannot find matching template for this print request. Please contact your template maintainer. I tried these: #1.', join ', ', map { "'$_'"} @template_files);
2226   }
2227
2228   return @errors if scalar @errors;
2229
2230   $print_form->throw_on_error(sub {
2231     eval {
2232       $print_form->prepare_for_printing;
2233
2234       $$doc_ref = SL::Helper::CreatePDF->create_pdf(
2235         format        => $print_form->{format},
2236         template_type => $template_type,
2237         template      => $template_file,
2238         variables     => $print_form,
2239         variable_content_types => {
2240           longdescription => 'html',
2241           partnotes       => 'html',
2242           notes           => 'html',
2243           $::form->get_variable_content_types_for_cvars,
2244         },
2245       );
2246       1;
2247     } || push @errors, ref($EVAL_ERROR) eq 'SL::X::FormError' ? $EVAL_ERROR->error : $EVAL_ERROR;
2248   });
2249
2250   return @errors;
2251 }
2252
2253 sub get_files_for_email_dialog {
2254   my ($self) = @_;
2255
2256   my %files = map { ($_ => []) } qw(versions files vc_files part_files);
2257
2258   return %files if !$::instance_conf->get_doc_storage;
2259
2260   if ($self->order->id) {
2261     $files{versions} = [ SL::File->get_all_versions(object_id => $self->order->id,              object_type => $self->order->type, file_type => 'document') ];
2262     $files{files}    = [ SL::File->get_all(         object_id => $self->order->id,              object_type => $self->order->type, file_type => 'attachment') ];
2263     $files{vc_files} = [ SL::File->get_all(         object_id => $self->order->{$self->cv}->id, object_type => $self->cv,          file_type => 'attachment') ];
2264     $files{project_files} = [ SL::File->get_all(    object_id => $self->order->globalproject_id, object_type => 'project',         file_type => 'attachment') ];
2265   }
2266
2267   my @parts =
2268     uniq_by { $_->{id} }
2269     map {
2270       +{ id         => $_->part->id,
2271          partnumber => $_->part->partnumber }
2272     } @{$self->order->items_sorted};
2273
2274   foreach my $part (@parts) {
2275     my @pfiles = SL::File->get_all(object_id => $part->{id}, object_type => 'part');
2276     push @{ $files{part_files} }, map { +{ %{ $_ }, partnumber => $part->{partnumber} } } @pfiles;
2277   }
2278
2279   foreach my $key (keys %files) {
2280     $files{$key} = [ sort_by { lc $_->{db_file}->{file_name} } @{ $files{$key} } ];
2281   }
2282
2283   return %files;
2284 }
2285
2286 sub make_periodic_invoices_config_from_yaml {
2287   my ($yaml_config) = @_;
2288
2289   return if !$yaml_config;
2290   my $attr = SL::YAML::Load($yaml_config);
2291   return if 'HASH' ne ref $attr;
2292   return SL::DB::PeriodicInvoicesConfig->new(%$attr);
2293 }
2294
2295
2296 sub get_periodic_invoices_status {
2297   my ($self, $config) = @_;
2298
2299   return                      if $self->type ne sales_order_type();
2300   return t8('not configured') if !$config;
2301
2302   my $active = ('HASH' eq ref $config)                           ? $config->{active}
2303              : ('SL::DB::PeriodicInvoicesConfig' eq ref $config) ? $config->active
2304              :                                                     die "Cannot get status of periodic invoices config";
2305
2306   return $active ? t8('active') : t8('inactive');
2307 }
2308
2309 sub get_title_for {
2310   my ($self, $action) = @_;
2311
2312   return '' if none { lc($action)} qw(add edit);
2313
2314   # for locales:
2315   # $::locale->text("Add Sales Order");
2316   # $::locale->text("Add Purchase Order");
2317   # $::locale->text("Add Quotation");
2318   # $::locale->text("Add Request for Quotation");
2319   # $::locale->text("Edit Sales Order");
2320   # $::locale->text("Edit Purchase Order");
2321   # $::locale->text("Edit Quotation");
2322   # $::locale->text("Edit Request for Quotation");
2323
2324   $action = ucfirst(lc($action));
2325   return $self->type eq sales_order_type()       ? $::locale->text("$action Sales Order")
2326        : $self->type eq purchase_order_type()    ? $::locale->text("$action Purchase Order")
2327        : $self->type eq sales_quotation_type()   ? $::locale->text("$action Quotation")
2328        : $self->type eq request_quotation_type() ? $::locale->text("$action Request for Quotation")
2329        : '';
2330 }
2331
2332 sub get_item_cvpartnumber {
2333   my ($self, $item) = @_;
2334
2335   return if !$self->search_cvpartnumber;
2336   return if !$self->order->customervendor;
2337
2338   if ($self->cv eq 'vendor') {
2339     my @mms = grep { $_->make eq $self->order->customervendor->id } @{$item->part->makemodels};
2340     $item->{cvpartnumber} = $mms[0]->model if scalar @mms;
2341   } elsif ($self->cv eq 'customer') {
2342     my @cps = grep { $_->customer_id eq $self->order->customervendor->id } @{$item->part->customerprices};
2343     $item->{cvpartnumber} = $cps[0]->customer_partnumber if scalar @cps;
2344   }
2345 }
2346
2347 sub get_part_texts {
2348   my ($part_or_id, $language_or_id, %defaults) = @_;
2349
2350   my $part        = ref($part_or_id)     ? $part_or_id         : SL::DB::Part->load_cached($part_or_id);
2351   my $language_id = ref($language_or_id) ? $language_or_id->id : $language_or_id;
2352   my $texts       = {
2353     description     => $defaults{description}     // $part->description,
2354     longdescription => $defaults{longdescription} // $part->notes,
2355   };
2356
2357   return $texts unless $language_id;
2358
2359   my $translation = SL::DB::Manager::Translation->get_first(
2360     where => [
2361       parts_id    => $part->id,
2362       language_id => $language_id,
2363     ]);
2364
2365   $texts->{description}     = $translation->translation     if $translation && $translation->translation;
2366   $texts->{longdescription} = $translation->longdescription if $translation && $translation->longdescription;
2367
2368   return $texts;
2369 }
2370
2371 sub sales_order_type {
2372   'sales_order';
2373 }
2374
2375 sub purchase_order_type {
2376   'purchase_order';
2377 }
2378
2379 sub sales_quotation_type {
2380   'sales_quotation';
2381 }
2382
2383 sub request_quotation_type {
2384   'request_quotation';
2385 }
2386
2387 sub nr_key {
2388   return $_[0]->type eq sales_order_type()       ? 'ordnumber'
2389        : $_[0]->type eq purchase_order_type()    ? 'ordnumber'
2390        : $_[0]->type eq sales_quotation_type()   ? 'quonumber'
2391        : $_[0]->type eq request_quotation_type() ? 'quonumber'
2392        : '';
2393 }
2394
2395 sub save_and_redirect_to {
2396   my ($self, %params) = @_;
2397
2398   my $errors = $self->save();
2399
2400   if (scalar @{ $errors }) {
2401     $self->js->flash('error', $_) foreach @{ $errors };
2402     return $self->js->render();
2403   }
2404
2405   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
2406            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
2407            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
2408            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
2409            : '';
2410   flash_later('info', $text);
2411
2412   $self->redirect_to(%params, id => $self->order->id);
2413 }
2414
2415 sub save_history {
2416   my ($self, $addition) = @_;
2417
2418   my $number_type = $self->order->type =~ m{order} ? 'ordnumber' : 'quonumber';
2419   my $snumbers    = $number_type . '_' . $self->order->$number_type;
2420
2421   SL::DB::History->new(
2422     trans_id    => $self->order->id,
2423     employee_id => SL::DB::Manager::Employee->current->id,
2424     what_done   => $self->order->type,
2425     snumbers    => $snumbers,
2426     addition    => $addition,
2427   )->save;
2428 }
2429
2430 sub store_doc_to_webdav_and_filemanagement {
2431   my ($self, $content, $filename, $variant) = @_;
2432
2433   my $order = $self->order;
2434   my @errors;
2435
2436   # copy file to webdav folder
2437   if ($order->number && $::instance_conf->get_webdav_documents) {
2438     my $webdav = SL::Webdav->new(
2439       type     => $order->type,
2440       number   => $order->number,
2441     );
2442     my $webdav_file = SL::Webdav::File->new(
2443       webdav   => $webdav,
2444       filename => $filename,
2445     );
2446     eval {
2447       $webdav_file->store(data => \$content);
2448       1;
2449     } or do {
2450       push @errors, t8('Storing the document to the WebDAV folder failed: #1', $@);
2451     };
2452   }
2453   if ($order->id && $::instance_conf->get_doc_storage) {
2454     eval {
2455       SL::File->save(object_id     => $order->id,
2456                      object_type   => $order->type,
2457                      mime_type     => SL::MIME->mime_type_from_ext($filename),
2458                      source        => 'created',
2459                      file_type     => 'document',
2460                      file_name     => $filename,
2461                      file_contents => $content,
2462                      print_variant => $variant);
2463       1;
2464     } or do {
2465       push @errors, t8('Storing the document in the storage backend failed: #1', $@);
2466     };
2467   }
2468
2469   return @errors;
2470 }
2471
2472 sub link_requirement_specs_linking_to_created_from_objects {
2473   my ($self, @converted_from_oe_ids) = @_;
2474
2475   return unless @converted_from_oe_ids;
2476
2477   my $rs_orders = SL::DB::Manager::RequirementSpecOrder->get_all(where => [ order_id => \@converted_from_oe_ids ]);
2478   foreach my $rs_order (@{ $rs_orders }) {
2479     SL::DB::RequirementSpecOrder->new(
2480       order_id            => $self->order->id,
2481       requirement_spec_id => $rs_order->requirement_spec_id,
2482       version_id          => $rs_order->version_id,
2483     )->save;
2484   }
2485 }
2486
2487 sub set_project_in_linked_requirement_specs {
2488   my ($self) = @_;
2489
2490   my $rs_orders = SL::DB::Manager::RequirementSpecOrder->get_all(where => [ order_id => $self->order->id ]);
2491   foreach my $rs_order (@{ $rs_orders }) {
2492     next if $rs_order->requirement_spec->project_id == $self->order->globalproject_id;
2493
2494     $rs_order->requirement_spec->update_attributes(project_id => $self->order->globalproject_id);
2495   }
2496 }
2497
2498 1;
2499
2500 __END__
2501
2502 =encoding utf-8
2503
2504 =head1 NAME
2505
2506 SL::Controller::Order - controller for orders
2507
2508 =head1 SYNOPSIS
2509
2510 This is a new form to enter orders, completely rewritten with the use
2511 of controller and java script techniques.
2512
2513 The aim is to provide the user a better experience and a faster workflow. Also
2514 the code should be more readable, more reliable and better to maintain.
2515
2516 =head2 Key Features
2517
2518 =over 4
2519
2520 =item *
2521
2522 One input row, so that input happens every time at the same place.
2523
2524 =item *
2525
2526 Use of pickers where possible.
2527
2528 =item *
2529
2530 Possibility to enter more than one item at once.
2531
2532 =item *
2533
2534 Item list in a scrollable area, so that the workflow buttons stay at
2535 the bottom.
2536
2537 =item *
2538
2539 Reordering item rows with drag and drop is possible. Sorting item rows is
2540 possible (by partnumber, description, qty, sellprice and discount for now).
2541
2542 =item *
2543
2544 No C<update> is necessary. All entries and calculations are managed
2545 with ajax-calls and the page only reloads on C<save>.
2546
2547 =item *
2548
2549 User can see changes immediately, because of the use of java script
2550 and ajax.
2551
2552 =back
2553
2554 =head1 CODE
2555
2556 =head2 Layout
2557
2558 =over 4
2559
2560 =item * C<SL/Controller/Order.pm>
2561
2562 the controller
2563
2564 =item * C<template/webpages/order/form.html>
2565
2566 main form
2567
2568 =item * C<template/webpages/order/tabs/basic_data.html>
2569
2570 Main tab for basic_data.
2571
2572 This is the only tab here for now. "linked records" and "webdav" tabs are
2573 reused from generic code.
2574
2575 =over 4
2576
2577 =item * C<template/webpages/order/tabs/_business_info_row.html>
2578
2579 For displaying information on business type
2580
2581 =item * C<template/webpages/order/tabs/_item_input.html>
2582
2583 The input line for items
2584
2585 =item * C<template/webpages/order/tabs/_row.html>
2586
2587 One row for already entered items
2588
2589 =item * C<template/webpages/order/tabs/_tax_row.html>
2590
2591 Displaying tax information
2592
2593 =item * C<template/webpages/order/tabs/_price_sources_dialog.html>
2594
2595 Dialog for selecting price and discount sources
2596
2597 =back
2598
2599 =item * C<js/kivi.Order.js>
2600
2601 java script functions
2602
2603 =back
2604
2605 =head1 TODO
2606
2607 =over 4
2608
2609 =item * testing
2610
2611 =item * price sources: little symbols showing better price / better discount
2612
2613 =item * select units in input row?
2614
2615 =item * check for direct delivery (workflow sales order -> purchase order)
2616
2617 =item * access rights
2618
2619 =item * display weights
2620
2621 =item * mtime check
2622
2623 =item * optional client/user behaviour
2624
2625 (transactions has to be set - department has to be set -
2626  force project if enabled in client config)
2627
2628 =back
2629
2630 =head1 KNOWN BUGS AND CAVEATS
2631
2632 =over 4
2633
2634 =item *
2635
2636 Customer discount is not displayed as a valid discount in price source popup
2637 (this might be a bug in price sources)
2638
2639 (I cannot reproduce this (Bernd))
2640
2641 =item *
2642
2643 No indication that <shift>-up/down expands/collapses second row.
2644
2645 =item *
2646
2647 Inline creation of parts is not currently supported
2648
2649 =item *
2650
2651 Table header is not sticky in the scrolling area.
2652
2653 =item *
2654
2655 Sorting does not include C<position>, neither does reordering.
2656
2657 This behavior was implemented intentionally. But we can discuss, which behavior
2658 should be implemented.
2659
2660 =back
2661
2662 =head1 To discuss / Nice to have
2663
2664 =over 4
2665
2666 =item *
2667
2668 How to expand/collapse second row. Now it can be done clicking the icon or
2669 <shift>-up/down.
2670
2671 =item *
2672
2673 Possibility to select PriceSources in input row?
2674
2675 =item *
2676
2677 This controller uses a (changed) copy of the template for the PriceSource
2678 dialog. Maybe there could be used one code source.
2679
2680 =item *
2681
2682 Rounding-differences between this controller (PriceTaxCalculator) and the old
2683 form. This is not only a problem here, but also in all parts using the PTC.
2684 There exists a ticket and a patch. This patch should be testet.
2685
2686 =item *
2687
2688 An indicator, if the actual inputs are saved (like in an
2689 editor or on text processing application).
2690
2691 =item *
2692
2693 A warning when leaving the page without saveing unchanged inputs.
2694
2695
2696 =back
2697
2698 =head1 AUTHOR
2699
2700 Bernd Bleßmann E<lt>bernd@kivitendo-premium.deE<gt>
2701
2702 =cut