SL/Controller/Order.pm

   1 package SL::Controller::Order;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use SL::Helper::Flash;
   7 use SL::Presenter;
   8 use SL::Locale::String;
   9 use SL::SessionFile::Random;
  10 use SL::PriceSource;
  11 use SL::Form;
  12 use SL::Webdav;
  13
  14 use SL::DB::Order;
  15 use SL::DB::Customer;
  16 use SL::DB::Vendor;
  17 use SL::DB::TaxZone;
  18 use SL::DB::Employee;
  19 use SL::DB::Project;
  20 use SL::DB::Default;
  21 use SL::DB::Unit;
  22 use SL::DB::Price;
  23
  24 use SL::Helper::DateTime;
  25 use SL::Helper::CreatePDF qw(:all);
  26
  27 use List::Util qw(max first);
  28 use List::MoreUtils qw(none pairwise first_index);
  29 use English qw(-no_match_vars);
  30 use File::Spec;
  31
  32 use Rose::Object::MakeMethods::Generic
  33 (
  34  'scalar --get_set_init' => [ qw(order valid_types type cv p) ],
  35 );
  36
  37
  38 # safety
  39 __PACKAGE__->run_before('_check_auth');
  40
  41 __PACKAGE__->run_before('_recalc',
  42                         only => [ qw(edit update save save_and_delivery_order create_pdf send_email) ]);
  43
  44 __PACKAGE__->run_before('_get_unalterable_data',
  45                         only => [ qw(save save_and_delivery_order create_pdf send_email) ]);
  46
  47 #
  48 # actions
  49 #
  50
  51 sub action_add {
  52   my ($self) = @_;
  53
  54   $self->order->transdate(DateTime->now_local());
  55   $self->order->reqdate(DateTime->today_local->next_workday) if !$self->order->reqdate;
  56
  57   $self->_pre_render();
  58   $self->render(
  59     'order/form',
  60     title => $self->type eq _sales_order_type()    ? $::locale->text('Add Sales Order')
  61            : $self->type eq _purchase_order_type() ? $::locale->text('Add Purchase Order')
  62            : '',
  63     %{$self->{template_args}}
  64   );
  65 }
  66
  67 sub action_edit {
  68   my ($self) = @_;
  69
  70   $self->_pre_render();
  71   $self->render(
  72     'order/form',
  73     title => $self->type eq _sales_order_type()    ? $::locale->text('Edit Sales Order')
  74            : $self->type eq _purchase_order_type() ? $::locale->text('Edit Purchase Order')
  75            : '',
  76     %{$self->{template_args}}
  77   );
  78 }
  79
  80 sub action_update {
  81   my ($self) = @_;
  82
  83   $self->_pre_render();
  84   $self->render(
  85     'order/form',
  86     title => $self->type eq _sales_order_type()    ? $::locale->text('Edit Sales Order')
  87            : $self->type eq _purchase_order_type() ? $::locale->text('Edit Purchase Order')
  88            : '',
  89     %{$self->{template_args}}
  90   );
  91 }
  92
  93 sub action_save {
  94   my ($self) = @_;
  95
  96   my $errors = $self->_save();
  97
  98   if (scalar @{ $errors }) {
  99     $self->js->flash('error', $_) foreach @{ $errors };
 100     return $self->js->render();
 101   }
 102
 103   flash_later('info', $::locale->text('The order has been saved'));
 104   my @redirect_params = (
 105     action => 'edit',
 106     type   => $self->type,
 107     id     => $self->order->id,
 108   );
 109
 110   $self->redirect_to(@redirect_params);
 111 }
 112
 113 sub action_create_pdf {
 114   my ($self) = @_;
 115
 116   my $pdf;
 117   my @errors = _create_pdf($self->order, \$pdf);
 118   if (scalar @errors) {
 119     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render($self);
 120   }
 121
 122   my $sfile = SL::SessionFile::Random->new(mode => "w");
 123   $sfile->fh->print($pdf);
 124   $sfile->fh->close;
 125
 126   my $key = join('_', Time::HiRes::gettimeofday(), int rand 1000000000000);
 127   $::auth->set_session_value("Order::create_pdf-${key}" => $sfile->file_name);
 128
 129   my $form = Form->new;
 130   $form->{ordnumber} = $self->order->ordnumber;
 131   $form->{formname}  = $self->type;
 132   $form->{type}      = $self->type;
 133   $form->{language}  = 'de';
 134   $form->{format}    = 'pdf';
 135
 136   my $pdf_filename = $form->generate_attachment_filename();
 137
 138   # copy file to webdav folder
 139   if ($self->order->ordnumber && $::instance_conf->get_webdav_documents) {
 140     my $webdav = SL::Webdav->new(
 141       type     => $self->type,
 142       number   => $self->order->ordnumber,
 143     );
 144     my $webdav_file = SL::Webdav::File->new(
 145       webdav   => $webdav,
 146       filename => $pdf_filename,
 147     );
 148     eval {
 149       $webdav_file->store(data => \$pdf);
 150       1;
 151     } or do {
 152       $self->js->flash('error', t8('Storing PDF to webdav folder failed: #1', $@));
 153     }
 154   }
 155
 156   $self->js
 157     ->run('download_pdf', $pdf_filename, $key)
 158     ->flash('info', t8('The PDF has been created'))->render($self);
 159 }
 160
 161 sub action_download_pdf {
 162   my ($self) = @_;
 163
 164   my $key = $::form->{key};
 165   my $tmp_filename = $::auth->get_session_value("Order::create_pdf-${key}");
 166   return $self->send_file(
 167     $tmp_filename,
 168     type => 'application/pdf',
 169     name => $::form->{pdf_filename},
 170   );
 171 }
 172
 173 sub action_show_email_dialog {
 174   my ($self) = @_;
 175
 176   my $cv_method = $self->cv;
 177
 178   if (!$self->order->$cv_method) {
 179     return $self->js->flash('error', t8('Cannot send E-mail without ' . $self->cv))
 180                     ->render($self);
 181   }
 182
 183   $self->{email}->{to}   = $self->order->contact->cp_email if $self->order->contact;
 184   $self->{email}->{to} ||= $self->order->$cv_method->email;
 185   $self->{email}->{cc}   = $self->order->$cv_method->cc;
 186   $self->{email}->{bcc}  = join ', ', grep $_, $self->order->$cv_method->bcc, SL::DB::Default->get->global_bcc;
 187   # Todo: get addresses from shipto, if any
 188
 189   my $form = Form->new;
 190   $form->{ordnumber} = $self->order->ordnumber;
 191   $form->{formname}  = $self->type;
 192   $form->{type}      = $self->type;
 193   $form->{language} = 'de';
 194   $form->{format}   = 'pdf';
 195
 196   $self->{email}->{subject}             = $form->generate_email_subject();
 197   $self->{email}->{attachment_filename} = $form->generate_attachment_filename();
 198   $self->{email}->{message}             = $form->create_email_signature();
 199
 200   my $dialog_html = $self->render('order/tabs/_email_dialog', { output => 0 });
 201   $self->js
 202       ->run('show_email_dialog', $dialog_html)
 203       ->reinit_widgets
 204       ->render($self);
 205 }
 206
 207 # Todo: handling error messages: flash is not displayed in dialog, but in the main form
 208 sub action_send_email {
 209   my ($self) = @_;
 210
 211   my $mail      = Mailer->new;
 212   $mail->{from} = qq|"$::myconfig{name}" <$::myconfig{email}>|;
 213   $mail->{$_}   = $::form->{email}->{$_} for qw(to cc bcc subject message);
 214
 215   my $pdf;
 216   my @errors = _create_pdf($self->order, \$pdf, {media => 'email'});
 217   if (scalar @errors) {
 218     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render($self);
 219   }
 220
 221   $mail->{attachments} = [{ "content" => $pdf,
 222                             "name"    => $::form->{email}->{attachment_filename} }];
 223
 224   if (my $err = $mail->send) {
 225     return $self->js->flash('error', t8('Sending E-mail: ') . $err)
 226                     ->render($self);
 227   }
 228
 229   # internal notes
 230   my $intnotes = $self->order->intnotes;
 231   $intnotes   .= "\n\n" if $self->order->intnotes;
 232   $intnotes   .= t8('[email]')                                                                                        . "\n";
 233   $intnotes   .= t8('Date')       . ": " . $::locale->format_date_object(DateTime->now_local, precision => 'seconds') . "\n";
 234   $intnotes   .= t8('To (email)') . ": " . $mail->{to}                                                                . "\n";
 235   $intnotes   .= t8('Cc')         . ": " . $mail->{cc}                                                                . "\n"    if $mail->{cc};
 236   $intnotes   .= t8('Bcc')        . ": " . $mail->{bcc}                                                               . "\n"    if $mail->{bcc};
 237   $intnotes   .= t8('Subject')    . ": " . $mail->{subject}                                                           . "\n\n";
 238   $intnotes   .= t8('Message')    . ": " . $mail->{message};
 239
 240   $self->js
 241       ->val('#order_intnotes', $intnotes)
 242       ->run('close_email_dialog')
 243       ->render($self);
 244 }
 245
 246 sub action_save_and_delivery_order {
 247   my ($self) = @_;
 248
 249   my $errors = $self->_save();
 250
 251   if (scalar @{ $errors }) {
 252     $self->js->flash('error', $_) foreach @{ $errors };
 253     return $self->js->render();
 254   }
 255
 256   my $delivery_order = $self->order->convert_to_delivery_order($self->order);
 257
 258   flash_later('info', $::locale->text('The order has been saved'));
 259   my @redirect_params = (
 260     controller => 'do.pl',
 261     action     => 'edit',
 262     type       => $delivery_order->type,
 263     id         => $delivery_order->id,
 264     vc         => $delivery_order->is_sales ? 'customer' : 'vendor',
 265   );
 266
 267   $self->redirect_to(@redirect_params);
 268 }
 269
 270 sub action_customer_vendor_changed {
 271   my ($self) = @_;
 272
 273   my $cv_method = $self->cv;
 274
 275   if ($self->order->$cv_method->contacts && scalar @{ $self->order->$cv_method->contacts } > 0) {
 276     $self->js->show('#cp_row');
 277   } else {
 278     $self->js->hide('#cp_row');
 279   }
 280
 281   if ($self->order->$cv_method->shipto && scalar @{ $self->order->$cv_method->shipto } > 0) {
 282     $self->js->show('#shipto_row');
 283   } else {
 284     $self->js->hide('#shipto_row');
 285   }
 286
 287   $self->order->taxzone_id($self->order->$cv_method->taxzone_id);
 288
 289   if ($self->order->is_sales) {
 290     $self->order->taxincluded(defined($self->order->$cv_method->taxincluded_checked)
 291                               ? $self->order->$cv_method->taxincluded_checked
 292                               : $::myconfig{taxincluded_checked});
 293   }
 294
 295   $self->_recalc();
 296
 297   $self->js
 298     ->replaceWith('#order_cp_id',       $self->build_contact_select)
 299     ->replaceWith('#order_shipto_id',   $self->build_shipto_select)
 300     ->val(        '#order_taxzone_id',  $self->order->taxzone_id)
 301     ->val(        '#order_taxincluded', $self->order->taxincluded)
 302     ->focus(      '#order_' . $self->cv . '_id');
 303
 304   $self->_js_redisplay_amounts_and_taxes;
 305   $self->js->render();
 306 }
 307
 308 sub action_add_item {
 309   my ($self) = @_;
 310
 311   my $form_attr = $::form->{add_item};
 312
 313   return unless $form_attr->{parts_id};
 314
 315   my $item = _make_item($self->order, $form_attr);
 316   $self->order->add_items($item);
 317
 318   $self->_recalc();
 319
 320   my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 321   my $row_as_html = $self->p->render('order/tabs/_row', ITEM => $item, ID => $item_id);
 322
 323   $self->js
 324     ->append('#row_table_id', $row_as_html)
 325     ->val('#add_item_parts_id', '')
 326     ->val('#add_item_parts_id_name', '')
 327     ->val('#add_item_description', '')
 328     ->val('#add_item_qty_as_number', '')
 329     ->val('#add_item_sellprice_as_number', '')
 330     ->val('#add_item_discount_as_percent', '')
 331     ->run('row_table_scroll_down')
 332     ->run('row_set_keyboard_events_by_id', $item_id)
 333     ->on('.recalc', 'change', 'recalc_amounts_and_taxes')
 334     ->on('.reformat_number', 'change', 'reformat_number')
 335     ->focus('#add_item_parts_id_name');
 336
 337   $self->_js_redisplay_amounts_and_taxes;
 338   $self->js->render();
 339 }
 340
 341 sub action_show_multi_items_dialog {
 342   my ($self) = @_;
 343
 344   $self->{multi_items}->{parts} = SL::DB::Manager::Part->get_all_sorted(where => [ obsolete => 0 ]);
 345   my $dialog_html = $self->render('order/tabs/_multi_items_dialog', { output => 0 });
 346
 347   $self->js
 348     ->run('show_multi_items_dialog', $dialog_html, t8('Add multiple parts'))
 349     ->reinit_widgets
 350     ->render();
 351 }
 352
 353 sub action_add_multi_items {
 354   my ($self) = @_;
 355
 356   my @form_attr = grep { $_->{qty} } @{ $::form->{add_multi_items} };
 357   return unless scalar @form_attr;
 358
 359   my @items;
 360   foreach my $attr (@form_attr) {
 361     push @items, _make_item($self->order, $attr);
 362   }
 363   $self->order->add_items(@items);
 364
 365   $self->_recalc();
 366
 367   foreach my $item (@items) {
 368     my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 369     my $row_as_html = $self->p->render('order/tabs/_row', ITEM => $item, ID => $item_id);
 370
 371     $self->js
 372         ->append('#row_table_id', $row_as_html)
 373         ->run('row_set_keyboard_events_by_id', $item_id);
 374   }
 375
 376   $self->js
 377     ->run('close_multi_items_dialog')
 378     ->run('row_table_scroll_down')
 379     ->on('.recalc', 'change', 'recalc_amounts_and_taxes')
 380     ->on('.reformat_number', 'change', 'reformat_number')
 381     ->focus('#add_item_parts_id_name');
 382
 383   $self->_js_redisplay_amounts_and_taxes;
 384   $self->js->render();
 385 }
 386
 387 sub action_recalc_amounts_and_taxes {
 388   my ($self) = @_;
 389
 390   $self->_recalc();
 391
 392   $self->_js_redisplay_linetotals;
 393   $self->_js_redisplay_amounts_and_taxes;
 394   $self->js->render();
 395 }
 396
 397 sub action_price_popup {
 398   my ($self) = @_;
 399
 400   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 401   my $item = $self->order->items->[$idx];
 402
 403   $self->render_price_dialog($item);
 404 }
 405
 406 sub _js_redisplay_linetotals {
 407   my ($self) = @_;
 408
 409   my @data = map {$::form->format_amount(\%::myconfig, $_->{linetotal}, 2, 0)} @{ $self->order->items };
 410   $self->js
 411     ->run('redisplay_linetotals', \@data);
 412 }
 413
 414 sub _js_redisplay_amounts_and_taxes {
 415   my ($self) = @_;
 416
 417   if (scalar @{ $self->{taxes} }) {
 418     $self->js->show('#taxincluded_row_id');
 419   } else {
 420     $self->js->hide('#taxincluded_row_id');
 421   }
 422
 423   if ($self->order->taxincluded) {
 424     $self->js->hide('#subtotal_row_id');
 425   } else {
 426     $self->js->show('#subtotal_row_id');
 427   }
 428
 429   $self->js
 430     ->html('#netamount_id', $::form->format_amount(\%::myconfig, $self->order->netamount, -2))
 431     ->html('#amount_id',    $::form->format_amount(\%::myconfig, $self->order->amount,    -2))
 432     ->remove('.tax_row')
 433     ->insertBefore($self->build_tax_rows, '#amount_row_id');
 434 }
 435
 436 #
 437 # helpers
 438 #
 439
 440 sub init_valid_types {
 441   [ _sales_order_type(), _purchase_order_type() ];
 442 }
 443
 444 sub init_type {
 445   my ($self) = @_;
 446
 447   if (none { $::form->{type} eq $_ } @{$self->valid_types}) {
 448     die "Not a valid type for order";
 449   }
 450
 451   $self->type($::form->{type});
 452 }
 453
 454 sub init_cv {
 455   my ($self) = @_;
 456
 457   my $cv = $self->type eq _sales_order_type()    ? 'customer'
 458          : $self->type eq _purchase_order_type() ? 'vendor'
 459          : die "Not a valid type for order";
 460
 461   return $cv;
 462 }
 463
 464 sub init_p {
 465   SL::Presenter->get;
 466 }
 467
 468 sub init_order {
 469   _make_order();
 470 }
 471
 472 sub _check_auth {
 473   my ($self) = @_;
 474
 475   my $right_for = { map { $_ => $_.'_edit' } @{$self->valid_types} };
 476
 477   my $right   = $right_for->{ $self->type };
 478   $right    ||= 'DOES_NOT_EXIST';
 479
 480   $::auth->assert($right);
 481 }
 482
 483 sub build_contact_select {
 484   my ($self) = @_;
 485
 486   $self->p->select_tag('order.cp_id', [ $self->order->{$self->cv}->contacts ],
 487                        value_key  => 'cp_id',
 488                        title_key  => 'full_name_dep',
 489                        default    => $self->order->cp_id,
 490                        with_empty => 1,
 491                        style      => 'width: 300px',
 492   );
 493 }
 494
 495 sub build_shipto_select {
 496   my ($self) = @_;
 497
 498   $self->p->select_tag('order.shipto_id', [ $self->order->{$self->cv}->shipto ],
 499                        value_key  => 'shipto_id',
 500                        title_key  => 'displayable_id',
 501                        default    => $self->order->shipto_id,
 502                        with_empty => 1,
 503                        style      => 'width: 300px',
 504   );
 505 }
 506
 507 sub build_tax_rows {
 508   my ($self) = @_;
 509
 510   my $rows_as_html;
 511   foreach my $tax (sort { $a->{tax}->rate cmp $b->{tax}->rate } @{ $self->{taxes} }) {
 512     $rows_as_html .= $self->p->render('order/tabs/_tax_row', TAX => $tax, TAXINCLUDED => $self->order->taxincluded);
 513   }
 514   return $rows_as_html;
 515 }
 516
 517
 518 sub render_price_dialog {
 519   my ($self, $record_item) = @_;
 520
 521   my $price_source = SL::PriceSource->new(record_item => $record_item, record => $self->order);
 522
 523   $self->js
 524     ->run(
 525       'kivi.io.price_chooser_dialog',
 526       t8('Available Prices'),
 527       $self->render('order/tabs/_price_sources_dialog', { output => 0 }, price_source => $price_source)
 528     )
 529     ->reinit_widgets;
 530
 531 #   if (@errors) {
 532 #     $self->js->text('#dialog_flash_error_content', join ' ', @errors);
 533 #     $self->js->show('#dialog_flash_error');
 534 #   }
 535
 536   $self->js->render;
 537 }
 538
 539 sub _make_order {
 540   my ($self) = @_;
 541
 542   # add_items adds items to an order with no items for saving, but they cannot
 543   # be retrieved via items until the order is saved. Adding empty items to new
 544   # order here solves this problem.
 545   my $order;
 546   $order   = SL::DB::Manager::Order->find_by(id => $::form->{id}) if $::form->{id};
 547   $order ||= SL::DB::Order->new(orderitems => []);
 548
 549   $order->assign_attributes(%{$::form->{order}});
 550
 551   return $order;
 552 }
 553
 554 sub _make_item {
 555   my ($record, $attr) = @_;
 556
 557   my $item = SL::DB::OrderItem->new;
 558   $item->assign_attributes(%$attr);
 559
 560   my $part         = SL::DB::Part->new(id => $attr->{parts_id})->load;
 561   my $price_source = SL::PriceSource->new(record_item => $item, record => $record);
 562
 563   $item->unit($part->unit) if !$item->unit;
 564
 565   my $price_src;
 566   if ($item->sellprice) {
 567     $price_src = $price_source->price_from_source("");
 568     $price_src->price($item->sellprice);
 569   } else {
 570     $price_src = $price_source->best_price
 571            ? $price_source->best_price
 572            : $price_source->price_from_source("");
 573     $price_src->price(0) if !$price_source->best_price;
 574   }
 575
 576   my $discount_src;
 577   if ($item->discount) {
 578     $discount_src = $price_source->discount_from_source("");
 579     $discount_src->discount($item->discount);
 580   } else {
 581     $discount_src = $price_source->best_discount
 582                   ? $price_source->best_discount
 583                   : $price_source->discount_from_source("");
 584     $discount_src->discount(0) if !$price_source->best_discount;
 585   }
 586
 587   my %new_attr;
 588   $new_attr{part}                   = $part;
 589   $new_attr{description}            = $part->description if ! $item->description;
 590   $new_attr{qty}                    = 1.0                if ! $item->qty;
 591   $new_attr{sellprice}              = $price_src->price;
 592   $new_attr{discount}               = $discount_src->discount;
 593   $new_attr{active_price_source}    = $price_src;
 594   $new_attr{active_discount_source} = $discount_src;
 595
 596   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
 597   # they cannot be retrieved via custom_variables until the order/orderitem is
 598   # saved. Adding empty custom_variables to new orderitem here solves this problem.
 599   $new_attr{custom_variables} = [];
 600
 601   $item->assign_attributes(%new_attr);
 602
 603   return $item;
 604 }
 605
 606 sub _recalc {
 607   my ($self) = @_;
 608
 609   # bb: todo: currency later
 610   $self->order->currency_id($::instance_conf->get_currency_id());
 611
 612   my %pat = $self->order->calculate_prices_and_taxes();
 613   $self->{taxes} = [];
 614   foreach my $tax_chart_id (keys %{ $pat{taxes} }) {
 615     my $tax = SL::DB::Manager::Tax->find_by(chart_id => $tax_chart_id);
 616
 617     my @amount_keys = grep { $pat{amounts}->{$_}->{tax_id} == $tax->id } keys %{ $pat{amounts} };
 618     push(@{ $self->{taxes} }, { amount    => $pat{taxes}->{$tax_chart_id},
 619                                 netamount => $pat{amounts}->{$amount_keys[0]}->{amount},
 620                                 tax       => $tax });
 621   }
 622
 623   pairwise { $a->{linetotal} = $b->{linetotal} } @{$self->order->items}, @{$pat{items}};
 624 }
 625
 626
 627 sub _get_unalterable_data {
 628   my ($self) = @_;
 629
 630   foreach my $item (@{ $self->order->items }) {
 631     if ($item->id) {
 632       # load data from orderitems (db)
 633       my $db_item = SL::DB::OrderItem->new(id => $item->id)->load;
 634       $item->$_($db_item->$_) for qw(longdescription);
 635     } else {
 636       # set data from part (or other sources)
 637       $item->longdescription($item->part->notes);
 638     }
 639
 640     # autovivify all cvars that are not in the form (cvars_by_config can do it).
 641     # workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
 642     foreach my $var (@{ $item->cvars_by_config }) {
 643       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
 644     }
 645     $item->parse_custom_variable_values;
 646   }
 647 }
 648
 649
 650 sub _save {
 651   my ($self) = @_;
 652
 653   my $errors = [];
 654   my $db = $self->order->db;
 655
 656   $db->do_transaction(
 657     sub {
 658       $self->order->save();
 659   }) || push(@{$errors}, $db->error);
 660
 661   return $errors;
 662 }
 663
 664
 665 sub _pre_render {
 666   my ($self) = @_;
 667
 668   $self->{all_taxzones}        = SL::DB::Manager::TaxZone->get_all_sorted();
 669   $self->{all_departments}     = SL::DB::Manager::Department->get_all_sorted();
 670   $self->{all_employees}       = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->employee_id,
 671                                                                                        deleted => 0 ] ],
 672                                                                     sort_by => 'name');
 673   $self->{all_salesmen}        = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->salesman_id,
 674                                                                                        deleted => 0 ] ],
 675                                                                     sort_by => 'name');
 676   $self->{all_projects}        = SL::DB::Manager::Project->get_all(where => [ or => [ id => $self->order->globalproject_id,
 677                                                                                       active => 1 ] ],
 678                                                                    sort_by => 'projectnumber');
 679   $self->{all_payment_terms}   = SL::DB::Manager::PaymentTerm->get_all_sorted();
 680   $self->{all_delivery_terms}  = SL::DB::Manager::DeliveryTerm->get_all_sorted();
 681
 682   $self->{current_employee_id} = SL::DB::Manager::Employee->current->id;
 683
 684   foreach  my $item (@{$self->order->items}) {
 685     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
 686     $item->active_price_source(   $price_source->price_from_source(   $item->active_price_source   ));
 687     $item->active_discount_source($price_source->discount_from_source($item->active_discount_source));
 688
 689   }
 690
 691   if ($self->order->ordnumber && $::instance_conf->get_webdav) {
 692     my $webdav = SL::Webdav->new(
 693       type     => $self->type,
 694       number   => $self->order->ordnumber,
 695     );
 696     my $webdav_path = $webdav->webdav_path;
 697     my @all_objects = $webdav->get_all_objects;
 698     @{ $self->{template_args}->{WEBDAV} } = map { { name => $_->filename,
 699                                                     type => t8('File'),
 700                                                     link => File::Spec->catdir($webdav_path, $_->filename),
 701                                                 } } @all_objects;
 702   }
 703
 704   $::request->{layout}->use_javascript("${_}.js")  for qw(ckeditor/ckeditor ckeditor/adapters/jquery);
 705 }
 706
 707 sub _create_pdf {
 708   my ($order, $pdf_ref, $params) = @_;
 709
 710   my $print_form = Form->new('');
 711   $print_form->{type}     = $order->type;
 712   $print_form->{formname} = $order->type;
 713   $print_form->{format}   = $params->{format} || 'pdf',
 714   $print_form->{media}    = $params->{media}  || 'file';
 715
 716   $order->flatten_to_form($print_form, format_amounts => 1);
 717   # flatten_to_form sets payment_terms from customer/vendor - we do not want that here
 718   delete $print_form->{payment_terms} if !$print_form->{payment_id};
 719
 720   my @errors = ();
 721   $print_form->throw_on_error(sub {
 722     eval {
 723       $print_form->prepare_for_printing;
 724
 725       $$pdf_ref = SL::Helper::CreatePDF->create_pdf(
 726         template  => SL::Helper::CreatePDF->find_template(name => $print_form->{formname}),
 727         variables => $print_form,
 728         variable_content_types => {
 729           longdescription => 'html',
 730           partnotes       => 'html',
 731           notes           => 'html',
 732         },
 733       );
 734       1;
 735     } || push @errors, ref($EVAL_ERROR) eq 'SL::X::FormError' ? $EVAL_ERROR->getMessage : $EVAL_ERROR;
 736   });
 737
 738   return @errors;
 739 }
 740
 741 sub _sales_order_type {
 742   'sales_order';
 743 }
 744
 745 sub _purchase_order_type {
 746   'purchase_order';
 747 }
 748
 749 1;
 750
 751 __END__
 752
 753 =encoding utf-8
 754
 755 =head1 NAME
 756
 757 SL::Controller::Order - controller for orders
 758
 759 =head1 TODO
 760
 761 Testing, PriceSources, pricefactor, units, currency, delivered, delivery order created, ...
 762
 763 =head1 AUTHOR
 764
 765 Bernd Bleßmann E<lt>bernd@kivitendo-premium.deE<gt>
 766
 767 =cut
 768