SL/Controller/Order.pm

   1 package SL::Controller::Order;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use SL::Helper::Flash;
   7 use SL::ClientJS;
   8 use SL::Presenter;
   9
  10 use SL::DB::Order;
  11 use SL::DB::Customer;
  12 use SL::DB::Vendor;
  13 use SL::DB::TaxZone;
  14 use SL::DB::Employee;
  15 use SL::DB::Project;
  16 use SL::DB::Default;
  17 use SL::DB::Unit;
  18
  19 use SL::Helper::DateTime;
  20
  21 use List::Util qw(max first);
  22 use List::MoreUtils qw(none pairwise);
  23
  24 use Rose::Object::MakeMethods::Generic
  25 (
  26  'scalar --get_set_init' => [ qw(order valid_types type cv js p) ],
  27 );
  28
  29
  30 # safety
  31 __PACKAGE__->run_before('_check_auth');
  32
  33 __PACKAGE__->run_before('_recalc',
  34                         only => [ qw(edit update save) ]);
  35
  36
  37 #
  38 # actions
  39 #
  40
  41 sub action_add {
  42   my ($self) = @_;
  43
  44   $self->order->transdate(DateTime->now_local());
  45
  46   $self->_pre_render();
  47   $self->render(
  48     'order/form',
  49     title => $self->type eq _sales_order_type()    ? $::locale->text('Add Sales Order')
  50            : $self->type eq _purchase_order_type() ? $::locale->text('Add Purchase Order')
  51            : '',
  52     %{$self->{template_args}}
  53   );
  54 }
  55
  56 sub action_edit {
  57   my ($self) = @_;
  58
  59   $self->_pre_render();
  60   $self->render(
  61     'order/form',
  62     title => $self->type eq _sales_order_type()    ? $::locale->text('Edit Sales Order')
  63            : $self->type eq _purchase_order_type() ? $::locale->text('Edit Purchase Order')
  64            : '',
  65     %{$self->{template_args}}
  66   );
  67 }
  68
  69 sub action_update {
  70   my ($self) = @_;
  71
  72   $self->_pre_render();
  73   $self->render(
  74     'order/form',
  75     title => $self->type eq _sales_order_type()    ? $::locale->text('Edit Sales Order')
  76            : $self->type eq _purchase_order_type() ? $::locale->text('Edit Purchase Order')
  77            : '',
  78     %{$self->{template_args}}
  79   );
  80 }
  81
  82 sub action_save {
  83   my ($self) = @_;
  84
  85   my $errors = $self->_save();
  86
  87   if (scalar @{ $errors }) {
  88     $self->js->flash('error', $_) foreach @{ $errors };
  89     return $self->js->render($self);
  90   }
  91
  92   flash_later('info', $::locale->text('The order has been saved'));
  93   my @redirect_params = (
  94     action => 'edit',
  95     type   => $self->type,
  96     id     => $self->order->id,
  97   );
  98
  99   $self->redirect_to(@redirect_params);
 100 }
 101
 102 sub action_customer_vendor_changed {
 103   my ($self) = @_;
 104
 105   if ($self->cv eq 'customer') {
 106     $self->order->customer(SL::DB::Manager::Customer->find_by_or_create(id => $::form->{cv_id}));
 107
 108   } elsif ($self->cv eq 'vendor') {
 109     $self->order->vendor(SL::DB::Manager::Vendor->find_by_or_create(id => $::form->{cv_id}));
 110   }
 111
 112   if ($self->order->{$self->cv}->contacts && scalar @{ $self->order->{$self->cv}->contacts } > 0) {
 113     $self->js->show('#cp_row');
 114   } else {
 115     $self->js->hide('#cp_row');
 116   }
 117
 118   if ($self->order->{$self->cv}->shipto && scalar @{ $self->order->{$self->cv}->shipto } > 0) {
 119     $self->js->show('#shipto_row');
 120   } else {
 121     $self->js->hide('#shipto_row');
 122   }
 123
 124   $self->js
 125     ->replaceWith('#order_cp_id',     $self->build_contact_select)
 126     ->replaceWith('#order_shipto_id', $self->build_shipto_select)
 127     ->val('#order_taxzone_id', $self->order->{$self->cv}->taxzone_id)
 128     ->focus('#order_' . $self->cv . '_id')
 129     ->render($self);
 130 }
 131
 132 sub action_add_item {
 133   my ($self) = @_;
 134
 135   my $form_attr = $::form->{add_item};
 136
 137   return unless $form_attr->{parts_id};
 138
 139   my $item = SL::DB::OrderItem->new;
 140   $item->assign_attributes(%$form_attr);
 141
 142   my $part        = SL::DB::Part->new(id => $form_attr->{parts_id})->load;
 143   my $cv_method   = $self->cv;
 144   my $cv_discount = $self->order->$cv_method? $self->order->$cv_method->discount : 0.0;
 145
 146   my %new_attr;
 147   $new_attr{part}        = $part;
 148   $new_attr{description} = $part->description if ! $item->description;
 149   $new_attr{qty}         = 1.0                if ! $item->qty;
 150   $new_attr{unit}        = $part->unit;
 151   $new_attr{sellprice}   = $part->sellprice   if ! $item->sellprice;
 152   $new_attr{discount}    = $cv_discount       if ! $item->discount;
 153
 154   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
 155   # they cannot be retrieved via custom_variables until the order/orderitem is
 156   # saved. Adding empty custom_variables to new orderitem here solves this problem.
 157   $new_attr{custom_variables} = [];
 158
 159   $item->assign_attributes(%new_attr);
 160
 161   $self->order->add_items($item);
 162
 163   $self->_recalc();
 164
 165   my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 166   my $row_as_html = $self->p->render('order/tabs/_row', ITEM => $item, ID => $item_id);
 167
 168   $self->js
 169     ->append('#row_table_id', $row_as_html)
 170     ->val('#add_item_parts_id', '')
 171     ->val('#add_item_parts_id_name', '')
 172     ->val('#add_item_description', '')
 173     ->val('#add_item_qty_as_number', '')
 174     ->val('#add_item_sellprice_as_number', '')
 175     ->val('#add_item_discount_as_percent', '')
 176     ->run('row_table_scroll_down')
 177     ->run('row_set_keyboard_events_by_id', $item_id)
 178     ->focus('#add_item_parts_id_name');
 179
 180   $self->_js_redisplay_amounts_and_taxes;
 181   $self->js->render($self);
 182 }
 183
 184 sub action_recalc_amounts_and_taxes {
 185   my ($self) = @_;
 186
 187   $self->_recalc();
 188
 189   $self->_js_redisplay_amounts_and_taxes;
 190   $self->js->render($self);
 191 }
 192
 193 sub _js_redisplay_amounts_and_taxes {
 194   my ($self) = @_;
 195
 196   $self->js
 197     ->html('#netamount_id', $::form->format_amount(\%::myconfig, $self->order->netamount, -2))
 198     ->html('#amount_id',    $::form->format_amount(\%::myconfig, $self->order->amount,    -2))
 199     ->remove('.tax_row')
 200     ->insertBefore($self->build_tax_rows, '#amount_row_id');
 201 }
 202
 203 #
 204 # helpers
 205 #
 206
 207 sub init_valid_types {
 208   [ _sales_order_type(), _purchase_order_type() ];
 209 }
 210
 211 sub init_type {
 212   my ($self) = @_;
 213
 214   if (none { $::form->{type} eq $_ } @{$self->valid_types}) {
 215     die "Not a valid type for order";
 216   }
 217
 218   $self->type($::form->{type});
 219 }
 220
 221 sub init_cv {
 222   my ($self) = @_;
 223
 224   my $cv = $self->type eq _sales_order_type()    ? 'customer'
 225          : $self->type eq _purchase_order_type() ? 'vendor'
 226          : die "Not a valid type for order";
 227
 228   return $cv;
 229 }
 230
 231 sub init_js {
 232   SL::ClientJS->new;
 233 }
 234
 235 sub init_p {
 236   SL::Presenter->get;
 237 }
 238
 239 sub init_order {
 240   _make_order();
 241 }
 242
 243 sub _check_auth {
 244   my ($self) = @_;
 245
 246   my $right_for = { map { $_ => $_.'_edit' } @{$self->valid_types} };
 247
 248   my $right   = $right_for->{ $self->type };
 249   $right    ||= 'DOES_NOT_EXIST';
 250
 251   $::auth->assert($right);
 252 }
 253
 254 sub build_contact_select {
 255   my ($self) = @_;
 256
 257   $self->p->select_tag('order.cp_id', [ $self->order->{$self->cv}->contacts ],
 258                        value_key  => 'cp_id',
 259                        title_key  => 'full_name_dep',
 260                        default    => $self->order->cp_id,
 261                        with_empty => 1,
 262                        style      => 'width: 300px',
 263   );
 264 }
 265
 266 sub build_shipto_select {
 267   my ($self) = @_;
 268
 269   $self->p->select_tag('order.shipto_id', [ $self->order->{$self->cv}->shipto ],
 270                        value_key  => 'shipto_id',
 271                        title_key  => 'displayable_id',
 272                        default    => $self->order->shipto_id,
 273                        with_empty => 1,
 274                        style      => 'width: 300px',
 275   );
 276 }
 277
 278 sub build_tax_rows {
 279   my ($self) = @_;
 280
 281   my $rows_as_html;
 282   foreach my $tax (@{ $self->{taxes} }) {
 283     $rows_as_html .= $self->p->render('order/tabs/_tax_row', TAX => $tax);
 284   }
 285   return $rows_as_html;
 286 }
 287
 288
 289 sub _make_order {
 290   my ($self) = @_;
 291
 292   # add_items adds items to an order with no items for saving, but they cannot
 293   # be retrieved via items until the order is saved. Adding empty items to new
 294   # order here solves this problem.
 295   my $order;
 296   $order   = SL::DB::Manager::Order->find_by(id => $::form->{id}) if $::form->{id};
 297   $order ||= SL::DB::Order->new(orderitems => []);
 298
 299   $order->assign_attributes(%{$::form->{order}});
 300
 301   return $order;
 302 }
 303
 304
 305 sub _recalc {
 306   my ($self) = @_;
 307
 308   # bb: todo: currency later
 309   $self->order->currency_id($::instance_conf->get_currency_id());
 310
 311   my %pat = $self->order->calculate_prices_and_taxes();
 312
 313   foreach my $tax_chart_id (keys %{ $pat{taxes} }) {
 314     my $tax = SL::DB::Manager::Tax->find_by(chart_id => $tax_chart_id);
 315     push(@{ $self->{taxes} }, { amount => $pat{taxes}->{$tax_chart_id},
 316                                 tax    => $tax });
 317   }
 318
 319   pairwise { $a->{linetotal} = $b->{linetotal} } @{$self->order->items}, @{$pat{items}};
 320 }
 321
 322 sub _save {
 323   my ($self) = @_;
 324
 325   my $errors = [];
 326   my $db = $self->order->db;
 327
 328   $db->do_transaction(
 329     sub {
 330       $self->order->save();
 331   }) || push(@{$errors}, $db->error);
 332
 333   return $errors;
 334 }
 335
 336
 337 sub _pre_render {
 338   my ($self) = @_;
 339
 340   $self->{all_taxzones}  = SL::DB::Manager::TaxZone->get_all_sorted();
 341   $self->{all_employees} = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->employee_id,
 342                                                                                  deleted => 0 ] ],
 343                                                               sort_by => 'name');
 344   $self->{all_projects}  = SL::DB::Manager::Project->get_all(where => [ or => [ id => $self->order->globalproject_id,
 345                                                                                 active => 1 ] ],
 346                                                              sort_by => 'projectnumber');
 347
 348   $self->{current_employee_id} = SL::DB::Manager::Employee->current->id;
 349 }
 350
 351 sub _sales_order_type {
 352   'sales_order';
 353 }
 354
 355 sub _purchase_order_type {
 356   'purchase_order';
 357 }
 358
 359 1;