SL/Controller/Order.pm

   1 package SL::Controller::Order;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use SL::Helper::Flash;
   7 use SL::ClientJS;
   8 use SL::Presenter;
   9
  10 use SL::DB::Order;
  11 use SL::DB::Customer;
  12 use SL::DB::Vendor;
  13 use SL::DB::TaxZone;
  14 use SL::DB::Employee;
  15 use SL::DB::Project;
  16 use SL::DB::Default;
  17 use SL::DB::Unit;
  18
  19 use SL::Helper::DateTime;
  20
  21 use List::Util qw(max first);
  22 use List::MoreUtils qw(none pairwise);
  23
  24 use Rose::Object::MakeMethods::Generic
  25 (
  26  'scalar --get_set_init' => [ qw(order valid_types type cv js p) ],
  27 );
  28
  29
  30 # safety
  31 __PACKAGE__->run_before('_check_auth');
  32
  33 __PACKAGE__->run_before('_recalc',
  34                         only => [ qw(edit update save) ]);
  35
  36
  37 #
  38 # actions
  39 #
  40
  41 sub action_add {
  42   my ($self) = @_;
  43
  44   $self->order->transdate(DateTime->now_local());
  45
  46   $self->_pre_render();
  47   $self->render(
  48     'order/form',
  49     title => $self->type eq _sales_order_type()    ? $::locale->text('Add Sales Order')
  50            : $self->type eq _purchase_order_type() ? $::locale->text('Add Purchase Order')
  51            : '',
  52     %{$self->{template_args}}
  53   );
  54 }
  55
  56 sub action_edit {
  57   my ($self) = @_;
  58
  59   $self->_pre_render();
  60   $self->render(
  61     'order/form',
  62     title => $self->type eq _sales_order_type()    ? $::locale->text('Edit Sales Order')
  63            : $self->type eq _purchase_order_type() ? $::locale->text('Edit Purchase Order')
  64            : '',
  65     %{$self->{template_args}}
  66   );
  67 }
  68
  69 sub action_update {
  70   my ($self) = @_;
  71
  72   $self->_pre_render();
  73   $self->render(
  74     'order/form',
  75     title => $self->type eq _sales_order_type()    ? $::locale->text('Edit Sales Order')
  76            : $self->type eq _purchase_order_type() ? $::locale->text('Edit Purchase Order')
  77            : '',
  78     %{$self->{template_args}}
  79   );
  80 }
  81
  82 sub action_save {
  83   my ($self) = @_;
  84
  85   my $errors = $self->_save();
  86
  87   if (scalar @{ $errors }) {
  88     $self->js->flash('error', $_) foreach @{ $errors };
  89     return $self->js->render($self);
  90   }
  91
  92   flash_later('info', 'The order has been saved');
  93   my @redirect_params = (
  94     action => 'edit',
  95     type   => $self->type,
  96     id     => $self->order->id,
  97   );
  98
  99   $self->redirect_to(@redirect_params);
 100 }
 101
 102 sub action_customer_vendor_changed {
 103   my ($self) = @_;
 104
 105   if ($self->cv eq 'customer') {
 106     $self->order->customer(SL::DB::Manager::Customer->find_by_or_create(id => $::form->{cv_id}));
 107
 108   } elsif ($self->cv eq 'vendor') {
 109     $self->order->vendor(SL::DB::Manager::Vendor->find_by_or_create(id => $::form->{cv_id}));
 110   }
 111
 112   if ($self->order->{$self->cv}->contacts && scalar @{ $self->order->{$self->cv}->contacts } > 0) {
 113     $self->js->show('#cp_row');
 114   } else {
 115     $self->js->hide('#cp_row');
 116   }
 117
 118   if ($self->order->{$self->cv}->shipto && scalar @{ $self->order->{$self->cv}->shipto } > 0) {
 119     $self->js->show('#shipto_row');
 120   } else {
 121     $self->js->hide('#shipto_row');
 122   }
 123
 124   $self->js
 125     ->replaceWith('#order_cp_id',     $self->build_contact_select)
 126     ->replaceWith('#order_shipto_id', $self->build_shipto_select)
 127     ->val('#order_taxzone_id', $self->order->{$self->cv}->taxzone_id)
 128     ->focus('#order_' . $self->cv . ' _id')
 129     ->render($self);
 130 }
 131
 132 sub action_add_item {
 133   my ($self) = @_;
 134
 135   my $form_attr = $::form->{add_item};
 136
 137   return unless $form_attr->{parts_id};
 138
 139   my $item      = SL::DB::OrderItem->new;
 140   $item->assign_attributes(%$form_attr);
 141
 142   my $part        = SL::DB::Part->new(id => $form_attr->{parts_id})->load;
 143   my $cv_discount = $self->order->customer? $self->order->customer->discount : 0.0;
 144
 145   my %new_attr;
 146   $new_attr{part}        = $part;
 147   $new_attr{description} = $part->description if ! $item->{description};
 148   $new_attr{qty}         = 1.0                if ! $item->{qty};
 149   $new_attr{unit}        = $part->unit;
 150   $new_attr{sellprice}   = $part->sellprice   if ! $item->{sellprice};
 151   $new_attr{discount}    = $cv_discount       if ! $item->{discount};
 152
 153   $item->assign_attributes(%new_attr);
 154   $item->id(join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000)) if !$item->id;
 155
 156   $self->order->add_items($item);
 157
 158   $self->_recalc();
 159
 160   my $row_as_html = $self->p->render('order/tabs/_row', ITEM => $item);
 161
 162   $self->js
 163     ->append('#row_table_id tbody', $row_as_html)
 164     ->val('#add_item_parts_id', '')
 165     ->val('#add_item_parts_id_name', '')
 166     ->val('#add_item_description', '')
 167     ->val('#add_item_qty_as_number', '')
 168     ->val('#add_item_sellprice_as_number', '')
 169     ->val('#add_item_discount_as_percent', '')
 170     ->run('row_table_scroll_down')
 171     ->focus('#add_item_parts_id_name');
 172
 173   $self->_js_redisplay_amounts_and_taxes;
 174   $self->js->render($self);
 175 }
 176
 177 sub action_recalc_amounts_and_taxes {
 178   my ($self) = @_;
 179
 180   $self->_recalc();
 181
 182   $self->_js_redisplay_amounts_and_taxes;
 183   $self->js->render($self);
 184 }
 185
 186 sub _js_redisplay_amounts_and_taxes {
 187   my ($self) = @_;
 188
 189   $self->js
 190     ->html('#netamount_id', $::form->format_amount(\%::myconfig, $self->order->netamount, -2))
 191     ->html('#amount_id',    $::form->format_amount(\%::myconfig, $self->order->amount,    -2))
 192     ->remove('.tax_row')
 193     ->insertBefore($self->build_tax_rows, '#amount_row_id');
 194 }
 195
 196 #
 197 # helpers
 198 #
 199
 200 sub init_valid_types {
 201   [ _sales_order_type(), _purchase_order_type() ];
 202 }
 203
 204 sub init_type {
 205   my ($self) = @_;
 206
 207   if (none { $::form->{type} eq $_ } @{$self->valid_types}) {
 208     die "Not a valid type for order";
 209   }
 210
 211   $self->type($::form->{type});
 212 }
 213
 214 sub init_cv {
 215   my ($self) = @_;
 216
 217   my $cv = $self->type eq _sales_order_type()    ? 'customer'
 218          : $self->type eq _purchase_order_type() ? 'vendor'
 219          : die "Not a valid type for order";
 220
 221   return $cv;
 222 }
 223
 224 sub init_js {
 225   SL::ClientJS->new;
 226 }
 227
 228 sub init_p {
 229   SL::Presenter->get;
 230 }
 231
 232 sub init_order {
 233   _make_order();
 234 }
 235
 236 sub _check_auth {
 237   my ($self) = @_;
 238
 239   my $right_for = { map { $_ => $_.'_edit' } @{$self->valid_types} };
 240
 241   my $right   = $right_for->{ $self->type };
 242   $right    ||= 'DOES_NOT_EXIST';
 243
 244   $::auth->assert($right);
 245 }
 246
 247 sub build_contact_select {
 248   my ($self) = @_;
 249
 250   $self->p->select_tag('order.cp_id', [ $self->order->{$self->cv}->contacts ],
 251                        value_key  => 'cp_id',
 252                        title_key  => 'full_name_dep',
 253                        default    => $self->order->cp_id,
 254                        with_empty => 1,
 255                        style      => 'width: 300px',
 256   );
 257 }
 258
 259 sub build_shipto_select {
 260   my ($self) = @_;
 261
 262   $self->p->select_tag('order.shipto_id', [ $self->order->{$self->cv}->shipto ],
 263                        value_key  => 'shipto_id',
 264                        title_key  => 'displayable_id',
 265                        default    => $self->order->shipto_id,
 266                        with_empty => 1,
 267                        style      => 'width: 300px',
 268   );
 269 }
 270
 271 sub build_tax_rows {
 272   my ($self) = @_;
 273
 274   my $rows_as_html;
 275   foreach my $tax (@{ $self->{taxes} }) {
 276     $rows_as_html .= $self->p->render('order/tabs/_tax_row', TAX => $tax);
 277   }
 278   return $rows_as_html;
 279 }
 280
 281
 282 sub _make_order {
 283   my ($self) = @_;
 284
 285   # add_items adds items to an order with no items for saving, but they cannot
 286   # be retrieved via items until the order is saved. Adding empty items to new
 287   # order here solves this problem.
 288   my $order;
 289   $order   = SL::DB::Manager::Order->find_by(id => $::form->{id}) if $::form->{id};
 290   $order ||= SL::DB::Order->new(orderitems => []);
 291
 292   $order->assign_attributes(%{$::form->{order}});
 293
 294   return $order;
 295 }
 296
 297
 298 sub _recalc {
 299   my ($self) = @_;
 300
 301   # bb: todo: currency later
 302   $self->order->currency_id($::instance_conf->get_currency_id());
 303
 304   my %pat = $self->order->calculate_prices_and_taxes();
 305
 306   foreach my $tax_chart_id (keys %{ $pat{taxes} }) {
 307     my $tax = SL::DB::Manager::Tax->find_by(chart_id => $tax_chart_id);
 308     push(@{ $self->{taxes} }, { amount => $pat{taxes}->{$tax_chart_id},
 309                                 tax    => $tax });
 310   }
 311
 312   pairwise { $a->{linetotal} = $b->{linetotal} } @{$self->order->items}, @{$pat{items}};
 313 }
 314
 315 sub _save {
 316   my ($self) = @_;
 317
 318   my $errors = [];
 319   my $db = $self->order->db;
 320
 321   $db->do_transaction(
 322     sub {
 323       $self->order->save();
 324   }) || push(@{$errors}, $db->error);
 325
 326   return $errors;
 327 }
 328
 329
 330 sub _pre_render {
 331   my ($self) = @_;
 332
 333   $self->{all_taxzones}  = SL::DB::Manager::TaxZone->get_all_sorted();
 334   $self->{all_employees} = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->employee_id,
 335                                                                                  deleted => 0 ] ],
 336                                                               sort_by => 'name');
 337   $self->{all_projects}  = SL::DB::Manager::Project->get_all(where => [ or => [ id => $self->order->globalproject_id,
 338                                                                                 active => 1 ] ],
 339                                                              sort_by => 'projectnumber');
 340
 341   $self->{current_employee_id} = SL::DB::Manager::Employee->current->id;
 342 }
 343
 344 sub _sales_order_type {
 345   'sales_order';
 346 }
 347
 348 sub _purchase_order_type {
 349   'purchase_order';
 350 }
 351
 352 1;