SL/Controller/Order.pm

   1 package SL::Controller::Order;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use SL::Helper::Flash;
   7 use SL::Presenter;
   8 use SL::Locale::String;
   9 use SL::SessionFile::Random;
  10 use SL::PriceSource;
  11 use SL::Form;
  12
  13 use SL::DB::Order;
  14 use SL::DB::Customer;
  15 use SL::DB::Vendor;
  16 use SL::DB::TaxZone;
  17 use SL::DB::Employee;
  18 use SL::DB::Project;
  19 use SL::DB::Default;
  20 use SL::DB::Unit;
  21 use SL::DB::Price;
  22
  23 use SL::Helper::DateTime;
  24 use SL::Helper::CreatePDF qw(:all);
  25
  26 use List::Util qw(max first);
  27 use List::MoreUtils qw(none pairwise first_index);
  28 use English qw(-no_match_vars);
  29 use File::Spec;
  30
  31 use Rose::Object::MakeMethods::Generic
  32 (
  33  'scalar --get_set_init' => [ qw(order valid_types type cv p) ],
  34 );
  35
  36
  37 # safety
  38 __PACKAGE__->run_before('_check_auth');
  39
  40 __PACKAGE__->run_before('_recalc',
  41                         only => [ qw(edit update save save_and_delivery_order create_pdf send_email) ]);
  42
  43 __PACKAGE__->run_before('_get_unalterable_data',
  44                         only => [ qw(save save_and_delivery_order create_pdf send_email) ]);
  45
  46 #
  47 # actions
  48 #
  49
  50 sub action_add {
  51   my ($self) = @_;
  52
  53   $self->order->transdate(DateTime->now_local());
  54   $self->order->reqdate(DateTime->today_local->next_workday) if !$self->order->reqdate;
  55
  56   $self->_pre_render();
  57   $self->render(
  58     'order/form',
  59     title => $self->type eq _sales_order_type()    ? $::locale->text('Add Sales Order')
  60            : $self->type eq _purchase_order_type() ? $::locale->text('Add Purchase Order')
  61            : '',
  62     %{$self->{template_args}}
  63   );
  64 }
  65
  66 sub action_edit {
  67   my ($self) = @_;
  68
  69   $self->_pre_render();
  70   $self->render(
  71     'order/form',
  72     title => $self->type eq _sales_order_type()    ? $::locale->text('Edit Sales Order')
  73            : $self->type eq _purchase_order_type() ? $::locale->text('Edit Purchase Order')
  74            : '',
  75     %{$self->{template_args}}
  76   );
  77 }
  78
  79 sub action_update {
  80   my ($self) = @_;
  81
  82   $self->_pre_render();
  83   $self->render(
  84     'order/form',
  85     title => $self->type eq _sales_order_type()    ? $::locale->text('Edit Sales Order')
  86            : $self->type eq _purchase_order_type() ? $::locale->text('Edit Purchase Order')
  87            : '',
  88     %{$self->{template_args}}
  89   );
  90 }
  91
  92 sub action_save {
  93   my ($self) = @_;
  94
  95   my $errors = $self->_save();
  96
  97   if (scalar @{ $errors }) {
  98     $self->js->flash('error', $_) foreach @{ $errors };
  99     return $self->js->render();
 100   }
 101
 102   flash_later('info', $::locale->text('The order has been saved'));
 103   my @redirect_params = (
 104     action => 'edit',
 105     type   => $self->type,
 106     id     => $self->order->id,
 107   );
 108
 109   $self->redirect_to(@redirect_params);
 110 }
 111
 112 sub action_create_pdf {
 113   my ($self) = @_;
 114
 115   my $pdf;
 116   my @errors = _create_pdf($self->order, \$pdf);
 117   if (scalar @errors) {
 118     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render($self);
 119   }
 120
 121   my $sfile = SL::SessionFile::Random->new(mode => "w");
 122   $sfile->fh->print($pdf);
 123   $sfile->fh->close;
 124
 125   my $key = join('_', Time::HiRes::gettimeofday(), int rand 1000000000000);
 126   $::auth->set_session_value("Order::create_pdf-${key}" => $sfile->file_name);
 127
 128   my $form = Form->new;
 129   $form->{ordnumber} = $self->order->ordnumber;
 130   $form->{formname}  = $self->type;
 131   $form->{type}      = $self->type;
 132   $form->{language}  = 'de';
 133   $form->{format}    = 'pdf';
 134
 135   my $pdf_filename = $form->generate_attachment_filename();
 136
 137   $self->js
 138     ->run('download_pdf', $pdf_filename, $key)
 139     ->flash('info', t8('The PDF has been created'))->render($self);
 140 }
 141
 142 sub action_download_pdf {
 143   my ($self) = @_;
 144
 145   my $key = $::form->{key};
 146   my $tmp_filename = $::auth->get_session_value("Order::create_pdf-${key}");
 147   return $self->send_file(
 148     $tmp_filename,
 149     type => 'application/pdf',
 150     name => $::form->{pdf_filename},
 151   );
 152 }
 153
 154 sub action_show_email_dialog {
 155   my ($self) = @_;
 156
 157   my $cv_method = $self->cv;
 158
 159   if (!$self->order->$cv_method) {
 160     return $self->js->flash('error', t8('Cannot send E-mail without ' . $self->cv))
 161                     ->render($self);
 162   }
 163
 164   $self->{email}->{to}   = $self->order->contact->cp_email if $self->order->contact;
 165   $self->{email}->{to} ||= $self->order->$cv_method->email;
 166   $self->{email}->{cc}   = $self->order->$cv_method->cc;
 167   $self->{email}->{bcc}  = join ', ', grep $_, $self->order->$cv_method->bcc, SL::DB::Default->get->global_bcc;
 168   # Todo: get addresses from shipto, if any
 169
 170   my $form = Form->new;
 171   $form->{ordnumber} = $self->order->ordnumber;
 172   $form->{formname}  = $self->type;
 173   $form->{type}      = $self->type;
 174   $form->{language} = 'de';
 175   $form->{format}   = 'pdf';
 176
 177   $self->{email}->{subject}             = $form->generate_email_subject();
 178   $self->{email}->{attachment_filename} = $form->generate_attachment_filename();
 179   $self->{email}->{message}             = $form->create_email_signature();
 180
 181   my $dialog_html = $self->render('order/tabs/_email_dialog', { output => 0 });
 182   $self->js
 183       ->run('show_email_dialog', $dialog_html)
 184       ->reinit_widgets
 185       ->render($self);
 186 }
 187
 188 # Todo: handling error messages: flash is not displayed in dialog, but in the main form
 189 sub action_send_email {
 190   my ($self) = @_;
 191
 192   my $mail      = Mailer->new;
 193   $mail->{from} = qq|"$::myconfig{name}" <$::myconfig{email}>|;
 194   $mail->{$_}   = $::form->{email}->{$_} for qw(to cc bcc subject message);
 195
 196   my $pdf;
 197   my @errors = _create_pdf($self->order, \$pdf, {media => 'email'});
 198   if (scalar @errors) {
 199     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render($self);
 200   }
 201
 202   $mail->{attachments} = [{ "content" => $pdf,
 203                             "name"    => $::form->{email}->{attachment_filename} }];
 204
 205   if (my $err = $mail->send) {
 206     return $self->js->flash('error', t8('Sending E-mail: ') . $err)
 207                     ->render($self);
 208   }
 209
 210   # internal notes
 211   my $intnotes = $self->order->intnotes;
 212   $intnotes   .= "\n\n" if $self->order->intnotes;
 213   $intnotes   .= t8('[email]')                                                                                        . "\n";
 214   $intnotes   .= t8('Date')       . ": " . $::locale->format_date_object(DateTime->now_local, precision => 'seconds') . "\n";
 215   $intnotes   .= t8('To (email)') . ": " . $mail->{to}                                                                . "\n";
 216   $intnotes   .= t8('Cc')         . ": " . $mail->{cc}                                                                . "\n"    if $mail->{cc};
 217   $intnotes   .= t8('Bcc')        . ": " . $mail->{bcc}                                                               . "\n"    if $mail->{bcc};
 218   $intnotes   .= t8('Subject')    . ": " . $mail->{subject}                                                           . "\n\n";
 219   $intnotes   .= t8('Message')    . ": " . $mail->{message};
 220
 221   $self->js
 222       ->val('#order_intnotes', $intnotes)
 223       ->run('close_email_dialog')
 224       ->render($self);
 225 }
 226
 227 sub action_save_and_delivery_order {
 228   my ($self) = @_;
 229
 230   my $errors = $self->_save();
 231
 232   if (scalar @{ $errors }) {
 233     $self->js->flash('error', $_) foreach @{ $errors };
 234     return $self->js->render();
 235   }
 236
 237   my $delivery_order = $self->order->convert_to_delivery_order($self->order);
 238
 239   flash_later('info', $::locale->text('The order has been saved'));
 240   my @redirect_params = (
 241     controller => 'do.pl',
 242     action     => 'edit',
 243     type       => $delivery_order->type,
 244     id         => $delivery_order->id,
 245     vc         => $delivery_order->is_sales ? 'customer' : 'vendor',
 246   );
 247
 248   $self->redirect_to(@redirect_params);
 249 }
 250
 251 sub action_customer_vendor_changed {
 252   my ($self) = @_;
 253
 254   my $cv_method = $self->cv;
 255
 256   if ($self->order->$cv_method->contacts && scalar @{ $self->order->$cv_method->contacts } > 0) {
 257     $self->js->show('#cp_row');
 258   } else {
 259     $self->js->hide('#cp_row');
 260   }
 261
 262   if ($self->order->$cv_method->shipto && scalar @{ $self->order->$cv_method->shipto } > 0) {
 263     $self->js->show('#shipto_row');
 264   } else {
 265     $self->js->hide('#shipto_row');
 266   }
 267
 268   $self->order->taxzone_id($self->order->$cv_method->taxzone_id);
 269
 270   if ($self->order->is_sales) {
 271     $self->order->taxincluded(defined($self->order->$cv_method->taxincluded_checked)
 272                               ? $self->order->$cv_method->taxincluded_checked
 273                               : $::myconfig{taxincluded_checked});
 274   }
 275
 276   $self->_recalc();
 277
 278   $self->js
 279     ->replaceWith('#order_cp_id',       $self->build_contact_select)
 280     ->replaceWith('#order_shipto_id',   $self->build_shipto_select)
 281     ->val(        '#order_taxzone_id',  $self->order->taxzone_id)
 282     ->val(        '#order_taxincluded', $self->order->taxincluded)
 283     ->focus(      '#order_' . $self->cv . '_id');
 284
 285   $self->_js_redisplay_amounts_and_taxes;
 286   $self->js->render();
 287 }
 288
 289 sub action_add_item {
 290   my ($self) = @_;
 291
 292   my $form_attr = $::form->{add_item};
 293
 294   return unless $form_attr->{parts_id};
 295
 296   my $item = _make_item($self->order, $form_attr);
 297   $self->order->add_items($item);
 298
 299   $self->_recalc();
 300
 301   my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 302   my $row_as_html = $self->p->render('order/tabs/_row', ITEM => $item, ID => $item_id);
 303
 304   $self->js
 305     ->append('#row_table_id', $row_as_html)
 306     ->val('#add_item_parts_id', '')
 307     ->val('#add_item_parts_id_name', '')
 308     ->val('#add_item_description', '')
 309     ->val('#add_item_qty_as_number', '')
 310     ->val('#add_item_sellprice_as_number', '')
 311     ->val('#add_item_discount_as_percent', '')
 312     ->run('row_table_scroll_down')
 313     ->run('row_set_keyboard_events_by_id', $item_id)
 314     ->on('.recalc', 'change', 'recalc_amounts_and_taxes')
 315     ->on('.reformat_number', 'change', 'reformat_number')
 316     ->focus('#add_item_parts_id_name');
 317
 318   $self->_js_redisplay_amounts_and_taxes;
 319   $self->js->render();
 320 }
 321
 322 sub action_show_multi_items_dialog {
 323   my ($self) = @_;
 324
 325   $self->{multi_items}->{parts} = SL::DB::Manager::Part->get_all_sorted(where => [ obsolete => 0 ]);
 326   my $dialog_html = $self->render('order/tabs/_multi_items_dialog', { output => 0 });
 327
 328   $self->js
 329     ->run('show_multi_items_dialog', $dialog_html, t8('Add multiple parts'))
 330     ->reinit_widgets
 331     ->render();
 332 }
 333
 334 sub action_add_multi_items {
 335   my ($self) = @_;
 336
 337   my @form_attr = grep { $_->{qty} } @{ $::form->{add_multi_items} };
 338   return unless scalar @form_attr;
 339
 340   my @items;
 341   foreach my $attr (@form_attr) {
 342     push @items, _make_item($self->order, $attr);
 343   }
 344   $self->order->add_items(@items);
 345
 346   $self->_recalc();
 347
 348   foreach my $item (@items) {
 349     my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 350     my $row_as_html = $self->p->render('order/tabs/_row', ITEM => $item, ID => $item_id);
 351
 352     $self->js
 353         ->append('#row_table_id', $row_as_html)
 354         ->run('row_set_keyboard_events_by_id', $item_id);
 355   }
 356
 357   $self->js
 358     ->run('close_multi_items_dialog')
 359     ->run('row_table_scroll_down')
 360     ->on('.recalc', 'change', 'recalc_amounts_and_taxes')
 361     ->on('.reformat_number', 'change', 'reformat_number')
 362     ->focus('#add_item_parts_id_name');
 363
 364   $self->_js_redisplay_amounts_and_taxes;
 365   $self->js->render();
 366 }
 367
 368 sub action_recalc_amounts_and_taxes {
 369   my ($self) = @_;
 370
 371   $self->_recalc();
 372
 373   $self->_js_redisplay_linetotals;
 374   $self->_js_redisplay_amounts_and_taxes;
 375   $self->js->render();
 376 }
 377
 378 sub action_price_popup {
 379   my ($self) = @_;
 380
 381   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 382   my $item = $self->order->items->[$idx];
 383
 384   $self->render_price_dialog($item);
 385 }
 386
 387 sub _js_redisplay_linetotals {
 388   my ($self) = @_;
 389
 390   my @data = map {$::form->format_amount(\%::myconfig, $_->{linetotal}, 2, 0)} @{ $self->order->items };
 391   $self->js
 392     ->run('redisplay_linetotals', \@data);
 393 }
 394
 395 sub _js_redisplay_amounts_and_taxes {
 396   my ($self) = @_;
 397
 398   if (scalar @{ $self->{taxes} }) {
 399     $self->js->show('#taxincluded_row_id');
 400   } else {
 401     $self->js->hide('#taxincluded_row_id');
 402   }
 403
 404   if ($self->order->taxincluded) {
 405     $self->js->hide('#subtotal_row_id');
 406   } else {
 407     $self->js->show('#subtotal_row_id');
 408   }
 409
 410   $self->js
 411     ->html('#netamount_id', $::form->format_amount(\%::myconfig, $self->order->netamount, -2))
 412     ->html('#amount_id',    $::form->format_amount(\%::myconfig, $self->order->amount,    -2))
 413     ->remove('.tax_row')
 414     ->insertBefore($self->build_tax_rows, '#amount_row_id');
 415 }
 416
 417 #
 418 # helpers
 419 #
 420
 421 sub init_valid_types {
 422   [ _sales_order_type(), _purchase_order_type() ];
 423 }
 424
 425 sub init_type {
 426   my ($self) = @_;
 427
 428   if (none { $::form->{type} eq $_ } @{$self->valid_types}) {
 429     die "Not a valid type for order";
 430   }
 431
 432   $self->type($::form->{type});
 433 }
 434
 435 sub init_cv {
 436   my ($self) = @_;
 437
 438   my $cv = $self->type eq _sales_order_type()    ? 'customer'
 439          : $self->type eq _purchase_order_type() ? 'vendor'
 440          : die "Not a valid type for order";
 441
 442   return $cv;
 443 }
 444
 445 sub init_p {
 446   SL::Presenter->get;
 447 }
 448
 449 sub init_order {
 450   _make_order();
 451 }
 452
 453 sub _check_auth {
 454   my ($self) = @_;
 455
 456   my $right_for = { map { $_ => $_.'_edit' } @{$self->valid_types} };
 457
 458   my $right   = $right_for->{ $self->type };
 459   $right    ||= 'DOES_NOT_EXIST';
 460
 461   $::auth->assert($right);
 462 }
 463
 464 sub build_contact_select {
 465   my ($self) = @_;
 466
 467   $self->p->select_tag('order.cp_id', [ $self->order->{$self->cv}->contacts ],
 468                        value_key  => 'cp_id',
 469                        title_key  => 'full_name_dep',
 470                        default    => $self->order->cp_id,
 471                        with_empty => 1,
 472                        style      => 'width: 300px',
 473   );
 474 }
 475
 476 sub build_shipto_select {
 477   my ($self) = @_;
 478
 479   $self->p->select_tag('order.shipto_id', [ $self->order->{$self->cv}->shipto ],
 480                        value_key  => 'shipto_id',
 481                        title_key  => 'displayable_id',
 482                        default    => $self->order->shipto_id,
 483                        with_empty => 1,
 484                        style      => 'width: 300px',
 485   );
 486 }
 487
 488 sub build_tax_rows {
 489   my ($self) = @_;
 490
 491   my $rows_as_html;
 492   foreach my $tax (sort { $a->{tax}->rate cmp $b->{tax}->rate } @{ $self->{taxes} }) {
 493     $rows_as_html .= $self->p->render('order/tabs/_tax_row', TAX => $tax, TAXINCLUDED => $self->order->taxincluded);
 494   }
 495   return $rows_as_html;
 496 }
 497
 498
 499 sub render_price_dialog {
 500   my ($self, $record_item) = @_;
 501
 502   my $price_source = SL::PriceSource->new(record_item => $record_item, record => $self->order);
 503
 504   $self->js
 505     ->run(
 506       'kivi.io.price_chooser_dialog',
 507       t8('Available Prices'),
 508       $self->render('order/tabs/_price_sources_dialog', { output => 0 }, price_source => $price_source)
 509     )
 510     ->reinit_widgets;
 511
 512 #   if (@errors) {
 513 #     $self->js->text('#dialog_flash_error_content', join ' ', @errors);
 514 #     $self->js->show('#dialog_flash_error');
 515 #   }
 516
 517   $self->js->render;
 518 }
 519
 520 sub _make_order {
 521   my ($self) = @_;
 522
 523   # add_items adds items to an order with no items for saving, but they cannot
 524   # be retrieved via items until the order is saved. Adding empty items to new
 525   # order here solves this problem.
 526   my $order;
 527   $order   = SL::DB::Manager::Order->find_by(id => $::form->{id}) if $::form->{id};
 528   $order ||= SL::DB::Order->new(orderitems => []);
 529
 530   $order->assign_attributes(%{$::form->{order}});
 531
 532   return $order;
 533 }
 534
 535 sub _make_item {
 536   my ($record, $attr) = @_;
 537
 538   my $item = SL::DB::OrderItem->new;
 539   $item->assign_attributes(%$attr);
 540
 541   my $part         = SL::DB::Part->new(id => $attr->{parts_id})->load;
 542   my $price_source = SL::PriceSource->new(record_item => $item, record => $record);
 543
 544   $item->unit($part->unit) if !$item->unit;
 545
 546   my $price_src;
 547   if ($item->sellprice) {
 548     $price_src = $price_source->price_from_source("");
 549     $price_src->price($item->sellprice);
 550   } else {
 551     $price_src = $price_source->best_price
 552            ? $price_source->best_price
 553            : $price_source->price_from_source("");
 554     $price_src->price(0) if !$price_source->best_price;
 555   }
 556
 557   my $discount_src;
 558   if ($item->discount) {
 559     $discount_src = $price_source->discount_from_source("");
 560     $discount_src->discount($item->discount);
 561   } else {
 562     $discount_src = $price_source->best_discount
 563                   ? $price_source->best_discount
 564                   : $price_source->discount_from_source("");
 565     $discount_src->discount(0) if !$price_source->best_discount;
 566   }
 567
 568   my %new_attr;
 569   $new_attr{part}                   = $part;
 570   $new_attr{description}            = $part->description if ! $item->description;
 571   $new_attr{qty}                    = 1.0                if ! $item->qty;
 572   $new_attr{sellprice}              = $price_src->price;
 573   $new_attr{discount}               = $discount_src->discount;
 574   $new_attr{active_price_source}    = $price_src;
 575   $new_attr{active_discount_source} = $discount_src;
 576
 577   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
 578   # they cannot be retrieved via custom_variables until the order/orderitem is
 579   # saved. Adding empty custom_variables to new orderitem here solves this problem.
 580   $new_attr{custom_variables} = [];
 581
 582   $item->assign_attributes(%new_attr);
 583
 584   return $item;
 585 }
 586
 587 sub _recalc {
 588   my ($self) = @_;
 589
 590   # bb: todo: currency later
 591   $self->order->currency_id($::instance_conf->get_currency_id());
 592
 593   my %pat = $self->order->calculate_prices_and_taxes();
 594   $self->{taxes} = [];
 595   foreach my $tax_chart_id (keys %{ $pat{taxes} }) {
 596     my $tax = SL::DB::Manager::Tax->find_by(chart_id => $tax_chart_id);
 597
 598     my @amount_keys = grep { $pat{amounts}->{$_}->{tax_id} == $tax->id } keys %{ $pat{amounts} };
 599     push(@{ $self->{taxes} }, { amount    => $pat{taxes}->{$tax_chart_id},
 600                                 netamount => $pat{amounts}->{$amount_keys[0]}->{amount},
 601                                 tax       => $tax });
 602   }
 603
 604   pairwise { $a->{linetotal} = $b->{linetotal} } @{$self->order->items}, @{$pat{items}};
 605 }
 606
 607
 608 sub _get_unalterable_data {
 609   my ($self) = @_;
 610
 611   foreach my $item (@{ $self->order->items }) {
 612     if ($item->id) {
 613       # load data from orderitems (db)
 614       my $db_item = SL::DB::OrderItem->new(id => $item->id)->load;
 615       $item->$_($db_item->$_) for qw(longdescription);
 616     } else {
 617       # set data from part (or other sources)
 618       $item->longdescription($item->part->notes);
 619     }
 620
 621     # autovivify all cvars that are not in the form (cvars_by_config can do it).
 622     # workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
 623     foreach my $var (@{ $item->cvars_by_config }) {
 624       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
 625     }
 626     $item->parse_custom_variable_values;
 627   }
 628 }
 629
 630
 631 sub _save {
 632   my ($self) = @_;
 633
 634   my $errors = [];
 635   my $db = $self->order->db;
 636
 637   $db->do_transaction(
 638     sub {
 639       $self->order->save();
 640   }) || push(@{$errors}, $db->error);
 641
 642   return $errors;
 643 }
 644
 645
 646 sub _pre_render {
 647   my ($self) = @_;
 648
 649   $self->{all_taxzones}        = SL::DB::Manager::TaxZone->get_all_sorted();
 650   $self->{all_departments}     = SL::DB::Manager::Department->get_all_sorted();
 651   $self->{all_employees}       = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->employee_id,
 652                                                                                        deleted => 0 ] ],
 653                                                                     sort_by => 'name');
 654   $self->{all_salesmen}        = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->salesman_id,
 655                                                                                        deleted => 0 ] ],
 656                                                                     sort_by => 'name');
 657   $self->{all_projects}        = SL::DB::Manager::Project->get_all(where => [ or => [ id => $self->order->globalproject_id,
 658                                                                                       active => 1 ] ],
 659                                                                    sort_by => 'projectnumber');
 660   $self->{all_payment_terms}   = SL::DB::Manager::PaymentTerm->get_all_sorted();
 661   $self->{all_delivery_terms}  = SL::DB::Manager::DeliveryTerm->get_all_sorted();
 662
 663   $self->{current_employee_id} = SL::DB::Manager::Employee->current->id;
 664
 665   foreach  my $item (@{$self->order->items}) {
 666     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
 667     $item->active_price_source(   $price_source->price_from_source(   $item->active_price_source   ));
 668     $item->active_discount_source($price_source->discount_from_source($item->active_discount_source));
 669
 670   }
 671
 672   $::request->{layout}->use_javascript("${_}.js")  for qw(ckeditor/ckeditor ckeditor/adapters/jquery);
 673 }
 674
 675 sub _create_pdf {
 676   my ($order, $pdf_ref, $params) = @_;
 677
 678   my $print_form = Form->new('');
 679   $print_form->{type}     = $order->type;
 680   $print_form->{formname} = $order->type;
 681   $print_form->{format}   = $params->{format} || 'pdf',
 682   $print_form->{media}    = $params->{media}  || 'file';
 683
 684   $order->flatten_to_form($print_form, format_amounts => 1);
 685   # flatten_to_form sets payment_terms from customer/vendor - we do not want that here
 686   delete $print_form->{payment_terms} if !$print_form->{payment_id};
 687
 688   my @errors = ();
 689   $print_form->throw_on_error(sub {
 690     eval {
 691       $print_form->prepare_for_printing;
 692
 693       $$pdf_ref = SL::Helper::CreatePDF->create_pdf(
 694         template  => SL::Helper::CreatePDF->find_template(name => $print_form->{formname}),
 695         variables => $print_form,
 696         variable_content_types => {
 697           longdescription => 'html',
 698           partnotes       => 'html',
 699           notes           => 'html',
 700         },
 701       );
 702       1;
 703     } || push @errors, ref($EVAL_ERROR) eq 'SL::X::FormError' ? $EVAL_ERROR->getMessage : $EVAL_ERROR;
 704   });
 705
 706   return @errors;
 707 }
 708
 709 sub _sales_order_type {
 710   'sales_order';
 711 }
 712
 713 sub _purchase_order_type {
 714   'purchase_order';
 715 }
 716
 717 1;
 718
 719 __END__
 720
 721 =encoding utf-8
 722
 723 =head1 NAME
 724
 725 SL::Controller::Order - controller for orders
 726
 727 =head1 TODO
 728
 729 Testing, PriceSources, pricefactor, units, currency, delivered, delivery order created, ...
 730
 731 =head1 AUTHOR
 732
 733 Bernd Bleßmann E<lt>bernd@kivitendo-premium.deE<gt>
 734
 735 =cut
 736