SL/Controller/Order.pm

   1 package SL::Controller::Order;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use SL::Helper::Flash;
   7 use SL::ClientJS;
   8 use SL::Presenter;
   9
  10 use SL::DB::Order;
  11 use SL::DB::Customer;
  12 use SL::DB::Vendor;
  13 use SL::DB::TaxZone;
  14 use SL::DB::Employee;
  15 use SL::DB::Project;
  16 use SL::DB::Default;
  17 use SL::DB::Unit;
  18
  19 use SL::Helper::DateTime;
  20
  21 use List::Util qw(max first);
  22 use List::MoreUtils qw(none pairwise);
  23
  24 use Rose::Object::MakeMethods::Generic
  25 (
  26  'scalar --get_set_init' => [ qw(order valid_types type cv js p) ],
  27 );
  28
  29
  30 # safety
  31 __PACKAGE__->run_before('_check_auth');
  32
  33 __PACKAGE__->run_before('_recalc',
  34                         only => [ qw(edit update save) ]);
  35
  36
  37 #
  38 # actions
  39 #
  40
  41 sub action_add {
  42   my ($self) = @_;
  43
  44   $self->order->transdate(DateTime->now_local());
  45
  46   $self->_pre_render();
  47   $self->render(
  48     'order/form',
  49     title => $self->type eq _sales_order_type()    ? $::locale->text('Add Sales Order')
  50            : $self->type eq _purchase_order_type() ? $::locale->text('Add Purchase Order')
  51            : '',
  52     %{$self->{template_args}}
  53   );
  54 }
  55
  56 sub action_edit {
  57   my ($self) = @_;
  58
  59   $self->_pre_render();
  60   $self->render(
  61     'order/form',
  62     title => $self->type eq _sales_order_type()    ? $::locale->text('Edit Sales Order')
  63            : $self->type eq _purchase_order_type() ? $::locale->text('Edit Purchase Order')
  64            : '',
  65     %{$self->{template_args}}
  66   );
  67 }
  68
  69 sub action_update {
  70   my ($self) = @_;
  71
  72   $self->_pre_render();
  73   $self->render(
  74     'order/form',
  75     title => $self->type eq _sales_order_type()    ? $::locale->text('Edit Sales Order')
  76            : $self->type eq _purchase_order_type() ? $::locale->text('Edit Purchase Order')
  77            : '',
  78     %{$self->{template_args}}
  79   );
  80 }
  81
  82 sub action_save {
  83   my ($self) = @_;
  84
  85   my $errors = $self->_save();
  86
  87   if (scalar @{ $errors }) {
  88     $self->js->flash('error', $_) foreach @{ $errors };
  89     return $self->js->render($self);
  90   }
  91
  92   flash_later('info', 'The order has been saved');
  93   my @redirect_params = (
  94     action => 'edit',
  95     type   => $self->type,
  96     id     => $self->order->id,
  97   );
  98
  99   $self->redirect_to(@redirect_params);
 100 }
 101
 102 sub action_customer_vendor_changed {
 103   my ($self) = @_;
 104
 105   if ($self->cv eq 'customer') {
 106     $self->order->customer(SL::DB::Manager::Customer->find_by_or_create(id => $::form->{cv_id}));
 107
 108   } elsif ($self->cv eq 'vendor') {
 109     $self->order->vendor(SL::DB::Manager::Vendor->find_by_or_create(id => $::form->{cv_id}));
 110   }
 111
 112   if ($self->order->{$self->cv}->contacts && scalar @{ $self->order->{$self->cv}->contacts } > 0) {
 113     $self->js->show('#cp_row');
 114   } else {
 115     $self->js->hide('#cp_row');
 116   }
 117
 118   if ($self->order->{$self->cv}->shipto && scalar @{ $self->order->{$self->cv}->shipto } > 0) {
 119     $self->js->show('#shipto_row');
 120   } else {
 121     $self->js->hide('#shipto_row');
 122   }
 123
 124   $self->js
 125     ->replaceWith('#order_cp_id',     $self->build_contact_select)
 126     ->replaceWith('#order_shipto_id', $self->build_shipto_select)
 127     ->val('#order_taxzone_id', $self->order->{$self->cv}->taxzone_id)
 128     ->focus('#order_' . $self->cv . ' _id')
 129     ->render($self);
 130 }
 131
 132 sub action_add_item {
 133   my ($self) = @_;
 134
 135   my $form_attr = $::form->{add_item};
 136
 137   return unless $form_attr->{parts_id};
 138
 139   my $item      = SL::DB::OrderItem->new;
 140   $item->assign_attributes(%$form_attr);
 141
 142   my $part        = SL::DB::Part->new(id => $form_attr->{parts_id})->load;
 143   my $cv_discount = $self->order->customer? $self->order->customer->discount : 0.0;
 144
 145   my %new_attr;
 146   $new_attr{id}          = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 147   $new_attr{part}        = $part;
 148   $new_attr{description} = $part->description if ! $item->{description};
 149   $new_attr{qty}         = 1.0                if ! $item->{qty};
 150   $new_attr{unit}        = $part->unit;
 151   $new_attr{sellprice}   = $part->sellprice   if ! $item->{sellprice};
 152   $new_attr{discount}    = $cv_discount       if ! $item->{discount};
 153   $item->assign_attributes(%new_attr);
 154
 155   $self->order->add_items($item);
 156
 157   $self->_recalc();
 158
 159   my $row_as_html = $self->p->render('order/tabs/_row', ITEM => $item);
 160
 161   $self->js
 162     ->append('#row_table_id tbody', $row_as_html)
 163     ->val('#add_item_parts_id', '')
 164     ->val('#add_item_parts_id_name', '')
 165     ->val('#add_item_description', '')
 166     ->val('#add_item_qty_as_number', '')
 167     ->val('#add_item_sellprice_as_number', '')
 168     ->val('#add_item_discount_as_percent', '')
 169     ->run('row_table_scroll_down')
 170     ->focus('#add_item_parts_id_name');
 171
 172   $self->_js_redisplay_amounts_and_taxes;
 173   $self->js->render($self);
 174 }
 175
 176 sub action_recalc_amounts_and_taxes {
 177   my ($self) = @_;
 178
 179   $self->_recalc();
 180
 181   $self->_js_redisplay_amounts_and_taxes;
 182   $self->js->render($self);
 183 }
 184
 185 sub _js_redisplay_amounts_and_taxes {
 186   my ($self) = @_;
 187
 188   $self->js
 189     ->html('#netamount_id', $::form->format_amount(\%::myconfig, $self->order->netamount, -2))
 190     ->html('#amount_id',    $::form->format_amount(\%::myconfig, $self->order->amount,    -2))
 191     ->remove('.tax_row')
 192     ->insertBefore($self->build_tax_rows, '#amount_row_id');
 193 }
 194
 195 #
 196 # helpers
 197 #
 198
 199 sub init_valid_types {
 200   [ _sales_order_type(), _purchase_order_type() ];
 201 }
 202
 203 sub init_type {
 204   my ($self) = @_;
 205
 206   if (none { $::form->{type} eq $_ } @{$self->valid_types}) {
 207     die "Not a valid type for order";
 208   }
 209
 210   $self->type($::form->{type});
 211 }
 212
 213 sub init_cv {
 214   my ($self) = @_;
 215
 216   my $cv = $self->type eq _sales_order_type()    ? 'customer'
 217          : $self->type eq _purchase_order_type() ? 'vendor'
 218          : die "Not a valid type for order";
 219
 220   return $cv;
 221 }
 222
 223 sub init_js {
 224   SL::ClientJS->new;
 225 }
 226
 227 sub init_p {
 228   SL::Presenter->get;
 229 }
 230
 231 sub init_order {
 232   _make_order();
 233 }
 234
 235 sub _check_auth {
 236   my ($self) = @_;
 237
 238   my $right_for = { map { $_ => $_.'_edit' } @{$self->valid_types} };
 239
 240   my $right   = $right_for->{ $self->type };
 241   $right    ||= 'DOES_NOT_EXIST';
 242
 243   $::auth->assert($right);
 244 }
 245
 246 sub build_contact_select {
 247   my ($self) = @_;
 248
 249   $self->p->select_tag('order.cp_id', [ $self->order->{$self->cv}->contacts ],
 250                        value_key  => 'cp_id',
 251                        title_key  => 'full_name_dep',
 252                        default    => $self->order->cp_id,
 253                        with_empty => 1,
 254                        style      => 'width: 300px',
 255   );
 256 }
 257
 258 sub build_shipto_select {
 259   my ($self) = @_;
 260
 261   $self->p->select_tag('order.shipto_id', [ $self->order->{$self->cv}->shipto ],
 262                        value_key  => 'shipto_id',
 263                        title_key  => 'displayable_id',
 264                        default    => $self->order->shipto_id,
 265                        with_empty => 1,
 266                        style      => 'width: 300px',
 267   );
 268 }
 269
 270 sub build_tax_rows {
 271   my ($self) = @_;
 272
 273   my $rows_as_html;
 274   foreach my $tax (@{ $self->{taxes} }) {
 275     $rows_as_html .= $self->p->render('order/tabs/_tax_row', TAX => $tax);
 276   }
 277   return $rows_as_html;
 278 }
 279
 280
 281 sub _make_order {
 282   my ($self) = @_;
 283
 284   # add_items adds items to an order with no items for saving, but they cannot
 285   # be retrieved via items until the order is saved. Adding empty items to new
 286   # order here solves this problem.
 287   my $order;
 288   $order   = SL::DB::Manager::Order->find_by(id => $::form->{id}) if $::form->{id};
 289   $order ||= SL::DB::Order->new(orderitems => []);
 290
 291   $order->assign_attributes(%{$::form->{order}});
 292
 293   return $order;
 294 }
 295
 296
 297 sub _recalc {
 298   my ($self) = @_;
 299
 300   # bb: todo: currency later
 301   $self->order->currency_id($::instance_conf->get_currency_id());
 302
 303   my %pat = $self->order->calculate_prices_and_taxes();
 304
 305   foreach my $tax_chart_id (keys %{ $pat{taxes} }) {
 306     my $tax = SL::DB::Manager::Tax->find_by(chart_id => $tax_chart_id);
 307     push(@{ $self->{taxes} }, { amount => $pat{taxes}->{$tax_chart_id},
 308                                 tax    => $tax });
 309   }
 310
 311   pairwise { $a->{linetotal} = $b->{linetotal} } @{$self->order->items}, @{$pat{items}};
 312 }
 313
 314 sub _save {
 315   my ($self) = @_;
 316
 317   my $errors = [];
 318   my $db = $self->order->db;
 319
 320   $db->do_transaction(
 321     sub {
 322       $self->order->save();
 323   }) || push(@{$errors}, $db->error);
 324
 325   return $errors;
 326 }
 327
 328
 329 sub _pre_render {
 330   my ($self) = @_;
 331
 332   $self->{all_taxzones}  = SL::DB::Manager::TaxZone->get_all_sorted();
 333   $self->{all_employees} = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->employee_id,
 334                                                                                  deleted => 0 ] ],
 335                                                               sort_by => 'name');
 336   $self->{all_projects}  = SL::DB::Manager::Project->get_all(where => [ or => [ id => $self->order->globalproject_id,
 337                                                                                 active => 1 ] ],
 338                                                              sort_by => 'projectnumber');
 339
 340   $self->{current_employee_id} = SL::DB::Manager::Employee->current->id;
 341 }
 342
 343 sub _sales_order_type {
 344   'sales_order';
 345 }
 346
 347 sub _purchase_order_type {
 348   'purchase_order';
 349 }
 350
 351 1;