SL/Controller/Order.pm

   1 package SL::Controller::Order;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use SL::Helper::Flash;
   7 use SL::Presenter;
   8 use SL::Locale::String;
   9 use SL::SessionFile::Random;
  10 use SL::PriceSource;
  11 use SL::Form;
  12
  13 use SL::DB::Order;
  14 use SL::DB::Customer;
  15 use SL::DB::Vendor;
  16 use SL::DB::TaxZone;
  17 use SL::DB::Employee;
  18 use SL::DB::Project;
  19 use SL::DB::Default;
  20 use SL::DB::Unit;
  21 use SL::DB::Price;
  22
  23 use SL::Helper::DateTime;
  24 use SL::Helper::CreatePDF qw(:all);
  25
  26 use List::Util qw(max first);
  27 use List::MoreUtils qw(none pairwise first_index);
  28 use English qw(-no_match_vars);
  29 use File::Spec;
  30
  31 use Rose::Object::MakeMethods::Generic
  32 (
  33  'scalar --get_set_init' => [ qw(order valid_types type cv p) ],
  34 );
  35
  36
  37 # safety
  38 __PACKAGE__->run_before('_check_auth');
  39
  40 __PACKAGE__->run_before('_recalc',
  41                         only => [ qw(edit update save save_and_delivery_order create_pdf send_email) ]);
  42
  43 __PACKAGE__->run_before('_get_unalterable_data',
  44                         only => [ qw(save save_and_delivery_order create_pdf send_email) ]);
  45
  46 #
  47 # actions
  48 #
  49
  50 sub action_add {
  51   my ($self) = @_;
  52
  53   $self->order->transdate(DateTime->now_local());
  54   $self->order->reqdate(DateTime->today_local->next_workday) if !$self->order->reqdate;
  55
  56   $self->_pre_render();
  57   $self->render(
  58     'order/form',
  59     title => $self->type eq _sales_order_type()    ? $::locale->text('Add Sales Order')
  60            : $self->type eq _purchase_order_type() ? $::locale->text('Add Purchase Order')
  61            : '',
  62     %{$self->{template_args}}
  63   );
  64 }
  65
  66 sub action_edit {
  67   my ($self) = @_;
  68
  69   $self->_pre_render();
  70   $self->render(
  71     'order/form',
  72     title => $self->type eq _sales_order_type()    ? $::locale->text('Edit Sales Order')
  73            : $self->type eq _purchase_order_type() ? $::locale->text('Edit Purchase Order')
  74            : '',
  75     %{$self->{template_args}}
  76   );
  77 }
  78
  79 sub action_update {
  80   my ($self) = @_;
  81
  82   $self->_pre_render();
  83   $self->render(
  84     'order/form',
  85     title => $self->type eq _sales_order_type()    ? $::locale->text('Edit Sales Order')
  86            : $self->type eq _purchase_order_type() ? $::locale->text('Edit Purchase Order')
  87            : '',
  88     %{$self->{template_args}}
  89   );
  90 }
  91
  92 sub action_delete {
  93   my ($self) = @_;
  94
  95   my $errors = $self->_delete();
  96
  97   if (scalar @{ $errors }) {
  98     $self->js->flash('error', $_) foreach @{ $errors };
  99     return $self->js->render();
 100   }
 101
 102   flash_later('info', $::locale->text('The order has been deleted'));
 103   my @redirect_params = (
 104     action => 'edit',
 105     type   => $self->type,
 106   );
 107
 108   $self->redirect_to(@redirect_params);
 109 }
 110
 111 sub action_save {
 112   my ($self) = @_;
 113
 114   my $errors = $self->_save();
 115
 116   if (scalar @{ $errors }) {
 117     $self->js->flash('error', $_) foreach @{ $errors };
 118     return $self->js->render();
 119   }
 120
 121   flash_later('info', $::locale->text('The order has been saved'));
 122   my @redirect_params = (
 123     action => 'edit',
 124     type   => $self->type,
 125     id     => $self->order->id,
 126   );
 127
 128   $self->redirect_to(@redirect_params);
 129 }
 130
 131 sub action_create_pdf {
 132   my ($self) = @_;
 133
 134   my $pdf;
 135   my @errors = _create_pdf($self->order, \$pdf);
 136   if (scalar @errors) {
 137     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render($self);
 138   }
 139
 140   my $sfile = SL::SessionFile::Random->new(mode => "w");
 141   $sfile->fh->print($pdf);
 142   $sfile->fh->close;
 143
 144   my $key = join('_', Time::HiRes::gettimeofday(), int rand 1000000000000);
 145   $::auth->set_session_value("Order::create_pdf-${key}" => $sfile->file_name);
 146
 147   my $form = Form->new;
 148   $form->{ordnumber} = $self->order->ordnumber;
 149   $form->{formname}  = $self->type;
 150   $form->{type}      = $self->type;
 151   $form->{language}  = 'de';
 152   $form->{format}    = 'pdf';
 153
 154   my $pdf_filename = $form->generate_attachment_filename();
 155
 156   $self->js
 157     ->run('download_pdf', $pdf_filename, $key)
 158     ->flash('info', t8('The PDF has been created'))->render($self);
 159 }
 160
 161 sub action_download_pdf {
 162   my ($self) = @_;
 163
 164   my $key = $::form->{key};
 165   my $tmp_filename = $::auth->get_session_value("Order::create_pdf-${key}");
 166   return $self->send_file(
 167     $tmp_filename,
 168     type => 'application/pdf',
 169     name => $::form->{pdf_filename},
 170   );
 171 }
 172
 173 sub action_show_email_dialog {
 174   my ($self) = @_;
 175
 176   my $cv_method = $self->cv;
 177
 178   if (!$self->order->$cv_method) {
 179     return $self->js->flash('error', $self->cv eq 'customer' ? t8('Cannot send E-mail without customer given') : t8('Cannot send E-mail without vendor given'))
 180                     ->render($self);
 181   }
 182
 183   $self->{email}->{to}   = $self->order->contact->cp_email if $self->order->contact;
 184   $self->{email}->{to} ||= $self->order->$cv_method->email;
 185   $self->{email}->{cc}   = $self->order->$cv_method->cc;
 186   $self->{email}->{bcc}  = join ', ', grep $_, $self->order->$cv_method->bcc, SL::DB::Default->get->global_bcc;
 187   # Todo: get addresses from shipto, if any
 188
 189   my $form = Form->new;
 190   $form->{ordnumber} = $self->order->ordnumber;
 191   $form->{formname}  = $self->type;
 192   $form->{type}      = $self->type;
 193   $form->{language} = 'de';
 194   $form->{format}   = 'pdf';
 195
 196   $self->{email}->{subject}             = $form->generate_email_subject();
 197   $self->{email}->{attachment_filename} = $form->generate_attachment_filename();
 198   $self->{email}->{message}             = $form->create_email_signature();
 199
 200   my $dialog_html = $self->render('order/tabs/_email_dialog', { output => 0 });
 201   $self->js
 202       ->run('show_email_dialog', $dialog_html)
 203       ->reinit_widgets
 204       ->render($self);
 205 }
 206
 207 # Todo: handling error messages: flash is not displayed in dialog, but in the main form
 208 sub action_send_email {
 209   my ($self) = @_;
 210
 211   my $mail      = Mailer->new;
 212   $mail->{from} = qq|"$::myconfig{name}" <$::myconfig{email}>|;
 213   $mail->{$_}   = $::form->{email}->{$_} for qw(to cc bcc subject message);
 214
 215   my $pdf;
 216   my @errors = _create_pdf($self->order, \$pdf, {media => 'email'});
 217   if (scalar @errors) {
 218     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render($self);
 219   }
 220
 221   $mail->{attachments} = [{ "content" => $pdf,
 222                             "name"    => $::form->{email}->{attachment_filename} }];
 223
 224   if (my $err = $mail->send) {
 225     return $self->js->flash('error', t8('Sending E-mail: ') . $err)
 226                     ->render($self);
 227   }
 228
 229   # internal notes
 230   my $intnotes = $self->order->intnotes;
 231   $intnotes   .= "\n\n" if $self->order->intnotes;
 232   $intnotes   .= t8('[email]')                                                                                        . "\n";
 233   $intnotes   .= t8('Date')       . ": " . $::locale->format_date_object(DateTime->now_local, precision => 'seconds') . "\n";
 234   $intnotes   .= t8('To (email)') . ": " . $mail->{to}                                                                . "\n";
 235   $intnotes   .= t8('Cc')         . ": " . $mail->{cc}                                                                . "\n"    if $mail->{cc};
 236   $intnotes   .= t8('Bcc')        . ": " . $mail->{bcc}                                                               . "\n"    if $mail->{bcc};
 237   $intnotes   .= t8('Subject')    . ": " . $mail->{subject}                                                           . "\n\n";
 238   $intnotes   .= t8('Message')    . ": " . $mail->{message};
 239
 240   $self->js
 241       ->val('#order_intnotes', $intnotes)
 242       ->run('close_email_dialog')
 243       ->render($self);
 244 }
 245
 246 sub action_save_and_delivery_order {
 247   my ($self) = @_;
 248
 249   my $errors = $self->_save();
 250
 251   if (scalar @{ $errors }) {
 252     $self->js->flash('error', $_) foreach @{ $errors };
 253     return $self->js->render();
 254   }
 255   flash_later('info', $::locale->text('The order has been saved'));
 256
 257   my @redirect_params = (
 258     controller => 'oe.pl',
 259     action     => 'oe_delivery_order_from_order',
 260     id         => $self->order->id,
 261   );
 262
 263   $self->redirect_to(@redirect_params);
 264 }
 265
 266 sub action_customer_vendor_changed {
 267   my ($self) = @_;
 268
 269   my $cv_method = $self->cv;
 270
 271   if ($self->order->$cv_method->contacts && scalar @{ $self->order->$cv_method->contacts } > 0) {
 272     $self->js->show('#cp_row');
 273   } else {
 274     $self->js->hide('#cp_row');
 275   }
 276
 277   if ($self->order->$cv_method->shipto && scalar @{ $self->order->$cv_method->shipto } > 0) {
 278     $self->js->show('#shipto_row');
 279   } else {
 280     $self->js->hide('#shipto_row');
 281   }
 282
 283   $self->order->taxzone_id($self->order->$cv_method->taxzone_id);
 284
 285   if ($self->order->is_sales) {
 286     $self->order->taxincluded(defined($self->order->$cv_method->taxincluded_checked)
 287                               ? $self->order->$cv_method->taxincluded_checked
 288                               : $::myconfig{taxincluded_checked});
 289   }
 290
 291   $self->order->payment_id($self->order->$cv_method->payment_id);
 292   $self->order->delivery_term_id($self->order->$cv_method->delivery_term_id);
 293
 294   $self->_recalc();
 295
 296   $self->js
 297     ->replaceWith('#order_cp_id',            $self->build_contact_select)
 298     ->replaceWith('#order_shipto_id',        $self->build_shipto_select)
 299     ->val(        '#order_taxzone_id',       $self->order->taxzone_id)
 300     ->val(        '#order_taxincluded',      $self->order->taxincluded)
 301     ->val(        '#order_payment_id',       $self->order->payment_id)
 302     ->val(        '#order_delivery_term_id', $self->order->delivery_term_id)
 303     ->val(        '#order_intnotes',         $self->order->$cv_method->notes)
 304     ->focus(      '#order_' . $self->cv . '_id');
 305
 306   $self->_js_redisplay_amounts_and_taxes;
 307   $self->js->render();
 308 }
 309
 310 sub action_add_item {
 311   my ($self) = @_;
 312
 313   my $form_attr = $::form->{add_item};
 314
 315   return unless $form_attr->{parts_id};
 316
 317   my $item = SL::DB::OrderItem->new;
 318   $item->assign_attributes(%$form_attr);
 319
 320   my $part         = SL::DB::Part->new(id => $form_attr->{parts_id})->load;
 321
 322   my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
 323
 324   my $price_src;
 325   if ($item->sellprice) {
 326     $price_src = $price_source->price_from_source("");
 327     $price_src->price($item->sellprice);
 328   } else {
 329     $price_src = $price_source->best_price
 330            ? $price_source->best_price
 331            : $price_source->price_from_source("");
 332     $price_src->price(0) if !$price_source->best_price;
 333   }
 334
 335   my $discount_src;
 336   if ($item->discount) {
 337     $discount_src = $price_source->discount_from_source("");
 338     $discount_src->discount($item->discount);
 339   } else {
 340     $discount_src = $price_source->best_discount
 341                   ? $price_source->best_discount
 342                   : $price_source->discount_from_source("");
 343     $discount_src->discount(0) if !$price_source->best_discount;
 344   }
 345
 346   my %new_attr;
 347   $new_attr{part}                   = $part;
 348   $new_attr{description}            = $part->description if ! $item->description;
 349   $new_attr{qty}                    = 1.0                if ! $item->qty;
 350   $new_attr{sellprice}              = $price_src->price;
 351   $new_attr{discount}               = $discount_src->discount;
 352   $new_attr{active_price_source}    = $price_src;
 353   $new_attr{active_discount_source} = $discount_src;
 354
 355   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
 356   # they cannot be retrieved via custom_variables until the order/orderitem is
 357   # saved. Adding empty custom_variables to new orderitem here solves this problem.
 358   $new_attr{custom_variables} = [];
 359
 360   $item->assign_attributes(%new_attr);
 361
 362   $self->order->add_items($item);
 363
 364   $self->_recalc();
 365
 366   my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 367   my $row_as_html = $self->p->render('order/tabs/_row', ITEM => $item, ID => $item_id);
 368
 369   $self->js
 370     ->append('#row_table_id', $row_as_html)
 371     ->val('.add_item_input', '')
 372     ->run('row_table_scroll_down')
 373     ->run('row_set_keyboard_events_by_id', $item_id)
 374     ->on('.recalc', 'change', 'recalc_amounts_and_taxes')
 375     ->on('.reformat_number', 'change', 'reformat_number')
 376     ->focus('#add_item_parts_id_name');
 377
 378   $self->_js_redisplay_amounts_and_taxes;
 379   $self->js->render();
 380 }
 381
 382 sub action_recalc_amounts_and_taxes {
 383   my ($self) = @_;
 384
 385   $self->_recalc();
 386
 387   $self->_js_redisplay_linetotals;
 388   $self->_js_redisplay_amounts_and_taxes;
 389   $self->js->render();
 390 }
 391
 392 sub action_price_popup {
 393   my ($self) = @_;
 394
 395   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 396   my $item = $self->order->items->[$idx];
 397
 398   $self->render_price_dialog($item);
 399 }
 400
 401 sub _js_redisplay_linetotals {
 402   my ($self) = @_;
 403
 404   my @data = map {$::form->format_amount(\%::myconfig, $_->{linetotal}, 2, 0)} @{ $self->order->items };
 405   $self->js
 406     ->run('redisplay_linetotals', \@data);
 407 }
 408
 409 sub _js_redisplay_amounts_and_taxes {
 410   my ($self) = @_;
 411
 412   if (scalar @{ $self->{taxes} }) {
 413     $self->js->show('#taxincluded_row_id');
 414   } else {
 415     $self->js->hide('#taxincluded_row_id');
 416   }
 417
 418   if ($self->order->taxincluded) {
 419     $self->js->hide('#subtotal_row_id');
 420   } else {
 421     $self->js->show('#subtotal_row_id');
 422   }
 423
 424   $self->js
 425     ->html('#netamount_id', $::form->format_amount(\%::myconfig, $self->order->netamount, -2))
 426     ->html('#amount_id',    $::form->format_amount(\%::myconfig, $self->order->amount,    -2))
 427     ->remove('.tax_row')
 428     ->insertBefore($self->build_tax_rows, '#amount_row_id');
 429 }
 430
 431 #
 432 # helpers
 433 #
 434
 435 sub init_valid_types {
 436   [ _sales_order_type(), _purchase_order_type() ];
 437 }
 438
 439 sub init_type {
 440   my ($self) = @_;
 441
 442   if (none { $::form->{type} eq $_ } @{$self->valid_types}) {
 443     die "Not a valid type for order";
 444   }
 445
 446   $self->type($::form->{type});
 447 }
 448
 449 sub init_cv {
 450   my ($self) = @_;
 451
 452   my $cv = $self->type eq _sales_order_type()    ? 'customer'
 453          : $self->type eq _purchase_order_type() ? 'vendor'
 454          : die "Not a valid type for order";
 455
 456   return $cv;
 457 }
 458
 459 sub init_p {
 460   SL::Presenter->get;
 461 }
 462
 463 sub init_order {
 464   _make_order();
 465 }
 466
 467 sub _check_auth {
 468   my ($self) = @_;
 469
 470   my $right_for = { map { $_ => $_.'_edit' } @{$self->valid_types} };
 471
 472   my $right   = $right_for->{ $self->type };
 473   $right    ||= 'DOES_NOT_EXIST';
 474
 475   $::auth->assert($right);
 476 }
 477
 478 sub build_contact_select {
 479   my ($self) = @_;
 480
 481   $self->p->select_tag('order.cp_id', [ $self->order->{$self->cv}->contacts ],
 482                        value_key  => 'cp_id',
 483                        title_key  => 'full_name_dep',
 484                        default    => $self->order->cp_id,
 485                        with_empty => 1,
 486                        style      => 'width: 300px',
 487   );
 488 }
 489
 490 sub build_shipto_select {
 491   my ($self) = @_;
 492
 493   $self->p->select_tag('order.shipto_id', [ $self->order->{$self->cv}->shipto ],
 494                        value_key  => 'shipto_id',
 495                        title_key  => 'displayable_id',
 496                        default    => $self->order->shipto_id,
 497                        with_empty => 1,
 498                        style      => 'width: 300px',
 499   );
 500 }
 501
 502 sub build_tax_rows {
 503   my ($self) = @_;
 504
 505   my $rows_as_html;
 506   foreach my $tax (sort { $a->{tax}->rate cmp $b->{tax}->rate } @{ $self->{taxes} }) {
 507     $rows_as_html .= $self->p->render('order/tabs/_tax_row', TAX => $tax, TAXINCLUDED => $self->order->taxincluded);
 508   }
 509   return $rows_as_html;
 510 }
 511
 512
 513 sub render_price_dialog {
 514   my ($self, $record_item) = @_;
 515
 516   my $price_source = SL::PriceSource->new(record_item => $record_item, record => $self->order);
 517
 518   $self->js
 519     ->run(
 520       'kivi.io.price_chooser_dialog',
 521       t8('Available Prices'),
 522       $self->render('order/tabs/_price_sources_dialog', { output => 0 }, price_source => $price_source)
 523     )
 524     ->reinit_widgets;
 525
 526 #   if (@errors) {
 527 #     $self->js->text('#dialog_flash_error_content', join ' ', @errors);
 528 #     $self->js->show('#dialog_flash_error');
 529 #   }
 530
 531   $self->js->render;
 532 }
 533
 534 sub _make_order {
 535   my ($self) = @_;
 536
 537   # add_items adds items to an order with no items for saving, but they cannot
 538   # be retrieved via items until the order is saved. Adding empty items to new
 539   # order here solves this problem.
 540   my $order;
 541   $order   = SL::DB::Manager::Order->find_by(id => $::form->{id}) if $::form->{id};
 542   $order ||= SL::DB::Order->new(orderitems => []);
 543
 544   $order->assign_attributes(%{$::form->{order}});
 545
 546   return $order;
 547 }
 548
 549 sub _recalc {
 550   my ($self) = @_;
 551
 552   # bb: todo: currency later
 553   $self->order->currency_id($::instance_conf->get_currency_id());
 554
 555   my %pat = $self->order->calculate_prices_and_taxes();
 556   $self->{taxes} = [];
 557   foreach my $tax_chart_id (keys %{ $pat{taxes} }) {
 558     my $tax = SL::DB::Manager::Tax->find_by(chart_id => $tax_chart_id);
 559
 560     my @amount_keys = grep { $pat{amounts}->{$_}->{tax_id} == $tax->id } keys %{ $pat{amounts} };
 561     push(@{ $self->{taxes} }, { amount    => $pat{taxes}->{$tax_chart_id},
 562                                 netamount => $pat{amounts}->{$amount_keys[0]}->{amount},
 563                                 tax       => $tax });
 564   }
 565
 566   pairwise { $a->{linetotal} = $b->{linetotal} } @{$self->order->items}, @{$pat{items}};
 567 }
 568
 569
 570 sub _get_unalterable_data {
 571   my ($self) = @_;
 572
 573   foreach my $item (@{ $self->order->items }) {
 574     if ($item->id) {
 575       # load data from orderitems (db)
 576       my $db_item = SL::DB::OrderItem->new(id => $item->id)->load;
 577       $item->$_($db_item->$_) for qw(longdescription);
 578     } else {
 579       # set data from part (or other sources)
 580       $item->longdescription($item->part->notes);
 581     }
 582
 583     # autovivify all cvars that are not in the form (cvars_by_config can do it).
 584     # workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
 585     foreach my $var (@{ $item->cvars_by_config }) {
 586       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
 587     }
 588     $item->parse_custom_variable_values;
 589   }
 590 }
 591
 592
 593 sub _delete {
 594   my ($self) = @_;
 595
 596   my $errors = [];
 597   my $db = $self->order->db;
 598
 599   $db->do_transaction(
 600     sub {
 601       my @spoolfiles = grep { $_ } map { $_->spoolfile } @{ SL::DB::Manager::Status->get_all(where => [ trans_id => $self->order->id ]) };
 602       $self->order->delete;
 603       my $spool = $::lx_office_conf{paths}->{spool};
 604       unlink map { "$spool/$_" } @spoolfiles if $spool;
 605
 606       1;
 607   }) || push(@{$errors}, $db->error);
 608
 609   return $errors;
 610 }
 611
 612
 613 sub _save {
 614   my ($self) = @_;
 615
 616   my $errors = [];
 617   my $db = $self->order->db;
 618
 619   $db->do_transaction(
 620     sub {
 621       $self->order->save();
 622   }) || push(@{$errors}, $db->error);
 623
 624   return $errors;
 625 }
 626
 627
 628 sub _pre_render {
 629   my ($self) = @_;
 630
 631   $self->{all_taxzones}        = SL::DB::Manager::TaxZone->get_all_sorted();
 632   $self->{all_employees}       = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->employee_id,
 633                                                                                        deleted => 0 ] ],
 634                                                                     sort_by => 'name');
 635   $self->{all_salesmen}        = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->salesman_id,
 636                                                                                        deleted => 0 ] ],
 637                                                                     sort_by => 'name');
 638   $self->{all_projects}        = SL::DB::Manager::Project->get_all(where => [ or => [ id => $self->order->globalproject_id,
 639                                                                                       active => 1 ] ],
 640                                                                    sort_by => 'projectnumber');
 641   $self->{all_payment_terms}   = SL::DB::Manager::PaymentTerm->get_all_sorted();
 642   $self->{all_delivery_terms}  = SL::DB::Manager::DeliveryTerm->get_all_sorted();
 643
 644   $self->{current_employee_id} = SL::DB::Manager::Employee->current->id;
 645
 646   foreach  my $item (@{$self->order->items}) {
 647     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
 648     $item->active_price_source(   $price_source->price_from_source(   $item->active_price_source   ));
 649     $item->active_discount_source($price_source->discount_from_source($item->active_discount_source));
 650
 651   }
 652
 653   $::request->{layout}->use_javascript("${_}.js")  for qw(ckeditor/ckeditor ckeditor/adapters/jquery);
 654 }
 655
 656 sub _create_pdf {
 657   my ($order, $pdf_ref, $params) = @_;
 658
 659   my $print_form = Form->new('');
 660   $print_form->{type}     = $order->type;
 661   $print_form->{formname} = $order->type;
 662   $print_form->{format}   = $params->{format} || 'pdf',
 663   $print_form->{media}    = $params->{media}  || 'file';
 664
 665   $order->flatten_to_form($print_form, format_amounts => 1);
 666   # flatten_to_form sets payment_terms from customer/vendor - we do not want that here
 667   delete $print_form->{payment_terms} if !$print_form->{payment_id};
 668
 669   my @errors = ();
 670   $print_form->throw_on_error(sub {
 671     eval {
 672       $print_form->prepare_for_printing;
 673
 674       $$pdf_ref = SL::Helper::CreatePDF->create_pdf(
 675         template  => SL::Helper::CreatePDF->find_template(name => $print_form->{formname}),
 676         variables => $print_form,
 677         variable_content_types => {
 678           longdescription => 'html',
 679           partnotes       => 'html',
 680           notes           => 'html',
 681         },
 682       );
 683       1;
 684     } || push @errors, ref($EVAL_ERROR) eq 'SL::X::FormError' ? $EVAL_ERROR->getMessage : $EVAL_ERROR;
 685   });
 686
 687   return @errors;
 688 }
 689
 690 sub _sales_order_type {
 691   'sales_order';
 692 }
 693
 694 sub _purchase_order_type {
 695   'purchase_order';
 696 }
 697
 698 1;