SL/Controller/Order.pm

   1 package SL::Controller::Order;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use SL::Helper::Flash;
   7 use SL::Presenter;
   8 use SL::Locale::String;
   9 use SL::SessionFile::Random;
  10 use SL::PriceSource;
  11 use SL::Form;
  12 use SL::Webdav;
  13 use SL::Template;
  14
  15 use SL::DB::Order;
  16 use SL::DB::Customer;
  17 use SL::DB::Vendor;
  18 use SL::DB::TaxZone;
  19 use SL::DB::Employee;
  20 use SL::DB::Project;
  21 use SL::DB::Default;
  22 use SL::DB::Unit;
  23 use SL::DB::Price;
  24 use SL::DB::PriceFactor;
  25 use SL::DB::Part;
  26 use SL::DB::Printer;
  27 use SL::DB::Language;
  28
  29 use SL::Helper::DateTime;
  30 use SL::Helper::CreatePDF qw(:all);
  31 use SL::Helper::PrintOptions;
  32
  33 use SL::Controller::Helper::GetModels;
  34
  35 use List::Util qw(max first);
  36 use List::MoreUtils qw(none pairwise first_index);
  37 use English qw(-no_match_vars);
  38 use File::Spec;
  39
  40 use Rose::Object::MakeMethods::Generic
  41 (
  42  scalar => [ qw(item_ids_to_delete) ],
  43  'scalar --get_set_init' => [ qw(order valid_types type cv p multi_items_models all_price_factors) ],
  44 );
  45
  46
  47 # safety
  48 __PACKAGE__->run_before('_check_auth');
  49
  50 __PACKAGE__->run_before('_recalc',
  51                         only => [ qw(update save save_and_delivery_order print create_pdf send_email) ]);
  52
  53 __PACKAGE__->run_before('_get_unalterable_data',
  54                         only => [ qw(save save_and_delivery_order print create_pdf send_email) ]);
  55
  56 #
  57 # actions
  58 #
  59
  60 sub action_add {
  61   my ($self) = @_;
  62
  63   $self->order->transdate(DateTime->now_local());
  64   $self->order->reqdate(DateTime->today_local->next_workday) if !$self->order->reqdate;
  65
  66   $self->_pre_render();
  67   $self->render(
  68     'order/form',
  69     title => $self->type eq _sales_order_type()    ? $::locale->text('Add Sales Order')
  70            : $self->type eq _purchase_order_type() ? $::locale->text('Add Purchase Order')
  71            : '',
  72     %{$self->{template_args}}
  73   );
  74 }
  75
  76 sub action_edit {
  77   my ($self) = @_;
  78
  79   $self->_load_order;
  80   $self->_recalc();
  81   $self->_pre_render();
  82   $self->render(
  83     'order/form',
  84     title => $self->type eq _sales_order_type()    ? $::locale->text('Edit Sales Order')
  85            : $self->type eq _purchase_order_type() ? $::locale->text('Edit Purchase Order')
  86            : '',
  87     %{$self->{template_args}}
  88   );
  89 }
  90
  91 sub action_update {
  92   my ($self) = @_;
  93
  94   $self->_pre_render();
  95   $self->render(
  96     'order/form',
  97     title => $self->type eq _sales_order_type()    ? $::locale->text('Edit Sales Order')
  98            : $self->type eq _purchase_order_type() ? $::locale->text('Edit Purchase Order')
  99            : '',
 100     %{$self->{template_args}}
 101   );
 102 }
 103
 104 sub action_delete {
 105   my ($self) = @_;
 106
 107   my $errors = $self->_delete();
 108
 109   if (scalar @{ $errors }) {
 110     $self->js->flash('error', $_) foreach @{ $errors };
 111     return $self->js->render();
 112   }
 113
 114   flash_later('info', $::locale->text('The order has been deleted'));
 115   my @redirect_params = (
 116     action => 'edit',
 117     type   => $self->type,
 118   );
 119
 120   $self->redirect_to(@redirect_params);
 121 }
 122
 123 sub action_save {
 124   my ($self) = @_;
 125
 126   my $errors = $self->_save();
 127
 128   if (scalar @{ $errors }) {
 129     $self->js->flash('error', $_) foreach @{ $errors };
 130     return $self->js->render();
 131   }
 132
 133   flash_later('info', $::locale->text('The order has been saved'));
 134   my @redirect_params = (
 135     action => 'edit',
 136     type   => $self->type,
 137     id     => $self->order->id,
 138   );
 139
 140   $self->redirect_to(@redirect_params);
 141 }
 142
 143 sub action_print {
 144   my ($self) = @_;
 145
 146   my $format      = $::form->{print_options}->{format};
 147   my $media       = $::form->{print_options}->{media};
 148   my $formname    = $::form->{print_options}->{formname};
 149   my $copies      = $::form->{print_options}->{copies};
 150   my $groupitems  = $::form->{print_options}->{groupitems};
 151
 152   # only pdf by now
 153   if (none { $format eq $_ } qw(pdf)) {
 154     return $self->js->flash('error', t8('Format \'#1\' is not supported yet/anymore.', $format))->render;
 155   }
 156
 157   # only screen or printer by now
 158   if (none { $media eq $_ } qw(screen printer)) {
 159     return $self->js->flash('error', t8('Media \'#1\' is not supported yet/anymore.', $media))->render;
 160   }
 161
 162   my $language;
 163   $language = SL::DB::Language->new(id => $::form->{print_options}->{language_id})->load if $::form->{print_options}->{language_id};
 164
 165   my $form = Form->new;
 166   $form->{ordnumber} = $self->order->ordnumber;
 167   $form->{type}      = $self->type;
 168   $form->{format}    = $format;
 169   $form->{formname}  = $formname;
 170   $form->{language}  = '_' . $language->template_code if $language;
 171   my $pdf_filename   = $form->generate_attachment_filename();
 172
 173   my $pdf;
 174   my @errors = _create_pdf($self->order, \$pdf, { format     => $format,
 175                                                   formname   => $formname,
 176                                                   language   => $language,
 177                                                   groupitems => $groupitems });
 178   if (scalar @errors) {
 179     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render;
 180   }
 181
 182   if ($media eq 'screen') {
 183     # screen/download
 184     my $sfile = SL::SessionFile::Random->new(mode => "w");
 185     $sfile->fh->print($pdf);
 186     $sfile->fh->close;
 187
 188     my $key = join('_', Time::HiRes::gettimeofday(), int rand 1000000000000);
 189     $::auth->set_session_value("Order::create_pdf-${key}" => $sfile->file_name);
 190
 191     $self->js
 192     ->run('download_pdf', $pdf_filename, $key)
 193     ->flash('info', t8('The PDF has been created'));
 194
 195   } elsif ($media eq 'printer') {
 196     # printer
 197     my $printer_id = $::form->{print_options}->{printer_id};
 198     my $printer;
 199     $printer = SL::DB::Printer->new(id => $printer_id)->load if $printer_id;
 200     if (!$printer) {
 201       return $self->js->flash('error', t8('Printer not found.'))->render;
 202     }
 203
 204     my $command = SL::Template::create(type => 'ShellCommand', form => Form->new(''))->parse($printer->printer_command);
 205
 206     for my $i (1 .. $copies) {
 207       open my $out, '|-', $command or die $!;
 208       binmode $out;
 209       print $out $pdf;
 210       close $out;
 211     }
 212
 213     $self->js->flash('info', t8('The PDF has been printed'));
 214   }
 215
 216   # copy file to webdav folder
 217   if ($self->order->ordnumber && $::instance_conf->get_webdav_documents) {
 218     my $webdav = SL::Webdav->new(
 219       type     => $self->type,
 220       number   => $self->order->ordnumber,
 221     );
 222     my $webdav_file = SL::Webdav::File->new(
 223       webdav   => $webdav,
 224       filename => $pdf_filename,
 225     );
 226     eval {
 227       $webdav_file->store(data => \$pdf);
 228       1;
 229     } or do {
 230       $self->js->flash('error', t8('Storing PDF to webdav folder failed: #1', $@));
 231     }
 232   }
 233
 234   $self->js->render;
 235 }
 236
 237 sub action_download_pdf {
 238   my ($self) = @_;
 239
 240   my $key = $::form->{key};
 241   my $tmp_filename = $::auth->get_session_value("Order::create_pdf-${key}");
 242   return $self->send_file(
 243     $tmp_filename,
 244     type => 'application/pdf',
 245     name => $::form->{pdf_filename},
 246   );
 247 }
 248
 249 sub action_show_email_dialog {
 250   my ($self) = @_;
 251
 252   my $cv_method = $self->cv;
 253
 254   if (!$self->order->$cv_method) {
 255     return $self->js->flash('error', $self->cv eq 'customer' ? t8('Cannot send E-mail without customer given') : t8('Cannot send E-mail without vendor given'))
 256                     ->render($self);
 257   }
 258
 259   $self->{email}->{to}   = $self->order->contact->cp_email if $self->order->contact;
 260   $self->{email}->{to} ||= $self->order->$cv_method->email;
 261   $self->{email}->{cc}   = $self->order->$cv_method->cc;
 262   $self->{email}->{bcc}  = join ', ', grep $_, $self->order->$cv_method->bcc, SL::DB::Default->get->global_bcc;
 263   # Todo: get addresses from shipto, if any
 264
 265   my $form = Form->new;
 266   $form->{ordnumber} = $self->order->ordnumber;
 267   $form->{formname}  = $self->type;
 268   $form->{type}      = $self->type;
 269   $form->{language} = 'de';
 270   $form->{format}   = 'pdf';
 271
 272   $self->{email}->{subject}             = $form->generate_email_subject();
 273   $self->{email}->{attachment_filename} = $form->generate_attachment_filename();
 274   $self->{email}->{message}             = $form->create_email_signature();
 275
 276   my $dialog_html = $self->render('order/tabs/_email_dialog', { output => 0 });
 277   $self->js
 278       ->run('show_email_dialog', $dialog_html)
 279       ->reinit_widgets
 280       ->render($self);
 281 }
 282
 283 # Todo: handling error messages: flash is not displayed in dialog, but in the main form
 284 sub action_send_email {
 285   my ($self) = @_;
 286
 287   my $mail      = Mailer->new;
 288   $mail->{from} = qq|"$::myconfig{name}" <$::myconfig{email}>|;
 289   $mail->{$_}   = $::form->{email}->{$_} for qw(to cc bcc subject message);
 290
 291   my $pdf;
 292   my @errors = _create_pdf($self->order, \$pdf, {media => 'email'});
 293   if (scalar @errors) {
 294     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render($self);
 295   }
 296
 297   $mail->{attachments} = [{ "content" => $pdf,
 298                             "name"    => $::form->{email}->{attachment_filename} }];
 299
 300   if (my $err = $mail->send) {
 301     return $self->js->flash('error', t8('Sending E-mail: ') . $err)
 302                     ->render($self);
 303   }
 304
 305   # internal notes
 306   my $intnotes = $self->order->intnotes;
 307   $intnotes   .= "\n\n" if $self->order->intnotes;
 308   $intnotes   .= t8('[email]')                                                                                        . "\n";
 309   $intnotes   .= t8('Date')       . ": " . $::locale->format_date_object(DateTime->now_local, precision => 'seconds') . "\n";
 310   $intnotes   .= t8('To (email)') . ": " . $mail->{to}                                                                . "\n";
 311   $intnotes   .= t8('Cc')         . ": " . $mail->{cc}                                                                . "\n"    if $mail->{cc};
 312   $intnotes   .= t8('Bcc')        . ": " . $mail->{bcc}                                                               . "\n"    if $mail->{bcc};
 313   $intnotes   .= t8('Subject')    . ": " . $mail->{subject}                                                           . "\n\n";
 314   $intnotes   .= t8('Message')    . ": " . $mail->{message};
 315
 316   $self->js
 317       ->val('#order_intnotes', $intnotes)
 318       ->run('close_email_dialog')
 319       ->render($self);
 320 }
 321
 322 sub action_save_and_delivery_order {
 323   my ($self) = @_;
 324
 325   my $errors = $self->_save();
 326
 327   if (scalar @{ $errors }) {
 328     $self->js->flash('error', $_) foreach @{ $errors };
 329     return $self->js->render();
 330   }
 331   flash_later('info', $::locale->text('The order has been saved'));
 332
 333   my @redirect_params = (
 334     controller => 'oe.pl',
 335     action     => 'oe_delivery_order_from_order',
 336     id         => $self->order->id,
 337   );
 338
 339   $self->redirect_to(@redirect_params);
 340 }
 341
 342 sub action_customer_vendor_changed {
 343   my ($self) = @_;
 344
 345   my $cv_method = $self->cv;
 346
 347   if ($self->order->$cv_method->contacts && scalar @{ $self->order->$cv_method->contacts } > 0) {
 348     $self->js->show('#cp_row');
 349   } else {
 350     $self->js->hide('#cp_row');
 351   }
 352
 353   if ($self->order->$cv_method->shipto && scalar @{ $self->order->$cv_method->shipto } > 0) {
 354     $self->js->show('#shipto_row');
 355   } else {
 356     $self->js->hide('#shipto_row');
 357   }
 358
 359   $self->order->taxzone_id($self->order->$cv_method->taxzone_id);
 360
 361   if ($self->order->is_sales) {
 362     $self->order->taxincluded(defined($self->order->$cv_method->taxincluded_checked)
 363                               ? $self->order->$cv_method->taxincluded_checked
 364                               : $::myconfig{taxincluded_checked});
 365   }
 366
 367   $self->order->payment_id($self->order->$cv_method->payment_id);
 368   $self->order->delivery_term_id($self->order->$cv_method->delivery_term_id);
 369
 370   $self->_recalc();
 371
 372   $self->js
 373     ->replaceWith('#order_cp_id',            $self->build_contact_select)
 374     ->replaceWith('#order_shipto_id',        $self->build_shipto_select)
 375     ->val(        '#order_taxzone_id',       $self->order->taxzone_id)
 376     ->val(        '#order_taxincluded',      $self->order->taxincluded)
 377     ->val(        '#order_payment_id',       $self->order->payment_id)
 378     ->val(        '#order_delivery_term_id', $self->order->delivery_term_id)
 379     ->val(        '#order_intnotes',         $self->order->$cv_method->notes)
 380     ->focus(      '#order_' . $self->cv . '_id');
 381
 382   $self->_js_redisplay_amounts_and_taxes;
 383   $self->js->render();
 384 }
 385
 386 sub action_unit_changed {
 387   my ($self) = @_;
 388
 389   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 390   my $item = $self->order->items_sorted->[$idx];
 391
 392   my $old_unit_obj = SL::DB::Unit->new(name => $::form->{old_unit})->load;
 393   $item->sellprice($item->unit_obj->convert_to($item->sellprice, $old_unit_obj));
 394
 395   $self->_recalc();
 396
 397   $self->js
 398     ->run('update_sellprice', $::form->{item_id}, $item->sellprice_as_number);
 399   $self->_js_redisplay_linetotals;
 400   $self->_js_redisplay_amounts_and_taxes;
 401   $self->js->render();
 402 }
 403
 404 sub action_add_item {
 405   my ($self) = @_;
 406
 407   my $form_attr = $::form->{add_item};
 408
 409   return unless $form_attr->{parts_id};
 410
 411   my $item = _new_item($self->order, $form_attr);
 412   $self->order->add_items($item);
 413
 414   $self->_recalc();
 415
 416   my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 417   my $row_as_html = $self->p->render('order/tabs/_row',
 418                                      ITEM              => $item,
 419                                      ID                => $item_id,
 420                                      ALL_PRICE_FACTORS => $self->all_price_factors
 421   );
 422
 423   $self->js
 424     ->append('#row_table_id', $row_as_html)
 425     ->val('.add_item_input', '')
 426     ->run('row_table_scroll_down')
 427     ->run('row_set_keyboard_events_by_id', $item_id)
 428     ->run('set_unit_change_with_oldval_by_id', $item_id)
 429     ->run('renumber_positions')
 430     ->on('.recalc', 'change', 'recalc_amounts_and_taxes')
 431     ->on('.reformat_number', 'change', 'reformat_number')
 432     ->focus('#add_item_parts_id_name');
 433
 434   $self->_js_redisplay_amounts_and_taxes;
 435   $self->js->render();
 436 }
 437
 438 sub action_show_multi_items_dialog {
 439   require SL::DB::PartsGroup;
 440   $_[0]->render('order/tabs/_multi_items_dialog', { layout => 0 },
 441                 all_partsgroups => SL::DB::Manager::PartsGroup->get_all);
 442 }
 443
 444 sub action_multi_items_update_result {
 445   my $max_count = 100;
 446
 447   $::form->{multi_items}->{filter}->{obsolete} = 0;
 448
 449   my $count = $_[0]->multi_items_models->count;
 450
 451   if ($count == 0) {
 452     my $text = SL::Presenter::EscapedText->new(text => $::locale->text('No results.'));
 453     $_[0]->render($text, { layout => 0 });
 454   } elsif ($count > $max_count) {
 455     my $text = SL::Presenter::EscapedText->new(text => $::locale->text('Too many results (#1 from #2).', $count, $max_count));
 456     $_[0]->render($text, { layout => 0 });
 457   } else {
 458     my $multi_items = $_[0]->multi_items_models->get;
 459     $_[0]->render('order/tabs/_multi_items_result', { layout => 0 },
 460                   multi_items => $multi_items);
 461   }
 462 }
 463
 464 sub action_add_multi_items {
 465   my ($self) = @_;
 466
 467   my @form_attr = grep { $_->{qty_as_number} } @{ $::form->{add_multi_items} };
 468   return $self->js->render() unless scalar @form_attr;
 469
 470   my @items;
 471   foreach my $attr (@form_attr) {
 472     push @items, _new_item($self->order, $attr);
 473   }
 474   $self->order->add_items(@items);
 475
 476   $self->_recalc();
 477
 478   foreach my $item (@items) {
 479     my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 480     my $row_as_html = $self->p->render('order/tabs/_row',
 481                                        ITEM              => $item,
 482                                        ID                => $item_id,
 483                                        ALL_PRICE_FACTORS => $self->all_price_factors
 484     );
 485
 486     $self->js
 487         ->append('#row_table_id', $row_as_html)
 488         ->run('row_set_keyboard_events_by_id', $item_id)
 489         ->run('set_unit_change_with_oldval_by_id', $item_id);
 490   }
 491
 492   $self->js
 493     ->run('close_multi_items_dialog')
 494     ->run('row_table_scroll_down')
 495     ->run('renumber_positions')
 496     ->on('.recalc', 'change', 'recalc_amounts_and_taxes')
 497     ->on('.reformat_number', 'change', 'reformat_number')
 498     ->focus('#add_item_parts_id_name');
 499
 500   $self->_js_redisplay_amounts_and_taxes;
 501   $self->js->render();
 502 }
 503
 504 sub action_recalc_amounts_and_taxes {
 505   my ($self) = @_;
 506
 507   $self->_recalc();
 508
 509   $self->_js_redisplay_linetotals;
 510   $self->_js_redisplay_amounts_and_taxes;
 511   $self->js->render();
 512 }
 513
 514 sub action_reorder_items {
 515   my ($self) = @_;
 516
 517   my %sort_keys = (
 518     partnumber  => sub { $_[0]->part->partnumber },
 519     description => sub { $_[0]->description },
 520     qty         => sub { $_[0]->qty },
 521     sellprice   => sub { $_[0]->sellprice },
 522     discount    => sub { $_[0]->discount },
 523   );
 524
 525   my $method = $sort_keys{$::form->{order_by}};
 526   my @to_sort = map { { old_pos => $_->position, order_by => $method->($_) } } @{ $self->order->items_sorted };
 527   if ($::form->{sort_dir}) {
 528     @to_sort = sort { $a->{order_by} cmp $b->{order_by} } @to_sort;
 529   } else {
 530     @to_sort = sort { $b->{order_by} cmp $a->{order_by} } @to_sort;
 531   }
 532   $self->js
 533     ->run('redisplay_items', \@to_sort)
 534     ->render;
 535 }
 536
 537 sub action_price_popup {
 538   my ($self) = @_;
 539
 540   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 541   my $item = $self->order->items_sorted->[$idx];
 542
 543   $self->render_price_dialog($item);
 544 }
 545
 546 sub action_get_item_longdescription {
 547   my $longdescription;
 548
 549   if ($::form->{item_id}) {
 550     $longdescription = SL::DB::OrderItem->new(id => $::form->{item_id})->load->longdescription;
 551   } elsif ($::form->{parts_id}) {
 552     $longdescription = SL::DB::Part->new(id => $::form->{parts_id})->load->notes;
 553   }
 554   $_[0]->render(\ $longdescription, { type => 'text' });
 555 }
 556
 557
 558 sub _js_redisplay_linetotals {
 559   my ($self) = @_;
 560
 561   my @data = map {$::form->format_amount(\%::myconfig, $_->{linetotal}, 2, 0)} @{ $self->order->items_sorted };
 562   $self->js
 563     ->run('redisplay_linetotals', \@data);
 564 }
 565
 566 sub _js_redisplay_amounts_and_taxes {
 567   my ($self) = @_;
 568
 569   if (scalar @{ $self->{taxes} }) {
 570     $self->js->show('#taxincluded_row_id');
 571   } else {
 572     $self->js->hide('#taxincluded_row_id');
 573   }
 574
 575   if ($self->order->taxincluded) {
 576     $self->js->hide('#subtotal_row_id');
 577   } else {
 578     $self->js->show('#subtotal_row_id');
 579   }
 580
 581   $self->js
 582     ->html('#netamount_id', $::form->format_amount(\%::myconfig, $self->order->netamount, -2))
 583     ->html('#amount_id',    $::form->format_amount(\%::myconfig, $self->order->amount,    -2))
 584     ->remove('.tax_row')
 585     ->insertBefore($self->build_tax_rows, '#amount_row_id');
 586 }
 587
 588 #
 589 # helpers
 590 #
 591
 592 sub init_valid_types {
 593   [ _sales_order_type(), _purchase_order_type() ];
 594 }
 595
 596 sub init_type {
 597   my ($self) = @_;
 598
 599   if (none { $::form->{type} eq $_ } @{$self->valid_types}) {
 600     die "Not a valid type for order";
 601   }
 602
 603   $self->type($::form->{type});
 604 }
 605
 606 sub init_cv {
 607   my ($self) = @_;
 608
 609   my $cv = $self->type eq _sales_order_type()    ? 'customer'
 610          : $self->type eq _purchase_order_type() ? 'vendor'
 611          : die "Not a valid type for order";
 612
 613   return $cv;
 614 }
 615
 616 sub init_p {
 617   SL::Presenter->get;
 618 }
 619
 620 sub init_order {
 621   $_[0]->_make_order;
 622 }
 623
 624 sub init_multi_items_models {
 625   SL::Controller::Helper::GetModels->new(
 626     controller     => $_[0],
 627     model          => 'Part',
 628     with_objects   => [ qw(unit_obj) ],
 629     disable_plugin => 'paginated',
 630     source         => $::form->{multi_items},
 631     sorted         => {
 632       _default    => {
 633         by  => 'partnumber',
 634         dir => 1,
 635       },
 636       partnumber  => t8('Partnumber'),
 637       description => t8('Description')}
 638   );
 639 }
 640
 641 sub init_all_price_factors {
 642   SL::DB::Manager::PriceFactor->get_all;
 643 }
 644
 645 sub _check_auth {
 646   my ($self) = @_;
 647
 648   my $right_for = { map { $_ => $_.'_edit' } @{$self->valid_types} };
 649
 650   my $right   = $right_for->{ $self->type };
 651   $right    ||= 'DOES_NOT_EXIST';
 652
 653   $::auth->assert($right);
 654 }
 655
 656 sub build_contact_select {
 657   my ($self) = @_;
 658
 659   $self->p->select_tag('order.cp_id', [ $self->order->{$self->cv}->contacts ],
 660                        value_key  => 'cp_id',
 661                        title_key  => 'full_name_dep',
 662                        default    => $self->order->cp_id,
 663                        with_empty => 1,
 664                        style      => 'width: 300px',
 665   );
 666 }
 667
 668 sub build_shipto_select {
 669   my ($self) = @_;
 670
 671   $self->p->select_tag('order.shipto_id', [ $self->order->{$self->cv}->shipto ],
 672                        value_key  => 'shipto_id',
 673                        title_key  => 'displayable_id',
 674                        default    => $self->order->shipto_id,
 675                        with_empty => 1,
 676                        style      => 'width: 300px',
 677   );
 678 }
 679
 680 sub build_tax_rows {
 681   my ($self) = @_;
 682
 683   my $rows_as_html;
 684   foreach my $tax (sort { $a->{tax}->rate cmp $b->{tax}->rate } @{ $self->{taxes} }) {
 685     $rows_as_html .= $self->p->render('order/tabs/_tax_row', TAX => $tax, TAXINCLUDED => $self->order->taxincluded);
 686   }
 687   return $rows_as_html;
 688 }
 689
 690
 691 sub render_price_dialog {
 692   my ($self, $record_item) = @_;
 693
 694   my $price_source = SL::PriceSource->new(record_item => $record_item, record => $self->order);
 695
 696   $self->js
 697     ->run(
 698       'kivi.io.price_chooser_dialog',
 699       t8('Available Prices'),
 700       $self->render('order/tabs/_price_sources_dialog', { output => 0 }, price_source => $price_source)
 701     )
 702     ->reinit_widgets;
 703
 704 #   if (@errors) {
 705 #     $self->js->text('#dialog_flash_error_content', join ' ', @errors);
 706 #     $self->js->show('#dialog_flash_error');
 707 #   }
 708
 709   $self->js->render;
 710 }
 711
 712 sub _load_order {
 713   my ($self) = @_;
 714
 715   return if !$::form->{id};
 716
 717   $self->order(SL::DB::Manager::Order->find_by(id => $::form->{id}));
 718 }
 719
 720 sub _make_order {
 721   my ($self) = @_;
 722
 723   # add_items adds items to an order with no items for saving, but they cannot
 724   # be retrieved via items until the order is saved. Adding empty items to new
 725   # order here solves this problem.
 726   my $order;
 727   $order   = SL::DB::Manager::Order->find_by(id => $::form->{id}) if $::form->{id};
 728   $order ||= SL::DB::Order->new(orderitems => []);
 729
 730   my $form_orderitems = delete $::form->{order}->{orderitems};
 731   $order->assign_attributes(%{$::form->{order}});
 732
 733   # remove deleted items
 734   $self->item_ids_to_delete([]);
 735   foreach my $idx (reverse 0..$#{$order->orderitems}) {
 736     my $item = $order->orderitems->[$idx];
 737     if (none { $item->id == $_->{id} } @{$form_orderitems}) {
 738       splice @{$order->orderitems}, $idx, 1;
 739       push @{$self->item_ids_to_delete}, $item->id;
 740     }
 741   }
 742
 743   my @items;
 744   my $pos = 1;
 745   foreach my $form_attr (@{$form_orderitems}) {
 746     my $item = _make_item($order, $form_attr);
 747     $item->position($pos);
 748     push @items, $item;
 749     $pos++;
 750   }
 751   $order->add_items(grep {!$_->id} @items);
 752
 753   return $order;
 754 }
 755
 756
 757 # Make item objects from form values. For items already existing read from db.
 758 # Create a new item else. And assign attributes.
 759 sub _make_item {
 760   my ($record, $attr) = @_;
 761
 762   my $item;
 763   $item = first { $_->id == $attr->{id} } @{$record->items} if $attr->{id};
 764
 765   my $is_new = !$item;
 766
 767   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
 768   # they cannot be retrieved via custom_variables until the order/orderitem is
 769   # saved. Adding empty custom_variables to new orderitem here solves this problem.
 770   $item ||= SL::DB::OrderItem->new(custom_variables => []);
 771
 772   $item->assign_attributes(%$attr);
 773   $item->longdescription($item->part->notes) if $is_new && !defined $attr->{longdescription};
 774
 775   return $item;
 776 }
 777
 778 sub _new_item {
 779   my ($record, $attr) = @_;
 780
 781   my $item = SL::DB::OrderItem->new;
 782   $item->assign_attributes(%$attr);
 783
 784   my $part         = SL::DB::Part->new(id => $attr->{parts_id})->load;
 785   my $price_source = SL::PriceSource->new(record_item => $item, record => $record);
 786
 787   $item->unit($part->unit) if !$item->unit;
 788
 789   my $price_src;
 790   if ($item->sellprice) {
 791     $price_src = $price_source->price_from_source("");
 792     $price_src->price($item->sellprice);
 793   } else {
 794     $price_src = $price_source->best_price
 795            ? $price_source->best_price
 796            : $price_source->price_from_source("");
 797     $price_src->price(0) if !$price_source->best_price;
 798   }
 799
 800   my $discount_src;
 801   if ($item->discount) {
 802     $discount_src = $price_source->discount_from_source("");
 803     $discount_src->discount($item->discount);
 804   } else {
 805     $discount_src = $price_source->best_discount
 806                   ? $price_source->best_discount
 807                   : $price_source->discount_from_source("");
 808     $discount_src->discount(0) if !$price_source->best_discount;
 809   }
 810
 811   my %new_attr;
 812   $new_attr{part}                   = $part;
 813   $new_attr{description}            = $part->description     if ! $item->description;
 814   $new_attr{qty}                    = 1.0                    if ! $item->qty;
 815   $new_attr{price_factor_id}        = $part->price_factor_id if ! $item->price_factor_id;
 816   $new_attr{sellprice}              = $price_src->price;
 817   $new_attr{discount}               = $discount_src->discount;
 818   $new_attr{active_price_source}    = $price_src;
 819   $new_attr{active_discount_source} = $discount_src;
 820
 821   $new_attr{longdescription}        = $part->notes if ! defined $attr->{longdescription};
 822
 823   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
 824   # they cannot be retrieved via custom_variables until the order/orderitem is
 825   # saved. Adding empty custom_variables to new orderitem here solves this problem.
 826   $new_attr{custom_variables} = [];
 827
 828   $item->assign_attributes(%new_attr);
 829
 830   return $item;
 831 }
 832
 833 sub _recalc {
 834   my ($self) = @_;
 835
 836   # bb: todo: currency later
 837   $self->order->currency_id($::instance_conf->get_currency_id());
 838
 839   my %pat = $self->order->calculate_prices_and_taxes();
 840   $self->{taxes} = [];
 841   foreach my $tax_chart_id (keys %{ $pat{taxes} }) {
 842     my $tax = SL::DB::Manager::Tax->find_by(chart_id => $tax_chart_id);
 843
 844     my @amount_keys = grep { $pat{amounts}->{$_}->{tax_id} == $tax->id } keys %{ $pat{amounts} };
 845     push(@{ $self->{taxes} }, { amount    => $pat{taxes}->{$tax_chart_id},
 846                                 netamount => $pat{amounts}->{$amount_keys[0]}->{amount},
 847                                 tax       => $tax });
 848   }
 849
 850   pairwise { $a->{linetotal} = $b->{linetotal} } @{$self->order->items}, @{$pat{items}};
 851 }
 852
 853
 854 sub _get_unalterable_data {
 855   my ($self) = @_;
 856
 857   foreach my $item (@{ $self->order->items }) {
 858     # autovivify all cvars that are not in the form (cvars_by_config can do it).
 859     # workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
 860     foreach my $var (@{ $item->cvars_by_config }) {
 861       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
 862     }
 863     $item->parse_custom_variable_values;
 864   }
 865 }
 866
 867
 868 sub _delete {
 869   my ($self) = @_;
 870
 871   my $errors = [];
 872   my $db = $self->order->db;
 873
 874   $db->do_transaction(
 875     sub {
 876       my @spoolfiles = grep { $_ } map { $_->spoolfile } @{ SL::DB::Manager::Status->get_all(where => [ trans_id => $self->order->id ]) };
 877       $self->order->delete;
 878       my $spool = $::lx_office_conf{paths}->{spool};
 879       unlink map { "$spool/$_" } @spoolfiles if $spool;
 880
 881       1;
 882   }) || push(@{$errors}, $db->error);
 883
 884   return $errors;
 885 }
 886
 887
 888 sub _save {
 889   my ($self) = @_;
 890
 891   my $errors = [];
 892   my $db = $self->order->db;
 893
 894   $db->do_transaction(
 895     sub {
 896       SL::DB::OrderItem->new(id => $_)->delete for @{$self->item_ids_to_delete};
 897       $self->order->save(cascade => 1);
 898   }) || push(@{$errors}, $db->error);
 899
 900   return $errors;
 901 }
 902
 903
 904 sub _pre_render {
 905   my ($self) = @_;
 906
 907   $self->{all_taxzones}        = SL::DB::Manager::TaxZone->get_all_sorted();
 908   $self->{all_departments}     = SL::DB::Manager::Department->get_all_sorted();
 909   $self->{all_employees}       = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->employee_id,
 910                                                                                        deleted => 0 ] ],
 911                                                                     sort_by => 'name');
 912   $self->{all_salesmen}        = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->salesman_id,
 913                                                                                        deleted => 0 ] ],
 914                                                                     sort_by => 'name');
 915   $self->{all_projects}        = SL::DB::Manager::Project->get_all(where => [ or => [ id => $self->order->globalproject_id,
 916                                                                                       active => 1 ] ],
 917                                                                    sort_by => 'projectnumber');
 918   $self->{all_payment_terms}   = SL::DB::Manager::PaymentTerm->get_all_sorted();
 919   $self->{all_delivery_terms}  = SL::DB::Manager::DeliveryTerm->get_all_sorted();
 920
 921   $self->{current_employee_id} = SL::DB::Manager::Employee->current->id;
 922
 923   my $print_form = Form->new('');
 924   $print_form->{type}      = $self->type;
 925   $print_form->{printers}  = SL::DB::Manager::Printer->get_all_sorted;
 926   $print_form->{languages} = SL::DB::Manager::Language->get_all_sorted;
 927   $self->{print_options}   = SL::Helper::PrintOptions->get_print_options(
 928     form => $print_form,
 929     options => {dialog_name_prefix => 'print_options.',
 930                 show_headers       => 1,
 931                 no_queue           => 1,
 932                 no_postscript      => 1,
 933                 no_opendocument    => 1,
 934                 no_html            => 1},
 935   );
 936
 937   foreach my $item (@{$self->order->orderitems}) {
 938     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
 939     $item->active_price_source(   $price_source->price_from_source(   $item->active_price_source   ));
 940     $item->active_discount_source($price_source->discount_from_source($item->active_discount_source));
 941   }
 942
 943   if ($self->order->ordnumber && $::instance_conf->get_webdav) {
 944     my $webdav = SL::Webdav->new(
 945       type     => $self->type,
 946       number   => $self->order->ordnumber,
 947     );
 948     my $webdav_path = $webdav->webdav_path;
 949     my @all_objects = $webdav->get_all_objects;
 950     @{ $self->{template_args}->{WEBDAV} } = map { { name => $_->filename,
 951                                                     type => t8('File'),
 952                                                     link => File::Spec->catdir($webdav_path, $_->filename),
 953                                                 } } @all_objects;
 954   }
 955
 956   $::request->{layout}->use_javascript("${_}.js")  for qw(kivi.SalesPurchase ckeditor/ckeditor ckeditor/adapters/jquery);
 957 }
 958
 959 sub _create_pdf {
 960   my ($order, $pdf_ref, $params) = @_;
 961
 962   my @errors = ();
 963
 964   my $print_form = Form->new('');
 965   $print_form->{type}        = $order->type;
 966   $print_form->{formname}    = $params->{formname} || $order->type;
 967   $print_form->{format}      = $params->{format}   || 'pdf';
 968   $print_form->{media}       = $params->{media}    || 'file';
 969   $print_form->{groupitems}  = $params->{groupitems};
 970   $print_form->{media}       = 'file'                             if $print_form->{media} eq 'screen';
 971   $print_form->{language}    = $params->{language}->template_code if $print_form->{language};
 972   $print_form->{language_id} = $params->{language}->id            if $print_form->{language};
 973
 974   $order->flatten_to_form($print_form, format_amounts => 1);
 975   # flatten_to_form sets payment_terms from customer/vendor - we do not want that here
 976   delete $print_form->{payment_terms} if !$print_form->{payment_id};
 977
 978   # search for the template
 979   my ($template_file, @template_files) = SL::Helper::CreatePDF->find_template(
 980     name        => $print_form->{formname},
 981     email       => $print_form->{media} eq 'email',
 982     language    => $params->{language},
 983     printer_id  => $print_form->{printer_id},  # todo
 984   );
 985
 986   if (!defined $template_file) {
 987     push @errors, $::locale->text('Cannot find matching template for this print request. Please contact your template maintainer. I tried these: #1.', join ', ', map { "'$_'"} @template_files);
 988   }
 989
 990   return @errors if scalar @errors;
 991
 992   $print_form->throw_on_error(sub {
 993     eval {
 994       $print_form->prepare_for_printing;
 995
 996       $$pdf_ref = SL::Helper::CreatePDF->create_pdf(
 997         template  => $template_file,
 998         variables => $print_form,
 999         variable_content_types => {
1000           longdescription => 'html',
1001           partnotes       => 'html',
1002           notes           => 'html',
1003         },
1004       );
1005       1;
1006     } || push @errors, ref($EVAL_ERROR) eq 'SL::X::FormError' ? $EVAL_ERROR->getMessage : $EVAL_ERROR;
1007   });
1008
1009   return @errors;
1010 }
1011
1012 sub _sales_order_type {
1013   'sales_order';
1014 }
1015
1016 sub _purchase_order_type {
1017   'purchase_order';
1018 }
1019
1020 1;