SL/Controller/Order.pm

   1 package SL::Controller::Order;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use SL::Helper::Flash qw(flash_later);
   7 use SL::HTML::Util;
   8 use SL::Presenter::Tag qw(select_tag hidden_tag div_tag);
   9 use SL::Locale::String qw(t8);
  10 use SL::SessionFile::Random;
  11 use SL::PriceSource;
  12 use SL::Webdav;
  13 use SL::File;
  14 use SL::MIME;
  15 use SL::Util qw(trim);
  16 use SL::YAML;
  17 use SL::DB::AdditionalBillingAddress;
  18 use SL::DB::AuthUser;
  19 use SL::DB::History;
  20 use SL::DB::Order;
  21 use SL::DB::Default;
  22 use SL::DB::Unit;
  23 use SL::DB::Part;
  24 use SL::DB::PartClassification;
  25 use SL::DB::PartsGroup;
  26 use SL::DB::Printer;
  27 use SL::DB::Language;
  28 use SL::DB::RecordLink;
  29 use SL::DB::RequirementSpec;
  30 use SL::DB::Shipto;
  31 use SL::DB::Translation;
  32
  33 use SL::Helper::CreatePDF qw(:all);
  34 use SL::Helper::PrintOptions;
  35 use SL::Helper::ShippedQty;
  36 use SL::Helper::UserPreferences::PositionsScrollbar;
  37 use SL::Helper::UserPreferences::UpdatePositions;
  38
  39 use SL::Controller::Helper::GetModels;
  40
  41 use List::Util qw(first sum0);
  42 use List::UtilsBy qw(sort_by uniq_by);
  43 use List::MoreUtils qw(any none pairwise first_index);
  44 use English qw(-no_match_vars);
  45 use File::Spec;
  46 use Cwd;
  47 use Sort::Naturally;
  48
  49 use Rose::Object::MakeMethods::Generic
  50 (
  51  scalar => [ qw(item_ids_to_delete is_custom_shipto_to_delete) ],
  52  'scalar --get_set_init' => [ qw(order valid_types type cv p all_price_factors search_cvpartnumber show_update_button part_picker_classification_ids) ],
  53 );
  54
  55
  56 # safety
  57 __PACKAGE__->run_before('check_auth');
  58
  59 __PACKAGE__->run_before('recalc',
  60                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice save_and_invoice_for_advance_payment save_and_ap_transaction
  61                                      print send_email) ]);
  62
  63 __PACKAGE__->run_before('get_unalterable_data',
  64                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice save_and_invoice_for_advance_payment save_and_ap_transaction
  65                                      print send_email) ]);
  66
  67 #
  68 # actions
  69 #
  70
  71 # add a new order
  72 sub action_add {
  73   my ($self) = @_;
  74
  75   $self->order->transdate(DateTime->now_local());
  76   my $extra_days = $self->type eq sales_quotation_type() ? $::instance_conf->get_reqdate_interval       :
  77                    $self->type eq sales_order_type()     ? $::instance_conf->get_delivery_date_interval : 1;
  78
  79   if (   ($self->type eq sales_order_type()     &&  $::instance_conf->get_deliverydate_on)
  80       || ($self->type eq sales_quotation_type() &&  $::instance_conf->get_reqdate_on)
  81       && (!$self->order->reqdate)) {
  82     $self->order->reqdate(DateTime->today_local->next_workday(extra_days => $extra_days));
  83   }
  84
  85
  86   $self->pre_render();
  87   $self->render(
  88     'order/form',
  89     title => $self->get_title_for('add'),
  90     %{$self->{template_args}}
  91   );
  92 }
  93
  94 # edit an existing order
  95 sub action_edit {
  96   my ($self) = @_;
  97
  98   if ($::form->{id}) {
  99     $self->load_order;
 100
 101   } else {
 102     # this is to edit an order from an unsaved order object
 103
 104     # set item ids to new fake id, to identify them as new items
 105     foreach my $item (@{$self->order->items_sorted}) {
 106       $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 107     }
 108     # trigger rendering values for second row as hidden, because they
 109     # are loaded only on demand. So we need to keep the values from
 110     # the source.
 111     $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
 112   }
 113
 114   $self->recalc();
 115   $self->pre_render();
 116   $self->render(
 117     'order/form',
 118     title => $self->get_title_for('edit'),
 119     %{$self->{template_args}}
 120   );
 121 }
 122
 123 # edit a collective order (consisting of one or more existing orders)
 124 sub action_edit_collective {
 125   my ($self) = @_;
 126
 127   # collect order ids
 128   my @multi_ids = map {
 129     $_ =~ m{^multi_id_(\d+)$} && $::form->{'multi_id_' . $1} && $::form->{'trans_id_' . $1} && $::form->{'trans_id_' . $1}
 130   } grep { $_ =~ m{^multi_id_\d+$} } keys %$::form;
 131
 132   # fall back to add if no ids are given
 133   if (scalar @multi_ids == 0) {
 134     $self->action_add();
 135     return;
 136   }
 137
 138   # fall back to save as new if only one id is given
 139   if (scalar @multi_ids == 1) {
 140     $self->order(SL::DB::Order->new(id => $multi_ids[0])->load);
 141     $self->action_save_as_new();
 142     return;
 143   }
 144
 145   # make new order from given orders
 146   my @multi_orders = map { SL::DB::Order->new(id => $_)->load } @multi_ids;
 147   $self->{converted_from_oe_id} = join ' ', map { $_->id } @multi_orders;
 148   $self->order(SL::DB::Order->new_from_multi(\@multi_orders, sort_sources_by => 'transdate'));
 149
 150   $self->action_edit();
 151 }
 152
 153 # delete the order
 154 sub action_delete {
 155   my ($self) = @_;
 156
 157   my $errors = $self->delete();
 158
 159   if (scalar @{ $errors }) {
 160     $self->js->flash('error', $_) foreach @{ $errors };
 161     return $self->js->render();
 162   }
 163
 164   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been deleted')
 165            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been deleted')
 166            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been deleted')
 167            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been deleted')
 168            : '';
 169   flash_later('info', $text);
 170
 171   my @redirect_params = (
 172     action => 'add',
 173     type   => $self->type,
 174   );
 175
 176   $self->redirect_to(@redirect_params);
 177 }
 178
 179 # save the order
 180 sub action_save {
 181   my ($self) = @_;
 182
 183   my $errors = $self->save();
 184
 185   if (scalar @{ $errors }) {
 186     $self->js->flash('error', $_) foreach @{ $errors };
 187     return $self->js->render();
 188   }
 189
 190   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
 191            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
 192            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
 193            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
 194            : '';
 195   flash_later('info', $text);
 196
 197   my @redirect_params = (
 198     action => 'edit',
 199     type   => $self->type,
 200     id     => $self->order->id,
 201   );
 202
 203   $self->redirect_to(@redirect_params);
 204 }
 205
 206 # save the order as new document an open it for edit
 207 sub action_save_as_new {
 208   my ($self) = @_;
 209
 210   my $order = $self->order;
 211
 212   if (!$order->id) {
 213     $self->js->flash('error', t8('This object has not been saved yet.'));
 214     return $self->js->render();
 215   }
 216
 217   # load order from db to check if values changed
 218   my $saved_order = SL::DB::Order->new(id => $order->id)->load;
 219
 220   my %new_attrs;
 221   # Lets assign a new number if the user hasn't changed the previous one.
 222   # If it has been changed manually then use it as-is.
 223   $new_attrs{number}    = (trim($order->number) eq $saved_order->number)
 224                         ? ''
 225                         : trim($order->number);
 226
 227   # Clear transdate unless changed
 228   $new_attrs{transdate} = ($order->transdate == $saved_order->transdate)
 229                         ? DateTime->today_local
 230                         : $order->transdate;
 231
 232   # Set new reqdate unless changed if it is enabled in client config
 233   if ($order->reqdate == $saved_order->reqdate) {
 234     my $extra_days = $self->type eq sales_quotation_type() ? $::instance_conf->get_reqdate_interval       :
 235                      $self->type eq sales_order_type()     ? $::instance_conf->get_delivery_date_interval : 1;
 236
 237     if (   ($self->type eq sales_order_type()     &&  !$::instance_conf->get_deliverydate_on)
 238         || ($self->type eq sales_quotation_type() &&  !$::instance_conf->get_reqdate_on)) {
 239       $new_attrs{reqdate} = '';
 240     } else {
 241       $new_attrs{reqdate} = DateTime->today_local->next_workday(extra_days => $extra_days);
 242     }
 243   } else {
 244     $new_attrs{reqdate} = $order->reqdate;
 245   }
 246
 247   # Update employee
 248   $new_attrs{employee}  = SL::DB::Manager::Employee->current;
 249
 250   # Create new record from current one
 251   $self->order(SL::DB::Order->new_from($order, destination_type => $order->type, attributes => \%new_attrs));
 252
 253   # no linked records on save as new
 254   delete $::form->{$_} for qw(converted_from_oe_id converted_from_orderitems_ids);
 255
 256   # save
 257   $self->action_save();
 258 }
 259
 260 # print the order
 261 #
 262 # This is called if "print" is pressed in the print dialog.
 263 # If PDF creation was requested and succeeded, the pdf is offered for download
 264 # via send_file (which uses ajax in this case).
 265 sub action_print {
 266   my ($self) = @_;
 267
 268   my $errors = $self->save();
 269
 270   if (scalar @{ $errors }) {
 271     $self->js->flash('error', $_) foreach @{ $errors };
 272     return $self->js->render();
 273   }
 274
 275   $self->js_reset_order_and_item_ids_after_save;
 276
 277   my $format      = $::form->{print_options}->{format};
 278   my $media       = $::form->{print_options}->{media};
 279   my $formname    = $::form->{print_options}->{formname};
 280   my $copies      = $::form->{print_options}->{copies};
 281   my $groupitems  = $::form->{print_options}->{groupitems};
 282   my $printer_id  = $::form->{print_options}->{printer_id};
 283
 284   # only PDF, OpenDocument & HTML for now
 285   if (none { $format eq $_ } qw(pdf opendocument opendocument_pdf html)) {
 286     return $self->js->flash('error', t8('Format \'#1\' is not supported yet/anymore.', $format))->render;
 287   }
 288
 289   # only screen or printer by now
 290   if (none { $media eq $_ } qw(screen printer)) {
 291     return $self->js->flash('error', t8('Media \'#1\' is not supported yet/anymore.', $media))->render;
 292   }
 293
 294   # create a form for generate_attachment_filename
 295   my $form   = Form->new;
 296   $form->{$self->nr_key()}  = $self->order->number;
 297   $form->{type}             = $self->type;
 298   $form->{format}           = $format;
 299   $form->{formname}         = $formname;
 300   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 301   my $doc_filename          = $form->generate_attachment_filename();
 302
 303   my $doc;
 304   my @errors = $self->generate_doc(\$doc, { format     => $format,
 305                                             formname   => $formname,
 306                                             language   => $self->order->language,
 307                                             printer_id => $printer_id,
 308                                             groupitems => $groupitems });
 309   if (scalar @errors) {
 310     return $self->js->flash('error', t8('Generating the document failed: #1', $errors[0]))->render;
 311   }
 312
 313   if ($media eq 'screen') {
 314     # screen/download
 315     $self->js->flash('info', t8('The document has been created.'));
 316     $self->send_file(
 317       \$doc,
 318       type         => SL::MIME->mime_type_from_ext($doc_filename),
 319       name         => $doc_filename,
 320       js_no_render => 1,
 321     );
 322
 323   } elsif ($media eq 'printer') {
 324     # printer
 325     my $printer_id = $::form->{print_options}->{printer_id};
 326     SL::DB::Printer->new(id => $printer_id)->load->print_document(
 327       copies  => $copies,
 328       content => $doc,
 329     );
 330
 331     $self->js->flash('info', t8('The document has been printed.'));
 332   }
 333
 334   my @warnings = $self->store_doc_to_webdav_and_filemanagement($doc, $doc_filename, $formname);
 335   if (scalar @warnings) {
 336     $self->js->flash('warning', $_) for @warnings;
 337   }
 338
 339   $self->save_history('PRINTED');
 340
 341   $self->js
 342     ->run('kivi.ActionBar.setEnabled', '#save_and_email_action')
 343     ->render;
 344 }
 345 sub action_preview_pdf {
 346   my ($self) = @_;
 347
 348   my $errors = $self->save();
 349   if (scalar @{ $errors }) {
 350     $self->js->flash('error', $_) foreach @{ $errors };
 351     return $self->js->render();
 352   }
 353
 354   $self->js_reset_order_and_item_ids_after_save;
 355
 356   my $format      = 'pdf';
 357   my $media       = 'screen';
 358   my $formname    = $self->type;
 359
 360   # only pdf
 361   # create a form for generate_attachment_filename
 362   my $form   = Form->new;
 363   $form->{$self->nr_key()}  = $self->order->number;
 364   $form->{type}             = $self->type;
 365   $form->{format}           = $format;
 366   $form->{formname}         = $formname;
 367   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 368   my $pdf_filename          = $form->generate_attachment_filename();
 369
 370   my $pdf;
 371   my @errors = $self->generate_doc(\$pdf, { format     => $format,
 372                                             formname   => $formname,
 373                                             language   => $self->order->language,
 374                                           });
 375   if (scalar @errors) {
 376     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render;
 377   }
 378   $self->save_history('PREVIEWED');
 379   $self->js->flash('info', t8('The PDF has been previewed'));
 380   # screen/download
 381   $self->send_file(
 382     \$pdf,
 383     type         => SL::MIME->mime_type_from_ext($pdf_filename),
 384     name         => $pdf_filename,
 385     js_no_render => 0,
 386   );
 387 }
 388
 389 # open the email dialog
 390 sub action_save_and_show_email_dialog {
 391   my ($self) = @_;
 392
 393   my $errors = $self->save();
 394
 395   if (scalar @{ $errors }) {
 396     $self->js->flash('error', $_) foreach @{ $errors };
 397     return $self->js->render();
 398   }
 399
 400   my $cv_method = $self->cv;
 401
 402   if (!$self->order->$cv_method) {
 403     return $self->js->flash('error', $self->cv eq 'customer' ? t8('Cannot send E-mail without customer given') : t8('Cannot send E-mail without vendor given'))
 404                     ->render($self);
 405   }
 406
 407   my $email_form;
 408   $email_form->{to}   = $self->order->contact->cp_email if $self->order->contact;
 409   $email_form->{to} ||= $self->order->$cv_method->email;
 410   $email_form->{cc}   = $self->order->$cv_method->cc;
 411   $email_form->{bcc}  = join ', ', grep $_, $self->order->$cv_method->bcc, SL::DB::Default->get->global_bcc;
 412   # Todo: get addresses from shipto, if any
 413
 414   my $form = Form->new;
 415   $form->{$self->nr_key()}  = $self->order->number;
 416   $form->{cusordnumber}     = $self->order->cusordnumber;
 417   $form->{formname}         = $self->type;
 418   $form->{type}             = $self->type;
 419   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 420   $form->{language_id}      = $self->order->language->id                  if $self->order->language;
 421   $form->{format}           = 'pdf';
 422   $form->{cp_id}            = $self->order->contact->cp_id if $self->order->contact;
 423
 424   $email_form->{subject}             = $form->generate_email_subject();
 425   $email_form->{attachment_filename} = $form->generate_attachment_filename();
 426   $email_form->{message}             = $form->generate_email_body();
 427   $email_form->{js_send_function}    = 'kivi.Order.send_email()';
 428
 429   my %files = $self->get_files_for_email_dialog();
 430
 431   my @employees_with_email = grep {
 432     my $user = SL::DB::Manager::AuthUser->find_by(login => $_->login);
 433     $user && !!trim($user->get_config_value('email'));
 434   } @{ SL::DB::Manager::Employee->get_all_sorted(query => [ deleted => 0 ]) };
 435
 436   my $dialog_html = $self->render('common/_send_email_dialog', { output => 0 },
 437                                   email_form    => $email_form,
 438                                   show_bcc      => $::auth->assert('email_bcc', 'may fail'),
 439                                   FILES         => \%files,
 440                                   is_customer   => $self->cv eq 'customer',
 441                                   ALL_EMPLOYEES => \@employees_with_email,
 442   );
 443
 444   $self->js
 445       ->run('kivi.Order.show_email_dialog', $dialog_html)
 446       ->reinit_widgets
 447       ->render($self);
 448 }
 449
 450 # send email
 451 #
 452 # Todo: handling error messages: flash is not displayed in dialog, but in the main form
 453 sub action_send_email {
 454   my ($self) = @_;
 455
 456   my $errors = $self->save();
 457
 458   if (scalar @{ $errors }) {
 459     $self->js->run('kivi.Order.close_email_dialog');
 460     $self->js->flash('error', $_) foreach @{ $errors };
 461     return $self->js->render();
 462   }
 463
 464   $self->js_reset_order_and_item_ids_after_save;
 465
 466   my $email_form  = delete $::form->{email_form};
 467   my %field_names = (to => 'email');
 468
 469   $::form->{ $field_names{$_} // $_ } = $email_form->{$_} for keys %{ $email_form };
 470
 471   # for Form::cleanup which may be called in Form::send_email
 472   $::form->{cwd}    = getcwd();
 473   $::form->{tmpdir} = $::lx_office_conf{paths}->{userspath};
 474
 475   $::form->{$_}     = $::form->{print_options}->{$_} for keys %{ $::form->{print_options} };
 476   $::form->{media}  = 'email';
 477
 478   $::form->{attachment_policy} //= '';
 479
 480   # Is an old file version available?
 481   my $attfile;
 482   if ($::form->{attachment_policy} eq 'old_file') {
 483     $attfile = SL::File->get_all(object_id     => $self->order->id,
 484                                  object_type   => $self->type,
 485                                  file_type     => 'document',
 486                                  print_variant => $::form->{formname});
 487   }
 488
 489   if ($::form->{attachment_policy} ne 'no_file' && !($::form->{attachment_policy} eq 'old_file' && $attfile)) {
 490     my $doc;
 491     my @errors = $self->generate_doc(\$doc, {media      => $::form->{media},
 492                                              format     => $::form->{print_options}->{format},
 493                                              formname   => $::form->{print_options}->{formname},
 494                                              language   => $self->order->language,
 495                                              printer_id => $::form->{print_options}->{printer_id},
 496                                              groupitems => $::form->{print_options}->{groupitems}});
 497     if (scalar @errors) {
 498       return $self->js->flash('error', t8('Generating the document failed: #1', $errors[0]))->render($self);
 499     }
 500
 501     my @warnings = $self->store_doc_to_webdav_and_filemanagement($doc, $::form->{attachment_filename}, $::form->{formname});
 502     if (scalar @warnings) {
 503       flash_later('warning', $_) for @warnings;
 504     }
 505
 506     my $sfile = SL::SessionFile::Random->new(mode => "w");
 507     $sfile->fh->print($doc);
 508     $sfile->fh->close;
 509
 510     $::form->{tmpfile} = $sfile->file_name;
 511     $::form->{tmpdir}  = $sfile->get_path; # for Form::cleanup which may be called in Form::send_email
 512   }
 513
 514   $::form->{id} = $self->order->id; # this is used in SL::Mailer to create a linked record to the mail
 515   $::form->send_email(\%::myconfig, $::form->{print_options}->{format});
 516
 517   # internal notes
 518   my $intnotes = $self->order->intnotes;
 519   $intnotes   .= "\n\n" if $self->order->intnotes;
 520   $intnotes   .= t8('[email]')                                                                                        . "\n";
 521   $intnotes   .= t8('Date')       . ": " . $::locale->format_date_object(DateTime->now_local, precision => 'seconds') . "\n";
 522   $intnotes   .= t8('To (email)') . ": " . $::form->{email}                                                           . "\n";
 523   $intnotes   .= t8('Cc')         . ": " . $::form->{cc}                                                              . "\n"    if $::form->{cc};
 524   $intnotes   .= t8('Bcc')        . ": " . $::form->{bcc}                                                             . "\n"    if $::form->{bcc};
 525   $intnotes   .= t8('Subject')    . ": " . $::form->{subject}                                                         . "\n\n";
 526   $intnotes   .= t8('Message')    . ": " . SL::HTML::Util->strip($::form->{message});
 527
 528   $self->order->update_attributes(intnotes => $intnotes);
 529
 530   $self->save_history('MAILED');
 531
 532   flash_later('info', t8('The email has been sent.'));
 533
 534   my @redirect_params = (
 535     action => 'edit',
 536     type   => $self->type,
 537     id     => $self->order->id,
 538   );
 539
 540   $self->redirect_to(@redirect_params);
 541 }
 542
 543 # open the periodic invoices config dialog
 544 #
 545 # If there are values in the form (i.e. dialog was opened before),
 546 # then use this values. Create new ones, else.
 547 sub action_show_periodic_invoices_config_dialog {
 548   my ($self) = @_;
 549
 550   my $config = make_periodic_invoices_config_from_yaml(delete $::form->{config});
 551   $config  ||= SL::DB::Manager::PeriodicInvoicesConfig->find_by(oe_id => $::form->{id}) if $::form->{id};
 552   $config  ||= SL::DB::PeriodicInvoicesConfig->new(periodicity             => 'm',
 553                                                    order_value_periodicity => 'p', # = same as periodicity
 554                                                    start_date_as_date      => $::form->{transdate_as_date} || $::form->current_date,
 555                                                    extend_automatically_by => 12,
 556                                                    active                  => 1,
 557                                                    email_subject           => GenericTranslations->get(
 558                                                                                 language_id      => $::form->{language_id},
 559                                                                                 translation_type =>"preset_text_periodic_invoices_email_subject"),
 560                                                    email_body              => GenericTranslations->get(
 561                                                                                 language_id      => $::form->{language_id},
 562                                                                                 translation_type => "salutation_general")
 563                                                                             . GenericTranslations->get(
 564                                                                                 language_id      => $::form->{language_id},
 565                                                                                 translation_type => "salutation_punctuation_mark") . "\n\n"
 566                                                                             . GenericTranslations->get(
 567                                                                                 language_id      => $::form->{language_id},
 568                                                                                 translation_type =>"preset_text_periodic_invoices_email_body"),
 569   );
 570   # for older configs, replace email preset text if not yet set.
 571   $config->email_subject(GenericTranslations->get(
 572                                               language_id      => $::form->{language_id},
 573                                               translation_type =>"preset_text_periodic_invoices_email_subject")
 574                         ) unless $config->email_subject;
 575
 576   $config->email_body(GenericTranslations->get(
 577                                               language_id      => $::form->{language_id},
 578                                               translation_type => "salutation_general")
 579                     . GenericTranslations->get(
 580                                               language_id      => $::form->{language_id},
 581                                               translation_type => "salutation_punctuation_mark") . "\n\n"
 582                     . GenericTranslations->get(
 583                                               language_id      => $::form->{language_id},
 584                                               translation_type =>"preset_text_periodic_invoices_email_body")
 585                      ) unless $config->email_body;
 586
 587   $config->periodicity('m')             if none { $_ eq $config->periodicity             }       @SL::DB::PeriodicInvoicesConfig::PERIODICITIES;
 588   $config->order_value_periodicity('p') if none { $_ eq $config->order_value_periodicity } ('p', @SL::DB::PeriodicInvoicesConfig::ORDER_VALUE_PERIODICITIES);
 589
 590   $::form->get_lists(printers => "ALL_PRINTERS",
 591                      charts   => { key       => 'ALL_CHARTS',
 592                                    transdate => 'current_date' });
 593
 594   $::form->{AR} = [ grep { $_->{link} =~ m/(?:^|:)AR(?::|$)/ } @{ $::form->{ALL_CHARTS} } ];
 595
 596   if ($::form->{customer_id}) {
 597     $::form->{ALL_CONTACTS} = SL::DB::Manager::Contact->get_all_sorted(where => [ cp_cv_id => $::form->{customer_id} ]);
 598     my $customer_object = SL::DB::Manager::Customer->find_by(id => $::form->{customer_id});
 599     $::form->{postal_invoice}                  = $customer_object->postal_invoice;
 600     $::form->{email_recipient_invoice_address} = $::form->{postal_invoice} ? '' : $customer_object->invoice_mail;
 601     $config->send_email(0) if $::form->{postal_invoice};
 602   }
 603
 604   $self->render('oe/edit_periodic_invoices_config', { layout => 0 },
 605                 popup_dialog             => 1,
 606                 popup_js_close_function  => 'kivi.Order.close_periodic_invoices_config_dialog()',
 607                 popup_js_assign_function => 'kivi.Order.assign_periodic_invoices_config()',
 608                 config                   => $config,
 609                 %$::form);
 610 }
 611
 612 # assign the values of the periodic invoices config dialog
 613 # as yaml in the hidden tag and set the status.
 614 sub action_assign_periodic_invoices_config {
 615   my ($self) = @_;
 616
 617   $::form->isblank('start_date_as_date', $::locale->text('The start date is missing.'));
 618
 619   my $config = { active                     => $::form->{active}       ? 1 : 0,
 620                  terminated                 => $::form->{terminated}   ? 1 : 0,
 621                  direct_debit               => $::form->{direct_debit} ? 1 : 0,
 622                  periodicity                => (any { $_ eq $::form->{periodicity}             }       @SL::DB::PeriodicInvoicesConfig::PERIODICITIES)              ? $::form->{periodicity}             : 'm',
 623                  order_value_periodicity    => (any { $_ eq $::form->{order_value_periodicity} } ('p', @SL::DB::PeriodicInvoicesConfig::ORDER_VALUE_PERIODICITIES)) ? $::form->{order_value_periodicity} : 'p',
 624                  start_date_as_date         => $::form->{start_date_as_date},
 625                  end_date_as_date           => $::form->{end_date_as_date},
 626                  first_billing_date_as_date => $::form->{first_billing_date_as_date},
 627                  print                      => $::form->{print}      ? 1                         : 0,
 628                  printer_id                 => $::form->{print}      ? $::form->{printer_id} * 1 : undef,
 629                  copies                     => $::form->{copies} * 1 ? $::form->{copies}         : 1,
 630                  extend_automatically_by    => $::form->{extend_automatically_by}    * 1 || undef,
 631                  ar_chart_id                => $::form->{ar_chart_id} * 1,
 632                  send_email                 => $::form->{send_email} ? 1 : 0,
 633                  email_recipient_contact_id => $::form->{email_recipient_contact_id} * 1 || undef,
 634                  email_recipient_address    => $::form->{email_recipient_address},
 635                  email_sender               => $::form->{email_sender},
 636                  email_subject              => $::form->{email_subject},
 637                  email_body                 => $::form->{email_body},
 638                };
 639
 640   my $periodic_invoices_config = SL::YAML::Dump($config);
 641
 642   my $status = $self->get_periodic_invoices_status($config);
 643
 644   $self->js
 645     ->remove('#order_periodic_invoices_config')
 646     ->insertAfter(hidden_tag('order.periodic_invoices_config', $periodic_invoices_config), '#periodic_invoices_status')
 647     ->run('kivi.Order.close_periodic_invoices_config_dialog')
 648     ->html('#periodic_invoices_status', $status)
 649     ->flash('info', t8('The periodic invoices config has been assigned.'))
 650     ->render($self);
 651 }
 652
 653 sub action_get_has_active_periodic_invoices {
 654   my ($self) = @_;
 655
 656   my $config = make_periodic_invoices_config_from_yaml(delete $::form->{config});
 657   $config  ||= SL::DB::Manager::PeriodicInvoicesConfig->find_by(oe_id => $::form->{id}) if $::form->{id};
 658
 659   my $has_active_periodic_invoices =
 660        $self->type eq sales_order_type()
 661     && $config
 662     && $config->active
 663     && (!$config->end_date || ($config->end_date > DateTime->today_local))
 664     && $config->get_previous_billed_period_start_date;
 665
 666   $_[0]->render(\ !!$has_active_periodic_invoices, { type => 'text' });
 667 }
 668
 669 # save the order and redirect to the frontend subroutine for a new
 670 # delivery order
 671 sub action_save_and_delivery_order {
 672   my ($self) = @_;
 673
 674   $self->save_and_redirect_to(
 675     controller => 'oe.pl',
 676     action     => 'oe_delivery_order_from_order',
 677   );
 678 }
 679
 680 # save the order and redirect to the frontend subroutine for a new
 681 # invoice
 682 sub action_save_and_invoice {
 683   my ($self) = @_;
 684
 685   $self->save_and_redirect_to(
 686     controller => 'oe.pl',
 687     action     => 'oe_invoice_from_order',
 688   );
 689 }
 690
 691 sub action_save_and_invoice_for_advance_payment {
 692   my ($self) = @_;
 693
 694   $self->save_and_redirect_to(
 695     controller       => 'oe.pl',
 696     action           => 'oe_invoice_from_order',
 697     new_invoice_type => 'invoice_for_advance_payment',
 698   );
 699 }
 700
 701 # workflow from sales order to sales quotation
 702 sub action_sales_quotation {
 703   $_[0]->workflow_sales_or_request_for_quotation();
 704 }
 705
 706 # workflow from sales order to sales quotation
 707 sub action_request_for_quotation {
 708   $_[0]->workflow_sales_or_request_for_quotation();
 709 }
 710
 711 # workflow from sales quotation to sales order
 712 sub action_sales_order {
 713   $_[0]->workflow_sales_or_purchase_order();
 714 }
 715
 716 # workflow from rfq to purchase order
 717 sub action_purchase_order {
 718   $_[0]->workflow_sales_or_purchase_order();
 719 }
 720
 721 # workflow from purchase order to ap transaction
 722 sub action_save_and_ap_transaction {
 723   my ($self) = @_;
 724
 725   $self->save_and_redirect_to(
 726     controller => 'ap.pl',
 727     action     => 'add_from_purchase_order',
 728   );
 729 }
 730
 731 # set form elements in respect to a changed customer or vendor
 732 #
 733 # This action is called on an change of the customer/vendor picker.
 734 sub action_customer_vendor_changed {
 735   my ($self) = @_;
 736
 737   setup_order_from_cv($self->order);
 738   $self->recalc();
 739
 740   my $cv_method = $self->cv;
 741
 742   if ($self->order->$cv_method->contacts && scalar @{ $self->order->$cv_method->contacts } > 0) {
 743     $self->js->show('#cp_row');
 744   } else {
 745     $self->js->hide('#cp_row');
 746   }
 747
 748   if ($self->order->$cv_method->shipto && scalar @{ $self->order->$cv_method->shipto } > 0) {
 749     $self->js->show('#shipto_selection');
 750   } else {
 751     $self->js->hide('#shipto_selection');
 752   }
 753
 754   if ($cv_method eq 'customer') {
 755     my $show_hide = scalar @{ $self->order->customer->additional_billing_addresses } > 0 ? 'show' : 'hide';
 756     $self->js->$show_hide('#billing_address_row');
 757   }
 758
 759   $self->js->val( '#order_salesman_id',      $self->order->salesman_id)        if $self->order->is_sales;
 760
 761   $self->js
 762     ->replaceWith('#order_cp_id',              $self->build_contact_select)
 763     ->replaceWith('#order_shipto_id',          $self->build_shipto_select)
 764     ->replaceWith('#shipto_inputs  ',          $self->build_shipto_inputs)
 765     ->replaceWith('#order_billing_address_id', $self->build_billing_address_select)
 766     ->replaceWith('#business_info_row',        $self->build_business_info_row)
 767     ->val(        '#order_taxzone_id',         $self->order->taxzone_id)
 768     ->val(        '#order_taxincluded',        $self->order->taxincluded)
 769     ->val(        '#order_currency_id',        $self->order->currency_id)
 770     ->val(        '#order_payment_id',         $self->order->payment_id)
 771     ->val(        '#order_delivery_term_id',   $self->order->delivery_term_id)
 772     ->val(        '#order_intnotes',           $self->order->intnotes)
 773     ->val(        '#order_language_id',        $self->order->$cv_method->language_id)
 774     ->focus(      '#order_' . $self->cv . '_id')
 775     ->run('kivi.Order.update_exchangerate');
 776
 777   $self->js_redisplay_amounts_and_taxes;
 778   $self->js_redisplay_cvpartnumbers;
 779   $self->js->render();
 780 }
 781
 782 # open the dialog for customer/vendor details
 783 sub action_show_customer_vendor_details_dialog {
 784   my ($self) = @_;
 785
 786   my $is_customer = 'customer' eq $::form->{vc};
 787   my $cv;
 788   if ($is_customer) {
 789     $cv = SL::DB::Customer->new(id => $::form->{vc_id})->load;
 790   } else {
 791     $cv = SL::DB::Vendor->new(id => $::form->{vc_id})->load;
 792   }
 793
 794   my %details = map { $_ => $cv->$_ } @{$cv->meta->columns};
 795   $details{discount_as_percent} = $cv->discount_as_percent;
 796   $details{creditlimt}          = $cv->creditlimit_as_number;
 797   $details{business}            = $cv->business->description      if $cv->business;
 798   $details{language}            = $cv->language_obj->description  if $cv->language_obj;
 799   $details{delivery_terms}      = $cv->delivery_term->description if $cv->delivery_term;
 800   $details{payment_terms}       = $cv->payment->description       if $cv->payment;
 801   $details{pricegroup}          = $cv->pricegroup->pricegroup     if $is_customer && $cv->pricegroup;
 802
 803   if ($is_customer) {
 804     foreach my $entry (@{ $cv->additional_billing_addresses }) {
 805       push @{ $details{ADDITIONAL_BILLING_ADDRESSES} },   { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 806     }
 807   }
 808   foreach my $entry (@{ $cv->shipto }) {
 809     push @{ $details{SHIPTO} },   { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 810   }
 811   foreach my $entry (@{ $cv->contacts }) {
 812     push @{ $details{CONTACTS} }, { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 813   }
 814
 815   $_[0]->render('common/show_vc_details', { layout => 0 },
 816                 is_customer => $is_customer,
 817                 %details);
 818
 819 }
 820
 821 # called if a unit in an existing item row is changed
 822 sub action_unit_changed {
 823   my ($self) = @_;
 824
 825   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 826   my $item = $self->order->items_sorted->[$idx];
 827
 828   my $old_unit_obj = SL::DB::Unit->new(name => $::form->{old_unit})->load;
 829   $item->sellprice($item->unit_obj->convert_to($item->sellprice, $old_unit_obj));
 830
 831   $self->recalc();
 832
 833   $self->js
 834     ->run('kivi.Order.update_sellprice', $::form->{item_id}, $item->sellprice_as_number);
 835   $self->js_redisplay_line_values;
 836   $self->js_redisplay_amounts_and_taxes;
 837   $self->js->render();
 838 }
 839
 840 # add an item row for a new item entered in the input row
 841 sub action_add_item {
 842   my ($self) = @_;
 843
 844   delete $::form->{add_item}->{create_part_type};
 845
 846   my $form_attr = $::form->{add_item};
 847
 848   return unless $form_attr->{parts_id};
 849
 850   my $item = new_item($self->order, $form_attr);
 851
 852   $self->order->add_items($item);
 853
 854   $self->recalc();
 855
 856   $self->get_item_cvpartnumber($item);
 857
 858   my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 859   my $row_as_html = $self->p->render('order/tabs/_row',
 860                                      ITEM => $item,
 861                                      ID   => $item_id,
 862                                      SELF => $self,
 863   );
 864
 865   if ($::form->{insert_before_item_id}) {
 866     $self->js
 867       ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 868   } else {
 869     $self->js
 870       ->append('#row_table_id', $row_as_html);
 871   }
 872
 873   if ( $item->part->is_assortment ) {
 874     $form_attr->{qty_as_number} = 1 unless $form_attr->{qty_as_number};
 875     foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 876       my $attr = { parts_id => $assortment_item->parts_id,
 877                    qty      => $assortment_item->qty * $::form->parse_amount(\%::myconfig, $form_attr->{qty_as_number}), # TODO $form_attr->{unit}
 878                    unit     => $assortment_item->unit,
 879                    description => $assortment_item->part->description,
 880                  };
 881       my $item = new_item($self->order, $attr);
 882
 883       # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 884       $item->discount(1) unless $assortment_item->charge;
 885
 886       $self->order->add_items( $item );
 887       $self->recalc();
 888       $self->get_item_cvpartnumber($item);
 889       my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 890       my $row_as_html = $self->p->render('order/tabs/_row',
 891                                          ITEM => $item,
 892                                          ID   => $item_id,
 893                                          SELF => $self,
 894       );
 895       if ($::form->{insert_before_item_id}) {
 896         $self->js
 897           ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 898       } else {
 899         $self->js
 900           ->append('#row_table_id', $row_as_html);
 901       }
 902     };
 903   };
 904
 905   $self->js
 906     ->val('.add_item_input', '')
 907     ->run('kivi.Order.init_row_handlers')
 908     ->run('kivi.Order.renumber_positions')
 909     ->focus('#add_item_parts_id_name');
 910
 911   $self->js->run('kivi.Order.row_table_scroll_down') if !$::form->{insert_before_item_id};
 912
 913   $self->js_redisplay_amounts_and_taxes;
 914   $self->js->render();
 915 }
 916
 917 # add item rows for multiple items at once
 918 sub action_add_multi_items {
 919   my ($self) = @_;
 920
 921   my @form_attr = grep { $_->{qty_as_number} } @{ $::form->{add_items} };
 922   return $self->js->render() unless scalar @form_attr;
 923
 924   my @items;
 925   foreach my $attr (@form_attr) {
 926     my $item = new_item($self->order, $attr);
 927     push @items, $item;
 928     if ( $item->part->is_assortment ) {
 929       foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 930         my $attr = { parts_id => $assortment_item->parts_id,
 931                      qty      => $assortment_item->qty * $item->qty, # TODO $form_attr->{unit}
 932                      unit     => $assortment_item->unit,
 933                      description => $assortment_item->part->description,
 934                    };
 935         my $item = new_item($self->order, $attr);
 936
 937         # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 938         $item->discount(1) unless $assortment_item->charge;
 939         push @items, $item;
 940       }
 941     }
 942   }
 943   $self->order->add_items(@items);
 944
 945   $self->recalc();
 946
 947   foreach my $item (@items) {
 948     $self->get_item_cvpartnumber($item);
 949     my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 950     my $row_as_html = $self->p->render('order/tabs/_row',
 951                                        ITEM => $item,
 952                                        ID   => $item_id,
 953                                        SELF => $self,
 954     );
 955
 956     if ($::form->{insert_before_item_id}) {
 957       $self->js
 958         ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 959     } else {
 960       $self->js
 961         ->append('#row_table_id', $row_as_html);
 962     }
 963   }
 964
 965   $self->js
 966     ->run('kivi.Part.close_picker_dialogs')
 967     ->run('kivi.Order.init_row_handlers')
 968     ->run('kivi.Order.renumber_positions')
 969     ->focus('#add_item_parts_id_name');
 970
 971   $self->js->run('kivi.Order.row_table_scroll_down') if !$::form->{insert_before_item_id};
 972
 973   $self->js_redisplay_amounts_and_taxes;
 974   $self->js->render();
 975 }
 976
 977 # recalculate all linetotals, amounts and taxes and redisplay them
 978 sub action_recalc_amounts_and_taxes {
 979   my ($self) = @_;
 980
 981   $self->recalc();
 982
 983   $self->js_redisplay_line_values;
 984   $self->js_redisplay_amounts_and_taxes;
 985   $self->js->render();
 986 }
 987
 988 sub action_update_exchangerate {
 989   my ($self) = @_;
 990
 991   my $data = {
 992     is_standard   => $self->order->currency_id == $::instance_conf->get_currency_id,
 993     currency_name => $self->order->currency->name,
 994     exchangerate  => $self->order->daily_exchangerate_as_null_number,
 995   };
 996
 997   $self->render(\SL::JSON::to_json($data), { type => 'json', process => 0 });
 998 }
 999
1000 # redisplay item rows if they are sorted by an attribute
1001 sub action_reorder_items {
1002   my ($self) = @_;
1003
1004   my %sort_keys = (
1005     partnumber   => sub { $_[0]->part->partnumber },
1006     description  => sub { $_[0]->description },
1007     qty          => sub { $_[0]->qty },
1008     sellprice    => sub { $_[0]->sellprice },
1009     discount     => sub { $_[0]->discount },
1010     cvpartnumber => sub { $_[0]->{cvpartnumber} },
1011   );
1012
1013   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
1014
1015   my $method = $sort_keys{$::form->{order_by}};
1016   my @to_sort = map { { old_pos => $_->position, order_by => $method->($_) } } @{ $self->order->items_sorted };
1017   if ($::form->{sort_dir}) {
1018     if ( $::form->{order_by} =~ m/qty|sellprice|discount/ ){
1019       @to_sort = sort { $a->{order_by} <=> $b->{order_by} } @to_sort;
1020     } else {
1021       @to_sort = sort { $a->{order_by} cmp $b->{order_by} } @to_sort;
1022     }
1023   } else {
1024     if ( $::form->{order_by} =~ m/qty|sellprice|discount/ ){
1025       @to_sort = sort { $b->{order_by} <=> $a->{order_by} } @to_sort;
1026     } else {
1027       @to_sort = sort { $b->{order_by} cmp $a->{order_by} } @to_sort;
1028     }
1029   }
1030   $self->js
1031     ->run('kivi.Order.redisplay_items', \@to_sort)
1032     ->render;
1033 }
1034
1035 # show the popup to choose a price/discount source
1036 sub action_price_popup {
1037   my ($self) = @_;
1038
1039   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
1040   my $item = $self->order->items_sorted->[$idx];
1041
1042   $self->render_price_dialog($item);
1043 }
1044
1045 # save the order in a session variable and redirect to the part controller
1046 sub action_create_part {
1047   my ($self) = @_;
1048
1049   my $previousform = $::auth->save_form_in_session(non_scalars => 1);
1050
1051   my $callback     = $self->url_for(
1052     action       => 'return_from_create_part',
1053     type         => $self->type, # type is needed for check_auth on return
1054     previousform => $previousform,
1055   );
1056
1057   flash_later('info', t8('You are adding a new part while you are editing another document. You will be redirected to your document when saving the new part or aborting this form.'));
1058
1059   my @redirect_params = (
1060     controller => 'Part',
1061     action     => 'add',
1062     part_type  => $::form->{add_item}->{create_part_type},
1063     callback   => $callback,
1064     show_abort => 1,
1065   );
1066
1067   $self->redirect_to(@redirect_params);
1068 }
1069
1070 sub action_return_from_create_part {
1071   my ($self) = @_;
1072
1073   $self->{created_part} = SL::DB::Part->new(id => delete $::form->{new_parts_id})->load if $::form->{new_parts_id};
1074
1075   $::auth->restore_form_from_session(delete $::form->{previousform});
1076
1077   # set item ids to new fake id, to identify them as new items
1078   foreach my $item (@{$self->order->items_sorted}) {
1079     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1080   }
1081
1082   $self->recalc();
1083   $self->get_unalterable_data();
1084   $self->pre_render();
1085
1086   # trigger rendering values for second row/longdescription as hidden,
1087   # because they are loaded only on demand. So we need to keep the values
1088   # from the source.
1089   $_->{render_second_row}      = 1 for @{ $self->order->items_sorted };
1090   $_->{render_longdescription} = 1 for @{ $self->order->items_sorted };
1091
1092   $self->render(
1093     'order/form',
1094     title => $self->get_title_for('edit'),
1095     %{$self->{template_args}}
1096   );
1097
1098 }
1099
1100 # load the second row for one or more items
1101 #
1102 # This action gets the html code for all items second rows by rendering a template for
1103 # the second row and sets the html code via client js.
1104 sub action_load_second_rows {
1105   my ($self) = @_;
1106
1107   $self->recalc() if $self->order->is_sales; # for margin calculation
1108
1109   foreach my $item_id (@{ $::form->{item_ids} }) {
1110     my $idx  = first_index { $_ eq $item_id } @{ $::form->{orderitem_ids} };
1111     my $item = $self->order->items_sorted->[$idx];
1112
1113     $self->js_load_second_row($item, $item_id, 0);
1114   }
1115
1116   $self->js->run('kivi.Order.init_row_handlers') if $self->order->is_sales; # for lastcosts change-callback
1117
1118   $self->js->render();
1119 }
1120
1121 # update description, notes and sellprice from master data
1122 sub action_update_row_from_master_data {
1123   my ($self) = @_;
1124
1125   foreach my $item_id (@{ $::form->{item_ids} }) {
1126     my $idx   = first_index { $_ eq $item_id } @{ $::form->{orderitem_ids} };
1127     my $item  = $self->order->items_sorted->[$idx];
1128     my $texts = get_part_texts($item->part, $self->order->language_id);
1129
1130     $item->description($texts->{description});
1131     $item->longdescription($texts->{longdescription});
1132
1133     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
1134
1135     my $price_src;
1136     if ($item->part->is_assortment) {
1137     # add assortment items with price 0, as the components carry the price
1138       $price_src = $price_source->price_from_source("");
1139       $price_src->price(0);
1140     } else {
1141       $price_src = $price_source->best_price
1142                  ? $price_source->best_price
1143                  : $price_source->price_from_source("");
1144       $price_src->price($::form->round_amount($price_src->price / $self->order->exchangerate, 5)) if $self->order->exchangerate;
1145       $price_src->price(0) if !$price_source->best_price;
1146     }
1147
1148
1149     $item->sellprice($price_src->price);
1150     $item->active_price_source($price_src);
1151
1152     $self->js
1153       ->run('kivi.Order.update_sellprice', $item_id, $item->sellprice_as_number)
1154       ->html('.row_entry:has(#item_' . $item_id . ') [name = "partnumber"] a', $item->part->partnumber)
1155       ->val ('.row_entry:has(#item_' . $item_id . ') [name = "order.orderitems[].description"]', $item->description)
1156       ->val ('.row_entry:has(#item_' . $item_id . ') [name = "order.orderitems[].longdescription"]', $item->longdescription);
1157
1158     if ($self->search_cvpartnumber) {
1159       $self->get_item_cvpartnumber($item);
1160       $self->js->html('.row_entry:has(#item_' . $item_id . ') [name = "cvpartnumber"]', $item->{cvpartnumber});
1161     }
1162   }
1163
1164   $self->recalc();
1165   $self->js_redisplay_line_values;
1166   $self->js_redisplay_amounts_and_taxes;
1167
1168   $self->js->render();
1169 }
1170
1171 sub js_load_second_row {
1172   my ($self, $item, $item_id, $do_parse) = @_;
1173
1174   if ($do_parse) {
1175     # Parse values from form (they are formated while rendering (template)).
1176     # Workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
1177     # This parsing is not necessary at all, if we assure that the second row/cvars are only loaded once.
1178     foreach my $var (@{ $item->cvars_by_config }) {
1179       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
1180     }
1181     $item->parse_custom_variable_values;
1182   }
1183
1184   my $row_as_html = $self->p->render('order/tabs/_second_row', ITEM => $item, TYPE => $self->type);
1185
1186   $self->js
1187     ->html('#second_row_' . $item_id, $row_as_html)
1188     ->data('#second_row_' . $item_id, 'loaded', 1);
1189 }
1190
1191 sub js_redisplay_line_values {
1192   my ($self) = @_;
1193
1194   my $is_sales = $self->order->is_sales;
1195
1196   # sales orders with margins
1197   my @data;
1198   if ($is_sales) {
1199     @data = map {
1200       [
1201        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
1202        $::form->format_amount(\%::myconfig, $_->{marge_total},   2, 0),
1203        $::form->format_amount(\%::myconfig, $_->{marge_percent}, 2, 0),
1204       ]} @{ $self->order->items_sorted };
1205   } else {
1206     @data = map {
1207       [
1208        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
1209       ]} @{ $self->order->items_sorted };
1210   }
1211
1212   $self->js
1213     ->run('kivi.Order.redisplay_line_values', $is_sales, \@data);
1214 }
1215
1216 sub js_redisplay_amounts_and_taxes {
1217   my ($self) = @_;
1218
1219   if (scalar @{ $self->{taxes} }) {
1220     $self->js->show('#taxincluded_row_id');
1221   } else {
1222     $self->js->hide('#taxincluded_row_id');
1223   }
1224
1225   if ($self->order->taxincluded) {
1226     $self->js->hide('#subtotal_row_id');
1227   } else {
1228     $self->js->show('#subtotal_row_id');
1229   }
1230
1231   if ($self->order->is_sales) {
1232     my $is_neg = $self->order->marge_total < 0;
1233     $self->js
1234       ->html('#marge_total_id',   $::form->format_amount(\%::myconfig, $self->order->marge_total,   2))
1235       ->html('#marge_percent_id', $::form->format_amount(\%::myconfig, $self->order->marge_percent, 2))
1236       ->action_if( $is_neg, 'addClass',    '#marge_total_id',        'plus0')
1237       ->action_if( $is_neg, 'addClass',    '#marge_percent_id',      'plus0')
1238       ->action_if( $is_neg, 'addClass',    '#marge_percent_sign_id', 'plus0')
1239       ->action_if(!$is_neg, 'removeClass', '#marge_total_id',        'plus0')
1240       ->action_if(!$is_neg, 'removeClass', '#marge_percent_id',      'plus0')
1241       ->action_if(!$is_neg, 'removeClass', '#marge_percent_sign_id', 'plus0');
1242   }
1243
1244   $self->js
1245     ->html('#netamount_id', $::form->format_amount(\%::myconfig, $self->order->netamount, -2))
1246     ->html('#amount_id',    $::form->format_amount(\%::myconfig, $self->order->amount,    -2))
1247     ->remove('.tax_row')
1248     ->insertBefore($self->build_tax_rows, '#amount_row_id');
1249 }
1250
1251 sub js_redisplay_cvpartnumbers {
1252   my ($self) = @_;
1253
1254   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
1255
1256   my @data = map {[$_->{cvpartnumber}]} @{ $self->order->items_sorted };
1257
1258   $self->js
1259     ->run('kivi.Order.redisplay_cvpartnumbers', \@data);
1260 }
1261
1262 sub js_reset_order_and_item_ids_after_save {
1263   my ($self) = @_;
1264
1265   $self->js
1266     ->val('#id', $self->order->id)
1267     ->val('#converted_from_oe_id', '')
1268     ->val('#order_' . $self->nr_key(), $self->order->number);
1269
1270   my $idx = 0;
1271   foreach my $form_item_id (@{ $::form->{orderitem_ids} }) {
1272     next if !$self->order->items_sorted->[$idx]->id;
1273     next if $form_item_id !~ m{^new};
1274     $self->js
1275       ->val ('[name="orderitem_ids[+]"][value="' . $form_item_id . '"]', $self->order->items_sorted->[$idx]->id)
1276       ->val ('#item_' . $form_item_id, $self->order->items_sorted->[$idx]->id)
1277       ->attr('#item_' . $form_item_id, "id", 'item_' . $self->order->items_sorted->[$idx]->id);
1278   } continue {
1279     $idx++;
1280   }
1281   $self->js->val('[name="converted_from_orderitems_ids[+]"]', '');
1282 }
1283
1284 #
1285 # helpers
1286 #
1287
1288 sub init_valid_types {
1289   [ sales_order_type(), purchase_order_type(), sales_quotation_type(), request_quotation_type() ];
1290 }
1291
1292 sub init_type {
1293   my ($self) = @_;
1294
1295   if (none { $::form->{type} eq $_ } @{$self->valid_types}) {
1296     die "Not a valid type for order";
1297   }
1298
1299   $self->type($::form->{type});
1300 }
1301
1302 sub init_cv {
1303   my ($self) = @_;
1304
1305   my $cv = (any { $self->type eq $_ } (sales_order_type(),    sales_quotation_type()))   ? 'customer'
1306          : (any { $self->type eq $_ } (purchase_order_type(), request_quotation_type())) ? 'vendor'
1307          : die "Not a valid type for order";
1308
1309   return $cv;
1310 }
1311
1312 sub init_search_cvpartnumber {
1313   my ($self) = @_;
1314
1315   my $user_prefs = SL::Helper::UserPreferences::PartPickerSearch->new();
1316   my $search_cvpartnumber;
1317   $search_cvpartnumber = !!$user_prefs->get_sales_search_customer_partnumber() if $self->cv eq 'customer';
1318   $search_cvpartnumber = !!$user_prefs->get_purchase_search_makemodel()        if $self->cv eq 'vendor';
1319
1320   return $search_cvpartnumber;
1321 }
1322
1323 sub init_show_update_button {
1324   my ($self) = @_;
1325
1326   !!SL::Helper::UserPreferences::UpdatePositions->new()->get_show_update_button();
1327 }
1328
1329 sub init_p {
1330   SL::Presenter->get;
1331 }
1332
1333 sub init_order {
1334   $_[0]->make_order;
1335 }
1336
1337 sub init_all_price_factors {
1338   SL::DB::Manager::PriceFactor->get_all;
1339 }
1340
1341 sub init_part_picker_classification_ids {
1342   my ($self)    = @_;
1343   my $attribute = 'used_for_' . ($self->type =~ m{sales} ? 'sale' : 'purchase');
1344
1345   return [ map { $_->id } @{ SL::DB::Manager::PartClassification->get_all(where => [ $attribute => 1 ]) } ];
1346 }
1347
1348 sub check_auth {
1349   my ($self) = @_;
1350
1351   my $right_for = { map { $_ => $_.'_edit' } @{$self->valid_types} };
1352
1353   my $right   = $right_for->{ $self->type };
1354   $right    ||= 'DOES_NOT_EXIST';
1355
1356   $::auth->assert($right);
1357 }
1358
1359 # build the selection box for contacts
1360 #
1361 # Needed, if customer/vendor changed.
1362 sub build_contact_select {
1363   my ($self) = @_;
1364
1365   select_tag('order.cp_id', [ $self->order->{$self->cv}->contacts ],
1366     value_key  => 'cp_id',
1367     title_key  => 'full_name_dep',
1368     default    => $self->order->cp_id,
1369     with_empty => 1,
1370     style      => 'width: 300px',
1371   );
1372 }
1373
1374 # build the selection box for the additional billing address
1375 #
1376 # Needed, if customer/vendor changed.
1377 sub build_billing_address_select {
1378   my ($self) = @_;
1379
1380   return '' if $self->cv ne 'customer';
1381
1382   select_tag('order.billing_address_id',
1383              [ {displayable_id => '', id => ''}, $self->order->{$self->cv}->additional_billing_addresses ],
1384              value_key  => 'id',
1385              title_key  => 'displayable_id',
1386              default    => $self->order->billing_address_id,
1387              with_empty => 0,
1388              style      => 'width: 300px',
1389   );
1390 }
1391
1392 # build the selection box for shiptos
1393 #
1394 # Needed, if customer/vendor changed.
1395 sub build_shipto_select {
1396   my ($self) = @_;
1397
1398   select_tag('order.shipto_id',
1399              [ {displayable_id => t8("No/individual shipping address"), shipto_id => ''}, $self->order->{$self->cv}->shipto ],
1400              value_key  => 'shipto_id',
1401              title_key  => 'displayable_id',
1402              default    => $self->order->shipto_id,
1403              with_empty => 0,
1404              style      => 'width: 300px',
1405   );
1406 }
1407
1408 # build the inputs for the cusom shipto dialog
1409 #
1410 # Needed, if customer/vendor changed.
1411 sub build_shipto_inputs {
1412   my ($self) = @_;
1413
1414   my $content = $self->p->render('common/_ship_to_dialog',
1415                                  vc_obj      => $self->order->customervendor,
1416                                  cs_obj      => $self->order->custom_shipto,
1417                                  cvars       => $self->order->custom_shipto->cvars_by_config,
1418                                  id_selector => '#order_shipto_id');
1419
1420   div_tag($content, id => 'shipto_inputs');
1421 }
1422
1423 # render the info line for business
1424 #
1425 # Needed, if customer/vendor changed.
1426 sub build_business_info_row
1427 {
1428   $_[0]->p->render('order/tabs/_business_info_row', SELF => $_[0]);
1429 }
1430
1431 # build the rows for displaying taxes
1432 #
1433 # Called if amounts where recalculated and redisplayed.
1434 sub build_tax_rows {
1435   my ($self) = @_;
1436
1437   my $rows_as_html;
1438   foreach my $tax (sort { $a->{tax}->rate cmp $b->{tax}->rate } @{ $self->{taxes} }) {
1439     $rows_as_html .= $self->p->render('order/tabs/_tax_row', TAX => $tax, TAXINCLUDED => $self->order->taxincluded);
1440   }
1441   return $rows_as_html;
1442 }
1443
1444
1445 sub render_price_dialog {
1446   my ($self, $record_item) = @_;
1447
1448   my $price_source = SL::PriceSource->new(record_item => $record_item, record => $self->order);
1449
1450   $self->js
1451     ->run(
1452       'kivi.io.price_chooser_dialog',
1453       t8('Available Prices'),
1454       $self->render('order/tabs/_price_sources_dialog', { output => 0 }, price_source => $price_source)
1455     )
1456     ->reinit_widgets;
1457
1458 #   if (@errors) {
1459 #     $self->js->text('#dialog_flash_error_content', join ' ', @errors);
1460 #     $self->js->show('#dialog_flash_error');
1461 #   }
1462
1463   $self->js->render;
1464 }
1465
1466 sub load_order {
1467   my ($self) = @_;
1468
1469   return if !$::form->{id};
1470
1471   $self->order(SL::DB::Order->new(id => $::form->{id})->load);
1472
1473   # Add an empty custom shipto to the order, so that the dialog can render the cvar inputs.
1474   # You need a custom shipto object to call cvars_by_config to get the cvars.
1475   $self->order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => [])) if !$self->order->custom_shipto;
1476
1477   return $self->order;
1478 }
1479
1480 # load or create a new order object
1481 #
1482 # And assign changes from the form to this object.
1483 # If the order is loaded from db, check if items are deleted in the form,
1484 # remove them form the object and collect them for removing from db on saving.
1485 # Then create/update items from form (via make_item) and add them.
1486 sub make_order {
1487   my ($self) = @_;
1488
1489   # add_items adds items to an order with no items for saving, but they cannot
1490   # be retrieved via items until the order is saved. Adding empty items to new
1491   # order here solves this problem.
1492   my $order;
1493   $order   = SL::DB::Order->new(id => $::form->{id})->load(with => [ 'orderitems', 'orderitems.part' ]) if $::form->{id};
1494   $order ||= SL::DB::Order->new(orderitems  => [],
1495                                 quotation   => (any { $self->type eq $_ } (sales_quotation_type(), request_quotation_type())),
1496                                 currency_id => $::instance_conf->get_currency_id(),);
1497
1498   my $cv_id_method = $self->cv . '_id';
1499   if (!$::form->{id} && $::form->{$cv_id_method}) {
1500     $order->$cv_id_method($::form->{$cv_id_method});
1501     setup_order_from_cv($order);
1502   }
1503
1504   my $form_orderitems                  = delete $::form->{order}->{orderitems};
1505   my $form_periodic_invoices_config    = delete $::form->{order}->{periodic_invoices_config};
1506
1507   $order->assign_attributes(%{$::form->{order}});
1508
1509   $self->setup_custom_shipto_from_form($order, $::form);
1510
1511   if (my $periodic_invoices_config_attrs = $form_periodic_invoices_config ? SL::YAML::Load($form_periodic_invoices_config) : undef) {
1512     my $periodic_invoices_config = $order->periodic_invoices_config || $order->periodic_invoices_config(SL::DB::PeriodicInvoicesConfig->new);
1513     $periodic_invoices_config->assign_attributes(%$periodic_invoices_config_attrs);
1514   }
1515
1516   # remove deleted items
1517   $self->item_ids_to_delete([]);
1518   foreach my $idx (reverse 0..$#{$order->orderitems}) {
1519     my $item = $order->orderitems->[$idx];
1520     if (none { $item->id == $_->{id} } @{$form_orderitems}) {
1521       splice @{$order->orderitems}, $idx, 1;
1522       push @{$self->item_ids_to_delete}, $item->id;
1523     }
1524   }
1525
1526   my @items;
1527   my $pos = 1;
1528   foreach my $form_attr (@{$form_orderitems}) {
1529     my $item = make_item($order, $form_attr);
1530     $item->position($pos);
1531     push @items, $item;
1532     $pos++;
1533   }
1534   $order->add_items(grep {!$_->id} @items);
1535
1536   return $order;
1537 }
1538
1539 # create or update items from form
1540 #
1541 # Make item objects from form values. For items already existing read from db.
1542 # Create a new item else. And assign attributes.
1543 sub make_item {
1544   my ($record, $attr) = @_;
1545
1546   my $item;
1547   $item = first { $_->id == $attr->{id} } @{$record->items} if $attr->{id};
1548
1549   my $is_new = !$item;
1550
1551   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1552   # they cannot be retrieved via custom_variables until the order/orderitem is
1553   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1554   $item ||= SL::DB::OrderItem->new(custom_variables => []);
1555
1556   $item->assign_attributes(%$attr);
1557
1558   if ($is_new) {
1559     my $texts = get_part_texts($item->part, $record->language_id);
1560     $item->longdescription($texts->{longdescription})              if !defined $attr->{longdescription};
1561     $item->project_id($record->globalproject_id)                   if !defined $attr->{project_id};
1562     $item->lastcost($record->is_sales ? $item->part->lastcost : 0) if !defined $attr->{lastcost_as_number};
1563   }
1564
1565   return $item;
1566 }
1567
1568 # create a new item
1569 #
1570 # This is used to add one item
1571 sub new_item {
1572   my ($record, $attr) = @_;
1573
1574   my $item = SL::DB::OrderItem->new;
1575
1576   # Remove attributes where the user left or set the inputs empty.
1577   # So these attributes will be undefined and we can distinguish them
1578   # from zero later on.
1579   for (qw(qty_as_number sellprice_as_number discount_as_percent)) {
1580     delete $attr->{$_} if $attr->{$_} eq '';
1581   }
1582
1583   $item->assign_attributes(%$attr);
1584
1585   my $part         = SL::DB::Part->new(id => $attr->{parts_id})->load;
1586   my $price_source = SL::PriceSource->new(record_item => $item, record => $record);
1587
1588   $item->unit($part->unit) if !$item->unit;
1589
1590   my $price_src;
1591   if ( $part->is_assortment ) {
1592     # add assortment items with price 0, as the components carry the price
1593     $price_src = $price_source->price_from_source("");
1594     $price_src->price(0);
1595   } elsif (defined $item->sellprice) {
1596     $price_src = $price_source->price_from_source("");
1597     $price_src->price($item->sellprice);
1598   } else {
1599     $price_src = $price_source->best_price
1600                ? $price_source->best_price
1601                : $price_source->price_from_source("");
1602     $price_src->price($::form->round_amount($price_src->price / $record->exchangerate, 5)) if $record->exchangerate;
1603     $price_src->price(0) if !$price_source->best_price;
1604   }
1605
1606   my $discount_src;
1607   if (defined $item->discount) {
1608     $discount_src = $price_source->discount_from_source("");
1609     $discount_src->discount($item->discount);
1610   } else {
1611     $discount_src = $price_source->best_discount
1612                   ? $price_source->best_discount
1613                   : $price_source->discount_from_source("");
1614     $discount_src->discount(0) if !$price_source->best_discount;
1615   }
1616
1617   my %new_attr;
1618   $new_attr{part}                   = $part;
1619   $new_attr{description}            = $part->description     if ! $item->description;
1620   $new_attr{qty}                    = 1.0                    if ! $item->qty;
1621   $new_attr{price_factor_id}        = $part->price_factor_id if ! $item->price_factor_id;
1622   $new_attr{sellprice}              = $price_src->price;
1623   $new_attr{discount}               = $discount_src->discount;
1624   $new_attr{active_price_source}    = $price_src;
1625   $new_attr{active_discount_source} = $discount_src;
1626   $new_attr{longdescription}        = $part->notes           if ! defined $attr->{longdescription};
1627   $new_attr{project_id}             = $record->globalproject_id;
1628   $new_attr{lastcost}               = $record->is_sales ? $part->lastcost : 0;
1629
1630   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1631   # they cannot be retrieved via custom_variables until the order/orderitem is
1632   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1633   $new_attr{custom_variables} = [];
1634
1635   my $texts = get_part_texts($part, $record->language_id, description => $new_attr{description}, longdescription => $new_attr{longdescription});
1636
1637   $item->assign_attributes(%new_attr, %{ $texts });
1638
1639   return $item;
1640 }
1641
1642 sub setup_order_from_cv {
1643   my ($order) = @_;
1644
1645   $order->$_($order->customervendor->$_) for (qw(taxzone_id payment_id delivery_term_id currency_id));
1646
1647   $order->intnotes($order->customervendor->notes);
1648
1649   return if !$order->is_sales;
1650
1651   $order->salesman_id($order->customer->salesman_id || SL::DB::Manager::Employee->current->id);
1652   $order->taxincluded(defined($order->customer->taxincluded_checked)
1653                       ? $order->customer->taxincluded_checked
1654                       : $::myconfig{taxincluded_checked});
1655
1656   my $address = $order->customer->default_billing_address;;
1657   $order->billing_address_id($address ? $address->id : undef);
1658 }
1659
1660 # setup custom shipto from form
1661 #
1662 # The dialog returns form variables starting with 'shipto' and cvars starting
1663 # with 'shiptocvar_'.
1664 # Mark it to be deleted if a shipto from master data is selected
1665 # (i.e. order has a shipto).
1666 # Else, update or create a new custom shipto. If the fields are empty, it
1667 # will not be saved on save.
1668 sub setup_custom_shipto_from_form {
1669   my ($self, $order, $form) = @_;
1670
1671   if ($order->shipto) {
1672     $self->is_custom_shipto_to_delete(1);
1673   } else {
1674     my $custom_shipto = $order->custom_shipto || $order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => []));
1675
1676     my $shipto_cvars  = {map { my ($key) = m{^shiptocvar_(.+)}; $key => delete $form->{$_}} grep { m{^shiptocvar_} } keys %$form};
1677     my $shipto_attrs  = {map {                                  $_   => delete $form->{$_}} grep { m{^shipto}      } keys %$form};
1678
1679     $custom_shipto->assign_attributes(%$shipto_attrs);
1680     $custom_shipto->cvar_by_name($_)->value($shipto_cvars->{$_}) for keys %$shipto_cvars;
1681   }
1682 }
1683
1684 # recalculate prices and taxes
1685 #
1686 # Using the PriceTaxCalculator. Store linetotals in the item objects.
1687 sub recalc {
1688   my ($self) = @_;
1689
1690   my %pat = $self->order->calculate_prices_and_taxes();
1691
1692   $self->{taxes} = [];
1693   foreach my $tax_id (keys %{ $pat{taxes_by_tax_id} }) {
1694     my $netamount = sum0 map { $pat{amounts}->{$_}->{amount} } grep { $pat{amounts}->{$_}->{tax_id} == $tax_id } keys %{ $pat{amounts} };
1695
1696     push(@{ $self->{taxes} }, { amount    => $pat{taxes_by_tax_id}->{$tax_id},
1697                                 netamount => $netamount,
1698                                 tax       => SL::DB::Tax->new(id => $tax_id)->load });
1699   }
1700   pairwise { $a->{linetotal} = $b->{linetotal} } @{$self->order->items_sorted}, @{$pat{items}};
1701 }
1702
1703 # get data for saving, printing, ..., that is not changed in the form
1704 #
1705 # Only cvars for now.
1706 sub get_unalterable_data {
1707   my ($self) = @_;
1708
1709   foreach my $item (@{ $self->order->items }) {
1710     # autovivify all cvars that are not in the form (cvars_by_config can do it).
1711     # workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
1712     foreach my $var (@{ $item->cvars_by_config }) {
1713       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
1714     }
1715     $item->parse_custom_variable_values;
1716   }
1717 }
1718
1719 # delete the order
1720 #
1721 # And remove related files in the spool directory
1722 sub delete {
1723   my ($self) = @_;
1724
1725   my $errors = [];
1726   my $db     = $self->order->db;
1727
1728   $db->with_transaction(
1729     sub {
1730       my @spoolfiles = grep { $_ } map { $_->spoolfile } @{ SL::DB::Manager::Status->get_all(where => [ trans_id => $self->order->id ]) };
1731       $self->order->delete;
1732       my $spool = $::lx_office_conf{paths}->{spool};
1733       unlink map { "$spool/$_" } @spoolfiles if $spool;
1734
1735       $self->save_history('DELETED');
1736
1737       1;
1738   }) || push(@{$errors}, $db->error);
1739
1740   return $errors;
1741 }
1742
1743 # save the order
1744 #
1745 # And delete items that are deleted in the form.
1746 sub save {
1747   my ($self) = @_;
1748
1749   my $errors = [];
1750   my $db     = $self->order->db;
1751
1752   $db->with_transaction(sub {
1753     # delete custom shipto if it is to be deleted or if it is empty
1754     if ($self->order->custom_shipto && ($self->is_custom_shipto_to_delete || $self->order->custom_shipto->is_empty)) {
1755       $self->order->custom_shipto->delete if $self->order->custom_shipto->shipto_id;
1756       $self->order->custom_shipto(undef);
1757     }
1758
1759     SL::DB::OrderItem->new(id => $_)->delete for @{$self->item_ids_to_delete || []};
1760     $self->order->save(cascade => 1);
1761
1762     # link records
1763     if ($::form->{converted_from_oe_id}) {
1764       my @converted_from_oe_ids = split ' ', $::form->{converted_from_oe_id};
1765
1766       foreach my $converted_from_oe_id (@converted_from_oe_ids) {
1767         my $src = SL::DB::Order->new(id => $converted_from_oe_id)->load;
1768         $src->update_attributes(closed => 1) if $src->type =~ /_quotation$/;
1769         $src->link_to_record($self->order);
1770       }
1771       if (scalar @{ $::form->{converted_from_orderitems_ids} || [] }) {
1772         my $idx = 0;
1773         foreach (@{ $self->order->items_sorted }) {
1774           my $from_id = $::form->{converted_from_orderitems_ids}->[$idx];
1775           next if !$from_id;
1776           SL::DB::RecordLink->new(from_table => 'orderitems',
1777                                   from_id    => $from_id,
1778                                   to_table   => 'orderitems',
1779                                   to_id      => $_->id
1780           )->save;
1781           $idx++;
1782         }
1783       }
1784
1785       $self->link_requirement_specs_linking_to_created_from_objects(@converted_from_oe_ids);
1786     }
1787
1788     $self->set_project_in_linked_requirement_specs if $self->order->globalproject_id;
1789
1790     $self->save_history('SAVED');
1791
1792     1;
1793   }) || push(@{$errors}, $db->error);
1794
1795   return $errors;
1796 }
1797
1798 sub workflow_sales_or_request_for_quotation {
1799   my ($self) = @_;
1800
1801   # always save
1802   my $errors = $self->save();
1803
1804   if (scalar @{ $errors }) {
1805     $self->js->flash('error', $_) for @{ $errors };
1806     return $self->js->render();
1807   }
1808
1809   my $destination_type = $::form->{type} eq sales_order_type() ? sales_quotation_type() : request_quotation_type();
1810
1811   $self->order(SL::DB::Order->new_from($self->order, destination_type => $destination_type));
1812   $self->{converted_from_oe_id} = delete $::form->{id};
1813
1814   # set item ids to new fake id, to identify them as new items
1815   foreach my $item (@{$self->order->items_sorted}) {
1816     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1817   }
1818
1819   # change form type
1820   $::form->{type} = $destination_type;
1821   $self->type($self->init_type);
1822   $self->cv  ($self->init_cv);
1823   $self->check_auth;
1824
1825   $self->recalc();
1826   $self->get_unalterable_data();
1827   $self->pre_render();
1828
1829   # trigger rendering values for second row as hidden, because they
1830   # are loaded only on demand. So we need to keep the values from the
1831   # source.
1832   $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
1833
1834   $self->render(
1835     'order/form',
1836     title => $self->get_title_for('edit'),
1837     %{$self->{template_args}}
1838   );
1839 }
1840
1841 sub workflow_sales_or_purchase_order {
1842   my ($self) = @_;
1843
1844   # always save
1845   my $errors = $self->save();
1846
1847   if (scalar @{ $errors }) {
1848     $self->js->flash('error', $_) foreach @{ $errors };
1849     return $self->js->render();
1850   }
1851
1852   my $destination_type = $::form->{type} eq sales_quotation_type()   ? sales_order_type()
1853                        : $::form->{type} eq request_quotation_type() ? purchase_order_type()
1854                        : $::form->{type} eq purchase_order_type()    ? sales_order_type()
1855                        : $::form->{type} eq sales_order_type()       ? purchase_order_type()
1856                        : '';
1857
1858   # check for direct delivery
1859   # copy shipto in custom shipto (custom shipto will be copied by new_from() in case)
1860   my $custom_shipto;
1861   if (   $::form->{type} eq sales_order_type() && $destination_type eq purchase_order_type()
1862       && $::form->{use_shipto} && $self->order->shipto) {
1863     $custom_shipto = $self->order->shipto->clone('SL::DB::Order');
1864   }
1865
1866   $self->order(SL::DB::Order->new_from($self->order, destination_type => $destination_type));
1867   $self->{converted_from_oe_id} = delete $::form->{id};
1868
1869   # set item ids to new fake id, to identify them as new items
1870   foreach my $item (@{$self->order->items_sorted}) {
1871     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1872   }
1873
1874   if ($::form->{type} eq sales_order_type() && $destination_type eq purchase_order_type()) {
1875     if ($::form->{use_shipto}) {
1876       $self->order->custom_shipto($custom_shipto) if $custom_shipto;
1877     } else {
1878       # remove any custom shipto if not wanted
1879       $self->order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => []));
1880     }
1881   }
1882
1883   # change form type
1884   $::form->{type} = $destination_type;
1885   $self->type($self->init_type);
1886   $self->cv  ($self->init_cv);
1887   $self->check_auth;
1888
1889   $self->recalc();
1890   $self->get_unalterable_data();
1891   $self->pre_render();
1892
1893   # trigger rendering values for second row as hidden, because they
1894   # are loaded only on demand. So we need to keep the values from the
1895   # source.
1896   $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
1897
1898   $self->render(
1899     'order/form',
1900     title => $self->get_title_for('edit'),
1901     %{$self->{template_args}}
1902   );
1903 }
1904
1905
1906 sub pre_render {
1907   my ($self) = @_;
1908
1909   $self->{all_taxzones}               = SL::DB::Manager::TaxZone->get_all_sorted();
1910   $self->{all_currencies}             = SL::DB::Manager::Currency->get_all_sorted();
1911   $self->{all_departments}            = SL::DB::Manager::Department->get_all_sorted();
1912   $self->{all_languages}              = SL::DB::Manager::Language->get_all_sorted();
1913   $self->{all_employees}              = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->employee_id,
1914                                                                                               deleted => 0 ] ],
1915                                                                            sort_by => 'name');
1916   $self->{all_salesmen}               = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->salesman_id,
1917                                                                                               deleted => 0 ] ],
1918                                                                            sort_by => 'name');
1919   $self->{all_payment_terms}          = SL::DB::Manager::PaymentTerm->get_all_sorted(where => [ or => [ id => $self->order->payment_id,
1920                                                                                                         obsolete => 0 ] ]);
1921   $self->{all_delivery_terms}         = SL::DB::Manager::DeliveryTerm->get_all_sorted();
1922   $self->{current_employee_id}        = SL::DB::Manager::Employee->current->id;
1923   $self->{periodic_invoices_status}   = $self->get_periodic_invoices_status($self->order->periodic_invoices_config);
1924   $self->{order_probabilities}        = [ map { { title => ($_ * 10) . '%', id => $_ * 10 } } (0..10) ];
1925   $self->{positions_scrollbar_height} = SL::Helper::UserPreferences::PositionsScrollbar->new()->get_height();
1926
1927   my $print_form = Form->new('');
1928   $print_form->{type}        = $self->type;
1929   $print_form->{printers}    = SL::DB::Manager::Printer->get_all_sorted;
1930   $self->{print_options}     = SL::Helper::PrintOptions->get_print_options(
1931     form => $print_form,
1932     options => {dialog_name_prefix => 'print_options.',
1933                 show_headers       => 1,
1934                 no_queue           => 1,
1935                 no_postscript      => 1,
1936                 no_opendocument    => 0,
1937                 no_html            => 0},
1938   );
1939
1940   foreach my $item (@{$self->order->orderitems}) {
1941     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
1942     $item->active_price_source(   $price_source->price_from_source(   $item->active_price_source   ));
1943     $item->active_discount_source($price_source->discount_from_source($item->active_discount_source));
1944   }
1945
1946   if (any { $self->type eq $_ } (sales_order_type(), purchase_order_type())) {
1947     # Calculate shipped qtys here to prevent calling calculate for every item via the items method.
1948     # Do not use write_to_objects to prevent order->delivered to be set, because this should be
1949     # the value from db, which can be set manually or is set when linked delivery orders are saved.
1950     SL::Helper::ShippedQty->new->calculate($self->order)->write_to(\@{$self->order->items});
1951   }
1952
1953   if ($self->order->number && $::instance_conf->get_webdav) {
1954     my $webdav = SL::Webdav->new(
1955       type     => $self->type,
1956       number   => $self->order->number,
1957     );
1958     my @all_objects = $webdav->get_all_objects;
1959     @{ $self->{template_args}->{WEBDAV} } = map { { name => $_->filename,
1960                                                     type => t8('File'),
1961                                                     link => File::Spec->catfile($_->full_filedescriptor),
1962                                                 } } @all_objects;
1963   }
1964
1965   if (   (any { $self->type eq $_ } (sales_quotation_type(), sales_order_type()))
1966       && $::instance_conf->get_transport_cost_reminder_article_number_id ) {
1967     $self->{template_args}->{transport_cost_reminder_article} = SL::DB::Part->new(id => $::instance_conf->get_transport_cost_reminder_article_number_id)->load;
1968   }
1969
1970   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
1971
1972   $::request->{layout}->use_javascript("${_}.js") for qw(kivi.Validator kivi.SalesPurchase kivi.Order kivi.File ckeditor/ckeditor ckeditor/adapters/jquery
1973                                                          edit_periodic_invoices_config calculate_qty follow_up show_history);
1974   $self->setup_edit_action_bar;
1975 }
1976
1977 sub setup_edit_action_bar {
1978   my ($self, %params) = @_;
1979
1980   my $deletion_allowed = (any { $self->type eq $_ } (sales_quotation_type(), request_quotation_type()))
1981                       || (($self->type eq sales_order_type())    && $::instance_conf->get_sales_order_show_delete)
1982                       || (($self->type eq purchase_order_type()) && $::instance_conf->get_purchase_order_show_delete);
1983
1984   my @req_trans_cost_art = qw(kivi.Order.check_transport_cost_article_presence) x!!$::instance_conf->get_transport_cost_reminder_article_number_id;
1985   my @req_cusordnumber   = qw(kivi.Order.check_cusordnumber_presence)           x($self->type eq sales_order_type() && $::instance_conf->get_order_warn_no_cusordnumber);
1986
1987   my $has_invoice_for_advance_payment;
1988   if ($self->order->id && $self->type eq sales_order_type()) {
1989     my $lr = $self->order->linked_records(direction => 'to', to => ['Invoice']);
1990     $has_invoice_for_advance_payment = any {'SL::DB::Invoice' eq ref $_ && "invoice_for_advance_payment" eq $_->type} @$lr;
1991   }
1992
1993   for my $bar ($::request->layout->get('actionbar')) {
1994     $bar->add(
1995       combobox => [
1996         action => [
1997           t8('Save'),
1998           call      => [ 'kivi.Order.save', 'save', $::instance_conf->get_order_warn_duplicate_parts,
1999                                                     $::instance_conf->get_order_warn_no_deliverydate,
2000           ],
2001           checks    => [ 'kivi.Order.check_save_active_periodic_invoices', ['kivi.validate_form','#order_form'],
2002                          @req_trans_cost_art, @req_cusordnumber,
2003           ],
2004         ],
2005         action => [
2006           t8('Save as new'),
2007           call      => [ 'kivi.Order.save', 'save_as_new', $::instance_conf->get_order_warn_duplicate_parts ],
2008           checks    => [ 'kivi.Order.check_save_active_periodic_invoices',
2009                          @req_trans_cost_art, @req_cusordnumber,
2010           ],
2011           disabled  => !$self->order->id ? t8('This object has not been saved yet.') : undef,
2012         ],
2013       ], # end of combobox "Save"
2014
2015       combobox => [
2016         action => [
2017           t8('Workflow'),
2018         ],
2019         action => [
2020           t8('Save and Quotation'),
2021           submit   => [ '#order_form', { action => "Order/sales_quotation" } ],
2022           checks   => [ @req_trans_cost_art, @req_cusordnumber ],
2023           only_if  => (any { $self->type eq $_ } (sales_order_type())),
2024         ],
2025         action => [
2026           t8('Save and RFQ'),
2027           submit   => [ '#order_form', { action => "Order/request_for_quotation" } ],
2028           only_if  => (any { $self->type eq $_ } (purchase_order_type())),
2029         ],
2030         action => [
2031           t8('Save and Sales Order'),
2032           submit   => [ '#order_form', { action => "Order/sales_order" } ],
2033           checks   => [ @req_trans_cost_art ],
2034           only_if  => (any { $self->type eq $_ } (sales_quotation_type(), purchase_order_type())),
2035         ],
2036         action => [
2037           t8('Save and Purchase Order'),
2038           call      => [ 'kivi.Order.purchase_order_check_for_direct_delivery' ],
2039           checks    => [ @req_trans_cost_art, @req_cusordnumber ],
2040           only_if   => (any { $self->type eq $_ } (sales_order_type(), request_quotation_type())),
2041         ],
2042         action => [
2043           t8('Save and Delivery Order'),
2044           call      => [ 'kivi.Order.save', 'save_and_delivery_order', $::instance_conf->get_order_warn_duplicate_parts,
2045                                                                        $::instance_conf->get_order_warn_no_deliverydate,
2046                                                                                                                         ],
2047           checks    => [ 'kivi.Order.check_save_active_periodic_invoices',
2048                          @req_trans_cost_art, @req_cusordnumber,
2049           ],
2050           only_if   => (any { $self->type eq $_ } (sales_order_type(), purchase_order_type()))
2051         ],
2052         action => [
2053           t8('Save and Invoice'),
2054           call      => [ 'kivi.Order.save', 'save_and_invoice', $::instance_conf->get_order_warn_duplicate_parts ],
2055           checks    => [ 'kivi.Order.check_save_active_periodic_invoices',
2056                          @req_trans_cost_art, @req_cusordnumber,
2057           ],
2058         ],
2059         action => [
2060           t8('Save and Invoice for Advance Payment'),
2061           call      => [ 'kivi.Order.save', 'save_and_invoice_for_advance_payment', $::instance_conf->get_order_warn_duplicate_parts ],
2062           checks    => [ 'kivi.Order.check_save_active_periodic_invoices',
2063                          @req_trans_cost_art, @req_cusordnumber,
2064           ],
2065           disabled  => $has_invoice_for_advance_payment ? t8('This order has already an invoice for advanced payment.')
2066                                                         : undef,
2067           only_if   => (any { $self->type eq $_ } (sales_order_type())),
2068         ],
2069         action => [
2070           t8('Save and AP Transaction'),
2071           call      => [ 'kivi.Order.save', 'save_and_ap_transaction', $::instance_conf->get_order_warn_duplicate_parts ],
2072           only_if   => (any { $self->type eq $_ } (purchase_order_type()))
2073         ],
2074
2075       ], # end of combobox "Workflow"
2076
2077       combobox => [
2078         action => [
2079           t8('Export'),
2080         ],
2081         action => [
2082           t8('Save and preview PDF'),
2083           call   => [ 'kivi.Order.save', 'preview_pdf', $::instance_conf->get_order_warn_duplicate_parts,
2084                                                         $::instance_conf->get_order_warn_no_deliverydate,
2085                     ],
2086           checks => [ @req_trans_cost_art, @req_cusordnumber ],
2087         ],
2088         action => [
2089           t8('Save and print'),
2090           call   => [ 'kivi.Order.show_print_options', $::instance_conf->get_order_warn_duplicate_parts,
2091                                                        $::instance_conf->get_order_warn_no_deliverydate,
2092                     ],
2093           checks => [ @req_trans_cost_art, @req_cusordnumber ],
2094         ],
2095         action => [
2096           t8('Save and E-mail'),
2097           id   => 'save_and_email_action',
2098           call => [ 'kivi.Order.save', 'save_and_show_email_dialog', $::instance_conf->get_order_warn_duplicate_parts,
2099                                                                      $::instance_conf->get_order_warn_no_deliverydate,
2100                   ],
2101           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
2102         ],
2103         action => [
2104           t8('Download attachments of all parts'),
2105           call     => [ 'kivi.File.downloadOrderitemsFiles', $::form->{type}, $::form->{id} ],
2106           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
2107           only_if  => $::instance_conf->get_doc_storage,
2108         ],
2109       ], # end of combobox "Export"
2110
2111       action => [
2112         t8('Delete'),
2113         call     => [ 'kivi.Order.delete_order' ],
2114         confirm  => $::locale->text('Do you really want to delete this object?'),
2115         disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
2116         only_if  => $deletion_allowed,
2117       ],
2118
2119       combobox => [
2120         action => [
2121           t8('more')
2122         ],
2123         action => [
2124           t8('History'),
2125           call     => [ 'set_history_window', $self->order->id, 'id' ],
2126           disabled => !$self->order->id ? t8('This record has not been saved yet.') : undef,
2127         ],
2128         action => [
2129           t8('Follow-Up'),
2130           call     => [ 'kivi.Order.follow_up_window' ],
2131           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
2132           only_if  => $::auth->assert('productivity', 1),
2133         ],
2134       ], # end of combobox "more"
2135     );
2136   }
2137 }
2138
2139 sub generate_doc {
2140   my ($self, $doc_ref, $params) = @_;
2141
2142   my $order  = $self->order;
2143   my @errors = ();
2144
2145   my $print_form = Form->new('');
2146   $print_form->{type}        = $order->type;
2147   $print_form->{formname}    = $params->{formname} || $order->type;
2148   $print_form->{format}      = $params->{format}   || 'pdf';
2149   $print_form->{media}       = $params->{media}    || 'file';
2150   $print_form->{groupitems}  = $params->{groupitems};
2151   $print_form->{printer_id}  = $params->{printer_id};
2152   $print_form->{media}       = 'file'                             if $print_form->{media} eq 'screen';
2153
2154   $order->language($params->{language});
2155   $order->flatten_to_form($print_form, format_amounts => 1);
2156
2157   my $template_ext;
2158   my $template_type;
2159   if ($print_form->{format} =~ /(opendocument|oasis)/i) {
2160     $template_ext  = 'odt';
2161     $template_type = 'OpenDocument';
2162   } elsif ($print_form->{format} =~ m{html}i) {
2163     $template_ext  = 'html';
2164     $template_type = 'HTML';
2165   }
2166
2167   # search for the template
2168   my ($template_file, @template_files) = SL::Helper::CreatePDF->find_template(
2169     name        => $print_form->{formname},
2170     extension   => $template_ext,
2171     email       => $print_form->{media} eq 'email',
2172     language    => $params->{language},
2173     printer_id  => $print_form->{printer_id},
2174   );
2175
2176   if (!defined $template_file) {
2177     push @errors, $::locale->text('Cannot find matching template for this print request. Please contact your template maintainer. I tried these: #1.', join ', ', map { "'$_'"} @template_files);
2178   }
2179
2180   return @errors if scalar @errors;
2181
2182   $print_form->throw_on_error(sub {
2183     eval {
2184       $print_form->prepare_for_printing;
2185
2186       $$doc_ref = SL::Helper::CreatePDF->create_pdf(
2187         format        => $print_form->{format},
2188         template_type => $template_type,
2189         template      => $template_file,
2190         variables     => $print_form,
2191         variable_content_types => {
2192           longdescription => 'html',
2193           partnotes       => 'html',
2194           notes           => 'html',
2195           $::form->get_variable_content_types_for_cvars,
2196         },
2197       );
2198       1;
2199     } || push @errors, ref($EVAL_ERROR) eq 'SL::X::FormError' ? $EVAL_ERROR->error : $EVAL_ERROR;
2200   });
2201
2202   return @errors;
2203 }
2204
2205 sub get_files_for_email_dialog {
2206   my ($self) = @_;
2207
2208   my %files = map { ($_ => []) } qw(versions files vc_files part_files);
2209
2210   return %files if !$::instance_conf->get_doc_storage;
2211
2212   if ($self->order->id) {
2213     $files{versions} = [ SL::File->get_all_versions(object_id => $self->order->id,              object_type => $self->order->type, file_type => 'document') ];
2214     $files{files}    = [ SL::File->get_all(         object_id => $self->order->id,              object_type => $self->order->type, file_type => 'attachment') ];
2215     $files{vc_files} = [ SL::File->get_all(         object_id => $self->order->{$self->cv}->id, object_type => $self->cv,          file_type => 'attachment') ];
2216     $files{project_files} = [ SL::File->get_all(    object_id => $self->order->globalproject_id, object_type => 'project',         file_type => 'attachment') ];
2217   }
2218
2219   my @parts =
2220     uniq_by { $_->{id} }
2221     map {
2222       +{ id         => $_->part->id,
2223          partnumber => $_->part->partnumber }
2224     } @{$self->order->items_sorted};
2225
2226   foreach my $part (@parts) {
2227     my @pfiles = SL::File->get_all(object_id => $part->{id}, object_type => 'part');
2228     push @{ $files{part_files} }, map { +{ %{ $_ }, partnumber => $part->{partnumber} } } @pfiles;
2229   }
2230
2231   foreach my $key (keys %files) {
2232     $files{$key} = [ sort_by { lc $_->{db_file}->{file_name} } @{ $files{$key} } ];
2233   }
2234
2235   return %files;
2236 }
2237
2238 sub make_periodic_invoices_config_from_yaml {
2239   my ($yaml_config) = @_;
2240
2241   return if !$yaml_config;
2242   my $attr = SL::YAML::Load($yaml_config);
2243   return if 'HASH' ne ref $attr;
2244   return SL::DB::PeriodicInvoicesConfig->new(%$attr);
2245 }
2246
2247
2248 sub get_periodic_invoices_status {
2249   my ($self, $config) = @_;
2250
2251   return                      if $self->type ne sales_order_type();
2252   return t8('not configured') if !$config;
2253
2254   my $active = ('HASH' eq ref $config)                           ? $config->{active}
2255              : ('SL::DB::PeriodicInvoicesConfig' eq ref $config) ? $config->active
2256              :                                                     die "Cannot get status of periodic invoices config";
2257
2258   return $active ? t8('active') : t8('inactive');
2259 }
2260
2261 sub get_title_for {
2262   my ($self, $action) = @_;
2263
2264   return '' if none { lc($action)} qw(add edit);
2265
2266   # for locales:
2267   # $::locale->text("Add Sales Order");
2268   # $::locale->text("Add Purchase Order");
2269   # $::locale->text("Add Quotation");
2270   # $::locale->text("Add Request for Quotation");
2271   # $::locale->text("Edit Sales Order");
2272   # $::locale->text("Edit Purchase Order");
2273   # $::locale->text("Edit Quotation");
2274   # $::locale->text("Edit Request for Quotation");
2275
2276   $action = ucfirst(lc($action));
2277   return $self->type eq sales_order_type()       ? $::locale->text("$action Sales Order")
2278        : $self->type eq purchase_order_type()    ? $::locale->text("$action Purchase Order")
2279        : $self->type eq sales_quotation_type()   ? $::locale->text("$action Quotation")
2280        : $self->type eq request_quotation_type() ? $::locale->text("$action Request for Quotation")
2281        : '';
2282 }
2283
2284 sub get_item_cvpartnumber {
2285   my ($self, $item) = @_;
2286
2287   return if !$self->search_cvpartnumber;
2288   return if !$self->order->customervendor;
2289
2290   if ($self->cv eq 'vendor') {
2291     my @mms = grep { $_->make eq $self->order->customervendor->id } @{$item->part->makemodels};
2292     $item->{cvpartnumber} = $mms[0]->model if scalar @mms;
2293   } elsif ($self->cv eq 'customer') {
2294     my @cps = grep { $_->customer_id eq $self->order->customervendor->id } @{$item->part->customerprices};
2295     $item->{cvpartnumber} = $cps[0]->customer_partnumber if scalar @cps;
2296   }
2297 }
2298
2299 sub get_part_texts {
2300   my ($part_or_id, $language_or_id, %defaults) = @_;
2301
2302   my $part        = ref($part_or_id)     ? $part_or_id         : SL::DB::Part->load_cached($part_or_id);
2303   my $language_id = ref($language_or_id) ? $language_or_id->id : $language_or_id;
2304   my $texts       = {
2305     description     => $defaults{description}     // $part->description,
2306     longdescription => $defaults{longdescription} // $part->notes,
2307   };
2308
2309   return $texts unless $language_id;
2310
2311   my $translation = SL::DB::Manager::Translation->get_first(
2312     where => [
2313       parts_id    => $part->id,
2314       language_id => $language_id,
2315     ]);
2316
2317   $texts->{description}     = $translation->translation     if $translation && $translation->translation;
2318   $texts->{longdescription} = $translation->longdescription if $translation && $translation->longdescription;
2319
2320   return $texts;
2321 }
2322
2323 sub sales_order_type {
2324   'sales_order';
2325 }
2326
2327 sub purchase_order_type {
2328   'purchase_order';
2329 }
2330
2331 sub sales_quotation_type {
2332   'sales_quotation';
2333 }
2334
2335 sub request_quotation_type {
2336   'request_quotation';
2337 }
2338
2339 sub nr_key {
2340   return $_[0]->type eq sales_order_type()       ? 'ordnumber'
2341        : $_[0]->type eq purchase_order_type()    ? 'ordnumber'
2342        : $_[0]->type eq sales_quotation_type()   ? 'quonumber'
2343        : $_[0]->type eq request_quotation_type() ? 'quonumber'
2344        : '';
2345 }
2346
2347 sub save_and_redirect_to {
2348   my ($self, %params) = @_;
2349
2350   my $errors = $self->save();
2351
2352   if (scalar @{ $errors }) {
2353     $self->js->flash('error', $_) foreach @{ $errors };
2354     return $self->js->render();
2355   }
2356
2357   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
2358            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
2359            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
2360            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
2361            : '';
2362   flash_later('info', $text);
2363
2364   $self->redirect_to(%params, id => $self->order->id);
2365 }
2366
2367 sub save_history {
2368   my ($self, $addition) = @_;
2369
2370   my $number_type = $self->order->type =~ m{order} ? 'ordnumber' : 'quonumber';
2371   my $snumbers    = $number_type . '_' . $self->order->$number_type;
2372
2373   SL::DB::History->new(
2374     trans_id    => $self->order->id,
2375     employee_id => SL::DB::Manager::Employee->current->id,
2376     what_done   => $self->order->type,
2377     snumbers    => $snumbers,
2378     addition    => $addition,
2379   )->save;
2380 }
2381
2382 sub store_doc_to_webdav_and_filemanagement {
2383   my ($self, $content, $filename, $variant) = @_;
2384
2385   my $order = $self->order;
2386   my @errors;
2387
2388   # copy file to webdav folder
2389   if ($order->number && $::instance_conf->get_webdav_documents) {
2390     my $webdav = SL::Webdav->new(
2391       type     => $order->type,
2392       number   => $order->number,
2393     );
2394     my $webdav_file = SL::Webdav::File->new(
2395       webdav   => $webdav,
2396       filename => $filename,
2397     );
2398     eval {
2399       $webdav_file->store(data => \$content);
2400       1;
2401     } or do {
2402       push @errors, t8('Storing the document to the WebDAV folder failed: #1', $@);
2403     };
2404   }
2405   if ($order->id && $::instance_conf->get_doc_storage) {
2406     eval {
2407       SL::File->save(object_id     => $order->id,
2408                      object_type   => $order->type,
2409                      mime_type     => SL::MIME->mime_type_from_ext($filename),
2410                      source        => 'created',
2411                      file_type     => 'document',
2412                      file_name     => $filename,
2413                      file_contents => $content,
2414                      print_variant => $variant);
2415       1;
2416     } or do {
2417       push @errors, t8('Storing the document in the storage backend failed: #1', $@);
2418     };
2419   }
2420
2421   return @errors;
2422 }
2423
2424 sub link_requirement_specs_linking_to_created_from_objects {
2425   my ($self, @converted_from_oe_ids) = @_;
2426
2427   return unless @converted_from_oe_ids;
2428
2429   my $rs_orders = SL::DB::Manager::RequirementSpecOrder->get_all(where => [ order_id => \@converted_from_oe_ids ]);
2430   foreach my $rs_order (@{ $rs_orders }) {
2431     SL::DB::RequirementSpecOrder->new(
2432       order_id            => $self->order->id,
2433       requirement_spec_id => $rs_order->requirement_spec_id,
2434       version_id          => $rs_order->version_id,
2435     )->save;
2436   }
2437 }
2438
2439 sub set_project_in_linked_requirement_specs {
2440   my ($self) = @_;
2441
2442   my $rs_orders = SL::DB::Manager::RequirementSpecOrder->get_all(where => [ order_id => $self->order->id ]);
2443   foreach my $rs_order (@{ $rs_orders }) {
2444     next if $rs_order->requirement_spec->project_id == $self->order->globalproject_id;
2445
2446     $rs_order->requirement_spec->update_attributes(project_id => $self->order->globalproject_id);
2447   }
2448 }
2449
2450 1;
2451
2452 __END__
2453
2454 =encoding utf-8
2455
2456 =head1 NAME
2457
2458 SL::Controller::Order - controller for orders
2459
2460 =head1 SYNOPSIS
2461
2462 This is a new form to enter orders, completely rewritten with the use
2463 of controller and java script techniques.
2464
2465 The aim is to provide the user a better experience and a faster workflow. Also
2466 the code should be more readable, more reliable and better to maintain.
2467
2468 =head2 Key Features
2469
2470 =over 4
2471
2472 =item *
2473
2474 One input row, so that input happens every time at the same place.
2475
2476 =item *
2477
2478 Use of pickers where possible.
2479
2480 =item *
2481
2482 Possibility to enter more than one item at once.
2483
2484 =item *
2485
2486 Item list in a scrollable area, so that the workflow buttons stay at
2487 the bottom.
2488
2489 =item *
2490
2491 Reordering item rows with drag and drop is possible. Sorting item rows is
2492 possible (by partnumber, description, qty, sellprice and discount for now).
2493
2494 =item *
2495
2496 No C<update> is necessary. All entries and calculations are managed
2497 with ajax-calls and the page only reloads on C<save>.
2498
2499 =item *
2500
2501 User can see changes immediately, because of the use of java script
2502 and ajax.
2503
2504 =back
2505
2506 =head1 CODE
2507
2508 =head2 Layout
2509
2510 =over 4
2511
2512 =item * C<SL/Controller/Order.pm>
2513
2514 the controller
2515
2516 =item * C<template/webpages/order/form.html>
2517
2518 main form
2519
2520 =item * C<template/webpages/order/tabs/basic_data.html>
2521
2522 Main tab for basic_data.
2523
2524 This is the only tab here for now. "linked records" and "webdav" tabs are
2525 reused from generic code.
2526
2527 =over 4
2528
2529 =item * C<template/webpages/order/tabs/_business_info_row.html>
2530
2531 For displaying information on business type
2532
2533 =item * C<template/webpages/order/tabs/_item_input.html>
2534
2535 The input line for items
2536
2537 =item * C<template/webpages/order/tabs/_row.html>
2538
2539 One row for already entered items
2540
2541 =item * C<template/webpages/order/tabs/_tax_row.html>
2542
2543 Displaying tax information
2544
2545 =item * C<template/webpages/order/tabs/_price_sources_dialog.html>
2546
2547 Dialog for selecting price and discount sources
2548
2549 =back
2550
2551 =item * C<js/kivi.Order.js>
2552
2553 java script functions
2554
2555 =back
2556
2557 =head1 TODO
2558
2559 =over 4
2560
2561 =item * testing
2562
2563 =item * price sources: little symbols showing better price / better discount
2564
2565 =item * select units in input row?
2566
2567 =item * check for direct delivery (workflow sales order -> purchase order)
2568
2569 =item * access rights
2570
2571 =item * display weights
2572
2573 =item * mtime check
2574
2575 =item * optional client/user behaviour
2576
2577 (transactions has to be set - department has to be set -
2578  force project if enabled in client config)
2579
2580 =back
2581
2582 =head1 KNOWN BUGS AND CAVEATS
2583
2584 =over 4
2585
2586 =item *
2587
2588 Customer discount is not displayed as a valid discount in price source popup
2589 (this might be a bug in price sources)
2590
2591 (I cannot reproduce this (Bernd))
2592
2593 =item *
2594
2595 No indication that <shift>-up/down expands/collapses second row.
2596
2597 =item *
2598
2599 Inline creation of parts is not currently supported
2600
2601 =item *
2602
2603 Table header is not sticky in the scrolling area.
2604
2605 =item *
2606
2607 Sorting does not include C<position>, neither does reordering.
2608
2609 This behavior was implemented intentionally. But we can discuss, which behavior
2610 should be implemented.
2611
2612 =back
2613
2614 =head1 To discuss / Nice to have
2615
2616 =over 4
2617
2618 =item *
2619
2620 How to expand/collapse second row. Now it can be done clicking the icon or
2621 <shift>-up/down.
2622
2623 =item *
2624
2625 Possibility to select PriceSources in input row?
2626
2627 =item *
2628
2629 This controller uses a (changed) copy of the template for the PriceSource
2630 dialog. Maybe there could be used one code source.
2631
2632 =item *
2633
2634 Rounding-differences between this controller (PriceTaxCalculator) and the old
2635 form. This is not only a problem here, but also in all parts using the PTC.
2636 There exists a ticket and a patch. This patch should be testet.
2637
2638 =item *
2639
2640 An indicator, if the actual inputs are saved (like in an
2641 editor or on text processing application).
2642
2643 =item *
2644
2645 A warning when leaving the page without saveing unchanged inputs.
2646
2647
2648 =back
2649
2650 =head1 AUTHOR
2651
2652 Bernd Bleßmann E<lt>bernd@kivitendo-premium.deE<gt>
2653
2654 =cut