SL/Controller/Order.pm

   1 package SL::Controller::Order;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use SL::Helper::Flash;
   7 use SL::Presenter;
   8 use SL::Locale::String;
   9 use SL::SessionFile::Random;
  10 use SL::PriceSource;
  11 use SL::Form;
  12
  13 use SL::DB::Order;
  14 use SL::DB::Customer;
  15 use SL::DB::Vendor;
  16 use SL::DB::TaxZone;
  17 use SL::DB::Employee;
  18 use SL::DB::Project;
  19 use SL::DB::Default;
  20 use SL::DB::Unit;
  21 use SL::DB::Price;
  22
  23 use SL::Helper::DateTime;
  24 use SL::Helper::CreatePDF qw(:all);
  25
  26 use List::Util qw(max first);
  27 use List::MoreUtils qw(none pairwise first_index);
  28 use English qw(-no_match_vars);
  29 use File::Spec;
  30
  31 use Rose::Object::MakeMethods::Generic
  32 (
  33  'scalar --get_set_init' => [ qw(order valid_types type cv p) ],
  34 );
  35
  36
  37 # safety
  38 __PACKAGE__->run_before('_check_auth');
  39
  40 __PACKAGE__->run_before('_recalc',
  41                         only => [ qw(edit update save save_and_delivery_order create_pdf send_email) ]);
  42
  43 __PACKAGE__->run_before('_get_unalterable_data',
  44                         only => [ qw(save save_and_delivery_order create_pdf send_email) ]);
  45
  46 #
  47 # actions
  48 #
  49
  50 sub action_add {
  51   my ($self) = @_;
  52
  53   $self->order->transdate(DateTime->now_local());
  54
  55   $self->_pre_render();
  56   $self->render(
  57     'order/form',
  58     title => $self->type eq _sales_order_type()    ? $::locale->text('Add Sales Order')
  59            : $self->type eq _purchase_order_type() ? $::locale->text('Add Purchase Order')
  60            : '',
  61     %{$self->{template_args}}
  62   );
  63 }
  64
  65 sub action_edit {
  66   my ($self) = @_;
  67
  68   $self->_pre_render();
  69   $self->render(
  70     'order/form',
  71     title => $self->type eq _sales_order_type()    ? $::locale->text('Edit Sales Order')
  72            : $self->type eq _purchase_order_type() ? $::locale->text('Edit Purchase Order')
  73            : '',
  74     %{$self->{template_args}}
  75   );
  76 }
  77
  78 sub action_update {
  79   my ($self) = @_;
  80
  81   $self->_pre_render();
  82   $self->render(
  83     'order/form',
  84     title => $self->type eq _sales_order_type()    ? $::locale->text('Edit Sales Order')
  85            : $self->type eq _purchase_order_type() ? $::locale->text('Edit Purchase Order')
  86            : '',
  87     %{$self->{template_args}}
  88   );
  89 }
  90
  91 sub action_save {
  92   my ($self) = @_;
  93
  94   my $errors = $self->_save();
  95
  96   if (scalar @{ $errors }) {
  97     $self->js->flash('error', $_) foreach @{ $errors };
  98     return $self->js->render();
  99   }
 100
 101   flash_later('info', $::locale->text('The order has been saved'));
 102   my @redirect_params = (
 103     action => 'edit',
 104     type   => $self->type,
 105     id     => $self->order->id,
 106   );
 107
 108   $self->redirect_to(@redirect_params);
 109 }
 110
 111 sub action_create_pdf {
 112   my ($self) = @_;
 113
 114   my $pdf;
 115   my @errors = _create_pdf($self->order, \$pdf);
 116   if (scalar @errors) {
 117     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render($self);
 118   }
 119
 120   my $sfile = SL::SessionFile::Random->new(mode => "w");
 121   $sfile->fh->print($pdf);
 122   $sfile->fh->close;
 123
 124   my $key = join('_', Time::HiRes::gettimeofday(), int rand 1000000000000);
 125   $::auth->set_session_value("Order::create_pdf-${key}" => $sfile->file_name);
 126
 127   $::form->{formname}  = $self->type;
 128   $::form->{language} = 'de';
 129   my $pdf_filename =  $::form->get_formname_translation . '_' . $self->order->ordnumber . '.pdf';
 130
 131   $self->js
 132     ->run('download_pdf', $pdf_filename, $key)
 133     ->flash('info', t8('The PDF has been created'))->render($self);
 134 }
 135
 136 sub action_download_pdf {
 137   my ($self) = @_;
 138
 139   my $key = $::form->{key};
 140   my $tmp_filename = $::auth->get_session_value("Order::create_pdf-${key}");
 141   return $self->send_file(
 142     $tmp_filename,
 143     type => 'application/pdf',
 144     name => $::form->{pdf_filename},
 145   );
 146 }
 147
 148 sub action_show_email_dialog {
 149   my ($self) = @_;
 150
 151   my $cv_method = $self->cv;
 152
 153   if (!$self->order->$cv_method) {
 154     return $self->js->flash('error', t8('Cannot send E-mail without ' . $self->cv))
 155                     ->render($self);
 156   }
 157
 158   $self->{email}->{to}   = $self->order->contact->cp_email if $self->order->contact;
 159   $self->{email}->{to} ||= $self->order->$cv_method->email;
 160   $self->{email}->{cc}   = $self->order->$cv_method->cc;
 161   $self->{email}->{bcc}  = join ', ', grep $_, $self->order->$cv_method->bcc, SL::DB::Default->get->global_bcc;
 162   # Todo: get addresses from shipto, if any
 163
 164   my $form = Form->new;
 165   $form->{ordnumber} = $self->order->ordnumber;
 166   $form->{formname}  = $self->type;
 167   $form->{type}      = $self->type;
 168   $form->{language} = 'de';
 169   $form->{format}   = 'pdf';
 170
 171   $self->{email}->{subject}             = $form->generate_email_subject();
 172   $self->{email}->{attachment_filename} = $form->generate_attachment_filename();
 173   $self->{email}->{message}             = $form->create_email_signature();
 174
 175   my $dialog_html = $self->render('order/tabs/_email_dialog', { output => 0 });
 176   $self->js
 177       ->run('show_email_dialog', $dialog_html)
 178       ->reinit_widgets
 179       ->render($self);
 180 }
 181
 182 # Todo: handling error messages: flash is not displayed in dialog, but in the main form
 183 sub action_send_email {
 184   my ($self) = @_;
 185
 186   my $mail      = Mailer->new;
 187   $mail->{from} = qq|"$::myconfig{name}" <$::myconfig{email}>|;
 188   $mail->{$_}   = $::form->{email}->{$_} for qw(to cc bcc subject message);
 189
 190   my $pdf;
 191   my @errors = _create_pdf($self->order, \$pdf, {media => 'email'});
 192   if (scalar @errors) {
 193     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render($self);
 194   }
 195
 196   $mail->{attachments} = [{ "content" => $pdf,
 197                             "name"    => $::form->{email}->{attachment_filename} }];
 198
 199   if (my $err = $mail->send) {
 200     return $self->js->flash('error', t8('Sending E-mail: ') . $err)
 201                     ->render($self);
 202   }
 203
 204   # internal notes
 205   my $intnotes = $self->order->intnotes;
 206   $intnotes   .= "\n\n" if $self->order->intnotes;
 207   $intnotes   .= t8('[email]')                                                                                        . "\n";
 208   $intnotes   .= t8('Date')       . ": " . $::locale->format_date_object(DateTime->now_local, precision => 'seconds') . "\n";
 209   $intnotes   .= t8('To (email)') . ": " . $mail->{to}                                                                . "\n";
 210   $intnotes   .= t8('Cc')         . ": " . $mail->{cc}                                                                . "\n"    if $mail->{cc};
 211   $intnotes   .= t8('Bcc')        . ": " . $mail->{bcc}                                                               . "\n"    if $mail->{bcc};
 212   $intnotes   .= t8('Subject')    . ": " . $mail->{subject}                                                           . "\n\n";
 213   $intnotes   .= t8('Message')    . ": " . $mail->{message};
 214
 215   $self->js
 216       ->val('#order_intnotes', $intnotes)
 217       ->run('close_email_dialog')
 218       ->render($self);
 219 }
 220
 221 sub action_save_and_delivery_order {
 222   my ($self) = @_;
 223
 224   my $errors = $self->_save();
 225
 226   if (scalar @{ $errors }) {
 227     $self->js->flash('error', $_) foreach @{ $errors };
 228     return $self->js->render();
 229   }
 230
 231   my $delivery_order = $self->order->convert_to_delivery_order($self->order);
 232
 233   flash_later('info', $::locale->text('The order has been saved'));
 234   my @redirect_params = (
 235     controller => 'do.pl',
 236     action     => 'edit',
 237     type       => $delivery_order->type,
 238     id         => $delivery_order->id,
 239     vc         => $delivery_order->is_sales ? 'customer' : 'vendor',
 240   );
 241
 242   $self->redirect_to(@redirect_params);
 243 }
 244
 245 sub action_customer_vendor_changed {
 246   my ($self) = @_;
 247
 248   my $cv_method = $self->cv;
 249
 250   if ($self->order->$cv_method->contacts && scalar @{ $self->order->$cv_method->contacts } > 0) {
 251     $self->js->show('#cp_row');
 252   } else {
 253     $self->js->hide('#cp_row');
 254   }
 255
 256   if ($self->order->$cv_method->shipto && scalar @{ $self->order->$cv_method->shipto } > 0) {
 257     $self->js->show('#shipto_row');
 258   } else {
 259     $self->js->hide('#shipto_row');
 260   }
 261
 262   $self->order->taxzone_id($self->order->$cv_method->taxzone_id);
 263
 264   if ($self->order->is_sales) {
 265     $self->order->taxincluded(defined($self->order->$cv_method->taxincluded_checked)
 266                               ? $self->order->$cv_method->taxincluded_checked
 267                               : $::myconfig{taxincluded_checked});
 268   }
 269
 270   $self->_recalc();
 271
 272   $self->js
 273     ->replaceWith('#order_cp_id',       $self->build_contact_select)
 274     ->replaceWith('#order_shipto_id',   $self->build_shipto_select)
 275     ->val(        '#order_taxzone_id',  $self->order->taxzone_id)
 276     ->val(        '#order_taxincluded', $self->order->taxincluded)
 277     ->focus(      '#order_' . $self->cv . '_id');
 278
 279   $self->_js_redisplay_amounts_and_taxes;
 280   $self->js->render();
 281 }
 282
 283 sub action_add_item {
 284   my ($self) = @_;
 285
 286   my $form_attr = $::form->{add_item};
 287
 288   return unless $form_attr->{parts_id};
 289
 290   my $item = SL::DB::OrderItem->new;
 291   $item->assign_attributes(%$form_attr);
 292
 293   my $part         = SL::DB::Part->new(id => $form_attr->{parts_id})->load;
 294
 295   my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
 296
 297   my $price_src;
 298   if ($item->sellprice) {
 299     $price_src = $price_source->price_from_source("");
 300     $price_src->price($item->sellprice);
 301   } else {
 302     $price_src = $price_source->best_price
 303            ? $price_source->best_price
 304            : $price_source->price_from_source("");
 305     $price_src->price(0) if !$price_source->best_price;
 306   }
 307
 308   # bb: not sure but: maybe there should be a $price_source->discount_from_source
 309   # which can alse return an empty_discout if source is "".
 310   my $discount;
 311   my $discount_src;
 312   if ($item->discount) {
 313     $discount = $item->discount;
 314   } else {
 315     $discount = $price_source->best_discount
 316               ? $price_source->best_discount->discount
 317               : 0;
 318     $discount_src = $price_source->best_discount->source if $price_source->best_discount;
 319   }
 320
 321   my %new_attr;
 322   $new_attr{part}                   = $part;
 323   $new_attr{description}            = $part->description if ! $item->description;
 324   $new_attr{qty}                    = 1.0                if ! $item->qty;
 325   $new_attr{sellprice}              = $price_src->price;
 326   $new_attr{discount}               = $discount;
 327   $new_attr{active_price_source}    = $price_src;
 328   $new_attr{active_discount_source} = $discount_src;
 329
 330   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
 331   # they cannot be retrieved via custom_variables until the order/orderitem is
 332   # saved. Adding empty custom_variables to new orderitem here solves this problem.
 333   $new_attr{custom_variables} = [];
 334
 335   $item->assign_attributes(%new_attr);
 336
 337   $self->order->add_items($item);
 338
 339   $self->_recalc();
 340
 341   my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 342   my $row_as_html = $self->p->render('order/tabs/_row', ITEM => $item, ID => $item_id);
 343
 344   $self->js
 345     ->append('#row_table_id', $row_as_html)
 346     ->val('#add_item_parts_id', '')
 347     ->val('#add_item_parts_id_name', '')
 348     ->val('#add_item_description', '')
 349     ->val('#add_item_qty_as_number', '')
 350     ->val('#add_item_sellprice_as_number', '')
 351     ->val('#add_item_discount_as_percent', '')
 352     ->run('row_table_scroll_down')
 353     ->run('row_set_keyboard_events_by_id', $item_id)
 354     ->on('.recalc', 'change', 'recalc_amounts_and_taxes')
 355     ->focus('#add_item_parts_id_name');
 356
 357   $self->_js_redisplay_amounts_and_taxes;
 358   $self->js->render();
 359 }
 360
 361 sub action_recalc_amounts_and_taxes {
 362   my ($self) = @_;
 363
 364   $self->_recalc();
 365
 366   $self->_js_redisplay_linetotals;
 367   $self->_js_redisplay_amounts_and_taxes;
 368   $self->js->render();
 369 }
 370
 371 sub action_price_popup {
 372   my ($self) = @_;
 373
 374   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 375   my $item = $self->order->items->[$idx];
 376
 377   $self->render_price_dialog($item);
 378 }
 379
 380 sub _js_redisplay_linetotals {
 381   my ($self) = @_;
 382
 383   my @data = map {$::form->format_amount(\%::myconfig, $_->{linetotal}, 2, 0)} @{ $self->order->items };
 384   $self->js
 385     ->run('redisplay_linetotals', \@data);
 386 }
 387
 388 sub _js_redisplay_amounts_and_taxes {
 389   my ($self) = @_;
 390
 391   if (scalar @{ $self->{taxes} }) {
 392     $self->js->show('#taxincluded_row_id');
 393   } else {
 394     $self->js->hide('#taxincluded_row_id');
 395   }
 396
 397   if ($self->order->taxincluded) {
 398     $self->js->hide('#subtotal_row_id');
 399   } else {
 400     $self->js->show('#subtotal_row_id');
 401   }
 402
 403   $self->js
 404     ->html('#netamount_id', $::form->format_amount(\%::myconfig, $self->order->netamount, -2))
 405     ->html('#amount_id',    $::form->format_amount(\%::myconfig, $self->order->amount,    -2))
 406     ->remove('.tax_row')
 407     ->insertBefore($self->build_tax_rows, '#amount_row_id');
 408 }
 409
 410 #
 411 # helpers
 412 #
 413
 414 sub init_valid_types {
 415   [ _sales_order_type(), _purchase_order_type() ];
 416 }
 417
 418 sub init_type {
 419   my ($self) = @_;
 420
 421   if (none { $::form->{type} eq $_ } @{$self->valid_types}) {
 422     die "Not a valid type for order";
 423   }
 424
 425   $self->type($::form->{type});
 426 }
 427
 428 sub init_cv {
 429   my ($self) = @_;
 430
 431   my $cv = $self->type eq _sales_order_type()    ? 'customer'
 432          : $self->type eq _purchase_order_type() ? 'vendor'
 433          : die "Not a valid type for order";
 434
 435   return $cv;
 436 }
 437
 438 sub init_p {
 439   SL::Presenter->get;
 440 }
 441
 442 sub init_order {
 443   _make_order();
 444 }
 445
 446 sub _check_auth {
 447   my ($self) = @_;
 448
 449   my $right_for = { map { $_ => $_.'_edit' } @{$self->valid_types} };
 450
 451   my $right   = $right_for->{ $self->type };
 452   $right    ||= 'DOES_NOT_EXIST';
 453
 454   $::auth->assert($right);
 455 }
 456
 457 sub build_contact_select {
 458   my ($self) = @_;
 459
 460   $self->p->select_tag('order.cp_id', [ $self->order->{$self->cv}->contacts ],
 461                        value_key  => 'cp_id',
 462                        title_key  => 'full_name_dep',
 463                        default    => $self->order->cp_id,
 464                        with_empty => 1,
 465                        style      => 'width: 300px',
 466   );
 467 }
 468
 469 sub build_shipto_select {
 470   my ($self) = @_;
 471
 472   $self->p->select_tag('order.shipto_id', [ $self->order->{$self->cv}->shipto ],
 473                        value_key  => 'shipto_id',
 474                        title_key  => 'displayable_id',
 475                        default    => $self->order->shipto_id,
 476                        with_empty => 1,
 477                        style      => 'width: 300px',
 478   );
 479 }
 480
 481 sub build_tax_rows {
 482   my ($self) = @_;
 483
 484   my $rows_as_html;
 485   foreach my $tax (sort { $a->{tax}->rate cmp $b->{tax}->rate } @{ $self->{taxes} }) {
 486     $rows_as_html .= $self->p->render('order/tabs/_tax_row', TAX => $tax, TAXINCLUDED => $self->order->taxincluded);
 487   }
 488   return $rows_as_html;
 489 }
 490
 491
 492 sub render_price_dialog {
 493   my ($self, $record_item) = @_;
 494
 495   my $price_source = SL::PriceSource->new(record_item => $record_item, record => $self->order);
 496
 497   $self->js
 498     ->run(
 499       'kivi.io.price_chooser_dialog',
 500       t8('Available Prices'),
 501       $self->render('order/tabs/_price_sources_dialog', { output => 0 }, price_source => $price_source)
 502     )
 503     ->reinit_widgets;
 504
 505 #   if (@errors) {
 506 #     $self->js->text('#dialog_flash_error_content', join ' ', @errors);
 507 #     $self->js->show('#dialog_flash_error');
 508 #   }
 509
 510   $self->js->render;
 511 }
 512
 513 sub _make_order {
 514   my ($self) = @_;
 515
 516   # add_items adds items to an order with no items for saving, but they cannot
 517   # be retrieved via items until the order is saved. Adding empty items to new
 518   # order here solves this problem.
 519   my $order;
 520   $order   = SL::DB::Manager::Order->find_by(id => $::form->{id}) if $::form->{id};
 521   $order ||= SL::DB::Order->new(orderitems => []);
 522
 523   $order->assign_attributes(%{$::form->{order}});
 524
 525   return $order;
 526 }
 527
 528 sub _recalc {
 529   my ($self) = @_;
 530
 531   # bb: todo: currency later
 532   $self->order->currency_id($::instance_conf->get_currency_id());
 533
 534   my %pat = $self->order->calculate_prices_and_taxes();
 535   $self->{taxes} = [];
 536   foreach my $tax_chart_id (keys %{ $pat{taxes} }) {
 537     my $tax = SL::DB::Manager::Tax->find_by(chart_id => $tax_chart_id);
 538
 539     my @amount_keys = grep { $pat{amounts}->{$_}->{tax_id} == $tax->id } keys %{ $pat{amounts} };
 540     push(@{ $self->{taxes} }, { amount    => $pat{taxes}->{$tax_chart_id},
 541                                 netamount => $pat{amounts}->{$amount_keys[0]}->{amount},
 542                                 tax       => $tax });
 543   }
 544
 545   pairwise { $a->{linetotal} = $b->{linetotal} } @{$self->order->items}, @{$pat{items}};
 546 }
 547
 548
 549 sub _get_unalterable_data {
 550   my ($self) = @_;
 551
 552   foreach my $item (@{ $self->order->items }) {
 553     if ($item->id) {
 554       # load data from orderitems (db)
 555       my $db_item = SL::DB::OrderItem->new(id => $item->id)->load;
 556       $item->$_($db_item->$_) for qw(longdescription);
 557     } else {
 558       # set data from part (or other sources)
 559       $item->longdescription($item->part->notes);
 560     }
 561
 562     # autovivify all cvars that are not in the form (cvars_by_config can do it).
 563     # workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
 564     foreach my $var (@{ $item->cvars_by_config }) {
 565       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
 566     }
 567     $item->parse_custom_variable_values;
 568   }
 569 }
 570
 571
 572 sub _save {
 573   my ($self) = @_;
 574
 575   my $errors = [];
 576   my $db = $self->order->db;
 577
 578   $db->do_transaction(
 579     sub {
 580       $self->order->save();
 581   }) || push(@{$errors}, $db->error);
 582
 583   return $errors;
 584 }
 585
 586
 587 sub _pre_render {
 588   my ($self) = @_;
 589
 590   $self->{all_taxzones}        = SL::DB::Manager::TaxZone->get_all_sorted();
 591   $self->{all_employees}       = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->employee_id,
 592                                                                                        deleted => 0 ] ],
 593                                                                     sort_by => 'name');
 594   $self->{all_salesmen}        = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->salesman_id,
 595                                                                                        deleted => 0 ] ],
 596                                                                     sort_by => 'name');
 597   $self->{all_projects}        = SL::DB::Manager::Project->get_all(where => [ or => [ id => $self->order->globalproject_id,
 598                                                                                       active => 1 ] ],
 599                                                                    sort_by => 'projectnumber');
 600   $self->{all_payment_terms}   = SL::DB::Manager::PaymentTerm->get_all_sorted();
 601   $self->{all_delivery_terms}  = SL::DB::Manager::DeliveryTerm->get_all_sorted();
 602
 603   $self->{current_employee_id} = SL::DB::Manager::Employee->current->id;
 604
 605   foreach  my $item (@{$self->order->items}) {
 606     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
 607
 608     my $price_src = $price_source->price_from_source($item->active_price_source);
 609     $item->active_price_source($price_src);
 610
 611     my $discount_src;
 612     $discount_src = $price_source->price_from_source($item->active_discount_source)->source if $item->active_discount_source;
 613     $item->active_discount_source($discount_src);
 614   }
 615
 616   $::request->{layout}->use_javascript("${_}.js")  for qw(ckeditor/ckeditor ckeditor/adapters/jquery);
 617 }
 618
 619 sub _create_pdf {
 620   my ($order, $pdf_ref, $params) = @_;
 621
 622   my $print_form = Form->new('');
 623   $print_form->{type}     = $order->type;
 624   $print_form->{formname} = $order->type;
 625   $print_form->{format}   = $params->{format} || 'pdf',
 626   $print_form->{media}    = $params->{media}  || 'file';
 627
 628   $order->flatten_to_form($print_form, format_amounts => 1);
 629   # flatten_to_form sets payment_terms from customer/vendor - we do not want that here
 630   delete $print_form->{payment_terms} if !$print_form->{payment_id};
 631
 632   my @errors = ();
 633   $print_form->throw_on_error(sub {
 634     eval {
 635       $print_form->prepare_for_printing;
 636
 637       $$pdf_ref = SL::Helper::CreatePDF->create_pdf(
 638         template  => SL::Helper::CreatePDF->find_template(name => $print_form->{formname}),
 639         variables => $print_form,
 640         variable_content_types => {
 641           longdescription => 'html',
 642           partnotes       => 'html',
 643           notes           => 'html',
 644         },
 645       );
 646       1;
 647     } || push @errors, ref($EVAL_ERROR) eq 'SL::X::FormError' ? $EVAL_ERROR->getMessage : $EVAL_ERROR;
 648   });
 649
 650   return @errors;
 651 }
 652
 653 sub _sales_order_type {
 654   'sales_order';
 655 }
 656
 657 sub _purchase_order_type {
 658   'purchase_order';
 659 }
 660
 661 1;
 662
 663 __END__
 664
 665 =encoding utf-8
 666
 667 =head1 NAME
 668
 669 SL::Controller::Order - controller for orders
 670
 671 =head1 TODO
 672
 673 Testing, PriceSources, pricefactor, units, currency, delivered, delivery order created, ...
 674
 675 =head1 AUTHOR
 676
 677 Bernd Bleßmann E<lt>bernd@kivitendo-premium.deE<gt>
 678
 679 =cut
 680