SL/Controller/Order.pm

   1 package SL::Controller::Order;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use SL::Helper::Flash;
   7 use SL::ClientJS;
   8 use SL::Presenter;
   9 use SL::Locale::String;
  10 use SL::SessionFile::Random;
  11 use SL::Form;
  12
  13 use SL::DB::Order;
  14 use SL::DB::Customer;
  15 use SL::DB::Vendor;
  16 use SL::DB::TaxZone;
  17 use SL::DB::Employee;
  18 use SL::DB::Project;
  19 use SL::DB::Default;
  20 use SL::DB::Unit;
  21
  22 use SL::Helper::DateTime;
  23 use SL::Helper::CreatePDF qw(:all);
  24
  25 use List::Util qw(max first);
  26 use List::MoreUtils qw(none pairwise);
  27 use English qw(-no_match_vars);
  28
  29 use Rose::Object::MakeMethods::Generic
  30 (
  31  'scalar --get_set_init' => [ qw(order valid_types type cv js p) ],
  32 );
  33
  34
  35 # safety
  36 __PACKAGE__->run_before('_check_auth');
  37
  38 __PACKAGE__->run_before('_recalc',
  39                         only => [ qw(edit update save create_pdf) ]);
  40
  41
  42 #
  43 # actions
  44 #
  45
  46 sub action_add {
  47   my ($self) = @_;
  48
  49   $self->order->transdate(DateTime->now_local());
  50
  51   $self->_pre_render();
  52   $self->render(
  53     'order/form',
  54     title => $self->type eq _sales_order_type()    ? $::locale->text('Add Sales Order')
  55            : $self->type eq _purchase_order_type() ? $::locale->text('Add Purchase Order')
  56            : '',
  57     %{$self->{template_args}}
  58   );
  59 }
  60
  61 sub action_edit {
  62   my ($self) = @_;
  63
  64   $self->_pre_render();
  65   $self->render(
  66     'order/form',
  67     title => $self->type eq _sales_order_type()    ? $::locale->text('Edit Sales Order')
  68            : $self->type eq _purchase_order_type() ? $::locale->text('Edit Purchase Order')
  69            : '',
  70     %{$self->{template_args}}
  71   );
  72 }
  73
  74 sub action_update {
  75   my ($self) = @_;
  76
  77   $self->_pre_render();
  78   $self->render(
  79     'order/form',
  80     title => $self->type eq _sales_order_type()    ? $::locale->text('Edit Sales Order')
  81            : $self->type eq _purchase_order_type() ? $::locale->text('Edit Purchase Order')
  82            : '',
  83     %{$self->{template_args}}
  84   );
  85 }
  86
  87 sub action_save {
  88   my ($self) = @_;
  89
  90   my $errors = $self->_save();
  91
  92   if (scalar @{ $errors }) {
  93     $self->js->flash('error', $_) foreach @{ $errors };
  94     return $self->js->render($self);
  95   }
  96
  97   flash_later('info', $::locale->text('The order has been saved'));
  98   my @redirect_params = (
  99     action => 'edit',
 100     type   => $self->type,
 101     id     => $self->order->id,
 102   );
 103
 104   $self->redirect_to(@redirect_params);
 105 }
 106
 107 sub action_create_pdf {
 108   my ($self) = @_;
 109
 110   my $print_form = Form->new('');
 111   $print_form->{type}     = 'sales_order';
 112   $print_form->{formname} = 'sales_order',
 113   $print_form->{format}   = 'pdf',
 114   $print_form->{media}    = 'file';
 115
 116   $self->order->flatten_to_form($print_form, format_amounts => 1);
 117
 118   my $pdf;
 119   my @errors;
 120   $print_form->throw_on_error(sub {
 121     eval {
 122       $print_form->prepare_for_printing;
 123
 124       $pdf = SL::Helper::CreatePDF->create_pdf(
 125         template  => SL::Helper::CreatePDF->find_template(name => $print_form->{formname}),
 126         variables => $print_form,
 127         variable_content_types => {
 128           longdescription => 'html',
 129           partnotes       => 'html',
 130           notes           => 'html',
 131         },
 132       );
 133       1;
 134     } || push @errors, ref($EVAL_ERROR) eq 'SL::X::FormError' ? $EVAL_ERROR->getMessage : $EVAL_ERROR;
 135   });
 136
 137   if (scalar @errors) {
 138     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render($self);
 139   }
 140
 141   my $sfile = SL::SessionFile::Random->new(mode => "w");
 142   $sfile->fh->print($pdf);
 143   $sfile->fh->close;
 144
 145   my $tmp_filename = $sfile->file_name;
 146   my $pdf_filename = t8('Sales Order') . '_' . $self->order->ordnumber . '.pdf';
 147
 148   $self->js
 149     ->run('download_pdf', $tmp_filename, $pdf_filename)
 150     ->flash('info', t8('The PDF has been created'))->render($self);
 151 }
 152
 153 sub action_download_pdf {
 154   my ($self) = @_;
 155
 156   return $self->send_file(
 157     $::form->{tmp_filename},
 158     type => 'application/pdf',
 159     name => $::form->{pdf_filename},
 160   );
 161 }
 162
 163 sub action_customer_vendor_changed {
 164   my ($self) = @_;
 165
 166   if ($self->cv eq 'customer') {
 167     $self->order->customer(SL::DB::Manager::Customer->find_by_or_create(id => $::form->{cv_id}));
 168
 169   } elsif ($self->cv eq 'vendor') {
 170     $self->order->vendor(SL::DB::Manager::Vendor->find_by_or_create(id => $::form->{cv_id}));
 171   }
 172
 173   if ($self->order->{$self->cv}->contacts && scalar @{ $self->order->{$self->cv}->contacts } > 0) {
 174     $self->js->show('#cp_row');
 175   } else {
 176     $self->js->hide('#cp_row');
 177   }
 178
 179   if ($self->order->{$self->cv}->shipto && scalar @{ $self->order->{$self->cv}->shipto } > 0) {
 180     $self->js->show('#shipto_row');
 181   } else {
 182     $self->js->hide('#shipto_row');
 183   }
 184
 185   $self->js
 186     ->replaceWith('#order_cp_id',     $self->build_contact_select)
 187     ->replaceWith('#order_shipto_id', $self->build_shipto_select)
 188     ->val('#order_taxzone_id', $self->order->{$self->cv}->taxzone_id)
 189     ->focus('#order_' . $self->cv . '_id')
 190     ->render($self);
 191 }
 192
 193 sub action_add_item {
 194   my ($self) = @_;
 195
 196   my $form_attr = $::form->{add_item};
 197
 198   return unless $form_attr->{parts_id};
 199
 200   my $item = SL::DB::OrderItem->new;
 201   $item->assign_attributes(%$form_attr);
 202
 203   my $part        = SL::DB::Part->new(id => $form_attr->{parts_id})->load;
 204   my $cv_method   = $self->cv;
 205   my $cv_discount = $self->order->$cv_method? $self->order->$cv_method->discount : 0.0;
 206
 207   my %new_attr;
 208   $new_attr{part}        = $part;
 209   $new_attr{description} = $part->description if ! $item->description;
 210   $new_attr{qty}         = 1.0                if ! $item->qty;
 211   $new_attr{unit}        = $part->unit;
 212   $new_attr{sellprice}   = $part->sellprice   if ! $item->sellprice;
 213   $new_attr{discount}    = $cv_discount       if ! $item->discount;
 214
 215   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
 216   # they cannot be retrieved via custom_variables until the order/orderitem is
 217   # saved. Adding empty custom_variables to new orderitem here solves this problem.
 218   $new_attr{custom_variables} = [];
 219
 220   $item->assign_attributes(%new_attr);
 221
 222   $self->order->add_items($item);
 223
 224   $self->_recalc();
 225
 226   my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 227   my $row_as_html = $self->p->render('order/tabs/_row', ITEM => $item, ID => $item_id);
 228
 229   $self->js
 230     ->append('#row_table_id', $row_as_html)
 231     ->val('#add_item_parts_id', '')
 232     ->val('#add_item_parts_id_name', '')
 233     ->val('#add_item_description', '')
 234     ->val('#add_item_qty_as_number', '')
 235     ->val('#add_item_sellprice_as_number', '')
 236     ->val('#add_item_discount_as_percent', '')
 237     ->run('row_table_scroll_down')
 238     ->run('row_set_keyboard_events_by_id', $item_id)
 239     ->on('.recalc', 'change', 'recalc_amounts_and_taxes')
 240     ->focus('#add_item_parts_id_name');
 241
 242   $self->_js_redisplay_amounts_and_taxes;
 243   $self->js->render($self);
 244 }
 245
 246 sub action_recalc_amounts_and_taxes {
 247   my ($self) = @_;
 248
 249   $self->_recalc();
 250
 251   $self->_js_redisplay_linetotals;
 252   $self->_js_redisplay_amounts_and_taxes;
 253   $self->js->render($self);
 254 }
 255
 256 sub _js_redisplay_linetotals {
 257   my ($self) = @_;
 258
 259   my @data = map {$::form->format_amount(\%::myconfig, $_->{linetotal}, 2, 0)} @{ $self->order->items };
 260   $self->js
 261     ->run('redisplay_linetotals', \@data);
 262 }
 263
 264 sub _js_redisplay_amounts_and_taxes {
 265   my ($self) = @_;
 266
 267   if (scalar @{ $self->{taxes} }) {
 268     $self->js->show('#taxincluded_row_id');
 269   } else {
 270     $self->js->hide('#taxincluded_row_id');
 271   }
 272
 273   if ($self->order->taxincluded) {
 274     $self->js->hide('#subtotal_row_id');
 275   } else {
 276     $self->js->show('#subtotal_row_id');
 277   }
 278
 279   $self->js
 280     ->html('#netamount_id', $::form->format_amount(\%::myconfig, $self->order->netamount, -2))
 281     ->html('#amount_id',    $::form->format_amount(\%::myconfig, $self->order->amount,    -2))
 282     ->remove('.tax_row')
 283     ->insertBefore($self->build_tax_rows, '#amount_row_id');
 284 }
 285
 286 #
 287 # helpers
 288 #
 289
 290 sub init_valid_types {
 291   [ _sales_order_type(), _purchase_order_type() ];
 292 }
 293
 294 sub init_type {
 295   my ($self) = @_;
 296
 297   if (none { $::form->{type} eq $_ } @{$self->valid_types}) {
 298     die "Not a valid type for order";
 299   }
 300
 301   $self->type($::form->{type});
 302 }
 303
 304 sub init_cv {
 305   my ($self) = @_;
 306
 307   my $cv = $self->type eq _sales_order_type()    ? 'customer'
 308          : $self->type eq _purchase_order_type() ? 'vendor'
 309          : die "Not a valid type for order";
 310
 311   return $cv;
 312 }
 313
 314 sub init_js {
 315   SL::ClientJS->new;
 316 }
 317
 318 sub init_p {
 319   SL::Presenter->get;
 320 }
 321
 322 sub init_order {
 323   _make_order();
 324 }
 325
 326 sub _check_auth {
 327   my ($self) = @_;
 328
 329   my $right_for = { map { $_ => $_.'_edit' } @{$self->valid_types} };
 330
 331   my $right   = $right_for->{ $self->type };
 332   $right    ||= 'DOES_NOT_EXIST';
 333
 334   $::auth->assert($right);
 335 }
 336
 337 sub build_contact_select {
 338   my ($self) = @_;
 339
 340   $self->p->select_tag('order.cp_id', [ $self->order->{$self->cv}->contacts ],
 341                        value_key  => 'cp_id',
 342                        title_key  => 'full_name_dep',
 343                        default    => $self->order->cp_id,
 344                        with_empty => 1,
 345                        style      => 'width: 300px',
 346   );
 347 }
 348
 349 sub build_shipto_select {
 350   my ($self) = @_;
 351
 352   $self->p->select_tag('order.shipto_id', [ $self->order->{$self->cv}->shipto ],
 353                        value_key  => 'shipto_id',
 354                        title_key  => 'displayable_id',
 355                        default    => $self->order->shipto_id,
 356                        with_empty => 1,
 357                        style      => 'width: 300px',
 358   );
 359 }
 360
 361 sub build_tax_rows {
 362   my ($self) = @_;
 363
 364   my $rows_as_html;
 365   foreach my $tax (@{ $self->{taxes} }) {
 366     $rows_as_html .= $self->p->render('order/tabs/_tax_row', TAX => $tax, TAXINCLUDED => $self->order->taxincluded);
 367   }
 368   return $rows_as_html;
 369 }
 370
 371
 372 sub _make_order {
 373   my ($self) = @_;
 374
 375   # add_items adds items to an order with no items for saving, but they cannot
 376   # be retrieved via items until the order is saved. Adding empty items to new
 377   # order here solves this problem.
 378   my $order;
 379   $order   = SL::DB::Manager::Order->find_by(id => $::form->{id}) if $::form->{id};
 380   $order ||= SL::DB::Order->new(orderitems => []);
 381
 382   $order->assign_attributes(%{$::form->{order}});
 383
 384   return $order;
 385 }
 386
 387
 388 sub _recalc {
 389   my ($self) = @_;
 390
 391   # bb: todo: currency later
 392   $self->order->currency_id($::instance_conf->get_currency_id());
 393
 394   my %pat = $self->order->calculate_prices_and_taxes();
 395   foreach my $tax_chart_id (keys %{ $pat{taxes} }) {
 396     my $tax = SL::DB::Manager::Tax->find_by(chart_id => $tax_chart_id);
 397
 398     my @amount_keys = grep { $pat{amounts}->{$_}->{tax_id} == $tax->id } keys %{ $pat{amounts} };
 399     push(@{ $self->{taxes} }, { amount    => $pat{taxes}->{$tax_chart_id},
 400                                 netamount => $pat{amounts}->{$amount_keys[0]}->{amount},
 401                                 tax       => $tax });
 402   }
 403
 404   pairwise { $a->{linetotal} = $b->{linetotal} } @{$self->order->items}, @{$pat{items}};
 405 }
 406
 407 sub _save {
 408   my ($self) = @_;
 409
 410   # autovivify all cvars that are not in the form (cvars_by_config can do it)
 411   foreach my $item (@{ $self->order->items }) {
 412     $item->cvars_by_config;
 413   }
 414
 415   my $errors = [];
 416   my $db = $self->order->db;
 417
 418   $db->do_transaction(
 419     sub {
 420       $self->order->save();
 421   }) || push(@{$errors}, $db->error);
 422
 423   return $errors;
 424 }
 425
 426
 427 sub _pre_render {
 428   my ($self) = @_;
 429
 430   $self->{all_taxzones}        = SL::DB::Manager::TaxZone->get_all_sorted();
 431   $self->{all_employees}       = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->employee_id,
 432                                                                                        deleted => 0 ] ],
 433                                                                     sort_by => 'name');
 434   $self->{all_salesmen}        = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->salesman_id,
 435                                                                                        deleted => 0 ] ],
 436                                                                     sort_by => 'name');
 437   $self->{all_projects}        = SL::DB::Manager::Project->get_all(where => [ or => [ id => $self->order->globalproject_id,
 438                                                                                       active => 1 ] ],
 439                                                                    sort_by => 'projectnumber');
 440   $self->{all_payment_terms}   = SL::DB::Manager::PaymentTerm->get_all_sorted();
 441   $self->{all_delivery_terms}  = SL::DB::Manager::DeliveryTerm->get_all_sorted();
 442
 443   $self->{current_employee_id} = SL::DB::Manager::Employee->current->id;
 444
 445   $::request->{layout}->use_javascript("${_}.js")  for qw(ckeditor/ckeditor ckeditor/adapters/jquery);
 446 }
 447
 448 sub _sales_order_type {
 449   'sales_order';
 450 }
 451
 452 sub _purchase_order_type {
 453   'purchase_order';
 454 }
 455
 456 1;