SL/Controller/Order.pm

   1 package SL::Controller::Order;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use SL::Helper::Flash;
   7 use SL::Presenter;
   8 use SL::Locale::String;
   9 use SL::SessionFile::Random;
  10 use SL::PriceSource;
  11 use SL::Form;
  12 use SL::Webdav;
  13
  14 use SL::DB::Order;
  15 use SL::DB::Customer;
  16 use SL::DB::Vendor;
  17 use SL::DB::TaxZone;
  18 use SL::DB::Employee;
  19 use SL::DB::Project;
  20 use SL::DB::Default;
  21 use SL::DB::Unit;
  22 use SL::DB::Price;
  23 use SL::DB::Part;
  24
  25 use SL::Helper::DateTime;
  26 use SL::Helper::CreatePDF qw(:all);
  27
  28 use SL::Controller::Helper::GetModels;
  29
  30 use List::Util qw(max first);
  31 use List::MoreUtils qw(none pairwise first_index);
  32 use English qw(-no_match_vars);
  33 use File::Spec;
  34
  35 use Rose::Object::MakeMethods::Generic
  36 (
  37  'scalar --get_set_init' => [ qw(order valid_types type cv p multi_items_models) ],
  38 );
  39
  40
  41 # safety
  42 __PACKAGE__->run_before('_check_auth');
  43
  44 __PACKAGE__->run_before('_recalc',
  45                         only => [ qw(edit update save save_and_delivery_order create_pdf send_email) ]);
  46
  47 __PACKAGE__->run_before('_get_unalterable_data',
  48                         only => [ qw(save save_and_delivery_order create_pdf send_email) ]);
  49
  50 #
  51 # actions
  52 #
  53
  54 sub action_add {
  55   my ($self) = @_;
  56
  57   $self->order->transdate(DateTime->now_local());
  58   $self->order->reqdate(DateTime->today_local->next_workday) if !$self->order->reqdate;
  59
  60   $self->_pre_render();
  61   $self->render(
  62     'order/form',
  63     title => $self->type eq _sales_order_type()    ? $::locale->text('Add Sales Order')
  64            : $self->type eq _purchase_order_type() ? $::locale->text('Add Purchase Order')
  65            : '',
  66     %{$self->{template_args}}
  67   );
  68 }
  69
  70 sub action_edit {
  71   my ($self) = @_;
  72
  73   $self->_pre_render();
  74   $self->render(
  75     'order/form',
  76     title => $self->type eq _sales_order_type()    ? $::locale->text('Edit Sales Order')
  77            : $self->type eq _purchase_order_type() ? $::locale->text('Edit Purchase Order')
  78            : '',
  79     %{$self->{template_args}}
  80   );
  81 }
  82
  83 sub action_update {
  84   my ($self) = @_;
  85
  86   $self->_pre_render();
  87   $self->render(
  88     'order/form',
  89     title => $self->type eq _sales_order_type()    ? $::locale->text('Edit Sales Order')
  90            : $self->type eq _purchase_order_type() ? $::locale->text('Edit Purchase Order')
  91            : '',
  92     %{$self->{template_args}}
  93   );
  94 }
  95
  96 sub action_save {
  97   my ($self) = @_;
  98
  99   my $errors = $self->_save();
 100
 101   if (scalar @{ $errors }) {
 102     $self->js->flash('error', $_) foreach @{ $errors };
 103     return $self->js->render();
 104   }
 105
 106   flash_later('info', $::locale->text('The order has been saved'));
 107   my @redirect_params = (
 108     action => 'edit',
 109     type   => $self->type,
 110     id     => $self->order->id,
 111   );
 112
 113   $self->redirect_to(@redirect_params);
 114 }
 115
 116 sub action_create_pdf {
 117   my ($self) = @_;
 118
 119   my $pdf;
 120   my @errors = _create_pdf($self->order, \$pdf);
 121   if (scalar @errors) {
 122     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render($self);
 123   }
 124
 125   my $sfile = SL::SessionFile::Random->new(mode => "w");
 126   $sfile->fh->print($pdf);
 127   $sfile->fh->close;
 128
 129   my $key = join('_', Time::HiRes::gettimeofday(), int rand 1000000000000);
 130   $::auth->set_session_value("Order::create_pdf-${key}" => $sfile->file_name);
 131
 132   my $form = Form->new;
 133   $form->{ordnumber} = $self->order->ordnumber;
 134   $form->{formname}  = $self->type;
 135   $form->{type}      = $self->type;
 136   $form->{language}  = 'de';
 137   $form->{format}    = 'pdf';
 138
 139   my $pdf_filename = $form->generate_attachment_filename();
 140
 141   # copy file to webdav folder
 142   if ($self->order->ordnumber && $::instance_conf->get_webdav_documents) {
 143     my $webdav = SL::Webdav->new(
 144       type     => $self->type,
 145       number   => $self->order->ordnumber,
 146     );
 147     my $webdav_file = SL::Webdav::File->new(
 148       webdav   => $webdav,
 149       filename => $pdf_filename,
 150     );
 151     eval {
 152       $webdav_file->store(data => \$pdf);
 153       1;
 154     } or do {
 155       $self->js->flash('error', t8('Storing PDF to webdav folder failed: #1', $@));
 156     }
 157   }
 158
 159   $self->js
 160     ->run('download_pdf', $pdf_filename, $key)
 161     ->flash('info', t8('The PDF has been created'))->render($self);
 162 }
 163
 164 sub action_download_pdf {
 165   my ($self) = @_;
 166
 167   my $key = $::form->{key};
 168   my $tmp_filename = $::auth->get_session_value("Order::create_pdf-${key}");
 169   return $self->send_file(
 170     $tmp_filename,
 171     type => 'application/pdf',
 172     name => $::form->{pdf_filename},
 173   );
 174 }
 175
 176 sub action_show_email_dialog {
 177   my ($self) = @_;
 178
 179   my $cv_method = $self->cv;
 180
 181   if (!$self->order->$cv_method) {
 182     return $self->js->flash('error', t8('Cannot send E-mail without ' . $self->cv))
 183                     ->render($self);
 184   }
 185
 186   $self->{email}->{to}   = $self->order->contact->cp_email if $self->order->contact;
 187   $self->{email}->{to} ||= $self->order->$cv_method->email;
 188   $self->{email}->{cc}   = $self->order->$cv_method->cc;
 189   $self->{email}->{bcc}  = join ', ', grep $_, $self->order->$cv_method->bcc, SL::DB::Default->get->global_bcc;
 190   # Todo: get addresses from shipto, if any
 191
 192   my $form = Form->new;
 193   $form->{ordnumber} = $self->order->ordnumber;
 194   $form->{formname}  = $self->type;
 195   $form->{type}      = $self->type;
 196   $form->{language} = 'de';
 197   $form->{format}   = 'pdf';
 198
 199   $self->{email}->{subject}             = $form->generate_email_subject();
 200   $self->{email}->{attachment_filename} = $form->generate_attachment_filename();
 201   $self->{email}->{message}             = $form->create_email_signature();
 202
 203   my $dialog_html = $self->render('order/tabs/_email_dialog', { output => 0 });
 204   $self->js
 205       ->run('show_email_dialog', $dialog_html)
 206       ->reinit_widgets
 207       ->render($self);
 208 }
 209
 210 # Todo: handling error messages: flash is not displayed in dialog, but in the main form
 211 sub action_send_email {
 212   my ($self) = @_;
 213
 214   my $mail      = Mailer->new;
 215   $mail->{from} = qq|"$::myconfig{name}" <$::myconfig{email}>|;
 216   $mail->{$_}   = $::form->{email}->{$_} for qw(to cc bcc subject message);
 217
 218   my $pdf;
 219   my @errors = _create_pdf($self->order, \$pdf, {media => 'email'});
 220   if (scalar @errors) {
 221     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render($self);
 222   }
 223
 224   $mail->{attachments} = [{ "content" => $pdf,
 225                             "name"    => $::form->{email}->{attachment_filename} }];
 226
 227   if (my $err = $mail->send) {
 228     return $self->js->flash('error', t8('Sending E-mail: ') . $err)
 229                     ->render($self);
 230   }
 231
 232   # internal notes
 233   my $intnotes = $self->order->intnotes;
 234   $intnotes   .= "\n\n" if $self->order->intnotes;
 235   $intnotes   .= t8('[email]')                                                                                        . "\n";
 236   $intnotes   .= t8('Date')       . ": " . $::locale->format_date_object(DateTime->now_local, precision => 'seconds') . "\n";
 237   $intnotes   .= t8('To (email)') . ": " . $mail->{to}                                                                . "\n";
 238   $intnotes   .= t8('Cc')         . ": " . $mail->{cc}                                                                . "\n"    if $mail->{cc};
 239   $intnotes   .= t8('Bcc')        . ": " . $mail->{bcc}                                                               . "\n"    if $mail->{bcc};
 240   $intnotes   .= t8('Subject')    . ": " . $mail->{subject}                                                           . "\n\n";
 241   $intnotes   .= t8('Message')    . ": " . $mail->{message};
 242
 243   $self->js
 244       ->val('#order_intnotes', $intnotes)
 245       ->run('close_email_dialog')
 246       ->render($self);
 247 }
 248
 249 sub action_save_and_delivery_order {
 250   my ($self) = @_;
 251
 252   my $errors = $self->_save();
 253
 254   if (scalar @{ $errors }) {
 255     $self->js->flash('error', $_) foreach @{ $errors };
 256     return $self->js->render();
 257   }
 258
 259   my $delivery_order = $self->order->convert_to_delivery_order($self->order);
 260
 261   flash_later('info', $::locale->text('The order has been saved'));
 262   my @redirect_params = (
 263     controller => 'do.pl',
 264     action     => 'edit',
 265     type       => $delivery_order->type,
 266     id         => $delivery_order->id,
 267     vc         => $delivery_order->is_sales ? 'customer' : 'vendor',
 268   );
 269
 270   $self->redirect_to(@redirect_params);
 271 }
 272
 273 sub action_customer_vendor_changed {
 274   my ($self) = @_;
 275
 276   my $cv_method = $self->cv;
 277
 278   if ($self->order->$cv_method->contacts && scalar @{ $self->order->$cv_method->contacts } > 0) {
 279     $self->js->show('#cp_row');
 280   } else {
 281     $self->js->hide('#cp_row');
 282   }
 283
 284   if ($self->order->$cv_method->shipto && scalar @{ $self->order->$cv_method->shipto } > 0) {
 285     $self->js->show('#shipto_row');
 286   } else {
 287     $self->js->hide('#shipto_row');
 288   }
 289
 290   $self->order->taxzone_id($self->order->$cv_method->taxzone_id);
 291
 292   if ($self->order->is_sales) {
 293     $self->order->taxincluded(defined($self->order->$cv_method->taxincluded_checked)
 294                               ? $self->order->$cv_method->taxincluded_checked
 295                               : $::myconfig{taxincluded_checked});
 296   }
 297
 298   $self->order->payment_id($self->order->$cv_method->payment_id);
 299   $self->order->delivery_term_id($self->order->$cv_method->delivery_term_id);
 300
 301   $self->_recalc();
 302
 303   $self->js
 304     ->replaceWith('#order_cp_id',            $self->build_contact_select)
 305     ->replaceWith('#order_shipto_id',        $self->build_shipto_select)
 306     ->val(        '#order_taxzone_id',       $self->order->taxzone_id)
 307     ->val(        '#order_taxincluded',      $self->order->taxincluded)
 308     ->val(        '#order_payment_id',       $self->order->payment_id)
 309     ->val(        '#order_delivery_term_id', $self->order->delivery_term_id)
 310     ->focus(      '#order_' . $self->cv . '_id');
 311
 312   $self->_js_redisplay_amounts_and_taxes;
 313   $self->js->render();
 314 }
 315
 316 sub action_unit_changed {
 317   my ($self) = @_;
 318
 319   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 320   my $item = $self->order->items->[$idx];
 321
 322   my $old_unit_obj = SL::DB::Unit->new(name => $::form->{old_unit})->load;
 323   $item->sellprice($item->unit_obj->convert_to($item->sellprice, $old_unit_obj));
 324
 325   $self->_recalc();
 326
 327   $self->js
 328     ->run('update_sellprice', $::form->{item_id}, $item->sellprice_as_number);
 329   $self->_js_redisplay_linetotals;
 330   $self->_js_redisplay_amounts_and_taxes;
 331   $self->js->render();
 332 }
 333
 334 sub action_add_item {
 335   my ($self) = @_;
 336
 337   my $form_attr = $::form->{add_item};
 338
 339   return unless $form_attr->{parts_id};
 340
 341   my $item = _make_item($self->order, $form_attr);
 342   $self->order->add_items($item);
 343
 344   $self->_recalc();
 345
 346   my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 347   my $row_as_html = $self->p->render('order/tabs/_row', ITEM => $item, ID => $item_id);
 348
 349   $self->js
 350     ->append('#row_table_id', $row_as_html)
 351     ->val('#add_item_parts_id', '')
 352     ->val('#add_item_parts_id_name', '')
 353     ->val('#add_item_description', '')
 354     ->val('#add_item_qty_as_number', '')
 355     ->val('#add_item_sellprice_as_number', '')
 356     ->val('#add_item_discount_as_percent', '')
 357     ->run('row_table_scroll_down')
 358     ->run('row_set_keyboard_events_by_id', $item_id)
 359     ->run('set_unit_change_with_oldval_by_id', $item_id)
 360     ->on('.recalc', 'change', 'recalc_amounts_and_taxes')
 361     ->on('.reformat_number', 'change', 'reformat_number')
 362     ->focus('#add_item_parts_id_name');
 363
 364   $self->_js_redisplay_amounts_and_taxes;
 365   $self->js->render();
 366 }
 367
 368 sub action_show_multi_items_dialog {
 369   require SL::DB::PartsGroup;
 370   $_[0]->render('order/tabs/_multi_items_dialog', { layout => 0 },
 371                 all_partsgroups => SL::DB::Manager::PartsGroup->get_all);
 372 }
 373
 374 sub action_multi_items_update_result {
 375   my $max_count = 100;
 376   my $count = $_[0]->multi_items_models->count;
 377
 378   if ($count == 0) {
 379     my $text = SL::Presenter::EscapedText->new(text => $::locale->text('No results.'));
 380     $_[0]->render($text, { layout => 0 });
 381   } elsif ($count > $max_count) {
 382     my $text = SL::Presenter::EscapedText->new(text => $::locale->text('Too many results (#1 from #2).', $count, $max_count));
 383     $_[0]->render($text, { layout => 0 });
 384   } else {
 385     my $multi_items = $_[0]->multi_items_models->get;
 386     $_[0]->render('order/tabs/_multi_items_result', { layout => 0 },
 387                   multi_items => $multi_items);
 388   }
 389 }
 390
 391 sub action_add_multi_items {
 392   my ($self) = @_;
 393
 394   my @form_attr = grep { $_->{qty_as_number} } @{ $::form->{add_multi_items} };
 395   return $self->js->render() unless scalar @form_attr;
 396
 397   my @items;
 398   foreach my $attr (@form_attr) {
 399     push @items, _make_item($self->order, $attr);
 400   }
 401   $self->order->add_items(@items);
 402
 403   $self->_recalc();
 404
 405   foreach my $item (@items) {
 406     my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 407     my $row_as_html = $self->p->render('order/tabs/_row', ITEM => $item, ID => $item_id);
 408
 409     $self->js
 410         ->append('#row_table_id', $row_as_html)
 411         ->run('row_set_keyboard_events_by_id', $item_id)
 412         ->run('set_unit_change_with_oldval_by_id', $item_id);
 413   }
 414
 415   $self->js
 416     ->run('close_multi_items_dialog')
 417     ->run('row_table_scroll_down')
 418     ->on('.recalc', 'change', 'recalc_amounts_and_taxes')
 419     ->on('.reformat_number', 'change', 'reformat_number')
 420     ->focus('#add_item_parts_id_name');
 421
 422   $self->_js_redisplay_amounts_and_taxes;
 423   $self->js->render();
 424 }
 425
 426 sub action_recalc_amounts_and_taxes {
 427   my ($self) = @_;
 428
 429   $self->_recalc();
 430
 431   $self->_js_redisplay_linetotals;
 432   $self->_js_redisplay_amounts_and_taxes;
 433   $self->js->render();
 434 }
 435
 436 sub action_price_popup {
 437   my ($self) = @_;
 438
 439   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 440   my $item = $self->order->items->[$idx];
 441
 442   $self->render_price_dialog($item);
 443 }
 444
 445 sub _js_redisplay_linetotals {
 446   my ($self) = @_;
 447
 448   my @data = map {$::form->format_amount(\%::myconfig, $_->{linetotal}, 2, 0)} @{ $self->order->items };
 449   $self->js
 450     ->run('redisplay_linetotals', \@data);
 451 }
 452
 453 sub _js_redisplay_amounts_and_taxes {
 454   my ($self) = @_;
 455
 456   if (scalar @{ $self->{taxes} }) {
 457     $self->js->show('#taxincluded_row_id');
 458   } else {
 459     $self->js->hide('#taxincluded_row_id');
 460   }
 461
 462   if ($self->order->taxincluded) {
 463     $self->js->hide('#subtotal_row_id');
 464   } else {
 465     $self->js->show('#subtotal_row_id');
 466   }
 467
 468   $self->js
 469     ->html('#netamount_id', $::form->format_amount(\%::myconfig, $self->order->netamount, -2))
 470     ->html('#amount_id',    $::form->format_amount(\%::myconfig, $self->order->amount,    -2))
 471     ->remove('.tax_row')
 472     ->insertBefore($self->build_tax_rows, '#amount_row_id');
 473 }
 474
 475 #
 476 # helpers
 477 #
 478
 479 sub init_valid_types {
 480   [ _sales_order_type(), _purchase_order_type() ];
 481 }
 482
 483 sub init_type {
 484   my ($self) = @_;
 485
 486   if (none { $::form->{type} eq $_ } @{$self->valid_types}) {
 487     die "Not a valid type for order";
 488   }
 489
 490   $self->type($::form->{type});
 491 }
 492
 493 sub init_cv {
 494   my ($self) = @_;
 495
 496   my $cv = $self->type eq _sales_order_type()    ? 'customer'
 497          : $self->type eq _purchase_order_type() ? 'vendor'
 498          : die "Not a valid type for order";
 499
 500   return $cv;
 501 }
 502
 503 sub init_p {
 504   SL::Presenter->get;
 505 }
 506
 507 sub init_order {
 508   _make_order();
 509 }
 510
 511 sub init_multi_items_models {
 512   SL::Controller::Helper::GetModels->new(
 513     controller     => $_[0],
 514     model          => 'Part',
 515     with_objects   => [ qw(unit_obj) ],
 516     disable_plugin => 'paginated',
 517     source         => $::form->{multi_items},
 518     sorted         => {
 519       _default    => {
 520         by  => 'partnumber',
 521         dir => 1,
 522       },
 523       partnumber  => t8('Partnumber'),
 524       description => t8('Description')}
 525   );
 526 }
 527
 528 sub _check_auth {
 529   my ($self) = @_;
 530
 531   my $right_for = { map { $_ => $_.'_edit' } @{$self->valid_types} };
 532
 533   my $right   = $right_for->{ $self->type };
 534   $right    ||= 'DOES_NOT_EXIST';
 535
 536   $::auth->assert($right);
 537 }
 538
 539 sub build_contact_select {
 540   my ($self) = @_;
 541
 542   $self->p->select_tag('order.cp_id', [ $self->order->{$self->cv}->contacts ],
 543                        value_key  => 'cp_id',
 544                        title_key  => 'full_name_dep',
 545                        default    => $self->order->cp_id,
 546                        with_empty => 1,
 547                        style      => 'width: 300px',
 548   );
 549 }
 550
 551 sub build_shipto_select {
 552   my ($self) = @_;
 553
 554   $self->p->select_tag('order.shipto_id', [ $self->order->{$self->cv}->shipto ],
 555                        value_key  => 'shipto_id',
 556                        title_key  => 'displayable_id',
 557                        default    => $self->order->shipto_id,
 558                        with_empty => 1,
 559                        style      => 'width: 300px',
 560   );
 561 }
 562
 563 sub build_tax_rows {
 564   my ($self) = @_;
 565
 566   my $rows_as_html;
 567   foreach my $tax (sort { $a->{tax}->rate cmp $b->{tax}->rate } @{ $self->{taxes} }) {
 568     $rows_as_html .= $self->p->render('order/tabs/_tax_row', TAX => $tax, TAXINCLUDED => $self->order->taxincluded);
 569   }
 570   return $rows_as_html;
 571 }
 572
 573
 574 sub render_price_dialog {
 575   my ($self, $record_item) = @_;
 576
 577   my $price_source = SL::PriceSource->new(record_item => $record_item, record => $self->order);
 578
 579   $self->js
 580     ->run(
 581       'kivi.io.price_chooser_dialog',
 582       t8('Available Prices'),
 583       $self->render('order/tabs/_price_sources_dialog', { output => 0 }, price_source => $price_source)
 584     )
 585     ->reinit_widgets;
 586
 587 #   if (@errors) {
 588 #     $self->js->text('#dialog_flash_error_content', join ' ', @errors);
 589 #     $self->js->show('#dialog_flash_error');
 590 #   }
 591
 592   $self->js->render;
 593 }
 594
 595 sub _make_order {
 596   my ($self) = @_;
 597
 598   # add_items adds items to an order with no items for saving, but they cannot
 599   # be retrieved via items until the order is saved. Adding empty items to new
 600   # order here solves this problem.
 601   my $order;
 602   $order   = SL::DB::Manager::Order->find_by(id => $::form->{id}) if $::form->{id};
 603   $order ||= SL::DB::Order->new(orderitems => []);
 604
 605   $order->assign_attributes(%{$::form->{order}});
 606
 607   return $order;
 608 }
 609
 610 sub _make_item {
 611   my ($record, $attr) = @_;
 612
 613   my $item = SL::DB::OrderItem->new;
 614   $item->assign_attributes(%$attr);
 615
 616   my $part         = SL::DB::Part->new(id => $attr->{parts_id})->load;
 617   my $price_source = SL::PriceSource->new(record_item => $item, record => $record);
 618
 619   $item->unit($part->unit) if !$item->unit;
 620
 621   my $price_src;
 622   if ($item->sellprice) {
 623     $price_src = $price_source->price_from_source("");
 624     $price_src->price($item->sellprice);
 625   } else {
 626     $price_src = $price_source->best_price
 627            ? $price_source->best_price
 628            : $price_source->price_from_source("");
 629     $price_src->price(0) if !$price_source->best_price;
 630   }
 631
 632   my $discount_src;
 633   if ($item->discount) {
 634     $discount_src = $price_source->discount_from_source("");
 635     $discount_src->discount($item->discount);
 636   } else {
 637     $discount_src = $price_source->best_discount
 638                   ? $price_source->best_discount
 639                   : $price_source->discount_from_source("");
 640     $discount_src->discount(0) if !$price_source->best_discount;
 641   }
 642
 643   my %new_attr;
 644   $new_attr{part}                   = $part;
 645   $new_attr{description}            = $part->description if ! $item->description;
 646   $new_attr{qty}                    = 1.0                if ! $item->qty;
 647   $new_attr{sellprice}              = $price_src->price;
 648   $new_attr{discount}               = $discount_src->discount;
 649   $new_attr{active_price_source}    = $price_src;
 650   $new_attr{active_discount_source} = $discount_src;
 651
 652   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
 653   # they cannot be retrieved via custom_variables until the order/orderitem is
 654   # saved. Adding empty custom_variables to new orderitem here solves this problem.
 655   $new_attr{custom_variables} = [];
 656
 657   $item->assign_attributes(%new_attr);
 658
 659   return $item;
 660 }
 661
 662 sub _recalc {
 663   my ($self) = @_;
 664
 665   # bb: todo: currency later
 666   $self->order->currency_id($::instance_conf->get_currency_id());
 667
 668   my %pat = $self->order->calculate_prices_and_taxes();
 669   $self->{taxes} = [];
 670   foreach my $tax_chart_id (keys %{ $pat{taxes} }) {
 671     my $tax = SL::DB::Manager::Tax->find_by(chart_id => $tax_chart_id);
 672
 673     my @amount_keys = grep { $pat{amounts}->{$_}->{tax_id} == $tax->id } keys %{ $pat{amounts} };
 674     push(@{ $self->{taxes} }, { amount    => $pat{taxes}->{$tax_chart_id},
 675                                 netamount => $pat{amounts}->{$amount_keys[0]}->{amount},
 676                                 tax       => $tax });
 677   }
 678
 679   pairwise { $a->{linetotal} = $b->{linetotal} } @{$self->order->items}, @{$pat{items}};
 680 }
 681
 682
 683 sub _get_unalterable_data {
 684   my ($self) = @_;
 685
 686   foreach my $item (@{ $self->order->items }) {
 687     if ($item->id) {
 688       # load data from orderitems (db)
 689       my $db_item = SL::DB::OrderItem->new(id => $item->id)->load;
 690       $item->$_($db_item->$_) for qw(longdescription);
 691     } else {
 692       # set data from part (or other sources)
 693       $item->longdescription($item->part->notes);
 694     }
 695
 696     # autovivify all cvars that are not in the form (cvars_by_config can do it).
 697     # workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
 698     foreach my $var (@{ $item->cvars_by_config }) {
 699       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
 700     }
 701     $item->parse_custom_variable_values;
 702   }
 703 }
 704
 705
 706 sub _save {
 707   my ($self) = @_;
 708
 709   my $errors = [];
 710   my $db = $self->order->db;
 711
 712   $db->do_transaction(
 713     sub {
 714       $self->order->save();
 715   }) || push(@{$errors}, $db->error);
 716
 717   return $errors;
 718 }
 719
 720
 721 sub _pre_render {
 722   my ($self) = @_;
 723
 724   $self->{all_taxzones}        = SL::DB::Manager::TaxZone->get_all_sorted();
 725   $self->{all_departments}     = SL::DB::Manager::Department->get_all_sorted();
 726   $self->{all_employees}       = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->employee_id,
 727                                                                                        deleted => 0 ] ],
 728                                                                     sort_by => 'name');
 729   $self->{all_salesmen}        = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->salesman_id,
 730                                                                                        deleted => 0 ] ],
 731                                                                     sort_by => 'name');
 732   $self->{all_projects}        = SL::DB::Manager::Project->get_all(where => [ or => [ id => $self->order->globalproject_id,
 733                                                                                       active => 1 ] ],
 734                                                                    sort_by => 'projectnumber');
 735   $self->{all_payment_terms}   = SL::DB::Manager::PaymentTerm->get_all_sorted();
 736   $self->{all_delivery_terms}  = SL::DB::Manager::DeliveryTerm->get_all_sorted();
 737
 738   $self->{current_employee_id} = SL::DB::Manager::Employee->current->id;
 739
 740   foreach  my $item (@{$self->order->items}) {
 741     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
 742     $item->active_price_source(   $price_source->price_from_source(   $item->active_price_source   ));
 743     $item->active_discount_source($price_source->discount_from_source($item->active_discount_source));
 744
 745   }
 746
 747   if ($self->order->ordnumber && $::instance_conf->get_webdav) {
 748     my $webdav = SL::Webdav->new(
 749       type     => $self->type,
 750       number   => $self->order->ordnumber,
 751     );
 752     my $webdav_path = $webdav->webdav_path;
 753     my @all_objects = $webdav->get_all_objects;
 754     @{ $self->{template_args}->{WEBDAV} } = map { { name => $_->filename,
 755                                                     type => t8('File'),
 756                                                     link => File::Spec->catdir($webdav_path, $_->filename),
 757                                                 } } @all_objects;
 758   }
 759
 760   $::request->{layout}->use_javascript("${_}.js")  for qw(ckeditor/ckeditor ckeditor/adapters/jquery);
 761 }
 762
 763 sub _create_pdf {
 764   my ($order, $pdf_ref, $params) = @_;
 765
 766   my $print_form = Form->new('');
 767   $print_form->{type}     = $order->type;
 768   $print_form->{formname} = $order->type;
 769   $print_form->{format}   = $params->{format} || 'pdf',
 770   $print_form->{media}    = $params->{media}  || 'file';
 771
 772   $order->flatten_to_form($print_form, format_amounts => 1);
 773   # flatten_to_form sets payment_terms from customer/vendor - we do not want that here
 774   delete $print_form->{payment_terms} if !$print_form->{payment_id};
 775
 776   my @errors = ();
 777   $print_form->throw_on_error(sub {
 778     eval {
 779       $print_form->prepare_for_printing;
 780
 781       $$pdf_ref = SL::Helper::CreatePDF->create_pdf(
 782         template  => SL::Helper::CreatePDF->find_template(name => $print_form->{formname}),
 783         variables => $print_form,
 784         variable_content_types => {
 785           longdescription => 'html',
 786           partnotes       => 'html',
 787           notes           => 'html',
 788         },
 789       );
 790       1;
 791     } || push @errors, ref($EVAL_ERROR) eq 'SL::X::FormError' ? $EVAL_ERROR->getMessage : $EVAL_ERROR;
 792   });
 793
 794   return @errors;
 795 }
 796
 797 sub _sales_order_type {
 798   'sales_order';
 799 }
 800
 801 sub _purchase_order_type {
 802   'purchase_order';
 803 }
 804
 805 1;
 806
 807 __END__
 808
 809 =encoding utf-8
 810
 811 =head1 NAME
 812
 813 SL::Controller::Order - controller for orders
 814
 815 =head1 TODO
 816
 817 Testing, PriceSources, pricefactor, units, currency, delivered, delivery order created, ...
 818
 819 =head1 AUTHOR
 820
 821 Bernd Bleßmann E<lt>bernd@kivitendo-premium.deE<gt>
 822
 823 =cut
 824