SL/Controller/Order.pm

   1 package SL::Controller::Order;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use SL::Helper::Flash qw(flash_later);
   7 use SL::Presenter::Tag qw(select_tag hidden_tag div_tag);
   8 use SL::Locale::String qw(t8);
   9 use SL::SessionFile::Random;
  10 use SL::PriceSource;
  11 use SL::Webdav;
  12 use SL::File;
  13 use SL::MIME;
  14 use SL::Util qw(trim);
  15 use SL::YAML;
  16 use SL::DB::Order;
  17 use SL::DB::Default;
  18 use SL::DB::Unit;
  19 use SL::DB::Part;
  20 use SL::DB::PartsGroup;
  21 use SL::DB::Printer;
  22 use SL::DB::Language;
  23 use SL::DB::RecordLink;
  24 use SL::DB::Shipto;
  25 use SL::DB::Translation;
  26
  27 use SL::Helper::CreatePDF qw(:all);
  28 use SL::Helper::PrintOptions;
  29 use SL::Helper::ShippedQty;
  30 use SL::Helper::UserPreferences::PositionsScrollbar;
  31 use SL::Helper::UserPreferences::UpdatePositions;
  32
  33 use SL::Controller::Helper::GetModels;
  34
  35 use List::Util qw(first sum0);
  36 use List::UtilsBy qw(sort_by uniq_by);
  37 use List::MoreUtils qw(any none pairwise first_index);
  38 use English qw(-no_match_vars);
  39 use File::Spec;
  40 use Cwd;
  41 use Sort::Naturally;
  42
  43 use Rose::Object::MakeMethods::Generic
  44 (
  45  scalar => [ qw(item_ids_to_delete is_custom_shipto_to_delete) ],
  46  'scalar --get_set_init' => [ qw(order valid_types type cv p multi_items_models all_price_factors search_cvpartnumber show_update_button) ],
  47 );
  48
  49
  50 # safety
  51 __PACKAGE__->run_before('check_auth');
  52
  53 __PACKAGE__->run_before('recalc',
  54                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice save_and_ap_transaction
  55                                      print send_email) ]);
  56
  57 __PACKAGE__->run_before('get_unalterable_data',
  58                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice save_and_ap_transaction
  59                                      print send_email) ]);
  60
  61 #
  62 # actions
  63 #
  64
  65 # add a new order
  66 sub action_add {
  67   my ($self) = @_;
  68
  69   $self->order->transdate(DateTime->now_local());
  70   my $extra_days = $self->{type} eq 'sales_quotation' ? $::instance_conf->get_reqdate_interval       :
  71                    $self->{type} eq 'sales_order'     ? $::instance_conf->get_delivery_date_interval : 1;
  72   $self->order->reqdate(DateTime->today_local->next_workday(extra_days => $extra_days)) if !$self->order->reqdate;
  73
  74
  75   $self->pre_render();
  76   $self->render(
  77     'order/form',
  78     title => $self->get_title_for('add'),
  79     %{$self->{template_args}}
  80   );
  81 }
  82
  83 # edit an existing order
  84 sub action_edit {
  85   my ($self) = @_;
  86
  87   if ($::form->{id}) {
  88     $self->load_order;
  89
  90   } else {
  91     # this is to edit an order from an unsaved order object
  92
  93     # set item ids to new fake id, to identify them as new items
  94     foreach my $item (@{$self->order->items_sorted}) {
  95       $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
  96     }
  97     # trigger rendering values for second row/longdescription as hidden,
  98     # because they are loaded only on demand. So we need to keep the values
  99     # from the source.
 100     $_->{render_second_row}      = 1 for @{ $self->order->items_sorted };
 101     $_->{render_longdescription} = 1 for @{ $self->order->items_sorted };
 102   }
 103
 104   $self->recalc();
 105   $self->pre_render();
 106   $self->render(
 107     'order/form',
 108     title => $self->get_title_for('edit'),
 109     %{$self->{template_args}}
 110   );
 111 }
 112
 113 # edit a collective order (consisting of one or more existing orders)
 114 sub action_edit_collective {
 115   my ($self) = @_;
 116
 117   # collect order ids
 118   my @multi_ids = map {
 119     $_ =~ m{^multi_id_(\d+)$} && $::form->{'multi_id_' . $1} && $::form->{'trans_id_' . $1} && $::form->{'trans_id_' . $1}
 120   } grep { $_ =~ m{^multi_id_\d+$} } keys %$::form;
 121
 122   # fall back to add if no ids are given
 123   if (scalar @multi_ids == 0) {
 124     $self->action_add();
 125     return;
 126   }
 127
 128   # fall back to save as new if only one id is given
 129   if (scalar @multi_ids == 1) {
 130     $self->order(SL::DB::Order->new(id => $multi_ids[0])->load);
 131     $self->action_save_as_new();
 132     return;
 133   }
 134
 135   # make new order from given orders
 136   my @multi_orders = map { SL::DB::Order->new(id => $_)->load } @multi_ids;
 137   $self->{converted_from_oe_id} = join ' ', map { $_->id } @multi_orders;
 138   $self->order(SL::DB::Order->new_from_multi(\@multi_orders, sort_sources_by => 'transdate'));
 139
 140   $self->action_edit();
 141 }
 142
 143 # delete the order
 144 sub action_delete {
 145   my ($self) = @_;
 146
 147   my $errors = $self->delete();
 148
 149   if (scalar @{ $errors }) {
 150     $self->js->flash('error', $_) foreach @{ $errors };
 151     return $self->js->render();
 152   }
 153
 154   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been deleted')
 155            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been deleted')
 156            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been deleted')
 157            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been deleted')
 158            : '';
 159   flash_later('info', $text);
 160
 161   my @redirect_params = (
 162     action => 'add',
 163     type   => $self->type,
 164   );
 165
 166   $self->redirect_to(@redirect_params);
 167 }
 168
 169 # save the order
 170 sub action_save {
 171   my ($self) = @_;
 172
 173   my $errors = $self->save();
 174
 175   if (scalar @{ $errors }) {
 176     $self->js->flash('error', $_) foreach @{ $errors };
 177     return $self->js->render();
 178   }
 179
 180   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
 181            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
 182            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
 183            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
 184            : '';
 185   flash_later('info', $text);
 186
 187   my @redirect_params = (
 188     action => 'edit',
 189     type   => $self->type,
 190     id     => $self->order->id,
 191   );
 192
 193   $self->redirect_to(@redirect_params);
 194 }
 195
 196 # save the order as new document an open it for edit
 197 sub action_save_as_new {
 198   my ($self) = @_;
 199
 200   my $order = $self->order;
 201
 202   if (!$order->id) {
 203     $self->js->flash('error', t8('This object has not been saved yet.'));
 204     return $self->js->render();
 205   }
 206
 207   # load order from db to check if values changed
 208   my $saved_order = SL::DB::Order->new(id => $order->id)->load;
 209
 210   my %new_attrs;
 211   # Lets assign a new number if the user hasn't changed the previous one.
 212   # If it has been changed manually then use it as-is.
 213   $new_attrs{number}    = (trim($order->number) eq $saved_order->number)
 214                         ? ''
 215                         : trim($order->number);
 216
 217   # Clear transdate unless changed
 218   $new_attrs{transdate} = ($order->transdate == $saved_order->transdate)
 219                         ? DateTime->today_local
 220                         : $order->transdate;
 221
 222   # Set new reqdate unless changed
 223   if ($order->reqdate == $saved_order->reqdate) {
 224     my $extra_days = $self->{type} eq 'sales_quotation' ? $::instance_conf->get_reqdate_interval       :
 225                      $self->{type} eq 'sales_order'     ? $::instance_conf->get_delivery_date_interval : 1;
 226     $new_attrs{reqdate} = DateTime->today_local->next_workday(extra_days => $extra_days);
 227   } else {
 228     $new_attrs{reqdate} = $order->reqdate;
 229   }
 230
 231   # Update employee
 232   $new_attrs{employee}  = SL::DB::Manager::Employee->current;
 233
 234   # Create new record from current one
 235   $self->order(SL::DB::Order->new_from($order, destination_type => $order->type, attributes => \%new_attrs));
 236
 237   # no linked records on save as new
 238   delete $::form->{$_} for qw(converted_from_oe_id converted_from_orderitems_ids);
 239
 240   # save
 241   $self->action_save();
 242 }
 243
 244 # print the order
 245 #
 246 # This is called if "print" is pressed in the print dialog.
 247 # If PDF creation was requested and succeeded, the pdf is offered for download
 248 # via send_file (which uses ajax in this case).
 249 sub action_print {
 250   my ($self) = @_;
 251
 252   my $errors = $self->save();
 253
 254   if (scalar @{ $errors }) {
 255     $self->js->flash('error', $_) foreach @{ $errors };
 256     return $self->js->render();
 257   }
 258
 259   $self->js_reset_order_and_item_ids_after_save;
 260
 261   my $format      = $::form->{print_options}->{format};
 262   my $media       = $::form->{print_options}->{media};
 263   my $formname    = $::form->{print_options}->{formname};
 264   my $copies      = $::form->{print_options}->{copies};
 265   my $groupitems  = $::form->{print_options}->{groupitems};
 266
 267   # only pdf and opendocument by now
 268   if (none { $format eq $_ } qw(pdf opendocument opendocument_pdf)) {
 269     return $self->js->flash('error', t8('Format \'#1\' is not supported yet/anymore.', $format))->render;
 270   }
 271
 272   # only screen or printer by now
 273   if (none { $media eq $_ } qw(screen printer)) {
 274     return $self->js->flash('error', t8('Media \'#1\' is not supported yet/anymore.', $media))->render;
 275   }
 276
 277   # create a form for generate_attachment_filename
 278   my $form   = Form->new;
 279   $form->{$self->nr_key()}  = $self->order->number;
 280   $form->{type}             = $self->type;
 281   $form->{format}           = $format;
 282   $form->{formname}         = $formname;
 283   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 284   my $pdf_filename          = $form->generate_attachment_filename();
 285
 286   my $pdf;
 287   my @errors = generate_pdf($self->order, \$pdf, { format     => $format,
 288                                                    formname   => $formname,
 289                                                    language   => $self->order->language,
 290                                                    groupitems => $groupitems });
 291   if (scalar @errors) {
 292     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render;
 293   }
 294
 295   if ($media eq 'screen') {
 296     # screen/download
 297     $self->js->flash('info', t8('The PDF has been created'));
 298     $self->send_file(
 299       \$pdf,
 300       type         => SL::MIME->mime_type_from_ext($pdf_filename),
 301       name         => $pdf_filename,
 302       js_no_render => 1,
 303     );
 304
 305   } elsif ($media eq 'printer') {
 306     # printer
 307     my $printer_id = $::form->{print_options}->{printer_id};
 308     SL::DB::Printer->new(id => $printer_id)->load->print_document(
 309       copies  => $copies,
 310       content => $pdf,
 311     );
 312
 313     $self->js->flash('info', t8('The PDF has been printed'));
 314   }
 315
 316   # copy file to webdav folder
 317   if ($self->order->number && $::instance_conf->get_webdav_documents) {
 318     my $webdav = SL::Webdav->new(
 319       type     => $self->type,
 320       number   => $self->order->number,
 321     );
 322     my $webdav_file = SL::Webdav::File->new(
 323       webdav   => $webdav,
 324       filename => $pdf_filename,
 325     );
 326     eval {
 327       $webdav_file->store(data => \$pdf);
 328       1;
 329     } or do {
 330       $self->js->flash('error', t8('Storing PDF to webdav folder failed: #1', $@));
 331     }
 332   }
 333   if ($self->order->number && $::instance_conf->get_doc_storage) {
 334     eval {
 335       SL::File->save(object_id     => $self->order->id,
 336                      object_type   => $self->type,
 337                      mime_type     => 'application/pdf',
 338                      source        => 'created',
 339                      file_type     => 'document',
 340                      file_name     => $pdf_filename,
 341                      file_contents => $pdf);
 342       1;
 343     } or do {
 344       $self->js->flash('error', t8('Storing PDF in storage backend failed: #1', $@));
 345     }
 346   }
 347   $self->js->render;
 348 }
 349
 350 # open the email dialog
 351 sub action_save_and_show_email_dialog {
 352   my ($self) = @_;
 353
 354   my $errors = $self->save();
 355
 356   if (scalar @{ $errors }) {
 357     $self->js->flash('error', $_) foreach @{ $errors };
 358     return $self->js->render();
 359   }
 360
 361   my $cv_method = $self->cv;
 362
 363   if (!$self->order->$cv_method) {
 364     return $self->js->flash('error', $self->cv eq 'customer' ? t8('Cannot send E-mail without customer given') : t8('Cannot send E-mail without vendor given'))
 365                     ->render($self);
 366   }
 367
 368   my $email_form;
 369   $email_form->{to}   = $self->order->contact->cp_email if $self->order->contact;
 370   $email_form->{to} ||= $self->order->$cv_method->email;
 371   $email_form->{cc}   = $self->order->$cv_method->cc;
 372   $email_form->{bcc}  = join ', ', grep $_, $self->order->$cv_method->bcc, SL::DB::Default->get->global_bcc;
 373   # Todo: get addresses from shipto, if any
 374
 375   my $form = Form->new;
 376   $form->{$self->nr_key()}  = $self->order->number;
 377   $form->{cusordnumber}     = $self->order->cusordnumber;
 378   $form->{formname}         = $self->type;
 379   $form->{type}             = $self->type;
 380   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 381   $form->{language_id}      = $self->order->language->id                  if $self->order->language;
 382   $form->{format}           = 'pdf';
 383
 384   $email_form->{subject}             = $form->generate_email_subject();
 385   $email_form->{attachment_filename} = $form->generate_attachment_filename();
 386   $email_form->{message}             = $form->generate_email_body();
 387   $email_form->{js_send_function}    = 'kivi.Order.send_email()';
 388
 389   my %files = $self->get_files_for_email_dialog();
 390   my $dialog_html = $self->render('common/_send_email_dialog', { output => 0 },
 391                                   email_form  => $email_form,
 392                                   show_bcc    => $::auth->assert('email_bcc', 'may fail'),
 393                                   FILES       => \%files,
 394                                   is_customer => $self->cv eq 'customer',
 395   );
 396
 397   $self->js
 398       ->run('kivi.Order.show_email_dialog', $dialog_html)
 399       ->reinit_widgets
 400       ->render($self);
 401 }
 402
 403 # send email
 404 #
 405 # Todo: handling error messages: flash is not displayed in dialog, but in the main form
 406 sub action_send_email {
 407   my ($self) = @_;
 408
 409   my $errors = $self->save();
 410
 411   if (scalar @{ $errors }) {
 412     $self->js->run('kivi.Order.close_email_dialog');
 413     $self->js->flash('error', $_) foreach @{ $errors };
 414     return $self->js->render();
 415   }
 416
 417   $self->js_reset_order_and_item_ids_after_save;
 418
 419   my $email_form  = delete $::form->{email_form};
 420   my %field_names = (to => 'email');
 421
 422   $::form->{ $field_names{$_} // $_ } = $email_form->{$_} for keys %{ $email_form };
 423
 424   # for Form::cleanup which may be called in Form::send_email
 425   $::form->{cwd}    = getcwd();
 426   $::form->{tmpdir} = $::lx_office_conf{paths}->{userspath};
 427
 428   $::form->{$_}     = $::form->{print_options}->{$_} for keys %{ $::form->{print_options} };
 429   $::form->{media}  = 'email';
 430
 431   if (($::form->{attachment_policy} // '') !~ m{^(?:old_file|no_file)$}) {
 432     my $pdf;
 433     my @errors = generate_pdf($self->order, \$pdf, {media      => $::form->{media},
 434                                                     format     => $::form->{print_options}->{format},
 435                                                     formname   => $::form->{print_options}->{formname},
 436                                                     language   => $self->order->language,
 437                                                     groupitems => $::form->{print_options}->{groupitems}});
 438     if (scalar @errors) {
 439       return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render($self);
 440     }
 441
 442     my $sfile = SL::SessionFile::Random->new(mode => "w");
 443     $sfile->fh->print($pdf);
 444     $sfile->fh->close;
 445
 446     $::form->{tmpfile} = $sfile->file_name;
 447     $::form->{tmpdir}  = $sfile->get_path; # for Form::cleanup which may be called in Form::send_email
 448   }
 449
 450   $::form->{id} = $self->order->id; # this is used in SL::Mailer to create a linked record to the mail
 451   $::form->send_email(\%::myconfig, 'pdf');
 452
 453   # internal notes
 454   my $intnotes = $self->order->intnotes;
 455   $intnotes   .= "\n\n" if $self->order->intnotes;
 456   $intnotes   .= t8('[email]')                                                                                        . "\n";
 457   $intnotes   .= t8('Date')       . ": " . $::locale->format_date_object(DateTime->now_local, precision => 'seconds') . "\n";
 458   $intnotes   .= t8('To (email)') . ": " . $::form->{email}                                                           . "\n";
 459   $intnotes   .= t8('Cc')         . ": " . $::form->{cc}                                                              . "\n"    if $::form->{cc};
 460   $intnotes   .= t8('Bcc')        . ": " . $::form->{bcc}                                                             . "\n"    if $::form->{bcc};
 461   $intnotes   .= t8('Subject')    . ": " . $::form->{subject}                                                         . "\n\n";
 462   $intnotes   .= t8('Message')    . ": " . $::form->{message};
 463
 464   $self->order->update_attributes(intnotes => $intnotes);
 465
 466   flash_later('info', t8('The email has been sent.'));
 467
 468   my @redirect_params = (
 469     action => 'edit',
 470     type   => $self->type,
 471     id     => $self->order->id,
 472   );
 473
 474   $self->redirect_to(@redirect_params);
 475 }
 476
 477 # open the periodic invoices config dialog
 478 #
 479 # If there are values in the form (i.e. dialog was opened before),
 480 # then use this values. Create new ones, else.
 481 sub action_show_periodic_invoices_config_dialog {
 482   my ($self) = @_;
 483
 484   my $config = make_periodic_invoices_config_from_yaml(delete $::form->{config});
 485   $config  ||= SL::DB::Manager::PeriodicInvoicesConfig->find_by(oe_id => $::form->{id}) if $::form->{id};
 486   $config  ||= SL::DB::PeriodicInvoicesConfig->new(periodicity             => 'm',
 487                                                    order_value_periodicity => 'p', # = same as periodicity
 488                                                    start_date_as_date      => $::form->{transdate_as_date} || $::form->current_date,
 489                                                    extend_automatically_by => 12,
 490                                                    active                  => 1,
 491                                                    email_subject           => GenericTranslations->get(
 492                                                                                 language_id      => $::form->{language_id},
 493                                                                                 translation_type =>"preset_text_periodic_invoices_email_subject"),
 494                                                    email_body              => GenericTranslations->get(
 495                                                                                 language_id      => $::form->{language_id},
 496                                                                                 translation_type =>"preset_text_periodic_invoices_email_body"),
 497   );
 498   $config->periodicity('m')             if none { $_ eq $config->periodicity             }       @SL::DB::PeriodicInvoicesConfig::PERIODICITIES;
 499   $config->order_value_periodicity('p') if none { $_ eq $config->order_value_periodicity } ('p', @SL::DB::PeriodicInvoicesConfig::ORDER_VALUE_PERIODICITIES);
 500
 501   $::form->get_lists(printers => "ALL_PRINTERS",
 502                      charts   => { key       => 'ALL_CHARTS',
 503                                    transdate => 'current_date' });
 504
 505   $::form->{AR} = [ grep { $_->{link} =~ m/(?:^|:)AR(?::|$)/ } @{ $::form->{ALL_CHARTS} } ];
 506
 507   if ($::form->{customer_id}) {
 508     $::form->{ALL_CONTACTS} = SL::DB::Manager::Contact->get_all_sorted(where => [ cp_cv_id => $::form->{customer_id} ]);
 509     $::form->{email_recipient_invoice_address} = SL::DB::Manager::Customer->find_by(id => $::form->{customer_id})->invoice_mail;
 510   }
 511
 512   $self->render('oe/edit_periodic_invoices_config', { layout => 0 },
 513                 popup_dialog             => 1,
 514                 popup_js_close_function  => 'kivi.Order.close_periodic_invoices_config_dialog()',
 515                 popup_js_assign_function => 'kivi.Order.assign_periodic_invoices_config()',
 516                 config                   => $config,
 517                 %$::form);
 518 }
 519
 520 # assign the values of the periodic invoices config dialog
 521 # as yaml in the hidden tag and set the status.
 522 sub action_assign_periodic_invoices_config {
 523   my ($self) = @_;
 524
 525   $::form->isblank('start_date_as_date', $::locale->text('The start date is missing.'));
 526
 527   my $config = { active                     => $::form->{active}       ? 1 : 0,
 528                  terminated                 => $::form->{terminated}   ? 1 : 0,
 529                  direct_debit               => $::form->{direct_debit} ? 1 : 0,
 530                  periodicity                => (any { $_ eq $::form->{periodicity}             }       @SL::DB::PeriodicInvoicesConfig::PERIODICITIES)              ? $::form->{periodicity}             : 'm',
 531                  order_value_periodicity    => (any { $_ eq $::form->{order_value_periodicity} } ('p', @SL::DB::PeriodicInvoicesConfig::ORDER_VALUE_PERIODICITIES)) ? $::form->{order_value_periodicity} : 'p',
 532                  start_date_as_date         => $::form->{start_date_as_date},
 533                  end_date_as_date           => $::form->{end_date_as_date},
 534                  first_billing_date_as_date => $::form->{first_billing_date_as_date},
 535                  print                      => $::form->{print}      ? 1                         : 0,
 536                  printer_id                 => $::form->{print}      ? $::form->{printer_id} * 1 : undef,
 537                  copies                     => $::form->{copies} * 1 ? $::form->{copies}         : 1,
 538                  extend_automatically_by    => $::form->{extend_automatically_by}    * 1 || undef,
 539                  ar_chart_id                => $::form->{ar_chart_id} * 1,
 540                  send_email                 => $::form->{send_email} ? 1 : 0,
 541                  email_recipient_contact_id => $::form->{email_recipient_contact_id} * 1 || undef,
 542                  email_recipient_address    => $::form->{email_recipient_address},
 543                  email_sender               => $::form->{email_sender},
 544                  email_subject              => $::form->{email_subject},
 545                  email_body                 => $::form->{email_body},
 546                };
 547
 548   my $periodic_invoices_config = SL::YAML::Dump($config);
 549
 550   my $status = $self->get_periodic_invoices_status($config);
 551
 552   $self->js
 553     ->remove('#order_periodic_invoices_config')
 554     ->insertAfter(hidden_tag('order.periodic_invoices_config', $periodic_invoices_config), '#periodic_invoices_status')
 555     ->run('kivi.Order.close_periodic_invoices_config_dialog')
 556     ->html('#periodic_invoices_status', $status)
 557     ->flash('info', t8('The periodic invoices config has been assigned.'))
 558     ->render($self);
 559 }
 560
 561 sub action_get_has_active_periodic_invoices {
 562   my ($self) = @_;
 563
 564   my $config = make_periodic_invoices_config_from_yaml(delete $::form->{config});
 565   $config  ||= SL::DB::Manager::PeriodicInvoicesConfig->find_by(oe_id => $::form->{id}) if $::form->{id};
 566
 567   my $has_active_periodic_invoices =
 568        $self->type eq sales_order_type()
 569     && $config
 570     && $config->active
 571     && (!$config->end_date || ($config->end_date > DateTime->today_local))
 572     && $config->get_previous_billed_period_start_date;
 573
 574   $_[0]->render(\ !!$has_active_periodic_invoices, { type => 'text' });
 575 }
 576
 577 # save the order and redirect to the frontend subroutine for a new
 578 # delivery order
 579 sub action_save_and_delivery_order {
 580   my ($self) = @_;
 581
 582   my $errors = $self->save();
 583
 584   if (scalar @{ $errors }) {
 585     $self->js->flash('error', $_) foreach @{ $errors };
 586     return $self->js->render();
 587   }
 588
 589   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
 590            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
 591            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
 592            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
 593            : '';
 594   flash_later('info', $text);
 595
 596   my @redirect_params = (
 597     controller => 'oe.pl',
 598     action     => 'oe_delivery_order_from_order',
 599     id         => $self->order->id,
 600   );
 601
 602   $self->redirect_to(@redirect_params);
 603 }
 604
 605 # save the order and redirect to the frontend subroutine for a new
 606 # invoice
 607 sub action_save_and_invoice {
 608   my ($self) = @_;
 609
 610   my $errors = $self->save();
 611
 612   if (scalar @{ $errors }) {
 613     $self->js->flash('error', $_) foreach @{ $errors };
 614     return $self->js->render();
 615   }
 616
 617   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
 618            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
 619            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
 620            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
 621            : '';
 622   flash_later('info', $text);
 623
 624   my @redirect_params = (
 625     controller => 'oe.pl',
 626     action     => 'oe_invoice_from_order',
 627     id         => $self->order->id,
 628   );
 629
 630   $self->redirect_to(@redirect_params);
 631 }
 632
 633 # workflow from sales quotation to sales order
 634 sub action_sales_order {
 635   $_[0]->workflow_sales_or_purchase_order();
 636 }
 637
 638 # workflow from rfq to purchase order
 639 sub action_purchase_order {
 640   $_[0]->workflow_sales_or_purchase_order();
 641 }
 642
 643 # workflow from purchase order to ap transaction
 644 sub action_save_and_ap_transaction {
 645   my ($self) = @_;
 646
 647   my $errors = $self->save();
 648
 649   if (scalar @{ $errors }) {
 650     $self->js->flash('error', $_) foreach @{ $errors };
 651     return $self->js->render();
 652   }
 653
 654   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
 655            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
 656            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
 657            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
 658            : '';
 659   flash_later('info', $text);
 660
 661   my @redirect_params = (
 662     controller => 'ap.pl',
 663     action     => 'add_from_purchase_order',
 664     id         => $self->order->id,
 665   );
 666
 667   $self->redirect_to(@redirect_params);
 668 }
 669
 670 # set form elements in respect to a changed customer or vendor
 671 #
 672 # This action is called on an change of the customer/vendor picker.
 673 sub action_customer_vendor_changed {
 674   my ($self) = @_;
 675
 676   setup_order_from_cv($self->order);
 677   $self->recalc();
 678
 679   my $cv_method = $self->cv;
 680
 681   if ($self->order->$cv_method->contacts && scalar @{ $self->order->$cv_method->contacts } > 0) {
 682     $self->js->show('#cp_row');
 683   } else {
 684     $self->js->hide('#cp_row');
 685   }
 686
 687   if ($self->order->$cv_method->shipto && scalar @{ $self->order->$cv_method->shipto } > 0) {
 688     $self->js->show('#shipto_selection');
 689   } else {
 690     $self->js->hide('#shipto_selection');
 691   }
 692
 693   $self->js->val( '#order_salesman_id',      $self->order->salesman_id)        if $self->order->is_sales;
 694
 695   $self->js
 696     ->replaceWith('#order_cp_id',            $self->build_contact_select)
 697     ->replaceWith('#order_shipto_id',        $self->build_shipto_select)
 698     ->replaceWith('#shipto_inputs  ',        $self->build_shipto_inputs)
 699     ->replaceWith('#business_info_row',      $self->build_business_info_row)
 700     ->val(        '#order_taxzone_id',       $self->order->taxzone_id)
 701     ->val(        '#order_taxincluded',      $self->order->taxincluded)
 702     ->val(        '#order_currency_id',      $self->order->currency_id)
 703     ->val(        '#order_payment_id',       $self->order->payment_id)
 704     ->val(        '#order_delivery_term_id', $self->order->delivery_term_id)
 705     ->val(        '#order_intnotes',         $self->order->intnotes)
 706     ->val(        '#order_language_id',      $self->order->$cv_method->language_id)
 707     ->focus(      '#order_' . $self->cv . '_id')
 708     ->run('kivi.Order.update_exchangerate');
 709
 710   $self->js_redisplay_amounts_and_taxes;
 711   $self->js_redisplay_cvpartnumbers;
 712   $self->js->render();
 713 }
 714
 715 # open the dialog for customer/vendor details
 716 sub action_show_customer_vendor_details_dialog {
 717   my ($self) = @_;
 718
 719   my $is_customer = 'customer' eq $::form->{vc};
 720   my $cv;
 721   if ($is_customer) {
 722     $cv = SL::DB::Customer->new(id => $::form->{vc_id})->load;
 723   } else {
 724     $cv = SL::DB::Vendor->new(id => $::form->{vc_id})->load;
 725   }
 726
 727   my %details = map { $_ => $cv->$_ } @{$cv->meta->columns};
 728   $details{discount_as_percent} = $cv->discount_as_percent;
 729   $details{creditlimt}          = $cv->creditlimit_as_number;
 730   $details{business}            = $cv->business->description      if $cv->business;
 731   $details{language}            = $cv->language_obj->description  if $cv->language_obj;
 732   $details{delivery_terms}      = $cv->delivery_term->description if $cv->delivery_term;
 733   $details{payment_terms}       = $cv->payment->description       if $cv->payment;
 734   $details{pricegroup}          = $cv->pricegroup->pricegroup     if $is_customer && $cv->pricegroup;
 735
 736   foreach my $entry (@{ $cv->shipto }) {
 737     push @{ $details{SHIPTO} },   { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 738   }
 739   foreach my $entry (@{ $cv->contacts }) {
 740     push @{ $details{CONTACTS} }, { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 741   }
 742
 743   $_[0]->render('common/show_vc_details', { layout => 0 },
 744                 is_customer => $is_customer,
 745                 %details);
 746
 747 }
 748
 749 # called if a unit in an existing item row is changed
 750 sub action_unit_changed {
 751   my ($self) = @_;
 752
 753   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 754   my $item = $self->order->items_sorted->[$idx];
 755
 756   my $old_unit_obj = SL::DB::Unit->new(name => $::form->{old_unit})->load;
 757   $item->sellprice($item->unit_obj->convert_to($item->sellprice, $old_unit_obj));
 758
 759   $self->recalc();
 760
 761   $self->js
 762     ->run('kivi.Order.update_sellprice', $::form->{item_id}, $item->sellprice_as_number);
 763   $self->js_redisplay_line_values;
 764   $self->js_redisplay_amounts_and_taxes;
 765   $self->js->render();
 766 }
 767
 768 # add an item row for a new item entered in the input row
 769 sub action_add_item {
 770   my ($self) = @_;
 771
 772   my $form_attr = $::form->{add_item};
 773
 774   return unless $form_attr->{parts_id};
 775
 776   my $item = new_item($self->order, $form_attr);
 777
 778   $self->order->add_items($item);
 779
 780   $self->recalc();
 781
 782   $self->get_item_cvpartnumber($item);
 783
 784   my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 785   my $row_as_html = $self->p->render('order/tabs/_row',
 786                                      ITEM => $item,
 787                                      ID   => $item_id,
 788                                      SELF => $self,
 789   );
 790
 791   if ($::form->{insert_before_item_id}) {
 792     $self->js
 793       ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 794   } else {
 795     $self->js
 796       ->append('#row_table_id', $row_as_html);
 797   }
 798
 799   if ( $item->part->is_assortment ) {
 800     $form_attr->{qty_as_number} = 1 unless $form_attr->{qty_as_number};
 801     foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 802       my $attr = { parts_id => $assortment_item->parts_id,
 803                    qty      => $assortment_item->qty * $::form->parse_amount(\%::myconfig, $form_attr->{qty_as_number}), # TODO $form_attr->{unit}
 804                    unit     => $assortment_item->unit,
 805                    description => $assortment_item->part->description,
 806                  };
 807       my $item = new_item($self->order, $attr);
 808
 809       # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 810       $item->discount(1) unless $assortment_item->charge;
 811
 812       $self->order->add_items( $item );
 813       $self->recalc();
 814       $self->get_item_cvpartnumber($item);
 815       my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 816       my $row_as_html = $self->p->render('order/tabs/_row',
 817                                          ITEM => $item,
 818                                          ID   => $item_id,
 819                                          SELF => $self,
 820       );
 821       if ($::form->{insert_before_item_id}) {
 822         $self->js
 823           ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 824       } else {
 825         $self->js
 826           ->append('#row_table_id', $row_as_html);
 827       }
 828     };
 829   };
 830
 831   $self->js
 832     ->val('.add_item_input', '')
 833     ->run('kivi.Order.init_row_handlers')
 834     ->run('kivi.Order.renumber_positions')
 835     ->focus('#add_item_parts_id_name');
 836
 837   $self->js->run('kivi.Order.row_table_scroll_down') if !$::form->{insert_before_item_id};
 838
 839   $self->js_redisplay_amounts_and_taxes;
 840   $self->js->render();
 841 }
 842
 843 # open the dialog for entering multiple items at once
 844 sub action_show_multi_items_dialog {
 845   $_[0]->render('order/tabs/_multi_items_dialog', { layout => 0 },
 846                 all_partsgroups => SL::DB::Manager::PartsGroup->get_all);
 847 }
 848
 849 # update the filter results in the multi item dialog
 850 sub action_multi_items_update_result {
 851   my $max_count = 100;
 852
 853   $::form->{multi_items}->{filter}->{obsolete} = 0;
 854
 855   my $count = $_[0]->multi_items_models->count;
 856
 857   if ($count == 0) {
 858     my $text = SL::Presenter::EscapedText->new(text => $::locale->text('No results.'));
 859     $_[0]->render($text, { layout => 0 });
 860   } elsif ($count > $max_count) {
 861     my $text = SL::Presenter::EscapedText->new(text => $::locale->text('Too many results (#1 from #2).', $count, $max_count));
 862     $_[0]->render($text, { layout => 0 });
 863   } else {
 864     my $multi_items = $_[0]->multi_items_models->get;
 865     $_[0]->render('order/tabs/_multi_items_result', { layout => 0 },
 866                   multi_items => $multi_items);
 867   }
 868 }
 869
 870 # add item rows for multiple items at once
 871 sub action_add_multi_items {
 872   my ($self) = @_;
 873
 874   my @form_attr = grep { $_->{qty_as_number} } @{ $::form->{add_multi_items} };
 875   return $self->js->render() unless scalar @form_attr;
 876
 877   my @items;
 878   foreach my $attr (@form_attr) {
 879     my $item = new_item($self->order, $attr);
 880     push @items, $item;
 881     if ( $item->part->is_assortment ) {
 882       foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 883         my $attr = { parts_id => $assortment_item->parts_id,
 884                      qty      => $assortment_item->qty * $item->qty, # TODO $form_attr->{unit}
 885                      unit     => $assortment_item->unit,
 886                      description => $assortment_item->part->description,
 887                    };
 888         my $item = new_item($self->order, $attr);
 889
 890         # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 891         $item->discount(1) unless $assortment_item->charge;
 892         push @items, $item;
 893       }
 894     }
 895   }
 896   $self->order->add_items(@items);
 897
 898   $self->recalc();
 899
 900   foreach my $item (@items) {
 901     $self->get_item_cvpartnumber($item);
 902     my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 903     my $row_as_html = $self->p->render('order/tabs/_row',
 904                                        ITEM => $item,
 905                                        ID   => $item_id,
 906                                        SELF => $self,
 907     );
 908
 909     if ($::form->{insert_before_item_id}) {
 910       $self->js
 911         ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 912     } else {
 913       $self->js
 914         ->append('#row_table_id', $row_as_html);
 915     }
 916   }
 917
 918   $self->js
 919     ->run('kivi.Order.close_multi_items_dialog')
 920     ->run('kivi.Order.init_row_handlers')
 921     ->run('kivi.Order.renumber_positions')
 922     ->focus('#add_item_parts_id_name');
 923
 924   $self->js->run('kivi.Order.row_table_scroll_down') if !$::form->{insert_before_item_id};
 925
 926   $self->js_redisplay_amounts_and_taxes;
 927   $self->js->render();
 928 }
 929
 930 # recalculate all linetotals, amounts and taxes and redisplay them
 931 sub action_recalc_amounts_and_taxes {
 932   my ($self) = @_;
 933
 934   $self->recalc();
 935
 936   $self->js_redisplay_line_values;
 937   $self->js_redisplay_amounts_and_taxes;
 938   $self->js->render();
 939 }
 940
 941 sub action_update_exchangerate {
 942   my ($self) = @_;
 943
 944   my $data = {
 945     is_standard   => $self->order->currency_id == $::instance_conf->get_currency_id,
 946     currency_name => $self->order->currency->name,
 947     exchangerate  => $self->order->daily_exchangerate_as_null_number,
 948   };
 949
 950   $self->render(\SL::JSON::to_json($data), { type => 'json', process => 0 });
 951 }
 952
 953 # redisplay item rows if they are sorted by an attribute
 954 sub action_reorder_items {
 955   my ($self) = @_;
 956
 957   my %sort_keys = (
 958     partnumber   => sub { $_[0]->part->partnumber },
 959     description  => sub { $_[0]->description },
 960     qty          => sub { $_[0]->qty },
 961     sellprice    => sub { $_[0]->sellprice },
 962     discount     => sub { $_[0]->discount },
 963     cvpartnumber => sub { $_[0]->{cvpartnumber} },
 964   );
 965
 966   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
 967
 968   my $method = $sort_keys{$::form->{order_by}};
 969   my @to_sort = map { { old_pos => $_->position, order_by => $method->($_) } } @{ $self->order->items_sorted };
 970   if ($::form->{sort_dir}) {
 971     if ( $::form->{order_by} =~ m/qty|sellprice|discount/ ){
 972       @to_sort = sort { $a->{order_by} <=> $b->{order_by} } @to_sort;
 973     } else {
 974       @to_sort = sort { $a->{order_by} cmp $b->{order_by} } @to_sort;
 975     }
 976   } else {
 977     if ( $::form->{order_by} =~ m/qty|sellprice|discount/ ){
 978       @to_sort = sort { $b->{order_by} <=> $a->{order_by} } @to_sort;
 979     } else {
 980       @to_sort = sort { $b->{order_by} cmp $a->{order_by} } @to_sort;
 981     }
 982   }
 983   $self->js
 984     ->run('kivi.Order.redisplay_items', \@to_sort)
 985     ->render;
 986 }
 987
 988 # show the popup to choose a price/discount source
 989 sub action_price_popup {
 990   my ($self) = @_;
 991
 992   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 993   my $item = $self->order->items_sorted->[$idx];
 994
 995   $self->render_price_dialog($item);
 996 }
 997
 998 # get the longdescription for an item if the dialog to enter/change the
 999 # longdescription was opened and the longdescription is empty
1000 #
1001 # If this item is new, get the longdescription from Part.
1002 # Otherwise get it from OrderItem.
1003 sub action_get_item_longdescription {
1004   my $longdescription;
1005
1006   if ($::form->{item_id}) {
1007     $longdescription = SL::DB::OrderItem->new(id => $::form->{item_id})->load->longdescription;
1008   } elsif ($::form->{parts_id}) {
1009     $longdescription = get_part_texts($::form->{parts_id}, $::form->{language_id})->{longdescription};
1010   }
1011   $_[0]->render(\ $longdescription, { type => 'text' });
1012 }
1013
1014 # load the second row for one or more items
1015 #
1016 # This action gets the html code for all items second rows by rendering a template for
1017 # the second row and sets the html code via client js.
1018 sub action_load_second_rows {
1019   my ($self) = @_;
1020
1021   $self->recalc() if $self->order->is_sales; # for margin calculation
1022
1023   foreach my $item_id (@{ $::form->{item_ids} }) {
1024     my $idx  = first_index { $_ eq $item_id } @{ $::form->{orderitem_ids} };
1025     my $item = $self->order->items_sorted->[$idx];
1026
1027     $self->js_load_second_row($item, $item_id, 0);
1028   }
1029
1030   $self->js->run('kivi.Order.init_row_handlers') if $self->order->is_sales; # for lastcosts change-callback
1031
1032   $self->js->render();
1033 }
1034
1035 # update description, notes and sellprice from master data
1036 sub action_update_row_from_master_data {
1037   my ($self) = @_;
1038
1039   foreach my $item_id (@{ $::form->{item_ids} }) {
1040     my $idx  = first_index { $_ eq $item_id } @{ $::form->{orderitem_ids} };
1041     my $item = $self->order->items_sorted->[$idx];
1042
1043     $item->description($item->part->description);
1044     $item->longdescription($item->part->notes);
1045
1046     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
1047
1048     my $price_src;
1049     if ($item->part->is_assortment) {
1050     # add assortment items with price 0, as the components carry the price
1051       $price_src = $price_source->price_from_source("");
1052       $price_src->price(0);
1053     } else {
1054       $price_src = $price_source->best_price
1055                  ? $price_source->best_price
1056                  : $price_source->price_from_source("");
1057       $price_src->price($::form->round_amount($price_src->price / $self->order->exchangerate, 5)) if $self->order->exchangerate;
1058       $price_src->price(0) if !$price_source->best_price;
1059     }
1060
1061
1062     $item->sellprice($price_src->price);
1063     $item->active_price_source($price_src);
1064
1065     $self->js
1066       ->run('kivi.Order.update_sellprice', $item_id, $item->sellprice_as_number)
1067       ->html('.row_entry:has(#item_' . $item_id . ') [name = "partnumber"] a', $item->part->partnumber)
1068       ->val ('.row_entry:has(#item_' . $item_id . ') [name = "order.orderitems[].description"]', $item->description)
1069       ->val ('.row_entry:has(#item_' . $item_id . ') [name = "order.orderitems[].longdescription"]', $item->longdescription);
1070
1071     if ($self->search_cvpartnumber) {
1072       $self->get_item_cvpartnumber($item);
1073       $self->js->html('.row_entry:has(#item_' . $item_id . ') [name = "cvpartnumber"]', $item->{cvpartnumber});
1074     }
1075   }
1076
1077   $self->recalc();
1078   $self->js_redisplay_line_values;
1079   $self->js_redisplay_amounts_and_taxes;
1080
1081   $self->js->render();
1082 }
1083
1084 sub js_load_second_row {
1085   my ($self, $item, $item_id, $do_parse) = @_;
1086
1087   if ($do_parse) {
1088     # Parse values from form (they are formated while rendering (template)).
1089     # Workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
1090     # This parsing is not necessary at all, if we assure that the second row/cvars are only loaded once.
1091     foreach my $var (@{ $item->cvars_by_config }) {
1092       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
1093     }
1094     $item->parse_custom_variable_values;
1095   }
1096
1097   my $row_as_html = $self->p->render('order/tabs/_second_row', ITEM => $item, TYPE => $self->type);
1098
1099   $self->js
1100     ->html('#second_row_' . $item_id, $row_as_html)
1101     ->data('#second_row_' . $item_id, 'loaded', 1);
1102 }
1103
1104 sub js_redisplay_line_values {
1105   my ($self) = @_;
1106
1107   my $is_sales = $self->order->is_sales;
1108
1109   # sales orders with margins
1110   my @data;
1111   if ($is_sales) {
1112     @data = map {
1113       [
1114        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
1115        $::form->format_amount(\%::myconfig, $_->{marge_total},   2, 0),
1116        $::form->format_amount(\%::myconfig, $_->{marge_percent}, 2, 0),
1117       ]} @{ $self->order->items_sorted };
1118   } else {
1119     @data = map {
1120       [
1121        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
1122       ]} @{ $self->order->items_sorted };
1123   }
1124
1125   $self->js
1126     ->run('kivi.Order.redisplay_line_values', $is_sales, \@data);
1127 }
1128
1129 sub js_redisplay_amounts_and_taxes {
1130   my ($self) = @_;
1131
1132   if (scalar @{ $self->{taxes} }) {
1133     $self->js->show('#taxincluded_row_id');
1134   } else {
1135     $self->js->hide('#taxincluded_row_id');
1136   }
1137
1138   if ($self->order->taxincluded) {
1139     $self->js->hide('#subtotal_row_id');
1140   } else {
1141     $self->js->show('#subtotal_row_id');
1142   }
1143
1144   if ($self->order->is_sales) {
1145     my $is_neg = $self->order->marge_total < 0;
1146     $self->js
1147       ->html('#marge_total_id',   $::form->format_amount(\%::myconfig, $self->order->marge_total,   2))
1148       ->html('#marge_percent_id', $::form->format_amount(\%::myconfig, $self->order->marge_percent, 2))
1149       ->action_if( $is_neg, 'addClass',    '#marge_total_id',        'plus0')
1150       ->action_if( $is_neg, 'addClass',    '#marge_percent_id',      'plus0')
1151       ->action_if( $is_neg, 'addClass',    '#marge_percent_sign_id', 'plus0')
1152       ->action_if(!$is_neg, 'removeClass', '#marge_total_id',        'plus0')
1153       ->action_if(!$is_neg, 'removeClass', '#marge_percent_id',      'plus0')
1154       ->action_if(!$is_neg, 'removeClass', '#marge_percent_sign_id', 'plus0');
1155   }
1156
1157   $self->js
1158     ->html('#netamount_id', $::form->format_amount(\%::myconfig, $self->order->netamount, -2))
1159     ->html('#amount_id',    $::form->format_amount(\%::myconfig, $self->order->amount,    -2))
1160     ->remove('.tax_row')
1161     ->insertBefore($self->build_tax_rows, '#amount_row_id');
1162 }
1163
1164 sub js_redisplay_cvpartnumbers {
1165   my ($self) = @_;
1166
1167   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
1168
1169   my @data = map {[$_->{cvpartnumber}]} @{ $self->order->items_sorted };
1170
1171   $self->js
1172     ->run('kivi.Order.redisplay_cvpartnumbers', \@data);
1173 }
1174
1175 sub js_reset_order_and_item_ids_after_save {
1176   my ($self) = @_;
1177
1178   $self->js
1179     ->val('#id', $self->order->id)
1180     ->val('#converted_from_oe_id', '')
1181     ->val('#order_' . $self->nr_key(), $self->order->number);
1182
1183   my $idx = 0;
1184   foreach my $form_item_id (@{ $::form->{orderitem_ids} }) {
1185     next if !$self->order->items_sorted->[$idx]->id;
1186     next if $form_item_id !~ m{^new};
1187     $self->js
1188       ->val ('[name="orderitem_ids[+]"][value="' . $form_item_id . '"]', $self->order->items_sorted->[$idx]->id)
1189       ->val ('#item_' . $form_item_id, $self->order->items_sorted->[$idx]->id)
1190       ->attr('#item_' . $form_item_id, "id", 'item_' . $self->order->items_sorted->[$idx]->id);
1191   } continue {
1192     $idx++;
1193   }
1194   $self->js->val('[name="converted_from_orderitems_ids[+]"]', '');
1195 }
1196
1197 #
1198 # helpers
1199 #
1200
1201 sub init_valid_types {
1202   [ sales_order_type(), purchase_order_type(), sales_quotation_type(), request_quotation_type() ];
1203 }
1204
1205 sub init_type {
1206   my ($self) = @_;
1207
1208   if (none { $::form->{type} eq $_ } @{$self->valid_types}) {
1209     die "Not a valid type for order";
1210   }
1211
1212   $self->type($::form->{type});
1213 }
1214
1215 sub init_cv {
1216   my ($self) = @_;
1217
1218   my $cv = (any { $self->type eq $_ } (sales_order_type(),    sales_quotation_type()))   ? 'customer'
1219          : (any { $self->type eq $_ } (purchase_order_type(), request_quotation_type())) ? 'vendor'
1220          : die "Not a valid type for order";
1221
1222   return $cv;
1223 }
1224
1225 sub init_search_cvpartnumber {
1226   my ($self) = @_;
1227
1228   my $user_prefs = SL::Helper::UserPreferences::PartPickerSearch->new();
1229   my $search_cvpartnumber;
1230   $search_cvpartnumber = !!$user_prefs->get_sales_search_customer_partnumber() if $self->cv eq 'customer';
1231   $search_cvpartnumber = !!$user_prefs->get_purchase_search_makemodel()        if $self->cv eq 'vendor';
1232
1233   return $search_cvpartnumber;
1234 }
1235
1236 sub init_show_update_button {
1237   my ($self) = @_;
1238
1239   !!SL::Helper::UserPreferences::UpdatePositions->new()->get_show_update_button();
1240 }
1241
1242 sub init_p {
1243   SL::Presenter->get;
1244 }
1245
1246 sub init_order {
1247   $_[0]->make_order;
1248 }
1249
1250 # model used to filter/display the parts in the multi-items dialog
1251 sub init_multi_items_models {
1252   SL::Controller::Helper::GetModels->new(
1253     controller     => $_[0],
1254     model          => 'Part',
1255     with_objects   => [ qw(unit_obj) ],
1256     disable_plugin => 'paginated',
1257     source         => $::form->{multi_items},
1258     sorted         => {
1259       _default    => {
1260         by  => 'partnumber',
1261         dir => 1,
1262       },
1263       partnumber  => t8('Partnumber'),
1264       description => t8('Description')}
1265   );
1266 }
1267
1268 sub init_all_price_factors {
1269   SL::DB::Manager::PriceFactor->get_all;
1270 }
1271
1272 sub check_auth {
1273   my ($self) = @_;
1274
1275   my $right_for = { map { $_ => $_.'_edit' } @{$self->valid_types} };
1276
1277   my $right   = $right_for->{ $self->type };
1278   $right    ||= 'DOES_NOT_EXIST';
1279
1280   $::auth->assert($right);
1281 }
1282
1283 # build the selection box for contacts
1284 #
1285 # Needed, if customer/vendor changed.
1286 sub build_contact_select {
1287   my ($self) = @_;
1288
1289   select_tag('order.cp_id', [ $self->order->{$self->cv}->contacts ],
1290     value_key  => 'cp_id',
1291     title_key  => 'full_name_dep',
1292     default    => $self->order->cp_id,
1293     with_empty => 1,
1294     style      => 'width: 300px',
1295   );
1296 }
1297
1298 # build the selection box for shiptos
1299 #
1300 # Needed, if customer/vendor changed.
1301 sub build_shipto_select {
1302   my ($self) = @_;
1303
1304   select_tag('order.shipto_id',
1305              [ {displayable_id => t8("No/individual shipping address"), shipto_id => ''}, $self->order->{$self->cv}->shipto ],
1306              value_key  => 'shipto_id',
1307              title_key  => 'displayable_id',
1308              default    => $self->order->shipto_id,
1309              with_empty => 0,
1310              style      => 'width: 300px',
1311   );
1312 }
1313
1314 # build the inputs for the cusom shipto dialog
1315 #
1316 # Needed, if customer/vendor changed.
1317 sub build_shipto_inputs {
1318   my ($self) = @_;
1319
1320   my $content = $self->p->render('common/_ship_to_dialog',
1321                                  vc_obj      => $self->order->customervendor,
1322                                  cs_obj      => $self->order->custom_shipto,
1323                                  cvars       => $self->order->custom_shipto->cvars_by_config,
1324                                  id_selector => '#order_shipto_id');
1325
1326   div_tag($content, id => 'shipto_inputs');
1327 }
1328
1329 # render the info line for business
1330 #
1331 # Needed, if customer/vendor changed.
1332 sub build_business_info_row
1333 {
1334   $_[0]->p->render('order/tabs/_business_info_row', SELF => $_[0]);
1335 }
1336
1337 # build the rows for displaying taxes
1338 #
1339 # Called if amounts where recalculated and redisplayed.
1340 sub build_tax_rows {
1341   my ($self) = @_;
1342
1343   my $rows_as_html;
1344   foreach my $tax (sort { $a->{tax}->rate cmp $b->{tax}->rate } @{ $self->{taxes} }) {
1345     $rows_as_html .= $self->p->render('order/tabs/_tax_row', TAX => $tax, TAXINCLUDED => $self->order->taxincluded);
1346   }
1347   return $rows_as_html;
1348 }
1349
1350
1351 sub render_price_dialog {
1352   my ($self, $record_item) = @_;
1353
1354   my $price_source = SL::PriceSource->new(record_item => $record_item, record => $self->order);
1355
1356   $self->js
1357     ->run(
1358       'kivi.io.price_chooser_dialog',
1359       t8('Available Prices'),
1360       $self->render('order/tabs/_price_sources_dialog', { output => 0 }, price_source => $price_source)
1361     )
1362     ->reinit_widgets;
1363
1364 #   if (@errors) {
1365 #     $self->js->text('#dialog_flash_error_content', join ' ', @errors);
1366 #     $self->js->show('#dialog_flash_error');
1367 #   }
1368
1369   $self->js->render;
1370 }
1371
1372 sub load_order {
1373   my ($self) = @_;
1374
1375   return if !$::form->{id};
1376
1377   $self->order(SL::DB::Order->new(id => $::form->{id})->load);
1378
1379   # Add an empty custom shipto to the order, so that the dialog can render the cvar inputs.
1380   # You need a custom shipto object to call cvars_by_config to get the cvars.
1381   $self->order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => [])) if !$self->order->custom_shipto;
1382
1383   return $self->order;
1384 }
1385
1386 # load or create a new order object
1387 #
1388 # And assign changes from the form to this object.
1389 # If the order is loaded from db, check if items are deleted in the form,
1390 # remove them form the object and collect them for removing from db on saving.
1391 # Then create/update items from form (via make_item) and add them.
1392 sub make_order {
1393   my ($self) = @_;
1394
1395   # add_items adds items to an order with no items for saving, but they cannot
1396   # be retrieved via items until the order is saved. Adding empty items to new
1397   # order here solves this problem.
1398   my $order;
1399   $order   = SL::DB::Order->new(id => $::form->{id})->load(with => [ 'orderitems', 'orderitems.part' ]) if $::form->{id};
1400   $order ||= SL::DB::Order->new(orderitems  => [],
1401                                 quotation   => (any { $self->type eq $_ } (sales_quotation_type(), request_quotation_type())),
1402                                 currency_id => $::instance_conf->get_currency_id(),);
1403
1404   my $cv_id_method = $self->cv . '_id';
1405   if (!$::form->{id} && $::form->{$cv_id_method}) {
1406     $order->$cv_id_method($::form->{$cv_id_method});
1407     setup_order_from_cv($order);
1408   }
1409
1410   my $form_orderitems                  = delete $::form->{order}->{orderitems};
1411   my $form_periodic_invoices_config    = delete $::form->{order}->{periodic_invoices_config};
1412
1413   $order->assign_attributes(%{$::form->{order}});
1414
1415   $self->setup_custom_shipto_from_form($order, $::form);
1416
1417   if (my $periodic_invoices_config_attrs = $form_periodic_invoices_config ? SL::YAML::Load($form_periodic_invoices_config) : undef) {
1418     my $periodic_invoices_config = $order->periodic_invoices_config || $order->periodic_invoices_config(SL::DB::PeriodicInvoicesConfig->new);
1419     $periodic_invoices_config->assign_attributes(%$periodic_invoices_config_attrs);
1420   }
1421
1422   # remove deleted items
1423   $self->item_ids_to_delete([]);
1424   foreach my $idx (reverse 0..$#{$order->orderitems}) {
1425     my $item = $order->orderitems->[$idx];
1426     if (none { $item->id == $_->{id} } @{$form_orderitems}) {
1427       splice @{$order->orderitems}, $idx, 1;
1428       push @{$self->item_ids_to_delete}, $item->id;
1429     }
1430   }
1431
1432   my @items;
1433   my $pos = 1;
1434   foreach my $form_attr (@{$form_orderitems}) {
1435     my $item = make_item($order, $form_attr);
1436     $item->position($pos);
1437     push @items, $item;
1438     $pos++;
1439   }
1440   $order->add_items(grep {!$_->id} @items);
1441
1442   return $order;
1443 }
1444
1445 # create or update items from form
1446 #
1447 # Make item objects from form values. For items already existing read from db.
1448 # Create a new item else. And assign attributes.
1449 sub make_item {
1450   my ($record, $attr) = @_;
1451
1452   my $item;
1453   $item = first { $_->id == $attr->{id} } @{$record->items} if $attr->{id};
1454
1455   my $is_new = !$item;
1456
1457   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1458   # they cannot be retrieved via custom_variables until the order/orderitem is
1459   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1460   $item ||= SL::DB::OrderItem->new(custom_variables => []);
1461
1462   $item->assign_attributes(%$attr);
1463
1464   if ($is_new) {
1465     my $texts = get_part_texts($item->part, $record->language_id);
1466     $item->longdescription($texts->{longdescription})              if !defined $attr->{longdescription};
1467     $item->project_id($record->globalproject_id)                   if !defined $attr->{project_id};
1468     $item->lastcost($record->is_sales ? $item->part->lastcost : 0) if !defined $attr->{lastcost_as_number};
1469   }
1470
1471   return $item;
1472 }
1473
1474 # create a new item
1475 #
1476 # This is used to add one item
1477 sub new_item {
1478   my ($record, $attr) = @_;
1479
1480   my $item = SL::DB::OrderItem->new;
1481
1482   # Remove attributes where the user left or set the inputs empty.
1483   # So these attributes will be undefined and we can distinguish them
1484   # from zero later on.
1485   for (qw(qty_as_number sellprice_as_number discount_as_percent)) {
1486     delete $attr->{$_} if $attr->{$_} eq '';
1487   }
1488
1489   $item->assign_attributes(%$attr);
1490
1491   my $part         = SL::DB::Part->new(id => $attr->{parts_id})->load;
1492   my $price_source = SL::PriceSource->new(record_item => $item, record => $record);
1493
1494   $item->unit($part->unit) if !$item->unit;
1495
1496   my $price_src;
1497   if ( $part->is_assortment ) {
1498     # add assortment items with price 0, as the components carry the price
1499     $price_src = $price_source->price_from_source("");
1500     $price_src->price(0);
1501   } elsif (defined $item->sellprice) {
1502     $price_src = $price_source->price_from_source("");
1503     $price_src->price($item->sellprice);
1504   } else {
1505     $price_src = $price_source->best_price
1506                ? $price_source->best_price
1507                : $price_source->price_from_source("");
1508     $price_src->price($::form->round_amount($price_src->price / $record->exchangerate, 5)) if $record->exchangerate;
1509     $price_src->price(0) if !$price_source->best_price;
1510   }
1511
1512   my $discount_src;
1513   if (defined $item->discount) {
1514     $discount_src = $price_source->discount_from_source("");
1515     $discount_src->discount($item->discount);
1516   } else {
1517     $discount_src = $price_source->best_discount
1518                   ? $price_source->best_discount
1519                   : $price_source->discount_from_source("");
1520     $discount_src->discount(0) if !$price_source->best_discount;
1521   }
1522
1523   my %new_attr;
1524   $new_attr{part}                   = $part;
1525   $new_attr{description}            = $part->description     if ! $item->description;
1526   $new_attr{qty}                    = 1.0                    if ! $item->qty;
1527   $new_attr{price_factor_id}        = $part->price_factor_id if ! $item->price_factor_id;
1528   $new_attr{sellprice}              = $price_src->price;
1529   $new_attr{discount}               = $discount_src->discount;
1530   $new_attr{active_price_source}    = $price_src;
1531   $new_attr{active_discount_source} = $discount_src;
1532   $new_attr{longdescription}        = $part->notes           if ! defined $attr->{longdescription};
1533   $new_attr{project_id}             = $record->globalproject_id;
1534   $new_attr{lastcost}               = $record->is_sales ? $part->lastcost : 0;
1535
1536   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1537   # they cannot be retrieved via custom_variables until the order/orderitem is
1538   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1539   $new_attr{custom_variables} = [];
1540
1541   my $texts = get_part_texts($part, $record->language_id, description => $new_attr{description}, longdescription => $new_attr{longdescription});
1542
1543   $item->assign_attributes(%new_attr, %{ $texts });
1544
1545   return $item;
1546 }
1547
1548 sub setup_order_from_cv {
1549   my ($order) = @_;
1550
1551   $order->$_($order->customervendor->$_) for (qw(taxzone_id payment_id delivery_term_id currency_id));
1552
1553   $order->intnotes($order->customervendor->notes);
1554
1555   if ($order->is_sales) {
1556     $order->salesman_id($order->customer->salesman_id || SL::DB::Manager::Employee->current->id);
1557     $order->taxincluded(defined($order->customer->taxincluded_checked)
1558                         ? $order->customer->taxincluded_checked
1559                         : $::myconfig{taxincluded_checked});
1560   }
1561
1562 }
1563
1564 # setup custom shipto from form
1565 #
1566 # The dialog returns form variables starting with 'shipto' and cvars starting
1567 # with 'shiptocvar_'.
1568 # Mark it to be deleted if a shipto from master data is selected
1569 # (i.e. order has a shipto).
1570 # Else, update or create a new custom shipto. If the fields are empty, it
1571 # will not be saved on save.
1572 sub setup_custom_shipto_from_form {
1573   my ($self, $order, $form) = @_;
1574
1575   if ($order->shipto) {
1576     $self->is_custom_shipto_to_delete(1);
1577   } else {
1578     my $custom_shipto = $order->custom_shipto || $order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => []));
1579
1580     my $shipto_cvars  = {map { my ($key) = m{^shiptocvar_(.+)}; $key => delete $form->{$_}} grep { m{^shiptocvar_} } keys %$form};
1581     my $shipto_attrs  = {map {                                  $_   => delete $form->{$_}} grep { m{^shipto}      } keys %$form};
1582
1583     $custom_shipto->assign_attributes(%$shipto_attrs);
1584     $custom_shipto->cvar_by_name($_)->value($shipto_cvars->{$_}) for keys %$shipto_cvars;
1585   }
1586 }
1587
1588 # recalculate prices and taxes
1589 #
1590 # Using the PriceTaxCalculator. Store linetotals in the item objects.
1591 sub recalc {
1592   my ($self) = @_;
1593
1594   my %pat = $self->order->calculate_prices_and_taxes();
1595
1596   $self->{taxes} = [];
1597   foreach my $tax_id (keys %{ $pat{taxes_by_tax_id} }) {
1598     my $netamount = sum0 map { $pat{amounts}->{$_}->{amount} } grep { $pat{amounts}->{$_}->{tax_id} == $tax_id } keys %{ $pat{amounts} };
1599
1600     push(@{ $self->{taxes} }, { amount    => $pat{taxes_by_tax_id}->{$tax_id},
1601                                 netamount => $netamount,
1602                                 tax       => SL::DB::Tax->new(id => $tax_id)->load });
1603   }
1604   pairwise { $a->{linetotal} = $b->{linetotal} } @{$self->order->items_sorted}, @{$pat{items}};
1605 }
1606
1607 # get data for saving, printing, ..., that is not changed in the form
1608 #
1609 # Only cvars for now.
1610 sub get_unalterable_data {
1611   my ($self) = @_;
1612
1613   foreach my $item (@{ $self->order->items }) {
1614     # autovivify all cvars that are not in the form (cvars_by_config can do it).
1615     # workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
1616     foreach my $var (@{ $item->cvars_by_config }) {
1617       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
1618     }
1619     $item->parse_custom_variable_values;
1620   }
1621 }
1622
1623 # delete the order
1624 #
1625 # And remove related files in the spool directory
1626 sub delete {
1627   my ($self) = @_;
1628
1629   my $errors = [];
1630   my $db     = $self->order->db;
1631
1632   $db->with_transaction(
1633     sub {
1634       my @spoolfiles = grep { $_ } map { $_->spoolfile } @{ SL::DB::Manager::Status->get_all(where => [ trans_id => $self->order->id ]) };
1635       $self->order->delete;
1636       my $spool = $::lx_office_conf{paths}->{spool};
1637       unlink map { "$spool/$_" } @spoolfiles if $spool;
1638
1639       1;
1640   }) || push(@{$errors}, $db->error);
1641
1642   return $errors;
1643 }
1644
1645 # save the order
1646 #
1647 # And delete items that are deleted in the form.
1648 sub save {
1649   my ($self) = @_;
1650
1651   my $errors = [];
1652   my $db     = $self->order->db;
1653
1654   $db->with_transaction(sub {
1655     # delete custom shipto if it is to be deleted or if it is empty
1656     if ($self->order->custom_shipto && ($self->is_custom_shipto_to_delete || $self->order->custom_shipto->is_empty)) {
1657       $self->order->custom_shipto->delete if $self->order->custom_shipto->shipto_id;
1658       $self->order->custom_shipto(undef);
1659     }
1660
1661     SL::DB::OrderItem->new(id => $_)->delete for @{$self->item_ids_to_delete || []};
1662     $self->order->save(cascade => 1);
1663
1664     # link records
1665     if ($::form->{converted_from_oe_id}) {
1666       my @converted_from_oe_ids = split ' ', $::form->{converted_from_oe_id};
1667       foreach my $converted_from_oe_id (@converted_from_oe_ids) {
1668         my $src = SL::DB::Order->new(id => $converted_from_oe_id)->load;
1669         $src->update_attributes(closed => 1) if $src->type =~ /_quotation$/;
1670         $src->link_to_record($self->order);
1671       }
1672       if (scalar @{ $::form->{converted_from_orderitems_ids} || [] }) {
1673         my $idx = 0;
1674         foreach (@{ $self->order->items_sorted }) {
1675           my $from_id = $::form->{converted_from_orderitems_ids}->[$idx];
1676           next if !$from_id;
1677           SL::DB::RecordLink->new(from_table => 'orderitems',
1678                                   from_id    => $from_id,
1679                                   to_table   => 'orderitems',
1680                                   to_id      => $_->id
1681           )->save;
1682           $idx++;
1683         }
1684       }
1685     }
1686     1;
1687   }) || push(@{$errors}, $db->error);
1688
1689   return $errors;
1690 }
1691
1692 sub workflow_sales_or_purchase_order {
1693   my ($self) = @_;
1694
1695   # always save
1696   my $errors = $self->save();
1697
1698   if (scalar @{ $errors }) {
1699     $self->js->flash('error', $_) foreach @{ $errors };
1700     return $self->js->render();
1701   }
1702
1703   my $destination_type = $::form->{type} eq sales_quotation_type()   ? sales_order_type()
1704                        : $::form->{type} eq request_quotation_type() ? purchase_order_type()
1705                        : $::form->{type} eq purchase_order_type()    ? sales_order_type()
1706                        : $::form->{type} eq sales_order_type()       ? purchase_order_type()
1707                        : '';
1708
1709   # check for direct delivery
1710   # copy shipto in custom shipto (custom shipto will be copied by new_from() in case)
1711   my $custom_shipto;
1712   if (   $::form->{type} eq sales_order_type() && $destination_type eq purchase_order_type()
1713       && $::form->{use_shipto} && $self->order->shipto) {
1714     $custom_shipto = $self->order->shipto->clone('SL::DB::Order');
1715   }
1716
1717   $self->order(SL::DB::Order->new_from($self->order, destination_type => $destination_type));
1718   $self->{converted_from_oe_id} = delete $::form->{id};
1719
1720   # set item ids to new fake id, to identify them as new items
1721   foreach my $item (@{$self->order->items_sorted}) {
1722     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1723   }
1724
1725   if ($::form->{type} eq sales_order_type() && $destination_type eq purchase_order_type()) {
1726     if ($::form->{use_shipto}) {
1727       $self->order->custom_shipto($custom_shipto) if $custom_shipto;
1728     } else {
1729       # remove any custom shipto if not wanted
1730       $self->order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => []));
1731     }
1732   }
1733
1734   # change form type
1735   $::form->{type} = $destination_type;
1736   $self->type($self->init_type);
1737   $self->cv  ($self->init_cv);
1738   $self->check_auth;
1739
1740   $self->recalc();
1741   $self->get_unalterable_data();
1742   $self->pre_render();
1743
1744   # trigger rendering values for second row/longdescription as hidden,
1745   # because they are loaded only on demand. So we need to keep the values
1746   # from the source.
1747   $_->{render_second_row}      = 1 for @{ $self->order->items_sorted };
1748   $_->{render_longdescription} = 1 for @{ $self->order->items_sorted };
1749
1750   $self->render(
1751     'order/form',
1752     title => $self->get_title_for('edit'),
1753     %{$self->{template_args}}
1754   );
1755 }
1756
1757
1758 sub pre_render {
1759   my ($self) = @_;
1760
1761   $self->{all_taxzones}               = SL::DB::Manager::TaxZone->get_all_sorted();
1762   $self->{all_currencies}             = SL::DB::Manager::Currency->get_all_sorted();
1763   $self->{all_departments}            = SL::DB::Manager::Department->get_all_sorted();
1764   $self->{all_languages}              = SL::DB::Manager::Language->get_all_sorted();
1765   $self->{all_employees}              = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->employee_id,
1766                                                                                               deleted => 0 ] ],
1767                                                                            sort_by => 'name');
1768   $self->{all_salesmen}               = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->salesman_id,
1769                                                                                               deleted => 0 ] ],
1770                                                                            sort_by => 'name');
1771   $self->{all_payment_terms}          = SL::DB::Manager::PaymentTerm->get_all_sorted(where => [ or => [ id => $self->order->payment_id,
1772                                                                                                         obsolete => 0 ] ]);
1773   $self->{all_delivery_terms}         = SL::DB::Manager::DeliveryTerm->get_all_sorted();
1774   $self->{current_employee_id}        = SL::DB::Manager::Employee->current->id;
1775   $self->{periodic_invoices_status}   = $self->get_periodic_invoices_status($self->order->periodic_invoices_config);
1776   $self->{order_probabilities}        = [ map { { title => ($_ * 10) . '%', id => $_ * 10 } } (0..10) ];
1777   $self->{positions_scrollbar_height} = SL::Helper::UserPreferences::PositionsScrollbar->new()->get_height();
1778
1779   my $print_form = Form->new('');
1780   $print_form->{type}        = $self->type;
1781   $print_form->{printers}    = SL::DB::Manager::Printer->get_all_sorted;
1782   $self->{print_options}     = SL::Helper::PrintOptions->get_print_options(
1783     form => $print_form,
1784     options => {dialog_name_prefix => 'print_options.',
1785                 show_headers       => 1,
1786                 no_queue           => 1,
1787                 no_postscript      => 1,
1788                 no_opendocument    => 0,
1789                 no_html            => 1},
1790   );
1791
1792   foreach my $item (@{$self->order->orderitems}) {
1793     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
1794     $item->active_price_source(   $price_source->price_from_source(   $item->active_price_source   ));
1795     $item->active_discount_source($price_source->discount_from_source($item->active_discount_source));
1796   }
1797
1798   if (any { $self->type eq $_ } (sales_order_type(), purchase_order_type())) {
1799     # calculate shipped qtys here to prevent calling calculate for every item via the items method
1800     SL::Helper::ShippedQty->new->calculate($self->order)->write_to_objects;
1801   }
1802
1803   if ($self->order->number && $::instance_conf->get_webdav) {
1804     my $webdav = SL::Webdav->new(
1805       type     => $self->type,
1806       number   => $self->order->number,
1807     );
1808     my @all_objects = $webdav->get_all_objects;
1809     @{ $self->{template_args}->{WEBDAV} } = map { { name => $_->filename,
1810                                                     type => t8('File'),
1811                                                     link => File::Spec->catfile($_->full_filedescriptor),
1812                                                 } } @all_objects;
1813   }
1814
1815   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
1816
1817   $::request->{layout}->use_javascript("${_}.js") for qw(kivi.SalesPurchase kivi.Order kivi.File ckeditor/ckeditor ckeditor/adapters/jquery
1818                                                          edit_periodic_invoices_config calculate_qty kivi.Validator follow_up);
1819   $self->setup_edit_action_bar;
1820 }
1821
1822 sub setup_edit_action_bar {
1823   my ($self, %params) = @_;
1824
1825   my $deletion_allowed = (any { $self->type eq $_ } (sales_quotation_type(), request_quotation_type()))
1826                       || (($self->type eq sales_order_type())    && $::instance_conf->get_sales_order_show_delete)
1827                       || (($self->type eq purchase_order_type()) && $::instance_conf->get_purchase_order_show_delete);
1828
1829   for my $bar ($::request->layout->get('actionbar')) {
1830     $bar->add(
1831       combobox => [
1832         action => [
1833           t8('Save'),
1834           call      => [ 'kivi.Order.save', 'save', $::instance_conf->get_order_warn_duplicate_parts,
1835                                                     $::instance_conf->get_order_warn_no_deliverydate,
1836                                                                                                       ],
1837           checks    => [ 'kivi.Order.check_save_active_periodic_invoices', ['kivi.validate_form','#order_form'] ],
1838         ],
1839         action => [
1840           t8('Save as new'),
1841           call      => [ 'kivi.Order.save', 'save_as_new', $::instance_conf->get_order_warn_duplicate_parts ],
1842           checks    => [ 'kivi.Order.check_save_active_periodic_invoices' ],
1843           disabled  => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1844         ],
1845       ], # end of combobox "Save"
1846
1847       combobox => [
1848         action => [
1849           t8('Workflow'),
1850         ],
1851         action => [
1852           t8('Save and Sales Order'),
1853           submit   => [ '#order_form', { action => "Order/sales_order" } ],
1854           only_if  => (any { $self->type eq $_ } (sales_quotation_type(), purchase_order_type())),
1855         ],
1856         action => [
1857           t8('Save and Purchase Order'),
1858           call      => [ 'kivi.Order.purchase_order_check_for_direct_delivery' ],
1859           only_if   => (any { $self->type eq $_ } (sales_order_type(), request_quotation_type())),
1860         ],
1861         action => [
1862           t8('Save and Delivery Order'),
1863           call      => [ 'kivi.Order.save', 'save_and_delivery_order', $::instance_conf->get_order_warn_duplicate_parts,
1864                                                                        $::instance_conf->get_order_warn_no_deliverydate,
1865                                                                                                                         ],
1866           checks    => [ 'kivi.Order.check_save_active_periodic_invoices' ],
1867           only_if   => (any { $self->type eq $_ } (sales_order_type(), purchase_order_type()))
1868         ],
1869         action => [
1870           t8('Save and Invoice'),
1871           call      => [ 'kivi.Order.save', 'save_and_invoice', $::instance_conf->get_order_warn_duplicate_parts ],
1872           checks    => [ 'kivi.Order.check_save_active_periodic_invoices' ],
1873         ],
1874         action => [
1875           t8('Save and AP Transaction'),
1876           call      => [ 'kivi.Order.save', 'save_and_ap_transaction', $::instance_conf->get_order_warn_duplicate_parts ],
1877           only_if   => (any { $self->type eq $_ } (purchase_order_type()))
1878         ],
1879
1880       ], # end of combobox "Workflow"
1881
1882       combobox => [
1883         action => [
1884           t8('Export'),
1885         ],
1886         action => [
1887           t8('Save and print'),
1888           call => [ 'kivi.Order.show_print_options', $::instance_conf->get_order_warn_duplicate_parts ],
1889         ],
1890         action => [
1891           t8('Save and E-mail'),
1892           call => [ 'kivi.Order.save', 'save_and_show_email_dialog', $::instance_conf->get_order_warn_duplicate_parts ],
1893           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1894         ],
1895         action => [
1896           t8('Download attachments of all parts'),
1897           call     => [ 'kivi.File.downloadOrderitemsFiles', $::form->{type}, $::form->{id} ],
1898           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1899           only_if  => $::instance_conf->get_doc_storage,
1900         ],
1901       ], # end of combobox "Export"
1902
1903       action => [
1904         t8('Delete'),
1905         call     => [ 'kivi.Order.delete_order' ],
1906         confirm  => $::locale->text('Do you really want to delete this object?'),
1907         disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1908         only_if  => $deletion_allowed,
1909       ],
1910
1911       combobox => [
1912         action => [
1913           t8('more')
1914         ],
1915         action => [
1916           t8('Follow-Up'),
1917           call     => [ 'kivi.Order.follow_up_window' ],
1918           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1919           only_if  => $::auth->assert('productivity', 1),
1920         ],
1921       ], # end of combobox "more"
1922     );
1923   }
1924 }
1925
1926 sub generate_pdf {
1927   my ($order, $pdf_ref, $params) = @_;
1928
1929   my @errors = ();
1930
1931   my $print_form = Form->new('');
1932   $print_form->{type}        = $order->type;
1933   $print_form->{formname}    = $params->{formname} || $order->type;
1934   $print_form->{format}      = $params->{format}   || 'pdf';
1935   $print_form->{media}       = $params->{media}    || 'file';
1936   $print_form->{groupitems}  = $params->{groupitems};
1937   $print_form->{media}       = 'file'                             if $print_form->{media} eq 'screen';
1938
1939   $order->language($params->{language});
1940   $order->flatten_to_form($print_form, format_amounts => 1);
1941
1942   my $template_ext;
1943   my $template_type;
1944   if ($print_form->{format} =~ /(opendocument|oasis)/i) {
1945     $template_ext  = 'odt';
1946     $template_type = 'OpenDocument';
1947   }
1948
1949   # search for the template
1950   my ($template_file, @template_files) = SL::Helper::CreatePDF->find_template(
1951     name        => $print_form->{formname},
1952     extension   => $template_ext,
1953     email       => $print_form->{media} eq 'email',
1954     language    => $params->{language},
1955     printer_id  => $print_form->{printer_id},  # todo
1956   );
1957
1958   if (!defined $template_file) {
1959     push @errors, $::locale->text('Cannot find matching template for this print request. Please contact your template maintainer. I tried these: #1.', join ', ', map { "'$_'"} @template_files);
1960   }
1961
1962   return @errors if scalar @errors;
1963
1964   $print_form->throw_on_error(sub {
1965     eval {
1966       $print_form->prepare_for_printing;
1967
1968       $$pdf_ref = SL::Helper::CreatePDF->create_pdf(
1969         format        => $print_form->{format},
1970         template_type => $template_type,
1971         template      => $template_file,
1972         variables     => $print_form,
1973         variable_content_types => {
1974           longdescription => 'html',
1975           partnotes       => 'html',
1976           notes           => 'html',
1977         },
1978       );
1979       1;
1980     } || push @errors, ref($EVAL_ERROR) eq 'SL::X::FormError' ? $EVAL_ERROR->error : $EVAL_ERROR;
1981   });
1982
1983   return @errors;
1984 }
1985
1986 sub get_files_for_email_dialog {
1987   my ($self) = @_;
1988
1989   my %files = map { ($_ => []) } qw(versions files vc_files part_files);
1990
1991   return %files if !$::instance_conf->get_doc_storage;
1992
1993   if ($self->order->id) {
1994     $files{versions} = [ SL::File->get_all_versions(object_id => $self->order->id,              object_type => $self->order->type, file_type => 'document') ];
1995     $files{files}    = [ SL::File->get_all(         object_id => $self->order->id,              object_type => $self->order->type, file_type => 'attachment') ];
1996     $files{vc_files} = [ SL::File->get_all(         object_id => $self->order->{$self->cv}->id, object_type => $self->cv,          file_type => 'attachment') ];
1997   }
1998
1999   my @parts =
2000     uniq_by { $_->{id} }
2001     map {
2002       +{ id         => $_->part->id,
2003          partnumber => $_->part->partnumber }
2004     } @{$self->order->items_sorted};
2005
2006   foreach my $part (@parts) {
2007     my @pfiles = SL::File->get_all(object_id => $part->{id}, object_type => 'part');
2008     push @{ $files{part_files} }, map { +{ %{ $_ }, partnumber => $part->{partnumber} } } @pfiles;
2009   }
2010
2011   foreach my $key (keys %files) {
2012     $files{$key} = [ sort_by { lc $_->{db_file}->{file_name} } @{ $files{$key} } ];
2013   }
2014
2015   return %files;
2016 }
2017
2018 sub make_periodic_invoices_config_from_yaml {
2019   my ($yaml_config) = @_;
2020
2021   return if !$yaml_config;
2022   my $attr = SL::YAML::Load($yaml_config);
2023   return if 'HASH' ne ref $attr;
2024   return SL::DB::PeriodicInvoicesConfig->new(%$attr);
2025 }
2026
2027
2028 sub get_periodic_invoices_status {
2029   my ($self, $config) = @_;
2030
2031   return                      if $self->type ne sales_order_type();
2032   return t8('not configured') if !$config;
2033
2034   my $active = ('HASH' eq ref $config)                           ? $config->{active}
2035              : ('SL::DB::PeriodicInvoicesConfig' eq ref $config) ? $config->active
2036              :                                                     die "Cannot get status of periodic invoices config";
2037
2038   return $active ? t8('active') : t8('inactive');
2039 }
2040
2041 sub get_title_for {
2042   my ($self, $action) = @_;
2043
2044   return '' if none { lc($action)} qw(add edit);
2045
2046   # for locales:
2047   # $::locale->text("Add Sales Order");
2048   # $::locale->text("Add Purchase Order");
2049   # $::locale->text("Add Quotation");
2050   # $::locale->text("Add Request for Quotation");
2051   # $::locale->text("Edit Sales Order");
2052   # $::locale->text("Edit Purchase Order");
2053   # $::locale->text("Edit Quotation");
2054   # $::locale->text("Edit Request for Quotation");
2055
2056   $action = ucfirst(lc($action));
2057   return $self->type eq sales_order_type()       ? $::locale->text("$action Sales Order")
2058        : $self->type eq purchase_order_type()    ? $::locale->text("$action Purchase Order")
2059        : $self->type eq sales_quotation_type()   ? $::locale->text("$action Quotation")
2060        : $self->type eq request_quotation_type() ? $::locale->text("$action Request for Quotation")
2061        : '';
2062 }
2063
2064 sub get_item_cvpartnumber {
2065   my ($self, $item) = @_;
2066
2067   return if !$self->search_cvpartnumber;
2068   return if !$self->order->customervendor;
2069
2070   if ($self->cv eq 'vendor') {
2071     my @mms = grep { $_->make eq $self->order->customervendor->id } @{$item->part->makemodels};
2072     $item->{cvpartnumber} = $mms[0]->model if scalar @mms;
2073   } elsif ($self->cv eq 'customer') {
2074     my @cps = grep { $_->customer_id eq $self->order->customervendor->id } @{$item->part->customerprices};
2075     $item->{cvpartnumber} = $cps[0]->customer_partnumber if scalar @cps;
2076   }
2077 }
2078
2079 sub get_part_texts {
2080   my ($part_or_id, $language_or_id, %defaults) = @_;
2081
2082   my $part        = ref($part_or_id)     ? $part_or_id         : SL::DB::Part->load_cached($part_or_id);
2083   my $language_id = ref($language_or_id) ? $language_or_id->id : $language_or_id;
2084   my $texts       = {
2085     description     => $defaults{description}     // $part->description,
2086     longdescription => $defaults{longdescription} // $part->notes,
2087   };
2088
2089   return $texts unless $language_id;
2090
2091   my $translation = SL::DB::Manager::Translation->get_first(
2092     where => [
2093       parts_id    => $part->id,
2094       language_id => $language_id,
2095     ]);
2096
2097   $texts->{description}     = $translation->translation     if $translation && $translation->translation;
2098   $texts->{longdescription} = $translation->longdescription if $translation && $translation->longdescription;
2099
2100   return $texts;
2101 }
2102
2103 sub sales_order_type {
2104   'sales_order';
2105 }
2106
2107 sub purchase_order_type {
2108   'purchase_order';
2109 }
2110
2111 sub sales_quotation_type {
2112   'sales_quotation';
2113 }
2114
2115 sub request_quotation_type {
2116   'request_quotation';
2117 }
2118
2119 sub nr_key {
2120   return $_[0]->type eq sales_order_type()       ? 'ordnumber'
2121        : $_[0]->type eq purchase_order_type()    ? 'ordnumber'
2122        : $_[0]->type eq sales_quotation_type()   ? 'quonumber'
2123        : $_[0]->type eq request_quotation_type() ? 'quonumber'
2124        : '';
2125 }
2126
2127 1;
2128
2129 __END__
2130
2131 =encoding utf-8
2132
2133 =head1 NAME
2134
2135 SL::Controller::Order - controller for orders
2136
2137 =head1 SYNOPSIS
2138
2139 This is a new form to enter orders, completely rewritten with the use
2140 of controller and java script techniques.
2141
2142 The aim is to provide the user a better experience and a faster workflow. Also
2143 the code should be more readable, more reliable and better to maintain.
2144
2145 =head2 Key Features
2146
2147 =over 4
2148
2149 =item *
2150
2151 One input row, so that input happens every time at the same place.
2152
2153 =item *
2154
2155 Use of pickers where possible.
2156
2157 =item *
2158
2159 Possibility to enter more than one item at once.
2160
2161 =item *
2162
2163 Item list in a scrollable area, so that the workflow buttons stay at
2164 the bottom.
2165
2166 =item *
2167
2168 Reordering item rows with drag and drop is possible. Sorting item rows is
2169 possible (by partnumber, description, qty, sellprice and discount for now).
2170
2171 =item *
2172
2173 No C<update> is necessary. All entries and calculations are managed
2174 with ajax-calls and the page only reloads on C<save>.
2175
2176 =item *
2177
2178 User can see changes immediately, because of the use of java script
2179 and ajax.
2180
2181 =back
2182
2183 =head1 CODE
2184
2185 =head2 Layout
2186
2187 =over 4
2188
2189 =item * C<SL/Controller/Order.pm>
2190
2191 the controller
2192
2193 =item * C<template/webpages/order/form.html>
2194
2195 main form
2196
2197 =item * C<template/webpages/order/tabs/basic_data.html>
2198
2199 Main tab for basic_data.
2200
2201 This is the only tab here for now. "linked records" and "webdav" tabs are
2202 reused from generic code.
2203
2204 =over 4
2205
2206 =item * C<template/webpages/order/tabs/_business_info_row.html>
2207
2208 For displaying information on business type
2209
2210 =item * C<template/webpages/order/tabs/_item_input.html>
2211
2212 The input line for items
2213
2214 =item * C<template/webpages/order/tabs/_row.html>
2215
2216 One row for already entered items
2217
2218 =item * C<template/webpages/order/tabs/_tax_row.html>
2219
2220 Displaying tax information
2221
2222 =item * C<template/webpages/order/tabs/_multi_items_dialog.html>
2223
2224 Dialog for entering more than one item at once
2225
2226 =item * C<template/webpages/order/tabs/_multi_items_result.html>
2227
2228 Results for the filter in the multi items dialog
2229
2230 =item * C<template/webpages/order/tabs/_price_sources_dialog.html>
2231
2232 Dialog for selecting price and discount sources
2233
2234 =back
2235
2236 =item * C<js/kivi.Order.js>
2237
2238 java script functions
2239
2240 =back
2241
2242 =head1 TODO
2243
2244 =over 4
2245
2246 =item * testing
2247
2248 =item * credit limit
2249
2250 =item * more workflows (quotation, rfq)
2251
2252 =item * price sources: little symbols showing better price / better discount
2253
2254 =item * select units in input row?
2255
2256 =item * check for direct delivery (workflow sales order -> purchase order)
2257
2258 =item * language / part translations
2259
2260 =item * access rights
2261
2262 =item * display weights
2263
2264 =item * history
2265
2266 =item * mtime check
2267
2268 =item * optional client/user behaviour
2269
2270 (transactions has to be set - department has to be set -
2271  force project if enabled in client config - transport cost reminder)
2272
2273 =back
2274
2275 =head1 KNOWN BUGS AND CAVEATS
2276
2277 =over 4
2278
2279 =item *
2280
2281 Customer discount is not displayed as a valid discount in price source popup
2282 (this might be a bug in price sources)
2283
2284 (I cannot reproduce this (Bernd))
2285
2286 =item *
2287
2288 No indication that <shift>-up/down expands/collapses second row.
2289
2290 =item *
2291
2292 Inline creation of parts is not currently supported
2293
2294 =item *
2295
2296 Table header is not sticky in the scrolling area.
2297
2298 =item *
2299
2300 Sorting does not include C<position>, neither does reordering.
2301
2302 This behavior was implemented intentionally. But we can discuss, which behavior
2303 should be implemented.
2304
2305 =item *
2306
2307 C<show_multi_items_dialog> does not use the currently inserted string for
2308 filtering.
2309
2310 =back
2311
2312 =head1 To discuss / Nice to have
2313
2314 =over 4
2315
2316 =item *
2317
2318 How to expand/collapse second row. Now it can be done clicking the icon or
2319 <shift>-up/down.
2320
2321 =item *
2322
2323 Possibility to change longdescription in input row?
2324
2325 =item *
2326
2327 Possibility to select PriceSources in input row?
2328
2329 =item *
2330
2331 This controller uses a (changed) copy of the template for the PriceSource
2332 dialog. Maybe there could be used one code source.
2333
2334 =item *
2335
2336 Rounding-differences between this controller (PriceTaxCalculator) and the old
2337 form. This is not only a problem here, but also in all parts using the PTC.
2338 There exists a ticket and a patch. This patch should be testet.
2339
2340 =item *
2341
2342 An indicator, if the actual inputs are saved (like in an
2343 editor or on text processing application).
2344
2345 =item *
2346
2347 A warning when leaving the page without saveing unchanged inputs.
2348
2349
2350 =back
2351
2352 =head1 AUTHOR
2353
2354 Bernd Bleßmann E<lt>bernd@kivitendo-premium.deE<gt>
2355
2356 =cut