SL/Controller/Order.pm

   1 package SL::Controller::Order;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use SL::Helper::Flash;
   7 use SL::ClientJS;
   8 use SL::Presenter;
   9
  10 use SL::DB::Order;
  11 use SL::DB::Customer;
  12 use SL::DB::Vendor;
  13 use SL::DB::TaxZone;
  14 use SL::DB::Employee;
  15 use SL::DB::Project;
  16 use SL::DB::Default;
  17 use SL::DB::Unit;
  18
  19 use SL::Helper::DateTime;
  20
  21 use List::Util qw(max first);
  22 use List::MoreUtils qw(none pairwise);
  23
  24 use Rose::Object::MakeMethods::Generic
  25 (
  26  'scalar --get_set_init' => [ qw(order valid_types type cv js p) ],
  27 );
  28
  29
  30 # safety
  31 __PACKAGE__->run_before('_check_auth');
  32
  33 __PACKAGE__->run_before('_recalc',
  34                         only => [ qw(edit update save) ]);
  35
  36
  37 #
  38 # actions
  39 #
  40
  41 sub action_add {
  42   my ($self) = @_;
  43
  44   $self->order->transdate(DateTime->now_local());
  45
  46   $self->_pre_render();
  47   $self->render(
  48     'order/form',
  49     title => $self->type eq _sales_order_type()    ? $::locale->text('Add Sales Order')
  50            : $self->type eq _purchase_order_type() ? $::locale->text('Add Purchase Order')
  51            : '',
  52     %{$self->{template_args}}
  53   );
  54 }
  55
  56 sub action_edit {
  57   my ($self) = @_;
  58
  59   $self->_pre_render();
  60   $self->render(
  61     'order/form',
  62     title => $self->type eq _sales_order_type()    ? $::locale->text('Edit Sales Order')
  63            : $self->type eq _purchase_order_type() ? $::locale->text('Edit Purchase Order')
  64            : '',
  65     %{$self->{template_args}}
  66   );
  67 }
  68
  69 sub action_update {
  70   my ($self) = @_;
  71
  72   $self->_pre_render();
  73   $self->render(
  74     'order/form',
  75     title => $self->type eq _sales_order_type()    ? $::locale->text('Edit Sales Order')
  76            : $self->type eq _purchase_order_type() ? $::locale->text('Edit Purchase Order')
  77            : '',
  78     %{$self->{template_args}}
  79   );
  80 }
  81
  82 sub action_save {
  83   my ($self) = @_;
  84
  85   $self->_save();
  86
  87   my @redirect_params = (
  88     action => 'edit',
  89     type   => $self->type,
  90     id     => $self->order->id,
  91   );
  92
  93   $self->redirect_to(@redirect_params);
  94 }
  95
  96 sub action_customer_vendor_changed {
  97   my ($self) = @_;
  98
  99   if ($self->cv eq 'customer') {
 100     $self->order->customer(SL::DB::Manager::Customer->find_by_or_create(id => $::form->{cv_id}));
 101
 102   } elsif ($self->cv eq 'vendor') {
 103     $self->order->vendor(SL::DB::Manager::Vendor->find_by_or_create(id => $::form->{cv_id}));
 104   }
 105
 106   if ($self->order->{$self->cv}->contacts && scalar @{ $self->order->{$self->cv}->contacts } > 0) {
 107     $self->js->show('#cp_row');
 108   } else {
 109     $self->js->hide('#cp_row');
 110   }
 111
 112   if ($self->order->{$self->cv}->shipto && scalar @{ $self->order->{$self->cv}->shipto } > 0) {
 113     $self->js->show('#shipto_row');
 114   } else {
 115     $self->js->hide('#shipto_row');
 116   }
 117
 118   $self->js
 119     ->replaceWith('#order_cp_id',     $self->build_contact_select)
 120     ->replaceWith('#order_shipto_id', $self->build_shipto_select)
 121     ->val('#order_taxzone_id', $self->order->{$self->cv}->taxzone_id)
 122     ->focus('#order_' . $self->cv . ' _id')
 123     ->render($self);
 124 }
 125
 126 sub action_add_item {
 127   my ($self) = @_;
 128
 129   my $form_attr = $::form->{add_item};
 130   my $item      = SL::DB::OrderItem->new;
 131   $item->assign_attributes(%$form_attr);
 132
 133   my $part        = SL::DB::Part->new(id => $form_attr->{parts_id})->load;
 134   my $cv_class    = "SL::DB::" . ucfirst($self->cv);
 135   my $cv_discount = $::form->{$self->cv . '_id'}? $cv_class->new(id => $::form->{$self->cv . '_id'})->load->discount :0.0;
 136
 137   my %new_attr;
 138   $new_attr{id}        = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 139   $new_attr{part}      = $part;
 140   $new_attr{qty}       = 1.0               if ! $item->{qty};
 141   $new_attr{unit}      = $part->unit;
 142   $new_attr{sellprice} = $part->sellprice  if ! $item->{sellprice};
 143   $new_attr{discount}  = $cv_discount      if ! $item->{discount};
 144   $item->assign_attributes(%new_attr);
 145
 146   $self->order->add_items($item);
 147
 148   $self->_recalc();
 149
 150   my $row_as_html = $self->p->render('order/tabs/_row', ITEM => $item);
 151
 152   $self->js
 153     ->append('#row_table_id tbody', $row_as_html)
 154     ->val('#add_item_parts_id', '')
 155     ->val('#add_item_parts_id_name', '')
 156     ->val('#add_item_description', '')
 157     ->val('#add_item_qty_as_number', '')
 158     ->val('#add_item_sellprice_as_number', '')
 159     ->val('#add_item_discount_as_percent', '')
 160     ->run('row_table_scroll_down')
 161     ->focus('#add_item_parts_id_name');
 162
 163   $self->_js_redisplay_amounts_and_taxes;
 164   $self->js->render($self);
 165 }
 166
 167 sub action_recalc_amounts_and_taxes {
 168   my ($self) = @_;
 169
 170   $self->_recalc();
 171
 172   $self->_js_redisplay_amounts_and_taxes;
 173   $self->js->render($self);
 174 }
 175
 176 sub _js_redisplay_amounts_and_taxes {
 177   my ($self) = @_;
 178
 179   $self->js
 180     ->html('#netamount_id', $::form->format_amount(\%::myconfig, $self->order->netamount, -2))
 181     ->html('#amount_id',    $::form->format_amount(\%::myconfig, $self->order->amount,    -2))
 182     ->remove('.tax_row')
 183     ->insertBefore($self->build_tax_rows, '#amount_row_id');
 184 }
 185
 186 #
 187 # helpers
 188 #
 189
 190 sub init_valid_types {
 191   [ _sales_order_type(), _purchase_order_type() ];
 192 }
 193
 194 sub init_type {
 195   my ($self) = @_;
 196
 197   if (none { $::form->{type} eq $_ } @{$self->valid_types}) {
 198     die "Not a valid type for order";
 199   }
 200
 201   $self->type($::form->{type});
 202 }
 203
 204 sub init_cv {
 205   my ($self) = @_;
 206
 207   my $cv = $self->type eq _sales_order_type()    ? 'customer'
 208          : $self->type eq _purchase_order_type() ? 'vendor'
 209          : die "Not a valid type for order";
 210
 211   return $cv;
 212 }
 213
 214 sub init_js {
 215   SL::ClientJS->new;
 216 }
 217
 218 sub init_p {
 219   SL::Presenter->get;
 220 }
 221
 222 sub init_order {
 223   _make_order();
 224 }
 225
 226 sub _check_auth {
 227   my ($self) = @_;
 228
 229   my $right_for = { map { $_ => $_.'_edit' } @{$self->valid_types} };
 230
 231   my $right   = $right_for->{ $self->type };
 232   $right    ||= 'DOES_NOT_EXIST';
 233
 234   $::auth->assert($right);
 235 }
 236
 237 sub build_contact_select {
 238   my ($self) = @_;
 239
 240   $self->p->select_tag('order.cp_id', [ $self->order->{$self->cv}->contacts ],
 241                        value_key  => 'cp_id',
 242                        title_key  => 'full_name_dep',
 243                        default    => $self->order->cp_id,
 244                        with_empty => 1,
 245                        style      => 'width: 300px',
 246   );
 247 }
 248
 249 sub build_shipto_select {
 250   my ($self) = @_;
 251
 252   $self->p->select_tag('order.shipto_id', [ $self->order->{$self->cv}->shipto ],
 253                        value_key  => 'shipto_id',
 254                        title_key  => 'displayable_id',
 255                        default    => $self->order->shipto_id,
 256                        with_empty => 1,
 257                        style      => 'width: 300px',
 258   );
 259 }
 260
 261 sub build_tax_rows {
 262   my ($self) = @_;
 263
 264   my $rows_as_html;
 265   foreach my $tax (@{ $self->{taxes} }) {
 266     $rows_as_html .= $self->p->render('order/tabs/_tax_row', TAX => $tax);
 267   }
 268   return $rows_as_html;
 269 }
 270
 271
 272 sub _make_order {
 273   my ($self) = @_;
 274
 275   # add_items adds items to an order with no items for saving, but they cannot
 276   # be retrieved via items until the order is saved. Adding empty items to new
 277   # order here solves this problem.
 278   my $order;
 279   $order   = SL::DB::Manager::Order->find_by(id => $::form->{id}) if $::form->{id};
 280   $order ||= SL::DB::Order->new(orderitems => []);
 281
 282   $order->assign_attributes(%{$::form->{order}});
 283
 284   return $order;
 285 }
 286
 287
 288 sub _recalc {
 289   my ($self) = @_;
 290
 291   # bb: todo: currency later
 292   $self->order->currency_id($::instance_conf->get_currency_id());
 293
 294   my %pat = $self->order->calculate_prices_and_taxes();
 295
 296   foreach my $tax_chart_id (keys %{ $pat{taxes} }) {
 297     my $tax = SL::DB::Manager::Tax->find_by(chart_id => $tax_chart_id);
 298     push(@{ $self->{taxes} }, { amount => $pat{taxes}->{$tax_chart_id},
 299                                 tax    => $tax });
 300   }
 301
 302   pairwise { $a->{linetotal} = $b->{linetotal} } @{$self->order->items}, @{$pat{items}};
 303 }
 304
 305 sub _save {
 306   my ($self) = @_;
 307
 308   my $db = $self->order->db;
 309
 310   $db->do_transaction(
 311     sub {
 312       $self->order->save();
 313   }) || die($db->error);
 314 }
 315
 316
 317 sub _pre_render {
 318   my ($self) = @_;
 319
 320   $self->{all_taxzones}  = SL::DB::Manager::TaxZone->get_all_sorted();
 321   $self->{all_employees} = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->employee_id,
 322                                                                                  deleted => 0 ] ],
 323                                                               sort_by => 'name');
 324   $self->{all_projects}  = SL::DB::Manager::Project->get_all(where => [ or => [ id => $self->order->globalproject_id,
 325                                                                                 active => 1 ] ],
 326                                                              sort_by => 'projectnumber');
 327
 328   $self->{current_employee_id} = SL::DB::Manager::Employee->current->id;
 329 }
 330
 331 sub _sales_order_type {
 332   'sales_order';
 333 }
 334
 335 sub _purchase_order_type {
 336   'purchase_order';
 337 }
 338
 339 1;