SL/Controller/Order.pm

   1 package SL::Controller::Order;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use SL::Helper::Flash qw(flash_later);
   7 use SL::Presenter::Tag qw(select_tag hidden_tag div_tag);
   8 use SL::Locale::String qw(t8);
   9 use SL::SessionFile::Random;
  10 use SL::PriceSource;
  11 use SL::Webdav;
  12 use SL::File;
  13 use SL::MIME;
  14 use SL::Util qw(trim);
  15 use SL::YAML;
  16 use SL::DB::AdditionalBillingAddress;
  17 use SL::DB::History;
  18 use SL::DB::Order;
  19 use SL::DB::Default;
  20 use SL::DB::Unit;
  21 use SL::DB::Part;
  22 use SL::DB::PartClassification;
  23 use SL::DB::PartsGroup;
  24 use SL::DB::Printer;
  25 use SL::DB::Language;
  26 use SL::DB::RecordLink;
  27 use SL::DB::RequirementSpec;
  28 use SL::DB::Shipto;
  29 use SL::DB::Translation;
  30
  31 use SL::Helper::CreatePDF qw(:all);
  32 use SL::Helper::PrintOptions;
  33 use SL::Helper::ShippedQty;
  34 use SL::Helper::UserPreferences::PositionsScrollbar;
  35 use SL::Helper::UserPreferences::UpdatePositions;
  36
  37 use SL::Controller::Helper::GetModels;
  38
  39 use List::Util qw(first sum0);
  40 use List::UtilsBy qw(sort_by uniq_by);
  41 use List::MoreUtils qw(any none pairwise first_index);
  42 use English qw(-no_match_vars);
  43 use File::Spec;
  44 use Cwd;
  45 use Sort::Naturally;
  46
  47 use Rose::Object::MakeMethods::Generic
  48 (
  49  scalar => [ qw(item_ids_to_delete is_custom_shipto_to_delete) ],
  50  'scalar --get_set_init' => [ qw(order valid_types type cv p all_price_factors search_cvpartnumber show_update_button part_picker_classification_ids) ],
  51 );
  52
  53
  54 # safety
  55 __PACKAGE__->run_before('check_auth');
  56
  57 __PACKAGE__->run_before('recalc',
  58                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice save_and_ap_transaction
  59                                      print send_email) ]);
  60
  61 __PACKAGE__->run_before('get_unalterable_data',
  62                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice save_and_ap_transaction
  63                                      print send_email) ]);
  64
  65 #
  66 # actions
  67 #
  68
  69 # add a new order
  70 sub action_add {
  71   my ($self) = @_;
  72
  73   $self->order->transdate(DateTime->now_local());
  74   my $extra_days = $self->type eq sales_quotation_type() ? $::instance_conf->get_reqdate_interval       :
  75                    $self->type eq sales_order_type()     ? $::instance_conf->get_delivery_date_interval : 1;
  76
  77   if (   ($self->type eq sales_order_type()     &&  $::instance_conf->get_deliverydate_on)
  78       || ($self->type eq sales_quotation_type() &&  $::instance_conf->get_reqdate_on)
  79       && (!$self->order->reqdate)) {
  80     $self->order->reqdate(DateTime->today_local->next_workday(extra_days => $extra_days));
  81   }
  82
  83
  84   $self->pre_render();
  85   $self->render(
  86     'order/form',
  87     title => $self->get_title_for('add'),
  88     %{$self->{template_args}}
  89   );
  90 }
  91
  92 # edit an existing order
  93 sub action_edit {
  94   my ($self) = @_;
  95
  96   if ($::form->{id}) {
  97     $self->load_order;
  98
  99   } else {
 100     # this is to edit an order from an unsaved order object
 101
 102     # set item ids to new fake id, to identify them as new items
 103     foreach my $item (@{$self->order->items_sorted}) {
 104       $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 105     }
 106     # trigger rendering values for second row as hidden, because they
 107     # are loaded only on demand. So we need to keep the values from
 108     # the source.
 109     $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
 110   }
 111
 112   $self->recalc();
 113   $self->pre_render();
 114   $self->render(
 115     'order/form',
 116     title => $self->get_title_for('edit'),
 117     %{$self->{template_args}}
 118   );
 119 }
 120
 121 # edit a collective order (consisting of one or more existing orders)
 122 sub action_edit_collective {
 123   my ($self) = @_;
 124
 125   # collect order ids
 126   my @multi_ids = map {
 127     $_ =~ m{^multi_id_(\d+)$} && $::form->{'multi_id_' . $1} && $::form->{'trans_id_' . $1} && $::form->{'trans_id_' . $1}
 128   } grep { $_ =~ m{^multi_id_\d+$} } keys %$::form;
 129
 130   # fall back to add if no ids are given
 131   if (scalar @multi_ids == 0) {
 132     $self->action_add();
 133     return;
 134   }
 135
 136   # fall back to save as new if only one id is given
 137   if (scalar @multi_ids == 1) {
 138     $self->order(SL::DB::Order->new(id => $multi_ids[0])->load);
 139     $self->action_save_as_new();
 140     return;
 141   }
 142
 143   # make new order from given orders
 144   my @multi_orders = map { SL::DB::Order->new(id => $_)->load } @multi_ids;
 145   $self->{converted_from_oe_id} = join ' ', map { $_->id } @multi_orders;
 146   $self->order(SL::DB::Order->new_from_multi(\@multi_orders, sort_sources_by => 'transdate'));
 147
 148   $self->action_edit();
 149 }
 150
 151 # delete the order
 152 sub action_delete {
 153   my ($self) = @_;
 154
 155   my $errors = $self->delete();
 156
 157   if (scalar @{ $errors }) {
 158     $self->js->flash('error', $_) foreach @{ $errors };
 159     return $self->js->render();
 160   }
 161
 162   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been deleted')
 163            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been deleted')
 164            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been deleted')
 165            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been deleted')
 166            : '';
 167   flash_later('info', $text);
 168
 169   my @redirect_params = (
 170     action => 'add',
 171     type   => $self->type,
 172   );
 173
 174   $self->redirect_to(@redirect_params);
 175 }
 176
 177 # save the order
 178 sub action_save {
 179   my ($self) = @_;
 180
 181   my $errors = $self->save();
 182
 183   if (scalar @{ $errors }) {
 184     $self->js->flash('error', $_) foreach @{ $errors };
 185     return $self->js->render();
 186   }
 187
 188   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
 189            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
 190            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
 191            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
 192            : '';
 193   flash_later('info', $text);
 194
 195   my @redirect_params = (
 196     action => 'edit',
 197     type   => $self->type,
 198     id     => $self->order->id,
 199   );
 200
 201   $self->redirect_to(@redirect_params);
 202 }
 203
 204 # save the order as new document an open it for edit
 205 sub action_save_as_new {
 206   my ($self) = @_;
 207
 208   my $order = $self->order;
 209
 210   if (!$order->id) {
 211     $self->js->flash('error', t8('This object has not been saved yet.'));
 212     return $self->js->render();
 213   }
 214
 215   # load order from db to check if values changed
 216   my $saved_order = SL::DB::Order->new(id => $order->id)->load;
 217
 218   my %new_attrs;
 219   # Lets assign a new number if the user hasn't changed the previous one.
 220   # If it has been changed manually then use it as-is.
 221   $new_attrs{number}    = (trim($order->number) eq $saved_order->number)
 222                         ? ''
 223                         : trim($order->number);
 224
 225   # Clear transdate unless changed
 226   $new_attrs{transdate} = ($order->transdate == $saved_order->transdate)
 227                         ? DateTime->today_local
 228                         : $order->transdate;
 229
 230   # Set new reqdate unless changed if it is enabled in client config
 231   if ($order->reqdate == $saved_order->reqdate) {
 232     my $extra_days = $self->type eq sales_quotation_type() ? $::instance_conf->get_reqdate_interval       :
 233                      $self->type eq sales_order_type()     ? $::instance_conf->get_delivery_date_interval : 1;
 234
 235     if (   ($self->type eq sales_order_type()     &&  !$::instance_conf->get_deliverydate_on)
 236         || ($self->type eq sales_quotation_type() &&  !$::instance_conf->get_reqdate_on)) {
 237       $new_attrs{reqdate} = '';
 238     } else {
 239       $new_attrs{reqdate} = DateTime->today_local->next_workday(extra_days => $extra_days);
 240     }
 241   } else {
 242     $new_attrs{reqdate} = $order->reqdate;
 243   }
 244
 245   # Update employee
 246   $new_attrs{employee}  = SL::DB::Manager::Employee->current;
 247
 248   # Create new record from current one
 249   $self->order(SL::DB::Order->new_from($order, destination_type => $order->type, attributes => \%new_attrs));
 250
 251   # no linked records on save as new
 252   delete $::form->{$_} for qw(converted_from_oe_id converted_from_orderitems_ids);
 253
 254   # save
 255   $self->action_save();
 256 }
 257
 258 # print the order
 259 #
 260 # This is called if "print" is pressed in the print dialog.
 261 # If PDF creation was requested and succeeded, the pdf is offered for download
 262 # via send_file (which uses ajax in this case).
 263 sub action_print {
 264   my ($self) = @_;
 265
 266   my $errors = $self->save();
 267
 268   if (scalar @{ $errors }) {
 269     $self->js->flash('error', $_) foreach @{ $errors };
 270     return $self->js->render();
 271   }
 272
 273   $self->js_reset_order_and_item_ids_after_save;
 274
 275   my $format      = $::form->{print_options}->{format};
 276   my $media       = $::form->{print_options}->{media};
 277   my $formname    = $::form->{print_options}->{formname};
 278   my $copies      = $::form->{print_options}->{copies};
 279   my $groupitems  = $::form->{print_options}->{groupitems};
 280   my $printer_id  = $::form->{print_options}->{printer_id};
 281
 282   # only pdf and opendocument by now
 283   if (none { $format eq $_ } qw(pdf opendocument opendocument_pdf)) {
 284     return $self->js->flash('error', t8('Format \'#1\' is not supported yet/anymore.', $format))->render;
 285   }
 286
 287   # only screen or printer by now
 288   if (none { $media eq $_ } qw(screen printer)) {
 289     return $self->js->flash('error', t8('Media \'#1\' is not supported yet/anymore.', $media))->render;
 290   }
 291
 292   # create a form for generate_attachment_filename
 293   my $form   = Form->new;
 294   $form->{$self->nr_key()}  = $self->order->number;
 295   $form->{type}             = $self->type;
 296   $form->{format}           = $format;
 297   $form->{formname}         = $formname;
 298   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 299   my $pdf_filename          = $form->generate_attachment_filename();
 300
 301   my $pdf;
 302   my @errors = $self->generate_pdf(\$pdf, { format     => $format,
 303                                             formname   => $formname,
 304                                             language   => $self->order->language,
 305                                             printer_id => $printer_id,
 306                                             groupitems => $groupitems });
 307   if (scalar @errors) {
 308     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render;
 309   }
 310
 311   if ($media eq 'screen') {
 312     # screen/download
 313     $self->js->flash('info', t8('The PDF has been created'));
 314     $self->send_file(
 315       \$pdf,
 316       type         => SL::MIME->mime_type_from_ext($pdf_filename),
 317       name         => $pdf_filename,
 318       js_no_render => 1,
 319     );
 320
 321   } elsif ($media eq 'printer') {
 322     # printer
 323     my $printer_id = $::form->{print_options}->{printer_id};
 324     SL::DB::Printer->new(id => $printer_id)->load->print_document(
 325       copies  => $copies,
 326       content => $pdf,
 327     );
 328
 329     $self->js->flash('info', t8('The PDF has been printed'));
 330   }
 331
 332   my @warnings = $self->store_pdf_to_webdav_and_filemanagement($pdf, $pdf_filename);
 333   if (scalar @warnings) {
 334     $self->js->flash('warning', $_) for @warnings;
 335   }
 336
 337   $self->save_history('PRINTED');
 338
 339   $self->js
 340     ->run('kivi.ActionBar.setEnabled', '#save_and_email_action')
 341     ->render;
 342 }
 343 sub action_preview_pdf {
 344   my ($self) = @_;
 345
 346   my $errors = $self->save();
 347   if (scalar @{ $errors }) {
 348     $self->js->flash('error', $_) foreach @{ $errors };
 349     return $self->js->render();
 350   }
 351
 352   $self->js_reset_order_and_item_ids_after_save;
 353
 354   my $format      = 'pdf';
 355   my $media       = 'screen';
 356   my $formname    = $self->type;
 357
 358   # only pdf
 359   # create a form for generate_attachment_filename
 360   my $form   = Form->new;
 361   $form->{$self->nr_key()}  = $self->order->number;
 362   $form->{type}             = $self->type;
 363   $form->{format}           = $format;
 364   $form->{formname}         = $formname;
 365   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 366   my $pdf_filename          = $form->generate_attachment_filename();
 367
 368   my $pdf;
 369   my @errors = $self->generate_pdf(\$pdf, { format     => $format,
 370                                             formname   => $formname,
 371                                             language   => $self->order->language,
 372                                           });
 373   if (scalar @errors) {
 374     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render;
 375   }
 376   $self->save_history('PREVIEWED');
 377   $self->js->flash('info', t8('The PDF has been previewed'));
 378   # screen/download
 379   $self->send_file(
 380     \$pdf,
 381     type         => SL::MIME->mime_type_from_ext($pdf_filename),
 382     name         => $pdf_filename,
 383     js_no_render => 0,
 384   );
 385 }
 386
 387 # open the email dialog
 388 sub action_save_and_show_email_dialog {
 389   my ($self) = @_;
 390
 391   my $errors = $self->save();
 392
 393   if (scalar @{ $errors }) {
 394     $self->js->flash('error', $_) foreach @{ $errors };
 395     return $self->js->render();
 396   }
 397
 398   my $cv_method = $self->cv;
 399
 400   if (!$self->order->$cv_method) {
 401     return $self->js->flash('error', $self->cv eq 'customer' ? t8('Cannot send E-mail without customer given') : t8('Cannot send E-mail without vendor given'))
 402                     ->render($self);
 403   }
 404
 405   my $email_form;
 406   $email_form->{to}   = $self->order->contact->cp_email if $self->order->contact;
 407   $email_form->{to} ||= $self->order->$cv_method->email;
 408   $email_form->{cc}   = $self->order->$cv_method->cc;
 409   $email_form->{bcc}  = join ', ', grep $_, $self->order->$cv_method->bcc, SL::DB::Default->get->global_bcc;
 410   # Todo: get addresses from shipto, if any
 411
 412   my $form = Form->new;
 413   $form->{$self->nr_key()}  = $self->order->number;
 414   $form->{cusordnumber}     = $self->order->cusordnumber;
 415   $form->{formname}         = $self->type;
 416   $form->{type}             = $self->type;
 417   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 418   $form->{language_id}      = $self->order->language->id                  if $self->order->language;
 419   $form->{format}           = 'pdf';
 420   $form->{cp_id}            = $self->order->contact->cp_id if $self->order->contact;
 421
 422   $email_form->{subject}             = $form->generate_email_subject();
 423   $email_form->{attachment_filename} = $form->generate_attachment_filename();
 424   $email_form->{message}             = $form->generate_email_body();
 425   $email_form->{js_send_function}    = 'kivi.Order.send_email()';
 426
 427   my %files = $self->get_files_for_email_dialog();
 428
 429   $self->{all_employees} = SL::DB::Manager::Employee->get_all(query => [ deleted => 0 ]);
 430   my $dialog_html = $self->render('common/_send_email_dialog', { output => 0 },
 431                                   email_form    => $email_form,
 432                                   show_bcc      => $::auth->assert('email_bcc', 'may fail'),
 433                                   FILES         => \%files,
 434                                   is_customer   => $self->cv eq 'customer',
 435                                   ALL_EMPLOYEES => $self->{all_employees},
 436   );
 437
 438   $self->js
 439       ->run('kivi.Order.show_email_dialog', $dialog_html)
 440       ->reinit_widgets
 441       ->render($self);
 442 }
 443
 444 # send email
 445 #
 446 # Todo: handling error messages: flash is not displayed in dialog, but in the main form
 447 sub action_send_email {
 448   my ($self) = @_;
 449
 450   my $errors = $self->save();
 451
 452   if (scalar @{ $errors }) {
 453     $self->js->run('kivi.Order.close_email_dialog');
 454     $self->js->flash('error', $_) foreach @{ $errors };
 455     return $self->js->render();
 456   }
 457
 458   $self->js_reset_order_and_item_ids_after_save;
 459
 460   my $email_form  = delete $::form->{email_form};
 461   my %field_names = (to => 'email');
 462
 463   $::form->{ $field_names{$_} // $_ } = $email_form->{$_} for keys %{ $email_form };
 464
 465   # for Form::cleanup which may be called in Form::send_email
 466   $::form->{cwd}    = getcwd();
 467   $::form->{tmpdir} = $::lx_office_conf{paths}->{userspath};
 468
 469   $::form->{$_}     = $::form->{print_options}->{$_} for keys %{ $::form->{print_options} };
 470   $::form->{media}  = 'email';
 471
 472   if (($::form->{attachment_policy} // '') !~ m{^(?:old_file|no_file)$}) {
 473     my $pdf;
 474     my @errors = $self->generate_pdf(\$pdf, {media      => $::form->{media},
 475                                             format     => $::form->{print_options}->{format},
 476                                             formname   => $::form->{print_options}->{formname},
 477                                             language   => $self->order->language,
 478                                             printer_id => $::form->{print_options}->{printer_id},
 479                                             groupitems => $::form->{print_options}->{groupitems}});
 480     if (scalar @errors) {
 481       return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render($self);
 482     }
 483
 484     my @warnings = $self->store_pdf_to_webdav_and_filemanagement($pdf, $::form->{attachment_filename});
 485     if (scalar @warnings) {
 486       flash_later('warning', $_) for @warnings;
 487     }
 488
 489     my $sfile = SL::SessionFile::Random->new(mode => "w");
 490     $sfile->fh->print($pdf);
 491     $sfile->fh->close;
 492
 493     $::form->{tmpfile} = $sfile->file_name;
 494     $::form->{tmpdir}  = $sfile->get_path; # for Form::cleanup which may be called in Form::send_email
 495   }
 496
 497   $::form->{id} = $self->order->id; # this is used in SL::Mailer to create a linked record to the mail
 498   $::form->send_email(\%::myconfig, 'pdf');
 499
 500   # internal notes
 501   my $intnotes = $self->order->intnotes;
 502   $intnotes   .= "\n\n" if $self->order->intnotes;
 503   $intnotes   .= t8('[email]')                                                                                        . "\n";
 504   $intnotes   .= t8('Date')       . ": " . $::locale->format_date_object(DateTime->now_local, precision => 'seconds') . "\n";
 505   $intnotes   .= t8('To (email)') . ": " . $::form->{email}                                                           . "\n";
 506   $intnotes   .= t8('Cc')         . ": " . $::form->{cc}                                                              . "\n"    if $::form->{cc};
 507   $intnotes   .= t8('Bcc')        . ": " . $::form->{bcc}                                                             . "\n"    if $::form->{bcc};
 508   $intnotes   .= t8('Subject')    . ": " . $::form->{subject}                                                         . "\n\n";
 509   $intnotes   .= t8('Message')    . ": " . $::form->{message};
 510
 511   $self->order->update_attributes(intnotes => $intnotes);
 512
 513   $self->save_history('MAILED');
 514
 515   flash_later('info', t8('The email has been sent.'));
 516
 517   my @redirect_params = (
 518     action => 'edit',
 519     type   => $self->type,
 520     id     => $self->order->id,
 521   );
 522
 523   $self->redirect_to(@redirect_params);
 524 }
 525
 526 # open the periodic invoices config dialog
 527 #
 528 # If there are values in the form (i.e. dialog was opened before),
 529 # then use this values. Create new ones, else.
 530 sub action_show_periodic_invoices_config_dialog {
 531   my ($self) = @_;
 532
 533   my $config = make_periodic_invoices_config_from_yaml(delete $::form->{config});
 534   $config  ||= SL::DB::Manager::PeriodicInvoicesConfig->find_by(oe_id => $::form->{id}) if $::form->{id};
 535   $config  ||= SL::DB::PeriodicInvoicesConfig->new(periodicity             => 'm',
 536                                                    order_value_periodicity => 'p', # = same as periodicity
 537                                                    start_date_as_date      => $::form->{transdate_as_date} || $::form->current_date,
 538                                                    extend_automatically_by => 12,
 539                                                    active                  => 1,
 540                                                    email_subject           => GenericTranslations->get(
 541                                                                                 language_id      => $::form->{language_id},
 542                                                                                 translation_type =>"preset_text_periodic_invoices_email_subject"),
 543                                                    email_body              => GenericTranslations->get(
 544                                                                                 language_id      => $::form->{language_id},
 545                                                                                 translation_type =>"preset_text_periodic_invoices_email_body"),
 546   );
 547   $config->periodicity('m')             if none { $_ eq $config->periodicity             }       @SL::DB::PeriodicInvoicesConfig::PERIODICITIES;
 548   $config->order_value_periodicity('p') if none { $_ eq $config->order_value_periodicity } ('p', @SL::DB::PeriodicInvoicesConfig::ORDER_VALUE_PERIODICITIES);
 549
 550   $::form->get_lists(printers => "ALL_PRINTERS",
 551                      charts   => { key       => 'ALL_CHARTS',
 552                                    transdate => 'current_date' });
 553
 554   $::form->{AR} = [ grep { $_->{link} =~ m/(?:^|:)AR(?::|$)/ } @{ $::form->{ALL_CHARTS} } ];
 555
 556   if ($::form->{customer_id}) {
 557     $::form->{ALL_CONTACTS} = SL::DB::Manager::Contact->get_all_sorted(where => [ cp_cv_id => $::form->{customer_id} ]);
 558     my $customer_object = SL::DB::Manager::Customer->find_by(id => $::form->{customer_id});
 559     $::form->{postal_invoice}                  = $customer_object->postal_invoice;
 560     $::form->{email_recipient_invoice_address} = $::form->{postal_invoice} ? '' : $customer_object->invoice_mail;
 561     $config->send_email(0) if $::form->{postal_invoice};
 562   }
 563
 564   $self->render('oe/edit_periodic_invoices_config', { layout => 0 },
 565                 popup_dialog             => 1,
 566                 popup_js_close_function  => 'kivi.Order.close_periodic_invoices_config_dialog()',
 567                 popup_js_assign_function => 'kivi.Order.assign_periodic_invoices_config()',
 568                 config                   => $config,
 569                 %$::form);
 570 }
 571
 572 # assign the values of the periodic invoices config dialog
 573 # as yaml in the hidden tag and set the status.
 574 sub action_assign_periodic_invoices_config {
 575   my ($self) = @_;
 576
 577   $::form->isblank('start_date_as_date', $::locale->text('The start date is missing.'));
 578
 579   my $config = { active                     => $::form->{active}       ? 1 : 0,
 580                  terminated                 => $::form->{terminated}   ? 1 : 0,
 581                  direct_debit               => $::form->{direct_debit} ? 1 : 0,
 582                  periodicity                => (any { $_ eq $::form->{periodicity}             }       @SL::DB::PeriodicInvoicesConfig::PERIODICITIES)              ? $::form->{periodicity}             : 'm',
 583                  order_value_periodicity    => (any { $_ eq $::form->{order_value_periodicity} } ('p', @SL::DB::PeriodicInvoicesConfig::ORDER_VALUE_PERIODICITIES)) ? $::form->{order_value_periodicity} : 'p',
 584                  start_date_as_date         => $::form->{start_date_as_date},
 585                  end_date_as_date           => $::form->{end_date_as_date},
 586                  first_billing_date_as_date => $::form->{first_billing_date_as_date},
 587                  print                      => $::form->{print}      ? 1                         : 0,
 588                  printer_id                 => $::form->{print}      ? $::form->{printer_id} * 1 : undef,
 589                  copies                     => $::form->{copies} * 1 ? $::form->{copies}         : 1,
 590                  extend_automatically_by    => $::form->{extend_automatically_by}    * 1 || undef,
 591                  ar_chart_id                => $::form->{ar_chart_id} * 1,
 592                  send_email                 => $::form->{send_email} ? 1 : 0,
 593                  email_recipient_contact_id => $::form->{email_recipient_contact_id} * 1 || undef,
 594                  email_recipient_address    => $::form->{email_recipient_address},
 595                  email_sender               => $::form->{email_sender},
 596                  email_subject              => $::form->{email_subject},
 597                  email_body                 => $::form->{email_body},
 598                };
 599
 600   my $periodic_invoices_config = SL::YAML::Dump($config);
 601
 602   my $status = $self->get_periodic_invoices_status($config);
 603
 604   $self->js
 605     ->remove('#order_periodic_invoices_config')
 606     ->insertAfter(hidden_tag('order.periodic_invoices_config', $periodic_invoices_config), '#periodic_invoices_status')
 607     ->run('kivi.Order.close_periodic_invoices_config_dialog')
 608     ->html('#periodic_invoices_status', $status)
 609     ->flash('info', t8('The periodic invoices config has been assigned.'))
 610     ->render($self);
 611 }
 612
 613 sub action_get_has_active_periodic_invoices {
 614   my ($self) = @_;
 615
 616   my $config = make_periodic_invoices_config_from_yaml(delete $::form->{config});
 617   $config  ||= SL::DB::Manager::PeriodicInvoicesConfig->find_by(oe_id => $::form->{id}) if $::form->{id};
 618
 619   my $has_active_periodic_invoices =
 620        $self->type eq sales_order_type()
 621     && $config
 622     && $config->active
 623     && (!$config->end_date || ($config->end_date > DateTime->today_local))
 624     && $config->get_previous_billed_period_start_date;
 625
 626   $_[0]->render(\ !!$has_active_periodic_invoices, { type => 'text' });
 627 }
 628
 629 # save the order and redirect to the frontend subroutine for a new
 630 # delivery order
 631 sub action_save_and_delivery_order {
 632   my ($self) = @_;
 633
 634   $self->save_and_redirect_to(
 635     controller => 'oe.pl',
 636     action     => 'oe_delivery_order_from_order',
 637   );
 638 }
 639
 640 # save the order and redirect to the frontend subroutine for a new
 641 # invoice
 642 sub action_save_and_invoice {
 643   my ($self) = @_;
 644
 645   $self->save_and_redirect_to(
 646     controller => 'oe.pl',
 647     action     => 'oe_invoice_from_order',
 648   );
 649 }
 650
 651 # workflow from sales order to sales quotation
 652 sub action_sales_quotation {
 653   $_[0]->workflow_sales_or_request_for_quotation();
 654 }
 655
 656 # workflow from sales order to sales quotation
 657 sub action_request_for_quotation {
 658   $_[0]->workflow_sales_or_request_for_quotation();
 659 }
 660
 661 # workflow from sales quotation to sales order
 662 sub action_sales_order {
 663   $_[0]->workflow_sales_or_purchase_order();
 664 }
 665
 666 # workflow from rfq to purchase order
 667 sub action_purchase_order {
 668   $_[0]->workflow_sales_or_purchase_order();
 669 }
 670
 671 # workflow from purchase order to ap transaction
 672 sub action_save_and_ap_transaction {
 673   my ($self) = @_;
 674
 675   $self->save_and_redirect_to(
 676     controller => 'ap.pl',
 677     action     => 'add_from_purchase_order',
 678   );
 679 }
 680
 681 # set form elements in respect to a changed customer or vendor
 682 #
 683 # This action is called on an change of the customer/vendor picker.
 684 sub action_customer_vendor_changed {
 685   my ($self) = @_;
 686
 687   setup_order_from_cv($self->order);
 688   $self->recalc();
 689
 690   my $cv_method = $self->cv;
 691
 692   if ($self->order->$cv_method->contacts && scalar @{ $self->order->$cv_method->contacts } > 0) {
 693     $self->js->show('#cp_row');
 694   } else {
 695     $self->js->hide('#cp_row');
 696   }
 697
 698   if ($self->order->$cv_method->shipto && scalar @{ $self->order->$cv_method->shipto } > 0) {
 699     $self->js->show('#shipto_selection');
 700   } else {
 701     $self->js->hide('#shipto_selection');
 702   }
 703
 704   if ($cv_method eq 'customer') {
 705     my $show_hide = scalar @{ $self->order->customer->additional_billing_addresses } > 0 ? 'show' : 'hide';
 706     $self->js->$show_hide('#billing_address_row');
 707   }
 708
 709   $self->js->val( '#order_salesman_id',      $self->order->salesman_id)        if $self->order->is_sales;
 710
 711   $self->js
 712     ->replaceWith('#order_cp_id',              $self->build_contact_select)
 713     ->replaceWith('#order_shipto_id',          $self->build_shipto_select)
 714     ->replaceWith('#shipto_inputs  ',          $self->build_shipto_inputs)
 715     ->replaceWith('#order_billing_address_id', $self->build_billing_address_select)
 716     ->replaceWith('#business_info_row',        $self->build_business_info_row)
 717     ->val(        '#order_taxzone_id',         $self->order->taxzone_id)
 718     ->val(        '#order_taxincluded',        $self->order->taxincluded)
 719     ->val(        '#order_currency_id',        $self->order->currency_id)
 720     ->val(        '#order_payment_id',         $self->order->payment_id)
 721     ->val(        '#order_delivery_term_id',   $self->order->delivery_term_id)
 722     ->val(        '#order_intnotes',           $self->order->intnotes)
 723     ->val(        '#order_language_id',        $self->order->$cv_method->language_id)
 724     ->focus(      '#order_' . $self->cv . '_id')
 725     ->run('kivi.Order.update_exchangerate');
 726
 727   $self->js_redisplay_amounts_and_taxes;
 728   $self->js_redisplay_cvpartnumbers;
 729   $self->js->render();
 730 }
 731
 732 # open the dialog for customer/vendor details
 733 sub action_show_customer_vendor_details_dialog {
 734   my ($self) = @_;
 735
 736   my $is_customer = 'customer' eq $::form->{vc};
 737   my $cv;
 738   if ($is_customer) {
 739     $cv = SL::DB::Customer->new(id => $::form->{vc_id})->load;
 740   } else {
 741     $cv = SL::DB::Vendor->new(id => $::form->{vc_id})->load;
 742   }
 743
 744   my %details = map { $_ => $cv->$_ } @{$cv->meta->columns};
 745   $details{discount_as_percent} = $cv->discount_as_percent;
 746   $details{creditlimt}          = $cv->creditlimit_as_number;
 747   $details{business}            = $cv->business->description      if $cv->business;
 748   $details{language}            = $cv->language_obj->description  if $cv->language_obj;
 749   $details{delivery_terms}      = $cv->delivery_term->description if $cv->delivery_term;
 750   $details{payment_terms}       = $cv->payment->description       if $cv->payment;
 751   $details{pricegroup}          = $cv->pricegroup->pricegroup     if $is_customer && $cv->pricegroup;
 752
 753   foreach my $entry (@{ $cv->additional_billing_addresses }) {
 754     push @{ $details{ADDITIONAL_BILLING_ADDRESSES} },   { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 755   }
 756   foreach my $entry (@{ $cv->shipto }) {
 757     push @{ $details{SHIPTO} },   { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 758   }
 759   foreach my $entry (@{ $cv->contacts }) {
 760     push @{ $details{CONTACTS} }, { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 761   }
 762
 763   $_[0]->render('common/show_vc_details', { layout => 0 },
 764                 is_customer => $is_customer,
 765                 %details);
 766
 767 }
 768
 769 # called if a unit in an existing item row is changed
 770 sub action_unit_changed {
 771   my ($self) = @_;
 772
 773   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 774   my $item = $self->order->items_sorted->[$idx];
 775
 776   my $old_unit_obj = SL::DB::Unit->new(name => $::form->{old_unit})->load;
 777   $item->sellprice($item->unit_obj->convert_to($item->sellprice, $old_unit_obj));
 778
 779   $self->recalc();
 780
 781   $self->js
 782     ->run('kivi.Order.update_sellprice', $::form->{item_id}, $item->sellprice_as_number);
 783   $self->js_redisplay_line_values;
 784   $self->js_redisplay_amounts_and_taxes;
 785   $self->js->render();
 786 }
 787
 788 # add an item row for a new item entered in the input row
 789 sub action_add_item {
 790   my ($self) = @_;
 791
 792   delete $::form->{add_item}->{create_part_type};
 793
 794   my $form_attr = $::form->{add_item};
 795
 796   return unless $form_attr->{parts_id};
 797
 798   my $item = new_item($self->order, $form_attr);
 799
 800   $self->order->add_items($item);
 801
 802   $self->recalc();
 803
 804   $self->get_item_cvpartnumber($item);
 805
 806   my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 807   my $row_as_html = $self->p->render('order/tabs/_row',
 808                                      ITEM => $item,
 809                                      ID   => $item_id,
 810                                      SELF => $self,
 811   );
 812
 813   if ($::form->{insert_before_item_id}) {
 814     $self->js
 815       ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 816   } else {
 817     $self->js
 818       ->append('#row_table_id', $row_as_html);
 819   }
 820
 821   if ( $item->part->is_assortment ) {
 822     $form_attr->{qty_as_number} = 1 unless $form_attr->{qty_as_number};
 823     foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 824       my $attr = { parts_id => $assortment_item->parts_id,
 825                    qty      => $assortment_item->qty * $::form->parse_amount(\%::myconfig, $form_attr->{qty_as_number}), # TODO $form_attr->{unit}
 826                    unit     => $assortment_item->unit,
 827                    description => $assortment_item->part->description,
 828                  };
 829       my $item = new_item($self->order, $attr);
 830
 831       # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 832       $item->discount(1) unless $assortment_item->charge;
 833
 834       $self->order->add_items( $item );
 835       $self->recalc();
 836       $self->get_item_cvpartnumber($item);
 837       my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 838       my $row_as_html = $self->p->render('order/tabs/_row',
 839                                          ITEM => $item,
 840                                          ID   => $item_id,
 841                                          SELF => $self,
 842       );
 843       if ($::form->{insert_before_item_id}) {
 844         $self->js
 845           ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 846       } else {
 847         $self->js
 848           ->append('#row_table_id', $row_as_html);
 849       }
 850     };
 851   };
 852
 853   $self->js
 854     ->val('.add_item_input', '')
 855     ->run('kivi.Order.init_row_handlers')
 856     ->run('kivi.Order.renumber_positions')
 857     ->focus('#add_item_parts_id_name');
 858
 859   $self->js->run('kivi.Order.row_table_scroll_down') if !$::form->{insert_before_item_id};
 860
 861   $self->js_redisplay_amounts_and_taxes;
 862   $self->js->render();
 863 }
 864
 865 # add item rows for multiple items at once
 866 sub action_add_multi_items {
 867   my ($self) = @_;
 868
 869   my @form_attr = grep { $_->{qty_as_number} } @{ $::form->{add_items} };
 870   return $self->js->render() unless scalar @form_attr;
 871
 872   my @items;
 873   foreach my $attr (@form_attr) {
 874     my $item = new_item($self->order, $attr);
 875     push @items, $item;
 876     if ( $item->part->is_assortment ) {
 877       foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 878         my $attr = { parts_id => $assortment_item->parts_id,
 879                      qty      => $assortment_item->qty * $item->qty, # TODO $form_attr->{unit}
 880                      unit     => $assortment_item->unit,
 881                      description => $assortment_item->part->description,
 882                    };
 883         my $item = new_item($self->order, $attr);
 884
 885         # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 886         $item->discount(1) unless $assortment_item->charge;
 887         push @items, $item;
 888       }
 889     }
 890   }
 891   $self->order->add_items(@items);
 892
 893   $self->recalc();
 894
 895   foreach my $item (@items) {
 896     $self->get_item_cvpartnumber($item);
 897     my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 898     my $row_as_html = $self->p->render('order/tabs/_row',
 899                                        ITEM => $item,
 900                                        ID   => $item_id,
 901                                        SELF => $self,
 902     );
 903
 904     if ($::form->{insert_before_item_id}) {
 905       $self->js
 906         ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 907     } else {
 908       $self->js
 909         ->append('#row_table_id', $row_as_html);
 910     }
 911   }
 912
 913   $self->js
 914     ->run('kivi.Part.close_picker_dialogs')
 915     ->run('kivi.Order.init_row_handlers')
 916     ->run('kivi.Order.renumber_positions')
 917     ->focus('#add_item_parts_id_name');
 918
 919   $self->js->run('kivi.Order.row_table_scroll_down') if !$::form->{insert_before_item_id};
 920
 921   $self->js_redisplay_amounts_and_taxes;
 922   $self->js->render();
 923 }
 924
 925 # recalculate all linetotals, amounts and taxes and redisplay them
 926 sub action_recalc_amounts_and_taxes {
 927   my ($self) = @_;
 928
 929   $self->recalc();
 930
 931   $self->js_redisplay_line_values;
 932   $self->js_redisplay_amounts_and_taxes;
 933   $self->js->render();
 934 }
 935
 936 sub action_update_exchangerate {
 937   my ($self) = @_;
 938
 939   my $data = {
 940     is_standard   => $self->order->currency_id == $::instance_conf->get_currency_id,
 941     currency_name => $self->order->currency->name,
 942     exchangerate  => $self->order->daily_exchangerate_as_null_number,
 943   };
 944
 945   $self->render(\SL::JSON::to_json($data), { type => 'json', process => 0 });
 946 }
 947
 948 # redisplay item rows if they are sorted by an attribute
 949 sub action_reorder_items {
 950   my ($self) = @_;
 951
 952   my %sort_keys = (
 953     partnumber   => sub { $_[0]->part->partnumber },
 954     description  => sub { $_[0]->description },
 955     qty          => sub { $_[0]->qty },
 956     sellprice    => sub { $_[0]->sellprice },
 957     discount     => sub { $_[0]->discount },
 958     cvpartnumber => sub { $_[0]->{cvpartnumber} },
 959   );
 960
 961   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
 962
 963   my $method = $sort_keys{$::form->{order_by}};
 964   my @to_sort = map { { old_pos => $_->position, order_by => $method->($_) } } @{ $self->order->items_sorted };
 965   if ($::form->{sort_dir}) {
 966     if ( $::form->{order_by} =~ m/qty|sellprice|discount/ ){
 967       @to_sort = sort { $a->{order_by} <=> $b->{order_by} } @to_sort;
 968     } else {
 969       @to_sort = sort { $a->{order_by} cmp $b->{order_by} } @to_sort;
 970     }
 971   } else {
 972     if ( $::form->{order_by} =~ m/qty|sellprice|discount/ ){
 973       @to_sort = sort { $b->{order_by} <=> $a->{order_by} } @to_sort;
 974     } else {
 975       @to_sort = sort { $b->{order_by} cmp $a->{order_by} } @to_sort;
 976     }
 977   }
 978   $self->js
 979     ->run('kivi.Order.redisplay_items', \@to_sort)
 980     ->render;
 981 }
 982
 983 # show the popup to choose a price/discount source
 984 sub action_price_popup {
 985   my ($self) = @_;
 986
 987   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 988   my $item = $self->order->items_sorted->[$idx];
 989
 990   $self->render_price_dialog($item);
 991 }
 992
 993 # save the order in a session variable and redirect to the part controller
 994 sub action_create_part {
 995   my ($self) = @_;
 996
 997   my $previousform = $::auth->save_form_in_session(non_scalars => 1);
 998
 999   my $callback     = $self->url_for(
1000     action       => 'return_from_create_part',
1001     type         => $self->type, # type is needed for check_auth on return
1002     previousform => $previousform,
1003   );
1004
1005   flash_later('info', t8('You are adding a new part while you are editing another document. You will be redirected to your document when saving the new part or aborting this form.'));
1006
1007   my @redirect_params = (
1008     controller => 'Part',
1009     action     => 'add',
1010     part_type  => $::form->{add_item}->{create_part_type},
1011     callback   => $callback,
1012     show_abort => 1,
1013   );
1014
1015   $self->redirect_to(@redirect_params);
1016 }
1017
1018 sub action_return_from_create_part {
1019   my ($self) = @_;
1020
1021   $self->{created_part} = SL::DB::Part->new(id => delete $::form->{new_parts_id})->load if $::form->{new_parts_id};
1022
1023   $::auth->restore_form_from_session(delete $::form->{previousform});
1024
1025   # set item ids to new fake id, to identify them as new items
1026   foreach my $item (@{$self->order->items_sorted}) {
1027     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1028   }
1029
1030   $self->recalc();
1031   $self->get_unalterable_data();
1032   $self->pre_render();
1033
1034   # trigger rendering values for second row/longdescription as hidden,
1035   # because they are loaded only on demand. So we need to keep the values
1036   # from the source.
1037   $_->{render_second_row}      = 1 for @{ $self->order->items_sorted };
1038   $_->{render_longdescription} = 1 for @{ $self->order->items_sorted };
1039
1040   $self->render(
1041     'order/form',
1042     title => $self->get_title_for('edit'),
1043     %{$self->{template_args}}
1044   );
1045
1046 }
1047
1048 # load the second row for one or more items
1049 #
1050 # This action gets the html code for all items second rows by rendering a template for
1051 # the second row and sets the html code via client js.
1052 sub action_load_second_rows {
1053   my ($self) = @_;
1054
1055   $self->recalc() if $self->order->is_sales; # for margin calculation
1056
1057   foreach my $item_id (@{ $::form->{item_ids} }) {
1058     my $idx  = first_index { $_ eq $item_id } @{ $::form->{orderitem_ids} };
1059     my $item = $self->order->items_sorted->[$idx];
1060
1061     $self->js_load_second_row($item, $item_id, 0);
1062   }
1063
1064   $self->js->run('kivi.Order.init_row_handlers') if $self->order->is_sales; # for lastcosts change-callback
1065
1066   $self->js->render();
1067 }
1068
1069 # update description, notes and sellprice from master data
1070 sub action_update_row_from_master_data {
1071   my ($self) = @_;
1072
1073   foreach my $item_id (@{ $::form->{item_ids} }) {
1074     my $idx   = first_index { $_ eq $item_id } @{ $::form->{orderitem_ids} };
1075     my $item  = $self->order->items_sorted->[$idx];
1076     my $texts = get_part_texts($item->part, $self->order->language_id);
1077
1078     $item->description($texts->{description});
1079     $item->longdescription($texts->{longdescription});
1080
1081     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
1082
1083     my $price_src;
1084     if ($item->part->is_assortment) {
1085     # add assortment items with price 0, as the components carry the price
1086       $price_src = $price_source->price_from_source("");
1087       $price_src->price(0);
1088     } else {
1089       $price_src = $price_source->best_price
1090                  ? $price_source->best_price
1091                  : $price_source->price_from_source("");
1092       $price_src->price($::form->round_amount($price_src->price / $self->order->exchangerate, 5)) if $self->order->exchangerate;
1093       $price_src->price(0) if !$price_source->best_price;
1094     }
1095
1096
1097     $item->sellprice($price_src->price);
1098     $item->active_price_source($price_src);
1099
1100     $self->js
1101       ->run('kivi.Order.update_sellprice', $item_id, $item->sellprice_as_number)
1102       ->html('.row_entry:has(#item_' . $item_id . ') [name = "partnumber"] a', $item->part->partnumber)
1103       ->val ('.row_entry:has(#item_' . $item_id . ') [name = "order.orderitems[].description"]', $item->description)
1104       ->val ('.row_entry:has(#item_' . $item_id . ') [name = "order.orderitems[].longdescription"]', $item->longdescription);
1105
1106     if ($self->search_cvpartnumber) {
1107       $self->get_item_cvpartnumber($item);
1108       $self->js->html('.row_entry:has(#item_' . $item_id . ') [name = "cvpartnumber"]', $item->{cvpartnumber});
1109     }
1110   }
1111
1112   $self->recalc();
1113   $self->js_redisplay_line_values;
1114   $self->js_redisplay_amounts_and_taxes;
1115
1116   $self->js->render();
1117 }
1118
1119 sub js_load_second_row {
1120   my ($self, $item, $item_id, $do_parse) = @_;
1121
1122   if ($do_parse) {
1123     # Parse values from form (they are formated while rendering (template)).
1124     # Workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
1125     # This parsing is not necessary at all, if we assure that the second row/cvars are only loaded once.
1126     foreach my $var (@{ $item->cvars_by_config }) {
1127       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
1128     }
1129     $item->parse_custom_variable_values;
1130   }
1131
1132   my $row_as_html = $self->p->render('order/tabs/_second_row', ITEM => $item, TYPE => $self->type);
1133
1134   $self->js
1135     ->html('#second_row_' . $item_id, $row_as_html)
1136     ->data('#second_row_' . $item_id, 'loaded', 1);
1137 }
1138
1139 sub js_redisplay_line_values {
1140   my ($self) = @_;
1141
1142   my $is_sales = $self->order->is_sales;
1143
1144   # sales orders with margins
1145   my @data;
1146   if ($is_sales) {
1147     @data = map {
1148       [
1149        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
1150        $::form->format_amount(\%::myconfig, $_->{marge_total},   2, 0),
1151        $::form->format_amount(\%::myconfig, $_->{marge_percent}, 2, 0),
1152       ]} @{ $self->order->items_sorted };
1153   } else {
1154     @data = map {
1155       [
1156        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
1157       ]} @{ $self->order->items_sorted };
1158   }
1159
1160   $self->js
1161     ->run('kivi.Order.redisplay_line_values', $is_sales, \@data);
1162 }
1163
1164 sub js_redisplay_amounts_and_taxes {
1165   my ($self) = @_;
1166
1167   if (scalar @{ $self->{taxes} }) {
1168     $self->js->show('#taxincluded_row_id');
1169   } else {
1170     $self->js->hide('#taxincluded_row_id');
1171   }
1172
1173   if ($self->order->taxincluded) {
1174     $self->js->hide('#subtotal_row_id');
1175   } else {
1176     $self->js->show('#subtotal_row_id');
1177   }
1178
1179   if ($self->order->is_sales) {
1180     my $is_neg = $self->order->marge_total < 0;
1181     $self->js
1182       ->html('#marge_total_id',   $::form->format_amount(\%::myconfig, $self->order->marge_total,   2))
1183       ->html('#marge_percent_id', $::form->format_amount(\%::myconfig, $self->order->marge_percent, 2))
1184       ->action_if( $is_neg, 'addClass',    '#marge_total_id',        'plus0')
1185       ->action_if( $is_neg, 'addClass',    '#marge_percent_id',      'plus0')
1186       ->action_if( $is_neg, 'addClass',    '#marge_percent_sign_id', 'plus0')
1187       ->action_if(!$is_neg, 'removeClass', '#marge_total_id',        'plus0')
1188       ->action_if(!$is_neg, 'removeClass', '#marge_percent_id',      'plus0')
1189       ->action_if(!$is_neg, 'removeClass', '#marge_percent_sign_id', 'plus0');
1190   }
1191
1192   $self->js
1193     ->html('#netamount_id', $::form->format_amount(\%::myconfig, $self->order->netamount, -2))
1194     ->html('#amount_id',    $::form->format_amount(\%::myconfig, $self->order->amount,    -2))
1195     ->remove('.tax_row')
1196     ->insertBefore($self->build_tax_rows, '#amount_row_id');
1197 }
1198
1199 sub js_redisplay_cvpartnumbers {
1200   my ($self) = @_;
1201
1202   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
1203
1204   my @data = map {[$_->{cvpartnumber}]} @{ $self->order->items_sorted };
1205
1206   $self->js
1207     ->run('kivi.Order.redisplay_cvpartnumbers', \@data);
1208 }
1209
1210 sub js_reset_order_and_item_ids_after_save {
1211   my ($self) = @_;
1212
1213   $self->js
1214     ->val('#id', $self->order->id)
1215     ->val('#converted_from_oe_id', '')
1216     ->val('#order_' . $self->nr_key(), $self->order->number);
1217
1218   my $idx = 0;
1219   foreach my $form_item_id (@{ $::form->{orderitem_ids} }) {
1220     next if !$self->order->items_sorted->[$idx]->id;
1221     next if $form_item_id !~ m{^new};
1222     $self->js
1223       ->val ('[name="orderitem_ids[+]"][value="' . $form_item_id . '"]', $self->order->items_sorted->[$idx]->id)
1224       ->val ('#item_' . $form_item_id, $self->order->items_sorted->[$idx]->id)
1225       ->attr('#item_' . $form_item_id, "id", 'item_' . $self->order->items_sorted->[$idx]->id);
1226   } continue {
1227     $idx++;
1228   }
1229   $self->js->val('[name="converted_from_orderitems_ids[+]"]', '');
1230 }
1231
1232 #
1233 # helpers
1234 #
1235
1236 sub init_valid_types {
1237   [ sales_order_type(), purchase_order_type(), sales_quotation_type(), request_quotation_type() ];
1238 }
1239
1240 sub init_type {
1241   my ($self) = @_;
1242
1243   if (none { $::form->{type} eq $_ } @{$self->valid_types}) {
1244     die "Not a valid type for order";
1245   }
1246
1247   $self->type($::form->{type});
1248 }
1249
1250 sub init_cv {
1251   my ($self) = @_;
1252
1253   my $cv = (any { $self->type eq $_ } (sales_order_type(),    sales_quotation_type()))   ? 'customer'
1254          : (any { $self->type eq $_ } (purchase_order_type(), request_quotation_type())) ? 'vendor'
1255          : die "Not a valid type for order";
1256
1257   return $cv;
1258 }
1259
1260 sub init_search_cvpartnumber {
1261   my ($self) = @_;
1262
1263   my $user_prefs = SL::Helper::UserPreferences::PartPickerSearch->new();
1264   my $search_cvpartnumber;
1265   $search_cvpartnumber = !!$user_prefs->get_sales_search_customer_partnumber() if $self->cv eq 'customer';
1266   $search_cvpartnumber = !!$user_prefs->get_purchase_search_makemodel()        if $self->cv eq 'vendor';
1267
1268   return $search_cvpartnumber;
1269 }
1270
1271 sub init_show_update_button {
1272   my ($self) = @_;
1273
1274   !!SL::Helper::UserPreferences::UpdatePositions->new()->get_show_update_button();
1275 }
1276
1277 sub init_p {
1278   SL::Presenter->get;
1279 }
1280
1281 sub init_order {
1282   $_[0]->make_order;
1283 }
1284
1285 sub init_all_price_factors {
1286   SL::DB::Manager::PriceFactor->get_all;
1287 }
1288
1289 sub init_part_picker_classification_ids {
1290   my ($self)    = @_;
1291   my $attribute = 'used_for_' . ($self->type =~ m{sales} ? 'sale' : 'purchase');
1292
1293   return [ map { $_->id } @{ SL::DB::Manager::PartClassification->get_all(where => [ $attribute => 1 ]) } ];
1294 }
1295
1296 sub check_auth {
1297   my ($self) = @_;
1298
1299   my $right_for = { map { $_ => $_.'_edit' } @{$self->valid_types} };
1300
1301   my $right   = $right_for->{ $self->type };
1302   $right    ||= 'DOES_NOT_EXIST';
1303
1304   $::auth->assert($right);
1305 }
1306
1307 # build the selection box for contacts
1308 #
1309 # Needed, if customer/vendor changed.
1310 sub build_contact_select {
1311   my ($self) = @_;
1312
1313   select_tag('order.cp_id', [ $self->order->{$self->cv}->contacts ],
1314     value_key  => 'cp_id',
1315     title_key  => 'full_name_dep',
1316     default    => $self->order->cp_id,
1317     with_empty => 1,
1318     style      => 'width: 300px',
1319   );
1320 }
1321
1322 # build the selection box for the additional billing address
1323 #
1324 # Needed, if customer/vendor changed.
1325 sub build_billing_address_select {
1326   my ($self) = @_;
1327
1328   select_tag('order.billing_address_id',
1329              [ {displayable_id => '', id => ''}, $self->order->{$self->cv}->additional_billing_addresses ],
1330              value_key  => 'id',
1331              title_key  => 'displayable_id',
1332              default    => $self->order->billing_address_id,
1333              with_empty => 0,
1334              style      => 'width: 300px',
1335   );
1336 }
1337
1338 # build the selection box for shiptos
1339 #
1340 # Needed, if customer/vendor changed.
1341 sub build_shipto_select {
1342   my ($self) = @_;
1343
1344   select_tag('order.shipto_id',
1345              [ {displayable_id => t8("No/individual shipping address"), shipto_id => ''}, $self->order->{$self->cv}->shipto ],
1346              value_key  => 'shipto_id',
1347              title_key  => 'displayable_id',
1348              default    => $self->order->shipto_id,
1349              with_empty => 0,
1350              style      => 'width: 300px',
1351   );
1352 }
1353
1354 # build the inputs for the cusom shipto dialog
1355 #
1356 # Needed, if customer/vendor changed.
1357 sub build_shipto_inputs {
1358   my ($self) = @_;
1359
1360   my $content = $self->p->render('common/_ship_to_dialog',
1361                                  vc_obj      => $self->order->customervendor,
1362                                  cs_obj      => $self->order->custom_shipto,
1363                                  cvars       => $self->order->custom_shipto->cvars_by_config,
1364                                  id_selector => '#order_shipto_id');
1365
1366   div_tag($content, id => 'shipto_inputs');
1367 }
1368
1369 # render the info line for business
1370 #
1371 # Needed, if customer/vendor changed.
1372 sub build_business_info_row
1373 {
1374   $_[0]->p->render('order/tabs/_business_info_row', SELF => $_[0]);
1375 }
1376
1377 # build the rows for displaying taxes
1378 #
1379 # Called if amounts where recalculated and redisplayed.
1380 sub build_tax_rows {
1381   my ($self) = @_;
1382
1383   my $rows_as_html;
1384   foreach my $tax (sort { $a->{tax}->rate cmp $b->{tax}->rate } @{ $self->{taxes} }) {
1385     $rows_as_html .= $self->p->render('order/tabs/_tax_row', TAX => $tax, TAXINCLUDED => $self->order->taxincluded);
1386   }
1387   return $rows_as_html;
1388 }
1389
1390
1391 sub render_price_dialog {
1392   my ($self, $record_item) = @_;
1393
1394   my $price_source = SL::PriceSource->new(record_item => $record_item, record => $self->order);
1395
1396   $self->js
1397     ->run(
1398       'kivi.io.price_chooser_dialog',
1399       t8('Available Prices'),
1400       $self->render('order/tabs/_price_sources_dialog', { output => 0 }, price_source => $price_source)
1401     )
1402     ->reinit_widgets;
1403
1404 #   if (@errors) {
1405 #     $self->js->text('#dialog_flash_error_content', join ' ', @errors);
1406 #     $self->js->show('#dialog_flash_error');
1407 #   }
1408
1409   $self->js->render;
1410 }
1411
1412 sub load_order {
1413   my ($self) = @_;
1414
1415   return if !$::form->{id};
1416
1417   $self->order(SL::DB::Order->new(id => $::form->{id})->load);
1418
1419   # Add an empty custom shipto to the order, so that the dialog can render the cvar inputs.
1420   # You need a custom shipto object to call cvars_by_config to get the cvars.
1421   $self->order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => [])) if !$self->order->custom_shipto;
1422
1423   return $self->order;
1424 }
1425
1426 # load or create a new order object
1427 #
1428 # And assign changes from the form to this object.
1429 # If the order is loaded from db, check if items are deleted in the form,
1430 # remove them form the object and collect them for removing from db on saving.
1431 # Then create/update items from form (via make_item) and add them.
1432 sub make_order {
1433   my ($self) = @_;
1434
1435   # add_items adds items to an order with no items for saving, but they cannot
1436   # be retrieved via items until the order is saved. Adding empty items to new
1437   # order here solves this problem.
1438   my $order;
1439   $order   = SL::DB::Order->new(id => $::form->{id})->load(with => [ 'orderitems', 'orderitems.part' ]) if $::form->{id};
1440   $order ||= SL::DB::Order->new(orderitems  => [],
1441                                 quotation   => (any { $self->type eq $_ } (sales_quotation_type(), request_quotation_type())),
1442                                 currency_id => $::instance_conf->get_currency_id(),);
1443
1444   my $cv_id_method = $self->cv . '_id';
1445   if (!$::form->{id} && $::form->{$cv_id_method}) {
1446     $order->$cv_id_method($::form->{$cv_id_method});
1447     setup_order_from_cv($order);
1448   }
1449
1450   my $form_orderitems                  = delete $::form->{order}->{orderitems};
1451   my $form_periodic_invoices_config    = delete $::form->{order}->{periodic_invoices_config};
1452
1453   $order->assign_attributes(%{$::form->{order}});
1454
1455   $self->setup_custom_shipto_from_form($order, $::form);
1456
1457   if (my $periodic_invoices_config_attrs = $form_periodic_invoices_config ? SL::YAML::Load($form_periodic_invoices_config) : undef) {
1458     my $periodic_invoices_config = $order->periodic_invoices_config || $order->periodic_invoices_config(SL::DB::PeriodicInvoicesConfig->new);
1459     $periodic_invoices_config->assign_attributes(%$periodic_invoices_config_attrs);
1460   }
1461
1462   # remove deleted items
1463   $self->item_ids_to_delete([]);
1464   foreach my $idx (reverse 0..$#{$order->orderitems}) {
1465     my $item = $order->orderitems->[$idx];
1466     if (none { $item->id == $_->{id} } @{$form_orderitems}) {
1467       splice @{$order->orderitems}, $idx, 1;
1468       push @{$self->item_ids_to_delete}, $item->id;
1469     }
1470   }
1471
1472   my @items;
1473   my $pos = 1;
1474   foreach my $form_attr (@{$form_orderitems}) {
1475     my $item = make_item($order, $form_attr);
1476     $item->position($pos);
1477     push @items, $item;
1478     $pos++;
1479   }
1480   $order->add_items(grep {!$_->id} @items);
1481
1482   return $order;
1483 }
1484
1485 # create or update items from form
1486 #
1487 # Make item objects from form values. For items already existing read from db.
1488 # Create a new item else. And assign attributes.
1489 sub make_item {
1490   my ($record, $attr) = @_;
1491
1492   my $item;
1493   $item = first { $_->id == $attr->{id} } @{$record->items} if $attr->{id};
1494
1495   my $is_new = !$item;
1496
1497   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1498   # they cannot be retrieved via custom_variables until the order/orderitem is
1499   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1500   $item ||= SL::DB::OrderItem->new(custom_variables => []);
1501
1502   $item->assign_attributes(%$attr);
1503
1504   if ($is_new) {
1505     my $texts = get_part_texts($item->part, $record->language_id);
1506     $item->longdescription($texts->{longdescription})              if !defined $attr->{longdescription};
1507     $item->project_id($record->globalproject_id)                   if !defined $attr->{project_id};
1508     $item->lastcost($record->is_sales ? $item->part->lastcost : 0) if !defined $attr->{lastcost_as_number};
1509   }
1510
1511   return $item;
1512 }
1513
1514 # create a new item
1515 #
1516 # This is used to add one item
1517 sub new_item {
1518   my ($record, $attr) = @_;
1519
1520   my $item = SL::DB::OrderItem->new;
1521
1522   # Remove attributes where the user left or set the inputs empty.
1523   # So these attributes will be undefined and we can distinguish them
1524   # from zero later on.
1525   for (qw(qty_as_number sellprice_as_number discount_as_percent)) {
1526     delete $attr->{$_} if $attr->{$_} eq '';
1527   }
1528
1529   $item->assign_attributes(%$attr);
1530
1531   my $part         = SL::DB::Part->new(id => $attr->{parts_id})->load;
1532   my $price_source = SL::PriceSource->new(record_item => $item, record => $record);
1533
1534   $item->unit($part->unit) if !$item->unit;
1535
1536   my $price_src;
1537   if ( $part->is_assortment ) {
1538     # add assortment items with price 0, as the components carry the price
1539     $price_src = $price_source->price_from_source("");
1540     $price_src->price(0);
1541   } elsif (defined $item->sellprice) {
1542     $price_src = $price_source->price_from_source("");
1543     $price_src->price($item->sellprice);
1544   } else {
1545     $price_src = $price_source->best_price
1546                ? $price_source->best_price
1547                : $price_source->price_from_source("");
1548     $price_src->price($::form->round_amount($price_src->price / $record->exchangerate, 5)) if $record->exchangerate;
1549     $price_src->price(0) if !$price_source->best_price;
1550   }
1551
1552   my $discount_src;
1553   if (defined $item->discount) {
1554     $discount_src = $price_source->discount_from_source("");
1555     $discount_src->discount($item->discount);
1556   } else {
1557     $discount_src = $price_source->best_discount
1558                   ? $price_source->best_discount
1559                   : $price_source->discount_from_source("");
1560     $discount_src->discount(0) if !$price_source->best_discount;
1561   }
1562
1563   my %new_attr;
1564   $new_attr{part}                   = $part;
1565   $new_attr{description}            = $part->description     if ! $item->description;
1566   $new_attr{qty}                    = 1.0                    if ! $item->qty;
1567   $new_attr{price_factor_id}        = $part->price_factor_id if ! $item->price_factor_id;
1568   $new_attr{sellprice}              = $price_src->price;
1569   $new_attr{discount}               = $discount_src->discount;
1570   $new_attr{active_price_source}    = $price_src;
1571   $new_attr{active_discount_source} = $discount_src;
1572   $new_attr{longdescription}        = $part->notes           if ! defined $attr->{longdescription};
1573   $new_attr{project_id}             = $record->globalproject_id;
1574   $new_attr{lastcost}               = $record->is_sales ? $part->lastcost : 0;
1575
1576   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1577   # they cannot be retrieved via custom_variables until the order/orderitem is
1578   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1579   $new_attr{custom_variables} = [];
1580
1581   my $texts = get_part_texts($part, $record->language_id, description => $new_attr{description}, longdescription => $new_attr{longdescription});
1582
1583   $item->assign_attributes(%new_attr, %{ $texts });
1584
1585   return $item;
1586 }
1587
1588 sub setup_order_from_cv {
1589   my ($order) = @_;
1590
1591   $order->$_($order->customervendor->$_) for (qw(taxzone_id payment_id delivery_term_id currency_id));
1592
1593   $order->intnotes($order->customervendor->notes);
1594
1595   return if !$order->is_sales;
1596
1597   $order->salesman_id($order->customer->salesman_id || SL::DB::Manager::Employee->current->id);
1598   $order->taxincluded(defined($order->customer->taxincluded_checked)
1599                       ? $order->customer->taxincluded_checked
1600                       : $::myconfig{taxincluded_checked});
1601
1602   my $address = $order->customer->default_billing_address;;
1603   $order->billing_address_id($address ? $address->id : undef);
1604 }
1605
1606 # setup custom shipto from form
1607 #
1608 # The dialog returns form variables starting with 'shipto' and cvars starting
1609 # with 'shiptocvar_'.
1610 # Mark it to be deleted if a shipto from master data is selected
1611 # (i.e. order has a shipto).
1612 # Else, update or create a new custom shipto. If the fields are empty, it
1613 # will not be saved on save.
1614 sub setup_custom_shipto_from_form {
1615   my ($self, $order, $form) = @_;
1616
1617   if ($order->shipto) {
1618     $self->is_custom_shipto_to_delete(1);
1619   } else {
1620     my $custom_shipto = $order->custom_shipto || $order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => []));
1621
1622     my $shipto_cvars  = {map { my ($key) = m{^shiptocvar_(.+)}; $key => delete $form->{$_}} grep { m{^shiptocvar_} } keys %$form};
1623     my $shipto_attrs  = {map {                                  $_   => delete $form->{$_}} grep { m{^shipto}      } keys %$form};
1624
1625     $custom_shipto->assign_attributes(%$shipto_attrs);
1626     $custom_shipto->cvar_by_name($_)->value($shipto_cvars->{$_}) for keys %$shipto_cvars;
1627   }
1628 }
1629
1630 # recalculate prices and taxes
1631 #
1632 # Using the PriceTaxCalculator. Store linetotals in the item objects.
1633 sub recalc {
1634   my ($self) = @_;
1635
1636   my %pat = $self->order->calculate_prices_and_taxes();
1637
1638   $self->{taxes} = [];
1639   foreach my $tax_id (keys %{ $pat{taxes_by_tax_id} }) {
1640     my $netamount = sum0 map { $pat{amounts}->{$_}->{amount} } grep { $pat{amounts}->{$_}->{tax_id} == $tax_id } keys %{ $pat{amounts} };
1641
1642     push(@{ $self->{taxes} }, { amount    => $pat{taxes_by_tax_id}->{$tax_id},
1643                                 netamount => $netamount,
1644                                 tax       => SL::DB::Tax->new(id => $tax_id)->load });
1645   }
1646   pairwise { $a->{linetotal} = $b->{linetotal} } @{$self->order->items_sorted}, @{$pat{items}};
1647 }
1648
1649 # get data for saving, printing, ..., that is not changed in the form
1650 #
1651 # Only cvars for now.
1652 sub get_unalterable_data {
1653   my ($self) = @_;
1654
1655   foreach my $item (@{ $self->order->items }) {
1656     # autovivify all cvars that are not in the form (cvars_by_config can do it).
1657     # workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
1658     foreach my $var (@{ $item->cvars_by_config }) {
1659       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
1660     }
1661     $item->parse_custom_variable_values;
1662   }
1663 }
1664
1665 # delete the order
1666 #
1667 # And remove related files in the spool directory
1668 sub delete {
1669   my ($self) = @_;
1670
1671   my $errors = [];
1672   my $db     = $self->order->db;
1673
1674   $db->with_transaction(
1675     sub {
1676       my @spoolfiles = grep { $_ } map { $_->spoolfile } @{ SL::DB::Manager::Status->get_all(where => [ trans_id => $self->order->id ]) };
1677       $self->order->delete;
1678       my $spool = $::lx_office_conf{paths}->{spool};
1679       unlink map { "$spool/$_" } @spoolfiles if $spool;
1680
1681       $self->save_history('DELETED');
1682
1683       1;
1684   }) || push(@{$errors}, $db->error);
1685
1686   return $errors;
1687 }
1688
1689 # save the order
1690 #
1691 # And delete items that are deleted in the form.
1692 sub save {
1693   my ($self) = @_;
1694
1695   my $errors = [];
1696   my $db     = $self->order->db;
1697
1698   $db->with_transaction(sub {
1699     # delete custom shipto if it is to be deleted or if it is empty
1700     if ($self->order->custom_shipto && ($self->is_custom_shipto_to_delete || $self->order->custom_shipto->is_empty)) {
1701       $self->order->custom_shipto->delete if $self->order->custom_shipto->shipto_id;
1702       $self->order->custom_shipto(undef);
1703     }
1704
1705     SL::DB::OrderItem->new(id => $_)->delete for @{$self->item_ids_to_delete || []};
1706     $self->order->save(cascade => 1);
1707
1708     # link records
1709     if ($::form->{converted_from_oe_id}) {
1710       my @converted_from_oe_ids = split ' ', $::form->{converted_from_oe_id};
1711
1712       foreach my $converted_from_oe_id (@converted_from_oe_ids) {
1713         my $src = SL::DB::Order->new(id => $converted_from_oe_id)->load;
1714         $src->update_attributes(closed => 1) if $src->type =~ /_quotation$/;
1715         $src->link_to_record($self->order);
1716       }
1717       if (scalar @{ $::form->{converted_from_orderitems_ids} || [] }) {
1718         my $idx = 0;
1719         foreach (@{ $self->order->items_sorted }) {
1720           my $from_id = $::form->{converted_from_orderitems_ids}->[$idx];
1721           next if !$from_id;
1722           SL::DB::RecordLink->new(from_table => 'orderitems',
1723                                   from_id    => $from_id,
1724                                   to_table   => 'orderitems',
1725                                   to_id      => $_->id
1726           )->save;
1727           $idx++;
1728         }
1729       }
1730
1731       $self->link_requirement_specs_linking_to_created_from_objects(@converted_from_oe_ids);
1732     }
1733
1734     $self->set_project_in_linked_requirement_specs if $self->order->globalproject_id;
1735
1736     $self->save_history('SAVED');
1737
1738     1;
1739   }) || push(@{$errors}, $db->error);
1740
1741   return $errors;
1742 }
1743
1744 sub workflow_sales_or_request_for_quotation {
1745   my ($self) = @_;
1746
1747   # always save
1748   my $errors = $self->save();
1749
1750   if (scalar @{ $errors }) {
1751     $self->js->flash('error', $_) for @{ $errors };
1752     return $self->js->render();
1753   }
1754
1755   my $destination_type = $::form->{type} eq sales_order_type() ? sales_quotation_type() : request_quotation_type();
1756
1757   $self->order(SL::DB::Order->new_from($self->order, destination_type => $destination_type));
1758   $self->{converted_from_oe_id} = delete $::form->{id};
1759
1760   # set item ids to new fake id, to identify them as new items
1761   foreach my $item (@{$self->order->items_sorted}) {
1762     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1763   }
1764
1765   # change form type
1766   $::form->{type} = $destination_type;
1767   $self->type($self->init_type);
1768   $self->cv  ($self->init_cv);
1769   $self->check_auth;
1770
1771   $self->recalc();
1772   $self->get_unalterable_data();
1773   $self->pre_render();
1774
1775   # trigger rendering values for second row as hidden, because they
1776   # are loaded only on demand. So we need to keep the values from the
1777   # source.
1778   $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
1779
1780   $self->render(
1781     'order/form',
1782     title => $self->get_title_for('edit'),
1783     %{$self->{template_args}}
1784   );
1785 }
1786
1787 sub workflow_sales_or_purchase_order {
1788   my ($self) = @_;
1789
1790   # always save
1791   my $errors = $self->save();
1792
1793   if (scalar @{ $errors }) {
1794     $self->js->flash('error', $_) foreach @{ $errors };
1795     return $self->js->render();
1796   }
1797
1798   my $destination_type = $::form->{type} eq sales_quotation_type()   ? sales_order_type()
1799                        : $::form->{type} eq request_quotation_type() ? purchase_order_type()
1800                        : $::form->{type} eq purchase_order_type()    ? sales_order_type()
1801                        : $::form->{type} eq sales_order_type()       ? purchase_order_type()
1802                        : '';
1803
1804   # check for direct delivery
1805   # copy shipto in custom shipto (custom shipto will be copied by new_from() in case)
1806   my $custom_shipto;
1807   if (   $::form->{type} eq sales_order_type() && $destination_type eq purchase_order_type()
1808       && $::form->{use_shipto} && $self->order->shipto) {
1809     $custom_shipto = $self->order->shipto->clone('SL::DB::Order');
1810   }
1811
1812   $self->order(SL::DB::Order->new_from($self->order, destination_type => $destination_type));
1813   $self->{converted_from_oe_id} = delete $::form->{id};
1814
1815   # set item ids to new fake id, to identify them as new items
1816   foreach my $item (@{$self->order->items_sorted}) {
1817     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1818   }
1819
1820   if ($::form->{type} eq sales_order_type() && $destination_type eq purchase_order_type()) {
1821     if ($::form->{use_shipto}) {
1822       $self->order->custom_shipto($custom_shipto) if $custom_shipto;
1823     } else {
1824       # remove any custom shipto if not wanted
1825       $self->order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => []));
1826     }
1827   }
1828
1829   # change form type
1830   $::form->{type} = $destination_type;
1831   $self->type($self->init_type);
1832   $self->cv  ($self->init_cv);
1833   $self->check_auth;
1834
1835   $self->recalc();
1836   $self->get_unalterable_data();
1837   $self->pre_render();
1838
1839   # trigger rendering values for second row as hidden, because they
1840   # are loaded only on demand. So we need to keep the values from the
1841   # source.
1842   $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
1843
1844   $self->render(
1845     'order/form',
1846     title => $self->get_title_for('edit'),
1847     %{$self->{template_args}}
1848   );
1849 }
1850
1851
1852 sub pre_render {
1853   my ($self) = @_;
1854
1855   $self->{all_taxzones}               = SL::DB::Manager::TaxZone->get_all_sorted();
1856   $self->{all_currencies}             = SL::DB::Manager::Currency->get_all_sorted();
1857   $self->{all_departments}            = SL::DB::Manager::Department->get_all_sorted();
1858   $self->{all_languages}              = SL::DB::Manager::Language->get_all_sorted();
1859   $self->{all_employees}              = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->employee_id,
1860                                                                                               deleted => 0 ] ],
1861                                                                            sort_by => 'name');
1862   $self->{all_salesmen}               = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->salesman_id,
1863                                                                                               deleted => 0 ] ],
1864                                                                            sort_by => 'name');
1865   $self->{all_payment_terms}          = SL::DB::Manager::PaymentTerm->get_all_sorted(where => [ or => [ id => $self->order->payment_id,
1866                                                                                                         obsolete => 0 ] ]);
1867   $self->{all_delivery_terms}         = SL::DB::Manager::DeliveryTerm->get_all_sorted();
1868   $self->{current_employee_id}        = SL::DB::Manager::Employee->current->id;
1869   $self->{periodic_invoices_status}   = $self->get_periodic_invoices_status($self->order->periodic_invoices_config);
1870   $self->{order_probabilities}        = [ map { { title => ($_ * 10) . '%', id => $_ * 10 } } (0..10) ];
1871   $self->{positions_scrollbar_height} = SL::Helper::UserPreferences::PositionsScrollbar->new()->get_height();
1872
1873   my $print_form = Form->new('');
1874   $print_form->{type}        = $self->type;
1875   $print_form->{printers}    = SL::DB::Manager::Printer->get_all_sorted;
1876   $self->{print_options}     = SL::Helper::PrintOptions->get_print_options(
1877     form => $print_form,
1878     options => {dialog_name_prefix => 'print_options.',
1879                 show_headers       => 1,
1880                 no_queue           => 1,
1881                 no_postscript      => 1,
1882                 no_opendocument    => 0,
1883                 no_html            => 1},
1884   );
1885
1886   foreach my $item (@{$self->order->orderitems}) {
1887     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
1888     $item->active_price_source(   $price_source->price_from_source(   $item->active_price_source   ));
1889     $item->active_discount_source($price_source->discount_from_source($item->active_discount_source));
1890   }
1891
1892   if (any { $self->type eq $_ } (sales_order_type(), purchase_order_type())) {
1893     # Calculate shipped qtys here to prevent calling calculate for every item via the items method.
1894     # Do not use write_to_objects to prevent order->delivered to be set, because this should be
1895     # the value from db, which can be set manually or is set when linked delivery orders are saved.
1896     SL::Helper::ShippedQty->new->calculate($self->order)->write_to(\@{$self->order->items});
1897   }
1898
1899   if ($self->order->number && $::instance_conf->get_webdav) {
1900     my $webdav = SL::Webdav->new(
1901       type     => $self->type,
1902       number   => $self->order->number,
1903     );
1904     my @all_objects = $webdav->get_all_objects;
1905     @{ $self->{template_args}->{WEBDAV} } = map { { name => $_->filename,
1906                                                     type => t8('File'),
1907                                                     link => File::Spec->catfile($_->full_filedescriptor),
1908                                                 } } @all_objects;
1909   }
1910
1911   if (   (any { $self->type eq $_ } (sales_quotation_type(), sales_order_type()))
1912       && $::instance_conf->get_transport_cost_reminder_article_number_id ) {
1913     $self->{template_args}->{transport_cost_reminder_article} = SL::DB::Part->new(id => $::instance_conf->get_transport_cost_reminder_article_number_id)->load;
1914   }
1915
1916   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
1917
1918   $::request->{layout}->use_javascript("${_}.js") for qw(kivi.SalesPurchase kivi.Order kivi.File ckeditor/ckeditor ckeditor/adapters/jquery
1919                                                          edit_periodic_invoices_config calculate_qty kivi.Validator follow_up show_history);
1920   $self->setup_edit_action_bar;
1921 }
1922
1923 sub setup_edit_action_bar {
1924   my ($self, %params) = @_;
1925
1926   my $deletion_allowed = (any { $self->type eq $_ } (sales_quotation_type(), request_quotation_type()))
1927                       || (($self->type eq sales_order_type())    && $::instance_conf->get_sales_order_show_delete)
1928                       || (($self->type eq purchase_order_type()) && $::instance_conf->get_purchase_order_show_delete);
1929
1930   my @req_trans_cost_art = qw(kivi.Order.check_transport_cost_article_presence) x!!$::instance_conf->get_transport_cost_reminder_article_number_id;
1931   my @req_cusordnumber   = qw(kivi.Order.check_cusordnumber_presence)           x($self->type eq sales_order_type() && $::instance_conf->get_order_warn_no_cusordnumber);
1932
1933   for my $bar ($::request->layout->get('actionbar')) {
1934     $bar->add(
1935       combobox => [
1936         action => [
1937           t8('Save'),
1938           call      => [ 'kivi.Order.save', 'save', $::instance_conf->get_order_warn_duplicate_parts,
1939                                                     $::instance_conf->get_order_warn_no_deliverydate,
1940           ],
1941           checks    => [ 'kivi.Order.check_save_active_periodic_invoices', ['kivi.validate_form','#order_form'],
1942                          @req_trans_cost_art, @req_cusordnumber,
1943           ],
1944         ],
1945         action => [
1946           t8('Save as new'),
1947           call      => [ 'kivi.Order.save', 'save_as_new', $::instance_conf->get_order_warn_duplicate_parts ],
1948           checks    => [ 'kivi.Order.check_save_active_periodic_invoices',
1949                          @req_trans_cost_art, @req_cusordnumber,
1950           ],
1951           disabled  => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1952         ],
1953       ], # end of combobox "Save"
1954
1955       combobox => [
1956         action => [
1957           t8('Workflow'),
1958         ],
1959         action => [
1960           t8('Save and Quotation'),
1961           submit   => [ '#order_form', { action => "Order/sales_quotation" } ],
1962           checks   => [ @req_trans_cost_art, @req_cusordnumber ],
1963           only_if  => (any { $self->type eq $_ } (sales_order_type())),
1964         ],
1965         action => [
1966           t8('Save and RFQ'),
1967           submit   => [ '#order_form', { action => "Order/request_for_quotation" } ],
1968           only_if  => (any { $self->type eq $_ } (purchase_order_type())),
1969         ],
1970         action => [
1971           t8('Save and Sales Order'),
1972           submit   => [ '#order_form', { action => "Order/sales_order" } ],
1973           checks   => [ @req_trans_cost_art ],
1974           only_if  => (any { $self->type eq $_ } (sales_quotation_type(), purchase_order_type())),
1975         ],
1976         action => [
1977           t8('Save and Purchase Order'),
1978           call      => [ 'kivi.Order.purchase_order_check_for_direct_delivery' ],
1979           checks    => [ @req_trans_cost_art, @req_cusordnumber ],
1980           only_if   => (any { $self->type eq $_ } (sales_order_type(), request_quotation_type())),
1981         ],
1982         action => [
1983           t8('Save and Delivery Order'),
1984           call      => [ 'kivi.Order.save', 'save_and_delivery_order', $::instance_conf->get_order_warn_duplicate_parts,
1985                                                                        $::instance_conf->get_order_warn_no_deliverydate,
1986                                                                                                                         ],
1987           checks    => [ 'kivi.Order.check_save_active_periodic_invoices',
1988                          @req_trans_cost_art, @req_cusordnumber,
1989           ],
1990           only_if   => (any { $self->type eq $_ } (sales_order_type(), purchase_order_type()))
1991         ],
1992         action => [
1993           t8('Save and Invoice'),
1994           call      => [ 'kivi.Order.save', 'save_and_invoice', $::instance_conf->get_order_warn_duplicate_parts ],
1995           checks    => [ 'kivi.Order.check_save_active_periodic_invoices',
1996                          @req_trans_cost_art, @req_cusordnumber,
1997           ],
1998         ],
1999         action => [
2000           t8('Save and AP Transaction'),
2001           call      => [ 'kivi.Order.save', 'save_and_ap_transaction', $::instance_conf->get_order_warn_duplicate_parts ],
2002           only_if   => (any { $self->type eq $_ } (purchase_order_type()))
2003         ],
2004
2005       ], # end of combobox "Workflow"
2006
2007       combobox => [
2008         action => [
2009           t8('Export'),
2010         ],
2011         action => [
2012           t8('Save and preview PDF'),
2013           call   => [ 'kivi.Order.save', 'preview_pdf', $::instance_conf->get_order_warn_duplicate_parts,
2014                                                         $::instance_conf->get_order_warn_no_deliverydate,
2015                     ],
2016           checks => [ @req_trans_cost_art, @req_cusordnumber ],
2017         ],
2018         action => [
2019           t8('Save and print'),
2020           call   => [ 'kivi.Order.show_print_options', $::instance_conf->get_order_warn_duplicate_parts,
2021                                                        $::instance_conf->get_order_warn_no_deliverydate,
2022                     ],
2023           checks => [ @req_trans_cost_art, @req_cusordnumber ],
2024         ],
2025         action => [
2026           t8('Save and E-mail'),
2027           id   => 'save_and_email_action',
2028           call => [ 'kivi.Order.save', 'save_and_show_email_dialog', $::instance_conf->get_order_warn_duplicate_parts,
2029                                                                      $::instance_conf->get_order_warn_no_deliverydate,
2030                   ],
2031           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
2032         ],
2033         action => [
2034           t8('Download attachments of all parts'),
2035           call     => [ 'kivi.File.downloadOrderitemsFiles', $::form->{type}, $::form->{id} ],
2036           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
2037           only_if  => $::instance_conf->get_doc_storage,
2038         ],
2039       ], # end of combobox "Export"
2040
2041       action => [
2042         t8('Delete'),
2043         call     => [ 'kivi.Order.delete_order' ],
2044         confirm  => $::locale->text('Do you really want to delete this object?'),
2045         disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
2046         only_if  => $deletion_allowed,
2047       ],
2048
2049       combobox => [
2050         action => [
2051           t8('more')
2052         ],
2053         action => [
2054           t8('History'),
2055           call     => [ 'set_history_window', $self->order->id, 'id' ],
2056           disabled => !$self->order->id ? t8('This record has not been saved yet.') : undef,
2057         ],
2058         action => [
2059           t8('Follow-Up'),
2060           call     => [ 'kivi.Order.follow_up_window' ],
2061           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
2062           only_if  => $::auth->assert('productivity', 1),
2063         ],
2064       ], # end of combobox "more"
2065     );
2066   }
2067 }
2068
2069 sub generate_pdf {
2070   my ($self, $pdf_ref, $params) = @_;
2071
2072   my $order  = $self->order;
2073   my @errors = ();
2074
2075   my $print_form = Form->new('');
2076   $print_form->{type}        = $order->type;
2077   $print_form->{formname}    = $params->{formname} || $order->type;
2078   $print_form->{format}      = $params->{format}   || 'pdf';
2079   $print_form->{media}       = $params->{media}    || 'file';
2080   $print_form->{groupitems}  = $params->{groupitems};
2081   $print_form->{printer_id}  = $params->{printer_id};
2082   $print_form->{media}       = 'file'                             if $print_form->{media} eq 'screen';
2083
2084   $order->language($params->{language});
2085   $order->flatten_to_form($print_form, format_amounts => 1);
2086
2087   my $template_ext;
2088   my $template_type;
2089   if ($print_form->{format} =~ /(opendocument|oasis)/i) {
2090     $template_ext  = 'odt';
2091     $template_type = 'OpenDocument';
2092   }
2093
2094   # search for the template
2095   my ($template_file, @template_files) = SL::Helper::CreatePDF->find_template(
2096     name        => $print_form->{formname},
2097     extension   => $template_ext,
2098     email       => $print_form->{media} eq 'email',
2099     language    => $params->{language},
2100     printer_id  => $print_form->{printer_id},
2101   );
2102
2103   if (!defined $template_file) {
2104     push @errors, $::locale->text('Cannot find matching template for this print request. Please contact your template maintainer. I tried these: #1.', join ', ', map { "'$_'"} @template_files);
2105   }
2106
2107   return @errors if scalar @errors;
2108
2109   $print_form->throw_on_error(sub {
2110     eval {
2111       $print_form->prepare_for_printing;
2112
2113       $$pdf_ref = SL::Helper::CreatePDF->create_pdf(
2114         format        => $print_form->{format},
2115         template_type => $template_type,
2116         template      => $template_file,
2117         variables     => $print_form,
2118         variable_content_types => {
2119           longdescription => 'html',
2120           partnotes       => 'html',
2121           notes           => 'html',
2122         },
2123       );
2124       1;
2125     } || push @errors, ref($EVAL_ERROR) eq 'SL::X::FormError' ? $EVAL_ERROR->error : $EVAL_ERROR;
2126   });
2127
2128   return @errors;
2129 }
2130
2131 sub get_files_for_email_dialog {
2132   my ($self) = @_;
2133
2134   my %files = map { ($_ => []) } qw(versions files vc_files part_files);
2135
2136   return %files if !$::instance_conf->get_doc_storage;
2137
2138   if ($self->order->id) {
2139     $files{versions} = [ SL::File->get_all_versions(object_id => $self->order->id,              object_type => $self->order->type, file_type => 'document') ];
2140     $files{files}    = [ SL::File->get_all(         object_id => $self->order->id,              object_type => $self->order->type, file_type => 'attachment') ];
2141     $files{vc_files} = [ SL::File->get_all(         object_id => $self->order->{$self->cv}->id, object_type => $self->cv,          file_type => 'attachment') ];
2142     $files{project_files} = [ SL::File->get_all(    object_id => $self->order->globalproject_id, object_type => 'project',         file_type => 'attachment') ];
2143   }
2144
2145   my @parts =
2146     uniq_by { $_->{id} }
2147     map {
2148       +{ id         => $_->part->id,
2149          partnumber => $_->part->partnumber }
2150     } @{$self->order->items_sorted};
2151
2152   foreach my $part (@parts) {
2153     my @pfiles = SL::File->get_all(object_id => $part->{id}, object_type => 'part');
2154     push @{ $files{part_files} }, map { +{ %{ $_ }, partnumber => $part->{partnumber} } } @pfiles;
2155   }
2156
2157   foreach my $key (keys %files) {
2158     $files{$key} = [ sort_by { lc $_->{db_file}->{file_name} } @{ $files{$key} } ];
2159   }
2160
2161   return %files;
2162 }
2163
2164 sub make_periodic_invoices_config_from_yaml {
2165   my ($yaml_config) = @_;
2166
2167   return if !$yaml_config;
2168   my $attr = SL::YAML::Load($yaml_config);
2169   return if 'HASH' ne ref $attr;
2170   return SL::DB::PeriodicInvoicesConfig->new(%$attr);
2171 }
2172
2173
2174 sub get_periodic_invoices_status {
2175   my ($self, $config) = @_;
2176
2177   return                      if $self->type ne sales_order_type();
2178   return t8('not configured') if !$config;
2179
2180   my $active = ('HASH' eq ref $config)                           ? $config->{active}
2181              : ('SL::DB::PeriodicInvoicesConfig' eq ref $config) ? $config->active
2182              :                                                     die "Cannot get status of periodic invoices config";
2183
2184   return $active ? t8('active') : t8('inactive');
2185 }
2186
2187 sub get_title_for {
2188   my ($self, $action) = @_;
2189
2190   return '' if none { lc($action)} qw(add edit);
2191
2192   # for locales:
2193   # $::locale->text("Add Sales Order");
2194   # $::locale->text("Add Purchase Order");
2195   # $::locale->text("Add Quotation");
2196   # $::locale->text("Add Request for Quotation");
2197   # $::locale->text("Edit Sales Order");
2198   # $::locale->text("Edit Purchase Order");
2199   # $::locale->text("Edit Quotation");
2200   # $::locale->text("Edit Request for Quotation");
2201
2202   $action = ucfirst(lc($action));
2203   return $self->type eq sales_order_type()       ? $::locale->text("$action Sales Order")
2204        : $self->type eq purchase_order_type()    ? $::locale->text("$action Purchase Order")
2205        : $self->type eq sales_quotation_type()   ? $::locale->text("$action Quotation")
2206        : $self->type eq request_quotation_type() ? $::locale->text("$action Request for Quotation")
2207        : '';
2208 }
2209
2210 sub get_item_cvpartnumber {
2211   my ($self, $item) = @_;
2212
2213   return if !$self->search_cvpartnumber;
2214   return if !$self->order->customervendor;
2215
2216   if ($self->cv eq 'vendor') {
2217     my @mms = grep { $_->make eq $self->order->customervendor->id } @{$item->part->makemodels};
2218     $item->{cvpartnumber} = $mms[0]->model if scalar @mms;
2219   } elsif ($self->cv eq 'customer') {
2220     my @cps = grep { $_->customer_id eq $self->order->customervendor->id } @{$item->part->customerprices};
2221     $item->{cvpartnumber} = $cps[0]->customer_partnumber if scalar @cps;
2222   }
2223 }
2224
2225 sub get_part_texts {
2226   my ($part_or_id, $language_or_id, %defaults) = @_;
2227
2228   my $part        = ref($part_or_id)     ? $part_or_id         : SL::DB::Part->load_cached($part_or_id);
2229   my $language_id = ref($language_or_id) ? $language_or_id->id : $language_or_id;
2230   my $texts       = {
2231     description     => $defaults{description}     // $part->description,
2232     longdescription => $defaults{longdescription} // $part->notes,
2233   };
2234
2235   return $texts unless $language_id;
2236
2237   my $translation = SL::DB::Manager::Translation->get_first(
2238     where => [
2239       parts_id    => $part->id,
2240       language_id => $language_id,
2241     ]);
2242
2243   $texts->{description}     = $translation->translation     if $translation && $translation->translation;
2244   $texts->{longdescription} = $translation->longdescription if $translation && $translation->longdescription;
2245
2246   return $texts;
2247 }
2248
2249 sub sales_order_type {
2250   'sales_order';
2251 }
2252
2253 sub purchase_order_type {
2254   'purchase_order';
2255 }
2256
2257 sub sales_quotation_type {
2258   'sales_quotation';
2259 }
2260
2261 sub request_quotation_type {
2262   'request_quotation';
2263 }
2264
2265 sub nr_key {
2266   return $_[0]->type eq sales_order_type()       ? 'ordnumber'
2267        : $_[0]->type eq purchase_order_type()    ? 'ordnumber'
2268        : $_[0]->type eq sales_quotation_type()   ? 'quonumber'
2269        : $_[0]->type eq request_quotation_type() ? 'quonumber'
2270        : '';
2271 }
2272
2273 sub save_and_redirect_to {
2274   my ($self, %params) = @_;
2275
2276   my $errors = $self->save();
2277
2278   if (scalar @{ $errors }) {
2279     $self->js->flash('error', $_) foreach @{ $errors };
2280     return $self->js->render();
2281   }
2282
2283   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
2284            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
2285            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
2286            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
2287            : '';
2288   flash_later('info', $text);
2289
2290   $self->redirect_to(%params, id => $self->order->id);
2291 }
2292
2293 sub save_history {
2294   my ($self, $addition) = @_;
2295
2296   my $number_type = $self->order->type =~ m{order} ? 'ordnumber' : 'quonumber';
2297   my $snumbers    = $number_type . '_' . $self->order->$number_type;
2298
2299   SL::DB::History->new(
2300     trans_id    => $self->order->id,
2301     employee_id => SL::DB::Manager::Employee->current->id,
2302     what_done   => $self->order->type,
2303     snumbers    => $snumbers,
2304     addition    => $addition,
2305   )->save;
2306 }
2307
2308 sub store_pdf_to_webdav_and_filemanagement {
2309   my ($self, $content, $filename) = @_;
2310
2311   my $order = $self->order;
2312   my @errors;
2313
2314   # copy file to webdav folder
2315   if ($order->number && $::instance_conf->get_webdav_documents) {
2316     my $webdav = SL::Webdav->new(
2317       type     => $order->type,
2318       number   => $order->number,
2319     );
2320     my $webdav_file = SL::Webdav::File->new(
2321       webdav   => $webdav,
2322       filename => $filename,
2323     );
2324     eval {
2325       $webdav_file->store(data => \$content);
2326       1;
2327     } or do {
2328       push @errors, t8('Storing PDF to webdav folder failed: #1', $@);
2329     };
2330   }
2331   if ($order->id && $::instance_conf->get_doc_storage) {
2332     eval {
2333       SL::File->save(object_id     => $order->id,
2334                      object_type   => $order->type,
2335                      mime_type     => 'application/pdf',
2336                      source        => 'created',
2337                      file_type     => 'document',
2338                      file_name     => $filename,
2339                      file_contents => $content);
2340       1;
2341     } or do {
2342       push @errors, t8('Storing PDF in storage backend failed: #1', $@);
2343     };
2344   }
2345
2346   return @errors;
2347 }
2348
2349 sub link_requirement_specs_linking_to_created_from_objects {
2350   my ($self, @converted_from_oe_ids) = @_;
2351
2352   return unless @converted_from_oe_ids;
2353
2354   my $rs_orders = SL::DB::Manager::RequirementSpecOrder->get_all(where => [ order_id => \@converted_from_oe_ids ]);
2355   foreach my $rs_order (@{ $rs_orders }) {
2356     SL::DB::RequirementSpecOrder->new(
2357       order_id            => $self->order->id,
2358       requirement_spec_id => $rs_order->requirement_spec_id,
2359       version_id          => $rs_order->version_id,
2360     )->save;
2361   }
2362 }
2363
2364 sub set_project_in_linked_requirement_specs {
2365   my ($self) = @_;
2366
2367   my $rs_orders = SL::DB::Manager::RequirementSpecOrder->get_all(where => [ order_id => $self->order->id ]);
2368   foreach my $rs_order (@{ $rs_orders }) {
2369     next if $rs_order->requirement_spec->project_id == $self->order->globalproject_id;
2370
2371     $rs_order->requirement_spec->update_attributes(project_id => $self->order->globalproject_id);
2372   }
2373 }
2374
2375 1;
2376
2377 __END__
2378
2379 =encoding utf-8
2380
2381 =head1 NAME
2382
2383 SL::Controller::Order - controller for orders
2384
2385 =head1 SYNOPSIS
2386
2387 This is a new form to enter orders, completely rewritten with the use
2388 of controller and java script techniques.
2389
2390 The aim is to provide the user a better experience and a faster workflow. Also
2391 the code should be more readable, more reliable and better to maintain.
2392
2393 =head2 Key Features
2394
2395 =over 4
2396
2397 =item *
2398
2399 One input row, so that input happens every time at the same place.
2400
2401 =item *
2402
2403 Use of pickers where possible.
2404
2405 =item *
2406
2407 Possibility to enter more than one item at once.
2408
2409 =item *
2410
2411 Item list in a scrollable area, so that the workflow buttons stay at
2412 the bottom.
2413
2414 =item *
2415
2416 Reordering item rows with drag and drop is possible. Sorting item rows is
2417 possible (by partnumber, description, qty, sellprice and discount for now).
2418
2419 =item *
2420
2421 No C<update> is necessary. All entries and calculations are managed
2422 with ajax-calls and the page only reloads on C<save>.
2423
2424 =item *
2425
2426 User can see changes immediately, because of the use of java script
2427 and ajax.
2428
2429 =back
2430
2431 =head1 CODE
2432
2433 =head2 Layout
2434
2435 =over 4
2436
2437 =item * C<SL/Controller/Order.pm>
2438
2439 the controller
2440
2441 =item * C<template/webpages/order/form.html>
2442
2443 main form
2444
2445 =item * C<template/webpages/order/tabs/basic_data.html>
2446
2447 Main tab for basic_data.
2448
2449 This is the only tab here for now. "linked records" and "webdav" tabs are
2450 reused from generic code.
2451
2452 =over 4
2453
2454 =item * C<template/webpages/order/tabs/_business_info_row.html>
2455
2456 For displaying information on business type
2457
2458 =item * C<template/webpages/order/tabs/_item_input.html>
2459
2460 The input line for items
2461
2462 =item * C<template/webpages/order/tabs/_row.html>
2463
2464 One row for already entered items
2465
2466 =item * C<template/webpages/order/tabs/_tax_row.html>
2467
2468 Displaying tax information
2469
2470 =item * C<template/webpages/order/tabs/_price_sources_dialog.html>
2471
2472 Dialog for selecting price and discount sources
2473
2474 =back
2475
2476 =item * C<js/kivi.Order.js>
2477
2478 java script functions
2479
2480 =back
2481
2482 =head1 TODO
2483
2484 =over 4
2485
2486 =item * testing
2487
2488 =item * price sources: little symbols showing better price / better discount
2489
2490 =item * select units in input row?
2491
2492 =item * check for direct delivery (workflow sales order -> purchase order)
2493
2494 =item * access rights
2495
2496 =item * display weights
2497
2498 =item * mtime check
2499
2500 =item * optional client/user behaviour
2501
2502 (transactions has to be set - department has to be set -
2503  force project if enabled in client config)
2504
2505 =back
2506
2507 =head1 KNOWN BUGS AND CAVEATS
2508
2509 =over 4
2510
2511 =item *
2512
2513 Customer discount is not displayed as a valid discount in price source popup
2514 (this might be a bug in price sources)
2515
2516 (I cannot reproduce this (Bernd))
2517
2518 =item *
2519
2520 No indication that <shift>-up/down expands/collapses second row.
2521
2522 =item *
2523
2524 Inline creation of parts is not currently supported
2525
2526 =item *
2527
2528 Table header is not sticky in the scrolling area.
2529
2530 =item *
2531
2532 Sorting does not include C<position>, neither does reordering.
2533
2534 This behavior was implemented intentionally. But we can discuss, which behavior
2535 should be implemented.
2536
2537 =back
2538
2539 =head1 To discuss / Nice to have
2540
2541 =over 4
2542
2543 =item *
2544
2545 How to expand/collapse second row. Now it can be done clicking the icon or
2546 <shift>-up/down.
2547
2548 =item *
2549
2550 Possibility to select PriceSources in input row?
2551
2552 =item *
2553
2554 This controller uses a (changed) copy of the template for the PriceSource
2555 dialog. Maybe there could be used one code source.
2556
2557 =item *
2558
2559 Rounding-differences between this controller (PriceTaxCalculator) and the old
2560 form. This is not only a problem here, but also in all parts using the PTC.
2561 There exists a ticket and a patch. This patch should be testet.
2562
2563 =item *
2564
2565 An indicator, if the actual inputs are saved (like in an
2566 editor or on text processing application).
2567
2568 =item *
2569
2570 A warning when leaving the page without saveing unchanged inputs.
2571
2572
2573 =back
2574
2575 =head1 AUTHOR
2576
2577 Bernd Bleßmann E<lt>bernd@kivitendo-premium.deE<gt>
2578
2579 =cut