SL/Controller/Order.pm

   1 package SL::Controller::Order;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use SL::Helper::Flash;
   7 use SL::ClientJS;
   8 use SL::Presenter;
   9 use SL::Locale::String;
  10 use SL::SessionFile::Random;
  11 use SL::Form;
  12
  13 use SL::DB::Order;
  14 use SL::DB::Customer;
  15 use SL::DB::Vendor;
  16 use SL::DB::TaxZone;
  17 use SL::DB::Employee;
  18 use SL::DB::Project;
  19 use SL::DB::Default;
  20 use SL::DB::Unit;
  21
  22 use SL::Helper::DateTime;
  23 use SL::Helper::CreatePDF qw(:all);
  24
  25 use List::Util qw(max first);
  26 use List::MoreUtils qw(none pairwise);
  27 use English qw(-no_match_vars);
  28
  29 use Rose::Object::MakeMethods::Generic
  30 (
  31  'scalar --get_set_init' => [ qw(order valid_types type cv js p) ],
  32 );
  33
  34
  35 # safety
  36 __PACKAGE__->run_before('_check_auth');
  37
  38 __PACKAGE__->run_before('_recalc',
  39                         only => [ qw(edit update save save_and_delivery_order create_pdf send_email) ]);
  40
  41
  42 #
  43 # actions
  44 #
  45
  46 sub action_add {
  47   my ($self) = @_;
  48
  49   $self->order->transdate(DateTime->now_local());
  50
  51   $self->_pre_render();
  52   $self->render(
  53     'order/form',
  54     title => $self->type eq _sales_order_type()    ? $::locale->text('Add Sales Order')
  55            : $self->type eq _purchase_order_type() ? $::locale->text('Add Purchase Order')
  56            : '',
  57     %{$self->{template_args}}
  58   );
  59 }
  60
  61 sub action_edit {
  62   my ($self) = @_;
  63
  64   $self->_pre_render();
  65   $self->render(
  66     'order/form',
  67     title => $self->type eq _sales_order_type()    ? $::locale->text('Edit Sales Order')
  68            : $self->type eq _purchase_order_type() ? $::locale->text('Edit Purchase Order')
  69            : '',
  70     %{$self->{template_args}}
  71   );
  72 }
  73
  74 sub action_update {
  75   my ($self) = @_;
  76
  77   $self->_pre_render();
  78   $self->render(
  79     'order/form',
  80     title => $self->type eq _sales_order_type()    ? $::locale->text('Edit Sales Order')
  81            : $self->type eq _purchase_order_type() ? $::locale->text('Edit Purchase Order')
  82            : '',
  83     %{$self->{template_args}}
  84   );
  85 }
  86
  87 sub action_save {
  88   my ($self) = @_;
  89
  90   my $errors = $self->_save();
  91
  92   if (scalar @{ $errors }) {
  93     $self->js->flash('error', $_) foreach @{ $errors };
  94     return $self->js->render($self);
  95   }
  96
  97   flash_later('info', $::locale->text('The order has been saved'));
  98   my @redirect_params = (
  99     action => 'edit',
 100     type   => $self->type,
 101     id     => $self->order->id,
 102   );
 103
 104   $self->redirect_to(@redirect_params);
 105 }
 106
 107 sub action_create_pdf {
 108   my ($self) = @_;
 109
 110   my $pdf;
 111   my @errors = _create_pdf($self->order, \$pdf);
 112   if (scalar @errors) {
 113     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render($self);
 114   }
 115
 116   my $sfile = SL::SessionFile::Random->new(mode => "w");
 117   $sfile->fh->print($pdf);
 118   $sfile->fh->close;
 119
 120   my $tmp_filename = $sfile->file_name;
 121   my $pdf_filename = t8('Sales Order') . '_' . $self->order->ordnumber . '.pdf';
 122
 123   $self->js
 124     ->run('download_pdf', $tmp_filename, $pdf_filename)
 125     ->flash('info', t8('The PDF has been created'))->render($self);
 126 }
 127
 128 sub action_download_pdf {
 129   my ($self) = @_;
 130
 131   return $self->send_file(
 132     $::form->{tmp_filename},
 133     type => 'application/pdf',
 134     name => $::form->{pdf_filename},
 135   );
 136 }
 137
 138 sub action_show_email_dialog {
 139   my ($self) = @_;
 140
 141   my $cv_method = $self->cv;
 142
 143   if (!$self->order->$cv_method) {
 144     return $self->js->flash('error', t8('Cannot send E-mail without ' . $self->cv))
 145                     ->render($self);
 146   }
 147
 148   $self->{email}->{to}   = $self->order->contact->cp_email if $self->order->contact;
 149   $self->{email}->{to} ||= $self->order->$cv_method->email;
 150   $self->{email}->{cc}   = $self->order->$cv_method->cc;
 151   $self->{email}->{bcc}  = join ', ', grep $_, $self->order->$cv_method->bcc, SL::DB::Default->get->global_bcc;
 152   # Todo: get addresses from shipto, if any
 153
 154   my $form = Form->new;
 155   $form->{ordnumber} = $self->order->ordnumber;
 156   $form->{formname}  = $self->type;
 157   $form->{type}      = $self->type;
 158   $form->{language} = 'de';
 159   $form->{format}   = 'pdf';
 160
 161   $self->{email}->{subject}             = $form->generate_email_subject();
 162   $self->{email}->{attachment_filename} = $form->generate_attachment_filename();
 163   $self->{email}->{message}             = $form->create_email_signature();
 164
 165   my $dialog_html = $self->render('order/tabs/_email_dialog', { output => 0 });
 166   $self->js
 167       ->run('show_email_dialog', $dialog_html)
 168       ->reinit_widgets
 169       ->render($self);
 170 }
 171
 172 # Todo: handling error messages: flash is not displayed in dialog, but in the main form
 173 sub action_send_email {
 174   my ($self) = @_;
 175
 176   my $mail      = Mailer->new;
 177   $mail->{from} = qq|"$::myconfig{name}" <$::myconfig{email}>|;
 178   $mail->{$_}   = $::form->{email}->{$_} for qw(to cc bcc subject message);
 179
 180   my $pdf;
 181   my @errors = _create_pdf($self->order, \$pdf, {media => 'email'});
 182   if (scalar @errors) {
 183     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render($self);
 184   }
 185
 186   my $sfile = SL::SessionFile::Random->new(mode => "w");
 187   $sfile->fh->print($pdf);
 188   $sfile->fh->close;
 189
 190   $mail->{attachments} = [{ "filename" => $sfile->file_name,
 191                             "name"     => $::form->{email}->{attachment_filename} }];
 192
 193   if (my $err = $mail->send) {
 194     return $self->js->flash('error', t8('Sending E-mail: ') . $err)
 195                     ->render($self);
 196   }
 197
 198   # internal notes
 199   my $intnotes = $self->order->intnotes;
 200   $intnotes   .= "\n\n" if $self->order->intnotes;
 201   $intnotes   .= t8('[email]')                                                                                        . "\n";
 202   $intnotes   .= t8('Date')       . ": " . $::locale->format_date_object(DateTime->now_local, precision => 'seconds') . "\n";
 203   $intnotes   .= t8('To (email)') . ": " . $mail->{to}                                                                . "\n";
 204   $intnotes   .= t8('Cc')         . ": " . $mail->{cc}                                                                . "\n"    if $mail->{cc};
 205   $intnotes   .= t8('Bcc')        . ": " . $mail->{bcc}                                                               . "\n"    if $mail->{bcc};
 206   $intnotes   .= t8('Subject')    . ": " . $mail->{subject}                                                           . "\n\n";
 207   $intnotes   .= t8('Message')    . ": " . $mail->{message};
 208
 209   $self->js
 210       ->val('#order_intnotes', $intnotes)
 211       ->run('close_email_dialog')
 212       ->render($self);
 213 }
 214
 215 sub action_save_and_delivery_order {
 216   my ($self) = @_;
 217
 218   my $errors = $self->_save();
 219
 220   if (scalar @{ $errors }) {
 221     $self->js->flash('error', $_) foreach @{ $errors };
 222     return $self->js->render($self);
 223   }
 224
 225   my $delivery_order = $self->order->convert_to_delivery_order($self->order);
 226
 227   flash_later('info', $::locale->text('The order has been saved'));
 228   my @redirect_params = (
 229     controller => 'do.pl',
 230     action     => 'edit',
 231     type       => $delivery_order->type,
 232     id         => $delivery_order->id,
 233     vc         => $delivery_order->is_sales ? 'customer' : 'vendor',
 234   );
 235
 236   $self->redirect_to(@redirect_params);
 237 }
 238
 239 sub action_customer_vendor_changed {
 240   my ($self) = @_;
 241
 242   if ($self->cv eq 'customer') {
 243     $self->order->customer(SL::DB::Manager::Customer->find_by_or_create(id => $::form->{cv_id}));
 244
 245   } elsif ($self->cv eq 'vendor') {
 246     $self->order->vendor(SL::DB::Manager::Vendor->find_by_or_create(id => $::form->{cv_id}));
 247   }
 248
 249   if ($self->order->{$self->cv}->contacts && scalar @{ $self->order->{$self->cv}->contacts } > 0) {
 250     $self->js->show('#cp_row');
 251   } else {
 252     $self->js->hide('#cp_row');
 253   }
 254
 255   if ($self->order->{$self->cv}->shipto && scalar @{ $self->order->{$self->cv}->shipto } > 0) {
 256     $self->js->show('#shipto_row');
 257   } else {
 258     $self->js->hide('#shipto_row');
 259   }
 260
 261   $self->js
 262     ->replaceWith('#order_cp_id',     $self->build_contact_select)
 263     ->replaceWith('#order_shipto_id', $self->build_shipto_select)
 264     ->val('#order_taxzone_id', $self->order->{$self->cv}->taxzone_id)
 265     ->focus('#order_' . $self->cv . '_id')
 266     ->render($self);
 267 }
 268
 269 sub action_add_item {
 270   my ($self) = @_;
 271
 272   my $form_attr = $::form->{add_item};
 273
 274   return unless $form_attr->{parts_id};
 275
 276   my $item = SL::DB::OrderItem->new;
 277   $item->assign_attributes(%$form_attr);
 278
 279   my $part        = SL::DB::Part->new(id => $form_attr->{parts_id})->load;
 280   my $cv_method   = $self->cv;
 281   my $cv_discount = $self->order->$cv_method? $self->order->$cv_method->discount : 0.0;
 282
 283   my %new_attr;
 284   $new_attr{part}        = $part;
 285   $new_attr{description} = $part->description if ! $item->description;
 286   $new_attr{qty}         = 1.0                if ! $item->qty;
 287   $new_attr{unit}        = $part->unit;
 288   $new_attr{sellprice}   = $part->sellprice   if ! $item->sellprice;
 289   $new_attr{discount}    = $cv_discount       if ! $item->discount;
 290
 291   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
 292   # they cannot be retrieved via custom_variables until the order/orderitem is
 293   # saved. Adding empty custom_variables to new orderitem here solves this problem.
 294   $new_attr{custom_variables} = [];
 295
 296   $item->assign_attributes(%new_attr);
 297
 298   $self->order->add_items($item);
 299
 300   $self->_recalc();
 301
 302   my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 303   my $row_as_html = $self->p->render('order/tabs/_row', ITEM => $item, ID => $item_id);
 304
 305   $self->js
 306     ->append('#row_table_id', $row_as_html)
 307     ->val('#add_item_parts_id', '')
 308     ->val('#add_item_parts_id_name', '')
 309     ->val('#add_item_description', '')
 310     ->val('#add_item_qty_as_number', '')
 311     ->val('#add_item_sellprice_as_number', '')
 312     ->val('#add_item_discount_as_percent', '')
 313     ->run('row_table_scroll_down')
 314     ->run('row_set_keyboard_events_by_id', $item_id)
 315     ->on('.recalc', 'change', 'recalc_amounts_and_taxes')
 316     ->focus('#add_item_parts_id_name');
 317
 318   $self->_js_redisplay_amounts_and_taxes;
 319   $self->js->render($self);
 320 }
 321
 322 sub action_recalc_amounts_and_taxes {
 323   my ($self) = @_;
 324
 325   $self->_recalc();
 326
 327   $self->_js_redisplay_linetotals;
 328   $self->_js_redisplay_amounts_and_taxes;
 329   $self->js->render($self);
 330 }
 331
 332 sub _js_redisplay_linetotals {
 333   my ($self) = @_;
 334
 335   my @data = map {$::form->format_amount(\%::myconfig, $_->{linetotal}, 2, 0)} @{ $self->order->items };
 336   $self->js
 337     ->run('redisplay_linetotals', \@data);
 338 }
 339
 340 sub _js_redisplay_amounts_and_taxes {
 341   my ($self) = @_;
 342
 343   if (scalar @{ $self->{taxes} }) {
 344     $self->js->show('#taxincluded_row_id');
 345   } else {
 346     $self->js->hide('#taxincluded_row_id');
 347   }
 348
 349   if ($self->order->taxincluded) {
 350     $self->js->hide('#subtotal_row_id');
 351   } else {
 352     $self->js->show('#subtotal_row_id');
 353   }
 354
 355   $self->js
 356     ->html('#netamount_id', $::form->format_amount(\%::myconfig, $self->order->netamount, -2))
 357     ->html('#amount_id',    $::form->format_amount(\%::myconfig, $self->order->amount,    -2))
 358     ->remove('.tax_row')
 359     ->insertBefore($self->build_tax_rows, '#amount_row_id');
 360 }
 361
 362 #
 363 # helpers
 364 #
 365
 366 sub init_valid_types {
 367   [ _sales_order_type(), _purchase_order_type() ];
 368 }
 369
 370 sub init_type {
 371   my ($self) = @_;
 372
 373   if (none { $::form->{type} eq $_ } @{$self->valid_types}) {
 374     die "Not a valid type for order";
 375   }
 376
 377   $self->type($::form->{type});
 378 }
 379
 380 sub init_cv {
 381   my ($self) = @_;
 382
 383   my $cv = $self->type eq _sales_order_type()    ? 'customer'
 384          : $self->type eq _purchase_order_type() ? 'vendor'
 385          : die "Not a valid type for order";
 386
 387   return $cv;
 388 }
 389
 390 sub init_js {
 391   SL::ClientJS->new;
 392 }
 393
 394 sub init_p {
 395   SL::Presenter->get;
 396 }
 397
 398 sub init_order {
 399   _make_order();
 400 }
 401
 402 sub _check_auth {
 403   my ($self) = @_;
 404
 405   my $right_for = { map { $_ => $_.'_edit' } @{$self->valid_types} };
 406
 407   my $right   = $right_for->{ $self->type };
 408   $right    ||= 'DOES_NOT_EXIST';
 409
 410   $::auth->assert($right);
 411 }
 412
 413 sub build_contact_select {
 414   my ($self) = @_;
 415
 416   $self->p->select_tag('order.cp_id', [ $self->order->{$self->cv}->contacts ],
 417                        value_key  => 'cp_id',
 418                        title_key  => 'full_name_dep',
 419                        default    => $self->order->cp_id,
 420                        with_empty => 1,
 421                        style      => 'width: 300px',
 422   );
 423 }
 424
 425 sub build_shipto_select {
 426   my ($self) = @_;
 427
 428   $self->p->select_tag('order.shipto_id', [ $self->order->{$self->cv}->shipto ],
 429                        value_key  => 'shipto_id',
 430                        title_key  => 'displayable_id',
 431                        default    => $self->order->shipto_id,
 432                        with_empty => 1,
 433                        style      => 'width: 300px',
 434   );
 435 }
 436
 437 sub build_tax_rows {
 438   my ($self) = @_;
 439
 440   my $rows_as_html;
 441   foreach my $tax (@{ $self->{taxes} }) {
 442     $rows_as_html .= $self->p->render('order/tabs/_tax_row', TAX => $tax, TAXINCLUDED => $self->order->taxincluded);
 443   }
 444   return $rows_as_html;
 445 }
 446
 447
 448 sub _make_order {
 449   my ($self) = @_;
 450
 451   # add_items adds items to an order with no items for saving, but they cannot
 452   # be retrieved via items until the order is saved. Adding empty items to new
 453   # order here solves this problem.
 454   my $order;
 455   $order   = SL::DB::Manager::Order->find_by(id => $::form->{id}) if $::form->{id};
 456   $order ||= SL::DB::Order->new(orderitems => []);
 457
 458   $order->assign_attributes(%{$::form->{order}});
 459
 460   return $order;
 461 }
 462
 463
 464 sub _recalc {
 465   my ($self) = @_;
 466
 467   # bb: todo: currency later
 468   $self->order->currency_id($::instance_conf->get_currency_id());
 469
 470   my %pat = $self->order->calculate_prices_and_taxes();
 471   $self->{taxes} = [];
 472   foreach my $tax_chart_id (keys %{ $pat{taxes} }) {
 473     my $tax = SL::DB::Manager::Tax->find_by(chart_id => $tax_chart_id);
 474
 475     my @amount_keys = grep { $pat{amounts}->{$_}->{tax_id} == $tax->id } keys %{ $pat{amounts} };
 476     push(@{ $self->{taxes} }, { amount    => $pat{taxes}->{$tax_chart_id},
 477                                 netamount => $pat{amounts}->{$amount_keys[0]}->{amount},
 478                                 tax       => $tax });
 479   }
 480
 481   pairwise { $a->{linetotal} = $b->{linetotal} } @{$self->order->items}, @{$pat{items}};
 482 }
 483
 484 sub _save {
 485   my ($self) = @_;
 486
 487   # autovivify all cvars that are not in the form (cvars_by_config can do it)
 488   foreach my $item (@{ $self->order->items }) {
 489     $item->cvars_by_config;
 490   }
 491
 492   my $errors = [];
 493   my $db = $self->order->db;
 494
 495   $db->do_transaction(
 496     sub {
 497       $self->order->save();
 498   }) || push(@{$errors}, $db->error);
 499
 500   return $errors;
 501 }
 502
 503
 504 sub _pre_render {
 505   my ($self) = @_;
 506
 507   $self->{all_taxzones}        = SL::DB::Manager::TaxZone->get_all_sorted();
 508   $self->{all_employees}       = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->employee_id,
 509                                                                                        deleted => 0 ] ],
 510                                                                     sort_by => 'name');
 511   $self->{all_salesmen}        = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->salesman_id,
 512                                                                                        deleted => 0 ] ],
 513                                                                     sort_by => 'name');
 514   $self->{all_projects}        = SL::DB::Manager::Project->get_all(where => [ or => [ id => $self->order->globalproject_id,
 515                                                                                       active => 1 ] ],
 516                                                                    sort_by => 'projectnumber');
 517   $self->{all_payment_terms}   = SL::DB::Manager::PaymentTerm->get_all_sorted();
 518   $self->{all_delivery_terms}  = SL::DB::Manager::DeliveryTerm->get_all_sorted();
 519
 520   $self->{current_employee_id} = SL::DB::Manager::Employee->current->id;
 521
 522   $::request->{layout}->use_javascript("${_}.js")  for qw(ckeditor/ckeditor ckeditor/adapters/jquery);
 523 }
 524
 525 sub _create_pdf {
 526   my ($order, $pdf_ref, $params) = @_;
 527
 528   my $print_form = Form->new('');
 529   $print_form->{type}     = 'sales_order';
 530   $print_form->{formname} = 'sales_order',
 531   $print_form->{format}   = $params->{format} || 'pdf',
 532   $print_form->{media}    = $params->{media}  || 'file';
 533
 534   $order->flatten_to_form($print_form, format_amounts => 1);
 535
 536   my @errors = ();
 537   $print_form->throw_on_error(sub {
 538     eval {
 539       $print_form->prepare_for_printing;
 540
 541       $$pdf_ref = SL::Helper::CreatePDF->create_pdf(
 542         template  => SL::Helper::CreatePDF->find_template(name => $print_form->{formname}),
 543         variables => $print_form,
 544         variable_content_types => {
 545           longdescription => 'html',
 546           partnotes       => 'html',
 547           notes           => 'html',
 548         },
 549       );
 550       1;
 551     } || push @errors, ref($EVAL_ERROR) eq 'SL::X::FormError' ? $EVAL_ERROR->getMessage : $EVAL_ERROR;
 552   });
 553
 554   return @errors;
 555 }
 556
 557 sub _sales_order_type {
 558   'sales_order';
 559 }
 560
 561 sub _purchase_order_type {
 562   'purchase_order';
 563 }
 564
 565 1;