SL/Controller/Order.pm

   1 package SL::Controller::Order;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use SL::Helper::Flash;
   7 use SL::Presenter;
   8 use SL::Locale::String;
   9 use SL::SessionFile::Random;
  10 use SL::PriceSource;
  11 use SL::Form;
  12 use SL::Webdav;
  13
  14 use SL::DB::Order;
  15 use SL::DB::Customer;
  16 use SL::DB::Vendor;
  17 use SL::DB::TaxZone;
  18 use SL::DB::Employee;
  19 use SL::DB::Project;
  20 use SL::DB::Default;
  21 use SL::DB::Unit;
  22 use SL::DB::Price;
  23 use SL::DB::Part;
  24
  25 use SL::Helper::DateTime;
  26 use SL::Helper::CreatePDF qw(:all);
  27
  28 use SL::Controller::Helper::GetModels;
  29
  30 use List::Util qw(max first);
  31 use List::MoreUtils qw(none pairwise first_index);
  32 use English qw(-no_match_vars);
  33 use File::Spec;
  34
  35 use Rose::Object::MakeMethods::Generic
  36 (
  37  scalar => [ qw(item_ids_to_delete) ],
  38  'scalar --get_set_init' => [ qw(order valid_types type cv p multi_items_models) ],
  39 );
  40
  41
  42 # safety
  43 __PACKAGE__->run_before('_check_auth');
  44
  45 __PACKAGE__->run_before('_recalc',
  46                         only => [ qw(update save save_and_delivery_order create_pdf send_email) ]);
  47
  48 __PACKAGE__->run_before('_get_unalterable_data',
  49                         only => [ qw(save save_and_delivery_order create_pdf send_email) ]);
  50
  51 #
  52 # actions
  53 #
  54
  55 sub action_add {
  56   my ($self) = @_;
  57
  58   $self->order->transdate(DateTime->now_local());
  59   $self->order->reqdate(DateTime->today_local->next_workday) if !$self->order->reqdate;
  60
  61   $self->_pre_render();
  62   $self->render(
  63     'order/form',
  64     title => $self->type eq _sales_order_type()    ? $::locale->text('Add Sales Order')
  65            : $self->type eq _purchase_order_type() ? $::locale->text('Add Purchase Order')
  66            : '',
  67     %{$self->{template_args}}
  68   );
  69 }
  70
  71 sub action_edit {
  72   my ($self) = @_;
  73
  74   $self->_load_order;
  75   $self->_recalc();
  76   $self->_pre_render();
  77   $self->render(
  78     'order/form',
  79     title => $self->type eq _sales_order_type()    ? $::locale->text('Edit Sales Order')
  80            : $self->type eq _purchase_order_type() ? $::locale->text('Edit Purchase Order')
  81            : '',
  82     %{$self->{template_args}}
  83   );
  84 }
  85
  86 sub action_update {
  87   my ($self) = @_;
  88
  89   $self->_pre_render();
  90   $self->render(
  91     'order/form',
  92     title => $self->type eq _sales_order_type()    ? $::locale->text('Edit Sales Order')
  93            : $self->type eq _purchase_order_type() ? $::locale->text('Edit Purchase Order')
  94            : '',
  95     %{$self->{template_args}}
  96   );
  97 }
  98
  99 sub action_delete {
 100   my ($self) = @_;
 101
 102   my $errors = $self->_delete();
 103
 104   if (scalar @{ $errors }) {
 105     $self->js->flash('error', $_) foreach @{ $errors };
 106     return $self->js->render();
 107   }
 108
 109   flash_later('info', $::locale->text('The order has been deleted'));
 110   my @redirect_params = (
 111     action => 'edit',
 112     type   => $self->type,
 113   );
 114
 115   $self->redirect_to(@redirect_params);
 116 }
 117
 118 sub action_save {
 119   my ($self) = @_;
 120
 121   my $errors = $self->_save();
 122
 123   if (scalar @{ $errors }) {
 124     $self->js->flash('error', $_) foreach @{ $errors };
 125     return $self->js->render();
 126   }
 127
 128   flash_later('info', $::locale->text('The order has been saved'));
 129   my @redirect_params = (
 130     action => 'edit',
 131     type   => $self->type,
 132     id     => $self->order->id,
 133   );
 134
 135   $self->redirect_to(@redirect_params);
 136 }
 137
 138 sub action_create_pdf {
 139   my ($self) = @_;
 140
 141   my $pdf;
 142   my @errors = _create_pdf($self->order, \$pdf);
 143   if (scalar @errors) {
 144     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render($self);
 145   }
 146
 147   my $sfile = SL::SessionFile::Random->new(mode => "w");
 148   $sfile->fh->print($pdf);
 149   $sfile->fh->close;
 150
 151   my $key = join('_', Time::HiRes::gettimeofday(), int rand 1000000000000);
 152   $::auth->set_session_value("Order::create_pdf-${key}" => $sfile->file_name);
 153
 154   my $form = Form->new;
 155   $form->{ordnumber} = $self->order->ordnumber;
 156   $form->{formname}  = $self->type;
 157   $form->{type}      = $self->type;
 158   $form->{language}  = 'de';
 159   $form->{format}    = 'pdf';
 160
 161   my $pdf_filename = $form->generate_attachment_filename();
 162
 163   # copy file to webdav folder
 164   if ($self->order->ordnumber && $::instance_conf->get_webdav_documents) {
 165     my $webdav = SL::Webdav->new(
 166       type     => $self->type,
 167       number   => $self->order->ordnumber,
 168     );
 169     my $webdav_file = SL::Webdav::File->new(
 170       webdav   => $webdav,
 171       filename => $pdf_filename,
 172     );
 173     eval {
 174       $webdav_file->store(data => \$pdf);
 175       1;
 176     } or do {
 177       $self->js->flash('error', t8('Storing PDF to webdav folder failed: #1', $@));
 178     }
 179   }
 180
 181   $self->js
 182     ->run('download_pdf', $pdf_filename, $key)
 183     ->flash('info', t8('The PDF has been created'))->render($self);
 184 }
 185
 186 sub action_download_pdf {
 187   my ($self) = @_;
 188
 189   my $key = $::form->{key};
 190   my $tmp_filename = $::auth->get_session_value("Order::create_pdf-${key}");
 191   return $self->send_file(
 192     $tmp_filename,
 193     type => 'application/pdf',
 194     name => $::form->{pdf_filename},
 195   );
 196 }
 197
 198 sub action_show_email_dialog {
 199   my ($self) = @_;
 200
 201   my $cv_method = $self->cv;
 202
 203   if (!$self->order->$cv_method) {
 204     return $self->js->flash('error', $self->cv eq 'customer' ? t8('Cannot send E-mail without customer given') : t8('Cannot send E-mail without vendor given'))
 205                     ->render($self);
 206   }
 207
 208   $self->{email}->{to}   = $self->order->contact->cp_email if $self->order->contact;
 209   $self->{email}->{to} ||= $self->order->$cv_method->email;
 210   $self->{email}->{cc}   = $self->order->$cv_method->cc;
 211   $self->{email}->{bcc}  = join ', ', grep $_, $self->order->$cv_method->bcc, SL::DB::Default->get->global_bcc;
 212   # Todo: get addresses from shipto, if any
 213
 214   my $form = Form->new;
 215   $form->{ordnumber} = $self->order->ordnumber;
 216   $form->{formname}  = $self->type;
 217   $form->{type}      = $self->type;
 218   $form->{language} = 'de';
 219   $form->{format}   = 'pdf';
 220
 221   $self->{email}->{subject}             = $form->generate_email_subject();
 222   $self->{email}->{attachment_filename} = $form->generate_attachment_filename();
 223   $self->{email}->{message}             = $form->create_email_signature();
 224
 225   my $dialog_html = $self->render('order/tabs/_email_dialog', { output => 0 });
 226   $self->js
 227       ->run('show_email_dialog', $dialog_html)
 228       ->reinit_widgets
 229       ->render($self);
 230 }
 231
 232 # Todo: handling error messages: flash is not displayed in dialog, but in the main form
 233 sub action_send_email {
 234   my ($self) = @_;
 235
 236   my $mail      = Mailer->new;
 237   $mail->{from} = qq|"$::myconfig{name}" <$::myconfig{email}>|;
 238   $mail->{$_}   = $::form->{email}->{$_} for qw(to cc bcc subject message);
 239
 240   my $pdf;
 241   my @errors = _create_pdf($self->order, \$pdf, {media => 'email'});
 242   if (scalar @errors) {
 243     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render($self);
 244   }
 245
 246   $mail->{attachments} = [{ "content" => $pdf,
 247                             "name"    => $::form->{email}->{attachment_filename} }];
 248
 249   if (my $err = $mail->send) {
 250     return $self->js->flash('error', t8('Sending E-mail: ') . $err)
 251                     ->render($self);
 252   }
 253
 254   # internal notes
 255   my $intnotes = $self->order->intnotes;
 256   $intnotes   .= "\n\n" if $self->order->intnotes;
 257   $intnotes   .= t8('[email]')                                                                                        . "\n";
 258   $intnotes   .= t8('Date')       . ": " . $::locale->format_date_object(DateTime->now_local, precision => 'seconds') . "\n";
 259   $intnotes   .= t8('To (email)') . ": " . $mail->{to}                                                                . "\n";
 260   $intnotes   .= t8('Cc')         . ": " . $mail->{cc}                                                                . "\n"    if $mail->{cc};
 261   $intnotes   .= t8('Bcc')        . ": " . $mail->{bcc}                                                               . "\n"    if $mail->{bcc};
 262   $intnotes   .= t8('Subject')    . ": " . $mail->{subject}                                                           . "\n\n";
 263   $intnotes   .= t8('Message')    . ": " . $mail->{message};
 264
 265   $self->js
 266       ->val('#order_intnotes', $intnotes)
 267       ->run('close_email_dialog')
 268       ->render($self);
 269 }
 270
 271 sub action_save_and_delivery_order {
 272   my ($self) = @_;
 273
 274   my $errors = $self->_save();
 275
 276   if (scalar @{ $errors }) {
 277     $self->js->flash('error', $_) foreach @{ $errors };
 278     return $self->js->render();
 279   }
 280   flash_later('info', $::locale->text('The order has been saved'));
 281
 282   my @redirect_params = (
 283     controller => 'oe.pl',
 284     action     => 'oe_delivery_order_from_order',
 285     id         => $self->order->id,
 286   );
 287
 288   $self->redirect_to(@redirect_params);
 289 }
 290
 291 sub action_customer_vendor_changed {
 292   my ($self) = @_;
 293
 294   my $cv_method = $self->cv;
 295
 296   if ($self->order->$cv_method->contacts && scalar @{ $self->order->$cv_method->contacts } > 0) {
 297     $self->js->show('#cp_row');
 298   } else {
 299     $self->js->hide('#cp_row');
 300   }
 301
 302   if ($self->order->$cv_method->shipto && scalar @{ $self->order->$cv_method->shipto } > 0) {
 303     $self->js->show('#shipto_row');
 304   } else {
 305     $self->js->hide('#shipto_row');
 306   }
 307
 308   $self->order->taxzone_id($self->order->$cv_method->taxzone_id);
 309
 310   if ($self->order->is_sales) {
 311     $self->order->taxincluded(defined($self->order->$cv_method->taxincluded_checked)
 312                               ? $self->order->$cv_method->taxincluded_checked
 313                               : $::myconfig{taxincluded_checked});
 314   }
 315
 316   $self->order->payment_id($self->order->$cv_method->payment_id);
 317   $self->order->delivery_term_id($self->order->$cv_method->delivery_term_id);
 318
 319   $self->_recalc();
 320
 321   $self->js
 322     ->replaceWith('#order_cp_id',            $self->build_contact_select)
 323     ->replaceWith('#order_shipto_id',        $self->build_shipto_select)
 324     ->val(        '#order_taxzone_id',       $self->order->taxzone_id)
 325     ->val(        '#order_taxincluded',      $self->order->taxincluded)
 326     ->val(        '#order_payment_id',       $self->order->payment_id)
 327     ->val(        '#order_delivery_term_id', $self->order->delivery_term_id)
 328     ->val(        '#order_intnotes',         $self->order->$cv_method->notes)
 329     ->focus(      '#order_' . $self->cv . '_id');
 330
 331   $self->_js_redisplay_amounts_and_taxes;
 332   $self->js->render();
 333 }
 334
 335 sub action_unit_changed {
 336   my ($self) = @_;
 337
 338   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 339   my $item = $self->order->items_sorted->[$idx];
 340
 341   my $old_unit_obj = SL::DB::Unit->new(name => $::form->{old_unit})->load;
 342   $item->sellprice($item->unit_obj->convert_to($item->sellprice, $old_unit_obj));
 343
 344   $self->_recalc();
 345
 346   $self->js
 347     ->run('update_sellprice', $::form->{item_id}, $item->sellprice_as_number);
 348   $self->_js_redisplay_linetotals;
 349   $self->_js_redisplay_amounts_and_taxes;
 350   $self->js->render();
 351 }
 352
 353 sub action_add_item {
 354   my ($self) = @_;
 355
 356   my $form_attr = $::form->{add_item};
 357
 358   return unless $form_attr->{parts_id};
 359
 360   my $item = _new_item($self->order, $form_attr);
 361   $self->order->add_items($item);
 362
 363   $self->_recalc();
 364
 365   my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 366   my $row_as_html = $self->p->render('order/tabs/_row', ITEM => $item, ID => $item_id);
 367
 368   $self->js
 369     ->append('#row_table_id', $row_as_html)
 370     ->val('.add_item_input', '')
 371     ->run('row_table_scroll_down')
 372     ->run('row_set_keyboard_events_by_id', $item_id)
 373     ->run('set_unit_change_with_oldval_by_id', $item_id)
 374     ->on('.recalc', 'change', 'recalc_amounts_and_taxes')
 375     ->on('.reformat_number', 'change', 'reformat_number')
 376     ->focus('#add_item_parts_id_name');
 377
 378   $self->_js_redisplay_amounts_and_taxes;
 379   $self->js->render();
 380 }
 381
 382 sub action_show_multi_items_dialog {
 383   require SL::DB::PartsGroup;
 384   $_[0]->render('order/tabs/_multi_items_dialog', { layout => 0 },
 385                 all_partsgroups => SL::DB::Manager::PartsGroup->get_all);
 386 }
 387
 388 sub action_multi_items_update_result {
 389   my $max_count = 100;
 390   my $count = $_[0]->multi_items_models->count;
 391
 392   if ($count == 0) {
 393     my $text = SL::Presenter::EscapedText->new(text => $::locale->text('No results.'));
 394     $_[0]->render($text, { layout => 0 });
 395   } elsif ($count > $max_count) {
 396     my $text = SL::Presenter::EscapedText->new(text => $::locale->text('Too many results (#1 from #2).', $count, $max_count));
 397     $_[0]->render($text, { layout => 0 });
 398   } else {
 399     my $multi_items = $_[0]->multi_items_models->get;
 400     $_[0]->render('order/tabs/_multi_items_result', { layout => 0 },
 401                   multi_items => $multi_items);
 402   }
 403 }
 404
 405 sub action_add_multi_items {
 406   my ($self) = @_;
 407
 408   my @form_attr = grep { $_->{qty_as_number} } @{ $::form->{add_multi_items} };
 409   return $self->js->render() unless scalar @form_attr;
 410
 411   my @items;
 412   foreach my $attr (@form_attr) {
 413     push @items, _new_item($self->order, $attr);
 414   }
 415   $self->order->add_items(@items);
 416
 417   $self->_recalc();
 418
 419   foreach my $item (@items) {
 420     my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 421     my $row_as_html = $self->p->render('order/tabs/_row', ITEM => $item, ID => $item_id);
 422
 423     $self->js
 424         ->append('#row_table_id', $row_as_html)
 425         ->run('row_set_keyboard_events_by_id', $item_id)
 426         ->run('set_unit_change_with_oldval_by_id', $item_id);
 427   }
 428
 429   $self->js
 430     ->run('close_multi_items_dialog')
 431     ->run('row_table_scroll_down')
 432     ->on('.recalc', 'change', 'recalc_amounts_and_taxes')
 433     ->on('.reformat_number', 'change', 'reformat_number')
 434     ->focus('#add_item_parts_id_name');
 435
 436   $self->_js_redisplay_amounts_and_taxes;
 437   $self->js->render();
 438 }
 439
 440 sub action_recalc_amounts_and_taxes {
 441   my ($self) = @_;
 442
 443   $self->_recalc();
 444
 445   $self->_js_redisplay_linetotals;
 446   $self->_js_redisplay_amounts_and_taxes;
 447   $self->js->render();
 448 }
 449
 450 sub action_price_popup {
 451   my ($self) = @_;
 452
 453   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 454   my $item = $self->order->items_sorted->[$idx];
 455
 456   $self->render_price_dialog($item);
 457 }
 458
 459 sub _js_redisplay_linetotals {
 460   my ($self) = @_;
 461
 462   my @data = map {$::form->format_amount(\%::myconfig, $_->{linetotal}, 2, 0)} @{ $self->order->items_sorted };
 463   $self->js
 464     ->run('redisplay_linetotals', \@data);
 465 }
 466
 467 sub _js_redisplay_amounts_and_taxes {
 468   my ($self) = @_;
 469
 470   if (scalar @{ $self->{taxes} }) {
 471     $self->js->show('#taxincluded_row_id');
 472   } else {
 473     $self->js->hide('#taxincluded_row_id');
 474   }
 475
 476   if ($self->order->taxincluded) {
 477     $self->js->hide('#subtotal_row_id');
 478   } else {
 479     $self->js->show('#subtotal_row_id');
 480   }
 481
 482   $self->js
 483     ->html('#netamount_id', $::form->format_amount(\%::myconfig, $self->order->netamount, -2))
 484     ->html('#amount_id',    $::form->format_amount(\%::myconfig, $self->order->amount,    -2))
 485     ->remove('.tax_row')
 486     ->insertBefore($self->build_tax_rows, '#amount_row_id');
 487 }
 488
 489 #
 490 # helpers
 491 #
 492
 493 sub init_valid_types {
 494   [ _sales_order_type(), _purchase_order_type() ];
 495 }
 496
 497 sub init_type {
 498   my ($self) = @_;
 499
 500   if (none { $::form->{type} eq $_ } @{$self->valid_types}) {
 501     die "Not a valid type for order";
 502   }
 503
 504   $self->type($::form->{type});
 505 }
 506
 507 sub init_cv {
 508   my ($self) = @_;
 509
 510   my $cv = $self->type eq _sales_order_type()    ? 'customer'
 511          : $self->type eq _purchase_order_type() ? 'vendor'
 512          : die "Not a valid type for order";
 513
 514   return $cv;
 515 }
 516
 517 sub init_p {
 518   SL::Presenter->get;
 519 }
 520
 521 sub init_order {
 522   $_[0]->_make_order;
 523 }
 524
 525 sub init_multi_items_models {
 526   SL::Controller::Helper::GetModels->new(
 527     controller     => $_[0],
 528     model          => 'Part',
 529     with_objects   => [ qw(unit_obj) ],
 530     disable_plugin => 'paginated',
 531     source         => $::form->{multi_items},
 532     sorted         => {
 533       _default    => {
 534         by  => 'partnumber',
 535         dir => 1,
 536       },
 537       partnumber  => t8('Partnumber'),
 538       description => t8('Description')}
 539   );
 540 }
 541
 542 sub _check_auth {
 543   my ($self) = @_;
 544
 545   my $right_for = { map { $_ => $_.'_edit' } @{$self->valid_types} };
 546
 547   my $right   = $right_for->{ $self->type };
 548   $right    ||= 'DOES_NOT_EXIST';
 549
 550   $::auth->assert($right);
 551 }
 552
 553 sub build_contact_select {
 554   my ($self) = @_;
 555
 556   $self->p->select_tag('order.cp_id', [ $self->order->{$self->cv}->contacts ],
 557                        value_key  => 'cp_id',
 558                        title_key  => 'full_name_dep',
 559                        default    => $self->order->cp_id,
 560                        with_empty => 1,
 561                        style      => 'width: 300px',
 562   );
 563 }
 564
 565 sub build_shipto_select {
 566   my ($self) = @_;
 567
 568   $self->p->select_tag('order.shipto_id', [ $self->order->{$self->cv}->shipto ],
 569                        value_key  => 'shipto_id',
 570                        title_key  => 'displayable_id',
 571                        default    => $self->order->shipto_id,
 572                        with_empty => 1,
 573                        style      => 'width: 300px',
 574   );
 575 }
 576
 577 sub build_tax_rows {
 578   my ($self) = @_;
 579
 580   my $rows_as_html;
 581   foreach my $tax (sort { $a->{tax}->rate cmp $b->{tax}->rate } @{ $self->{taxes} }) {
 582     $rows_as_html .= $self->p->render('order/tabs/_tax_row', TAX => $tax, TAXINCLUDED => $self->order->taxincluded);
 583   }
 584   return $rows_as_html;
 585 }
 586
 587
 588 sub render_price_dialog {
 589   my ($self, $record_item) = @_;
 590
 591   my $price_source = SL::PriceSource->new(record_item => $record_item, record => $self->order);
 592
 593   $self->js
 594     ->run(
 595       'kivi.io.price_chooser_dialog',
 596       t8('Available Prices'),
 597       $self->render('order/tabs/_price_sources_dialog', { output => 0 }, price_source => $price_source)
 598     )
 599     ->reinit_widgets;
 600
 601 #   if (@errors) {
 602 #     $self->js->text('#dialog_flash_error_content', join ' ', @errors);
 603 #     $self->js->show('#dialog_flash_error');
 604 #   }
 605
 606   $self->js->render;
 607 }
 608
 609 sub _load_order {
 610   my ($self) = @_;
 611
 612   return if !$::form->{id};
 613
 614   $self->order(SL::DB::Manager::Order->find_by(id => $::form->{id}));
 615 }
 616
 617 sub _make_order {
 618   my ($self) = @_;
 619
 620   # add_items adds items to an order with no items for saving, but they cannot
 621   # be retrieved via items until the order is saved. Adding empty items to new
 622   # order here solves this problem.
 623   my $order;
 624   $order   = SL::DB::Manager::Order->find_by(id => $::form->{id}) if $::form->{id};
 625   $order ||= SL::DB::Order->new(orderitems => []);
 626
 627   my $form_orderitems = delete $::form->{order}->{orderitems};
 628   $order->assign_attributes(%{$::form->{order}});
 629
 630   # remove deleted items
 631   $self->item_ids_to_delete([]);
 632   foreach my $idx (reverse 0..$#{$order->orderitems}) {
 633     my $item = $order->orderitems->[$idx];
 634     if (none { $item->id == $_->{id} } @{$form_orderitems}) {
 635       splice @{$order->orderitems}, $idx, 1;
 636       push @{$self->item_ids_to_delete}, $item->id;
 637     }
 638   }
 639
 640   my @items;
 641   my $pos = 1;
 642   foreach my $form_attr (@{$form_orderitems}) {
 643     my $item = _make_item($order, $form_attr);
 644     $item->position($pos);
 645     push @items, $item;
 646     $pos++;
 647   }
 648   $order->add_items(grep {!$_->id} @items);
 649
 650   return $order;
 651 }
 652
 653
 654 # Make item objects from form values. For items already existing read from db.
 655 # Create a new item else. And assign attributes.
 656 sub _make_item {
 657   my ($record, $attr) = @_;
 658
 659   my $item;
 660   $item = first { $_->id == $attr->{id} } @{$record->items} if $attr->{id};
 661
 662   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
 663   # they cannot be retrieved via custom_variables until the order/orderitem is
 664   # saved. Adding empty custom_variables to new orderitem here solves this problem.
 665   $item ||= SL::DB::OrderItem->new(custom_variables => []);
 666   $item->assign_attributes(%$attr);
 667
 668   return $item;
 669 }
 670
 671 sub _new_item {
 672   my ($record, $attr) = @_;
 673
 674   my $item = SL::DB::OrderItem->new;
 675   $item->assign_attributes(%$attr);
 676
 677   my $part         = SL::DB::Part->new(id => $attr->{parts_id})->load;
 678   my $price_source = SL::PriceSource->new(record_item => $item, record => $record);
 679
 680   $item->unit($part->unit) if !$item->unit;
 681
 682   my $price_src;
 683   if ($item->sellprice) {
 684     $price_src = $price_source->price_from_source("");
 685     $price_src->price($item->sellprice);
 686   } else {
 687     $price_src = $price_source->best_price
 688            ? $price_source->best_price
 689            : $price_source->price_from_source("");
 690     $price_src->price(0) if !$price_source->best_price;
 691   }
 692
 693   my $discount_src;
 694   if ($item->discount) {
 695     $discount_src = $price_source->discount_from_source("");
 696     $discount_src->discount($item->discount);
 697   } else {
 698     $discount_src = $price_source->best_discount
 699                   ? $price_source->best_discount
 700                   : $price_source->discount_from_source("");
 701     $discount_src->discount(0) if !$price_source->best_discount;
 702   }
 703
 704   my %new_attr;
 705   $new_attr{part}                   = $part;
 706   $new_attr{description}            = $part->description if ! $item->description;
 707   $new_attr{qty}                    = 1.0                if ! $item->qty;
 708   $new_attr{sellprice}              = $price_src->price;
 709   $new_attr{discount}               = $discount_src->discount;
 710   $new_attr{active_price_source}    = $price_src;
 711   $new_attr{active_discount_source} = $discount_src;
 712
 713   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
 714   # they cannot be retrieved via custom_variables until the order/orderitem is
 715   # saved. Adding empty custom_variables to new orderitem here solves this problem.
 716   $new_attr{custom_variables} = [];
 717
 718   $item->assign_attributes(%new_attr);
 719
 720   return $item;
 721 }
 722
 723 sub _recalc {
 724   my ($self) = @_;
 725
 726   # bb: todo: currency later
 727   $self->order->currency_id($::instance_conf->get_currency_id());
 728
 729   my %pat = $self->order->calculate_prices_and_taxes();
 730   $self->{taxes} = [];
 731   foreach my $tax_chart_id (keys %{ $pat{taxes} }) {
 732     my $tax = SL::DB::Manager::Tax->find_by(chart_id => $tax_chart_id);
 733
 734     my @amount_keys = grep { $pat{amounts}->{$_}->{tax_id} == $tax->id } keys %{ $pat{amounts} };
 735     push(@{ $self->{taxes} }, { amount    => $pat{taxes}->{$tax_chart_id},
 736                                 netamount => $pat{amounts}->{$amount_keys[0]}->{amount},
 737                                 tax       => $tax });
 738   }
 739
 740   pairwise { $a->{linetotal} = $b->{linetotal} } @{$self->order->items}, @{$pat{items}};
 741 }
 742
 743
 744 sub _get_unalterable_data {
 745   my ($self) = @_;
 746
 747   foreach my $item (@{ $self->order->items }) {
 748     if ($item->id) {
 749       # load data from orderitems (db)
 750       my $db_item = SL::DB::OrderItem->new(id => $item->id)->load;
 751       $item->$_($db_item->$_) for qw(longdescription);
 752     } else {
 753       # set data from part (or other sources)
 754       $item->longdescription($item->part->notes);
 755     }
 756
 757     # autovivify all cvars that are not in the form (cvars_by_config can do it).
 758     # workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
 759     foreach my $var (@{ $item->cvars_by_config }) {
 760       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
 761     }
 762     $item->parse_custom_variable_values;
 763   }
 764 }
 765
 766
 767 sub _delete {
 768   my ($self) = @_;
 769
 770   my $errors = [];
 771   my $db = $self->order->db;
 772
 773   $db->do_transaction(
 774     sub {
 775       my @spoolfiles = grep { $_ } map { $_->spoolfile } @{ SL::DB::Manager::Status->get_all(where => [ trans_id => $self->order->id ]) };
 776       $self->order->delete;
 777       my $spool = $::lx_office_conf{paths}->{spool};
 778       unlink map { "$spool/$_" } @spoolfiles if $spool;
 779
 780       1;
 781   }) || push(@{$errors}, $db->error);
 782
 783   return $errors;
 784 }
 785
 786
 787 sub _save {
 788   my ($self) = @_;
 789
 790   my $errors = [];
 791   my $db = $self->order->db;
 792
 793   $db->do_transaction(
 794     sub {
 795       SL::DB::OrderItem->new(id => $_)->delete for @{$self->item_ids_to_delete};
 796       $self->order->save(cascade => 1);
 797   }) || push(@{$errors}, $db->error);
 798
 799   return $errors;
 800 }
 801
 802
 803 sub _pre_render {
 804   my ($self) = @_;
 805
 806   $self->{all_taxzones}        = SL::DB::Manager::TaxZone->get_all_sorted();
 807   $self->{all_departments}     = SL::DB::Manager::Department->get_all_sorted();
 808   $self->{all_employees}       = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->employee_id,
 809                                                                                        deleted => 0 ] ],
 810                                                                     sort_by => 'name');
 811   $self->{all_salesmen}        = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->salesman_id,
 812                                                                                        deleted => 0 ] ],
 813                                                                     sort_by => 'name');
 814   $self->{all_projects}        = SL::DB::Manager::Project->get_all(where => [ or => [ id => $self->order->globalproject_id,
 815                                                                                       active => 1 ] ],
 816                                                                    sort_by => 'projectnumber');
 817   $self->{all_payment_terms}   = SL::DB::Manager::PaymentTerm->get_all_sorted();
 818   $self->{all_delivery_terms}  = SL::DB::Manager::DeliveryTerm->get_all_sorted();
 819
 820   $self->{current_employee_id} = SL::DB::Manager::Employee->current->id;
 821
 822   foreach my $item (@{$self->order->orderitems}) {
 823     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
 824     $item->active_price_source(   $price_source->price_from_source(   $item->active_price_source   ));
 825     $item->active_discount_source($price_source->discount_from_source($item->active_discount_source));
 826   }
 827
 828   if ($self->order->ordnumber && $::instance_conf->get_webdav) {
 829     my $webdav = SL::Webdav->new(
 830       type     => $self->type,
 831       number   => $self->order->ordnumber,
 832     );
 833     my $webdav_path = $webdav->webdav_path;
 834     my @all_objects = $webdav->get_all_objects;
 835     @{ $self->{template_args}->{WEBDAV} } = map { { name => $_->filename,
 836                                                     type => t8('File'),
 837                                                     link => File::Spec->catdir($webdav_path, $_->filename),
 838                                                 } } @all_objects;
 839   }
 840
 841   $::request->{layout}->use_javascript("${_}.js")  for qw(ckeditor/ckeditor ckeditor/adapters/jquery);
 842 }
 843
 844 sub _create_pdf {
 845   my ($order, $pdf_ref, $params) = @_;
 846
 847   my $print_form = Form->new('');
 848   $print_form->{type}     = $order->type;
 849   $print_form->{formname} = $order->type;
 850   $print_form->{format}   = $params->{format} || 'pdf',
 851   $print_form->{media}    = $params->{media}  || 'file';
 852
 853   $order->flatten_to_form($print_form, format_amounts => 1);
 854   # flatten_to_form sets payment_terms from customer/vendor - we do not want that here
 855   delete $print_form->{payment_terms} if !$print_form->{payment_id};
 856
 857   my @errors = ();
 858   $print_form->throw_on_error(sub {
 859     eval {
 860       $print_form->prepare_for_printing;
 861
 862       $$pdf_ref = SL::Helper::CreatePDF->create_pdf(
 863         template  => SL::Helper::CreatePDF->find_template(name => $print_form->{formname}),
 864         variables => $print_form,
 865         variable_content_types => {
 866           longdescription => 'html',
 867           partnotes       => 'html',
 868           notes           => 'html',
 869         },
 870       );
 871       1;
 872     } || push @errors, ref($EVAL_ERROR) eq 'SL::X::FormError' ? $EVAL_ERROR->getMessage : $EVAL_ERROR;
 873   });
 874
 875   return @errors;
 876 }
 877
 878 sub _sales_order_type {
 879   'sales_order';
 880 }
 881
 882 sub _purchase_order_type {
 883   'purchase_order';
 884 }
 885
 886 1;