SL/Controller/Order.pm

   1 package SL::Controller::Order;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use SL::Helper::Flash qw(flash_later);
   7 use SL::Presenter::Tag qw(select_tag hidden_tag div_tag);
   8 use SL::Locale::String qw(t8);
   9 use SL::SessionFile::Random;
  10 use SL::PriceSource;
  11 use SL::Webdav;
  12 use SL::File;
  13 use SL::MIME;
  14 use SL::Util qw(trim);
  15 use SL::YAML;
  16 use SL::DB::Order;
  17 use SL::DB::Default;
  18 use SL::DB::Unit;
  19 use SL::DB::Part;
  20 use SL::DB::PartsGroup;
  21 use SL::DB::Printer;
  22 use SL::DB::Language;
  23 use SL::DB::RecordLink;
  24 use SL::DB::Shipto;
  25 use SL::DB::Translation;
  26
  27 use SL::Helper::CreatePDF qw(:all);
  28 use SL::Helper::PrintOptions;
  29 use SL::Helper::ShippedQty;
  30 use SL::Helper::UserPreferences::PositionsScrollbar;
  31 use SL::Helper::UserPreferences::UpdatePositions;
  32
  33 use SL::Controller::Helper::GetModels;
  34
  35 use List::Util qw(first sum0);
  36 use List::UtilsBy qw(sort_by uniq_by);
  37 use List::MoreUtils qw(any none pairwise first_index);
  38 use English qw(-no_match_vars);
  39 use File::Spec;
  40 use Cwd;
  41 use Sort::Naturally;
  42
  43 use Rose::Object::MakeMethods::Generic
  44 (
  45  scalar => [ qw(item_ids_to_delete is_custom_shipto_to_delete) ],
  46  'scalar --get_set_init' => [ qw(order valid_types type cv p all_price_factors search_cvpartnumber show_update_button) ],
  47 );
  48
  49
  50 # safety
  51 __PACKAGE__->run_before('check_auth');
  52
  53 __PACKAGE__->run_before('recalc',
  54                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice save_and_ap_transaction
  55                                      print send_email) ]);
  56
  57 __PACKAGE__->run_before('get_unalterable_data',
  58                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice save_and_ap_transaction
  59                                      print send_email) ]);
  60
  61 #
  62 # actions
  63 #
  64
  65 # add a new order
  66 sub action_add {
  67   my ($self) = @_;
  68
  69   $self->order->transdate(DateTime->now_local());
  70   my $extra_days = $self->{type} eq 'sales_quotation' ? $::instance_conf->get_reqdate_interval       :
  71                    $self->{type} eq 'sales_order'     ? $::instance_conf->get_delivery_date_interval : 1;
  72   $self->order->reqdate(DateTime->today_local->next_workday(extra_days => $extra_days)) if !$self->order->reqdate;
  73
  74
  75   $self->pre_render();
  76   $self->render(
  77     'order/form',
  78     title => $self->get_title_for('add'),
  79     %{$self->{template_args}}
  80   );
  81 }
  82
  83 # edit an existing order
  84 sub action_edit {
  85   my ($self) = @_;
  86
  87   if ($::form->{id}) {
  88     $self->load_order;
  89
  90   } else {
  91     # this is to edit an order from an unsaved order object
  92
  93     # set item ids to new fake id, to identify them as new items
  94     foreach my $item (@{$self->order->items_sorted}) {
  95       $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
  96     }
  97     # trigger rendering values for second row as hidden, because they
  98     # are loaded only on demand. So we need to keep the values from
  99     # the source.
 100     $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
 101   }
 102
 103   $self->recalc();
 104   $self->pre_render();
 105   $self->render(
 106     'order/form',
 107     title => $self->get_title_for('edit'),
 108     %{$self->{template_args}}
 109   );
 110 }
 111
 112 # edit a collective order (consisting of one or more existing orders)
 113 sub action_edit_collective {
 114   my ($self) = @_;
 115
 116   # collect order ids
 117   my @multi_ids = map {
 118     $_ =~ m{^multi_id_(\d+)$} && $::form->{'multi_id_' . $1} && $::form->{'trans_id_' . $1} && $::form->{'trans_id_' . $1}
 119   } grep { $_ =~ m{^multi_id_\d+$} } keys %$::form;
 120
 121   # fall back to add if no ids are given
 122   if (scalar @multi_ids == 0) {
 123     $self->action_add();
 124     return;
 125   }
 126
 127   # fall back to save as new if only one id is given
 128   if (scalar @multi_ids == 1) {
 129     $self->order(SL::DB::Order->new(id => $multi_ids[0])->load);
 130     $self->action_save_as_new();
 131     return;
 132   }
 133
 134   # make new order from given orders
 135   my @multi_orders = map { SL::DB::Order->new(id => $_)->load } @multi_ids;
 136   $self->{converted_from_oe_id} = join ' ', map { $_->id } @multi_orders;
 137   $self->order(SL::DB::Order->new_from_multi(\@multi_orders, sort_sources_by => 'transdate'));
 138
 139   $self->action_edit();
 140 }
 141
 142 # delete the order
 143 sub action_delete {
 144   my ($self) = @_;
 145
 146   my $errors = $self->delete();
 147
 148   if (scalar @{ $errors }) {
 149     $self->js->flash('error', $_) foreach @{ $errors };
 150     return $self->js->render();
 151   }
 152
 153   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been deleted')
 154            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been deleted')
 155            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been deleted')
 156            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been deleted')
 157            : '';
 158   flash_later('info', $text);
 159
 160   my @redirect_params = (
 161     action => 'add',
 162     type   => $self->type,
 163   );
 164
 165   $self->redirect_to(@redirect_params);
 166 }
 167
 168 # save the order
 169 sub action_save {
 170   my ($self) = @_;
 171
 172   my $errors = $self->save();
 173
 174   if (scalar @{ $errors }) {
 175     $self->js->flash('error', $_) foreach @{ $errors };
 176     return $self->js->render();
 177   }
 178
 179   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
 180            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
 181            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
 182            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
 183            : '';
 184   flash_later('info', $text);
 185
 186   my @redirect_params = (
 187     action => 'edit',
 188     type   => $self->type,
 189     id     => $self->order->id,
 190   );
 191
 192   $self->redirect_to(@redirect_params);
 193 }
 194
 195 # save the order as new document an open it for edit
 196 sub action_save_as_new {
 197   my ($self) = @_;
 198
 199   my $order = $self->order;
 200
 201   if (!$order->id) {
 202     $self->js->flash('error', t8('This object has not been saved yet.'));
 203     return $self->js->render();
 204   }
 205
 206   # load order from db to check if values changed
 207   my $saved_order = SL::DB::Order->new(id => $order->id)->load;
 208
 209   my %new_attrs;
 210   # Lets assign a new number if the user hasn't changed the previous one.
 211   # If it has been changed manually then use it as-is.
 212   $new_attrs{number}    = (trim($order->number) eq $saved_order->number)
 213                         ? ''
 214                         : trim($order->number);
 215
 216   # Clear transdate unless changed
 217   $new_attrs{transdate} = ($order->transdate == $saved_order->transdate)
 218                         ? DateTime->today_local
 219                         : $order->transdate;
 220
 221   # Set new reqdate unless changed
 222   if ($order->reqdate == $saved_order->reqdate) {
 223     my $extra_days = $self->{type} eq 'sales_quotation' ? $::instance_conf->get_reqdate_interval       :
 224                      $self->{type} eq 'sales_order'     ? $::instance_conf->get_delivery_date_interval : 1;
 225     $new_attrs{reqdate} = DateTime->today_local->next_workday(extra_days => $extra_days);
 226   } else {
 227     $new_attrs{reqdate} = $order->reqdate;
 228   }
 229
 230   # Update employee
 231   $new_attrs{employee}  = SL::DB::Manager::Employee->current;
 232
 233   # Create new record from current one
 234   $self->order(SL::DB::Order->new_from($order, destination_type => $order->type, attributes => \%new_attrs));
 235
 236   # no linked records on save as new
 237   delete $::form->{$_} for qw(converted_from_oe_id converted_from_orderitems_ids);
 238
 239   # save
 240   $self->action_save();
 241 }
 242
 243 # print the order
 244 #
 245 # This is called if "print" is pressed in the print dialog.
 246 # If PDF creation was requested and succeeded, the pdf is offered for download
 247 # via send_file (which uses ajax in this case).
 248 sub action_print {
 249   my ($self) = @_;
 250
 251   my $errors = $self->save();
 252
 253   if (scalar @{ $errors }) {
 254     $self->js->flash('error', $_) foreach @{ $errors };
 255     return $self->js->render();
 256   }
 257
 258   $self->js_reset_order_and_item_ids_after_save;
 259
 260   my $format      = $::form->{print_options}->{format};
 261   my $media       = $::form->{print_options}->{media};
 262   my $formname    = $::form->{print_options}->{formname};
 263   my $copies      = $::form->{print_options}->{copies};
 264   my $groupitems  = $::form->{print_options}->{groupitems};
 265   my $printer_id  = $::form->{print_options}->{printer_id};
 266
 267   # only pdf and opendocument by now
 268   if (none { $format eq $_ } qw(pdf opendocument opendocument_pdf)) {
 269     return $self->js->flash('error', t8('Format \'#1\' is not supported yet/anymore.', $format))->render;
 270   }
 271
 272   # only screen or printer by now
 273   if (none { $media eq $_ } qw(screen printer)) {
 274     return $self->js->flash('error', t8('Media \'#1\' is not supported yet/anymore.', $media))->render;
 275   }
 276
 277   # create a form for generate_attachment_filename
 278   my $form   = Form->new;
 279   $form->{$self->nr_key()}  = $self->order->number;
 280   $form->{type}             = $self->type;
 281   $form->{format}           = $format;
 282   $form->{formname}         = $formname;
 283   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 284   my $pdf_filename          = $form->generate_attachment_filename();
 285
 286   my $pdf;
 287   my @errors = generate_pdf($self->order, \$pdf, { format     => $format,
 288                                                    formname   => $formname,
 289                                                    language   => $self->order->language,
 290                                                    printer_id => $printer_id,
 291                                                    groupitems => $groupitems });
 292   if (scalar @errors) {
 293     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render;
 294   }
 295
 296   if ($media eq 'screen') {
 297     # screen/download
 298     $self->js->flash('info', t8('The PDF has been created'));
 299     $self->send_file(
 300       \$pdf,
 301       type         => SL::MIME->mime_type_from_ext($pdf_filename),
 302       name         => $pdf_filename,
 303       js_no_render => 1,
 304     );
 305
 306   } elsif ($media eq 'printer') {
 307     # printer
 308     my $printer_id = $::form->{print_options}->{printer_id};
 309     SL::DB::Printer->new(id => $printer_id)->load->print_document(
 310       copies  => $copies,
 311       content => $pdf,
 312     );
 313
 314     $self->js->flash('info', t8('The PDF has been printed'));
 315   }
 316
 317   # copy file to webdav folder
 318   if ($self->order->number && $::instance_conf->get_webdav_documents) {
 319     my $webdav = SL::Webdav->new(
 320       type     => $self->type,
 321       number   => $self->order->number,
 322     );
 323     my $webdav_file = SL::Webdav::File->new(
 324       webdav   => $webdav,
 325       filename => $pdf_filename,
 326     );
 327     eval {
 328       $webdav_file->store(data => \$pdf);
 329       1;
 330     } or do {
 331       $self->js->flash('error', t8('Storing PDF to webdav folder failed: #1', $@));
 332     }
 333   }
 334   if ($self->order->number && $::instance_conf->get_doc_storage) {
 335     eval {
 336       SL::File->save(object_id     => $self->order->id,
 337                      object_type   => $self->type,
 338                      mime_type     => 'application/pdf',
 339                      source        => 'created',
 340                      file_type     => 'document',
 341                      file_name     => $pdf_filename,
 342                      file_contents => $pdf);
 343       1;
 344     } or do {
 345       $self->js->flash('error', t8('Storing PDF in storage backend failed: #1', $@));
 346     }
 347   }
 348   $self->js->render;
 349 }
 350
 351 # open the email dialog
 352 sub action_save_and_show_email_dialog {
 353   my ($self) = @_;
 354
 355   my $errors = $self->save();
 356
 357   if (scalar @{ $errors }) {
 358     $self->js->flash('error', $_) foreach @{ $errors };
 359     return $self->js->render();
 360   }
 361
 362   my $cv_method = $self->cv;
 363
 364   if (!$self->order->$cv_method) {
 365     return $self->js->flash('error', $self->cv eq 'customer' ? t8('Cannot send E-mail without customer given') : t8('Cannot send E-mail without vendor given'))
 366                     ->render($self);
 367   }
 368
 369   my $email_form;
 370   $email_form->{to}   = $self->order->contact->cp_email if $self->order->contact;
 371   $email_form->{to} ||= $self->order->$cv_method->email;
 372   $email_form->{cc}   = $self->order->$cv_method->cc;
 373   $email_form->{bcc}  = join ', ', grep $_, $self->order->$cv_method->bcc, SL::DB::Default->get->global_bcc;
 374   # Todo: get addresses from shipto, if any
 375
 376   my $form = Form->new;
 377   $form->{$self->nr_key()}  = $self->order->number;
 378   $form->{cusordnumber}     = $self->order->cusordnumber;
 379   $form->{formname}         = $self->type;
 380   $form->{type}             = $self->type;
 381   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 382   $form->{language_id}      = $self->order->language->id                  if $self->order->language;
 383   $form->{format}           = 'pdf';
 384
 385   $email_form->{subject}             = $form->generate_email_subject();
 386   $email_form->{attachment_filename} = $form->generate_attachment_filename();
 387   $email_form->{message}             = $form->generate_email_body();
 388   $email_form->{js_send_function}    = 'kivi.Order.send_email()';
 389
 390   my %files = $self->get_files_for_email_dialog();
 391   my $dialog_html = $self->render('common/_send_email_dialog', { output => 0 },
 392                                   email_form  => $email_form,
 393                                   show_bcc    => $::auth->assert('email_bcc', 'may fail'),
 394                                   FILES       => \%files,
 395                                   is_customer => $self->cv eq 'customer',
 396   );
 397
 398   $self->js
 399       ->run('kivi.Order.show_email_dialog', $dialog_html)
 400       ->reinit_widgets
 401       ->render($self);
 402 }
 403
 404 # send email
 405 #
 406 # Todo: handling error messages: flash is not displayed in dialog, but in the main form
 407 sub action_send_email {
 408   my ($self) = @_;
 409
 410   my $errors = $self->save();
 411
 412   if (scalar @{ $errors }) {
 413     $self->js->run('kivi.Order.close_email_dialog');
 414     $self->js->flash('error', $_) foreach @{ $errors };
 415     return $self->js->render();
 416   }
 417
 418   $self->js_reset_order_and_item_ids_after_save;
 419
 420   my $email_form  = delete $::form->{email_form};
 421   my %field_names = (to => 'email');
 422
 423   $::form->{ $field_names{$_} // $_ } = $email_form->{$_} for keys %{ $email_form };
 424
 425   # for Form::cleanup which may be called in Form::send_email
 426   $::form->{cwd}    = getcwd();
 427   $::form->{tmpdir} = $::lx_office_conf{paths}->{userspath};
 428
 429   $::form->{$_}     = $::form->{print_options}->{$_} for keys %{ $::form->{print_options} };
 430   $::form->{media}  = 'email';
 431
 432   if (($::form->{attachment_policy} // '') !~ m{^(?:old_file|no_file)$}) {
 433     my $pdf;
 434     my @errors = generate_pdf($self->order, \$pdf, {media      => $::form->{media},
 435                                                     format     => $::form->{print_options}->{format},
 436                                                     formname   => $::form->{print_options}->{formname},
 437                                                     language   => $self->order->language,
 438                                                     printer_id => $::form->{print_options}->{printer_id},
 439                                                     groupitems => $::form->{print_options}->{groupitems}});
 440     if (scalar @errors) {
 441       return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render($self);
 442     }
 443
 444     my $sfile = SL::SessionFile::Random->new(mode => "w");
 445     $sfile->fh->print($pdf);
 446     $sfile->fh->close;
 447
 448     $::form->{tmpfile} = $sfile->file_name;
 449     $::form->{tmpdir}  = $sfile->get_path; # for Form::cleanup which may be called in Form::send_email
 450   }
 451
 452   $::form->{id} = $self->order->id; # this is used in SL::Mailer to create a linked record to the mail
 453   $::form->send_email(\%::myconfig, 'pdf');
 454
 455   # internal notes
 456   my $intnotes = $self->order->intnotes;
 457   $intnotes   .= "\n\n" if $self->order->intnotes;
 458   $intnotes   .= t8('[email]')                                                                                        . "\n";
 459   $intnotes   .= t8('Date')       . ": " . $::locale->format_date_object(DateTime->now_local, precision => 'seconds') . "\n";
 460   $intnotes   .= t8('To (email)') . ": " . $::form->{email}                                                           . "\n";
 461   $intnotes   .= t8('Cc')         . ": " . $::form->{cc}                                                              . "\n"    if $::form->{cc};
 462   $intnotes   .= t8('Bcc')        . ": " . $::form->{bcc}                                                             . "\n"    if $::form->{bcc};
 463   $intnotes   .= t8('Subject')    . ": " . $::form->{subject}                                                         . "\n\n";
 464   $intnotes   .= t8('Message')    . ": " . $::form->{message};
 465
 466   $self->order->update_attributes(intnotes => $intnotes);
 467
 468   flash_later('info', t8('The email has been sent.'));
 469
 470   my @redirect_params = (
 471     action => 'edit',
 472     type   => $self->type,
 473     id     => $self->order->id,
 474   );
 475
 476   $self->redirect_to(@redirect_params);
 477 }
 478
 479 # open the periodic invoices config dialog
 480 #
 481 # If there are values in the form (i.e. dialog was opened before),
 482 # then use this values. Create new ones, else.
 483 sub action_show_periodic_invoices_config_dialog {
 484   my ($self) = @_;
 485
 486   my $config = make_periodic_invoices_config_from_yaml(delete $::form->{config});
 487   $config  ||= SL::DB::Manager::PeriodicInvoicesConfig->find_by(oe_id => $::form->{id}) if $::form->{id};
 488   $config  ||= SL::DB::PeriodicInvoicesConfig->new(periodicity             => 'm',
 489                                                    order_value_periodicity => 'p', # = same as periodicity
 490                                                    start_date_as_date      => $::form->{transdate_as_date} || $::form->current_date,
 491                                                    extend_automatically_by => 12,
 492                                                    active                  => 1,
 493                                                    email_subject           => GenericTranslations->get(
 494                                                                                 language_id      => $::form->{language_id},
 495                                                                                 translation_type =>"preset_text_periodic_invoices_email_subject"),
 496                                                    email_body              => GenericTranslations->get(
 497                                                                                 language_id      => $::form->{language_id},
 498                                                                                 translation_type =>"preset_text_periodic_invoices_email_body"),
 499   );
 500   $config->periodicity('m')             if none { $_ eq $config->periodicity             }       @SL::DB::PeriodicInvoicesConfig::PERIODICITIES;
 501   $config->order_value_periodicity('p') if none { $_ eq $config->order_value_periodicity } ('p', @SL::DB::PeriodicInvoicesConfig::ORDER_VALUE_PERIODICITIES);
 502
 503   $::form->get_lists(printers => "ALL_PRINTERS",
 504                      charts   => { key       => 'ALL_CHARTS',
 505                                    transdate => 'current_date' });
 506
 507   $::form->{AR} = [ grep { $_->{link} =~ m/(?:^|:)AR(?::|$)/ } @{ $::form->{ALL_CHARTS} } ];
 508
 509   if ($::form->{customer_id}) {
 510     $::form->{ALL_CONTACTS} = SL::DB::Manager::Contact->get_all_sorted(where => [ cp_cv_id => $::form->{customer_id} ]);
 511     $::form->{email_recipient_invoice_address} = SL::DB::Manager::Customer->find_by(id => $::form->{customer_id})->invoice_mail;
 512   }
 513
 514   $self->render('oe/edit_periodic_invoices_config', { layout => 0 },
 515                 popup_dialog             => 1,
 516                 popup_js_close_function  => 'kivi.Order.close_periodic_invoices_config_dialog()',
 517                 popup_js_assign_function => 'kivi.Order.assign_periodic_invoices_config()',
 518                 config                   => $config,
 519                 %$::form);
 520 }
 521
 522 # assign the values of the periodic invoices config dialog
 523 # as yaml in the hidden tag and set the status.
 524 sub action_assign_periodic_invoices_config {
 525   my ($self) = @_;
 526
 527   $::form->isblank('start_date_as_date', $::locale->text('The start date is missing.'));
 528
 529   my $config = { active                     => $::form->{active}       ? 1 : 0,
 530                  terminated                 => $::form->{terminated}   ? 1 : 0,
 531                  direct_debit               => $::form->{direct_debit} ? 1 : 0,
 532                  periodicity                => (any { $_ eq $::form->{periodicity}             }       @SL::DB::PeriodicInvoicesConfig::PERIODICITIES)              ? $::form->{periodicity}             : 'm',
 533                  order_value_periodicity    => (any { $_ eq $::form->{order_value_periodicity} } ('p', @SL::DB::PeriodicInvoicesConfig::ORDER_VALUE_PERIODICITIES)) ? $::form->{order_value_periodicity} : 'p',
 534                  start_date_as_date         => $::form->{start_date_as_date},
 535                  end_date_as_date           => $::form->{end_date_as_date},
 536                  first_billing_date_as_date => $::form->{first_billing_date_as_date},
 537                  print                      => $::form->{print}      ? 1                         : 0,
 538                  printer_id                 => $::form->{print}      ? $::form->{printer_id} * 1 : undef,
 539                  copies                     => $::form->{copies} * 1 ? $::form->{copies}         : 1,
 540                  extend_automatically_by    => $::form->{extend_automatically_by}    * 1 || undef,
 541                  ar_chart_id                => $::form->{ar_chart_id} * 1,
 542                  send_email                 => $::form->{send_email} ? 1 : 0,
 543                  email_recipient_contact_id => $::form->{email_recipient_contact_id} * 1 || undef,
 544                  email_recipient_address    => $::form->{email_recipient_address},
 545                  email_sender               => $::form->{email_sender},
 546                  email_subject              => $::form->{email_subject},
 547                  email_body                 => $::form->{email_body},
 548                };
 549
 550   my $periodic_invoices_config = SL::YAML::Dump($config);
 551
 552   my $status = $self->get_periodic_invoices_status($config);
 553
 554   $self->js
 555     ->remove('#order_periodic_invoices_config')
 556     ->insertAfter(hidden_tag('order.periodic_invoices_config', $periodic_invoices_config), '#periodic_invoices_status')
 557     ->run('kivi.Order.close_periodic_invoices_config_dialog')
 558     ->html('#periodic_invoices_status', $status)
 559     ->flash('info', t8('The periodic invoices config has been assigned.'))
 560     ->render($self);
 561 }
 562
 563 sub action_get_has_active_periodic_invoices {
 564   my ($self) = @_;
 565
 566   my $config = make_periodic_invoices_config_from_yaml(delete $::form->{config});
 567   $config  ||= SL::DB::Manager::PeriodicInvoicesConfig->find_by(oe_id => $::form->{id}) if $::form->{id};
 568
 569   my $has_active_periodic_invoices =
 570        $self->type eq sales_order_type()
 571     && $config
 572     && $config->active
 573     && (!$config->end_date || ($config->end_date > DateTime->today_local))
 574     && $config->get_previous_billed_period_start_date;
 575
 576   $_[0]->render(\ !!$has_active_periodic_invoices, { type => 'text' });
 577 }
 578
 579 # save the order and redirect to the frontend subroutine for a new
 580 # delivery order
 581 sub action_save_and_delivery_order {
 582   my ($self) = @_;
 583
 584   $self->save_and_redirect_to(
 585     controller => 'oe.pl',
 586     action     => 'oe_delivery_order_from_order',
 587   );
 588 }
 589
 590 # save the order and redirect to the frontend subroutine for a new
 591 # invoice
 592 sub action_save_and_invoice {
 593   my ($self) = @_;
 594
 595   $self->save_and_redirect_to(
 596     controller => 'oe.pl',
 597     action     => 'oe_invoice_from_order',
 598   );
 599 }
 600
 601 # workflow from sales order to sales quotation
 602 sub action_sales_quotation {
 603   $_[0]->workflow_sales_or_request_for_quotation();
 604 }
 605
 606 # workflow from sales order to sales quotation
 607 sub action_request_for_quotation {
 608   $_[0]->workflow_sales_or_request_for_quotation();
 609 }
 610
 611 # workflow from sales quotation to sales order
 612 sub action_sales_order {
 613   $_[0]->workflow_sales_or_purchase_order();
 614 }
 615
 616 # workflow from rfq to purchase order
 617 sub action_purchase_order {
 618   $_[0]->workflow_sales_or_purchase_order();
 619 }
 620
 621 # workflow from purchase order to ap transaction
 622 sub action_save_and_ap_transaction {
 623   my ($self) = @_;
 624
 625   $self->save_and_redirect_to(
 626     controller => 'ap.pl',
 627     action     => 'add_from_purchase_order',
 628   );
 629 }
 630
 631 # set form elements in respect to a changed customer or vendor
 632 #
 633 # This action is called on an change of the customer/vendor picker.
 634 sub action_customer_vendor_changed {
 635   my ($self) = @_;
 636
 637   setup_order_from_cv($self->order);
 638   $self->recalc();
 639
 640   my $cv_method = $self->cv;
 641
 642   if ($self->order->$cv_method->contacts && scalar @{ $self->order->$cv_method->contacts } > 0) {
 643     $self->js->show('#cp_row');
 644   } else {
 645     $self->js->hide('#cp_row');
 646   }
 647
 648   if ($self->order->$cv_method->shipto && scalar @{ $self->order->$cv_method->shipto } > 0) {
 649     $self->js->show('#shipto_selection');
 650   } else {
 651     $self->js->hide('#shipto_selection');
 652   }
 653
 654   $self->js->val( '#order_salesman_id',      $self->order->salesman_id)        if $self->order->is_sales;
 655
 656   $self->js
 657     ->replaceWith('#order_cp_id',            $self->build_contact_select)
 658     ->replaceWith('#order_shipto_id',        $self->build_shipto_select)
 659     ->replaceWith('#shipto_inputs  ',        $self->build_shipto_inputs)
 660     ->replaceWith('#business_info_row',      $self->build_business_info_row)
 661     ->val(        '#order_taxzone_id',       $self->order->taxzone_id)
 662     ->val(        '#order_taxincluded',      $self->order->taxincluded)
 663     ->val(        '#order_currency_id',      $self->order->currency_id)
 664     ->val(        '#order_payment_id',       $self->order->payment_id)
 665     ->val(        '#order_delivery_term_id', $self->order->delivery_term_id)
 666     ->val(        '#order_intnotes',         $self->order->intnotes)
 667     ->val(        '#order_language_id',      $self->order->$cv_method->language_id)
 668     ->focus(      '#order_' . $self->cv . '_id')
 669     ->run('kivi.Order.update_exchangerate');
 670
 671   $self->js_redisplay_amounts_and_taxes;
 672   $self->js_redisplay_cvpartnumbers;
 673   $self->js->render();
 674 }
 675
 676 # open the dialog for customer/vendor details
 677 sub action_show_customer_vendor_details_dialog {
 678   my ($self) = @_;
 679
 680   my $is_customer = 'customer' eq $::form->{vc};
 681   my $cv;
 682   if ($is_customer) {
 683     $cv = SL::DB::Customer->new(id => $::form->{vc_id})->load;
 684   } else {
 685     $cv = SL::DB::Vendor->new(id => $::form->{vc_id})->load;
 686   }
 687
 688   my %details = map { $_ => $cv->$_ } @{$cv->meta->columns};
 689   $details{discount_as_percent} = $cv->discount_as_percent;
 690   $details{creditlimt}          = $cv->creditlimit_as_number;
 691   $details{business}            = $cv->business->description      if $cv->business;
 692   $details{language}            = $cv->language_obj->description  if $cv->language_obj;
 693   $details{delivery_terms}      = $cv->delivery_term->description if $cv->delivery_term;
 694   $details{payment_terms}       = $cv->payment->description       if $cv->payment;
 695   $details{pricegroup}          = $cv->pricegroup->pricegroup     if $is_customer && $cv->pricegroup;
 696
 697   foreach my $entry (@{ $cv->shipto }) {
 698     push @{ $details{SHIPTO} },   { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 699   }
 700   foreach my $entry (@{ $cv->contacts }) {
 701     push @{ $details{CONTACTS} }, { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 702   }
 703
 704   $_[0]->render('common/show_vc_details', { layout => 0 },
 705                 is_customer => $is_customer,
 706                 %details);
 707
 708 }
 709
 710 # called if a unit in an existing item row is changed
 711 sub action_unit_changed {
 712   my ($self) = @_;
 713
 714   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 715   my $item = $self->order->items_sorted->[$idx];
 716
 717   my $old_unit_obj = SL::DB::Unit->new(name => $::form->{old_unit})->load;
 718   $item->sellprice($item->unit_obj->convert_to($item->sellprice, $old_unit_obj));
 719
 720   $self->recalc();
 721
 722   $self->js
 723     ->run('kivi.Order.update_sellprice', $::form->{item_id}, $item->sellprice_as_number);
 724   $self->js_redisplay_line_values;
 725   $self->js_redisplay_amounts_and_taxes;
 726   $self->js->render();
 727 }
 728
 729 # add an item row for a new item entered in the input row
 730 sub action_add_item {
 731   my ($self) = @_;
 732
 733   my $form_attr = $::form->{add_item};
 734
 735   return unless $form_attr->{parts_id};
 736
 737   my $item = new_item($self->order, $form_attr);
 738
 739   $self->order->add_items($item);
 740
 741   $self->recalc();
 742
 743   $self->get_item_cvpartnumber($item);
 744
 745   my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 746   my $row_as_html = $self->p->render('order/tabs/_row',
 747                                      ITEM => $item,
 748                                      ID   => $item_id,
 749                                      SELF => $self,
 750   );
 751
 752   if ($::form->{insert_before_item_id}) {
 753     $self->js
 754       ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 755   } else {
 756     $self->js
 757       ->append('#row_table_id', $row_as_html);
 758   }
 759
 760   if ( $item->part->is_assortment ) {
 761     $form_attr->{qty_as_number} = 1 unless $form_attr->{qty_as_number};
 762     foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 763       my $attr = { parts_id => $assortment_item->parts_id,
 764                    qty      => $assortment_item->qty * $::form->parse_amount(\%::myconfig, $form_attr->{qty_as_number}), # TODO $form_attr->{unit}
 765                    unit     => $assortment_item->unit,
 766                    description => $assortment_item->part->description,
 767                  };
 768       my $item = new_item($self->order, $attr);
 769
 770       # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 771       $item->discount(1) unless $assortment_item->charge;
 772
 773       $self->order->add_items( $item );
 774       $self->recalc();
 775       $self->get_item_cvpartnumber($item);
 776       my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 777       my $row_as_html = $self->p->render('order/tabs/_row',
 778                                          ITEM => $item,
 779                                          ID   => $item_id,
 780                                          SELF => $self,
 781       );
 782       if ($::form->{insert_before_item_id}) {
 783         $self->js
 784           ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 785       } else {
 786         $self->js
 787           ->append('#row_table_id', $row_as_html);
 788       }
 789     };
 790   };
 791
 792   $self->js
 793     ->val('.add_item_input', '')
 794     ->run('kivi.Order.init_row_handlers')
 795     ->run('kivi.Order.renumber_positions')
 796     ->focus('#add_item_parts_id_name');
 797
 798   $self->js->run('kivi.Order.row_table_scroll_down') if !$::form->{insert_before_item_id};
 799
 800   $self->js_redisplay_amounts_and_taxes;
 801   $self->js->render();
 802 }
 803
 804 # add item rows for multiple items at once
 805 sub action_add_multi_items {
 806   my ($self) = @_;
 807
 808   my @form_attr = grep { $_->{qty_as_number} } @{ $::form->{add_items} };
 809   return $self->js->render() unless scalar @form_attr;
 810
 811   my @items;
 812   foreach my $attr (@form_attr) {
 813     my $item = new_item($self->order, $attr);
 814     push @items, $item;
 815     if ( $item->part->is_assortment ) {
 816       foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 817         my $attr = { parts_id => $assortment_item->parts_id,
 818                      qty      => $assortment_item->qty * $item->qty, # TODO $form_attr->{unit}
 819                      unit     => $assortment_item->unit,
 820                      description => $assortment_item->part->description,
 821                    };
 822         my $item = new_item($self->order, $attr);
 823
 824         # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 825         $item->discount(1) unless $assortment_item->charge;
 826         push @items, $item;
 827       }
 828     }
 829   }
 830   $self->order->add_items(@items);
 831
 832   $self->recalc();
 833
 834   foreach my $item (@items) {
 835     $self->get_item_cvpartnumber($item);
 836     my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 837     my $row_as_html = $self->p->render('order/tabs/_row',
 838                                        ITEM => $item,
 839                                        ID   => $item_id,
 840                                        SELF => $self,
 841     );
 842
 843     if ($::form->{insert_before_item_id}) {
 844       $self->js
 845         ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 846     } else {
 847       $self->js
 848         ->append('#row_table_id', $row_as_html);
 849     }
 850   }
 851
 852   $self->js
 853     ->run('kivi.Part.close_picker_dialogs')
 854     ->run('kivi.Order.init_row_handlers')
 855     ->run('kivi.Order.renumber_positions')
 856     ->focus('#add_item_parts_id_name');
 857
 858   $self->js->run('kivi.Order.row_table_scroll_down') if !$::form->{insert_before_item_id};
 859
 860   $self->js_redisplay_amounts_and_taxes;
 861   $self->js->render();
 862 }
 863
 864 # recalculate all linetotals, amounts and taxes and redisplay them
 865 sub action_recalc_amounts_and_taxes {
 866   my ($self) = @_;
 867
 868   $self->recalc();
 869
 870   $self->js_redisplay_line_values;
 871   $self->js_redisplay_amounts_and_taxes;
 872   $self->js->render();
 873 }
 874
 875 sub action_update_exchangerate {
 876   my ($self) = @_;
 877
 878   my $data = {
 879     is_standard   => $self->order->currency_id == $::instance_conf->get_currency_id,
 880     currency_name => $self->order->currency->name,
 881     exchangerate  => $self->order->daily_exchangerate_as_null_number,
 882   };
 883
 884   $self->render(\SL::JSON::to_json($data), { type => 'json', process => 0 });
 885 }
 886
 887 # redisplay item rows if they are sorted by an attribute
 888 sub action_reorder_items {
 889   my ($self) = @_;
 890
 891   my %sort_keys = (
 892     partnumber   => sub { $_[0]->part->partnumber },
 893     description  => sub { $_[0]->description },
 894     qty          => sub { $_[0]->qty },
 895     sellprice    => sub { $_[0]->sellprice },
 896     discount     => sub { $_[0]->discount },
 897     cvpartnumber => sub { $_[0]->{cvpartnumber} },
 898   );
 899
 900   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
 901
 902   my $method = $sort_keys{$::form->{order_by}};
 903   my @to_sort = map { { old_pos => $_->position, order_by => $method->($_) } } @{ $self->order->items_sorted };
 904   if ($::form->{sort_dir}) {
 905     if ( $::form->{order_by} =~ m/qty|sellprice|discount/ ){
 906       @to_sort = sort { $a->{order_by} <=> $b->{order_by} } @to_sort;
 907     } else {
 908       @to_sort = sort { $a->{order_by} cmp $b->{order_by} } @to_sort;
 909     }
 910   } else {
 911     if ( $::form->{order_by} =~ m/qty|sellprice|discount/ ){
 912       @to_sort = sort { $b->{order_by} <=> $a->{order_by} } @to_sort;
 913     } else {
 914       @to_sort = sort { $b->{order_by} cmp $a->{order_by} } @to_sort;
 915     }
 916   }
 917   $self->js
 918     ->run('kivi.Order.redisplay_items', \@to_sort)
 919     ->render;
 920 }
 921
 922 # show the popup to choose a price/discount source
 923 sub action_price_popup {
 924   my ($self) = @_;
 925
 926   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 927   my $item = $self->order->items_sorted->[$idx];
 928
 929   $self->render_price_dialog($item);
 930 }
 931
 932 # load the second row for one or more items
 933 #
 934 # This action gets the html code for all items second rows by rendering a template for
 935 # the second row and sets the html code via client js.
 936 sub action_load_second_rows {
 937   my ($self) = @_;
 938
 939   $self->recalc() if $self->order->is_sales; # for margin calculation
 940
 941   foreach my $item_id (@{ $::form->{item_ids} }) {
 942     my $idx  = first_index { $_ eq $item_id } @{ $::form->{orderitem_ids} };
 943     my $item = $self->order->items_sorted->[$idx];
 944
 945     $self->js_load_second_row($item, $item_id, 0);
 946   }
 947
 948   $self->js->run('kivi.Order.init_row_handlers') if $self->order->is_sales; # for lastcosts change-callback
 949
 950   $self->js->render();
 951 }
 952
 953 # update description, notes and sellprice from master data
 954 sub action_update_row_from_master_data {
 955   my ($self) = @_;
 956
 957   foreach my $item_id (@{ $::form->{item_ids} }) {
 958     my $idx   = first_index { $_ eq $item_id } @{ $::form->{orderitem_ids} };
 959     my $item  = $self->order->items_sorted->[$idx];
 960     my $texts = get_part_texts($item->part, $self->order->language_id);
 961
 962     $item->description($texts->{description});
 963     $item->longdescription($texts->{longdescription});
 964
 965     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
 966
 967     my $price_src;
 968     if ($item->part->is_assortment) {
 969     # add assortment items with price 0, as the components carry the price
 970       $price_src = $price_source->price_from_source("");
 971       $price_src->price(0);
 972     } else {
 973       $price_src = $price_source->best_price
 974                  ? $price_source->best_price
 975                  : $price_source->price_from_source("");
 976       $price_src->price($::form->round_amount($price_src->price / $self->order->exchangerate, 5)) if $self->order->exchangerate;
 977       $price_src->price(0) if !$price_source->best_price;
 978     }
 979
 980
 981     $item->sellprice($price_src->price);
 982     $item->active_price_source($price_src);
 983
 984     $self->js
 985       ->run('kivi.Order.update_sellprice', $item_id, $item->sellprice_as_number)
 986       ->html('.row_entry:has(#item_' . $item_id . ') [name = "partnumber"] a', $item->part->partnumber)
 987       ->val ('.row_entry:has(#item_' . $item_id . ') [name = "order.orderitems[].description"]', $item->description)
 988       ->val ('.row_entry:has(#item_' . $item_id . ') [name = "order.orderitems[].longdescription"]', $item->longdescription);
 989
 990     if ($self->search_cvpartnumber) {
 991       $self->get_item_cvpartnumber($item);
 992       $self->js->html('.row_entry:has(#item_' . $item_id . ') [name = "cvpartnumber"]', $item->{cvpartnumber});
 993     }
 994   }
 995
 996   $self->recalc();
 997   $self->js_redisplay_line_values;
 998   $self->js_redisplay_amounts_and_taxes;
 999
1000   $self->js->render();
1001 }
1002
1003 sub js_load_second_row {
1004   my ($self, $item, $item_id, $do_parse) = @_;
1005
1006   if ($do_parse) {
1007     # Parse values from form (they are formated while rendering (template)).
1008     # Workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
1009     # This parsing is not necessary at all, if we assure that the second row/cvars are only loaded once.
1010     foreach my $var (@{ $item->cvars_by_config }) {
1011       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
1012     }
1013     $item->parse_custom_variable_values;
1014   }
1015
1016   my $row_as_html = $self->p->render('order/tabs/_second_row', ITEM => $item, TYPE => $self->type);
1017
1018   $self->js
1019     ->html('#second_row_' . $item_id, $row_as_html)
1020     ->data('#second_row_' . $item_id, 'loaded', 1);
1021 }
1022
1023 sub js_redisplay_line_values {
1024   my ($self) = @_;
1025
1026   my $is_sales = $self->order->is_sales;
1027
1028   # sales orders with margins
1029   my @data;
1030   if ($is_sales) {
1031     @data = map {
1032       [
1033        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
1034        $::form->format_amount(\%::myconfig, $_->{marge_total},   2, 0),
1035        $::form->format_amount(\%::myconfig, $_->{marge_percent}, 2, 0),
1036       ]} @{ $self->order->items_sorted };
1037   } else {
1038     @data = map {
1039       [
1040        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
1041       ]} @{ $self->order->items_sorted };
1042   }
1043
1044   $self->js
1045     ->run('kivi.Order.redisplay_line_values', $is_sales, \@data);
1046 }
1047
1048 sub js_redisplay_amounts_and_taxes {
1049   my ($self) = @_;
1050
1051   if (scalar @{ $self->{taxes} }) {
1052     $self->js->show('#taxincluded_row_id');
1053   } else {
1054     $self->js->hide('#taxincluded_row_id');
1055   }
1056
1057   if ($self->order->taxincluded) {
1058     $self->js->hide('#subtotal_row_id');
1059   } else {
1060     $self->js->show('#subtotal_row_id');
1061   }
1062
1063   if ($self->order->is_sales) {
1064     my $is_neg = $self->order->marge_total < 0;
1065     $self->js
1066       ->html('#marge_total_id',   $::form->format_amount(\%::myconfig, $self->order->marge_total,   2))
1067       ->html('#marge_percent_id', $::form->format_amount(\%::myconfig, $self->order->marge_percent, 2))
1068       ->action_if( $is_neg, 'addClass',    '#marge_total_id',        'plus0')
1069       ->action_if( $is_neg, 'addClass',    '#marge_percent_id',      'plus0')
1070       ->action_if( $is_neg, 'addClass',    '#marge_percent_sign_id', 'plus0')
1071       ->action_if(!$is_neg, 'removeClass', '#marge_total_id',        'plus0')
1072       ->action_if(!$is_neg, 'removeClass', '#marge_percent_id',      'plus0')
1073       ->action_if(!$is_neg, 'removeClass', '#marge_percent_sign_id', 'plus0');
1074   }
1075
1076   $self->js
1077     ->html('#netamount_id', $::form->format_amount(\%::myconfig, $self->order->netamount, -2))
1078     ->html('#amount_id',    $::form->format_amount(\%::myconfig, $self->order->amount,    -2))
1079     ->remove('.tax_row')
1080     ->insertBefore($self->build_tax_rows, '#amount_row_id');
1081 }
1082
1083 sub js_redisplay_cvpartnumbers {
1084   my ($self) = @_;
1085
1086   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
1087
1088   my @data = map {[$_->{cvpartnumber}]} @{ $self->order->items_sorted };
1089
1090   $self->js
1091     ->run('kivi.Order.redisplay_cvpartnumbers', \@data);
1092 }
1093
1094 sub js_reset_order_and_item_ids_after_save {
1095   my ($self) = @_;
1096
1097   $self->js
1098     ->val('#id', $self->order->id)
1099     ->val('#converted_from_oe_id', '')
1100     ->val('#order_' . $self->nr_key(), $self->order->number);
1101
1102   my $idx = 0;
1103   foreach my $form_item_id (@{ $::form->{orderitem_ids} }) {
1104     next if !$self->order->items_sorted->[$idx]->id;
1105     next if $form_item_id !~ m{^new};
1106     $self->js
1107       ->val ('[name="orderitem_ids[+]"][value="' . $form_item_id . '"]', $self->order->items_sorted->[$idx]->id)
1108       ->val ('#item_' . $form_item_id, $self->order->items_sorted->[$idx]->id)
1109       ->attr('#item_' . $form_item_id, "id", 'item_' . $self->order->items_sorted->[$idx]->id);
1110   } continue {
1111     $idx++;
1112   }
1113   $self->js->val('[name="converted_from_orderitems_ids[+]"]', '');
1114 }
1115
1116 #
1117 # helpers
1118 #
1119
1120 sub init_valid_types {
1121   [ sales_order_type(), purchase_order_type(), sales_quotation_type(), request_quotation_type() ];
1122 }
1123
1124 sub init_type {
1125   my ($self) = @_;
1126
1127   if (none { $::form->{type} eq $_ } @{$self->valid_types}) {
1128     die "Not a valid type for order";
1129   }
1130
1131   $self->type($::form->{type});
1132 }
1133
1134 sub init_cv {
1135   my ($self) = @_;
1136
1137   my $cv = (any { $self->type eq $_ } (sales_order_type(),    sales_quotation_type()))   ? 'customer'
1138          : (any { $self->type eq $_ } (purchase_order_type(), request_quotation_type())) ? 'vendor'
1139          : die "Not a valid type for order";
1140
1141   return $cv;
1142 }
1143
1144 sub init_search_cvpartnumber {
1145   my ($self) = @_;
1146
1147   my $user_prefs = SL::Helper::UserPreferences::PartPickerSearch->new();
1148   my $search_cvpartnumber;
1149   $search_cvpartnumber = !!$user_prefs->get_sales_search_customer_partnumber() if $self->cv eq 'customer';
1150   $search_cvpartnumber = !!$user_prefs->get_purchase_search_makemodel()        if $self->cv eq 'vendor';
1151
1152   return $search_cvpartnumber;
1153 }
1154
1155 sub init_show_update_button {
1156   my ($self) = @_;
1157
1158   !!SL::Helper::UserPreferences::UpdatePositions->new()->get_show_update_button();
1159 }
1160
1161 sub init_p {
1162   SL::Presenter->get;
1163 }
1164
1165 sub init_order {
1166   $_[0]->make_order;
1167 }
1168
1169 sub init_all_price_factors {
1170   SL::DB::Manager::PriceFactor->get_all;
1171 }
1172
1173 sub check_auth {
1174   my ($self) = @_;
1175
1176   my $right_for = { map { $_ => $_.'_edit' } @{$self->valid_types} };
1177
1178   my $right   = $right_for->{ $self->type };
1179   $right    ||= 'DOES_NOT_EXIST';
1180
1181   $::auth->assert($right);
1182 }
1183
1184 # build the selection box for contacts
1185 #
1186 # Needed, if customer/vendor changed.
1187 sub build_contact_select {
1188   my ($self) = @_;
1189
1190   select_tag('order.cp_id', [ $self->order->{$self->cv}->contacts ],
1191     value_key  => 'cp_id',
1192     title_key  => 'full_name_dep',
1193     default    => $self->order->cp_id,
1194     with_empty => 1,
1195     style      => 'width: 300px',
1196   );
1197 }
1198
1199 # build the selection box for shiptos
1200 #
1201 # Needed, if customer/vendor changed.
1202 sub build_shipto_select {
1203   my ($self) = @_;
1204
1205   select_tag('order.shipto_id',
1206              [ {displayable_id => t8("No/individual shipping address"), shipto_id => ''}, $self->order->{$self->cv}->shipto ],
1207              value_key  => 'shipto_id',
1208              title_key  => 'displayable_id',
1209              default    => $self->order->shipto_id,
1210              with_empty => 0,
1211              style      => 'width: 300px',
1212   );
1213 }
1214
1215 # build the inputs for the cusom shipto dialog
1216 #
1217 # Needed, if customer/vendor changed.
1218 sub build_shipto_inputs {
1219   my ($self) = @_;
1220
1221   my $content = $self->p->render('common/_ship_to_dialog',
1222                                  vc_obj      => $self->order->customervendor,
1223                                  cs_obj      => $self->order->custom_shipto,
1224                                  cvars       => $self->order->custom_shipto->cvars_by_config,
1225                                  id_selector => '#order_shipto_id');
1226
1227   div_tag($content, id => 'shipto_inputs');
1228 }
1229
1230 # render the info line for business
1231 #
1232 # Needed, if customer/vendor changed.
1233 sub build_business_info_row
1234 {
1235   $_[0]->p->render('order/tabs/_business_info_row', SELF => $_[0]);
1236 }
1237
1238 # build the rows for displaying taxes
1239 #
1240 # Called if amounts where recalculated and redisplayed.
1241 sub build_tax_rows {
1242   my ($self) = @_;
1243
1244   my $rows_as_html;
1245   foreach my $tax (sort { $a->{tax}->rate cmp $b->{tax}->rate } @{ $self->{taxes} }) {
1246     $rows_as_html .= $self->p->render('order/tabs/_tax_row', TAX => $tax, TAXINCLUDED => $self->order->taxincluded);
1247   }
1248   return $rows_as_html;
1249 }
1250
1251
1252 sub render_price_dialog {
1253   my ($self, $record_item) = @_;
1254
1255   my $price_source = SL::PriceSource->new(record_item => $record_item, record => $self->order);
1256
1257   $self->js
1258     ->run(
1259       'kivi.io.price_chooser_dialog',
1260       t8('Available Prices'),
1261       $self->render('order/tabs/_price_sources_dialog', { output => 0 }, price_source => $price_source)
1262     )
1263     ->reinit_widgets;
1264
1265 #   if (@errors) {
1266 #     $self->js->text('#dialog_flash_error_content', join ' ', @errors);
1267 #     $self->js->show('#dialog_flash_error');
1268 #   }
1269
1270   $self->js->render;
1271 }
1272
1273 sub load_order {
1274   my ($self) = @_;
1275
1276   return if !$::form->{id};
1277
1278   $self->order(SL::DB::Order->new(id => $::form->{id})->load);
1279
1280   # Add an empty custom shipto to the order, so that the dialog can render the cvar inputs.
1281   # You need a custom shipto object to call cvars_by_config to get the cvars.
1282   $self->order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => [])) if !$self->order->custom_shipto;
1283
1284   return $self->order;
1285 }
1286
1287 # load or create a new order object
1288 #
1289 # And assign changes from the form to this object.
1290 # If the order is loaded from db, check if items are deleted in the form,
1291 # remove them form the object and collect them for removing from db on saving.
1292 # Then create/update items from form (via make_item) and add them.
1293 sub make_order {
1294   my ($self) = @_;
1295
1296   # add_items adds items to an order with no items for saving, but they cannot
1297   # be retrieved via items until the order is saved. Adding empty items to new
1298   # order here solves this problem.
1299   my $order;
1300   $order   = SL::DB::Order->new(id => $::form->{id})->load(with => [ 'orderitems', 'orderitems.part' ]) if $::form->{id};
1301   $order ||= SL::DB::Order->new(orderitems  => [],
1302                                 quotation   => (any { $self->type eq $_ } (sales_quotation_type(), request_quotation_type())),
1303                                 currency_id => $::instance_conf->get_currency_id(),);
1304
1305   my $cv_id_method = $self->cv . '_id';
1306   if (!$::form->{id} && $::form->{$cv_id_method}) {
1307     $order->$cv_id_method($::form->{$cv_id_method});
1308     setup_order_from_cv($order);
1309   }
1310
1311   my $form_orderitems                  = delete $::form->{order}->{orderitems};
1312   my $form_periodic_invoices_config    = delete $::form->{order}->{periodic_invoices_config};
1313
1314   $order->assign_attributes(%{$::form->{order}});
1315
1316   $self->setup_custom_shipto_from_form($order, $::form);
1317
1318   if (my $periodic_invoices_config_attrs = $form_periodic_invoices_config ? SL::YAML::Load($form_periodic_invoices_config) : undef) {
1319     my $periodic_invoices_config = $order->periodic_invoices_config || $order->periodic_invoices_config(SL::DB::PeriodicInvoicesConfig->new);
1320     $periodic_invoices_config->assign_attributes(%$periodic_invoices_config_attrs);
1321   }
1322
1323   # remove deleted items
1324   $self->item_ids_to_delete([]);
1325   foreach my $idx (reverse 0..$#{$order->orderitems}) {
1326     my $item = $order->orderitems->[$idx];
1327     if (none { $item->id == $_->{id} } @{$form_orderitems}) {
1328       splice @{$order->orderitems}, $idx, 1;
1329       push @{$self->item_ids_to_delete}, $item->id;
1330     }
1331   }
1332
1333   my @items;
1334   my $pos = 1;
1335   foreach my $form_attr (@{$form_orderitems}) {
1336     my $item = make_item($order, $form_attr);
1337     $item->position($pos);
1338     push @items, $item;
1339     $pos++;
1340   }
1341   $order->add_items(grep {!$_->id} @items);
1342
1343   return $order;
1344 }
1345
1346 # create or update items from form
1347 #
1348 # Make item objects from form values. For items already existing read from db.
1349 # Create a new item else. And assign attributes.
1350 sub make_item {
1351   my ($record, $attr) = @_;
1352
1353   my $item;
1354   $item = first { $_->id == $attr->{id} } @{$record->items} if $attr->{id};
1355
1356   my $is_new = !$item;
1357
1358   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1359   # they cannot be retrieved via custom_variables until the order/orderitem is
1360   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1361   $item ||= SL::DB::OrderItem->new(custom_variables => []);
1362
1363   $item->assign_attributes(%$attr);
1364
1365   if ($is_new) {
1366     my $texts = get_part_texts($item->part, $record->language_id);
1367     $item->longdescription($texts->{longdescription})              if !defined $attr->{longdescription};
1368     $item->project_id($record->globalproject_id)                   if !defined $attr->{project_id};
1369     $item->lastcost($record->is_sales ? $item->part->lastcost : 0) if !defined $attr->{lastcost_as_number};
1370   }
1371
1372   return $item;
1373 }
1374
1375 # create a new item
1376 #
1377 # This is used to add one item
1378 sub new_item {
1379   my ($record, $attr) = @_;
1380
1381   my $item = SL::DB::OrderItem->new;
1382
1383   # Remove attributes where the user left or set the inputs empty.
1384   # So these attributes will be undefined and we can distinguish them
1385   # from zero later on.
1386   for (qw(qty_as_number sellprice_as_number discount_as_percent)) {
1387     delete $attr->{$_} if $attr->{$_} eq '';
1388   }
1389
1390   $item->assign_attributes(%$attr);
1391
1392   my $part         = SL::DB::Part->new(id => $attr->{parts_id})->load;
1393   my $price_source = SL::PriceSource->new(record_item => $item, record => $record);
1394
1395   $item->unit($part->unit) if !$item->unit;
1396
1397   my $price_src;
1398   if ( $part->is_assortment ) {
1399     # add assortment items with price 0, as the components carry the price
1400     $price_src = $price_source->price_from_source("");
1401     $price_src->price(0);
1402   } elsif (defined $item->sellprice) {
1403     $price_src = $price_source->price_from_source("");
1404     $price_src->price($item->sellprice);
1405   } else {
1406     $price_src = $price_source->best_price
1407                ? $price_source->best_price
1408                : $price_source->price_from_source("");
1409     $price_src->price($::form->round_amount($price_src->price / $record->exchangerate, 5)) if $record->exchangerate;
1410     $price_src->price(0) if !$price_source->best_price;
1411   }
1412
1413   my $discount_src;
1414   if (defined $item->discount) {
1415     $discount_src = $price_source->discount_from_source("");
1416     $discount_src->discount($item->discount);
1417   } else {
1418     $discount_src = $price_source->best_discount
1419                   ? $price_source->best_discount
1420                   : $price_source->discount_from_source("");
1421     $discount_src->discount(0) if !$price_source->best_discount;
1422   }
1423
1424   my %new_attr;
1425   $new_attr{part}                   = $part;
1426   $new_attr{description}            = $part->description     if ! $item->description;
1427   $new_attr{qty}                    = 1.0                    if ! $item->qty;
1428   $new_attr{price_factor_id}        = $part->price_factor_id if ! $item->price_factor_id;
1429   $new_attr{sellprice}              = $price_src->price;
1430   $new_attr{discount}               = $discount_src->discount;
1431   $new_attr{active_price_source}    = $price_src;
1432   $new_attr{active_discount_source} = $discount_src;
1433   $new_attr{longdescription}        = $part->notes           if ! defined $attr->{longdescription};
1434   $new_attr{project_id}             = $record->globalproject_id;
1435   $new_attr{lastcost}               = $record->is_sales ? $part->lastcost : 0;
1436
1437   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1438   # they cannot be retrieved via custom_variables until the order/orderitem is
1439   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1440   $new_attr{custom_variables} = [];
1441
1442   my $texts = get_part_texts($part, $record->language_id, description => $new_attr{description}, longdescription => $new_attr{longdescription});
1443
1444   $item->assign_attributes(%new_attr, %{ $texts });
1445
1446   return $item;
1447 }
1448
1449 sub setup_order_from_cv {
1450   my ($order) = @_;
1451
1452   $order->$_($order->customervendor->$_) for (qw(taxzone_id payment_id delivery_term_id currency_id));
1453
1454   $order->intnotes($order->customervendor->notes);
1455
1456   if ($order->is_sales) {
1457     $order->salesman_id($order->customer->salesman_id || SL::DB::Manager::Employee->current->id);
1458     $order->taxincluded(defined($order->customer->taxincluded_checked)
1459                         ? $order->customer->taxincluded_checked
1460                         : $::myconfig{taxincluded_checked});
1461   }
1462
1463 }
1464
1465 # setup custom shipto from form
1466 #
1467 # The dialog returns form variables starting with 'shipto' and cvars starting
1468 # with 'shiptocvar_'.
1469 # Mark it to be deleted if a shipto from master data is selected
1470 # (i.e. order has a shipto).
1471 # Else, update or create a new custom shipto. If the fields are empty, it
1472 # will not be saved on save.
1473 sub setup_custom_shipto_from_form {
1474   my ($self, $order, $form) = @_;
1475
1476   if ($order->shipto) {
1477     $self->is_custom_shipto_to_delete(1);
1478   } else {
1479     my $custom_shipto = $order->custom_shipto || $order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => []));
1480
1481     my $shipto_cvars  = {map { my ($key) = m{^shiptocvar_(.+)}; $key => delete $form->{$_}} grep { m{^shiptocvar_} } keys %$form};
1482     my $shipto_attrs  = {map {                                  $_   => delete $form->{$_}} grep { m{^shipto}      } keys %$form};
1483
1484     $custom_shipto->assign_attributes(%$shipto_attrs);
1485     $custom_shipto->cvar_by_name($_)->value($shipto_cvars->{$_}) for keys %$shipto_cvars;
1486   }
1487 }
1488
1489 # recalculate prices and taxes
1490 #
1491 # Using the PriceTaxCalculator. Store linetotals in the item objects.
1492 sub recalc {
1493   my ($self) = @_;
1494
1495   my %pat = $self->order->calculate_prices_and_taxes();
1496
1497   $self->{taxes} = [];
1498   foreach my $tax_id (keys %{ $pat{taxes_by_tax_id} }) {
1499     my $netamount = sum0 map { $pat{amounts}->{$_}->{amount} } grep { $pat{amounts}->{$_}->{tax_id} == $tax_id } keys %{ $pat{amounts} };
1500
1501     push(@{ $self->{taxes} }, { amount    => $pat{taxes_by_tax_id}->{$tax_id},
1502                                 netamount => $netamount,
1503                                 tax       => SL::DB::Tax->new(id => $tax_id)->load });
1504   }
1505   pairwise { $a->{linetotal} = $b->{linetotal} } @{$self->order->items_sorted}, @{$pat{items}};
1506 }
1507
1508 # get data for saving, printing, ..., that is not changed in the form
1509 #
1510 # Only cvars for now.
1511 sub get_unalterable_data {
1512   my ($self) = @_;
1513
1514   foreach my $item (@{ $self->order->items }) {
1515     # autovivify all cvars that are not in the form (cvars_by_config can do it).
1516     # workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
1517     foreach my $var (@{ $item->cvars_by_config }) {
1518       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
1519     }
1520     $item->parse_custom_variable_values;
1521   }
1522 }
1523
1524 # delete the order
1525 #
1526 # And remove related files in the spool directory
1527 sub delete {
1528   my ($self) = @_;
1529
1530   my $errors = [];
1531   my $db     = $self->order->db;
1532
1533   $db->with_transaction(
1534     sub {
1535       my @spoolfiles = grep { $_ } map { $_->spoolfile } @{ SL::DB::Manager::Status->get_all(where => [ trans_id => $self->order->id ]) };
1536       $self->order->delete;
1537       my $spool = $::lx_office_conf{paths}->{spool};
1538       unlink map { "$spool/$_" } @spoolfiles if $spool;
1539
1540       1;
1541   }) || push(@{$errors}, $db->error);
1542
1543   return $errors;
1544 }
1545
1546 # save the order
1547 #
1548 # And delete items that are deleted in the form.
1549 sub save {
1550   my ($self) = @_;
1551
1552   my $errors = [];
1553   my $db     = $self->order->db;
1554
1555   $db->with_transaction(sub {
1556     # delete custom shipto if it is to be deleted or if it is empty
1557     if ($self->order->custom_shipto && ($self->is_custom_shipto_to_delete || $self->order->custom_shipto->is_empty)) {
1558       $self->order->custom_shipto->delete if $self->order->custom_shipto->shipto_id;
1559       $self->order->custom_shipto(undef);
1560     }
1561
1562     SL::DB::OrderItem->new(id => $_)->delete for @{$self->item_ids_to_delete || []};
1563     $self->order->save(cascade => 1);
1564
1565     # link records
1566     if ($::form->{converted_from_oe_id}) {
1567       my @converted_from_oe_ids = split ' ', $::form->{converted_from_oe_id};
1568       foreach my $converted_from_oe_id (@converted_from_oe_ids) {
1569         my $src = SL::DB::Order->new(id => $converted_from_oe_id)->load;
1570         $src->update_attributes(closed => 1) if $src->type =~ /_quotation$/;
1571         $src->link_to_record($self->order);
1572       }
1573       if (scalar @{ $::form->{converted_from_orderitems_ids} || [] }) {
1574         my $idx = 0;
1575         foreach (@{ $self->order->items_sorted }) {
1576           my $from_id = $::form->{converted_from_orderitems_ids}->[$idx];
1577           next if !$from_id;
1578           SL::DB::RecordLink->new(from_table => 'orderitems',
1579                                   from_id    => $from_id,
1580                                   to_table   => 'orderitems',
1581                                   to_id      => $_->id
1582           )->save;
1583           $idx++;
1584         }
1585       }
1586     }
1587     1;
1588   }) || push(@{$errors}, $db->error);
1589
1590   return $errors;
1591 }
1592
1593 sub workflow_sales_or_request_for_quotation {
1594   my ($self) = @_;
1595
1596   # always save
1597   my $errors = $self->save();
1598
1599   if (scalar @{ $errors }) {
1600     $self->js->flash('error', $_) for @{ $errors };
1601     return $self->js->render();
1602   }
1603
1604   my $destination_type = $::form->{type} eq sales_order_type() ? sales_quotation_type() : request_quotation_type();
1605
1606   $self->order(SL::DB::Order->new_from($self->order, destination_type => $destination_type));
1607   $self->{converted_from_oe_id} = delete $::form->{id};
1608
1609   # set item ids to new fake id, to identify them as new items
1610   foreach my $item (@{$self->order->items_sorted}) {
1611     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1612   }
1613
1614   # change form type
1615   $::form->{type} = $destination_type;
1616   $self->type($self->init_type);
1617   $self->cv  ($self->init_cv);
1618   $self->check_auth;
1619
1620   $self->recalc();
1621   $self->get_unalterable_data();
1622   $self->pre_render();
1623
1624   # trigger rendering values for second row as hidden, because they
1625   # are loaded only on demand. So we need to keep the values from the
1626   # source.
1627   $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
1628
1629   $self->render(
1630     'order/form',
1631     title => $self->get_title_for('edit'),
1632     %{$self->{template_args}}
1633   );
1634 }
1635
1636 sub workflow_sales_or_purchase_order {
1637   my ($self) = @_;
1638
1639   # always save
1640   my $errors = $self->save();
1641
1642   if (scalar @{ $errors }) {
1643     $self->js->flash('error', $_) foreach @{ $errors };
1644     return $self->js->render();
1645   }
1646
1647   my $destination_type = $::form->{type} eq sales_quotation_type()   ? sales_order_type()
1648                        : $::form->{type} eq request_quotation_type() ? purchase_order_type()
1649                        : $::form->{type} eq purchase_order_type()    ? sales_order_type()
1650                        : $::form->{type} eq sales_order_type()       ? purchase_order_type()
1651                        : '';
1652
1653   # check for direct delivery
1654   # copy shipto in custom shipto (custom shipto will be copied by new_from() in case)
1655   my $custom_shipto;
1656   if (   $::form->{type} eq sales_order_type() && $destination_type eq purchase_order_type()
1657       && $::form->{use_shipto} && $self->order->shipto) {
1658     $custom_shipto = $self->order->shipto->clone('SL::DB::Order');
1659   }
1660
1661   $self->order(SL::DB::Order->new_from($self->order, destination_type => $destination_type));
1662   $self->{converted_from_oe_id} = delete $::form->{id};
1663
1664   # set item ids to new fake id, to identify them as new items
1665   foreach my $item (@{$self->order->items_sorted}) {
1666     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1667   }
1668
1669   if ($::form->{type} eq sales_order_type() && $destination_type eq purchase_order_type()) {
1670     if ($::form->{use_shipto}) {
1671       $self->order->custom_shipto($custom_shipto) if $custom_shipto;
1672     } else {
1673       # remove any custom shipto if not wanted
1674       $self->order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => []));
1675     }
1676   }
1677
1678   # change form type
1679   $::form->{type} = $destination_type;
1680   $self->type($self->init_type);
1681   $self->cv  ($self->init_cv);
1682   $self->check_auth;
1683
1684   $self->recalc();
1685   $self->get_unalterable_data();
1686   $self->pre_render();
1687
1688   # trigger rendering values for second row as hidden, because they
1689   # are loaded only on demand. So we need to keep the values from the
1690   # source.
1691   $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
1692
1693   $self->render(
1694     'order/form',
1695     title => $self->get_title_for('edit'),
1696     %{$self->{template_args}}
1697   );
1698 }
1699
1700
1701 sub pre_render {
1702   my ($self) = @_;
1703
1704   $self->{all_taxzones}               = SL::DB::Manager::TaxZone->get_all_sorted();
1705   $self->{all_currencies}             = SL::DB::Manager::Currency->get_all_sorted();
1706   $self->{all_departments}            = SL::DB::Manager::Department->get_all_sorted();
1707   $self->{all_languages}              = SL::DB::Manager::Language->get_all_sorted();
1708   $self->{all_employees}              = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->employee_id,
1709                                                                                               deleted => 0 ] ],
1710                                                                            sort_by => 'name');
1711   $self->{all_salesmen}               = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->salesman_id,
1712                                                                                               deleted => 0 ] ],
1713                                                                            sort_by => 'name');
1714   $self->{all_payment_terms}          = SL::DB::Manager::PaymentTerm->get_all_sorted(where => [ or => [ id => $self->order->payment_id,
1715                                                                                                         obsolete => 0 ] ]);
1716   $self->{all_delivery_terms}         = SL::DB::Manager::DeliveryTerm->get_all_sorted();
1717   $self->{current_employee_id}        = SL::DB::Manager::Employee->current->id;
1718   $self->{periodic_invoices_status}   = $self->get_periodic_invoices_status($self->order->periodic_invoices_config);
1719   $self->{order_probabilities}        = [ map { { title => ($_ * 10) . '%', id => $_ * 10 } } (0..10) ];
1720   $self->{positions_scrollbar_height} = SL::Helper::UserPreferences::PositionsScrollbar->new()->get_height();
1721
1722   my $print_form = Form->new('');
1723   $print_form->{type}        = $self->type;
1724   $print_form->{printers}    = SL::DB::Manager::Printer->get_all_sorted;
1725   $self->{print_options}     = SL::Helper::PrintOptions->get_print_options(
1726     form => $print_form,
1727     options => {dialog_name_prefix => 'print_options.',
1728                 show_headers       => 1,
1729                 no_queue           => 1,
1730                 no_postscript      => 1,
1731                 no_opendocument    => 0,
1732                 no_html            => 1},
1733   );
1734
1735   foreach my $item (@{$self->order->orderitems}) {
1736     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
1737     $item->active_price_source(   $price_source->price_from_source(   $item->active_price_source   ));
1738     $item->active_discount_source($price_source->discount_from_source($item->active_discount_source));
1739   }
1740
1741   if (any { $self->type eq $_ } (sales_order_type(), purchase_order_type())) {
1742     # calculate shipped qtys here to prevent calling calculate for every item via the items method
1743     SL::Helper::ShippedQty->new->calculate($self->order)->write_to_objects;
1744   }
1745
1746   if ($self->order->number && $::instance_conf->get_webdav) {
1747     my $webdav = SL::Webdav->new(
1748       type     => $self->type,
1749       number   => $self->order->number,
1750     );
1751     my @all_objects = $webdav->get_all_objects;
1752     @{ $self->{template_args}->{WEBDAV} } = map { { name => $_->filename,
1753                                                     type => t8('File'),
1754                                                     link => File::Spec->catfile($_->full_filedescriptor),
1755                                                 } } @all_objects;
1756   }
1757
1758   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
1759
1760   $::request->{layout}->use_javascript("${_}.js") for qw(kivi.SalesPurchase kivi.Order kivi.File ckeditor/ckeditor ckeditor/adapters/jquery
1761                                                          edit_periodic_invoices_config calculate_qty kivi.Validator follow_up);
1762   $self->setup_edit_action_bar;
1763 }
1764
1765 sub setup_edit_action_bar {
1766   my ($self, %params) = @_;
1767
1768   my $deletion_allowed = (any { $self->type eq $_ } (sales_quotation_type(), request_quotation_type()))
1769                       || (($self->type eq sales_order_type())    && $::instance_conf->get_sales_order_show_delete)
1770                       || (($self->type eq purchase_order_type()) && $::instance_conf->get_purchase_order_show_delete);
1771
1772   for my $bar ($::request->layout->get('actionbar')) {
1773     $bar->add(
1774       combobox => [
1775         action => [
1776           t8('Save'),
1777           call      => [ 'kivi.Order.save', 'save', $::instance_conf->get_order_warn_duplicate_parts,
1778                                                     $::instance_conf->get_order_warn_no_deliverydate,
1779                                                                                                       ],
1780           checks    => [ 'kivi.Order.check_save_active_periodic_invoices', ['kivi.validate_form','#order_form'] ],
1781         ],
1782         action => [
1783           t8('Save as new'),
1784           call      => [ 'kivi.Order.save', 'save_as_new', $::instance_conf->get_order_warn_duplicate_parts ],
1785           checks    => [ 'kivi.Order.check_save_active_periodic_invoices' ],
1786           disabled  => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1787         ],
1788       ], # end of combobox "Save"
1789
1790       combobox => [
1791         action => [
1792           t8('Workflow'),
1793         ],
1794         action => [
1795           t8('Save and Quotation'),
1796           submit   => [ '#order_form', { action => "Order/sales_quotation" } ],
1797           only_if  => (any { $self->type eq $_ } (sales_order_type())),
1798         ],
1799         action => [
1800           t8('Save and RFQ'),
1801           submit   => [ '#order_form', { action => "Order/request_for_quotation" } ],
1802           only_if  => (any { $self->type eq $_ } (purchase_order_type())),
1803         ],
1804         action => [
1805           t8('Save and Sales Order'),
1806           submit   => [ '#order_form', { action => "Order/sales_order" } ],
1807           only_if  => (any { $self->type eq $_ } (sales_quotation_type(), purchase_order_type())),
1808         ],
1809         action => [
1810           t8('Save and Purchase Order'),
1811           call      => [ 'kivi.Order.purchase_order_check_for_direct_delivery' ],
1812           only_if   => (any { $self->type eq $_ } (sales_order_type(), request_quotation_type())),
1813         ],
1814         action => [
1815           t8('Save and Delivery Order'),
1816           call      => [ 'kivi.Order.save', 'save_and_delivery_order', $::instance_conf->get_order_warn_duplicate_parts,
1817                                                                        $::instance_conf->get_order_warn_no_deliverydate,
1818                                                                                                                         ],
1819           checks    => [ 'kivi.Order.check_save_active_periodic_invoices' ],
1820           only_if   => (any { $self->type eq $_ } (sales_order_type(), purchase_order_type()))
1821         ],
1822         action => [
1823           t8('Save and Invoice'),
1824           call      => [ 'kivi.Order.save', 'save_and_invoice', $::instance_conf->get_order_warn_duplicate_parts ],
1825           checks    => [ 'kivi.Order.check_save_active_periodic_invoices' ],
1826         ],
1827         action => [
1828           t8('Save and AP Transaction'),
1829           call      => [ 'kivi.Order.save', 'save_and_ap_transaction', $::instance_conf->get_order_warn_duplicate_parts ],
1830           only_if   => (any { $self->type eq $_ } (purchase_order_type()))
1831         ],
1832
1833       ], # end of combobox "Workflow"
1834
1835       combobox => [
1836         action => [
1837           t8('Export'),
1838         ],
1839         action => [
1840           t8('Save and print'),
1841           call => [ 'kivi.Order.show_print_options', $::instance_conf->get_order_warn_duplicate_parts ],
1842         ],
1843         action => [
1844           t8('Save and E-mail'),
1845           call => [ 'kivi.Order.save', 'save_and_show_email_dialog', $::instance_conf->get_order_warn_duplicate_parts ],
1846           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1847         ],
1848         action => [
1849           t8('Download attachments of all parts'),
1850           call     => [ 'kivi.File.downloadOrderitemsFiles', $::form->{type}, $::form->{id} ],
1851           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1852           only_if  => $::instance_conf->get_doc_storage,
1853         ],
1854       ], # end of combobox "Export"
1855
1856       action => [
1857         t8('Delete'),
1858         call     => [ 'kivi.Order.delete_order' ],
1859         confirm  => $::locale->text('Do you really want to delete this object?'),
1860         disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1861         only_if  => $deletion_allowed,
1862       ],
1863
1864       combobox => [
1865         action => [
1866           t8('more')
1867         ],
1868         action => [
1869           t8('Follow-Up'),
1870           call     => [ 'kivi.Order.follow_up_window' ],
1871           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1872           only_if  => $::auth->assert('productivity', 1),
1873         ],
1874       ], # end of combobox "more"
1875     );
1876   }
1877 }
1878
1879 sub generate_pdf {
1880   my ($order, $pdf_ref, $params) = @_;
1881
1882   my @errors = ();
1883
1884   my $print_form = Form->new('');
1885   $print_form->{type}        = $order->type;
1886   $print_form->{formname}    = $params->{formname} || $order->type;
1887   $print_form->{format}      = $params->{format}   || 'pdf';
1888   $print_form->{media}       = $params->{media}    || 'file';
1889   $print_form->{groupitems}  = $params->{groupitems};
1890   $print_form->{printer_id}  = $params->{printer_id};
1891   $print_form->{media}       = 'file'                             if $print_form->{media} eq 'screen';
1892
1893   $order->language($params->{language});
1894   $order->flatten_to_form($print_form, format_amounts => 1);
1895
1896   my $template_ext;
1897   my $template_type;
1898   if ($print_form->{format} =~ /(opendocument|oasis)/i) {
1899     $template_ext  = 'odt';
1900     $template_type = 'OpenDocument';
1901   }
1902
1903   # search for the template
1904   my ($template_file, @template_files) = SL::Helper::CreatePDF->find_template(
1905     name        => $print_form->{formname},
1906     extension   => $template_ext,
1907     email       => $print_form->{media} eq 'email',
1908     language    => $params->{language},
1909     printer_id  => $print_form->{printer_id},
1910   );
1911
1912   if (!defined $template_file) {
1913     push @errors, $::locale->text('Cannot find matching template for this print request. Please contact your template maintainer. I tried these: #1.', join ', ', map { "'$_'"} @template_files);
1914   }
1915
1916   return @errors if scalar @errors;
1917
1918   $print_form->throw_on_error(sub {
1919     eval {
1920       $print_form->prepare_for_printing;
1921
1922       $$pdf_ref = SL::Helper::CreatePDF->create_pdf(
1923         format        => $print_form->{format},
1924         template_type => $template_type,
1925         template      => $template_file,
1926         variables     => $print_form,
1927         variable_content_types => {
1928           longdescription => 'html',
1929           partnotes       => 'html',
1930           notes           => 'html',
1931         },
1932       );
1933       1;
1934     } || push @errors, ref($EVAL_ERROR) eq 'SL::X::FormError' ? $EVAL_ERROR->error : $EVAL_ERROR;
1935   });
1936
1937   return @errors;
1938 }
1939
1940 sub get_files_for_email_dialog {
1941   my ($self) = @_;
1942
1943   my %files = map { ($_ => []) } qw(versions files vc_files part_files);
1944
1945   return %files if !$::instance_conf->get_doc_storage;
1946
1947   if ($self->order->id) {
1948     $files{versions} = [ SL::File->get_all_versions(object_id => $self->order->id,              object_type => $self->order->type, file_type => 'document') ];
1949     $files{files}    = [ SL::File->get_all(         object_id => $self->order->id,              object_type => $self->order->type, file_type => 'attachment') ];
1950     $files{vc_files} = [ SL::File->get_all(         object_id => $self->order->{$self->cv}->id, object_type => $self->cv,          file_type => 'attachment') ];
1951   }
1952
1953   my @parts =
1954     uniq_by { $_->{id} }
1955     map {
1956       +{ id         => $_->part->id,
1957          partnumber => $_->part->partnumber }
1958     } @{$self->order->items_sorted};
1959
1960   foreach my $part (@parts) {
1961     my @pfiles = SL::File->get_all(object_id => $part->{id}, object_type => 'part');
1962     push @{ $files{part_files} }, map { +{ %{ $_ }, partnumber => $part->{partnumber} } } @pfiles;
1963   }
1964
1965   foreach my $key (keys %files) {
1966     $files{$key} = [ sort_by { lc $_->{db_file}->{file_name} } @{ $files{$key} } ];
1967   }
1968
1969   return %files;
1970 }
1971
1972 sub make_periodic_invoices_config_from_yaml {
1973   my ($yaml_config) = @_;
1974
1975   return if !$yaml_config;
1976   my $attr = SL::YAML::Load($yaml_config);
1977   return if 'HASH' ne ref $attr;
1978   return SL::DB::PeriodicInvoicesConfig->new(%$attr);
1979 }
1980
1981
1982 sub get_periodic_invoices_status {
1983   my ($self, $config) = @_;
1984
1985   return                      if $self->type ne sales_order_type();
1986   return t8('not configured') if !$config;
1987
1988   my $active = ('HASH' eq ref $config)                           ? $config->{active}
1989              : ('SL::DB::PeriodicInvoicesConfig' eq ref $config) ? $config->active
1990              :                                                     die "Cannot get status of periodic invoices config";
1991
1992   return $active ? t8('active') : t8('inactive');
1993 }
1994
1995 sub get_title_for {
1996   my ($self, $action) = @_;
1997
1998   return '' if none { lc($action)} qw(add edit);
1999
2000   # for locales:
2001   # $::locale->text("Add Sales Order");
2002   # $::locale->text("Add Purchase Order");
2003   # $::locale->text("Add Quotation");
2004   # $::locale->text("Add Request for Quotation");
2005   # $::locale->text("Edit Sales Order");
2006   # $::locale->text("Edit Purchase Order");
2007   # $::locale->text("Edit Quotation");
2008   # $::locale->text("Edit Request for Quotation");
2009
2010   $action = ucfirst(lc($action));
2011   return $self->type eq sales_order_type()       ? $::locale->text("$action Sales Order")
2012        : $self->type eq purchase_order_type()    ? $::locale->text("$action Purchase Order")
2013        : $self->type eq sales_quotation_type()   ? $::locale->text("$action Quotation")
2014        : $self->type eq request_quotation_type() ? $::locale->text("$action Request for Quotation")
2015        : '';
2016 }
2017
2018 sub get_item_cvpartnumber {
2019   my ($self, $item) = @_;
2020
2021   return if !$self->search_cvpartnumber;
2022   return if !$self->order->customervendor;
2023
2024   if ($self->cv eq 'vendor') {
2025     my @mms = grep { $_->make eq $self->order->customervendor->id } @{$item->part->makemodels};
2026     $item->{cvpartnumber} = $mms[0]->model if scalar @mms;
2027   } elsif ($self->cv eq 'customer') {
2028     my @cps = grep { $_->customer_id eq $self->order->customervendor->id } @{$item->part->customerprices};
2029     $item->{cvpartnumber} = $cps[0]->customer_partnumber if scalar @cps;
2030   }
2031 }
2032
2033 sub get_part_texts {
2034   my ($part_or_id, $language_or_id, %defaults) = @_;
2035
2036   my $part        = ref($part_or_id)     ? $part_or_id         : SL::DB::Part->load_cached($part_or_id);
2037   my $language_id = ref($language_or_id) ? $language_or_id->id : $language_or_id;
2038   my $texts       = {
2039     description     => $defaults{description}     // $part->description,
2040     longdescription => $defaults{longdescription} // $part->notes,
2041   };
2042
2043   return $texts unless $language_id;
2044
2045   my $translation = SL::DB::Manager::Translation->get_first(
2046     where => [
2047       parts_id    => $part->id,
2048       language_id => $language_id,
2049     ]);
2050
2051   $texts->{description}     = $translation->translation     if $translation && $translation->translation;
2052   $texts->{longdescription} = $translation->longdescription if $translation && $translation->longdescription;
2053
2054   return $texts;
2055 }
2056
2057 sub sales_order_type {
2058   'sales_order';
2059 }
2060
2061 sub purchase_order_type {
2062   'purchase_order';
2063 }
2064
2065 sub sales_quotation_type {
2066   'sales_quotation';
2067 }
2068
2069 sub request_quotation_type {
2070   'request_quotation';
2071 }
2072
2073 sub nr_key {
2074   return $_[0]->type eq sales_order_type()       ? 'ordnumber'
2075        : $_[0]->type eq purchase_order_type()    ? 'ordnumber'
2076        : $_[0]->type eq sales_quotation_type()   ? 'quonumber'
2077        : $_[0]->type eq request_quotation_type() ? 'quonumber'
2078        : '';
2079 }
2080
2081 sub save_and_redirect_to {
2082   my ($self, %params) = @_;
2083
2084   my $errors = $self->save();
2085
2086   if (scalar @{ $errors }) {
2087     $self->js->flash('error', $_) foreach @{ $errors };
2088     return $self->js->render();
2089   }
2090
2091   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
2092            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
2093            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
2094            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
2095            : '';
2096   flash_later('info', $text);
2097
2098   $self->redirect_to(%params, id => $self->order->id);
2099 }
2100
2101 1;
2102
2103 __END__
2104
2105 =encoding utf-8
2106
2107 =head1 NAME
2108
2109 SL::Controller::Order - controller for orders
2110
2111 =head1 SYNOPSIS
2112
2113 This is a new form to enter orders, completely rewritten with the use
2114 of controller and java script techniques.
2115
2116 The aim is to provide the user a better experience and a faster workflow. Also
2117 the code should be more readable, more reliable and better to maintain.
2118
2119 =head2 Key Features
2120
2121 =over 4
2122
2123 =item *
2124
2125 One input row, so that input happens every time at the same place.
2126
2127 =item *
2128
2129 Use of pickers where possible.
2130
2131 =item *
2132
2133 Possibility to enter more than one item at once.
2134
2135 =item *
2136
2137 Item list in a scrollable area, so that the workflow buttons stay at
2138 the bottom.
2139
2140 =item *
2141
2142 Reordering item rows with drag and drop is possible. Sorting item rows is
2143 possible (by partnumber, description, qty, sellprice and discount for now).
2144
2145 =item *
2146
2147 No C<update> is necessary. All entries and calculations are managed
2148 with ajax-calls and the page only reloads on C<save>.
2149
2150 =item *
2151
2152 User can see changes immediately, because of the use of java script
2153 and ajax.
2154
2155 =back
2156
2157 =head1 CODE
2158
2159 =head2 Layout
2160
2161 =over 4
2162
2163 =item * C<SL/Controller/Order.pm>
2164
2165 the controller
2166
2167 =item * C<template/webpages/order/form.html>
2168
2169 main form
2170
2171 =item * C<template/webpages/order/tabs/basic_data.html>
2172
2173 Main tab for basic_data.
2174
2175 This is the only tab here for now. "linked records" and "webdav" tabs are
2176 reused from generic code.
2177
2178 =over 4
2179
2180 =item * C<template/webpages/order/tabs/_business_info_row.html>
2181
2182 For displaying information on business type
2183
2184 =item * C<template/webpages/order/tabs/_item_input.html>
2185
2186 The input line for items
2187
2188 =item * C<template/webpages/order/tabs/_row.html>
2189
2190 One row for already entered items
2191
2192 =item * C<template/webpages/order/tabs/_tax_row.html>
2193
2194 Displaying tax information
2195
2196 =item * C<template/webpages/order/tabs/_price_sources_dialog.html>
2197
2198 Dialog for selecting price and discount sources
2199
2200 =back
2201
2202 =item * C<js/kivi.Order.js>
2203
2204 java script functions
2205
2206 =back
2207
2208 =head1 TODO
2209
2210 =over 4
2211
2212 =item * testing
2213
2214 =item * price sources: little symbols showing better price / better discount
2215
2216 =item * select units in input row?
2217
2218 =item * check for direct delivery (workflow sales order -> purchase order)
2219
2220 =item * access rights
2221
2222 =item * display weights
2223
2224 =item * history
2225
2226 =item * mtime check
2227
2228 =item * optional client/user behaviour
2229
2230 (transactions has to be set - department has to be set -
2231  force project if enabled in client config - transport cost reminder)
2232
2233 =back
2234
2235 =head1 KNOWN BUGS AND CAVEATS
2236
2237 =over 4
2238
2239 =item *
2240
2241 Customer discount is not displayed as a valid discount in price source popup
2242 (this might be a bug in price sources)
2243
2244 (I cannot reproduce this (Bernd))
2245
2246 =item *
2247
2248 No indication that <shift>-up/down expands/collapses second row.
2249
2250 =item *
2251
2252 Inline creation of parts is not currently supported
2253
2254 =item *
2255
2256 Table header is not sticky in the scrolling area.
2257
2258 =item *
2259
2260 Sorting does not include C<position>, neither does reordering.
2261
2262 This behavior was implemented intentionally. But we can discuss, which behavior
2263 should be implemented.
2264
2265 =back
2266
2267 =head1 To discuss / Nice to have
2268
2269 =over 4
2270
2271 =item *
2272
2273 How to expand/collapse second row. Now it can be done clicking the icon or
2274 <shift>-up/down.
2275
2276 =item *
2277
2278 Possibility to select PriceSources in input row?
2279
2280 =item *
2281
2282 This controller uses a (changed) copy of the template for the PriceSource
2283 dialog. Maybe there could be used one code source.
2284
2285 =item *
2286
2287 Rounding-differences between this controller (PriceTaxCalculator) and the old
2288 form. This is not only a problem here, but also in all parts using the PTC.
2289 There exists a ticket and a patch. This patch should be testet.
2290
2291 =item *
2292
2293 An indicator, if the actual inputs are saved (like in an
2294 editor or on text processing application).
2295
2296 =item *
2297
2298 A warning when leaving the page without saveing unchanged inputs.
2299
2300
2301 =back
2302
2303 =head1 AUTHOR
2304
2305 Bernd Bleßmann E<lt>bernd@kivitendo-premium.deE<gt>
2306
2307 =cut