SL/Controller/Order.pm

   1 package SL::Controller::Order;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use SL::Helper::Flash;
   7 use SL::ClientJS;
   8 use SL::Presenter;
   9
  10 use SL::DB::Order;
  11 use SL::DB::Customer;
  12 use SL::DB::Vendor;
  13 use SL::DB::TaxZone;
  14 use SL::DB::Employee;
  15 use SL::DB::Project;
  16 use SL::DB::Default;
  17 use SL::DB::Unit;
  18
  19 use SL::Helper::DateTime;
  20
  21 use List::Util qw(max first);
  22 use List::MoreUtils qw(none pairwise);
  23
  24 use Rose::Object::MakeMethods::Generic
  25 (
  26  'scalar --get_set_init' => [ qw(order valid_types type cv js p) ],
  27 );
  28
  29
  30 # safety
  31 __PACKAGE__->run_before('_check_auth');
  32
  33 __PACKAGE__->run_before('_recalc',
  34                         only => [ qw(edit update save) ]);
  35
  36
  37 #
  38 # actions
  39 #
  40
  41 sub action_add {
  42   my ($self) = @_;
  43
  44   $self->order->transdate(DateTime->now_local());
  45
  46   $self->_pre_render();
  47   $self->render(
  48     'order/form',
  49     title => $self->type eq _sales_order_type()    ? $::locale->text('Add Sales Order')
  50            : $self->type eq _purchase_order_type() ? $::locale->text('Add Purchase Order')
  51            : '',
  52     %{$self->{template_args}}
  53   );
  54 }
  55
  56 sub action_edit {
  57   my ($self) = @_;
  58
  59   $self->_pre_render();
  60   $self->render(
  61     'order/form',
  62     title => $self->type eq _sales_order_type()    ? $::locale->text('Edit Sales Order')
  63            : $self->type eq _purchase_order_type() ? $::locale->text('Edit Purchase Order')
  64            : '',
  65     %{$self->{template_args}}
  66   );
  67 }
  68
  69 sub action_update {
  70   my ($self) = @_;
  71
  72   $self->_pre_render();
  73   $self->render(
  74     'order/form',
  75     title => $self->type eq _sales_order_type()    ? $::locale->text('Edit Sales Order')
  76            : $self->type eq _purchase_order_type() ? $::locale->text('Edit Purchase Order')
  77            : '',
  78     %{$self->{template_args}}
  79   );
  80 }
  81
  82 sub action_save {
  83   my ($self) = @_;
  84
  85   $self->_save();
  86
  87   my @redirect_params = (
  88     action => 'edit',
  89     type   => $self->type,
  90     id     => $self->order->id,
  91   );
  92
  93   $self->redirect_to(@redirect_params);
  94 }
  95
  96 sub action_customer_vendor_changed {
  97   my ($self) = @_;
  98
  99   if ($self->cv eq 'customer') {
 100     $self->order->customer(SL::DB::Manager::Customer->find_by_or_create(id => $::form->{cv_id}));
 101
 102   } elsif ($self->cv eq 'vendor') {
 103     $self->order->vendor(SL::DB::Manager::Vendor->find_by_or_create(id => $::form->{cv_id}));
 104   }
 105
 106   if ($self->order->{$self->cv}->contacts && scalar @{ $self->order->{$self->cv}->contacts } > 0) {
 107     $self->js->show('#cp_row');
 108   } else {
 109     $self->js->hide('#cp_row');
 110   }
 111
 112   if ($self->order->{$self->cv}->shipto && scalar @{ $self->order->{$self->cv}->shipto } > 0) {
 113     $self->js->show('#shipto_row');
 114   } else {
 115     $self->js->hide('#shipto_row');
 116   }
 117
 118   $self->js
 119     ->replaceWith('#order_cp_id',     $self->build_contact_select)
 120     ->replaceWith('#order_shipto_id', $self->build_shipto_select)
 121     ->val('#order_taxzone_id', $self->order->{$self->cv}->taxzone_id)
 122     ->focus('#order_' . $self->cv . ' _id')
 123     ->render($self);
 124 }
 125
 126 sub action_add_item {
 127   my ($self) = @_;
 128
 129   my $form_attr = $::form->{add_item};
 130   my $item      = SL::DB::OrderItem->new;
 131   $item->assign_attributes(%$form_attr);
 132
 133   my $part        = SL::DB::Part->new(id => $form_attr->{parts_id})->load;
 134   my $cv_class    = "SL::DB::" . ucfirst($self->cv);
 135   my $cv_discount = $::form->{$self->cv . '_id'}? $cv_class->new(id => $::form->{$self->cv . '_id'})->load->discount :0.0;
 136
 137   my %new_attr;
 138   $new_attr{id}        = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 139   $new_attr{part}      = $part;
 140   $new_attr{qty}       = 1.0               if ! $item->{qty};
 141   $new_attr{unit}      = $part->unit;
 142   $new_attr{sellprice} = $part->sellprice  if ! $item->{sellprice};
 143   $new_attr{discount}  = $cv_discount      if ! $item->{discount};
 144   $item->assign_attributes(%new_attr);
 145
 146   $self->order->add_items($item);
 147
 148   $self->_recalc();
 149
 150   my $row_as_html = $self->p->render('order/tabs/_row', ITEM => $item);
 151
 152   $self->js
 153     ->append('#row_table_id tbody', $row_as_html)
 154     ->val('#add_item_parts_id', '')
 155     ->val('#add_item_parts_id_name', '')
 156     ->val('#add_item_description', '')
 157     ->val('#add_item_qty_as_number', '')
 158     ->val('#add_item_sellprice_as_number', '')
 159     ->val('#add_item_discount_as_percent', '')
 160     ->focus('#add_item_parts_id_name');
 161
 162   $self->_js_redisplay_amounts_and_taxes;
 163   $self->js->render($self);
 164 }
 165
 166 sub action_recalc_amounts_and_taxes {
 167   my ($self) = @_;
 168
 169   $self->_recalc();
 170
 171   $self->_js_redisplay_amounts_and_taxes;
 172   $self->js->render($self);
 173 }
 174
 175 sub _js_redisplay_amounts_and_taxes {
 176   my ($self) = @_;
 177
 178   $self->js
 179     ->html('#netamount_id', $::form->format_amount(\%::myconfig, $self->order->netamount, -2))
 180     ->html('#amount_id',    $::form->format_amount(\%::myconfig, $self->order->amount,    -2))
 181     ->remove('.tax_row')
 182     ->insertBefore($self->build_tax_rows, '#amount_row_id');
 183 }
 184
 185 #
 186 # helpers
 187 #
 188
 189 sub init_valid_types {
 190   [ _sales_order_type(), _purchase_order_type() ];
 191 }
 192
 193 sub init_type {
 194   my ($self) = @_;
 195
 196   if (none { $::form->{type} eq $_ } @{$self->valid_types}) {
 197     die "Not a valid type for order";
 198   }
 199
 200   $self->type($::form->{type});
 201 }
 202
 203 sub init_cv {
 204   my ($self) = @_;
 205
 206   my $cv = $self->type eq _sales_order_type()    ? 'customer'
 207          : $self->type eq _purchase_order_type() ? 'vendor'
 208          : die "Not a valid type for order";
 209
 210   return $cv;
 211 }
 212
 213 sub init_js {
 214   SL::ClientJS->new;
 215 }
 216
 217 sub init_p {
 218   SL::Presenter->get;
 219 }
 220
 221 sub init_order {
 222   _make_order();
 223 }
 224
 225 sub _check_auth {
 226   my ($self) = @_;
 227
 228   my $right_for = { map { $_ => $_.'_edit' } @{$self->valid_types} };
 229
 230   my $right   = $right_for->{ $self->type };
 231   $right    ||= 'DOES_NOT_EXIST';
 232
 233   $::auth->assert($right);
 234 }
 235
 236 sub build_contact_select {
 237   my ($self) = @_;
 238
 239   $self->p->select_tag('order.cp_id', [ $self->order->{$self->cv}->contacts ],
 240                        value_key  => 'cp_id',
 241                        title_key  => 'full_name_dep',
 242                        default    => $self->order->cp_id,
 243                        with_empty => 1,
 244                        style      => 'width: 300px',
 245   );
 246 }
 247
 248 sub build_shipto_select {
 249   my ($self) = @_;
 250
 251   $self->p->select_tag('order.shipto_id', [ $self->order->{$self->cv}->shipto ],
 252                        value_key  => 'shipto_id',
 253                        title_key  => 'displayable_id',
 254                        default    => $self->order->shipto_id,
 255                        with_empty => 1,
 256                        style      => 'width: 300px',
 257   );
 258 }
 259
 260 sub build_tax_rows {
 261   my ($self) = @_;
 262
 263   my $rows_as_html;
 264   foreach my $tax (@{ $self->{taxes} }) {
 265     $rows_as_html .= $self->p->render('order/tabs/_tax_row', TAX => $tax);
 266   }
 267   return $rows_as_html;
 268 }
 269
 270
 271 sub _make_order {
 272   my ($self) = @_;
 273
 274   # add_items adds items to an order with no items for saving, but they cannot
 275   # be retrieved via items until the order is saved. Adding empty items to new
 276   # order here solves this problem.
 277   my $order;
 278   $order   = SL::DB::Manager::Order->find_by(id => $::form->{id}) if $::form->{id};
 279   $order ||= SL::DB::Order->new(orderitems => []);
 280
 281   $order->assign_attributes(%{$::form->{order}});
 282
 283   return $order;
 284 }
 285
 286
 287 sub _recalc {
 288   my ($self) = @_;
 289
 290   # bb: todo: currency later
 291   $self->order->currency_id($::instance_conf->get_currency_id());
 292
 293   my %pat = $self->order->calculate_prices_and_taxes();
 294
 295   foreach my $tax_chart_id (keys %{ $pat{taxes} }) {
 296     my $tax = SL::DB::Manager::Tax->find_by(chart_id => $tax_chart_id);
 297     push(@{ $self->{taxes} }, { amount => $pat{taxes}->{$tax_chart_id},
 298                                 tax    => $tax });
 299   }
 300
 301   pairwise { $a->{linetotal} = $b->{linetotal} } @{$self->order->items}, @{$pat{items}};
 302 }
 303
 304 sub _save {
 305   my ($self) = @_;
 306
 307   my $db = $self->order->db;
 308
 309   $db->do_transaction(
 310     sub {
 311       $self->order->save();
 312   }) || die($db->error);
 313 }
 314
 315
 316 sub _pre_render {
 317   my ($self) = @_;
 318
 319   $self->{all_taxzones}  = SL::DB::Manager::TaxZone->get_all_sorted();
 320   $self->{all_employees} = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->employee_id,
 321                                                                                  deleted => 0 ] ],
 322                                                               sort_by => 'name');
 323   $self->{all_projects}  = SL::DB::Manager::Project->get_all(where => [ or => [ id => $self->order->globalproject_id,
 324                                                                                 active => 1 ] ],
 325                                                              sort_by => 'projectnumber');
 326
 327   $self->{current_employee_id} = SL::DB::Manager::Employee->current->id;
 328 }
 329
 330 sub _sales_order_type {
 331   'sales_order';
 332 }
 333
 334 sub _purchase_order_type {
 335   'purchase_order';
 336 }
 337
 338 1;