SL/Controller/Order.pm

   1 package SL::Controller::Order;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use SL::Helper::Flash;
   7 use SL::Presenter;
   8 use SL::Locale::String;
   9 use SL::SessionFile::Random;
  10 use SL::PriceSource;
  11 use SL::Form;
  12 use SL::Webdav;
  13 use SL::Template;
  14
  15 use SL::DB::Order;
  16 use SL::DB::Customer;
  17 use SL::DB::Vendor;
  18 use SL::DB::TaxZone;
  19 use SL::DB::Employee;
  20 use SL::DB::Project;
  21 use SL::DB::Default;
  22 use SL::DB::Unit;
  23 use SL::DB::Price;
  24 use SL::DB::Part;
  25 use SL::DB::Printer;
  26 use SL::DB::Language;
  27
  28 use SL::Helper::DateTime;
  29 use SL::Helper::CreatePDF qw(:all);
  30 use SL::Helper::PrintOptions;
  31
  32 use SL::Controller::Helper::GetModels;
  33
  34 use List::Util qw(max first);
  35 use List::MoreUtils qw(none pairwise first_index);
  36 use English qw(-no_match_vars);
  37 use File::Spec;
  38
  39 use Rose::Object::MakeMethods::Generic
  40 (
  41  scalar => [ qw(item_ids_to_delete) ],
  42  'scalar --get_set_init' => [ qw(order valid_types type cv p multi_items_models) ],
  43 );
  44
  45
  46 # safety
  47 __PACKAGE__->run_before('_check_auth');
  48
  49 __PACKAGE__->run_before('_recalc',
  50                         only => [ qw(update save save_and_delivery_order print create_pdf send_email) ]);
  51
  52 __PACKAGE__->run_before('_get_unalterable_data',
  53                         only => [ qw(save save_and_delivery_order print create_pdf send_email) ]);
  54
  55 #
  56 # actions
  57 #
  58
  59 sub action_add {
  60   my ($self) = @_;
  61
  62   $self->order->transdate(DateTime->now_local());
  63   $self->order->reqdate(DateTime->today_local->next_workday) if !$self->order->reqdate;
  64
  65   $self->_pre_render();
  66   $self->render(
  67     'order/form',
  68     title => $self->type eq _sales_order_type()    ? $::locale->text('Add Sales Order')
  69            : $self->type eq _purchase_order_type() ? $::locale->text('Add Purchase Order')
  70            : '',
  71     %{$self->{template_args}}
  72   );
  73 }
  74
  75 sub action_edit {
  76   my ($self) = @_;
  77
  78   $self->_load_order;
  79   $self->_recalc();
  80   $self->_pre_render();
  81   $self->render(
  82     'order/form',
  83     title => $self->type eq _sales_order_type()    ? $::locale->text('Edit Sales Order')
  84            : $self->type eq _purchase_order_type() ? $::locale->text('Edit Purchase Order')
  85            : '',
  86     %{$self->{template_args}}
  87   );
  88 }
  89
  90 sub action_update {
  91   my ($self) = @_;
  92
  93   $self->_pre_render();
  94   $self->render(
  95     'order/form',
  96     title => $self->type eq _sales_order_type()    ? $::locale->text('Edit Sales Order')
  97            : $self->type eq _purchase_order_type() ? $::locale->text('Edit Purchase Order')
  98            : '',
  99     %{$self->{template_args}}
 100   );
 101 }
 102
 103 sub action_delete {
 104   my ($self) = @_;
 105
 106   my $errors = $self->_delete();
 107
 108   if (scalar @{ $errors }) {
 109     $self->js->flash('error', $_) foreach @{ $errors };
 110     return $self->js->render();
 111   }
 112
 113   flash_later('info', $::locale->text('The order has been deleted'));
 114   my @redirect_params = (
 115     action => 'edit',
 116     type   => $self->type,
 117   );
 118
 119   $self->redirect_to(@redirect_params);
 120 }
 121
 122 sub action_save {
 123   my ($self) = @_;
 124
 125   my $errors = $self->_save();
 126
 127   if (scalar @{ $errors }) {
 128     $self->js->flash('error', $_) foreach @{ $errors };
 129     return $self->js->render();
 130   }
 131
 132   flash_later('info', $::locale->text('The order has been saved'));
 133   my @redirect_params = (
 134     action => 'edit',
 135     type   => $self->type,
 136     id     => $self->order->id,
 137   );
 138
 139   $self->redirect_to(@redirect_params);
 140 }
 141
 142 sub action_print {
 143   my ($self) = @_;
 144
 145   my $format      = $::form->{print_options}->{format};
 146   my $media       = $::form->{print_options}->{media};
 147   my $formname    = $::form->{print_options}->{formname};
 148   my $copies      = $::form->{print_options}->{copies};
 149   my $groupitems  = $::form->{print_options}->{groupitems};
 150
 151   # only pdf by now
 152   if (none { $format eq $_ } qw(pdf)) {
 153     return $self->js->flash('error', t8('Format \'#1\' is not supported yet/anymore.', $format))->render;
 154   }
 155
 156   # only screen or printer by now
 157   if (none { $media eq $_ } qw(screen printer)) {
 158     return $self->js->flash('error', t8('Media \'#1\' is not supported yet/anymore.', $media))->render;
 159   }
 160
 161   my $language;
 162   $language = SL::DB::Language->new(id => $::form->{print_options}->{language_id})->load if $::form->{print_options}->{language_id};
 163
 164   my $form = Form->new;
 165   $form->{ordnumber} = $self->order->ordnumber;
 166   $form->{type}      = $self->type;
 167   $form->{format}    = $format;
 168   $form->{formname}  = $formname;
 169   $form->{language}  = '_' . $language->template_code if $language;
 170   my $pdf_filename   = $form->generate_attachment_filename();
 171
 172   my $pdf;
 173   my @errors = _create_pdf($self->order, \$pdf, { format     => $format,
 174                                                   formname   => $formname,
 175                                                   language   => $language,
 176                                                   groupitems => $groupitems });
 177   if (scalar @errors) {
 178     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render;
 179   }
 180
 181   if ($media eq 'screen') {
 182     # screen/download
 183     my $sfile = SL::SessionFile::Random->new(mode => "w");
 184     $sfile->fh->print($pdf);
 185     $sfile->fh->close;
 186
 187     my $key = join('_', Time::HiRes::gettimeofday(), int rand 1000000000000);
 188     $::auth->set_session_value("Order::create_pdf-${key}" => $sfile->file_name);
 189
 190     $self->js
 191     ->run('download_pdf', $pdf_filename, $key)
 192     ->flash('info', t8('The PDF has been created'));
 193
 194   } elsif ($media eq 'printer') {
 195     # printer
 196     my $printer_id = $::form->{print_options}->{printer_id};
 197     my $printer;
 198     $printer = SL::DB::Printer->new(id => $printer_id)->load if $printer_id;
 199     if (!$printer) {
 200       return $self->js->flash('error', t8('Printer not found.'))->render;
 201     }
 202
 203     my $command = SL::Template::create(type => 'ShellCommand', form => Form->new(''))->parse($printer->printer_command);
 204
 205     for my $i (1 .. $copies) {
 206       open my $out, '|-', $command or die $!;
 207       binmode $out;
 208       print $out $pdf;
 209       close $out;
 210     }
 211
 212     $self->js->flash('info', t8('The PDF has been printed'));
 213   }
 214
 215   # copy file to webdav folder
 216   if ($self->order->ordnumber && $::instance_conf->get_webdav_documents) {
 217     my $webdav = SL::Webdav->new(
 218       type     => $self->type,
 219       number   => $self->order->ordnumber,
 220     );
 221     my $webdav_file = SL::Webdav::File->new(
 222       webdav   => $webdav,
 223       filename => $pdf_filename,
 224     );
 225     eval {
 226       $webdav_file->store(data => \$pdf);
 227       1;
 228     } or do {
 229       $self->js->flash('error', t8('Storing PDF to webdav folder failed: #1', $@));
 230     }
 231   }
 232
 233   $self->js->render;
 234 }
 235
 236 sub action_download_pdf {
 237   my ($self) = @_;
 238
 239   my $key = $::form->{key};
 240   my $tmp_filename = $::auth->get_session_value("Order::create_pdf-${key}");
 241   return $self->send_file(
 242     $tmp_filename,
 243     type => 'application/pdf',
 244     name => $::form->{pdf_filename},
 245   );
 246 }
 247
 248 sub action_show_email_dialog {
 249   my ($self) = @_;
 250
 251   my $cv_method = $self->cv;
 252
 253   if (!$self->order->$cv_method) {
 254     return $self->js->flash('error', $self->cv eq 'customer' ? t8('Cannot send E-mail without customer given') : t8('Cannot send E-mail without vendor given'))
 255                     ->render($self);
 256   }
 257
 258   $self->{email}->{to}   = $self->order->contact->cp_email if $self->order->contact;
 259   $self->{email}->{to} ||= $self->order->$cv_method->email;
 260   $self->{email}->{cc}   = $self->order->$cv_method->cc;
 261   $self->{email}->{bcc}  = join ', ', grep $_, $self->order->$cv_method->bcc, SL::DB::Default->get->global_bcc;
 262   # Todo: get addresses from shipto, if any
 263
 264   my $form = Form->new;
 265   $form->{ordnumber} = $self->order->ordnumber;
 266   $form->{formname}  = $self->type;
 267   $form->{type}      = $self->type;
 268   $form->{language} = 'de';
 269   $form->{format}   = 'pdf';
 270
 271   $self->{email}->{subject}             = $form->generate_email_subject();
 272   $self->{email}->{attachment_filename} = $form->generate_attachment_filename();
 273   $self->{email}->{message}             = $form->create_email_signature();
 274
 275   my $dialog_html = $self->render('order/tabs/_email_dialog', { output => 0 });
 276   $self->js
 277       ->run('show_email_dialog', $dialog_html)
 278       ->reinit_widgets
 279       ->render($self);
 280 }
 281
 282 # Todo: handling error messages: flash is not displayed in dialog, but in the main form
 283 sub action_send_email {
 284   my ($self) = @_;
 285
 286   my $mail      = Mailer->new;
 287   $mail->{from} = qq|"$::myconfig{name}" <$::myconfig{email}>|;
 288   $mail->{$_}   = $::form->{email}->{$_} for qw(to cc bcc subject message);
 289
 290   my $pdf;
 291   my @errors = _create_pdf($self->order, \$pdf, {media => 'email'});
 292   if (scalar @errors) {
 293     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render($self);
 294   }
 295
 296   $mail->{attachments} = [{ "content" => $pdf,
 297                             "name"    => $::form->{email}->{attachment_filename} }];
 298
 299   if (my $err = $mail->send) {
 300     return $self->js->flash('error', t8('Sending E-mail: ') . $err)
 301                     ->render($self);
 302   }
 303
 304   # internal notes
 305   my $intnotes = $self->order->intnotes;
 306   $intnotes   .= "\n\n" if $self->order->intnotes;
 307   $intnotes   .= t8('[email]')                                                                                        . "\n";
 308   $intnotes   .= t8('Date')       . ": " . $::locale->format_date_object(DateTime->now_local, precision => 'seconds') . "\n";
 309   $intnotes   .= t8('To (email)') . ": " . $mail->{to}                                                                . "\n";
 310   $intnotes   .= t8('Cc')         . ": " . $mail->{cc}                                                                . "\n"    if $mail->{cc};
 311   $intnotes   .= t8('Bcc')        . ": " . $mail->{bcc}                                                               . "\n"    if $mail->{bcc};
 312   $intnotes   .= t8('Subject')    . ": " . $mail->{subject}                                                           . "\n\n";
 313   $intnotes   .= t8('Message')    . ": " . $mail->{message};
 314
 315   $self->js
 316       ->val('#order_intnotes', $intnotes)
 317       ->run('close_email_dialog')
 318       ->render($self);
 319 }
 320
 321 sub action_save_and_delivery_order {
 322   my ($self) = @_;
 323
 324   my $errors = $self->_save();
 325
 326   if (scalar @{ $errors }) {
 327     $self->js->flash('error', $_) foreach @{ $errors };
 328     return $self->js->render();
 329   }
 330   flash_later('info', $::locale->text('The order has been saved'));
 331
 332   my @redirect_params = (
 333     controller => 'oe.pl',
 334     action     => 'oe_delivery_order_from_order',
 335     id         => $self->order->id,
 336   );
 337
 338   $self->redirect_to(@redirect_params);
 339 }
 340
 341 sub action_customer_vendor_changed {
 342   my ($self) = @_;
 343
 344   my $cv_method = $self->cv;
 345
 346   if ($self->order->$cv_method->contacts && scalar @{ $self->order->$cv_method->contacts } > 0) {
 347     $self->js->show('#cp_row');
 348   } else {
 349     $self->js->hide('#cp_row');
 350   }
 351
 352   if ($self->order->$cv_method->shipto && scalar @{ $self->order->$cv_method->shipto } > 0) {
 353     $self->js->show('#shipto_row');
 354   } else {
 355     $self->js->hide('#shipto_row');
 356   }
 357
 358   $self->order->taxzone_id($self->order->$cv_method->taxzone_id);
 359
 360   if ($self->order->is_sales) {
 361     $self->order->taxincluded(defined($self->order->$cv_method->taxincluded_checked)
 362                               ? $self->order->$cv_method->taxincluded_checked
 363                               : $::myconfig{taxincluded_checked});
 364   }
 365
 366   $self->order->payment_id($self->order->$cv_method->payment_id);
 367   $self->order->delivery_term_id($self->order->$cv_method->delivery_term_id);
 368
 369   $self->_recalc();
 370
 371   $self->js
 372     ->replaceWith('#order_cp_id',            $self->build_contact_select)
 373     ->replaceWith('#order_shipto_id',        $self->build_shipto_select)
 374     ->val(        '#order_taxzone_id',       $self->order->taxzone_id)
 375     ->val(        '#order_taxincluded',      $self->order->taxincluded)
 376     ->val(        '#order_payment_id',       $self->order->payment_id)
 377     ->val(        '#order_delivery_term_id', $self->order->delivery_term_id)
 378     ->val(        '#order_intnotes',         $self->order->$cv_method->notes)
 379     ->focus(      '#order_' . $self->cv . '_id');
 380
 381   $self->_js_redisplay_amounts_and_taxes;
 382   $self->js->render();
 383 }
 384
 385 sub action_unit_changed {
 386   my ($self) = @_;
 387
 388   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 389   my $item = $self->order->items_sorted->[$idx];
 390
 391   my $old_unit_obj = SL::DB::Unit->new(name => $::form->{old_unit})->load;
 392   $item->sellprice($item->unit_obj->convert_to($item->sellprice, $old_unit_obj));
 393
 394   $self->_recalc();
 395
 396   $self->js
 397     ->run('update_sellprice', $::form->{item_id}, $item->sellprice_as_number);
 398   $self->_js_redisplay_linetotals;
 399   $self->_js_redisplay_amounts_and_taxes;
 400   $self->js->render();
 401 }
 402
 403 sub action_add_item {
 404   my ($self) = @_;
 405
 406   my $form_attr = $::form->{add_item};
 407
 408   return unless $form_attr->{parts_id};
 409
 410   my $item = _new_item($self->order, $form_attr);
 411   $self->order->add_items($item);
 412
 413   $self->_recalc();
 414
 415   my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 416   my $row_as_html = $self->p->render('order/tabs/_row', ITEM => $item, ID => $item_id);
 417
 418   $self->js
 419     ->append('#row_table_id', $row_as_html)
 420     ->val('.add_item_input', '')
 421     ->run('row_table_scroll_down')
 422     ->run('row_set_keyboard_events_by_id', $item_id)
 423     ->run('set_unit_change_with_oldval_by_id', $item_id)
 424     ->run('renumber_positions')
 425     ->on('.recalc', 'change', 'recalc_amounts_and_taxes')
 426     ->on('.reformat_number', 'change', 'reformat_number')
 427     ->focus('#add_item_parts_id_name');
 428
 429   $self->_js_redisplay_amounts_and_taxes;
 430   $self->js->render();
 431 }
 432
 433 sub action_show_multi_items_dialog {
 434   require SL::DB::PartsGroup;
 435   $_[0]->render('order/tabs/_multi_items_dialog', { layout => 0 },
 436                 all_partsgroups => SL::DB::Manager::PartsGroup->get_all);
 437 }
 438
 439 sub action_multi_items_update_result {
 440   my $max_count = 100;
 441   my $count = $_[0]->multi_items_models->count;
 442
 443   if ($count == 0) {
 444     my $text = SL::Presenter::EscapedText->new(text => $::locale->text('No results.'));
 445     $_[0]->render($text, { layout => 0 });
 446   } elsif ($count > $max_count) {
 447     my $text = SL::Presenter::EscapedText->new(text => $::locale->text('Too many results (#1 from #2).', $count, $max_count));
 448     $_[0]->render($text, { layout => 0 });
 449   } else {
 450     my $multi_items = $_[0]->multi_items_models->get;
 451     $_[0]->render('order/tabs/_multi_items_result', { layout => 0 },
 452                   multi_items => $multi_items);
 453   }
 454 }
 455
 456 sub action_add_multi_items {
 457   my ($self) = @_;
 458
 459   my @form_attr = grep { $_->{qty_as_number} } @{ $::form->{add_multi_items} };
 460   return $self->js->render() unless scalar @form_attr;
 461
 462   my @items;
 463   foreach my $attr (@form_attr) {
 464     push @items, _new_item($self->order, $attr);
 465   }
 466   $self->order->add_items(@items);
 467
 468   $self->_recalc();
 469
 470   foreach my $item (@items) {
 471     my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 472     my $row_as_html = $self->p->render('order/tabs/_row', ITEM => $item, ID => $item_id);
 473
 474     $self->js
 475         ->append('#row_table_id', $row_as_html)
 476         ->run('row_set_keyboard_events_by_id', $item_id)
 477         ->run('set_unit_change_with_oldval_by_id', $item_id);
 478   }
 479
 480   $self->js
 481     ->run('close_multi_items_dialog')
 482     ->run('row_table_scroll_down')
 483     ->run('renumber_positions')
 484     ->on('.recalc', 'change', 'recalc_amounts_and_taxes')
 485     ->on('.reformat_number', 'change', 'reformat_number')
 486     ->focus('#add_item_parts_id_name');
 487
 488   $self->_js_redisplay_amounts_and_taxes;
 489   $self->js->render();
 490 }
 491
 492 sub action_recalc_amounts_and_taxes {
 493   my ($self) = @_;
 494
 495   $self->_recalc();
 496
 497   $self->_js_redisplay_linetotals;
 498   $self->_js_redisplay_amounts_and_taxes;
 499   $self->js->render();
 500 }
 501
 502 sub action_reorder_items {
 503   my ($self) = @_;
 504
 505   my %sort_keys = (
 506     partnumber  => sub { $_[0]->part->partnumber },
 507     description => sub { $_[0]->description },
 508     qty         => sub { $_[0]->qty },
 509     sellprice   => sub { $_[0]->sellprice },
 510     discount    => sub { $_[0]->discount },
 511   );
 512
 513   my $method = $sort_keys{$::form->{order_by}};
 514   my @to_sort = map { { old_pos => $_->position, order_by => $method->($_) } } @{ $self->order->items_sorted };
 515   if ($::form->{sort_dir}) {
 516     @to_sort = sort { $a->{order_by} cmp $b->{order_by} } @to_sort;
 517   } else {
 518     @to_sort = sort { $b->{order_by} cmp $a->{order_by} } @to_sort;
 519   }
 520   $self->js
 521     ->run('redisplay_items', \@to_sort)
 522     ->render;
 523 }
 524
 525 sub action_price_popup {
 526   my ($self) = @_;
 527
 528   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 529   my $item = $self->order->items_sorted->[$idx];
 530
 531   $self->render_price_dialog($item);
 532 }
 533
 534 sub action_get_item_longdescription {
 535   my $longdescription;
 536
 537   if ($::form->{item_id}) {
 538     $longdescription = SL::DB::OrderItem->new(id => $::form->{item_id})->load->longdescription;
 539   } elsif ($::form->{parts_id}) {
 540     $longdescription = SL::DB::Part->new(id => $::form->{parts_id})->load->notes;
 541   }
 542   $_[0]->render(\ $longdescription, { type => 'text' });
 543 }
 544
 545
 546 sub _js_redisplay_linetotals {
 547   my ($self) = @_;
 548
 549   my @data = map {$::form->format_amount(\%::myconfig, $_->{linetotal}, 2, 0)} @{ $self->order->items_sorted };
 550   $self->js
 551     ->run('redisplay_linetotals', \@data);
 552 }
 553
 554 sub _js_redisplay_amounts_and_taxes {
 555   my ($self) = @_;
 556
 557   if (scalar @{ $self->{taxes} }) {
 558     $self->js->show('#taxincluded_row_id');
 559   } else {
 560     $self->js->hide('#taxincluded_row_id');
 561   }
 562
 563   if ($self->order->taxincluded) {
 564     $self->js->hide('#subtotal_row_id');
 565   } else {
 566     $self->js->show('#subtotal_row_id');
 567   }
 568
 569   $self->js
 570     ->html('#netamount_id', $::form->format_amount(\%::myconfig, $self->order->netamount, -2))
 571     ->html('#amount_id',    $::form->format_amount(\%::myconfig, $self->order->amount,    -2))
 572     ->remove('.tax_row')
 573     ->insertBefore($self->build_tax_rows, '#amount_row_id');
 574 }
 575
 576 #
 577 # helpers
 578 #
 579
 580 sub init_valid_types {
 581   [ _sales_order_type(), _purchase_order_type() ];
 582 }
 583
 584 sub init_type {
 585   my ($self) = @_;
 586
 587   if (none { $::form->{type} eq $_ } @{$self->valid_types}) {
 588     die "Not a valid type for order";
 589   }
 590
 591   $self->type($::form->{type});
 592 }
 593
 594 sub init_cv {
 595   my ($self) = @_;
 596
 597   my $cv = $self->type eq _sales_order_type()    ? 'customer'
 598          : $self->type eq _purchase_order_type() ? 'vendor'
 599          : die "Not a valid type for order";
 600
 601   return $cv;
 602 }
 603
 604 sub init_p {
 605   SL::Presenter->get;
 606 }
 607
 608 sub init_order {
 609   $_[0]->_make_order;
 610 }
 611
 612 sub init_multi_items_models {
 613   SL::Controller::Helper::GetModels->new(
 614     controller     => $_[0],
 615     model          => 'Part',
 616     with_objects   => [ qw(unit_obj) ],
 617     disable_plugin => 'paginated',
 618     source         => $::form->{multi_items},
 619     sorted         => {
 620       _default    => {
 621         by  => 'partnumber',
 622         dir => 1,
 623       },
 624       partnumber  => t8('Partnumber'),
 625       description => t8('Description')}
 626   );
 627 }
 628
 629 sub _check_auth {
 630   my ($self) = @_;
 631
 632   my $right_for = { map { $_ => $_.'_edit' } @{$self->valid_types} };
 633
 634   my $right   = $right_for->{ $self->type };
 635   $right    ||= 'DOES_NOT_EXIST';
 636
 637   $::auth->assert($right);
 638 }
 639
 640 sub build_contact_select {
 641   my ($self) = @_;
 642
 643   $self->p->select_tag('order.cp_id', [ $self->order->{$self->cv}->contacts ],
 644                        value_key  => 'cp_id',
 645                        title_key  => 'full_name_dep',
 646                        default    => $self->order->cp_id,
 647                        with_empty => 1,
 648                        style      => 'width: 300px',
 649   );
 650 }
 651
 652 sub build_shipto_select {
 653   my ($self) = @_;
 654
 655   $self->p->select_tag('order.shipto_id', [ $self->order->{$self->cv}->shipto ],
 656                        value_key  => 'shipto_id',
 657                        title_key  => 'displayable_id',
 658                        default    => $self->order->shipto_id,
 659                        with_empty => 1,
 660                        style      => 'width: 300px',
 661   );
 662 }
 663
 664 sub build_tax_rows {
 665   my ($self) = @_;
 666
 667   my $rows_as_html;
 668   foreach my $tax (sort { $a->{tax}->rate cmp $b->{tax}->rate } @{ $self->{taxes} }) {
 669     $rows_as_html .= $self->p->render('order/tabs/_tax_row', TAX => $tax, TAXINCLUDED => $self->order->taxincluded);
 670   }
 671   return $rows_as_html;
 672 }
 673
 674
 675 sub render_price_dialog {
 676   my ($self, $record_item) = @_;
 677
 678   my $price_source = SL::PriceSource->new(record_item => $record_item, record => $self->order);
 679
 680   $self->js
 681     ->run(
 682       'kivi.io.price_chooser_dialog',
 683       t8('Available Prices'),
 684       $self->render('order/tabs/_price_sources_dialog', { output => 0 }, price_source => $price_source)
 685     )
 686     ->reinit_widgets;
 687
 688 #   if (@errors) {
 689 #     $self->js->text('#dialog_flash_error_content', join ' ', @errors);
 690 #     $self->js->show('#dialog_flash_error');
 691 #   }
 692
 693   $self->js->render;
 694 }
 695
 696 sub _load_order {
 697   my ($self) = @_;
 698
 699   return if !$::form->{id};
 700
 701   $self->order(SL::DB::Manager::Order->find_by(id => $::form->{id}));
 702 }
 703
 704 sub _make_order {
 705   my ($self) = @_;
 706
 707   # add_items adds items to an order with no items for saving, but they cannot
 708   # be retrieved via items until the order is saved. Adding empty items to new
 709   # order here solves this problem.
 710   my $order;
 711   $order   = SL::DB::Manager::Order->find_by(id => $::form->{id}) if $::form->{id};
 712   $order ||= SL::DB::Order->new(orderitems => []);
 713
 714   my $form_orderitems = delete $::form->{order}->{orderitems};
 715   $order->assign_attributes(%{$::form->{order}});
 716
 717   # remove deleted items
 718   $self->item_ids_to_delete([]);
 719   foreach my $idx (reverse 0..$#{$order->orderitems}) {
 720     my $item = $order->orderitems->[$idx];
 721     if (none { $item->id == $_->{id} } @{$form_orderitems}) {
 722       splice @{$order->orderitems}, $idx, 1;
 723       push @{$self->item_ids_to_delete}, $item->id;
 724     }
 725   }
 726
 727   my @items;
 728   my $pos = 1;
 729   foreach my $form_attr (@{$form_orderitems}) {
 730     my $item = _make_item($order, $form_attr);
 731     $item->position($pos);
 732     push @items, $item;
 733     $pos++;
 734   }
 735   $order->add_items(grep {!$_->id} @items);
 736
 737   return $order;
 738 }
 739
 740
 741 # Make item objects from form values. For items already existing read from db.
 742 # Create a new item else. And assign attributes.
 743 sub _make_item {
 744   my ($record, $attr) = @_;
 745
 746   my $item;
 747   $item = first { $_->id == $attr->{id} } @{$record->items} if $attr->{id};
 748
 749   my $is_new = !$item;
 750
 751   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
 752   # they cannot be retrieved via custom_variables until the order/orderitem is
 753   # saved. Adding empty custom_variables to new orderitem here solves this problem.
 754   $item ||= SL::DB::OrderItem->new(custom_variables => []);
 755
 756   $item->assign_attributes(%$attr);
 757   $item->longdescription($item->part->notes) if $is_new && !defined $attr->{longdescription};
 758
 759   return $item;
 760 }
 761
 762 sub _new_item {
 763   my ($record, $attr) = @_;
 764
 765   my $item = SL::DB::OrderItem->new;
 766   $item->assign_attributes(%$attr);
 767
 768   my $part         = SL::DB::Part->new(id => $attr->{parts_id})->load;
 769   my $price_source = SL::PriceSource->new(record_item => $item, record => $record);
 770
 771   $item->unit($part->unit) if !$item->unit;
 772
 773   my $price_src;
 774   if ($item->sellprice) {
 775     $price_src = $price_source->price_from_source("");
 776     $price_src->price($item->sellprice);
 777   } else {
 778     $price_src = $price_source->best_price
 779            ? $price_source->best_price
 780            : $price_source->price_from_source("");
 781     $price_src->price(0) if !$price_source->best_price;
 782   }
 783
 784   my $discount_src;
 785   if ($item->discount) {
 786     $discount_src = $price_source->discount_from_source("");
 787     $discount_src->discount($item->discount);
 788   } else {
 789     $discount_src = $price_source->best_discount
 790                   ? $price_source->best_discount
 791                   : $price_source->discount_from_source("");
 792     $discount_src->discount(0) if !$price_source->best_discount;
 793   }
 794
 795   my %new_attr;
 796   $new_attr{part}                   = $part;
 797   $new_attr{description}            = $part->description if ! $item->description;
 798   $new_attr{qty}                    = 1.0                if ! $item->qty;
 799   $new_attr{sellprice}              = $price_src->price;
 800   $new_attr{discount}               = $discount_src->discount;
 801   $new_attr{active_price_source}    = $price_src;
 802   $new_attr{active_discount_source} = $discount_src;
 803
 804   $new_attr{longdescription}        = $part->notes if ! defined $attr->{longdescription};
 805
 806   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
 807   # they cannot be retrieved via custom_variables until the order/orderitem is
 808   # saved. Adding empty custom_variables to new orderitem here solves this problem.
 809   $new_attr{custom_variables} = [];
 810
 811   $item->assign_attributes(%new_attr);
 812
 813   return $item;
 814 }
 815
 816 sub _recalc {
 817   my ($self) = @_;
 818
 819   # bb: todo: currency later
 820   $self->order->currency_id($::instance_conf->get_currency_id());
 821
 822   my %pat = $self->order->calculate_prices_and_taxes();
 823   $self->{taxes} = [];
 824   foreach my $tax_chart_id (keys %{ $pat{taxes} }) {
 825     my $tax = SL::DB::Manager::Tax->find_by(chart_id => $tax_chart_id);
 826
 827     my @amount_keys = grep { $pat{amounts}->{$_}->{tax_id} == $tax->id } keys %{ $pat{amounts} };
 828     push(@{ $self->{taxes} }, { amount    => $pat{taxes}->{$tax_chart_id},
 829                                 netamount => $pat{amounts}->{$amount_keys[0]}->{amount},
 830                                 tax       => $tax });
 831   }
 832
 833   pairwise { $a->{linetotal} = $b->{linetotal} } @{$self->order->items}, @{$pat{items}};
 834 }
 835
 836
 837 sub _get_unalterable_data {
 838   my ($self) = @_;
 839
 840   foreach my $item (@{ $self->order->items }) {
 841     # autovivify all cvars that are not in the form (cvars_by_config can do it).
 842     # workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
 843     foreach my $var (@{ $item->cvars_by_config }) {
 844       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
 845     }
 846     $item->parse_custom_variable_values;
 847   }
 848 }
 849
 850
 851 sub _delete {
 852   my ($self) = @_;
 853
 854   my $errors = [];
 855   my $db = $self->order->db;
 856
 857   $db->do_transaction(
 858     sub {
 859       my @spoolfiles = grep { $_ } map { $_->spoolfile } @{ SL::DB::Manager::Status->get_all(where => [ trans_id => $self->order->id ]) };
 860       $self->order->delete;
 861       my $spool = $::lx_office_conf{paths}->{spool};
 862       unlink map { "$spool/$_" } @spoolfiles if $spool;
 863
 864       1;
 865   }) || push(@{$errors}, $db->error);
 866
 867   return $errors;
 868 }
 869
 870
 871 sub _save {
 872   my ($self) = @_;
 873
 874   my $errors = [];
 875   my $db = $self->order->db;
 876
 877   $db->do_transaction(
 878     sub {
 879       SL::DB::OrderItem->new(id => $_)->delete for @{$self->item_ids_to_delete};
 880       $self->order->save(cascade => 1);
 881   }) || push(@{$errors}, $db->error);
 882
 883   return $errors;
 884 }
 885
 886
 887 sub _pre_render {
 888   my ($self) = @_;
 889
 890   $self->{all_taxzones}        = SL::DB::Manager::TaxZone->get_all_sorted();
 891   $self->{all_departments}     = SL::DB::Manager::Department->get_all_sorted();
 892   $self->{all_employees}       = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->employee_id,
 893                                                                                        deleted => 0 ] ],
 894                                                                     sort_by => 'name');
 895   $self->{all_salesmen}        = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->salesman_id,
 896                                                                                        deleted => 0 ] ],
 897                                                                     sort_by => 'name');
 898   $self->{all_projects}        = SL::DB::Manager::Project->get_all(where => [ or => [ id => $self->order->globalproject_id,
 899                                                                                       active => 1 ] ],
 900                                                                    sort_by => 'projectnumber');
 901   $self->{all_payment_terms}   = SL::DB::Manager::PaymentTerm->get_all_sorted();
 902   $self->{all_delivery_terms}  = SL::DB::Manager::DeliveryTerm->get_all_sorted();
 903
 904   $self->{current_employee_id} = SL::DB::Manager::Employee->current->id;
 905
 906   my $print_form = Form->new('');
 907   $print_form->{type}      = $self->type;
 908   $print_form->{printers}  = SL::DB::Manager::Printer->get_all_sorted;
 909   $print_form->{languages} = SL::DB::Manager::Language->get_all_sorted;
 910   $self->{print_options}   = SL::Helper::PrintOptions->get_print_options(
 911     form => $print_form,
 912     options => {dialog_name_prefix => 'print_options.',
 913                 show_headers       => 1,
 914                 no_queue           => 1,
 915                 no_postscript      => 1,
 916                 no_opendocument    => 1,
 917                 no_html            => 1},
 918   );
 919
 920   foreach my $item (@{$self->order->orderitems}) {
 921     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
 922     $item->active_price_source(   $price_source->price_from_source(   $item->active_price_source   ));
 923     $item->active_discount_source($price_source->discount_from_source($item->active_discount_source));
 924   }
 925
 926   if ($self->order->ordnumber && $::instance_conf->get_webdav) {
 927     my $webdav = SL::Webdav->new(
 928       type     => $self->type,
 929       number   => $self->order->ordnumber,
 930     );
 931     my $webdav_path = $webdav->webdav_path;
 932     my @all_objects = $webdav->get_all_objects;
 933     @{ $self->{template_args}->{WEBDAV} } = map { { name => $_->filename,
 934                                                     type => t8('File'),
 935                                                     link => File::Spec->catdir($webdav_path, $_->filename),
 936                                                 } } @all_objects;
 937   }
 938
 939   $::request->{layout}->use_javascript("${_}.js")  for qw(kivi.SalesPurchase ckeditor/ckeditor ckeditor/adapters/jquery);
 940 }
 941
 942 sub _create_pdf {
 943   my ($order, $pdf_ref, $params) = @_;
 944
 945   my @errors = ();
 946
 947   my $print_form = Form->new('');
 948   $print_form->{type}        = $order->type;
 949   $print_form->{formname}    = $params->{formname} || $order->type;
 950   $print_form->{format}      = $params->{format}   || 'pdf';
 951   $print_form->{media}       = $params->{media}    || 'file';
 952   $print_form->{groupitems}  = $params->{groupitems};
 953   $print_form->{media}       = 'file'                             if $print_form->{media} eq 'screen';
 954   $print_form->{language}    = $params->{language}->template_code if $print_form->{language};
 955   $print_form->{language_id} = $params->{language}->id            if $print_form->{language};
 956
 957   $order->flatten_to_form($print_form, format_amounts => 1);
 958   # flatten_to_form sets payment_terms from customer/vendor - we do not want that here
 959   delete $print_form->{payment_terms} if !$print_form->{payment_id};
 960
 961   # search for the template
 962   my ($template_file, @template_files) = SL::Helper::CreatePDF->find_template(
 963     name        => $print_form->{formname},
 964     email       => $print_form->{media} eq 'email',
 965     language    => $params->{language},
 966     printer_id  => $print_form->{printer_id},  # todo
 967   );
 968
 969   if (!defined $template_file) {
 970     push @errors, $::locale->text('Cannot find matching template for this print request. Please contact your template maintainer. I tried these: #1.', join ', ', map { "'$_'"} @template_files);
 971   }
 972
 973   return @errors if scalar @errors;
 974
 975   $print_form->throw_on_error(sub {
 976     eval {
 977       $print_form->prepare_for_printing;
 978
 979       $$pdf_ref = SL::Helper::CreatePDF->create_pdf(
 980         template  => $template_file,
 981         variables => $print_form,
 982         variable_content_types => {
 983           longdescription => 'html',
 984           partnotes       => 'html',
 985           notes           => 'html',
 986         },
 987       );
 988       1;
 989     } || push @errors, ref($EVAL_ERROR) eq 'SL::X::FormError' ? $EVAL_ERROR->getMessage : $EVAL_ERROR;
 990   });
 991
 992   return @errors;
 993 }
 994
 995 sub _sales_order_type {
 996   'sales_order';
 997 }
 998
 999 sub _purchase_order_type {
1000   'purchase_order';
1001 }
1002
1003 1;