SL/Controller/Order.pm

   1 package SL::Controller::Order;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use SL::Helper::Flash qw(flash_later);
   7 use SL::Presenter::Tag qw(select_tag hidden_tag div_tag);
   8 use SL::Locale::String qw(t8);
   9 use SL::SessionFile::Random;
  10 use SL::PriceSource;
  11 use SL::Webdav;
  12 use SL::File;
  13 use SL::MIME;
  14 use SL::Util qw(trim);
  15 use SL::YAML;
  16 use SL::DB::Order;
  17 use SL::DB::Default;
  18 use SL::DB::Unit;
  19 use SL::DB::Part;
  20 use SL::DB::PartsGroup;
  21 use SL::DB::Printer;
  22 use SL::DB::Language;
  23 use SL::DB::RecordLink;
  24 use SL::DB::Shipto;
  25 use SL::DB::Translation;
  26
  27 use SL::Helper::CreatePDF qw(:all);
  28 use SL::Helper::PrintOptions;
  29 use SL::Helper::ShippedQty;
  30 use SL::Helper::UserPreferences::PositionsScrollbar;
  31 use SL::Helper::UserPreferences::UpdatePositions;
  32
  33 use SL::Controller::Helper::GetModels;
  34
  35 use List::Util qw(first sum0);
  36 use List::UtilsBy qw(sort_by uniq_by);
  37 use List::MoreUtils qw(any none pairwise first_index);
  38 use English qw(-no_match_vars);
  39 use File::Spec;
  40 use Cwd;
  41 use Sort::Naturally;
  42
  43 use Rose::Object::MakeMethods::Generic
  44 (
  45  scalar => [ qw(item_ids_to_delete is_custom_shipto_to_delete) ],
  46  'scalar --get_set_init' => [ qw(order valid_types type cv p all_price_factors search_cvpartnumber show_update_button) ],
  47 );
  48
  49
  50 # safety
  51 __PACKAGE__->run_before('check_auth');
  52
  53 __PACKAGE__->run_before('recalc',
  54                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice save_and_ap_transaction
  55                                      print send_email) ]);
  56
  57 __PACKAGE__->run_before('get_unalterable_data',
  58                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice save_and_ap_transaction
  59                                      print send_email) ]);
  60
  61 #
  62 # actions
  63 #
  64
  65 # add a new order
  66 sub action_add {
  67   my ($self) = @_;
  68
  69   $self->order->transdate(DateTime->now_local());
  70   my $extra_days = $self->{type} eq 'sales_quotation' ? $::instance_conf->get_reqdate_interval       :
  71                    $self->{type} eq 'sales_order'     ? $::instance_conf->get_delivery_date_interval : 1;
  72   $self->order->reqdate(DateTime->today_local->next_workday(extra_days => $extra_days)) if !$self->order->reqdate;
  73
  74
  75   $self->pre_render();
  76   $self->render(
  77     'order/form',
  78     title => $self->get_title_for('add'),
  79     %{$self->{template_args}}
  80   );
  81 }
  82
  83 # edit an existing order
  84 sub action_edit {
  85   my ($self) = @_;
  86
  87   if ($::form->{id}) {
  88     $self->load_order;
  89
  90   } else {
  91     # this is to edit an order from an unsaved order object
  92
  93     # set item ids to new fake id, to identify them as new items
  94     foreach my $item (@{$self->order->items_sorted}) {
  95       $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
  96     }
  97     # trigger rendering values for second row as hidden, because they
  98     # are loaded only on demand. So we need to keep the values from
  99     # the source.
 100     $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
 101   }
 102
 103   $self->recalc();
 104   $self->pre_render();
 105   $self->render(
 106     'order/form',
 107     title => $self->get_title_for('edit'),
 108     %{$self->{template_args}}
 109   );
 110 }
 111
 112 # edit a collective order (consisting of one or more existing orders)
 113 sub action_edit_collective {
 114   my ($self) = @_;
 115
 116   # collect order ids
 117   my @multi_ids = map {
 118     $_ =~ m{^multi_id_(\d+)$} && $::form->{'multi_id_' . $1} && $::form->{'trans_id_' . $1} && $::form->{'trans_id_' . $1}
 119   } grep { $_ =~ m{^multi_id_\d+$} } keys %$::form;
 120
 121   # fall back to add if no ids are given
 122   if (scalar @multi_ids == 0) {
 123     $self->action_add();
 124     return;
 125   }
 126
 127   # fall back to save as new if only one id is given
 128   if (scalar @multi_ids == 1) {
 129     $self->order(SL::DB::Order->new(id => $multi_ids[0])->load);
 130     $self->action_save_as_new();
 131     return;
 132   }
 133
 134   # make new order from given orders
 135   my @multi_orders = map { SL::DB::Order->new(id => $_)->load } @multi_ids;
 136   $self->{converted_from_oe_id} = join ' ', map { $_->id } @multi_orders;
 137   $self->order(SL::DB::Order->new_from_multi(\@multi_orders, sort_sources_by => 'transdate'));
 138
 139   $self->action_edit();
 140 }
 141
 142 # delete the order
 143 sub action_delete {
 144   my ($self) = @_;
 145
 146   my $errors = $self->delete();
 147
 148   if (scalar @{ $errors }) {
 149     $self->js->flash('error', $_) foreach @{ $errors };
 150     return $self->js->render();
 151   }
 152
 153   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been deleted')
 154            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been deleted')
 155            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been deleted')
 156            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been deleted')
 157            : '';
 158   flash_later('info', $text);
 159
 160   my @redirect_params = (
 161     action => 'add',
 162     type   => $self->type,
 163   );
 164
 165   $self->redirect_to(@redirect_params);
 166 }
 167
 168 # save the order
 169 sub action_save {
 170   my ($self) = @_;
 171
 172   my $errors = $self->save();
 173
 174   if (scalar @{ $errors }) {
 175     $self->js->flash('error', $_) foreach @{ $errors };
 176     return $self->js->render();
 177   }
 178
 179   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
 180            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
 181            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
 182            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
 183            : '';
 184   flash_later('info', $text);
 185
 186   my @redirect_params = (
 187     action => 'edit',
 188     type   => $self->type,
 189     id     => $self->order->id,
 190   );
 191
 192   $self->redirect_to(@redirect_params);
 193 }
 194
 195 # save the order as new document an open it for edit
 196 sub action_save_as_new {
 197   my ($self) = @_;
 198
 199   my $order = $self->order;
 200
 201   if (!$order->id) {
 202     $self->js->flash('error', t8('This object has not been saved yet.'));
 203     return $self->js->render();
 204   }
 205
 206   # load order from db to check if values changed
 207   my $saved_order = SL::DB::Order->new(id => $order->id)->load;
 208
 209   my %new_attrs;
 210   # Lets assign a new number if the user hasn't changed the previous one.
 211   # If it has been changed manually then use it as-is.
 212   $new_attrs{number}    = (trim($order->number) eq $saved_order->number)
 213                         ? ''
 214                         : trim($order->number);
 215
 216   # Clear transdate unless changed
 217   $new_attrs{transdate} = ($order->transdate == $saved_order->transdate)
 218                         ? DateTime->today_local
 219                         : $order->transdate;
 220
 221   # Set new reqdate unless changed
 222   if ($order->reqdate == $saved_order->reqdate) {
 223     my $extra_days = $self->{type} eq 'sales_quotation' ? $::instance_conf->get_reqdate_interval       :
 224                      $self->{type} eq 'sales_order'     ? $::instance_conf->get_delivery_date_interval : 1;
 225     $new_attrs{reqdate} = DateTime->today_local->next_workday(extra_days => $extra_days);
 226   } else {
 227     $new_attrs{reqdate} = $order->reqdate;
 228   }
 229
 230   # Update employee
 231   $new_attrs{employee}  = SL::DB::Manager::Employee->current;
 232
 233   # Create new record from current one
 234   $self->order(SL::DB::Order->new_from($order, destination_type => $order->type, attributes => \%new_attrs));
 235
 236   # no linked records on save as new
 237   delete $::form->{$_} for qw(converted_from_oe_id converted_from_orderitems_ids);
 238
 239   # save
 240   $self->action_save();
 241 }
 242
 243 # print the order
 244 #
 245 # This is called if "print" is pressed in the print dialog.
 246 # If PDF creation was requested and succeeded, the pdf is offered for download
 247 # via send_file (which uses ajax in this case).
 248 sub action_print {
 249   my ($self) = @_;
 250
 251   my $errors = $self->save();
 252
 253   if (scalar @{ $errors }) {
 254     $self->js->flash('error', $_) foreach @{ $errors };
 255     return $self->js->render();
 256   }
 257
 258   $self->js_reset_order_and_item_ids_after_save;
 259
 260   my $format      = $::form->{print_options}->{format};
 261   my $media       = $::form->{print_options}->{media};
 262   my $formname    = $::form->{print_options}->{formname};
 263   my $copies      = $::form->{print_options}->{copies};
 264   my $groupitems  = $::form->{print_options}->{groupitems};
 265   my $printer_id  = $::form->{print_options}->{printer_id};
 266
 267   # only pdf and opendocument by now
 268   if (none { $format eq $_ } qw(pdf opendocument opendocument_pdf)) {
 269     return $self->js->flash('error', t8('Format \'#1\' is not supported yet/anymore.', $format))->render;
 270   }
 271
 272   # only screen or printer by now
 273   if (none { $media eq $_ } qw(screen printer)) {
 274     return $self->js->flash('error', t8('Media \'#1\' is not supported yet/anymore.', $media))->render;
 275   }
 276
 277   # create a form for generate_attachment_filename
 278   my $form   = Form->new;
 279   $form->{$self->nr_key()}  = $self->order->number;
 280   $form->{type}             = $self->type;
 281   $form->{format}           = $format;
 282   $form->{formname}         = $formname;
 283   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 284   my $pdf_filename          = $form->generate_attachment_filename();
 285
 286   my $pdf;
 287   my @errors = generate_pdf($self->order, \$pdf, { format     => $format,
 288                                                    formname   => $formname,
 289                                                    language   => $self->order->language,
 290                                                    printer_id => $printer_id,
 291                                                    groupitems => $groupitems });
 292   if (scalar @errors) {
 293     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render;
 294   }
 295
 296   if ($media eq 'screen') {
 297     # screen/download
 298     $self->js->flash('info', t8('The PDF has been created'));
 299     $self->send_file(
 300       \$pdf,
 301       type         => SL::MIME->mime_type_from_ext($pdf_filename),
 302       name         => $pdf_filename,
 303       js_no_render => 1,
 304     );
 305
 306   } elsif ($media eq 'printer') {
 307     # printer
 308     my $printer_id = $::form->{print_options}->{printer_id};
 309     SL::DB::Printer->new(id => $printer_id)->load->print_document(
 310       copies  => $copies,
 311       content => $pdf,
 312     );
 313
 314     $self->js->flash('info', t8('The PDF has been printed'));
 315   }
 316
 317   # copy file to webdav folder
 318   if ($self->order->number && $::instance_conf->get_webdav_documents) {
 319     my $webdav = SL::Webdav->new(
 320       type     => $self->type,
 321       number   => $self->order->number,
 322     );
 323     my $webdav_file = SL::Webdav::File->new(
 324       webdav   => $webdav,
 325       filename => $pdf_filename,
 326     );
 327     eval {
 328       $webdav_file->store(data => \$pdf);
 329       1;
 330     } or do {
 331       $self->js->flash('error', t8('Storing PDF to webdav folder failed: #1', $@));
 332     }
 333   }
 334   if ($self->order->number && $::instance_conf->get_doc_storage) {
 335     eval {
 336       SL::File->save(object_id     => $self->order->id,
 337                      object_type   => $self->type,
 338                      mime_type     => 'application/pdf',
 339                      source        => 'created',
 340                      file_type     => 'document',
 341                      file_name     => $pdf_filename,
 342                      file_contents => $pdf);
 343       1;
 344     } or do {
 345       $self->js->flash('error', t8('Storing PDF in storage backend failed: #1', $@));
 346     }
 347   }
 348   $self->js->render;
 349 }
 350
 351 # open the email dialog
 352 sub action_save_and_show_email_dialog {
 353   my ($self) = @_;
 354
 355   my $errors = $self->save();
 356
 357   if (scalar @{ $errors }) {
 358     $self->js->flash('error', $_) foreach @{ $errors };
 359     return $self->js->render();
 360   }
 361
 362   my $cv_method = $self->cv;
 363
 364   if (!$self->order->$cv_method) {
 365     return $self->js->flash('error', $self->cv eq 'customer' ? t8('Cannot send E-mail without customer given') : t8('Cannot send E-mail without vendor given'))
 366                     ->render($self);
 367   }
 368
 369   my $email_form;
 370   $email_form->{to}   = $self->order->contact->cp_email if $self->order->contact;
 371   $email_form->{to} ||= $self->order->$cv_method->email;
 372   $email_form->{cc}   = $self->order->$cv_method->cc;
 373   $email_form->{bcc}  = join ', ', grep $_, $self->order->$cv_method->bcc, SL::DB::Default->get->global_bcc;
 374   # Todo: get addresses from shipto, if any
 375
 376   my $form = Form->new;
 377   $form->{$self->nr_key()}  = $self->order->number;
 378   $form->{cusordnumber}     = $self->order->cusordnumber;
 379   $form->{formname}         = $self->type;
 380   $form->{type}             = $self->type;
 381   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 382   $form->{language_id}      = $self->order->language->id                  if $self->order->language;
 383   $form->{format}           = 'pdf';
 384
 385   $email_form->{subject}             = $form->generate_email_subject();
 386   $email_form->{attachment_filename} = $form->generate_attachment_filename();
 387   $email_form->{message}             = $form->generate_email_body();
 388   $email_form->{js_send_function}    = 'kivi.Order.send_email()';
 389
 390   my %files = $self->get_files_for_email_dialog();
 391   my $dialog_html = $self->render('common/_send_email_dialog', { output => 0 },
 392                                   email_form  => $email_form,
 393                                   show_bcc    => $::auth->assert('email_bcc', 'may fail'),
 394                                   FILES       => \%files,
 395                                   is_customer => $self->cv eq 'customer',
 396   );
 397
 398   $self->js
 399       ->run('kivi.Order.show_email_dialog', $dialog_html)
 400       ->reinit_widgets
 401       ->render($self);
 402 }
 403
 404 # send email
 405 #
 406 # Todo: handling error messages: flash is not displayed in dialog, but in the main form
 407 sub action_send_email {
 408   my ($self) = @_;
 409
 410   my $errors = $self->save();
 411
 412   if (scalar @{ $errors }) {
 413     $self->js->run('kivi.Order.close_email_dialog');
 414     $self->js->flash('error', $_) foreach @{ $errors };
 415     return $self->js->render();
 416   }
 417
 418   $self->js_reset_order_and_item_ids_after_save;
 419
 420   my $email_form  = delete $::form->{email_form};
 421   my %field_names = (to => 'email');
 422
 423   $::form->{ $field_names{$_} // $_ } = $email_form->{$_} for keys %{ $email_form };
 424
 425   # for Form::cleanup which may be called in Form::send_email
 426   $::form->{cwd}    = getcwd();
 427   $::form->{tmpdir} = $::lx_office_conf{paths}->{userspath};
 428
 429   $::form->{$_}     = $::form->{print_options}->{$_} for keys %{ $::form->{print_options} };
 430   $::form->{media}  = 'email';
 431
 432   if (($::form->{attachment_policy} // '') !~ m{^(?:old_file|no_file)$}) {
 433     my $pdf;
 434     my @errors = generate_pdf($self->order, \$pdf, {media      => $::form->{media},
 435                                                     format     => $::form->{print_options}->{format},
 436                                                     formname   => $::form->{print_options}->{formname},
 437                                                     language   => $self->order->language,
 438                                                     printer_id => $::form->{print_options}->{printer_id},
 439                                                     groupitems => $::form->{print_options}->{groupitems}});
 440     if (scalar @errors) {
 441       return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render($self);
 442     }
 443
 444     my $sfile = SL::SessionFile::Random->new(mode => "w");
 445     $sfile->fh->print($pdf);
 446     $sfile->fh->close;
 447
 448     $::form->{tmpfile} = $sfile->file_name;
 449     $::form->{tmpdir}  = $sfile->get_path; # for Form::cleanup which may be called in Form::send_email
 450   }
 451
 452   $::form->{id} = $self->order->id; # this is used in SL::Mailer to create a linked record to the mail
 453   $::form->send_email(\%::myconfig, 'pdf');
 454
 455   # internal notes
 456   my $intnotes = $self->order->intnotes;
 457   $intnotes   .= "\n\n" if $self->order->intnotes;
 458   $intnotes   .= t8('[email]')                                                                                        . "\n";
 459   $intnotes   .= t8('Date')       . ": " . $::locale->format_date_object(DateTime->now_local, precision => 'seconds') . "\n";
 460   $intnotes   .= t8('To (email)') . ": " . $::form->{email}                                                           . "\n";
 461   $intnotes   .= t8('Cc')         . ": " . $::form->{cc}                                                              . "\n"    if $::form->{cc};
 462   $intnotes   .= t8('Bcc')        . ": " . $::form->{bcc}                                                             . "\n"    if $::form->{bcc};
 463   $intnotes   .= t8('Subject')    . ": " . $::form->{subject}                                                         . "\n\n";
 464   $intnotes   .= t8('Message')    . ": " . $::form->{message};
 465
 466   $self->order->update_attributes(intnotes => $intnotes);
 467
 468   flash_later('info', t8('The email has been sent.'));
 469
 470   my @redirect_params = (
 471     action => 'edit',
 472     type   => $self->type,
 473     id     => $self->order->id,
 474   );
 475
 476   $self->redirect_to(@redirect_params);
 477 }
 478
 479 # open the periodic invoices config dialog
 480 #
 481 # If there are values in the form (i.e. dialog was opened before),
 482 # then use this values. Create new ones, else.
 483 sub action_show_periodic_invoices_config_dialog {
 484   my ($self) = @_;
 485
 486   my $config = make_periodic_invoices_config_from_yaml(delete $::form->{config});
 487   $config  ||= SL::DB::Manager::PeriodicInvoicesConfig->find_by(oe_id => $::form->{id}) if $::form->{id};
 488   $config  ||= SL::DB::PeriodicInvoicesConfig->new(periodicity             => 'm',
 489                                                    order_value_periodicity => 'p', # = same as periodicity
 490                                                    start_date_as_date      => $::form->{transdate_as_date} || $::form->current_date,
 491                                                    extend_automatically_by => 12,
 492                                                    active                  => 1,
 493                                                    email_subject           => GenericTranslations->get(
 494                                                                                 language_id      => $::form->{language_id},
 495                                                                                 translation_type =>"preset_text_periodic_invoices_email_subject"),
 496                                                    email_body              => GenericTranslations->get(
 497                                                                                 language_id      => $::form->{language_id},
 498                                                                                 translation_type =>"preset_text_periodic_invoices_email_body"),
 499   );
 500   $config->periodicity('m')             if none { $_ eq $config->periodicity             }       @SL::DB::PeriodicInvoicesConfig::PERIODICITIES;
 501   $config->order_value_periodicity('p') if none { $_ eq $config->order_value_periodicity } ('p', @SL::DB::PeriodicInvoicesConfig::ORDER_VALUE_PERIODICITIES);
 502
 503   $::form->get_lists(printers => "ALL_PRINTERS",
 504                      charts   => { key       => 'ALL_CHARTS',
 505                                    transdate => 'current_date' });
 506
 507   $::form->{AR} = [ grep { $_->{link} =~ m/(?:^|:)AR(?::|$)/ } @{ $::form->{ALL_CHARTS} } ];
 508
 509   if ($::form->{customer_id}) {
 510     $::form->{ALL_CONTACTS} = SL::DB::Manager::Contact->get_all_sorted(where => [ cp_cv_id => $::form->{customer_id} ]);
 511     $::form->{email_recipient_invoice_address} = SL::DB::Manager::Customer->find_by(id => $::form->{customer_id})->invoice_mail;
 512   }
 513
 514   $self->render('oe/edit_periodic_invoices_config', { layout => 0 },
 515                 popup_dialog             => 1,
 516                 popup_js_close_function  => 'kivi.Order.close_periodic_invoices_config_dialog()',
 517                 popup_js_assign_function => 'kivi.Order.assign_periodic_invoices_config()',
 518                 config                   => $config,
 519                 %$::form);
 520 }
 521
 522 # assign the values of the periodic invoices config dialog
 523 # as yaml in the hidden tag and set the status.
 524 sub action_assign_periodic_invoices_config {
 525   my ($self) = @_;
 526
 527   $::form->isblank('start_date_as_date', $::locale->text('The start date is missing.'));
 528
 529   my $config = { active                     => $::form->{active}       ? 1 : 0,
 530                  terminated                 => $::form->{terminated}   ? 1 : 0,
 531                  direct_debit               => $::form->{direct_debit} ? 1 : 0,
 532                  periodicity                => (any { $_ eq $::form->{periodicity}             }       @SL::DB::PeriodicInvoicesConfig::PERIODICITIES)              ? $::form->{periodicity}             : 'm',
 533                  order_value_periodicity    => (any { $_ eq $::form->{order_value_periodicity} } ('p', @SL::DB::PeriodicInvoicesConfig::ORDER_VALUE_PERIODICITIES)) ? $::form->{order_value_periodicity} : 'p',
 534                  start_date_as_date         => $::form->{start_date_as_date},
 535                  end_date_as_date           => $::form->{end_date_as_date},
 536                  first_billing_date_as_date => $::form->{first_billing_date_as_date},
 537                  print                      => $::form->{print}      ? 1                         : 0,
 538                  printer_id                 => $::form->{print}      ? $::form->{printer_id} * 1 : undef,
 539                  copies                     => $::form->{copies} * 1 ? $::form->{copies}         : 1,
 540                  extend_automatically_by    => $::form->{extend_automatically_by}    * 1 || undef,
 541                  ar_chart_id                => $::form->{ar_chart_id} * 1,
 542                  send_email                 => $::form->{send_email} ? 1 : 0,
 543                  email_recipient_contact_id => $::form->{email_recipient_contact_id} * 1 || undef,
 544                  email_recipient_address    => $::form->{email_recipient_address},
 545                  email_sender               => $::form->{email_sender},
 546                  email_subject              => $::form->{email_subject},
 547                  email_body                 => $::form->{email_body},
 548                };
 549
 550   my $periodic_invoices_config = SL::YAML::Dump($config);
 551
 552   my $status = $self->get_periodic_invoices_status($config);
 553
 554   $self->js
 555     ->remove('#order_periodic_invoices_config')
 556     ->insertAfter(hidden_tag('order.periodic_invoices_config', $periodic_invoices_config), '#periodic_invoices_status')
 557     ->run('kivi.Order.close_periodic_invoices_config_dialog')
 558     ->html('#periodic_invoices_status', $status)
 559     ->flash('info', t8('The periodic invoices config has been assigned.'))
 560     ->render($self);
 561 }
 562
 563 sub action_get_has_active_periodic_invoices {
 564   my ($self) = @_;
 565
 566   my $config = make_periodic_invoices_config_from_yaml(delete $::form->{config});
 567   $config  ||= SL::DB::Manager::PeriodicInvoicesConfig->find_by(oe_id => $::form->{id}) if $::form->{id};
 568
 569   my $has_active_periodic_invoices =
 570        $self->type eq sales_order_type()
 571     && $config
 572     && $config->active
 573     && (!$config->end_date || ($config->end_date > DateTime->today_local))
 574     && $config->get_previous_billed_period_start_date;
 575
 576   $_[0]->render(\ !!$has_active_periodic_invoices, { type => 'text' });
 577 }
 578
 579 # save the order and redirect to the frontend subroutine for a new
 580 # delivery order
 581 sub action_save_and_delivery_order {
 582   my ($self) = @_;
 583
 584   $self->save_and_redirect_to(
 585     controller => 'oe.pl',
 586     action     => 'oe_delivery_order_from_order',
 587   );
 588 }
 589
 590 # save the order and redirect to the frontend subroutine for a new
 591 # invoice
 592 sub action_save_and_invoice {
 593   my ($self) = @_;
 594
 595   $self->save_and_redirect_to(
 596     controller => 'oe.pl',
 597     action     => 'oe_invoice_from_order',
 598   );
 599 }
 600
 601 # workflow from sales quotation to sales order
 602 sub action_sales_order {
 603   $_[0]->workflow_sales_or_purchase_order();
 604 }
 605
 606 # workflow from rfq to purchase order
 607 sub action_purchase_order {
 608   $_[0]->workflow_sales_or_purchase_order();
 609 }
 610
 611 # workflow from purchase order to ap transaction
 612 sub action_save_and_ap_transaction {
 613   my ($self) = @_;
 614
 615   $self->save_and_redirect_to(
 616     controller => 'ap.pl',
 617     action     => 'add_from_purchase_order',
 618   );
 619 }
 620
 621 # set form elements in respect to a changed customer or vendor
 622 #
 623 # This action is called on an change of the customer/vendor picker.
 624 sub action_customer_vendor_changed {
 625   my ($self) = @_;
 626
 627   setup_order_from_cv($self->order);
 628   $self->recalc();
 629
 630   my $cv_method = $self->cv;
 631
 632   if ($self->order->$cv_method->contacts && scalar @{ $self->order->$cv_method->contacts } > 0) {
 633     $self->js->show('#cp_row');
 634   } else {
 635     $self->js->hide('#cp_row');
 636   }
 637
 638   if ($self->order->$cv_method->shipto && scalar @{ $self->order->$cv_method->shipto } > 0) {
 639     $self->js->show('#shipto_selection');
 640   } else {
 641     $self->js->hide('#shipto_selection');
 642   }
 643
 644   $self->js->val( '#order_salesman_id',      $self->order->salesman_id)        if $self->order->is_sales;
 645
 646   $self->js
 647     ->replaceWith('#order_cp_id',            $self->build_contact_select)
 648     ->replaceWith('#order_shipto_id',        $self->build_shipto_select)
 649     ->replaceWith('#shipto_inputs  ',        $self->build_shipto_inputs)
 650     ->replaceWith('#business_info_row',      $self->build_business_info_row)
 651     ->val(        '#order_taxzone_id',       $self->order->taxzone_id)
 652     ->val(        '#order_taxincluded',      $self->order->taxincluded)
 653     ->val(        '#order_currency_id',      $self->order->currency_id)
 654     ->val(        '#order_payment_id',       $self->order->payment_id)
 655     ->val(        '#order_delivery_term_id', $self->order->delivery_term_id)
 656     ->val(        '#order_intnotes',         $self->order->intnotes)
 657     ->val(        '#order_language_id',      $self->order->$cv_method->language_id)
 658     ->focus(      '#order_' . $self->cv . '_id')
 659     ->run('kivi.Order.update_exchangerate');
 660
 661   $self->js_redisplay_amounts_and_taxes;
 662   $self->js_redisplay_cvpartnumbers;
 663   $self->js->render();
 664 }
 665
 666 # open the dialog for customer/vendor details
 667 sub action_show_customer_vendor_details_dialog {
 668   my ($self) = @_;
 669
 670   my $is_customer = 'customer' eq $::form->{vc};
 671   my $cv;
 672   if ($is_customer) {
 673     $cv = SL::DB::Customer->new(id => $::form->{vc_id})->load;
 674   } else {
 675     $cv = SL::DB::Vendor->new(id => $::form->{vc_id})->load;
 676   }
 677
 678   my %details = map { $_ => $cv->$_ } @{$cv->meta->columns};
 679   $details{discount_as_percent} = $cv->discount_as_percent;
 680   $details{creditlimt}          = $cv->creditlimit_as_number;
 681   $details{business}            = $cv->business->description      if $cv->business;
 682   $details{language}            = $cv->language_obj->description  if $cv->language_obj;
 683   $details{delivery_terms}      = $cv->delivery_term->description if $cv->delivery_term;
 684   $details{payment_terms}       = $cv->payment->description       if $cv->payment;
 685   $details{pricegroup}          = $cv->pricegroup->pricegroup     if $is_customer && $cv->pricegroup;
 686
 687   foreach my $entry (@{ $cv->shipto }) {
 688     push @{ $details{SHIPTO} },   { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 689   }
 690   foreach my $entry (@{ $cv->contacts }) {
 691     push @{ $details{CONTACTS} }, { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 692   }
 693
 694   $_[0]->render('common/show_vc_details', { layout => 0 },
 695                 is_customer => $is_customer,
 696                 %details);
 697
 698 }
 699
 700 # called if a unit in an existing item row is changed
 701 sub action_unit_changed {
 702   my ($self) = @_;
 703
 704   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 705   my $item = $self->order->items_sorted->[$idx];
 706
 707   my $old_unit_obj = SL::DB::Unit->new(name => $::form->{old_unit})->load;
 708   $item->sellprice($item->unit_obj->convert_to($item->sellprice, $old_unit_obj));
 709
 710   $self->recalc();
 711
 712   $self->js
 713     ->run('kivi.Order.update_sellprice', $::form->{item_id}, $item->sellprice_as_number);
 714   $self->js_redisplay_line_values;
 715   $self->js_redisplay_amounts_and_taxes;
 716   $self->js->render();
 717 }
 718
 719 # add an item row for a new item entered in the input row
 720 sub action_add_item {
 721   my ($self) = @_;
 722
 723   my $form_attr = $::form->{add_item};
 724
 725   return unless $form_attr->{parts_id};
 726
 727   my $item = new_item($self->order, $form_attr);
 728
 729   $self->order->add_items($item);
 730
 731   $self->recalc();
 732
 733   $self->get_item_cvpartnumber($item);
 734
 735   my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 736   my $row_as_html = $self->p->render('order/tabs/_row',
 737                                      ITEM => $item,
 738                                      ID   => $item_id,
 739                                      SELF => $self,
 740   );
 741
 742   if ($::form->{insert_before_item_id}) {
 743     $self->js
 744       ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 745   } else {
 746     $self->js
 747       ->append('#row_table_id', $row_as_html);
 748   }
 749
 750   if ( $item->part->is_assortment ) {
 751     $form_attr->{qty_as_number} = 1 unless $form_attr->{qty_as_number};
 752     foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 753       my $attr = { parts_id => $assortment_item->parts_id,
 754                    qty      => $assortment_item->qty * $::form->parse_amount(\%::myconfig, $form_attr->{qty_as_number}), # TODO $form_attr->{unit}
 755                    unit     => $assortment_item->unit,
 756                    description => $assortment_item->part->description,
 757                  };
 758       my $item = new_item($self->order, $attr);
 759
 760       # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 761       $item->discount(1) unless $assortment_item->charge;
 762
 763       $self->order->add_items( $item );
 764       $self->recalc();
 765       $self->get_item_cvpartnumber($item);
 766       my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 767       my $row_as_html = $self->p->render('order/tabs/_row',
 768                                          ITEM => $item,
 769                                          ID   => $item_id,
 770                                          SELF => $self,
 771       );
 772       if ($::form->{insert_before_item_id}) {
 773         $self->js
 774           ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 775       } else {
 776         $self->js
 777           ->append('#row_table_id', $row_as_html);
 778       }
 779     };
 780   };
 781
 782   $self->js
 783     ->val('.add_item_input', '')
 784     ->run('kivi.Order.init_row_handlers')
 785     ->run('kivi.Order.renumber_positions')
 786     ->focus('#add_item_parts_id_name');
 787
 788   $self->js->run('kivi.Order.row_table_scroll_down') if !$::form->{insert_before_item_id};
 789
 790   $self->js_redisplay_amounts_and_taxes;
 791   $self->js->render();
 792 }
 793
 794 # add item rows for multiple items at once
 795 sub action_add_multi_items {
 796   my ($self) = @_;
 797
 798   my @form_attr = grep { $_->{qty_as_number} } @{ $::form->{add_items} };
 799   return $self->js->render() unless scalar @form_attr;
 800
 801   my @items;
 802   foreach my $attr (@form_attr) {
 803     my $item = new_item($self->order, $attr);
 804     push @items, $item;
 805     if ( $item->part->is_assortment ) {
 806       foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 807         my $attr = { parts_id => $assortment_item->parts_id,
 808                      qty      => $assortment_item->qty * $item->qty, # TODO $form_attr->{unit}
 809                      unit     => $assortment_item->unit,
 810                      description => $assortment_item->part->description,
 811                    };
 812         my $item = new_item($self->order, $attr);
 813
 814         # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 815         $item->discount(1) unless $assortment_item->charge;
 816         push @items, $item;
 817       }
 818     }
 819   }
 820   $self->order->add_items(@items);
 821
 822   $self->recalc();
 823
 824   foreach my $item (@items) {
 825     $self->get_item_cvpartnumber($item);
 826     my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 827     my $row_as_html = $self->p->render('order/tabs/_row',
 828                                        ITEM => $item,
 829                                        ID   => $item_id,
 830                                        SELF => $self,
 831     );
 832
 833     if ($::form->{insert_before_item_id}) {
 834       $self->js
 835         ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 836     } else {
 837       $self->js
 838         ->append('#row_table_id', $row_as_html);
 839     }
 840   }
 841
 842   $self->js
 843     ->run('kivi.Part.close_picker_dialogs')
 844     ->run('kivi.Order.init_row_handlers')
 845     ->run('kivi.Order.renumber_positions')
 846     ->focus('#add_item_parts_id_name');
 847
 848   $self->js->run('kivi.Order.row_table_scroll_down') if !$::form->{insert_before_item_id};
 849
 850   $self->js_redisplay_amounts_and_taxes;
 851   $self->js->render();
 852 }
 853
 854 # recalculate all linetotals, amounts and taxes and redisplay them
 855 sub action_recalc_amounts_and_taxes {
 856   my ($self) = @_;
 857
 858   $self->recalc();
 859
 860   $self->js_redisplay_line_values;
 861   $self->js_redisplay_amounts_and_taxes;
 862   $self->js->render();
 863 }
 864
 865 sub action_update_exchangerate {
 866   my ($self) = @_;
 867
 868   my $data = {
 869     is_standard   => $self->order->currency_id == $::instance_conf->get_currency_id,
 870     currency_name => $self->order->currency->name,
 871     exchangerate  => $self->order->daily_exchangerate_as_null_number,
 872   };
 873
 874   $self->render(\SL::JSON::to_json($data), { type => 'json', process => 0 });
 875 }
 876
 877 # redisplay item rows if they are sorted by an attribute
 878 sub action_reorder_items {
 879   my ($self) = @_;
 880
 881   my %sort_keys = (
 882     partnumber   => sub { $_[0]->part->partnumber },
 883     description  => sub { $_[0]->description },
 884     qty          => sub { $_[0]->qty },
 885     sellprice    => sub { $_[0]->sellprice },
 886     discount     => sub { $_[0]->discount },
 887     cvpartnumber => sub { $_[0]->{cvpartnumber} },
 888   );
 889
 890   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
 891
 892   my $method = $sort_keys{$::form->{order_by}};
 893   my @to_sort = map { { old_pos => $_->position, order_by => $method->($_) } } @{ $self->order->items_sorted };
 894   if ($::form->{sort_dir}) {
 895     if ( $::form->{order_by} =~ m/qty|sellprice|discount/ ){
 896       @to_sort = sort { $a->{order_by} <=> $b->{order_by} } @to_sort;
 897     } else {
 898       @to_sort = sort { $a->{order_by} cmp $b->{order_by} } @to_sort;
 899     }
 900   } else {
 901     if ( $::form->{order_by} =~ m/qty|sellprice|discount/ ){
 902       @to_sort = sort { $b->{order_by} <=> $a->{order_by} } @to_sort;
 903     } else {
 904       @to_sort = sort { $b->{order_by} cmp $a->{order_by} } @to_sort;
 905     }
 906   }
 907   $self->js
 908     ->run('kivi.Order.redisplay_items', \@to_sort)
 909     ->render;
 910 }
 911
 912 # show the popup to choose a price/discount source
 913 sub action_price_popup {
 914   my ($self) = @_;
 915
 916   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 917   my $item = $self->order->items_sorted->[$idx];
 918
 919   $self->render_price_dialog($item);
 920 }
 921
 922 # load the second row for one or more items
 923 #
 924 # This action gets the html code for all items second rows by rendering a template for
 925 # the second row and sets the html code via client js.
 926 sub action_load_second_rows {
 927   my ($self) = @_;
 928
 929   $self->recalc() if $self->order->is_sales; # for margin calculation
 930
 931   foreach my $item_id (@{ $::form->{item_ids} }) {
 932     my $idx  = first_index { $_ eq $item_id } @{ $::form->{orderitem_ids} };
 933     my $item = $self->order->items_sorted->[$idx];
 934
 935     $self->js_load_second_row($item, $item_id, 0);
 936   }
 937
 938   $self->js->run('kivi.Order.init_row_handlers') if $self->order->is_sales; # for lastcosts change-callback
 939
 940   $self->js->render();
 941 }
 942
 943 # update description, notes and sellprice from master data
 944 sub action_update_row_from_master_data {
 945   my ($self) = @_;
 946
 947   foreach my $item_id (@{ $::form->{item_ids} }) {
 948     my $idx   = first_index { $_ eq $item_id } @{ $::form->{orderitem_ids} };
 949     my $item  = $self->order->items_sorted->[$idx];
 950     my $texts = get_part_texts($item->part, $self->order->language_id);
 951
 952     $item->description($texts->{description});
 953     $item->longdescription($texts->{longdescription});
 954
 955     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
 956
 957     my $price_src;
 958     if ($item->part->is_assortment) {
 959     # add assortment items with price 0, as the components carry the price
 960       $price_src = $price_source->price_from_source("");
 961       $price_src->price(0);
 962     } else {
 963       $price_src = $price_source->best_price
 964                  ? $price_source->best_price
 965                  : $price_source->price_from_source("");
 966       $price_src->price($::form->round_amount($price_src->price / $self->order->exchangerate, 5)) if $self->order->exchangerate;
 967       $price_src->price(0) if !$price_source->best_price;
 968     }
 969
 970
 971     $item->sellprice($price_src->price);
 972     $item->active_price_source($price_src);
 973
 974     $self->js
 975       ->run('kivi.Order.update_sellprice', $item_id, $item->sellprice_as_number)
 976       ->html('.row_entry:has(#item_' . $item_id . ') [name = "partnumber"] a', $item->part->partnumber)
 977       ->val ('.row_entry:has(#item_' . $item_id . ') [name = "order.orderitems[].description"]', $item->description)
 978       ->val ('.row_entry:has(#item_' . $item_id . ') [name = "order.orderitems[].longdescription"]', $item->longdescription);
 979
 980     if ($self->search_cvpartnumber) {
 981       $self->get_item_cvpartnumber($item);
 982       $self->js->html('.row_entry:has(#item_' . $item_id . ') [name = "cvpartnumber"]', $item->{cvpartnumber});
 983     }
 984   }
 985
 986   $self->recalc();
 987   $self->js_redisplay_line_values;
 988   $self->js_redisplay_amounts_and_taxes;
 989
 990   $self->js->render();
 991 }
 992
 993 sub js_load_second_row {
 994   my ($self, $item, $item_id, $do_parse) = @_;
 995
 996   if ($do_parse) {
 997     # Parse values from form (they are formated while rendering (template)).
 998     # Workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
 999     # This parsing is not necessary at all, if we assure that the second row/cvars are only loaded once.
1000     foreach my $var (@{ $item->cvars_by_config }) {
1001       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
1002     }
1003     $item->parse_custom_variable_values;
1004   }
1005
1006   my $row_as_html = $self->p->render('order/tabs/_second_row', ITEM => $item, TYPE => $self->type);
1007
1008   $self->js
1009     ->html('#second_row_' . $item_id, $row_as_html)
1010     ->data('#second_row_' . $item_id, 'loaded', 1);
1011 }
1012
1013 sub js_redisplay_line_values {
1014   my ($self) = @_;
1015
1016   my $is_sales = $self->order->is_sales;
1017
1018   # sales orders with margins
1019   my @data;
1020   if ($is_sales) {
1021     @data = map {
1022       [
1023        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
1024        $::form->format_amount(\%::myconfig, $_->{marge_total},   2, 0),
1025        $::form->format_amount(\%::myconfig, $_->{marge_percent}, 2, 0),
1026       ]} @{ $self->order->items_sorted };
1027   } else {
1028     @data = map {
1029       [
1030        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
1031       ]} @{ $self->order->items_sorted };
1032   }
1033
1034   $self->js
1035     ->run('kivi.Order.redisplay_line_values', $is_sales, \@data);
1036 }
1037
1038 sub js_redisplay_amounts_and_taxes {
1039   my ($self) = @_;
1040
1041   if (scalar @{ $self->{taxes} }) {
1042     $self->js->show('#taxincluded_row_id');
1043   } else {
1044     $self->js->hide('#taxincluded_row_id');
1045   }
1046
1047   if ($self->order->taxincluded) {
1048     $self->js->hide('#subtotal_row_id');
1049   } else {
1050     $self->js->show('#subtotal_row_id');
1051   }
1052
1053   if ($self->order->is_sales) {
1054     my $is_neg = $self->order->marge_total < 0;
1055     $self->js
1056       ->html('#marge_total_id',   $::form->format_amount(\%::myconfig, $self->order->marge_total,   2))
1057       ->html('#marge_percent_id', $::form->format_amount(\%::myconfig, $self->order->marge_percent, 2))
1058       ->action_if( $is_neg, 'addClass',    '#marge_total_id',        'plus0')
1059       ->action_if( $is_neg, 'addClass',    '#marge_percent_id',      'plus0')
1060       ->action_if( $is_neg, 'addClass',    '#marge_percent_sign_id', 'plus0')
1061       ->action_if(!$is_neg, 'removeClass', '#marge_total_id',        'plus0')
1062       ->action_if(!$is_neg, 'removeClass', '#marge_percent_id',      'plus0')
1063       ->action_if(!$is_neg, 'removeClass', '#marge_percent_sign_id', 'plus0');
1064   }
1065
1066   $self->js
1067     ->html('#netamount_id', $::form->format_amount(\%::myconfig, $self->order->netamount, -2))
1068     ->html('#amount_id',    $::form->format_amount(\%::myconfig, $self->order->amount,    -2))
1069     ->remove('.tax_row')
1070     ->insertBefore($self->build_tax_rows, '#amount_row_id');
1071 }
1072
1073 sub js_redisplay_cvpartnumbers {
1074   my ($self) = @_;
1075
1076   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
1077
1078   my @data = map {[$_->{cvpartnumber}]} @{ $self->order->items_sorted };
1079
1080   $self->js
1081     ->run('kivi.Order.redisplay_cvpartnumbers', \@data);
1082 }
1083
1084 sub js_reset_order_and_item_ids_after_save {
1085   my ($self) = @_;
1086
1087   $self->js
1088     ->val('#id', $self->order->id)
1089     ->val('#converted_from_oe_id', '')
1090     ->val('#order_' . $self->nr_key(), $self->order->number);
1091
1092   my $idx = 0;
1093   foreach my $form_item_id (@{ $::form->{orderitem_ids} }) {
1094     next if !$self->order->items_sorted->[$idx]->id;
1095     next if $form_item_id !~ m{^new};
1096     $self->js
1097       ->val ('[name="orderitem_ids[+]"][value="' . $form_item_id . '"]', $self->order->items_sorted->[$idx]->id)
1098       ->val ('#item_' . $form_item_id, $self->order->items_sorted->[$idx]->id)
1099       ->attr('#item_' . $form_item_id, "id", 'item_' . $self->order->items_sorted->[$idx]->id);
1100   } continue {
1101     $idx++;
1102   }
1103   $self->js->val('[name="converted_from_orderitems_ids[+]"]', '');
1104 }
1105
1106 #
1107 # helpers
1108 #
1109
1110 sub init_valid_types {
1111   [ sales_order_type(), purchase_order_type(), sales_quotation_type(), request_quotation_type() ];
1112 }
1113
1114 sub init_type {
1115   my ($self) = @_;
1116
1117   if (none { $::form->{type} eq $_ } @{$self->valid_types}) {
1118     die "Not a valid type for order";
1119   }
1120
1121   $self->type($::form->{type});
1122 }
1123
1124 sub init_cv {
1125   my ($self) = @_;
1126
1127   my $cv = (any { $self->type eq $_ } (sales_order_type(),    sales_quotation_type()))   ? 'customer'
1128          : (any { $self->type eq $_ } (purchase_order_type(), request_quotation_type())) ? 'vendor'
1129          : die "Not a valid type for order";
1130
1131   return $cv;
1132 }
1133
1134 sub init_search_cvpartnumber {
1135   my ($self) = @_;
1136
1137   my $user_prefs = SL::Helper::UserPreferences::PartPickerSearch->new();
1138   my $search_cvpartnumber;
1139   $search_cvpartnumber = !!$user_prefs->get_sales_search_customer_partnumber() if $self->cv eq 'customer';
1140   $search_cvpartnumber = !!$user_prefs->get_purchase_search_makemodel()        if $self->cv eq 'vendor';
1141
1142   return $search_cvpartnumber;
1143 }
1144
1145 sub init_show_update_button {
1146   my ($self) = @_;
1147
1148   !!SL::Helper::UserPreferences::UpdatePositions->new()->get_show_update_button();
1149 }
1150
1151 sub init_p {
1152   SL::Presenter->get;
1153 }
1154
1155 sub init_order {
1156   $_[0]->make_order;
1157 }
1158
1159 sub init_all_price_factors {
1160   SL::DB::Manager::PriceFactor->get_all;
1161 }
1162
1163 sub check_auth {
1164   my ($self) = @_;
1165
1166   my $right_for = { map { $_ => $_.'_edit' } @{$self->valid_types} };
1167
1168   my $right   = $right_for->{ $self->type };
1169   $right    ||= 'DOES_NOT_EXIST';
1170
1171   $::auth->assert($right);
1172 }
1173
1174 # build the selection box for contacts
1175 #
1176 # Needed, if customer/vendor changed.
1177 sub build_contact_select {
1178   my ($self) = @_;
1179
1180   select_tag('order.cp_id', [ $self->order->{$self->cv}->contacts ],
1181     value_key  => 'cp_id',
1182     title_key  => 'full_name_dep',
1183     default    => $self->order->cp_id,
1184     with_empty => 1,
1185     style      => 'width: 300px',
1186   );
1187 }
1188
1189 # build the selection box for shiptos
1190 #
1191 # Needed, if customer/vendor changed.
1192 sub build_shipto_select {
1193   my ($self) = @_;
1194
1195   select_tag('order.shipto_id',
1196              [ {displayable_id => t8("No/individual shipping address"), shipto_id => ''}, $self->order->{$self->cv}->shipto ],
1197              value_key  => 'shipto_id',
1198              title_key  => 'displayable_id',
1199              default    => $self->order->shipto_id,
1200              with_empty => 0,
1201              style      => 'width: 300px',
1202   );
1203 }
1204
1205 # build the inputs for the cusom shipto dialog
1206 #
1207 # Needed, if customer/vendor changed.
1208 sub build_shipto_inputs {
1209   my ($self) = @_;
1210
1211   my $content = $self->p->render('common/_ship_to_dialog',
1212                                  vc_obj      => $self->order->customervendor,
1213                                  cs_obj      => $self->order->custom_shipto,
1214                                  cvars       => $self->order->custom_shipto->cvars_by_config,
1215                                  id_selector => '#order_shipto_id');
1216
1217   div_tag($content, id => 'shipto_inputs');
1218 }
1219
1220 # render the info line for business
1221 #
1222 # Needed, if customer/vendor changed.
1223 sub build_business_info_row
1224 {
1225   $_[0]->p->render('order/tabs/_business_info_row', SELF => $_[0]);
1226 }
1227
1228 # build the rows for displaying taxes
1229 #
1230 # Called if amounts where recalculated and redisplayed.
1231 sub build_tax_rows {
1232   my ($self) = @_;
1233
1234   my $rows_as_html;
1235   foreach my $tax (sort { $a->{tax}->rate cmp $b->{tax}->rate } @{ $self->{taxes} }) {
1236     $rows_as_html .= $self->p->render('order/tabs/_tax_row', TAX => $tax, TAXINCLUDED => $self->order->taxincluded);
1237   }
1238   return $rows_as_html;
1239 }
1240
1241
1242 sub render_price_dialog {
1243   my ($self, $record_item) = @_;
1244
1245   my $price_source = SL::PriceSource->new(record_item => $record_item, record => $self->order);
1246
1247   $self->js
1248     ->run(
1249       'kivi.io.price_chooser_dialog',
1250       t8('Available Prices'),
1251       $self->render('order/tabs/_price_sources_dialog', { output => 0 }, price_source => $price_source)
1252     )
1253     ->reinit_widgets;
1254
1255 #   if (@errors) {
1256 #     $self->js->text('#dialog_flash_error_content', join ' ', @errors);
1257 #     $self->js->show('#dialog_flash_error');
1258 #   }
1259
1260   $self->js->render;
1261 }
1262
1263 sub load_order {
1264   my ($self) = @_;
1265
1266   return if !$::form->{id};
1267
1268   $self->order(SL::DB::Order->new(id => $::form->{id})->load);
1269
1270   # Add an empty custom shipto to the order, so that the dialog can render the cvar inputs.
1271   # You need a custom shipto object to call cvars_by_config to get the cvars.
1272   $self->order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => [])) if !$self->order->custom_shipto;
1273
1274   return $self->order;
1275 }
1276
1277 # load or create a new order object
1278 #
1279 # And assign changes from the form to this object.
1280 # If the order is loaded from db, check if items are deleted in the form,
1281 # remove them form the object and collect them for removing from db on saving.
1282 # Then create/update items from form (via make_item) and add them.
1283 sub make_order {
1284   my ($self) = @_;
1285
1286   # add_items adds items to an order with no items for saving, but they cannot
1287   # be retrieved via items until the order is saved. Adding empty items to new
1288   # order here solves this problem.
1289   my $order;
1290   $order   = SL::DB::Order->new(id => $::form->{id})->load(with => [ 'orderitems', 'orderitems.part' ]) if $::form->{id};
1291   $order ||= SL::DB::Order->new(orderitems  => [],
1292                                 quotation   => (any { $self->type eq $_ } (sales_quotation_type(), request_quotation_type())),
1293                                 currency_id => $::instance_conf->get_currency_id(),);
1294
1295   my $cv_id_method = $self->cv . '_id';
1296   if (!$::form->{id} && $::form->{$cv_id_method}) {
1297     $order->$cv_id_method($::form->{$cv_id_method});
1298     setup_order_from_cv($order);
1299   }
1300
1301   my $form_orderitems                  = delete $::form->{order}->{orderitems};
1302   my $form_periodic_invoices_config    = delete $::form->{order}->{periodic_invoices_config};
1303
1304   $order->assign_attributes(%{$::form->{order}});
1305
1306   $self->setup_custom_shipto_from_form($order, $::form);
1307
1308   if (my $periodic_invoices_config_attrs = $form_periodic_invoices_config ? SL::YAML::Load($form_periodic_invoices_config) : undef) {
1309     my $periodic_invoices_config = $order->periodic_invoices_config || $order->periodic_invoices_config(SL::DB::PeriodicInvoicesConfig->new);
1310     $periodic_invoices_config->assign_attributes(%$periodic_invoices_config_attrs);
1311   }
1312
1313   # remove deleted items
1314   $self->item_ids_to_delete([]);
1315   foreach my $idx (reverse 0..$#{$order->orderitems}) {
1316     my $item = $order->orderitems->[$idx];
1317     if (none { $item->id == $_->{id} } @{$form_orderitems}) {
1318       splice @{$order->orderitems}, $idx, 1;
1319       push @{$self->item_ids_to_delete}, $item->id;
1320     }
1321   }
1322
1323   my @items;
1324   my $pos = 1;
1325   foreach my $form_attr (@{$form_orderitems}) {
1326     my $item = make_item($order, $form_attr);
1327     $item->position($pos);
1328     push @items, $item;
1329     $pos++;
1330   }
1331   $order->add_items(grep {!$_->id} @items);
1332
1333   return $order;
1334 }
1335
1336 # create or update items from form
1337 #
1338 # Make item objects from form values. For items already existing read from db.
1339 # Create a new item else. And assign attributes.
1340 sub make_item {
1341   my ($record, $attr) = @_;
1342
1343   my $item;
1344   $item = first { $_->id == $attr->{id} } @{$record->items} if $attr->{id};
1345
1346   my $is_new = !$item;
1347
1348   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1349   # they cannot be retrieved via custom_variables until the order/orderitem is
1350   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1351   $item ||= SL::DB::OrderItem->new(custom_variables => []);
1352
1353   $item->assign_attributes(%$attr);
1354
1355   if ($is_new) {
1356     my $texts = get_part_texts($item->part, $record->language_id);
1357     $item->longdescription($texts->{longdescription})              if !defined $attr->{longdescription};
1358     $item->project_id($record->globalproject_id)                   if !defined $attr->{project_id};
1359     $item->lastcost($record->is_sales ? $item->part->lastcost : 0) if !defined $attr->{lastcost_as_number};
1360   }
1361
1362   return $item;
1363 }
1364
1365 # create a new item
1366 #
1367 # This is used to add one item
1368 sub new_item {
1369   my ($record, $attr) = @_;
1370
1371   my $item = SL::DB::OrderItem->new;
1372
1373   # Remove attributes where the user left or set the inputs empty.
1374   # So these attributes will be undefined and we can distinguish them
1375   # from zero later on.
1376   for (qw(qty_as_number sellprice_as_number discount_as_percent)) {
1377     delete $attr->{$_} if $attr->{$_} eq '';
1378   }
1379
1380   $item->assign_attributes(%$attr);
1381
1382   my $part         = SL::DB::Part->new(id => $attr->{parts_id})->load;
1383   my $price_source = SL::PriceSource->new(record_item => $item, record => $record);
1384
1385   $item->unit($part->unit) if !$item->unit;
1386
1387   my $price_src;
1388   if ( $part->is_assortment ) {
1389     # add assortment items with price 0, as the components carry the price
1390     $price_src = $price_source->price_from_source("");
1391     $price_src->price(0);
1392   } elsif (defined $item->sellprice) {
1393     $price_src = $price_source->price_from_source("");
1394     $price_src->price($item->sellprice);
1395   } else {
1396     $price_src = $price_source->best_price
1397                ? $price_source->best_price
1398                : $price_source->price_from_source("");
1399     $price_src->price($::form->round_amount($price_src->price / $record->exchangerate, 5)) if $record->exchangerate;
1400     $price_src->price(0) if !$price_source->best_price;
1401   }
1402
1403   my $discount_src;
1404   if (defined $item->discount) {
1405     $discount_src = $price_source->discount_from_source("");
1406     $discount_src->discount($item->discount);
1407   } else {
1408     $discount_src = $price_source->best_discount
1409                   ? $price_source->best_discount
1410                   : $price_source->discount_from_source("");
1411     $discount_src->discount(0) if !$price_source->best_discount;
1412   }
1413
1414   my %new_attr;
1415   $new_attr{part}                   = $part;
1416   $new_attr{description}            = $part->description     if ! $item->description;
1417   $new_attr{qty}                    = 1.0                    if ! $item->qty;
1418   $new_attr{price_factor_id}        = $part->price_factor_id if ! $item->price_factor_id;
1419   $new_attr{sellprice}              = $price_src->price;
1420   $new_attr{discount}               = $discount_src->discount;
1421   $new_attr{active_price_source}    = $price_src;
1422   $new_attr{active_discount_source} = $discount_src;
1423   $new_attr{longdescription}        = $part->notes           if ! defined $attr->{longdescription};
1424   $new_attr{project_id}             = $record->globalproject_id;
1425   $new_attr{lastcost}               = $record->is_sales ? $part->lastcost : 0;
1426
1427   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1428   # they cannot be retrieved via custom_variables until the order/orderitem is
1429   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1430   $new_attr{custom_variables} = [];
1431
1432   my $texts = get_part_texts($part, $record->language_id, description => $new_attr{description}, longdescription => $new_attr{longdescription});
1433
1434   $item->assign_attributes(%new_attr, %{ $texts });
1435
1436   return $item;
1437 }
1438
1439 sub setup_order_from_cv {
1440   my ($order) = @_;
1441
1442   $order->$_($order->customervendor->$_) for (qw(taxzone_id payment_id delivery_term_id currency_id));
1443
1444   $order->intnotes($order->customervendor->notes);
1445
1446   if ($order->is_sales) {
1447     $order->salesman_id($order->customer->salesman_id || SL::DB::Manager::Employee->current->id);
1448     $order->taxincluded(defined($order->customer->taxincluded_checked)
1449                         ? $order->customer->taxincluded_checked
1450                         : $::myconfig{taxincluded_checked});
1451   }
1452
1453 }
1454
1455 # setup custom shipto from form
1456 #
1457 # The dialog returns form variables starting with 'shipto' and cvars starting
1458 # with 'shiptocvar_'.
1459 # Mark it to be deleted if a shipto from master data is selected
1460 # (i.e. order has a shipto).
1461 # Else, update or create a new custom shipto. If the fields are empty, it
1462 # will not be saved on save.
1463 sub setup_custom_shipto_from_form {
1464   my ($self, $order, $form) = @_;
1465
1466   if ($order->shipto) {
1467     $self->is_custom_shipto_to_delete(1);
1468   } else {
1469     my $custom_shipto = $order->custom_shipto || $order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => []));
1470
1471     my $shipto_cvars  = {map { my ($key) = m{^shiptocvar_(.+)}; $key => delete $form->{$_}} grep { m{^shiptocvar_} } keys %$form};
1472     my $shipto_attrs  = {map {                                  $_   => delete $form->{$_}} grep { m{^shipto}      } keys %$form};
1473
1474     $custom_shipto->assign_attributes(%$shipto_attrs);
1475     $custom_shipto->cvar_by_name($_)->value($shipto_cvars->{$_}) for keys %$shipto_cvars;
1476   }
1477 }
1478
1479 # recalculate prices and taxes
1480 #
1481 # Using the PriceTaxCalculator. Store linetotals in the item objects.
1482 sub recalc {
1483   my ($self) = @_;
1484
1485   my %pat = $self->order->calculate_prices_and_taxes();
1486
1487   $self->{taxes} = [];
1488   foreach my $tax_id (keys %{ $pat{taxes_by_tax_id} }) {
1489     my $netamount = sum0 map { $pat{amounts}->{$_}->{amount} } grep { $pat{amounts}->{$_}->{tax_id} == $tax_id } keys %{ $pat{amounts} };
1490
1491     push(@{ $self->{taxes} }, { amount    => $pat{taxes_by_tax_id}->{$tax_id},
1492                                 netamount => $netamount,
1493                                 tax       => SL::DB::Tax->new(id => $tax_id)->load });
1494   }
1495   pairwise { $a->{linetotal} = $b->{linetotal} } @{$self->order->items_sorted}, @{$pat{items}};
1496 }
1497
1498 # get data for saving, printing, ..., that is not changed in the form
1499 #
1500 # Only cvars for now.
1501 sub get_unalterable_data {
1502   my ($self) = @_;
1503
1504   foreach my $item (@{ $self->order->items }) {
1505     # autovivify all cvars that are not in the form (cvars_by_config can do it).
1506     # workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
1507     foreach my $var (@{ $item->cvars_by_config }) {
1508       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
1509     }
1510     $item->parse_custom_variable_values;
1511   }
1512 }
1513
1514 # delete the order
1515 #
1516 # And remove related files in the spool directory
1517 sub delete {
1518   my ($self) = @_;
1519
1520   my $errors = [];
1521   my $db     = $self->order->db;
1522
1523   $db->with_transaction(
1524     sub {
1525       my @spoolfiles = grep { $_ } map { $_->spoolfile } @{ SL::DB::Manager::Status->get_all(where => [ trans_id => $self->order->id ]) };
1526       $self->order->delete;
1527       my $spool = $::lx_office_conf{paths}->{spool};
1528       unlink map { "$spool/$_" } @spoolfiles if $spool;
1529
1530       1;
1531   }) || push(@{$errors}, $db->error);
1532
1533   return $errors;
1534 }
1535
1536 # save the order
1537 #
1538 # And delete items that are deleted in the form.
1539 sub save {
1540   my ($self) = @_;
1541
1542   my $errors = [];
1543   my $db     = $self->order->db;
1544
1545   $db->with_transaction(sub {
1546     # delete custom shipto if it is to be deleted or if it is empty
1547     if ($self->order->custom_shipto && ($self->is_custom_shipto_to_delete || $self->order->custom_shipto->is_empty)) {
1548       $self->order->custom_shipto->delete if $self->order->custom_shipto->shipto_id;
1549       $self->order->custom_shipto(undef);
1550     }
1551
1552     SL::DB::OrderItem->new(id => $_)->delete for @{$self->item_ids_to_delete || []};
1553     $self->order->save(cascade => 1);
1554
1555     # link records
1556     if ($::form->{converted_from_oe_id}) {
1557       my @converted_from_oe_ids = split ' ', $::form->{converted_from_oe_id};
1558       foreach my $converted_from_oe_id (@converted_from_oe_ids) {
1559         my $src = SL::DB::Order->new(id => $converted_from_oe_id)->load;
1560         $src->update_attributes(closed => 1) if $src->type =~ /_quotation$/;
1561         $src->link_to_record($self->order);
1562       }
1563       if (scalar @{ $::form->{converted_from_orderitems_ids} || [] }) {
1564         my $idx = 0;
1565         foreach (@{ $self->order->items_sorted }) {
1566           my $from_id = $::form->{converted_from_orderitems_ids}->[$idx];
1567           next if !$from_id;
1568           SL::DB::RecordLink->new(from_table => 'orderitems',
1569                                   from_id    => $from_id,
1570                                   to_table   => 'orderitems',
1571                                   to_id      => $_->id
1572           )->save;
1573           $idx++;
1574         }
1575       }
1576     }
1577     1;
1578   }) || push(@{$errors}, $db->error);
1579
1580   return $errors;
1581 }
1582
1583 sub workflow_sales_or_purchase_order {
1584   my ($self) = @_;
1585
1586   # always save
1587   my $errors = $self->save();
1588
1589   if (scalar @{ $errors }) {
1590     $self->js->flash('error', $_) foreach @{ $errors };
1591     return $self->js->render();
1592   }
1593
1594   my $destination_type = $::form->{type} eq sales_quotation_type()   ? sales_order_type()
1595                        : $::form->{type} eq request_quotation_type() ? purchase_order_type()
1596                        : $::form->{type} eq purchase_order_type()    ? sales_order_type()
1597                        : $::form->{type} eq sales_order_type()       ? purchase_order_type()
1598                        : '';
1599
1600   # check for direct delivery
1601   # copy shipto in custom shipto (custom shipto will be copied by new_from() in case)
1602   my $custom_shipto;
1603   if (   $::form->{type} eq sales_order_type() && $destination_type eq purchase_order_type()
1604       && $::form->{use_shipto} && $self->order->shipto) {
1605     $custom_shipto = $self->order->shipto->clone('SL::DB::Order');
1606   }
1607
1608   $self->order(SL::DB::Order->new_from($self->order, destination_type => $destination_type));
1609   $self->{converted_from_oe_id} = delete $::form->{id};
1610
1611   # set item ids to new fake id, to identify them as new items
1612   foreach my $item (@{$self->order->items_sorted}) {
1613     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1614   }
1615
1616   if ($::form->{type} eq sales_order_type() && $destination_type eq purchase_order_type()) {
1617     if ($::form->{use_shipto}) {
1618       $self->order->custom_shipto($custom_shipto) if $custom_shipto;
1619     } else {
1620       # remove any custom shipto if not wanted
1621       $self->order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => []));
1622     }
1623   }
1624
1625   # change form type
1626   $::form->{type} = $destination_type;
1627   $self->type($self->init_type);
1628   $self->cv  ($self->init_cv);
1629   $self->check_auth;
1630
1631   $self->recalc();
1632   $self->get_unalterable_data();
1633   $self->pre_render();
1634
1635   # trigger rendering values for second row as hidden, because they
1636   # are loaded only on demand. So we need to keep the values from the
1637   # source.
1638   $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
1639
1640   $self->render(
1641     'order/form',
1642     title => $self->get_title_for('edit'),
1643     %{$self->{template_args}}
1644   );
1645 }
1646
1647
1648 sub pre_render {
1649   my ($self) = @_;
1650
1651   $self->{all_taxzones}               = SL::DB::Manager::TaxZone->get_all_sorted();
1652   $self->{all_currencies}             = SL::DB::Manager::Currency->get_all_sorted();
1653   $self->{all_departments}            = SL::DB::Manager::Department->get_all_sorted();
1654   $self->{all_languages}              = SL::DB::Manager::Language->get_all_sorted();
1655   $self->{all_employees}              = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->employee_id,
1656                                                                                               deleted => 0 ] ],
1657                                                                            sort_by => 'name');
1658   $self->{all_salesmen}               = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->salesman_id,
1659                                                                                               deleted => 0 ] ],
1660                                                                            sort_by => 'name');
1661   $self->{all_payment_terms}          = SL::DB::Manager::PaymentTerm->get_all_sorted(where => [ or => [ id => $self->order->payment_id,
1662                                                                                                         obsolete => 0 ] ]);
1663   $self->{all_delivery_terms}         = SL::DB::Manager::DeliveryTerm->get_all_sorted();
1664   $self->{current_employee_id}        = SL::DB::Manager::Employee->current->id;
1665   $self->{periodic_invoices_status}   = $self->get_periodic_invoices_status($self->order->periodic_invoices_config);
1666   $self->{order_probabilities}        = [ map { { title => ($_ * 10) . '%', id => $_ * 10 } } (0..10) ];
1667   $self->{positions_scrollbar_height} = SL::Helper::UserPreferences::PositionsScrollbar->new()->get_height();
1668
1669   my $print_form = Form->new('');
1670   $print_form->{type}        = $self->type;
1671   $print_form->{printers}    = SL::DB::Manager::Printer->get_all_sorted;
1672   $self->{print_options}     = SL::Helper::PrintOptions->get_print_options(
1673     form => $print_form,
1674     options => {dialog_name_prefix => 'print_options.',
1675                 show_headers       => 1,
1676                 no_queue           => 1,
1677                 no_postscript      => 1,
1678                 no_opendocument    => 0,
1679                 no_html            => 1},
1680   );
1681
1682   foreach my $item (@{$self->order->orderitems}) {
1683     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
1684     $item->active_price_source(   $price_source->price_from_source(   $item->active_price_source   ));
1685     $item->active_discount_source($price_source->discount_from_source($item->active_discount_source));
1686   }
1687
1688   if (any { $self->type eq $_ } (sales_order_type(), purchase_order_type())) {
1689     # calculate shipped qtys here to prevent calling calculate for every item via the items method
1690     SL::Helper::ShippedQty->new->calculate($self->order)->write_to_objects;
1691   }
1692
1693   if ($self->order->number && $::instance_conf->get_webdav) {
1694     my $webdav = SL::Webdav->new(
1695       type     => $self->type,
1696       number   => $self->order->number,
1697     );
1698     my @all_objects = $webdav->get_all_objects;
1699     @{ $self->{template_args}->{WEBDAV} } = map { { name => $_->filename,
1700                                                     type => t8('File'),
1701                                                     link => File::Spec->catfile($_->full_filedescriptor),
1702                                                 } } @all_objects;
1703   }
1704
1705   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
1706
1707   $::request->{layout}->use_javascript("${_}.js") for qw(kivi.SalesPurchase kivi.Order kivi.File ckeditor/ckeditor ckeditor/adapters/jquery
1708                                                          edit_periodic_invoices_config calculate_qty kivi.Validator follow_up);
1709   $self->setup_edit_action_bar;
1710 }
1711
1712 sub setup_edit_action_bar {
1713   my ($self, %params) = @_;
1714
1715   my $deletion_allowed = (any { $self->type eq $_ } (sales_quotation_type(), request_quotation_type()))
1716                       || (($self->type eq sales_order_type())    && $::instance_conf->get_sales_order_show_delete)
1717                       || (($self->type eq purchase_order_type()) && $::instance_conf->get_purchase_order_show_delete);
1718
1719   for my $bar ($::request->layout->get('actionbar')) {
1720     $bar->add(
1721       combobox => [
1722         action => [
1723           t8('Save'),
1724           call      => [ 'kivi.Order.save', 'save', $::instance_conf->get_order_warn_duplicate_parts,
1725                                                     $::instance_conf->get_order_warn_no_deliverydate,
1726                                                                                                       ],
1727           checks    => [ 'kivi.Order.check_save_active_periodic_invoices', ['kivi.validate_form','#order_form'] ],
1728         ],
1729         action => [
1730           t8('Save as new'),
1731           call      => [ 'kivi.Order.save', 'save_as_new', $::instance_conf->get_order_warn_duplicate_parts ],
1732           checks    => [ 'kivi.Order.check_save_active_periodic_invoices' ],
1733           disabled  => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1734         ],
1735       ], # end of combobox "Save"
1736
1737       combobox => [
1738         action => [
1739           t8('Workflow'),
1740         ],
1741         action => [
1742           t8('Save and Sales Order'),
1743           submit   => [ '#order_form', { action => "Order/sales_order" } ],
1744           only_if  => (any { $self->type eq $_ } (sales_quotation_type(), purchase_order_type())),
1745         ],
1746         action => [
1747           t8('Save and Purchase Order'),
1748           call      => [ 'kivi.Order.purchase_order_check_for_direct_delivery' ],
1749           only_if   => (any { $self->type eq $_ } (sales_order_type(), request_quotation_type())),
1750         ],
1751         action => [
1752           t8('Save and Delivery Order'),
1753           call      => [ 'kivi.Order.save', 'save_and_delivery_order', $::instance_conf->get_order_warn_duplicate_parts,
1754                                                                        $::instance_conf->get_order_warn_no_deliverydate,
1755                                                                                                                         ],
1756           checks    => [ 'kivi.Order.check_save_active_periodic_invoices' ],
1757           only_if   => (any { $self->type eq $_ } (sales_order_type(), purchase_order_type()))
1758         ],
1759         action => [
1760           t8('Save and Invoice'),
1761           call      => [ 'kivi.Order.save', 'save_and_invoice', $::instance_conf->get_order_warn_duplicate_parts ],
1762           checks    => [ 'kivi.Order.check_save_active_periodic_invoices' ],
1763         ],
1764         action => [
1765           t8('Save and AP Transaction'),
1766           call      => [ 'kivi.Order.save', 'save_and_ap_transaction', $::instance_conf->get_order_warn_duplicate_parts ],
1767           only_if   => (any { $self->type eq $_ } (purchase_order_type()))
1768         ],
1769
1770       ], # end of combobox "Workflow"
1771
1772       combobox => [
1773         action => [
1774           t8('Export'),
1775         ],
1776         action => [
1777           t8('Save and print'),
1778           call => [ 'kivi.Order.show_print_options', $::instance_conf->get_order_warn_duplicate_parts ],
1779         ],
1780         action => [
1781           t8('Save and E-mail'),
1782           call => [ 'kivi.Order.save', 'save_and_show_email_dialog', $::instance_conf->get_order_warn_duplicate_parts ],
1783           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1784         ],
1785         action => [
1786           t8('Download attachments of all parts'),
1787           call     => [ 'kivi.File.downloadOrderitemsFiles', $::form->{type}, $::form->{id} ],
1788           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1789           only_if  => $::instance_conf->get_doc_storage,
1790         ],
1791       ], # end of combobox "Export"
1792
1793       action => [
1794         t8('Delete'),
1795         call     => [ 'kivi.Order.delete_order' ],
1796         confirm  => $::locale->text('Do you really want to delete this object?'),
1797         disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1798         only_if  => $deletion_allowed,
1799       ],
1800
1801       combobox => [
1802         action => [
1803           t8('more')
1804         ],
1805         action => [
1806           t8('Follow-Up'),
1807           call     => [ 'kivi.Order.follow_up_window' ],
1808           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1809           only_if  => $::auth->assert('productivity', 1),
1810         ],
1811       ], # end of combobox "more"
1812     );
1813   }
1814 }
1815
1816 sub generate_pdf {
1817   my ($order, $pdf_ref, $params) = @_;
1818
1819   my @errors = ();
1820
1821   my $print_form = Form->new('');
1822   $print_form->{type}        = $order->type;
1823   $print_form->{formname}    = $params->{formname} || $order->type;
1824   $print_form->{format}      = $params->{format}   || 'pdf';
1825   $print_form->{media}       = $params->{media}    || 'file';
1826   $print_form->{groupitems}  = $params->{groupitems};
1827   $print_form->{printer_id}  = $params->{printer_id};
1828   $print_form->{media}       = 'file'                             if $print_form->{media} eq 'screen';
1829
1830   $order->language($params->{language});
1831   $order->flatten_to_form($print_form, format_amounts => 1);
1832
1833   my $template_ext;
1834   my $template_type;
1835   if ($print_form->{format} =~ /(opendocument|oasis)/i) {
1836     $template_ext  = 'odt';
1837     $template_type = 'OpenDocument';
1838   }
1839
1840   # search for the template
1841   my ($template_file, @template_files) = SL::Helper::CreatePDF->find_template(
1842     name        => $print_form->{formname},
1843     extension   => $template_ext,
1844     email       => $print_form->{media} eq 'email',
1845     language    => $params->{language},
1846     printer_id  => $print_form->{printer_id},
1847   );
1848
1849   if (!defined $template_file) {
1850     push @errors, $::locale->text('Cannot find matching template for this print request. Please contact your template maintainer. I tried these: #1.', join ', ', map { "'$_'"} @template_files);
1851   }
1852
1853   return @errors if scalar @errors;
1854
1855   $print_form->throw_on_error(sub {
1856     eval {
1857       $print_form->prepare_for_printing;
1858
1859       $$pdf_ref = SL::Helper::CreatePDF->create_pdf(
1860         format        => $print_form->{format},
1861         template_type => $template_type,
1862         template      => $template_file,
1863         variables     => $print_form,
1864         variable_content_types => {
1865           longdescription => 'html',
1866           partnotes       => 'html',
1867           notes           => 'html',
1868         },
1869       );
1870       1;
1871     } || push @errors, ref($EVAL_ERROR) eq 'SL::X::FormError' ? $EVAL_ERROR->error : $EVAL_ERROR;
1872   });
1873
1874   return @errors;
1875 }
1876
1877 sub get_files_for_email_dialog {
1878   my ($self) = @_;
1879
1880   my %files = map { ($_ => []) } qw(versions files vc_files part_files);
1881
1882   return %files if !$::instance_conf->get_doc_storage;
1883
1884   if ($self->order->id) {
1885     $files{versions} = [ SL::File->get_all_versions(object_id => $self->order->id,              object_type => $self->order->type, file_type => 'document') ];
1886     $files{files}    = [ SL::File->get_all(         object_id => $self->order->id,              object_type => $self->order->type, file_type => 'attachment') ];
1887     $files{vc_files} = [ SL::File->get_all(         object_id => $self->order->{$self->cv}->id, object_type => $self->cv,          file_type => 'attachment') ];
1888   }
1889
1890   my @parts =
1891     uniq_by { $_->{id} }
1892     map {
1893       +{ id         => $_->part->id,
1894          partnumber => $_->part->partnumber }
1895     } @{$self->order->items_sorted};
1896
1897   foreach my $part (@parts) {
1898     my @pfiles = SL::File->get_all(object_id => $part->{id}, object_type => 'part');
1899     push @{ $files{part_files} }, map { +{ %{ $_ }, partnumber => $part->{partnumber} } } @pfiles;
1900   }
1901
1902   foreach my $key (keys %files) {
1903     $files{$key} = [ sort_by { lc $_->{db_file}->{file_name} } @{ $files{$key} } ];
1904   }
1905
1906   return %files;
1907 }
1908
1909 sub make_periodic_invoices_config_from_yaml {
1910   my ($yaml_config) = @_;
1911
1912   return if !$yaml_config;
1913   my $attr = SL::YAML::Load($yaml_config);
1914   return if 'HASH' ne ref $attr;
1915   return SL::DB::PeriodicInvoicesConfig->new(%$attr);
1916 }
1917
1918
1919 sub get_periodic_invoices_status {
1920   my ($self, $config) = @_;
1921
1922   return                      if $self->type ne sales_order_type();
1923   return t8('not configured') if !$config;
1924
1925   my $active = ('HASH' eq ref $config)                           ? $config->{active}
1926              : ('SL::DB::PeriodicInvoicesConfig' eq ref $config) ? $config->active
1927              :                                                     die "Cannot get status of periodic invoices config";
1928
1929   return $active ? t8('active') : t8('inactive');
1930 }
1931
1932 sub get_title_for {
1933   my ($self, $action) = @_;
1934
1935   return '' if none { lc($action)} qw(add edit);
1936
1937   # for locales:
1938   # $::locale->text("Add Sales Order");
1939   # $::locale->text("Add Purchase Order");
1940   # $::locale->text("Add Quotation");
1941   # $::locale->text("Add Request for Quotation");
1942   # $::locale->text("Edit Sales Order");
1943   # $::locale->text("Edit Purchase Order");
1944   # $::locale->text("Edit Quotation");
1945   # $::locale->text("Edit Request for Quotation");
1946
1947   $action = ucfirst(lc($action));
1948   return $self->type eq sales_order_type()       ? $::locale->text("$action Sales Order")
1949        : $self->type eq purchase_order_type()    ? $::locale->text("$action Purchase Order")
1950        : $self->type eq sales_quotation_type()   ? $::locale->text("$action Quotation")
1951        : $self->type eq request_quotation_type() ? $::locale->text("$action Request for Quotation")
1952        : '';
1953 }
1954
1955 sub get_item_cvpartnumber {
1956   my ($self, $item) = @_;
1957
1958   return if !$self->search_cvpartnumber;
1959   return if !$self->order->customervendor;
1960
1961   if ($self->cv eq 'vendor') {
1962     my @mms = grep { $_->make eq $self->order->customervendor->id } @{$item->part->makemodels};
1963     $item->{cvpartnumber} = $mms[0]->model if scalar @mms;
1964   } elsif ($self->cv eq 'customer') {
1965     my @cps = grep { $_->customer_id eq $self->order->customervendor->id } @{$item->part->customerprices};
1966     $item->{cvpartnumber} = $cps[0]->customer_partnumber if scalar @cps;
1967   }
1968 }
1969
1970 sub get_part_texts {
1971   my ($part_or_id, $language_or_id, %defaults) = @_;
1972
1973   my $part        = ref($part_or_id)     ? $part_or_id         : SL::DB::Part->load_cached($part_or_id);
1974   my $language_id = ref($language_or_id) ? $language_or_id->id : $language_or_id;
1975   my $texts       = {
1976     description     => $defaults{description}     // $part->description,
1977     longdescription => $defaults{longdescription} // $part->notes,
1978   };
1979
1980   return $texts unless $language_id;
1981
1982   my $translation = SL::DB::Manager::Translation->get_first(
1983     where => [
1984       parts_id    => $part->id,
1985       language_id => $language_id,
1986     ]);
1987
1988   $texts->{description}     = $translation->translation     if $translation && $translation->translation;
1989   $texts->{longdescription} = $translation->longdescription if $translation && $translation->longdescription;
1990
1991   return $texts;
1992 }
1993
1994 sub sales_order_type {
1995   'sales_order';
1996 }
1997
1998 sub purchase_order_type {
1999   'purchase_order';
2000 }
2001
2002 sub sales_quotation_type {
2003   'sales_quotation';
2004 }
2005
2006 sub request_quotation_type {
2007   'request_quotation';
2008 }
2009
2010 sub nr_key {
2011   return $_[0]->type eq sales_order_type()       ? 'ordnumber'
2012        : $_[0]->type eq purchase_order_type()    ? 'ordnumber'
2013        : $_[0]->type eq sales_quotation_type()   ? 'quonumber'
2014        : $_[0]->type eq request_quotation_type() ? 'quonumber'
2015        : '';
2016 }
2017
2018 sub save_and_redirect_to {
2019   my ($self, %params) = @_;
2020
2021   my $errors = $self->save();
2022
2023   if (scalar @{ $errors }) {
2024     $self->js->flash('error', $_) foreach @{ $errors };
2025     return $self->js->render();
2026   }
2027
2028   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
2029            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
2030            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
2031            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
2032            : '';
2033   flash_later('info', $text);
2034
2035   $self->redirect_to(%params, id => $self->order->id);
2036 }
2037
2038 1;
2039
2040 __END__
2041
2042 =encoding utf-8
2043
2044 =head1 NAME
2045
2046 SL::Controller::Order - controller for orders
2047
2048 =head1 SYNOPSIS
2049
2050 This is a new form to enter orders, completely rewritten with the use
2051 of controller and java script techniques.
2052
2053 The aim is to provide the user a better experience and a faster workflow. Also
2054 the code should be more readable, more reliable and better to maintain.
2055
2056 =head2 Key Features
2057
2058 =over 4
2059
2060 =item *
2061
2062 One input row, so that input happens every time at the same place.
2063
2064 =item *
2065
2066 Use of pickers where possible.
2067
2068 =item *
2069
2070 Possibility to enter more than one item at once.
2071
2072 =item *
2073
2074 Item list in a scrollable area, so that the workflow buttons stay at
2075 the bottom.
2076
2077 =item *
2078
2079 Reordering item rows with drag and drop is possible. Sorting item rows is
2080 possible (by partnumber, description, qty, sellprice and discount for now).
2081
2082 =item *
2083
2084 No C<update> is necessary. All entries and calculations are managed
2085 with ajax-calls and the page only reloads on C<save>.
2086
2087 =item *
2088
2089 User can see changes immediately, because of the use of java script
2090 and ajax.
2091
2092 =back
2093
2094 =head1 CODE
2095
2096 =head2 Layout
2097
2098 =over 4
2099
2100 =item * C<SL/Controller/Order.pm>
2101
2102 the controller
2103
2104 =item * C<template/webpages/order/form.html>
2105
2106 main form
2107
2108 =item * C<template/webpages/order/tabs/basic_data.html>
2109
2110 Main tab for basic_data.
2111
2112 This is the only tab here for now. "linked records" and "webdav" tabs are
2113 reused from generic code.
2114
2115 =over 4
2116
2117 =item * C<template/webpages/order/tabs/_business_info_row.html>
2118
2119 For displaying information on business type
2120
2121 =item * C<template/webpages/order/tabs/_item_input.html>
2122
2123 The input line for items
2124
2125 =item * C<template/webpages/order/tabs/_row.html>
2126
2127 One row for already entered items
2128
2129 =item * C<template/webpages/order/tabs/_tax_row.html>
2130
2131 Displaying tax information
2132
2133 =item * C<template/webpages/order/tabs/_price_sources_dialog.html>
2134
2135 Dialog for selecting price and discount sources
2136
2137 =back
2138
2139 =item * C<js/kivi.Order.js>
2140
2141 java script functions
2142
2143 =back
2144
2145 =head1 TODO
2146
2147 =over 4
2148
2149 =item * testing
2150
2151 =item * credit limit
2152
2153 =item * more workflows (quotation, rfq)
2154
2155 =item * price sources: little symbols showing better price / better discount
2156
2157 =item * select units in input row?
2158
2159 =item * check for direct delivery (workflow sales order -> purchase order)
2160
2161 =item * access rights
2162
2163 =item * display weights
2164
2165 =item * history
2166
2167 =item * mtime check
2168
2169 =item * optional client/user behaviour
2170
2171 (transactions has to be set - department has to be set -
2172  force project if enabled in client config - transport cost reminder)
2173
2174 =back
2175
2176 =head1 KNOWN BUGS AND CAVEATS
2177
2178 =over 4
2179
2180 =item *
2181
2182 Customer discount is not displayed as a valid discount in price source popup
2183 (this might be a bug in price sources)
2184
2185 (I cannot reproduce this (Bernd))
2186
2187 =item *
2188
2189 No indication that <shift>-up/down expands/collapses second row.
2190
2191 =item *
2192
2193 Inline creation of parts is not currently supported
2194
2195 =item *
2196
2197 Table header is not sticky in the scrolling area.
2198
2199 =item *
2200
2201 Sorting does not include C<position>, neither does reordering.
2202
2203 This behavior was implemented intentionally. But we can discuss, which behavior
2204 should be implemented.
2205
2206 =back
2207
2208 =head1 To discuss / Nice to have
2209
2210 =over 4
2211
2212 =item *
2213
2214 How to expand/collapse second row. Now it can be done clicking the icon or
2215 <shift>-up/down.
2216
2217 =item *
2218
2219 Possibility to select PriceSources in input row?
2220
2221 =item *
2222
2223 This controller uses a (changed) copy of the template for the PriceSource
2224 dialog. Maybe there could be used one code source.
2225
2226 =item *
2227
2228 Rounding-differences between this controller (PriceTaxCalculator) and the old
2229 form. This is not only a problem here, but also in all parts using the PTC.
2230 There exists a ticket and a patch. This patch should be testet.
2231
2232 =item *
2233
2234 An indicator, if the actual inputs are saved (like in an
2235 editor or on text processing application).
2236
2237 =item *
2238
2239 A warning when leaving the page without saveing unchanged inputs.
2240
2241
2242 =back
2243
2244 =head1 AUTHOR
2245
2246 Bernd Bleßmann E<lt>bernd@kivitendo-premium.deE<gt>
2247
2248 =cut