SL/Controller/Order.pm

   1 package SL::Controller::Order;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use SL::Helper::Flash;
   7 use SL::Presenter;
   8 use SL::PriceSource;
   9
  10 use SL::DB::Order;
  11 use SL::DB::Customer;
  12 use SL::DB::Vendor;
  13 use SL::DB::TaxZone;
  14 use SL::DB::Employee;
  15 use SL::DB::Project;
  16 use SL::DB::Default;
  17 use SL::DB::Unit;
  18
  19 use SL::Helper::DateTime;
  20
  21 use List::Util qw(max first);
  22 use List::MoreUtils qw(none pairwise);
  23
  24 use Rose::Object::MakeMethods::Generic
  25 (
  26  'scalar --get_set_init' => [ qw(order valid_types type cv p) ],
  27 );
  28
  29
  30 # safety
  31 __PACKAGE__->run_before('_check_auth');
  32
  33 __PACKAGE__->run_before('_recalc',
  34                         only => [ qw(edit update save) ]);
  35
  36 __PACKAGE__->run_before('_get_unalterable_data',
  37                         only => [ qw(save save_and_delivery_order create_pdf send_email) ]);
  38
  39 #
  40 # actions
  41 #
  42
  43 sub action_add {
  44   my ($self) = @_;
  45
  46   $self->order->transdate(DateTime->now_local());
  47
  48   $self->_pre_render();
  49   $self->render(
  50     'order/form',
  51     title => $self->type eq _sales_order_type()    ? $::locale->text('Add Sales Order')
  52            : $self->type eq _purchase_order_type() ? $::locale->text('Add Purchase Order')
  53            : '',
  54     %{$self->{template_args}}
  55   );
  56 }
  57
  58 sub action_edit {
  59   my ($self) = @_;
  60
  61   $self->_pre_render();
  62   $self->render(
  63     'order/form',
  64     title => $self->type eq _sales_order_type()    ? $::locale->text('Edit Sales Order')
  65            : $self->type eq _purchase_order_type() ? $::locale->text('Edit Purchase Order')
  66            : '',
  67     %{$self->{template_args}}
  68   );
  69 }
  70
  71 sub action_update {
  72   my ($self) = @_;
  73
  74   $self->_pre_render();
  75   $self->render(
  76     'order/form',
  77     title => $self->type eq _sales_order_type()    ? $::locale->text('Edit Sales Order')
  78            : $self->type eq _purchase_order_type() ? $::locale->text('Edit Purchase Order')
  79            : '',
  80     %{$self->{template_args}}
  81   );
  82 }
  83
  84 sub action_delete {
  85   my ($self) = @_;
  86
  87   my $errors = $self->_delete();
  88
  89   if (scalar @{ $errors }) {
  90     $self->js->flash('error', $_) foreach @{ $errors };
  91     return $self->js->render();
  92   }
  93
  94   flash_later('info', $::locale->text('The order has been deleted'));
  95   my @redirect_params = (
  96     action => 'edit',
  97     type   => $self->type,
  98   );
  99
 100   $self->redirect_to(@redirect_params);
 101 }
 102
 103 sub action_save {
 104   my ($self) = @_;
 105
 106   my $errors = $self->_save();
 107
 108   if (scalar @{ $errors }) {
 109     $self->js->flash('error', $_) foreach @{ $errors };
 110     return $self->js->render();
 111   }
 112
 113   flash_later('info', $::locale->text('The order has been saved'));
 114   my @redirect_params = (
 115     action => 'edit',
 116     type   => $self->type,
 117     id     => $self->order->id,
 118   );
 119
 120   $self->redirect_to(@redirect_params);
 121 }
 122
 123 sub action_customer_vendor_changed {
 124   my ($self) = @_;
 125
 126   my $cv_method = $self->cv;
 127
 128   if ($self->order->$cv_method->contacts && scalar @{ $self->order->$cv_method->contacts } > 0) {
 129     $self->js->show('#cp_row');
 130   } else {
 131     $self->js->hide('#cp_row');
 132   }
 133
 134   if ($self->order->$cv_method->shipto && scalar @{ $self->order->$cv_method->shipto } > 0) {
 135     $self->js->show('#shipto_row');
 136   } else {
 137     $self->js->hide('#shipto_row');
 138   }
 139
 140   $self->order->payment_id($self->order->$cv_method->payment_id);
 141   $self->order->delivery_term_id($self->order->$cv_method->delivery_term_id);
 142
 143   $self->js
 144     ->replaceWith('#order_cp_id',     $self->build_contact_select)
 145     ->replaceWith('#order_shipto_id', $self->build_shipto_select)
 146     ->val('#order_taxzone_id', $self->order->taxzone_id)
 147     ->val('#order_payment_id',       $self->order->payment_id)
 148     ->val('#order_delivery_term_id', $self->order->delivery_term_id)
 149     ->focus('#order_' . $self->cv . '_id')
 150     ->render($self);
 151 }
 152
 153 sub action_add_item {
 154   my ($self) = @_;
 155
 156   my $form_attr = $::form->{add_item};
 157
 158   return unless $form_attr->{parts_id};
 159
 160   my $item = SL::DB::OrderItem->new;
 161   $item->assign_attributes(%$form_attr);
 162
 163   my $part        = SL::DB::Part->new(id => $form_attr->{parts_id})->load;
 164   my $cv_method   = $self->cv;
 165   my $cv_discount = $self->order->$cv_method? $self->order->$cv_method->discount : 0.0;
 166
 167   my %new_attr;
 168   $new_attr{part}        = $part;
 169   $new_attr{description} = $part->description if ! $item->description;
 170   $new_attr{qty}         = 1.0                if ! $item->qty;
 171   $new_attr{unit}        = $part->unit;
 172   $new_attr{sellprice}   = $part->sellprice   if ! $item->sellprice;
 173   $new_attr{discount}    = $cv_discount       if ! $item->discount;
 174
 175   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
 176   # they cannot be retrieved via custom_variables until the order/orderitem is
 177   # saved. Adding empty custom_variables to new orderitem here solves this problem.
 178   $new_attr{custom_variables} = [];
 179
 180   $item->assign_attributes(%new_attr);
 181
 182   $self->order->add_items($item);
 183
 184   $self->_recalc();
 185
 186   my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 187   my $row_as_html = $self->p->render('order/tabs/_row', ITEM => $item, ID => $item_id);
 188
 189   $self->js
 190     ->append('#row_table_id', $row_as_html)
 191     ->val('.add_item_input', '')
 192     ->run('row_table_scroll_down')
 193     ->run('row_set_keyboard_events_by_id', $item_id)
 194     ->on('.recalc', 'change', 'recalc_amounts_and_taxes')
 195     ->focus('#add_item_parts_id_name');
 196
 197   $self->_js_redisplay_amounts_and_taxes;
 198   $self->js->render();
 199 }
 200
 201 sub action_recalc_amounts_and_taxes {
 202   my ($self) = @_;
 203
 204   $self->_recalc();
 205
 206   $self->_js_redisplay_linetotals;
 207   $self->_js_redisplay_amounts_and_taxes;
 208   $self->js->render();
 209 }
 210
 211 sub _js_redisplay_linetotals {
 212   my ($self) = @_;
 213
 214   my @data = map {$::form->format_amount(\%::myconfig, $_->{linetotal}, 2, 0)} @{ $self->order->items };
 215   $self->js
 216     ->run('redisplay_linetotals', \@data);
 217 }
 218
 219 sub _js_redisplay_amounts_and_taxes {
 220   my ($self) = @_;
 221
 222   $self->js
 223     ->html('#netamount_id', $::form->format_amount(\%::myconfig, $self->order->netamount, -2))
 224     ->html('#amount_id',    $::form->format_amount(\%::myconfig, $self->order->amount,    -2))
 225     ->remove('.tax_row')
 226     ->insertBefore($self->build_tax_rows, '#amount_row_id');
 227 }
 228
 229 #
 230 # helpers
 231 #
 232
 233 sub init_valid_types {
 234   [ _sales_order_type(), _purchase_order_type() ];
 235 }
 236
 237 sub init_type {
 238   my ($self) = @_;
 239
 240   if (none { $::form->{type} eq $_ } @{$self->valid_types}) {
 241     die "Not a valid type for order";
 242   }
 243
 244   $self->type($::form->{type});
 245 }
 246
 247 sub init_cv {
 248   my ($self) = @_;
 249
 250   my $cv = $self->type eq _sales_order_type()    ? 'customer'
 251          : $self->type eq _purchase_order_type() ? 'vendor'
 252          : die "Not a valid type for order";
 253
 254   return $cv;
 255 }
 256
 257 sub init_p {
 258   SL::Presenter->get;
 259 }
 260
 261 sub init_order {
 262   _make_order();
 263 }
 264
 265 sub _check_auth {
 266   my ($self) = @_;
 267
 268   my $right_for = { map { $_ => $_.'_edit' } @{$self->valid_types} };
 269
 270   my $right   = $right_for->{ $self->type };
 271   $right    ||= 'DOES_NOT_EXIST';
 272
 273   $::auth->assert($right);
 274 }
 275
 276 sub build_contact_select {
 277   my ($self) = @_;
 278
 279   $self->p->select_tag('order.cp_id', [ $self->order->{$self->cv}->contacts ],
 280                        value_key  => 'cp_id',
 281                        title_key  => 'full_name_dep',
 282                        default    => $self->order->cp_id,
 283                        with_empty => 1,
 284                        style      => 'width: 300px',
 285   );
 286 }
 287
 288 sub build_shipto_select {
 289   my ($self) = @_;
 290
 291   $self->p->select_tag('order.shipto_id', [ $self->order->{$self->cv}->shipto ],
 292                        value_key  => 'shipto_id',
 293                        title_key  => 'displayable_id',
 294                        default    => $self->order->shipto_id,
 295                        with_empty => 1,
 296                        style      => 'width: 300px',
 297   );
 298 }
 299
 300 sub build_tax_rows {
 301   my ($self) = @_;
 302
 303   my $rows_as_html;
 304   foreach my $tax (sort { $a->{tax}->rate cmp $b->{tax}->rate } @{ $self->{taxes} }) {
 305     $rows_as_html .= $self->p->render('order/tabs/_tax_row', TAX => $tax);
 306   }
 307   return $rows_as_html;
 308 }
 309
 310
 311 sub _make_order {
 312   my ($self) = @_;
 313
 314   # add_items adds items to an order with no items for saving, but they cannot
 315   # be retrieved via items until the order is saved. Adding empty items to new
 316   # order here solves this problem.
 317   my $order;
 318   $order   = SL::DB::Manager::Order->find_by(id => $::form->{id}) if $::form->{id};
 319   $order ||= SL::DB::Order->new(orderitems => []);
 320
 321   $order->assign_attributes(%{$::form->{order}});
 322
 323   return $order;
 324 }
 325
 326
 327 sub _recalc {
 328   my ($self) = @_;
 329
 330   # bb: todo: currency later
 331   $self->order->currency_id($::instance_conf->get_currency_id());
 332
 333   my %pat = $self->order->calculate_prices_and_taxes();
 334   $self->{taxes} = [];
 335   foreach my $tax_chart_id (keys %{ $pat{taxes} }) {
 336     my $tax = SL::DB::Manager::Tax->find_by(chart_id => $tax_chart_id);
 337     push(@{ $self->{taxes} }, { amount => $pat{taxes}->{$tax_chart_id},
 338                                 tax    => $tax });
 339   }
 340
 341   pairwise { $a->{linetotal} = $b->{linetotal} } @{$self->order->items}, @{$pat{items}};
 342 }
 343
 344
 345 sub _get_unalterable_data {
 346   my ($self) = @_;
 347
 348   foreach my $item (@{ $self->order->items }) {
 349     if ($item->id) {
 350       # load data from orderitems (db)
 351       my $db_item = SL::DB::OrderItem->new(id => $item->id)->load;
 352       $item->$_($db_item->$_) for qw(active_discount_source active_price_source longdescription);
 353     } else {
 354       # set data from part (or other sources)
 355       $item->longdescription($item->part->notes);
 356       #$item->active_price_source('');
 357       #$item->active_discount_source('');
 358     }
 359
 360     # autovivify all cvars that are not in the form (cvars_by_config can do it).
 361     # workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
 362     foreach my $var (@{ $item->cvars_by_config }) {
 363       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
 364     }
 365     $item->parse_custom_variable_values;
 366   }
 367 }
 368
 369
 370 sub _delete {
 371   my ($self) = @_;
 372
 373   my $errors = [];
 374   my $db = $self->order->db;
 375
 376   $db->do_transaction(
 377     sub {
 378       my @spoolfiles = grep { $_ } map { $_->spoolfile } @{ SL::DB::Manager::Status->get_all(where => [ trans_id => $self->order->id ]) };
 379       $self->order->delete;
 380       my $spool = $::lx_office_conf{paths}->{spool};
 381       unlink map { "$spool/$_" } @spoolfiles if $spool;
 382
 383       1;
 384   }) || push(@{$errors}, $db->error);
 385
 386   return $errors;
 387 }
 388
 389
 390 sub _save {
 391   my ($self) = @_;
 392
 393   my $errors = [];
 394   my $db = $self->order->db;
 395
 396   $db->do_transaction(
 397     sub {
 398       $self->order->save();
 399   }) || push(@{$errors}, $db->error);
 400
 401   return $errors;
 402 }
 403
 404
 405 sub _pre_render {
 406   my ($self) = @_;
 407
 408   $self->{all_taxzones}        = SL::DB::Manager::TaxZone->get_all_sorted();
 409   $self->{all_employees}       = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->employee_id,
 410                                                                                        deleted => 0 ] ],
 411                                                                     sort_by => 'name');
 412   $self->{all_salesmen}        = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->salesman_id,
 413                                                                                        deleted => 0 ] ],
 414                                                                     sort_by => 'name');
 415   $self->{all_projects}        = SL::DB::Manager::Project->get_all(where => [ or => [ id => $self->order->globalproject_id,
 416                                                                                       active => 1 ] ],
 417                                                                    sort_by => 'projectnumber');
 418   $self->{all_payment_terms}   = SL::DB::Manager::PaymentTerm->get_all_sorted();
 419   $self->{all_delivery_terms}  = SL::DB::Manager::DeliveryTerm->get_all_sorted();
 420
 421   $self->{current_employee_id} = SL::DB::Manager::Employee->current->id;
 422 }
 423
 424 sub _sales_order_type {
 425   'sales_order';
 426 }
 427
 428 sub _purchase_order_type {
 429   'purchase_order';
 430 }
 431
 432 1;