SL/Controller/Order.pm

   1 package SL::Controller::Order;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use SL::Helper::Flash qw(flash_later);
   7 use SL::Presenter::Tag qw(select_tag hidden_tag);
   8 use SL::Locale::String qw(t8);
   9 use SL::SessionFile::Random;
  10 use SL::PriceSource;
  11 use SL::Webdav;
  12 use SL::File;
  13 use SL::MIME;
  14 use SL::Util qw(trim);
  15 use SL::YAML;
  16 use SL::DB::Order;
  17 use SL::DB::Default;
  18 use SL::DB::Unit;
  19 use SL::DB::Part;
  20 use SL::DB::PartsGroup;
  21 use SL::DB::Printer;
  22 use SL::DB::Language;
  23 use SL::DB::RecordLink;
  24
  25 use SL::Helper::CreatePDF qw(:all);
  26 use SL::Helper::PrintOptions;
  27 use SL::Helper::ShippedQty;
  28 use SL::Helper::UserPreferences::PositionsScrollbar;
  29
  30 use SL::Controller::Helper::GetModels;
  31
  32 use List::Util qw(first);
  33 use List::UtilsBy qw(sort_by uniq_by);
  34 use List::MoreUtils qw(any none pairwise first_index);
  35 use English qw(-no_match_vars);
  36 use File::Spec;
  37 use Cwd;
  38 use Sort::Naturally;
  39
  40 use Rose::Object::MakeMethods::Generic
  41 (
  42  scalar => [ qw(item_ids_to_delete) ],
  43  'scalar --get_set_init' => [ qw(order valid_types type cv p multi_items_models all_price_factors search_cvpartnumber) ],
  44 );
  45
  46
  47 # safety
  48 __PACKAGE__->run_before('check_auth');
  49
  50 __PACKAGE__->run_before('recalc',
  51                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice save_and_ap_transaction
  52                                      print send_email) ]);
  53
  54 __PACKAGE__->run_before('get_unalterable_data',
  55                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice save_and_ap_transaction
  56                                      print send_email) ]);
  57
  58 #
  59 # actions
  60 #
  61
  62 # add a new order
  63 sub action_add {
  64   my ($self) = @_;
  65
  66   $self->order->transdate(DateTime->now_local());
  67   my $extra_days = $self->{type} eq 'sales_quotation' ? $::instance_conf->get_reqdate_interval       :
  68                    $self->{type} eq 'sales_order'     ? $::instance_conf->get_delivery_date_interval : 1;
  69   $self->order->reqdate(DateTime->today_local->next_workday(extra_days => $extra_days)) if !$self->order->reqdate;
  70
  71
  72   $self->pre_render();
  73   $self->render(
  74     'order/form',
  75     title => $self->get_title_for('add'),
  76     %{$self->{template_args}}
  77   );
  78 }
  79
  80 # edit an existing order
  81 sub action_edit {
  82   my ($self) = @_;
  83
  84   if ($::form->{id}) {
  85     $self->load_order;
  86
  87   } else {
  88     # this is to edit an order from an unsaved order object
  89
  90     # set item ids to new fake id, to identify them as new items
  91     foreach my $item (@{$self->order->items_sorted}) {
  92       $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
  93     }
  94     # trigger rendering values for second row/longdescription as hidden,
  95     # because they are loaded only on demand. So we need to keep the values
  96     # from the source.
  97     $_->{render_second_row}      = 1 for @{ $self->order->items_sorted };
  98     $_->{render_longdescription} = 1 for @{ $self->order->items_sorted };
  99   }
 100
 101   $self->recalc();
 102   $self->pre_render();
 103   $self->render(
 104     'order/form',
 105     title => $self->get_title_for('edit'),
 106     %{$self->{template_args}}
 107   );
 108 }
 109
 110 # edit a collective order (consisting of one or more existing orders)
 111 sub action_edit_collective {
 112   my ($self) = @_;
 113
 114   # collect order ids
 115   my @multi_ids = map {
 116     $_ =~ m{^multi_id_(\d+)$} && $::form->{'multi_id_' . $1} && $::form->{'trans_id_' . $1} && $::form->{'trans_id_' . $1}
 117   } grep { $_ =~ m{^multi_id_\d+$} } keys %$::form;
 118
 119   # fall back to add if no ids are given
 120   if (scalar @multi_ids == 0) {
 121     $self->action_add();
 122     return;
 123   }
 124
 125   # fall back to save as new if only one id is given
 126   if (scalar @multi_ids == 1) {
 127     $self->order(SL::DB::Order->new(id => $multi_ids[0])->load);
 128     $self->action_save_as_new();
 129     return;
 130   }
 131
 132   # make new order from given orders
 133   my @multi_orders = map { SL::DB::Order->new(id => $_)->load } @multi_ids;
 134   $self->{converted_from_oe_id} = join ' ', map { $_->id } @multi_orders;
 135   $self->order(SL::DB::Order->new_from_multi(\@multi_orders, sort_sources_by => 'transdate'));
 136
 137   $self->action_edit();
 138 }
 139
 140 # delete the order
 141 sub action_delete {
 142   my ($self) = @_;
 143
 144   my $errors = $self->delete();
 145
 146   if (scalar @{ $errors }) {
 147     $self->js->flash('error', $_) foreach @{ $errors };
 148     return $self->js->render();
 149   }
 150
 151   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been deleted')
 152            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been deleted')
 153            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been deleted')
 154            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been deleted')
 155            : '';
 156   flash_later('info', $text);
 157
 158   my @redirect_params = (
 159     action => 'add',
 160     type   => $self->type,
 161   );
 162
 163   $self->redirect_to(@redirect_params);
 164 }
 165
 166 # save the order
 167 sub action_save {
 168   my ($self) = @_;
 169
 170   my $errors = $self->save();
 171
 172   if (scalar @{ $errors }) {
 173     $self->js->flash('error', $_) foreach @{ $errors };
 174     return $self->js->render();
 175   }
 176
 177   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
 178            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
 179            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
 180            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
 181            : '';
 182   flash_later('info', $text);
 183
 184   my @redirect_params = (
 185     action => 'edit',
 186     type   => $self->type,
 187     id     => $self->order->id,
 188   );
 189
 190   $self->redirect_to(@redirect_params);
 191 }
 192
 193 # save the order as new document an open it for edit
 194 sub action_save_as_new {
 195   my ($self) = @_;
 196
 197   my $order = $self->order;
 198
 199   if (!$order->id) {
 200     $self->js->flash('error', t8('This object has not been saved yet.'));
 201     return $self->js->render();
 202   }
 203
 204   # load order from db to check if values changed
 205   my $saved_order = SL::DB::Order->new(id => $order->id)->load;
 206
 207   my %new_attrs;
 208   # Lets assign a new number if the user hasn't changed the previous one.
 209   # If it has been changed manually then use it as-is.
 210   $new_attrs{number}    = (trim($order->number) eq $saved_order->number)
 211                         ? ''
 212                         : trim($order->number);
 213
 214   # Clear transdate unless changed
 215   $new_attrs{transdate} = ($order->transdate == $saved_order->transdate)
 216                         ? DateTime->today_local
 217                         : $order->transdate;
 218
 219   # Set new reqdate unless changed
 220   if ($order->reqdate == $saved_order->reqdate) {
 221     my $extra_days = $self->{type} eq 'sales_quotation' ? $::instance_conf->get_reqdate_interval       :
 222                      $self->{type} eq 'sales_order'     ? $::instance_conf->get_delivery_date_interval : 1;
 223     $new_attrs{reqdate} = DateTime->today_local->next_workday(extra_days => $extra_days);
 224   } else {
 225     $new_attrs{reqdate} = $order->reqdate;
 226   }
 227
 228   # Update employee
 229   $new_attrs{employee}  = SL::DB::Manager::Employee->current;
 230
 231   # Create new record from current one
 232   $self->order(SL::DB::Order->new_from($order, destination_type => $order->type, attributes => \%new_attrs));
 233
 234   # no linked records on save as new
 235   delete $::form->{$_} for qw(converted_from_oe_id converted_from_orderitems_ids);
 236
 237   # save
 238   $self->action_save();
 239 }
 240
 241 # print the order
 242 #
 243 # This is called if "print" is pressed in the print dialog.
 244 # If PDF creation was requested and succeeded, the pdf is stored in a session
 245 # file and the filename is stored as session value with an unique key. A
 246 # javascript function with this key is then called. This function calls the
 247 # download action below (action_download_pdf), which offers the file for
 248 # download.
 249 sub action_print {
 250   my ($self) = @_;
 251
 252   my $errors = $self->save();
 253
 254   if (scalar @{ $errors }) {
 255     $self->js->flash('error', $_) foreach @{ $errors };
 256     return $self->js->render();
 257   }
 258
 259   $self->js_reset_order_and_item_ids_after_save;
 260
 261   my $format      = $::form->{print_options}->{format};
 262   my $media       = $::form->{print_options}->{media};
 263   my $formname    = $::form->{print_options}->{formname};
 264   my $copies      = $::form->{print_options}->{copies};
 265   my $groupitems  = $::form->{print_options}->{groupitems};
 266
 267   # only pdf and opendocument by now
 268   if (none { $format eq $_ } qw(pdf opendocument opendocument_pdf)) {
 269     return $self->js->flash('error', t8('Format \'#1\' is not supported yet/anymore.', $format))->render;
 270   }
 271
 272   # only screen or printer by now
 273   if (none { $media eq $_ } qw(screen printer)) {
 274     return $self->js->flash('error', t8('Media \'#1\' is not supported yet/anymore.', $media))->render;
 275   }
 276
 277   my $language;
 278   $language = SL::DB::Language->new(id => $::form->{print_options}->{language_id})->load if $::form->{print_options}->{language_id};
 279
 280   # create a form for generate_attachment_filename
 281   my $form   = Form->new;
 282   $form->{$self->nr_key()}  = $self->order->number;
 283   $form->{type}             = $self->type;
 284   $form->{format}           = $format;
 285   $form->{formname}         = $formname;
 286   $form->{language}         = '_' . $language->template_code if $language;
 287   my $pdf_filename          = $form->generate_attachment_filename();
 288
 289   my $pdf;
 290   my @errors = generate_pdf($self->order, \$pdf, { format     => $format,
 291                                                    formname   => $formname,
 292                                                    language   => $language,
 293                                                    groupitems => $groupitems });
 294   if (scalar @errors) {
 295     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render;
 296   }
 297
 298   if ($media eq 'screen') {
 299     # screen/download
 300     my $sfile = SL::SessionFile::Random->new(mode => "w");
 301     $sfile->fh->print($pdf);
 302     $sfile->fh->close;
 303
 304     my $key = join('_', Time::HiRes::gettimeofday(), int rand 1000000000000);
 305     $::auth->set_session_value("Order::print-${key}" => $sfile->file_name);
 306
 307     $self->js
 308     ->run('kivi.Order.download_pdf', $pdf_filename, $key)
 309     ->flash('info', t8('The PDF has been created'));
 310
 311   } elsif ($media eq 'printer') {
 312     # printer
 313     my $printer_id = $::form->{print_options}->{printer_id};
 314     SL::DB::Printer->new(id => $printer_id)->load->print_document(
 315       copies  => $copies,
 316       content => $pdf,
 317     );
 318
 319     $self->js->flash('info', t8('The PDF has been printed'));
 320   }
 321
 322   # copy file to webdav folder
 323   if ($self->order->number && $::instance_conf->get_webdav_documents) {
 324     my $webdav = SL::Webdav->new(
 325       type     => $self->type,
 326       number   => $self->order->number,
 327     );
 328     my $webdav_file = SL::Webdav::File->new(
 329       webdav   => $webdav,
 330       filename => $pdf_filename,
 331     );
 332     eval {
 333       $webdav_file->store(data => \$pdf);
 334       1;
 335     } or do {
 336       $self->js->flash('error', t8('Storing PDF to webdav folder failed: #1', $@));
 337     }
 338   }
 339   if ($self->order->number && $::instance_conf->get_doc_storage) {
 340     eval {
 341       SL::File->save(object_id     => $self->order->id,
 342                      object_type   => $self->type,
 343                      mime_type     => 'application/pdf',
 344                      source        => 'created',
 345                      file_type     => 'document',
 346                      file_name     => $pdf_filename,
 347                      file_contents => $pdf);
 348       1;
 349     } or do {
 350       $self->js->flash('error', t8('Storing PDF in storage backend failed: #1', $@));
 351     }
 352   }
 353   $self->js->render;
 354 }
 355
 356 # offer pdf for download
 357 #
 358 # It needs to get the key for the session value to get the pdf file.
 359 sub action_download_pdf {
 360   my ($self) = @_;
 361
 362   my $key = $::form->{key};
 363   my $tmp_filename = $::auth->get_session_value("Order::print-${key}");
 364   return $self->send_file(
 365     $tmp_filename,
 366     type => SL::MIME->mime_type_from_ext($::form->{pdf_filename}),
 367     name => $::form->{pdf_filename},
 368   );
 369 }
 370
 371 # open the email dialog
 372 sub action_show_email_dialog {
 373   my ($self) = @_;
 374
 375   my $cv_method = $self->cv;
 376
 377   if (!$self->order->$cv_method) {
 378     return $self->js->flash('error', $self->cv eq 'customer' ? t8('Cannot send E-mail without customer given') : t8('Cannot send E-mail without vendor given'))
 379                     ->render($self);
 380   }
 381
 382   my $email_form;
 383   $email_form->{to}   = $self->order->contact->cp_email if $self->order->contact;
 384   $email_form->{to} ||= $self->order->$cv_method->email;
 385   $email_form->{cc}   = $self->order->$cv_method->cc;
 386   $email_form->{bcc}  = join ', ', grep $_, $self->order->$cv_method->bcc, SL::DB::Default->get->global_bcc;
 387   # Todo: get addresses from shipto, if any
 388
 389   my $form = Form->new;
 390   $form->{$self->nr_key()}  = $self->order->number;
 391   $form->{formname}         = $self->type;
 392   $form->{type}             = $self->type;
 393   $form->{language}         = 'de';
 394   $form->{format}           = 'pdf';
 395
 396   $email_form->{subject}             = $form->generate_email_subject();
 397   $email_form->{attachment_filename} = $form->generate_attachment_filename();
 398   $email_form->{message}             = $form->generate_email_body();
 399   $email_form->{js_send_function}    = 'kivi.Order.send_email()';
 400
 401   my %files = $self->get_files_for_email_dialog();
 402   my $dialog_html = $self->render('common/_send_email_dialog', { output => 0 },
 403                                   email_form  => $email_form,
 404                                   show_bcc    => $::auth->assert('email_bcc', 'may fail'),
 405                                   FILES       => \%files,
 406                                   is_customer => $self->cv eq 'customer',
 407   );
 408
 409   $self->js
 410       ->run('kivi.Order.show_email_dialog', $dialog_html)
 411       ->reinit_widgets
 412       ->render($self);
 413 }
 414
 415 # send email
 416 #
 417 # Todo: handling error messages: flash is not displayed in dialog, but in the main form
 418 sub action_send_email {
 419   my ($self) = @_;
 420
 421   my $errors = $self->save();
 422
 423   if (scalar @{ $errors }) {
 424     $self->js->run('kivi.Order.close_email_dialog');
 425     $self->js->flash('error', $_) foreach @{ $errors };
 426     return $self->js->render();
 427   }
 428
 429   $self->js_reset_order_and_item_ids_after_save;
 430
 431   my $email_form  = delete $::form->{email_form};
 432   my %field_names = (to => 'email');
 433
 434   $::form->{ $field_names{$_} // $_ } = $email_form->{$_} for keys %{ $email_form };
 435
 436   # for Form::cleanup which may be called in Form::send_email
 437   $::form->{cwd}    = getcwd();
 438   $::form->{tmpdir} = $::lx_office_conf{paths}->{userspath};
 439
 440   $::form->{$_}     = $::form->{print_options}->{$_} for keys %{ $::form->{print_options} };
 441   $::form->{media}  = 'email';
 442
 443   if (($::form->{attachment_policy} // '') !~ m{^(?:old_file|no_file)$}) {
 444     my $language;
 445     $language = SL::DB::Language->new(id => $::form->{print_options}->{language_id})->load if $::form->{print_options}->{language_id};
 446
 447     my $pdf;
 448     my @errors = generate_pdf($self->order, \$pdf, {media      => $::form->{media},
 449                                                     format     => $::form->{print_options}->{format},
 450                                                     formname   => $::form->{print_options}->{formname},
 451                                                     language   => $language,
 452                                                     groupitems => $::form->{print_options}->{groupitems}});
 453     if (scalar @errors) {
 454       return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render($self);
 455     }
 456
 457     my $sfile = SL::SessionFile::Random->new(mode => "w");
 458     $sfile->fh->print($pdf);
 459     $sfile->fh->close;
 460
 461     $::form->{tmpfile} = $sfile->file_name;
 462     $::form->{tmpdir}  = $sfile->get_path; # for Form::cleanup which may be called in Form::send_email
 463   }
 464
 465   $::form->send_email(\%::myconfig, 'pdf');
 466
 467   # internal notes
 468   my $intnotes = $self->order->intnotes;
 469   $intnotes   .= "\n\n" if $self->order->intnotes;
 470   $intnotes   .= t8('[email]')                                                                                        . "\n";
 471   $intnotes   .= t8('Date')       . ": " . $::locale->format_date_object(DateTime->now_local, precision => 'seconds') . "\n";
 472   $intnotes   .= t8('To (email)') . ": " . $::form->{email}                                                           . "\n";
 473   $intnotes   .= t8('Cc')         . ": " . $::form->{cc}                                                              . "\n"    if $::form->{cc};
 474   $intnotes   .= t8('Bcc')        . ": " . $::form->{bcc}                                                             . "\n"    if $::form->{bcc};
 475   $intnotes   .= t8('Subject')    . ": " . $::form->{subject}                                                         . "\n\n";
 476   $intnotes   .= t8('Message')    . ": " . $::form->{message};
 477
 478   $self->order->update_attributes(intnotes => $intnotes);
 479
 480   $self->js
 481       ->val('#order_intnotes', $intnotes)
 482       ->run('kivi.Order.close_email_dialog')
 483       ->flash('info', t8('The email has been sent.'))
 484       ->render($self);
 485 }
 486
 487 # open the periodic invoices config dialog
 488 #
 489 # If there are values in the form (i.e. dialog was opened before),
 490 # then use this values. Create new ones, else.
 491 sub action_show_periodic_invoices_config_dialog {
 492   my ($self) = @_;
 493
 494   my $config = make_periodic_invoices_config_from_yaml(delete $::form->{config});
 495   $config  ||= SL::DB::Manager::PeriodicInvoicesConfig->find_by(oe_id => $::form->{id}) if $::form->{id};
 496   $config  ||= SL::DB::PeriodicInvoicesConfig->new(periodicity             => 'm',
 497                                                    order_value_periodicity => 'p', # = same as periodicity
 498                                                    start_date_as_date      => $::form->{transdate_as_date} || $::form->current_date,
 499                                                    extend_automatically_by => 12,
 500                                                    active                  => 1,
 501                                                    email_subject           => GenericTranslations->get(
 502                                                                                 language_id      => $::form->{language_id},
 503                                                                                 translation_type =>"preset_text_periodic_invoices_email_subject"),
 504                                                    email_body              => GenericTranslations->get(
 505                                                                                 language_id      => $::form->{language_id},
 506                                                                                 translation_type =>"preset_text_periodic_invoices_email_body"),
 507   );
 508   $config->periodicity('m')             if none { $_ eq $config->periodicity             }       @SL::DB::PeriodicInvoicesConfig::PERIODICITIES;
 509   $config->order_value_periodicity('p') if none { $_ eq $config->order_value_periodicity } ('p', @SL::DB::PeriodicInvoicesConfig::ORDER_VALUE_PERIODICITIES);
 510
 511   $::form->get_lists(printers => "ALL_PRINTERS",
 512                      charts   => { key       => 'ALL_CHARTS',
 513                                    transdate => 'current_date' });
 514
 515   $::form->{AR} = [ grep { $_->{link} =~ m/(?:^|:)AR(?::|$)/ } @{ $::form->{ALL_CHARTS} } ];
 516
 517   if ($::form->{customer_id}) {
 518     $::form->{ALL_CONTACTS} = SL::DB::Manager::Contact->get_all_sorted(where => [ cp_cv_id => $::form->{customer_id} ]);
 519     $::form->{email_recipient_invoice_address} = SL::DB::Manager::Customer->find_by(id => $::form->{customer_id})->invoice_mail;
 520   }
 521
 522   $self->render('oe/edit_periodic_invoices_config', { layout => 0 },
 523                 popup_dialog             => 1,
 524                 popup_js_close_function  => 'kivi.Order.close_periodic_invoices_config_dialog()',
 525                 popup_js_assign_function => 'kivi.Order.assign_periodic_invoices_config()',
 526                 config                   => $config,
 527                 %$::form);
 528 }
 529
 530 # assign the values of the periodic invoices config dialog
 531 # as yaml in the hidden tag and set the status.
 532 sub action_assign_periodic_invoices_config {
 533   my ($self) = @_;
 534
 535   $::form->isblank('start_date_as_date', $::locale->text('The start date is missing.'));
 536
 537   my $config = { active                     => $::form->{active}       ? 1 : 0,
 538                  terminated                 => $::form->{terminated}   ? 1 : 0,
 539                  direct_debit               => $::form->{direct_debit} ? 1 : 0,
 540                  periodicity                => (any { $_ eq $::form->{periodicity}             }       @SL::DB::PeriodicInvoicesConfig::PERIODICITIES)              ? $::form->{periodicity}             : 'm',
 541                  order_value_periodicity    => (any { $_ eq $::form->{order_value_periodicity} } ('p', @SL::DB::PeriodicInvoicesConfig::ORDER_VALUE_PERIODICITIES)) ? $::form->{order_value_periodicity} : 'p',
 542                  start_date_as_date         => $::form->{start_date_as_date},
 543                  end_date_as_date           => $::form->{end_date_as_date},
 544                  first_billing_date_as_date => $::form->{first_billing_date_as_date},
 545                  print                      => $::form->{print}      ? 1                         : 0,
 546                  printer_id                 => $::form->{print}      ? $::form->{printer_id} * 1 : undef,
 547                  copies                     => $::form->{copies} * 1 ? $::form->{copies}         : 1,
 548                  extend_automatically_by    => $::form->{extend_automatically_by}    * 1 || undef,
 549                  ar_chart_id                => $::form->{ar_chart_id} * 1,
 550                  send_email                 => $::form->{send_email} ? 1 : 0,
 551                  email_recipient_contact_id => $::form->{email_recipient_contact_id} * 1 || undef,
 552                  email_recipient_address    => $::form->{email_recipient_address},
 553                  email_sender               => $::form->{email_sender},
 554                  email_subject              => $::form->{email_subject},
 555                  email_body                 => $::form->{email_body},
 556                };
 557
 558   my $periodic_invoices_config = SL::YAML::Dump($config);
 559
 560   my $status = $self->get_periodic_invoices_status($config);
 561
 562   $self->js
 563     ->remove('#order_periodic_invoices_config')
 564     ->insertAfter(hidden_tag('order.periodic_invoices_config', $periodic_invoices_config), '#periodic_invoices_status')
 565     ->run('kivi.Order.close_periodic_invoices_config_dialog')
 566     ->html('#periodic_invoices_status', $status)
 567     ->flash('info', t8('The periodic invoices config has been assigned.'))
 568     ->render($self);
 569 }
 570
 571 sub action_get_has_active_periodic_invoices {
 572   my ($self) = @_;
 573
 574   my $config = make_periodic_invoices_config_from_yaml(delete $::form->{config});
 575   $config  ||= SL::DB::Manager::PeriodicInvoicesConfig->find_by(oe_id => $::form->{id}) if $::form->{id};
 576
 577   my $has_active_periodic_invoices =
 578        $self->type eq sales_order_type()
 579     && $config
 580     && $config->active
 581     && (!$config->end_date || ($config->end_date > DateTime->today_local))
 582     && $config->get_previous_billed_period_start_date;
 583
 584   $_[0]->render(\ !!$has_active_periodic_invoices, { type => 'text' });
 585 }
 586
 587 # save the order and redirect to the frontend subroutine for a new
 588 # delivery order
 589 sub action_save_and_delivery_order {
 590   my ($self) = @_;
 591
 592   my $errors = $self->save();
 593
 594   if (scalar @{ $errors }) {
 595     $self->js->flash('error', $_) foreach @{ $errors };
 596     return $self->js->render();
 597   }
 598
 599   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
 600            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
 601            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
 602            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
 603            : '';
 604   flash_later('info', $text);
 605
 606   my @redirect_params = (
 607     controller => 'oe.pl',
 608     action     => 'oe_delivery_order_from_order',
 609     id         => $self->order->id,
 610   );
 611
 612   $self->redirect_to(@redirect_params);
 613 }
 614
 615 # save the order and redirect to the frontend subroutine for a new
 616 # invoice
 617 sub action_save_and_invoice {
 618   my ($self) = @_;
 619
 620   my $errors = $self->save();
 621
 622   if (scalar @{ $errors }) {
 623     $self->js->flash('error', $_) foreach @{ $errors };
 624     return $self->js->render();
 625   }
 626
 627   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
 628            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
 629            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
 630            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
 631            : '';
 632   flash_later('info', $text);
 633
 634   my @redirect_params = (
 635     controller => 'oe.pl',
 636     action     => 'oe_invoice_from_order',
 637     id         => $self->order->id,
 638   );
 639
 640   $self->redirect_to(@redirect_params);
 641 }
 642
 643 # workflow from sales quotation to sales order
 644 sub action_sales_order {
 645   $_[0]->workflow_sales_or_purchase_order();
 646 }
 647
 648 # workflow from rfq to purchase order
 649 sub action_purchase_order {
 650   $_[0]->workflow_sales_or_purchase_order();
 651 }
 652
 653 # workflow from purchase order to ap transaction
 654 sub action_save_and_ap_transaction {
 655   my ($self) = @_;
 656
 657   my $errors = $self->save();
 658
 659   if (scalar @{ $errors }) {
 660     $self->js->flash('error', $_) foreach @{ $errors };
 661     return $self->js->render();
 662   }
 663
 664   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
 665            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
 666            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
 667            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
 668            : '';
 669   flash_later('info', $text);
 670
 671   my @redirect_params = (
 672     controller => 'ap.pl',
 673     action     => 'add_from_purchase_order',
 674     id         => $self->order->id,
 675   );
 676
 677   $self->redirect_to(@redirect_params);
 678 }
 679
 680 # set form elements in respect to a changed customer or vendor
 681 #
 682 # This action is called on an change of the customer/vendor picker.
 683 sub action_customer_vendor_changed {
 684   my ($self) = @_;
 685
 686   setup_order_from_cv($self->order);
 687   $self->recalc();
 688
 689   my $cv_method = $self->cv;
 690
 691   if ($self->order->$cv_method->contacts && scalar @{ $self->order->$cv_method->contacts } > 0) {
 692     $self->js->show('#cp_row');
 693   } else {
 694     $self->js->hide('#cp_row');
 695   }
 696
 697   if ($self->order->$cv_method->shipto && scalar @{ $self->order->$cv_method->shipto } > 0) {
 698     $self->js->show('#shipto_row');
 699   } else {
 700     $self->js->hide('#shipto_row');
 701   }
 702
 703   $self->js->val( '#order_salesman_id',      $self->order->salesman_id)        if $self->order->is_sales;
 704
 705   $self->js
 706     ->replaceWith('#order_cp_id',            $self->build_contact_select)
 707     ->replaceWith('#order_shipto_id',        $self->build_shipto_select)
 708     ->replaceWith('#business_info_row',      $self->build_business_info_row)
 709     ->val(        '#order_taxzone_id',       $self->order->taxzone_id)
 710     ->val(        '#order_taxincluded',      $self->order->taxincluded)
 711     ->val(        '#order_payment_id',       $self->order->payment_id)
 712     ->val(        '#order_delivery_term_id', $self->order->delivery_term_id)
 713     ->val(        '#order_intnotes',         $self->order->intnotes)
 714     ->val(        '#language_id',            $self->order->$cv_method->language_id)
 715     ->focus(      '#order_' . $self->cv . '_id');
 716
 717   $self->js_redisplay_amounts_and_taxes;
 718   $self->js_redisplay_cvpartnumbers;
 719   $self->js->render();
 720 }
 721
 722 # open the dialog for customer/vendor details
 723 sub action_show_customer_vendor_details_dialog {
 724   my ($self) = @_;
 725
 726   my $is_customer = 'customer' eq $::form->{vc};
 727   my $cv;
 728   if ($is_customer) {
 729     $cv = SL::DB::Customer->new(id => $::form->{vc_id})->load;
 730   } else {
 731     $cv = SL::DB::Vendor->new(id => $::form->{vc_id})->load;
 732   }
 733
 734   my %details = map { $_ => $cv->$_ } @{$cv->meta->columns};
 735   $details{discount_as_percent} = $cv->discount_as_percent;
 736   $details{creditlimt}          = $cv->creditlimit_as_number;
 737   $details{business}            = $cv->business->description      if $cv->business;
 738   $details{language}            = $cv->language_obj->description  if $cv->language_obj;
 739   $details{delivery_terms}      = $cv->delivery_term->description if $cv->delivery_term;
 740   $details{payment_terms}       = $cv->payment->description       if $cv->payment;
 741   $details{pricegroup}          = $cv->pricegroup->pricegroup     if $is_customer && $cv->pricegroup;
 742
 743   foreach my $entry (@{ $cv->shipto }) {
 744     push @{ $details{SHIPTO} },   { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 745   }
 746   foreach my $entry (@{ $cv->contacts }) {
 747     push @{ $details{CONTACTS} }, { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 748   }
 749
 750   $_[0]->render('common/show_vc_details', { layout => 0 },
 751                 is_customer => $is_customer,
 752                 %details);
 753
 754 }
 755
 756 # called if a unit in an existing item row is changed
 757 sub action_unit_changed {
 758   my ($self) = @_;
 759
 760   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 761   my $item = $self->order->items_sorted->[$idx];
 762
 763   my $old_unit_obj = SL::DB::Unit->new(name => $::form->{old_unit})->load;
 764   $item->sellprice($item->unit_obj->convert_to($item->sellprice, $old_unit_obj));
 765
 766   $self->recalc();
 767
 768   $self->js
 769     ->run('kivi.Order.update_sellprice', $::form->{item_id}, $item->sellprice_as_number);
 770   $self->js_redisplay_line_values;
 771   $self->js_redisplay_amounts_and_taxes;
 772   $self->js->render();
 773 }
 774
 775 # add an item row for a new item entered in the input row
 776 sub action_add_item {
 777   my ($self) = @_;
 778
 779   my $form_attr = $::form->{add_item};
 780
 781   return unless $form_attr->{parts_id};
 782
 783   my $item = new_item($self->order, $form_attr);
 784
 785   $self->order->add_items($item);
 786
 787   $self->recalc();
 788
 789   $self->get_item_cvpartnumber($item);
 790
 791   my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 792   my $row_as_html = $self->p->render('order/tabs/_row',
 793                                      ITEM                => $item,
 794                                      ID                  => $item_id,
 795                                      TYPE                => $self->type,
 796                                      ALL_PRICE_FACTORS   => $self->all_price_factors,
 797                                      SEARCH_CVPARTNUMBER => $self->search_cvpartnumber,
 798   );
 799
 800   $self->js
 801     ->append('#row_table_id', $row_as_html);
 802
 803   if ( $item->part->is_assortment ) {
 804     $form_attr->{qty_as_number} = 1 unless $form_attr->{qty_as_number};
 805     foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 806       my $attr = { parts_id => $assortment_item->parts_id,
 807                    qty      => $assortment_item->qty * $::form->parse_amount(\%::myconfig, $form_attr->{qty_as_number}), # TODO $form_attr->{unit}
 808                    unit     => $assortment_item->unit,
 809                    description => $assortment_item->part->description,
 810                  };
 811       my $item = new_item($self->order, $attr);
 812
 813       # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 814       $item->discount(1) unless $assortment_item->charge;
 815
 816       $self->order->add_items( $item );
 817       $self->recalc();
 818       $self->get_item_cvpartnumber($item);
 819       my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 820       my $row_as_html = $self->p->render('order/tabs/_row',
 821                                          ITEM                => $item,
 822                                          ID                  => $item_id,
 823                                          TYPE                => $self->type,
 824                                          ALL_PRICE_FACTORS   => $self->all_price_factors,
 825                                          SEARCH_CVPARTNUMBER => $self->search_cvpartnumber,
 826       );
 827       $self->js
 828         ->append('#row_table_id', $row_as_html);
 829     };
 830   };
 831
 832   $self->js
 833     ->val('.add_item_input', '')
 834     ->run('kivi.Order.init_row_handlers')
 835     ->run('kivi.Order.row_table_scroll_down')
 836     ->run('kivi.Order.renumber_positions')
 837     ->focus('#add_item_parts_id_name');
 838
 839   $self->js_redisplay_amounts_and_taxes;
 840   $self->js->render();
 841 }
 842
 843 # open the dialog for entering multiple items at once
 844 sub action_show_multi_items_dialog {
 845   $_[0]->render('order/tabs/_multi_items_dialog', { layout => 0 },
 846                 all_partsgroups => SL::DB::Manager::PartsGroup->get_all);
 847 }
 848
 849 # update the filter results in the multi item dialog
 850 sub action_multi_items_update_result {
 851   my $max_count = 100;
 852
 853   $::form->{multi_items}->{filter}->{obsolete} = 0;
 854
 855   my $count = $_[0]->multi_items_models->count;
 856
 857   if ($count == 0) {
 858     my $text = SL::Presenter::EscapedText->new(text => $::locale->text('No results.'));
 859     $_[0]->render($text, { layout => 0 });
 860   } elsif ($count > $max_count) {
 861     my $text = SL::Presenter::EscapedText->new(text => $::locale->text('Too many results (#1 from #2).', $count, $max_count));
 862     $_[0]->render($text, { layout => 0 });
 863   } else {
 864     my $multi_items = $_[0]->multi_items_models->get;
 865     $_[0]->render('order/tabs/_multi_items_result', { layout => 0 },
 866                   multi_items => $multi_items);
 867   }
 868 }
 869
 870 # add item rows for multiple items at once
 871 sub action_add_multi_items {
 872   my ($self) = @_;
 873
 874   my @form_attr = grep { $_->{qty_as_number} } @{ $::form->{add_multi_items} };
 875   return $self->js->render() unless scalar @form_attr;
 876
 877   my @items;
 878   foreach my $attr (@form_attr) {
 879     my $item = new_item($self->order, $attr);
 880     push @items, $item;
 881     if ( $item->part->is_assortment ) {
 882       foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 883         my $attr = { parts_id => $assortment_item->parts_id,
 884                      qty      => $assortment_item->qty * $item->qty, # TODO $form_attr->{unit}
 885                      unit     => $assortment_item->unit,
 886                      description => $assortment_item->part->description,
 887                    };
 888         my $item = new_item($self->order, $attr);
 889
 890         # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 891         $item->discount(1) unless $assortment_item->charge;
 892         push @items, $item;
 893       }
 894     }
 895   }
 896   $self->order->add_items(@items);
 897
 898   $self->recalc();
 899
 900   foreach my $item (@items) {
 901     $self->get_item_cvpartnumber($item);
 902     my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 903     my $row_as_html = $self->p->render('order/tabs/_row',
 904                                        ITEM                => $item,
 905                                        ID                  => $item_id,
 906                                        TYPE                => $self->type,
 907                                        ALL_PRICE_FACTORS   => $self->all_price_factors,
 908                                        SEARCH_CVPARTNUMBER => $self->search_cvpartnumber,
 909     );
 910
 911     $self->js->append('#row_table_id', $row_as_html);
 912   }
 913
 914   $self->js
 915     ->run('kivi.Order.close_multi_items_dialog')
 916     ->run('kivi.Order.init_row_handlers')
 917     ->run('kivi.Order.row_table_scroll_down')
 918     ->run('kivi.Order.renumber_positions')
 919     ->focus('#add_item_parts_id_name');
 920
 921   $self->js_redisplay_amounts_and_taxes;
 922   $self->js->render();
 923 }
 924
 925 # recalculate all linetotals, amounts and taxes and redisplay them
 926 sub action_recalc_amounts_and_taxes {
 927   my ($self) = @_;
 928
 929   $self->recalc();
 930
 931   $self->js_redisplay_line_values;
 932   $self->js_redisplay_amounts_and_taxes;
 933   $self->js->render();
 934 }
 935
 936 # redisplay item rows if they are sorted by an attribute
 937 sub action_reorder_items {
 938   my ($self) = @_;
 939
 940   my %sort_keys = (
 941     partnumber   => sub { $_[0]->part->partnumber },
 942     description  => sub { $_[0]->description },
 943     qty          => sub { $_[0]->qty },
 944     sellprice    => sub { $_[0]->sellprice },
 945     discount     => sub { $_[0]->discount },
 946     cvpartnumber => sub { $_[0]->{cvpartnumber} },
 947   );
 948
 949   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
 950
 951   my $method = $sort_keys{$::form->{order_by}};
 952   my @to_sort = map { { old_pos => $_->position, order_by => $method->($_) } } @{ $self->order->items_sorted };
 953   if ($::form->{sort_dir}) {
 954     if ( $::form->{order_by} =~ m/qty|sellprice|discount/ ){
 955       @to_sort = sort { $a->{order_by} <=> $b->{order_by} } @to_sort;
 956     } else {
 957       @to_sort = sort { $a->{order_by} cmp $b->{order_by} } @to_sort;
 958     }
 959   } else {
 960     if ( $::form->{order_by} =~ m/qty|sellprice|discount/ ){
 961       @to_sort = sort { $b->{order_by} <=> $a->{order_by} } @to_sort;
 962     } else {
 963       @to_sort = sort { $b->{order_by} cmp $a->{order_by} } @to_sort;
 964     }
 965   }
 966   $self->js
 967     ->run('kivi.Order.redisplay_items', \@to_sort)
 968     ->render;
 969 }
 970
 971 # show the popup to choose a price/discount source
 972 sub action_price_popup {
 973   my ($self) = @_;
 974
 975   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 976   my $item = $self->order->items_sorted->[$idx];
 977
 978   $self->render_price_dialog($item);
 979 }
 980
 981 # get the longdescription for an item if the dialog to enter/change the
 982 # longdescription was opened and the longdescription is empty
 983 #
 984 # If this item is new, get the longdescription from Part.
 985 # Otherwise get it from OrderItem.
 986 sub action_get_item_longdescription {
 987   my $longdescription;
 988
 989   if ($::form->{item_id}) {
 990     $longdescription = SL::DB::OrderItem->new(id => $::form->{item_id})->load->longdescription;
 991   } elsif ($::form->{parts_id}) {
 992     $longdescription = SL::DB::Part->new(id => $::form->{parts_id})->load->notes;
 993   }
 994   $_[0]->render(\ $longdescription, { type => 'text' });
 995 }
 996
 997 # load the second row for one or more items
 998 #
 999 # This action gets the html code for all items second rows by rendering a template for
1000 # the second row and sets the html code via client js.
1001 sub action_load_second_rows {
1002   my ($self) = @_;
1003
1004   $self->recalc() if $self->order->is_sales; # for margin calculation
1005
1006   foreach my $item_id (@{ $::form->{item_ids} }) {
1007     my $idx  = first_index { $_ eq $item_id } @{ $::form->{orderitem_ids} };
1008     my $item = $self->order->items_sorted->[$idx];
1009
1010     $self->js_load_second_row($item, $item_id, 0);
1011   }
1012
1013   $self->js->run('kivi.Order.init_row_handlers') if $self->order->is_sales; # for lastcosts change-callback
1014
1015   $self->js->render();
1016 }
1017
1018 # update description, notes and sellprice from master data
1019 sub action_update_row_from_master_data {
1020   my ($self) = @_;
1021
1022   foreach my $item_id (@{ $::form->{item_ids} }) {
1023     my $idx  = first_index { $_ eq $item_id } @{ $::form->{orderitem_ids} };
1024     my $item = $self->order->items_sorted->[$idx];
1025
1026     $item->description($item->part->description);
1027     $item->longdescription($item->part->notes);
1028
1029     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
1030
1031     my $price_src;
1032     if ($item->part->is_assortment) {
1033     # add assortment items with price 0, as the components carry the price
1034       $price_src = $price_source->price_from_source("");
1035       $price_src->price(0);
1036     } else {
1037       $price_src = $price_source->best_price
1038                  ? $price_source->best_price
1039                  : $price_source->price_from_source("");
1040       $price_src->price(0) if !$price_source->best_price;
1041     }
1042
1043     $item->sellprice($price_src->price);
1044     $item->active_price_source($price_src);
1045
1046     $self->js
1047       ->run('kivi.Order.update_sellprice', $item_id, $item->sellprice_as_number)
1048       ->val('.row_entry:has(#item_' . $item_id . ') [name = "order.orderitems[].description"]', $item->description)
1049       ->val('.row_entry:has(#item_' . $item_id . ') [name = "order.orderitems[].longdescription"]', $item->longdescription);
1050   }
1051
1052   $self->recalc();
1053   $self->js_redisplay_line_values;
1054   $self->js_redisplay_amounts_and_taxes;
1055
1056   $self->js->render();
1057 }
1058
1059 sub js_load_second_row {
1060   my ($self, $item, $item_id, $do_parse) = @_;
1061
1062   if ($do_parse) {
1063     # Parse values from form (they are formated while rendering (template)).
1064     # Workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
1065     # This parsing is not necessary at all, if we assure that the second row/cvars are only loaded once.
1066     foreach my $var (@{ $item->cvars_by_config }) {
1067       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
1068     }
1069     $item->parse_custom_variable_values;
1070   }
1071
1072   my $row_as_html = $self->p->render('order/tabs/_second_row', ITEM => $item, TYPE => $self->type);
1073
1074   $self->js
1075     ->html('#second_row_' . $item_id, $row_as_html)
1076     ->data('#second_row_' . $item_id, 'loaded', 1);
1077 }
1078
1079 sub js_redisplay_line_values {
1080   my ($self) = @_;
1081
1082   my $is_sales = $self->order->is_sales;
1083
1084   # sales orders with margins
1085   my @data;
1086   if ($is_sales) {
1087     @data = map {
1088       [
1089        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
1090        $::form->format_amount(\%::myconfig, $_->{marge_total},   2, 0),
1091        $::form->format_amount(\%::myconfig, $_->{marge_percent}, 2, 0),
1092       ]} @{ $self->order->items_sorted };
1093   } else {
1094     @data = map {
1095       [
1096        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
1097       ]} @{ $self->order->items_sorted };
1098   }
1099
1100   $self->js
1101     ->run('kivi.Order.redisplay_line_values', $is_sales, \@data);
1102 }
1103
1104 sub js_redisplay_amounts_and_taxes {
1105   my ($self) = @_;
1106
1107   if (scalar @{ $self->{taxes} }) {
1108     $self->js->show('#taxincluded_row_id');
1109   } else {
1110     $self->js->hide('#taxincluded_row_id');
1111   }
1112
1113   if ($self->order->taxincluded) {
1114     $self->js->hide('#subtotal_row_id');
1115   } else {
1116     $self->js->show('#subtotal_row_id');
1117   }
1118
1119   if ($self->order->is_sales) {
1120     my $is_neg = $self->order->marge_total < 0;
1121     $self->js
1122       ->html('#marge_total_id',   $::form->format_amount(\%::myconfig, $self->order->marge_total,   2))
1123       ->html('#marge_percent_id', $::form->format_amount(\%::myconfig, $self->order->marge_percent, 2))
1124       ->action_if( $is_neg, 'addClass',    '#marge_total_id',        'plus0')
1125       ->action_if( $is_neg, 'addClass',    '#marge_percent_id',      'plus0')
1126       ->action_if( $is_neg, 'addClass',    '#marge_percent_sign_id', 'plus0')
1127       ->action_if(!$is_neg, 'removeClass', '#marge_total_id',        'plus0')
1128       ->action_if(!$is_neg, 'removeClass', '#marge_percent_id',      'plus0')
1129       ->action_if(!$is_neg, 'removeClass', '#marge_percent_sign_id', 'plus0');
1130   }
1131
1132   $self->js
1133     ->html('#netamount_id', $::form->format_amount(\%::myconfig, $self->order->netamount, -2))
1134     ->html('#amount_id',    $::form->format_amount(\%::myconfig, $self->order->amount,    -2))
1135     ->remove('.tax_row')
1136     ->insertBefore($self->build_tax_rows, '#amount_row_id');
1137 }
1138
1139 sub js_redisplay_cvpartnumbers {
1140   my ($self) = @_;
1141
1142   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
1143
1144   my @data = map {[$_->{cvpartnumber}]} @{ $self->order->items_sorted };
1145
1146   $self->js
1147     ->run('kivi.Order.redisplay_cvpartnumbers', \@data);
1148 }
1149
1150 sub js_reset_order_and_item_ids_after_save {
1151   my ($self) = @_;
1152
1153   $self->js
1154     ->val('#id', $self->order->id)
1155     ->val('#converted_from_oe_id', '')
1156     ->val('#order_' . $self->nr_key(), $self->order->number);
1157
1158   my $idx = 0;
1159   foreach my $form_item_id (@{ $::form->{orderitem_ids} }) {
1160     next if !$self->order->items_sorted->[$idx]->id;
1161     next if $form_item_id !~ m{^new};
1162     $self->js
1163       ->val ('[name="orderitem_ids[+]"][value="' . $form_item_id . '"]', $self->order->items_sorted->[$idx]->id)
1164       ->val ('#item_' . $form_item_id, $self->order->items_sorted->[$idx]->id)
1165       ->attr('#item_' . $form_item_id, "id", 'item_' . $self->order->items_sorted->[$idx]->id);
1166   } continue {
1167     $idx++;
1168   }
1169   $self->js->val('[name="converted_from_orderitems_ids[+]"]', '');
1170 }
1171
1172 #
1173 # helpers
1174 #
1175
1176 sub init_valid_types {
1177   [ sales_order_type(), purchase_order_type(), sales_quotation_type(), request_quotation_type() ];
1178 }
1179
1180 sub init_type {
1181   my ($self) = @_;
1182
1183   if (none { $::form->{type} eq $_ } @{$self->valid_types}) {
1184     die "Not a valid type for order";
1185   }
1186
1187   $self->type($::form->{type});
1188 }
1189
1190 sub init_cv {
1191   my ($self) = @_;
1192
1193   my $cv = (any { $self->type eq $_ } (sales_order_type(),    sales_quotation_type()))   ? 'customer'
1194          : (any { $self->type eq $_ } (purchase_order_type(), request_quotation_type())) ? 'vendor'
1195          : die "Not a valid type for order";
1196
1197   return $cv;
1198 }
1199
1200 sub init_search_cvpartnumber {
1201   my ($self) = @_;
1202
1203   my $user_prefs = SL::Helper::UserPreferences::PartPickerSearch->new();
1204   my $search_cvpartnumber;
1205   $search_cvpartnumber = !!$user_prefs->get_sales_search_customer_partnumber() if $self->cv eq 'customer';
1206   $search_cvpartnumber = !!$user_prefs->get_purchase_search_makemodel()        if $self->cv eq 'vendor';
1207
1208   return $search_cvpartnumber;
1209 }
1210
1211 sub init_p {
1212   SL::Presenter->get;
1213 }
1214
1215 sub init_order {
1216   $_[0]->make_order;
1217 }
1218
1219 # model used to filter/display the parts in the multi-items dialog
1220 sub init_multi_items_models {
1221   SL::Controller::Helper::GetModels->new(
1222     controller     => $_[0],
1223     model          => 'Part',
1224     with_objects   => [ qw(unit_obj) ],
1225     disable_plugin => 'paginated',
1226     source         => $::form->{multi_items},
1227     sorted         => {
1228       _default    => {
1229         by  => 'partnumber',
1230         dir => 1,
1231       },
1232       partnumber  => t8('Partnumber'),
1233       description => t8('Description')}
1234   );
1235 }
1236
1237 sub init_all_price_factors {
1238   SL::DB::Manager::PriceFactor->get_all;
1239 }
1240
1241 sub check_auth {
1242   my ($self) = @_;
1243
1244   my $right_for = { map { $_ => $_.'_edit' } @{$self->valid_types} };
1245
1246   my $right   = $right_for->{ $self->type };
1247   $right    ||= 'DOES_NOT_EXIST';
1248
1249   $::auth->assert($right);
1250 }
1251
1252 # build the selection box for contacts
1253 #
1254 # Needed, if customer/vendor changed.
1255 sub build_contact_select {
1256   my ($self) = @_;
1257
1258   select_tag('order.cp_id', [ $self->order->{$self->cv}->contacts ],
1259     value_key  => 'cp_id',
1260     title_key  => 'full_name_dep',
1261     default    => $self->order->cp_id,
1262     with_empty => 1,
1263     style      => 'width: 300px',
1264   );
1265 }
1266
1267 # build the selection box for shiptos
1268 #
1269 # Needed, if customer/vendor changed.
1270 sub build_shipto_select {
1271   my ($self) = @_;
1272
1273   select_tag('order.shipto_id', [ $self->order->{$self->cv}->shipto ],
1274     value_key  => 'shipto_id',
1275     title_key  => 'displayable_id',
1276     default    => $self->order->shipto_id,
1277     with_empty => 1,
1278     style      => 'width: 300px',
1279   );
1280 }
1281
1282 # render the info line for business
1283 #
1284 # Needed, if customer/vendor changed.
1285 sub build_business_info_row
1286 {
1287   $_[0]->p->render('order/tabs/_business_info_row', SELF => $_[0]);
1288 }
1289
1290 # build the rows for displaying taxes
1291 #
1292 # Called if amounts where recalculated and redisplayed.
1293 sub build_tax_rows {
1294   my ($self) = @_;
1295
1296   my $rows_as_html;
1297   foreach my $tax (sort { $a->{tax}->rate cmp $b->{tax}->rate } @{ $self->{taxes} }) {
1298     $rows_as_html .= $self->p->render('order/tabs/_tax_row', TAX => $tax, TAXINCLUDED => $self->order->taxincluded);
1299   }
1300   return $rows_as_html;
1301 }
1302
1303
1304 sub render_price_dialog {
1305   my ($self, $record_item) = @_;
1306
1307   my $price_source = SL::PriceSource->new(record_item => $record_item, record => $self->order);
1308
1309   $self->js
1310     ->run(
1311       'kivi.io.price_chooser_dialog',
1312       t8('Available Prices'),
1313       $self->render('order/tabs/_price_sources_dialog', { output => 0 }, price_source => $price_source)
1314     )
1315     ->reinit_widgets;
1316
1317 #   if (@errors) {
1318 #     $self->js->text('#dialog_flash_error_content', join ' ', @errors);
1319 #     $self->js->show('#dialog_flash_error');
1320 #   }
1321
1322   $self->js->render;
1323 }
1324
1325 sub load_order {
1326   my ($self) = @_;
1327
1328   return if !$::form->{id};
1329
1330   $self->order(SL::DB::Order->new(id => $::form->{id})->load);
1331 }
1332
1333 # load or create a new order object
1334 #
1335 # And assign changes from the form to this object.
1336 # If the order is loaded from db, check if items are deleted in the form,
1337 # remove them form the object and collect them for removing from db on saving.
1338 # Then create/update items from form (via make_item) and add them.
1339 sub make_order {
1340   my ($self) = @_;
1341
1342   # add_items adds items to an order with no items for saving, but they cannot
1343   # be retrieved via items until the order is saved. Adding empty items to new
1344   # order here solves this problem.
1345   my $order;
1346   $order   = SL::DB::Order->new(id => $::form->{id})->load(with => [ 'orderitems', 'orderitems.part' ]) if $::form->{id};
1347   $order ||= SL::DB::Order->new(orderitems => [],
1348                                 quotation  => (any { $self->type eq $_ } (sales_quotation_type(), request_quotation_type())));
1349
1350   my $cv_id_method = $self->cv . '_id';
1351   if (!$::form->{id} && $::form->{$cv_id_method}) {
1352     $order->$cv_id_method($::form->{$cv_id_method});
1353     setup_order_from_cv($order);
1354   }
1355
1356   my $form_orderitems               = delete $::form->{order}->{orderitems};
1357   my $form_periodic_invoices_config = delete $::form->{order}->{periodic_invoices_config};
1358
1359   $order->assign_attributes(%{$::form->{order}});
1360
1361   if (my $periodic_invoices_config_attrs = $form_periodic_invoices_config ? SL::YAML::Load($form_periodic_invoices_config) : undef) {
1362     my $periodic_invoices_config = $order->periodic_invoices_config || $order->periodic_invoices_config(SL::DB::PeriodicInvoicesConfig->new);
1363     $periodic_invoices_config->assign_attributes(%$periodic_invoices_config_attrs);
1364   }
1365
1366   # remove deleted items
1367   $self->item_ids_to_delete([]);
1368   foreach my $idx (reverse 0..$#{$order->orderitems}) {
1369     my $item = $order->orderitems->[$idx];
1370     if (none { $item->id == $_->{id} } @{$form_orderitems}) {
1371       splice @{$order->orderitems}, $idx, 1;
1372       push @{$self->item_ids_to_delete}, $item->id;
1373     }
1374   }
1375
1376   my @items;
1377   my $pos = 1;
1378   foreach my $form_attr (@{$form_orderitems}) {
1379     my $item = make_item($order, $form_attr);
1380     $item->position($pos);
1381     push @items, $item;
1382     $pos++;
1383   }
1384   $order->add_items(grep {!$_->id} @items);
1385
1386   return $order;
1387 }
1388
1389 # create or update items from form
1390 #
1391 # Make item objects from form values. For items already existing read from db.
1392 # Create a new item else. And assign attributes.
1393 sub make_item {
1394   my ($record, $attr) = @_;
1395
1396   my $item;
1397   $item = first { $_->id == $attr->{id} } @{$record->items} if $attr->{id};
1398
1399   my $is_new = !$item;
1400
1401   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1402   # they cannot be retrieved via custom_variables until the order/orderitem is
1403   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1404   $item ||= SL::DB::OrderItem->new(custom_variables => []);
1405
1406   $item->assign_attributes(%$attr);
1407   $item->longdescription($item->part->notes)                     if $is_new && !defined $attr->{longdescription};
1408   $item->project_id($record->globalproject_id)                   if $is_new && !defined $attr->{project_id};
1409   $item->lastcost($record->is_sales ? $item->part->lastcost : 0) if $is_new && !defined $attr->{lastcost_as_number};
1410
1411   return $item;
1412 }
1413
1414 # create a new item
1415 #
1416 # This is used to add one item
1417 sub new_item {
1418   my ($record, $attr) = @_;
1419
1420   my $item = SL::DB::OrderItem->new;
1421
1422   # Remove attributes where the user left or set the inputs empty.
1423   # So these attributes will be undefined and we can distinguish them
1424   # from zero later on.
1425   for (qw(qty_as_number sellprice_as_number discount_as_percent)) {
1426     delete $attr->{$_} if $attr->{$_} eq '';
1427   }
1428
1429   $item->assign_attributes(%$attr);
1430
1431   my $part         = SL::DB::Part->new(id => $attr->{parts_id})->load;
1432   my $price_source = SL::PriceSource->new(record_item => $item, record => $record);
1433
1434   $item->unit($part->unit) if !$item->unit;
1435
1436   my $price_src;
1437   if ( $part->is_assortment ) {
1438     # add assortment items with price 0, as the components carry the price
1439     $price_src = $price_source->price_from_source("");
1440     $price_src->price(0);
1441   } elsif (defined $item->sellprice) {
1442     $price_src = $price_source->price_from_source("");
1443     $price_src->price($item->sellprice);
1444   } else {
1445     $price_src = $price_source->best_price
1446            ? $price_source->best_price
1447            : $price_source->price_from_source("");
1448     $price_src->price(0) if !$price_source->best_price;
1449   }
1450
1451   my $discount_src;
1452   if (defined $item->discount) {
1453     $discount_src = $price_source->discount_from_source("");
1454     $discount_src->discount($item->discount);
1455   } else {
1456     $discount_src = $price_source->best_discount
1457                   ? $price_source->best_discount
1458                   : $price_source->discount_from_source("");
1459     $discount_src->discount(0) if !$price_source->best_discount;
1460   }
1461
1462   my %new_attr;
1463   $new_attr{part}                   = $part;
1464   $new_attr{description}            = $part->description     if ! $item->description;
1465   $new_attr{qty}                    = 1.0                    if ! $item->qty;
1466   $new_attr{price_factor_id}        = $part->price_factor_id if ! $item->price_factor_id;
1467   $new_attr{sellprice}              = $price_src->price;
1468   $new_attr{discount}               = $discount_src->discount;
1469   $new_attr{active_price_source}    = $price_src;
1470   $new_attr{active_discount_source} = $discount_src;
1471   $new_attr{longdescription}        = $part->notes           if ! defined $attr->{longdescription};
1472   $new_attr{project_id}             = $record->globalproject_id;
1473   $new_attr{lastcost}               = $record->is_sales ? $part->lastcost : 0;
1474
1475   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1476   # they cannot be retrieved via custom_variables until the order/orderitem is
1477   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1478   $new_attr{custom_variables} = [];
1479
1480   $item->assign_attributes(%new_attr);
1481
1482   return $item;
1483 }
1484
1485 sub setup_order_from_cv {
1486   my ($order) = @_;
1487
1488   $order->$_($order->customervendor->$_) for (qw(taxzone_id payment_id delivery_term_id));
1489
1490   $order->intnotes($order->customervendor->notes);
1491
1492   if ($order->is_sales) {
1493     $order->salesman_id($order->customer->salesman_id || SL::DB::Manager::Employee->current->id);
1494     $order->taxincluded(defined($order->customer->taxincluded_checked)
1495                         ? $order->customer->taxincluded_checked
1496                         : $::myconfig{taxincluded_checked});
1497   }
1498
1499 }
1500
1501 # recalculate prices and taxes
1502 #
1503 # Using the PriceTaxCalculator. Store linetotals in the item objects.
1504 sub recalc {
1505   my ($self) = @_;
1506
1507   # bb: todo: currency later
1508   $self->order->currency_id($::instance_conf->get_currency_id());
1509
1510   my %pat = $self->order->calculate_prices_and_taxes();
1511   $self->{taxes} = [];
1512   foreach my $tax_chart_id (keys %{ $pat{taxes} }) {
1513     my $tax = SL::DB::Manager::Tax->find_by(chart_id => $tax_chart_id);
1514
1515     my @amount_keys = grep { $pat{amounts}->{$_}->{tax_id} == $tax->id } keys %{ $pat{amounts} };
1516     push(@{ $self->{taxes} }, { amount    => $pat{taxes}->{$tax_chart_id},
1517                                 netamount => $pat{amounts}->{$amount_keys[0]}->{amount},
1518                                 tax       => $tax });
1519   }
1520
1521   pairwise { $a->{linetotal} = $b->{linetotal} } @{$self->order->items_sorted}, @{$pat{items}};
1522 }
1523
1524 # get data for saving, printing, ..., that is not changed in the form
1525 #
1526 # Only cvars for now.
1527 sub get_unalterable_data {
1528   my ($self) = @_;
1529
1530   foreach my $item (@{ $self->order->items }) {
1531     # autovivify all cvars that are not in the form (cvars_by_config can do it).
1532     # workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
1533     foreach my $var (@{ $item->cvars_by_config }) {
1534       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
1535     }
1536     $item->parse_custom_variable_values;
1537   }
1538 }
1539
1540 # delete the order
1541 #
1542 # And remove related files in the spool directory
1543 sub delete {
1544   my ($self) = @_;
1545
1546   my $errors = [];
1547   my $db     = $self->order->db;
1548
1549   $db->with_transaction(
1550     sub {
1551       my @spoolfiles = grep { $_ } map { $_->spoolfile } @{ SL::DB::Manager::Status->get_all(where => [ trans_id => $self->order->id ]) };
1552       $self->order->delete;
1553       my $spool = $::lx_office_conf{paths}->{spool};
1554       unlink map { "$spool/$_" } @spoolfiles if $spool;
1555
1556       1;
1557   }) || push(@{$errors}, $db->error);
1558
1559   return $errors;
1560 }
1561
1562 # save the order
1563 #
1564 # And delete items that are deleted in the form.
1565 sub save {
1566   my ($self) = @_;
1567
1568   my $errors = [];
1569   my $db     = $self->order->db;
1570
1571   $db->with_transaction(sub {
1572     SL::DB::OrderItem->new(id => $_)->delete for @{$self->item_ids_to_delete || []};
1573     $self->order->save(cascade => 1);
1574
1575     # link records
1576     if ($::form->{converted_from_oe_id}) {
1577       my @converted_from_oe_ids = split ' ', $::form->{converted_from_oe_id};
1578       foreach my $converted_from_oe_id (@converted_from_oe_ids) {
1579         my $src = SL::DB::Order->new(id => $converted_from_oe_id)->load;
1580         $src->update_attributes(closed => 1) if $src->type =~ /_quotation$/;
1581         $src->link_to_record($self->order);
1582       }
1583       if (scalar @{ $::form->{converted_from_orderitems_ids} || [] }) {
1584         my $idx = 0;
1585         foreach (@{ $self->order->items_sorted }) {
1586           my $from_id = $::form->{converted_from_orderitems_ids}->[$idx];
1587           next if !$from_id;
1588           SL::DB::RecordLink->new(from_table => 'orderitems',
1589                                   from_id    => $from_id,
1590                                   to_table   => 'orderitems',
1591                                   to_id      => $_->id
1592           )->save;
1593           $idx++;
1594         }
1595       }
1596     }
1597     1;
1598   }) || push(@{$errors}, $db->error);
1599
1600   return $errors;
1601 }
1602
1603 sub workflow_sales_or_purchase_order {
1604   my ($self) = @_;
1605
1606   # always save
1607   my $errors = $self->save();
1608
1609   if (scalar @{ $errors }) {
1610     $self->js->flash('error', $_) foreach @{ $errors };
1611     return $self->js->render();
1612   }
1613
1614   my $destination_type = $::form->{type} eq sales_quotation_type()   ? sales_order_type()
1615                        : $::form->{type} eq request_quotation_type() ? purchase_order_type()
1616                        : $::form->{type} eq purchase_order_type()    ? sales_order_type()
1617                        : $::form->{type} eq sales_order_type()       ? purchase_order_type()
1618                        : '';
1619
1620   $self->order(SL::DB::Order->new_from($self->order, destination_type => $destination_type));
1621   $self->{converted_from_oe_id} = delete $::form->{id};
1622
1623   # set item ids to new fake id, to identify them as new items
1624   foreach my $item (@{$self->order->items_sorted}) {
1625     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1626   }
1627
1628   # change form type
1629   $::form->{type} = $destination_type;
1630   $self->type($self->init_type);
1631   $self->cv  ($self->init_cv);
1632   $self->check_auth;
1633
1634   $self->recalc();
1635   $self->get_unalterable_data();
1636   $self->pre_render();
1637
1638   # trigger rendering values for second row/longdescription as hidden,
1639   # because they are loaded only on demand. So we need to keep the values
1640   # from the source.
1641   $_->{render_second_row}      = 1 for @{ $self->order->items_sorted };
1642   $_->{render_longdescription} = 1 for @{ $self->order->items_sorted };
1643
1644   $self->render(
1645     'order/form',
1646     title => $self->get_title_for('edit'),
1647     %{$self->{template_args}}
1648   );
1649 }
1650
1651
1652 sub pre_render {
1653   my ($self) = @_;
1654
1655   $self->{all_taxzones}               = SL::DB::Manager::TaxZone->get_all_sorted();
1656   $self->{all_departments}            = SL::DB::Manager::Department->get_all_sorted();
1657   $self->{all_employees}              = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->employee_id,
1658                                                                                               deleted => 0 ] ],
1659                                                                            sort_by => 'name');
1660   $self->{all_salesmen}               = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->salesman_id,
1661                                                                                               deleted => 0 ] ],
1662                                                                            sort_by => 'name');
1663   $self->{all_payment_terms}          = SL::DB::Manager::PaymentTerm->get_all_sorted(where => [ or => [ id => $self->order->payment_id,
1664                                                                                                         obsolete => 0 ] ]);
1665   $self->{all_delivery_terms}         = SL::DB::Manager::DeliveryTerm->get_all_sorted();
1666   $self->{current_employee_id}        = SL::DB::Manager::Employee->current->id;
1667   $self->{periodic_invoices_status}   = $self->get_periodic_invoices_status($self->order->periodic_invoices_config);
1668   $self->{order_probabilities}        = [ map { { title => ($_ * 10) . '%', id => $_ * 10 } } (0..10) ];
1669   $self->{positions_scrollbar_height} = SL::Helper::UserPreferences::PositionsScrollbar->new()->get_height();
1670
1671   my $print_form = Form->new('');
1672   $print_form->{type}      = $self->type;
1673   $print_form->{printers}  = SL::DB::Manager::Printer->get_all_sorted;
1674   $print_form->{languages} = SL::DB::Manager::Language->get_all_sorted;
1675   $self->{print_options}   = SL::Helper::PrintOptions->get_print_options(
1676     form => $print_form,
1677     options => {dialog_name_prefix => 'print_options.',
1678                 show_headers       => 1,
1679                 no_queue           => 1,
1680                 no_postscript      => 1,
1681                 no_opendocument    => 0,
1682                 no_html            => 1},
1683   );
1684
1685   foreach my $item (@{$self->order->orderitems}) {
1686     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
1687     $item->active_price_source(   $price_source->price_from_source(   $item->active_price_source   ));
1688     $item->active_discount_source($price_source->discount_from_source($item->active_discount_source));
1689   }
1690
1691   if (any { $self->type eq $_ } (sales_order_type(), purchase_order_type())) {
1692     # calculate shipped qtys here to prevent calling calculate for every item via the items method
1693     SL::Helper::ShippedQty->new->calculate($self->order)->write_to_objects;
1694   }
1695
1696   if ($self->order->number && $::instance_conf->get_webdav) {
1697     my $webdav = SL::Webdav->new(
1698       type     => $self->type,
1699       number   => $self->order->number,
1700     );
1701     my @all_objects = $webdav->get_all_objects;
1702     @{ $self->{template_args}->{WEBDAV} } = map { { name => $_->filename,
1703                                                     type => t8('File'),
1704                                                     link => File::Spec->catfile($_->full_filedescriptor),
1705                                                 } } @all_objects;
1706   }
1707
1708   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
1709
1710   $::request->{layout}->use_javascript("${_}.js") for qw(kivi.SalesPurchase kivi.Order kivi.File ckeditor/ckeditor ckeditor/adapters/jquery edit_periodic_invoices_config calculate_qty);
1711   $self->setup_edit_action_bar;
1712 }
1713
1714 sub setup_edit_action_bar {
1715   my ($self, %params) = @_;
1716
1717   my $deletion_allowed = (any { $self->type eq $_ } (sales_quotation_type(), request_quotation_type()))
1718                       || (($self->type eq sales_order_type())    && $::instance_conf->get_sales_order_show_delete)
1719                       || (($self->type eq purchase_order_type()) && $::instance_conf->get_purchase_order_show_delete);
1720
1721   for my $bar ($::request->layout->get('actionbar')) {
1722     $bar->add(
1723       combobox => [
1724         action => [
1725           t8('Save'),
1726           call      => [ 'kivi.Order.save', 'save', $::instance_conf->get_order_warn_duplicate_parts,
1727                                                     $::instance_conf->get_order_warn_no_deliverydate,
1728                                                                                                       ],
1729           checks    => [ 'kivi.Order.check_save_active_periodic_invoices' ],
1730         ],
1731         action => [
1732           t8('Save as new'),
1733           call      => [ 'kivi.Order.save', 'save_as_new', $::instance_conf->get_order_warn_duplicate_parts ],
1734           checks    => [ 'kivi.Order.check_save_active_periodic_invoices' ],
1735           disabled  => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1736         ],
1737       ], # end of combobox "Save"
1738
1739       combobox => [
1740         action => [
1741           t8('Workflow'),
1742         ],
1743         action => [
1744           t8('Save and Sales Order'),
1745           submit   => [ '#order_form', { action => "Order/sales_order" } ],
1746           only_if  => (any { $self->type eq $_ } (sales_quotation_type(), purchase_order_type())),
1747           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1748         ],
1749         action => [
1750           t8('Save and Purchase Order'),
1751           submit   => [ '#order_form', { action => "Order/purchase_order" } ],
1752           only_if  => (any { $self->type eq $_ } (sales_order_type(), request_quotation_type())),
1753           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1754         ],
1755         action => [
1756           t8('Save and Delivery Order'),
1757           call      => [ 'kivi.Order.save', 'save_and_delivery_order', $::instance_conf->get_order_warn_duplicate_parts,
1758                                                                        $::instance_conf->get_order_warn_no_deliverydate,
1759                                                                                                                         ],
1760           checks    => [ 'kivi.Order.check_save_active_periodic_invoices' ],
1761           only_if   => (any { $self->type eq $_ } (sales_order_type(), purchase_order_type()))
1762         ],
1763         action => [
1764           t8('Save and Invoice'),
1765           call      => [ 'kivi.Order.save', 'save_and_invoice', $::instance_conf->get_order_warn_duplicate_parts ],
1766           checks    => [ 'kivi.Order.check_save_active_periodic_invoices' ],
1767         ],
1768         action => [
1769           t8('Save and AP Transaction'),
1770           call      => [ 'kivi.Order.save', 'save_and_ap_transaction', $::instance_conf->get_order_warn_duplicate_parts ],
1771           only_if   => (any { $self->type eq $_ } (purchase_order_type()))
1772         ],
1773
1774       ], # end of combobox "Workflow"
1775
1776       combobox => [
1777         action => [
1778           t8('Export'),
1779         ],
1780         action => [
1781           t8('Save and print'),
1782           call => [ 'kivi.Order.show_print_options', $::instance_conf->get_order_warn_duplicate_parts ],
1783         ],
1784         action => [
1785           t8('Save and E-mail'),
1786           call => [ 'kivi.Order.email', $::instance_conf->get_order_warn_duplicate_parts ],
1787         ],
1788         action => [
1789           t8('Download attachments of all parts'),
1790           call     => [ 'kivi.File.downloadOrderitemsFiles', $::form->{type}, $::form->{id} ],
1791           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1792           only_if  => $::instance_conf->get_doc_storage,
1793         ],
1794       ], # end of combobox "Export"
1795
1796       action => [
1797         t8('Delete'),
1798         call     => [ 'kivi.Order.delete_order' ],
1799         confirm  => $::locale->text('Do you really want to delete this object?'),
1800         disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1801         only_if  => $deletion_allowed,
1802       ],
1803     );
1804   }
1805 }
1806
1807 sub generate_pdf {
1808   my ($order, $pdf_ref, $params) = @_;
1809
1810   my @errors = ();
1811
1812   my $print_form = Form->new('');
1813   $print_form->{type}        = $order->type;
1814   $print_form->{formname}    = $params->{formname} || $order->type;
1815   $print_form->{format}      = $params->{format}   || 'pdf';
1816   $print_form->{media}       = $params->{media}    || 'file';
1817   $print_form->{groupitems}  = $params->{groupitems};
1818   $print_form->{media}       = 'file'                             if $print_form->{media} eq 'screen';
1819
1820   $order->language($params->{language});
1821   $order->flatten_to_form($print_form, format_amounts => 1);
1822
1823   my $template_ext;
1824   my $template_type;
1825   if ($print_form->{format} =~ /(opendocument|oasis)/i) {
1826     $template_ext  = 'odt';
1827     $template_type = 'OpenDocument';
1828   }
1829
1830   # search for the template
1831   my ($template_file, @template_files) = SL::Helper::CreatePDF->find_template(
1832     name        => $print_form->{formname},
1833     extension   => $template_ext,
1834     email       => $print_form->{media} eq 'email',
1835     language    => $params->{language},
1836     printer_id  => $print_form->{printer_id},  # todo
1837   );
1838
1839   if (!defined $template_file) {
1840     push @errors, $::locale->text('Cannot find matching template for this print request. Please contact your template maintainer. I tried these: #1.', join ', ', map { "'$_'"} @template_files);
1841   }
1842
1843   return @errors if scalar @errors;
1844
1845   $print_form->throw_on_error(sub {
1846     eval {
1847       $print_form->prepare_for_printing;
1848
1849       $$pdf_ref = SL::Helper::CreatePDF->create_pdf(
1850         format        => $print_form->{format},
1851         template_type => $template_type,
1852         template      => $template_file,
1853         variables     => $print_form,
1854         variable_content_types => {
1855           longdescription => 'html',
1856           partnotes       => 'html',
1857           notes           => 'html',
1858         },
1859       );
1860       1;
1861     } || push @errors, ref($EVAL_ERROR) eq 'SL::X::FormError' ? $EVAL_ERROR->error : $EVAL_ERROR;
1862   });
1863
1864   return @errors;
1865 }
1866
1867 sub get_files_for_email_dialog {
1868   my ($self) = @_;
1869
1870   my %files = map { ($_ => []) } qw(versions files vc_files part_files);
1871
1872   return %files if !$::instance_conf->get_doc_storage;
1873
1874   if ($self->order->id) {
1875     $files{versions} = [ SL::File->get_all_versions(object_id => $self->order->id,              object_type => $self->order->type, file_type => 'document') ];
1876     $files{files}    = [ SL::File->get_all(         object_id => $self->order->id,              object_type => $self->order->type, file_type => 'attachment') ];
1877     $files{vc_files} = [ SL::File->get_all(         object_id => $self->order->{$self->cv}->id, object_type => $self->cv,          file_type => 'attachment') ];
1878   }
1879
1880   my @parts =
1881     uniq_by { $_->{id} }
1882     map {
1883       +{ id         => $_->part->id,
1884          partnumber => $_->part->partnumber }
1885     } @{$self->order->items_sorted};
1886
1887   foreach my $part (@parts) {
1888     my @pfiles = SL::File->get_all(object_id => $part->{id}, object_type => 'part');
1889     push @{ $files{part_files} }, map { +{ %{ $_ }, partnumber => $part->{partnumber} } } @pfiles;
1890   }
1891
1892   foreach my $key (keys %files) {
1893     $files{$key} = [ sort_by { lc $_->{db_file}->{file_name} } @{ $files{$key} } ];
1894   }
1895
1896   return %files;
1897 }
1898
1899 sub make_periodic_invoices_config_from_yaml {
1900   my ($yaml_config) = @_;
1901
1902   return if !$yaml_config;
1903   my $attr = SL::YAML::Load($yaml_config);
1904   return if 'HASH' ne ref $attr;
1905   return SL::DB::PeriodicInvoicesConfig->new(%$attr);
1906 }
1907
1908
1909 sub get_periodic_invoices_status {
1910   my ($self, $config) = @_;
1911
1912   return                      if $self->type ne sales_order_type();
1913   return t8('not configured') if !$config;
1914
1915   my $active = ('HASH' eq ref $config)                           ? $config->{active}
1916              : ('SL::DB::PeriodicInvoicesConfig' eq ref $config) ? $config->active
1917              :                                                     die "Cannot get status of periodic invoices config";
1918
1919   return $active ? t8('active') : t8('inactive');
1920 }
1921
1922 sub get_title_for {
1923   my ($self, $action) = @_;
1924
1925   return '' if none { lc($action)} qw(add edit);
1926
1927   # for locales:
1928   # $::locale->text("Add Sales Order");
1929   # $::locale->text("Add Purchase Order");
1930   # $::locale->text("Add Quotation");
1931   # $::locale->text("Add Request for Quotation");
1932   # $::locale->text("Edit Sales Order");
1933   # $::locale->text("Edit Purchase Order");
1934   # $::locale->text("Edit Quotation");
1935   # $::locale->text("Edit Request for Quotation");
1936
1937   $action = ucfirst(lc($action));
1938   return $self->type eq sales_order_type()       ? $::locale->text("$action Sales Order")
1939        : $self->type eq purchase_order_type()    ? $::locale->text("$action Purchase Order")
1940        : $self->type eq sales_quotation_type()   ? $::locale->text("$action Quotation")
1941        : $self->type eq request_quotation_type() ? $::locale->text("$action Request for Quotation")
1942        : '';
1943 }
1944
1945 sub get_item_cvpartnumber {
1946   my ($self, $item) = @_;
1947
1948   if ($self->cv eq 'vendor') {
1949     my @mms = grep { $_->make eq $self->order->customervendor->id } @{$item->part->makemodels};
1950     $item->{cvpartnumber} = $mms[0]->model if scalar @mms;
1951   } elsif ($self->cv eq 'customer') {
1952     my @cps = grep { $_->customer_id eq $self->order->customervendor->id } @{$item->part->customerprices};
1953     $item->{cvpartnumber} = $cps[0]->customer_partnumber if scalar @cps;
1954   }
1955 }
1956
1957 sub sales_order_type {
1958   'sales_order';
1959 }
1960
1961 sub purchase_order_type {
1962   'purchase_order';
1963 }
1964
1965 sub sales_quotation_type {
1966   'sales_quotation';
1967 }
1968
1969 sub request_quotation_type {
1970   'request_quotation';
1971 }
1972
1973 sub nr_key {
1974   return $_[0]->type eq sales_order_type()       ? 'ordnumber'
1975        : $_[0]->type eq purchase_order_type()    ? 'ordnumber'
1976        : $_[0]->type eq sales_quotation_type()   ? 'quonumber'
1977        : $_[0]->type eq request_quotation_type() ? 'quonumber'
1978        : '';
1979 }
1980
1981 1;
1982
1983 __END__
1984
1985 =encoding utf-8
1986
1987 =head1 NAME
1988
1989 SL::Controller::Order - controller for orders
1990
1991 =head1 SYNOPSIS
1992
1993 This is a new form to enter orders, completely rewritten with the use
1994 of controller and java script techniques.
1995
1996 The aim is to provide the user a better experience and a faster workflow. Also
1997 the code should be more readable, more reliable and better to maintain.
1998
1999 =head2 Key Features
2000
2001 =over 4
2002
2003 =item *
2004
2005 One input row, so that input happens every time at the same place.
2006
2007 =item *
2008
2009 Use of pickers where possible.
2010
2011 =item *
2012
2013 Possibility to enter more than one item at once.
2014
2015 =item *
2016
2017 Item list in a scrollable area, so that the workflow buttons stay at
2018 the bottom.
2019
2020 =item *
2021
2022 Reordering item rows with drag and drop is possible. Sorting item rows is
2023 possible (by partnumber, description, qty, sellprice and discount for now).
2024
2025 =item *
2026
2027 No C<update> is necessary. All entries and calculations are managed
2028 with ajax-calls and the page only reloads on C<save>.
2029
2030 =item *
2031
2032 User can see changes immediately, because of the use of java script
2033 and ajax.
2034
2035 =back
2036
2037 =head1 CODE
2038
2039 =head2 Layout
2040
2041 =over 4
2042
2043 =item * C<SL/Controller/Order.pm>
2044
2045 the controller
2046
2047 =item * C<template/webpages/order/form.html>
2048
2049 main form
2050
2051 =item * C<template/webpages/order/tabs/basic_data.html>
2052
2053 Main tab for basic_data.
2054
2055 This is the only tab here for now. "linked records" and "webdav" tabs are
2056 reused from generic code.
2057
2058 =over 4
2059
2060 =item * C<template/webpages/order/tabs/_business_info_row.html>
2061
2062 For displaying information on business type
2063
2064 =item * C<template/webpages/order/tabs/_item_input.html>
2065
2066 The input line for items
2067
2068 =item * C<template/webpages/order/tabs/_row.html>
2069
2070 One row for already entered items
2071
2072 =item * C<template/webpages/order/tabs/_tax_row.html>
2073
2074 Displaying tax information
2075
2076 =item * C<template/webpages/order/tabs/_multi_items_dialog.html>
2077
2078 Dialog for entering more than one item at once
2079
2080 =item * C<template/webpages/order/tabs/_multi_items_result.html>
2081
2082 Results for the filter in the multi items dialog
2083
2084 =item * C<template/webpages/order/tabs/_price_sources_dialog.html>
2085
2086 Dialog for selecting price and discount sources
2087
2088 =back
2089
2090 =item * C<js/kivi.Order.js>
2091
2092 java script functions
2093
2094 =back
2095
2096 =head1 TODO
2097
2098 =over 4
2099
2100 =item * testing
2101
2102 =item * currency
2103
2104 =item * credit limit
2105
2106 =item * more workflows (quotation, rfq)
2107
2108 =item * price sources: little symbols showing better price / better discount
2109
2110 =item * select units in input row?
2111
2112 =item * custom shipto address
2113
2114 =item * check for direct delivery (workflow sales order -> purchase order)
2115
2116 =item * language / part translations
2117
2118 =item * access rights
2119
2120 =item * display weights
2121
2122 =item * history
2123
2124 =item * mtime check
2125
2126 =item * optional client/user behaviour
2127
2128 (transactions has to be set - department has to be set -
2129  force project if enabled in client config - transport cost reminder)
2130
2131 =back
2132
2133 =head1 KNOWN BUGS AND CAVEATS
2134
2135 =over 4
2136
2137 =item *
2138
2139 Customer discount is not displayed as a valid discount in price source popup
2140 (this might be a bug in price sources)
2141
2142 (I cannot reproduce this (Bernd))
2143
2144 =item *
2145
2146 No indication that <shift>-up/down expands/collapses second row.
2147
2148 =item *
2149
2150 Inline creation of parts is not currently supported
2151
2152 =item *
2153
2154 Table header is not sticky in the scrolling area.
2155
2156 =item *
2157
2158 Sorting does not include C<position>, neither does reordering.
2159
2160 This behavior was implemented intentionally. But we can discuss, which behavior
2161 should be implemented.
2162
2163 =item *
2164
2165 C<show_multi_items_dialog> does not use the currently inserted string for
2166 filtering.
2167
2168 =item *
2169
2170 The language selected in print or email dialog is not saved when the order is saved.
2171
2172 =back
2173
2174 =head1 To discuss / Nice to have
2175
2176 =over 4
2177
2178 =item *
2179
2180 How to expand/collapse second row. Now it can be done clicking the icon or
2181 <shift>-up/down.
2182
2183 =item *
2184
2185 Possibility to change longdescription in input row?
2186
2187 =item *
2188
2189 Possibility to select PriceSources in input row?
2190
2191 =item *
2192
2193 This controller uses a (changed) copy of the template for the PriceSource
2194 dialog. Maybe there could be used one code source.
2195
2196 =item *
2197
2198 Rounding-differences between this controller (PriceTaxCalculator) and the old
2199 form. This is not only a problem here, but also in all parts using the PTC.
2200 There exists a ticket and a patch. This patch should be testet.
2201
2202 =item *
2203
2204 An indicator, if the actual inputs are saved (like in an
2205 editor or on text processing application).
2206
2207 =item *
2208
2209 A warning when leaving the page without saveing unchanged inputs.
2210
2211
2212 =back
2213
2214 =head1 AUTHOR
2215
2216 Bernd Bleßmann E<lt>bernd@kivitendo-premium.deE<gt>
2217
2218 =cut