SL/Controller/Order.pm

   1 package SL::Controller::Order;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use SL::Helper::Flash qw(flash_later);
   7 use SL::Presenter::Tag qw(select_tag hidden_tag);
   8 use SL::Locale::String qw(t8);
   9 use SL::SessionFile::Random;
  10 use SL::PriceSource;
  11 use SL::Webdav;
  12 use SL::File;
  13 use SL::Util qw(trim);
  14 use SL::DB::Order;
  15 use SL::DB::Default;
  16 use SL::DB::Unit;
  17 use SL::DB::Part;
  18 use SL::DB::PartsGroup;
  19 use SL::DB::Printer;
  20 use SL::DB::Language;
  21 use SL::DB::RecordLink;
  22
  23 use SL::Helper::CreatePDF qw(:all);
  24 use SL::Helper::PrintOptions;
  25 use SL::Helper::ShippedQty;
  26
  27 use SL::Controller::Helper::GetModels;
  28
  29 use List::Util qw(first);
  30 use List::UtilsBy qw(sort_by uniq_by);
  31 use List::MoreUtils qw(any none pairwise first_index);
  32 use English qw(-no_match_vars);
  33 use File::Spec;
  34 use Cwd;
  35
  36 use Rose::Object::MakeMethods::Generic
  37 (
  38  scalar => [ qw(item_ids_to_delete) ],
  39  'scalar --get_set_init' => [ qw(order valid_types type cv p multi_items_models all_price_factors) ],
  40 );
  41
  42
  43 # safety
  44 __PACKAGE__->run_before('check_auth');
  45
  46 __PACKAGE__->run_before('recalc',
  47                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice print send_email) ]);
  48
  49 __PACKAGE__->run_before('get_unalterable_data',
  50                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice print send_email) ]);
  51
  52 #
  53 # actions
  54 #
  55
  56 # add a new order
  57 sub action_add {
  58   my ($self) = @_;
  59
  60   $self->order->transdate(DateTime->now_local());
  61   my $extra_days = $self->type eq sales_quotation_type() ? $::instance_conf->get_reqdate_interval : 1;
  62   $self->order->reqdate(DateTime->today_local->next_workday(extra_days => $extra_days)) if !$self->order->reqdate;
  63
  64   $self->pre_render();
  65   $self->render(
  66     'order/form',
  67     title => $self->get_title_for('add'),
  68     %{$self->{template_args}}
  69   );
  70 }
  71
  72 # edit an existing order
  73 sub action_edit {
  74   my ($self) = @_;
  75
  76   if ($::form->{id}) {
  77     $self->load_order;
  78
  79   } else {
  80     # this is to edit an order from an unsaved order object
  81
  82     # set item ids to new fake id, to identify them as new items
  83     foreach my $item (@{$self->order->items_sorted}) {
  84       $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
  85     }
  86     # trigger rendering values for second row/longdescription as hidden,
  87     # because they are loaded only on demand. So we need to keep the values
  88     # from the source.
  89     $_->{render_second_row}      = 1 for @{ $self->order->items_sorted };
  90     $_->{render_longdescription} = 1 for @{ $self->order->items_sorted };
  91   }
  92
  93   $self->recalc();
  94   $self->pre_render();
  95   $self->render(
  96     'order/form',
  97     title => $self->get_title_for('edit'),
  98     %{$self->{template_args}}
  99   );
 100 }
 101
 102 # delete the order
 103 sub action_delete {
 104   my ($self) = @_;
 105
 106   my $errors = $self->delete();
 107
 108   if (scalar @{ $errors }) {
 109     $self->js->flash('error', $_) foreach @{ $errors };
 110     return $self->js->render();
 111   }
 112
 113   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been deleted')
 114            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been deleted')
 115            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been deleted')
 116            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been deleted')
 117            : '';
 118   flash_later('info', $text);
 119
 120   my @redirect_params = (
 121     action => 'add',
 122     type   => $self->type,
 123   );
 124
 125   $self->redirect_to(@redirect_params);
 126 }
 127
 128 # save the order
 129 sub action_save {
 130   my ($self) = @_;
 131
 132   my $errors = $self->save();
 133
 134   if (scalar @{ $errors }) {
 135     $self->js->flash('error', $_) foreach @{ $errors };
 136     return $self->js->render();
 137   }
 138
 139   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
 140            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
 141            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
 142            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
 143            : '';
 144   flash_later('info', $text);
 145
 146   my @redirect_params = (
 147     action => 'edit',
 148     type   => $self->type,
 149     id     => $self->order->id,
 150   );
 151
 152   $self->redirect_to(@redirect_params);
 153 }
 154
 155 # save the order as new document an open it for edit
 156 sub action_save_as_new {
 157   my ($self) = @_;
 158
 159   my $order = $self->order;
 160
 161   if (!$order->id) {
 162     $self->js->flash('error', t8('This object has not been saved yet.'));
 163     return $self->js->render();
 164   }
 165
 166   # load order from db to check if values changed
 167   my $saved_order = SL::DB::Order->new(id => $order->id)->load;
 168
 169   my %new_attrs;
 170   # Lets assign a new number if the user hasn't changed the previous one.
 171   # If it has been changed manually then use it as-is.
 172   $new_attrs{number}    = (trim($order->number) eq $saved_order->number)
 173                         ? ''
 174                         : trim($order->number);
 175
 176   # Clear transdate unless changed
 177   $new_attrs{transdate} = ($order->transdate == $saved_order->transdate)
 178                         ? DateTime->today_local
 179                         : $order->transdate;
 180
 181   # Set new reqdate unless changed
 182   if ($order->reqdate == $saved_order->reqdate) {
 183     my $extra_days = $self->type eq sales_quotation_type() ? $::instance_conf->get_reqdate_interval : 1;
 184     $new_attrs{reqdate} = DateTime->today_local->next_workday(extra_days => $extra_days);
 185   } else {
 186     $new_attrs{reqdate} = $order->reqdate;
 187   }
 188
 189   # Update employee
 190   $new_attrs{employee}  = SL::DB::Manager::Employee->current;
 191
 192   # Create new record from current one
 193   $self->order(SL::DB::Order->new_from($order, destination_type => $order->type, attributes => \%new_attrs));
 194
 195   # no linked records on save as new
 196   delete $::form->{$_} for qw(converted_from_oe_id converted_from_orderitems_ids);
 197
 198   # save
 199   $self->action_save();
 200 }
 201
 202 # print the order
 203 #
 204 # This is called if "print" is pressed in the print dialog.
 205 # If PDF creation was requested and succeeded, the pdf is stored in a session
 206 # file and the filename is stored as session value with an unique key. A
 207 # javascript function with this key is then called. This function calls the
 208 # download action below (action_download_pdf), which offers the file for
 209 # download.
 210 sub action_print {
 211   my ($self) = @_;
 212
 213   my $format      = $::form->{print_options}->{format};
 214   my $media       = $::form->{print_options}->{media};
 215   my $formname    = $::form->{print_options}->{formname};
 216   my $copies      = $::form->{print_options}->{copies};
 217   my $groupitems  = $::form->{print_options}->{groupitems};
 218
 219   # only pdf and opendocument by now
 220   if (none { $format eq $_ } qw(pdf opendocument opendocument_pdf)) {
 221     return $self->js->flash('error', t8('Format \'#1\' is not supported yet/anymore.', $format))->render;
 222   }
 223
 224   # only screen or printer by now
 225   if (none { $media eq $_ } qw(screen printer)) {
 226     return $self->js->flash('error', t8('Media \'#1\' is not supported yet/anymore.', $media))->render;
 227   }
 228
 229   my $language;
 230   $language = SL::DB::Language->new(id => $::form->{print_options}->{language_id})->load if $::form->{print_options}->{language_id};
 231
 232   # create a form for generate_attachment_filename
 233   my $form   = Form->new;
 234   $form->{$self->nr_key()}  = $self->order->number;
 235   $form->{type}             = $self->type;
 236   $form->{format}           = $format;
 237   $form->{formname}         = $formname;
 238   $form->{language}         = '_' . $language->template_code if $language;
 239   my $pdf_filename          = $form->generate_attachment_filename();
 240
 241   my $pdf;
 242   my @errors = generate_pdf($self->order, \$pdf, { format     => $format,
 243                                                    formname   => $formname,
 244                                                    language   => $language,
 245                                                    groupitems => $groupitems });
 246   if (scalar @errors) {
 247     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render;
 248   }
 249
 250   if ($media eq 'screen') {
 251     # screen/download
 252     my $sfile = SL::SessionFile::Random->new(mode => "w");
 253     $sfile->fh->print($pdf);
 254     $sfile->fh->close;
 255
 256     my $key = join('_', Time::HiRes::gettimeofday(), int rand 1000000000000);
 257     $::auth->set_session_value("Order::print-${key}" => $sfile->file_name);
 258
 259     $self->js
 260     ->run('kivi.Order.download_pdf', $pdf_filename, $key)
 261     ->flash('info', t8('The PDF has been created'));
 262
 263   } elsif ($media eq 'printer') {
 264     # printer
 265     my $printer_id = $::form->{print_options}->{printer_id};
 266     SL::DB::Printer->new(id => $printer_id)->load->print_document(
 267       copies  => $copies,
 268       content => $pdf,
 269     );
 270
 271     $self->js->flash('info', t8('The PDF has been printed'));
 272   }
 273
 274   # copy file to webdav folder
 275   if ($self->order->number && $::instance_conf->get_webdav_documents) {
 276     my $webdav = SL::Webdav->new(
 277       type     => $self->type,
 278       number   => $self->order->number,
 279     );
 280     my $webdav_file = SL::Webdav::File->new(
 281       webdav   => $webdav,
 282       filename => $pdf_filename,
 283     );
 284     eval {
 285       $webdav_file->store(data => \$pdf);
 286       1;
 287     } or do {
 288       $self->js->flash('error', t8('Storing PDF to webdav folder failed: #1', $@));
 289     }
 290   }
 291   if ($self->order->number && $::instance_conf->get_doc_storage) {
 292     eval {
 293       SL::File->save(object_id     => $self->order->id,
 294                      object_type   => $self->type,
 295                      mime_type     => 'application/pdf',
 296                      source        => 'created',
 297                      file_type     => 'document',
 298                      file_name     => $pdf_filename,
 299                      file_contents => $pdf);
 300       1;
 301     } or do {
 302       $self->js->flash('error', t8('Storing PDF in storage backend failed: #1', $@));
 303     }
 304   }
 305   $self->js->render;
 306 }
 307
 308 # offer pdf for download
 309 #
 310 # It needs to get the key for the session value to get the pdf file.
 311 sub action_download_pdf {
 312   my ($self) = @_;
 313
 314   my $key = $::form->{key};
 315   my $tmp_filename = $::auth->get_session_value("Order::print-${key}");
 316   return $self->send_file(
 317     $tmp_filename,
 318     type => 'application/pdf',
 319     name => $::form->{pdf_filename},
 320   );
 321 }
 322
 323 # open the email dialog
 324 sub action_show_email_dialog {
 325   my ($self) = @_;
 326
 327   my $cv_method = $self->cv;
 328
 329   if (!$self->order->$cv_method) {
 330     return $self->js->flash('error', $self->cv eq 'customer' ? t8('Cannot send E-mail without customer given') : t8('Cannot send E-mail without vendor given'))
 331                     ->render($self);
 332   }
 333
 334   my $email_form;
 335   $email_form->{to}   = $self->order->contact->cp_email if $self->order->contact;
 336   $email_form->{to} ||= $self->order->$cv_method->email;
 337   $email_form->{cc}   = $self->order->$cv_method->cc;
 338   $email_form->{bcc}  = join ', ', grep $_, $self->order->$cv_method->bcc, SL::DB::Default->get->global_bcc;
 339   # Todo: get addresses from shipto, if any
 340
 341   my $form = Form->new;
 342   $form->{$self->nr_key()}  = $self->order->number;
 343   $form->{formname}         = $self->type;
 344   $form->{type}             = $self->type;
 345   $form->{language}         = 'de';
 346   $form->{format}           = 'pdf';
 347
 348   $email_form->{subject}             = $form->generate_email_subject();
 349   $email_form->{attachment_filename} = $form->generate_attachment_filename();
 350   $email_form->{message}             = $form->generate_email_body();
 351   $email_form->{js_send_function}    = 'kivi.Order.send_email()';
 352
 353   my %files = $self->get_files_for_email_dialog();
 354   my $dialog_html = $self->render('common/_send_email_dialog', { output => 0 },
 355                                   email_form  => $email_form,
 356                                   show_bcc    => $::auth->assert('email_bcc', 'may fail'),
 357                                   FILES       => \%files,
 358                                   is_customer => $self->cv eq 'customer',
 359   );
 360
 361   $self->js
 362       ->run('kivi.Order.show_email_dialog', $dialog_html)
 363       ->reinit_widgets
 364       ->render($self);
 365 }
 366
 367 # send email
 368 #
 369 # Todo: handling error messages: flash is not displayed in dialog, but in the main form
 370 sub action_send_email {
 371   my ($self) = @_;
 372
 373   my $email_form  = delete $::form->{email_form};
 374   my %field_names = (to => 'email');
 375
 376   $::form->{ $field_names{$_} // $_ } = $email_form->{$_} for keys %{ $email_form };
 377
 378   # for Form::cleanup which may be called in Form::send_email
 379   $::form->{cwd}    = getcwd();
 380   $::form->{tmpdir} = $::lx_office_conf{paths}->{userspath};
 381
 382   $::form->{$_}     = $::form->{print_options}->{$_} for keys %{ $::form->{print_options} };
 383   $::form->{media}  = 'email';
 384
 385   if (($::form->{attachment_policy} // '') !~ m{^(?:old_file|no_file)$}) {
 386     my $language;
 387     $language = SL::DB::Language->new(id => $::form->{print_options}->{language_id})->load if $::form->{print_options}->{language_id};
 388
 389     my $pdf;
 390     my @errors = generate_pdf($self->order, \$pdf, {media      => $::form->{media},
 391                                                     format     => $::form->{print_options}->{format},
 392                                                     formname   => $::form->{print_options}->{formname},
 393                                                     language   => $language,
 394                                                     groupitems => $::form->{print_options}->{groupitems}});
 395     if (scalar @errors) {
 396       return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render($self);
 397     }
 398
 399     my $sfile = SL::SessionFile::Random->new(mode => "w");
 400     $sfile->fh->print($pdf);
 401     $sfile->fh->close;
 402
 403     $::form->{tmpfile} = $sfile->file_name;
 404     $::form->{tmpdir}  = $sfile->get_path; # for Form::cleanup which may be called in Form::send_email
 405   }
 406
 407   $::form->send_email(\%::myconfig, 'pdf');
 408
 409   # internal notes
 410   my $intnotes = $self->order->intnotes;
 411   $intnotes   .= "\n\n" if $self->order->intnotes;
 412   $intnotes   .= t8('[email]')                                                                                        . "\n";
 413   $intnotes   .= t8('Date')       . ": " . $::locale->format_date_object(DateTime->now_local, precision => 'seconds') . "\n";
 414   $intnotes   .= t8('To (email)') . ": " . $::form->{email}                                                           . "\n";
 415   $intnotes   .= t8('Cc')         . ": " . $::form->{cc}                                                              . "\n"    if $::form->{cc};
 416   $intnotes   .= t8('Bcc')        . ": " . $::form->{bcc}                                                             . "\n"    if $::form->{bcc};
 417   $intnotes   .= t8('Subject')    . ": " . $::form->{subject}                                                         . "\n\n";
 418   $intnotes   .= t8('Message')    . ": " . $::form->{message};
 419
 420   $self->js
 421       ->val('#order_intnotes', $intnotes)
 422       ->run('kivi.Order.close_email_dialog')
 423       ->flash('info', t8('The email has been sent.'))
 424       ->render($self);
 425 }
 426
 427 # open the periodic invoices config dialog
 428 #
 429 # If there are values in the form (i.e. dialog was opened before),
 430 # then use this values. Create new ones, else.
 431 sub action_show_periodic_invoices_config_dialog {
 432   my ($self) = @_;
 433
 434   my $config = make_periodic_invoices_config_from_yaml(delete $::form->{config});
 435   $config  ||= SL::DB::Manager::PeriodicInvoicesConfig->find_by(oe_id => $::form->{id}) if $::form->{id};
 436   $config  ||= SL::DB::PeriodicInvoicesConfig->new(periodicity             => 'm',
 437                                                    order_value_periodicity => 'p', # = same as periodicity
 438                                                    start_date_as_date      => $::form->{transdate} || $::form->current_date,
 439                                                    extend_automatically_by => 12,
 440                                                    active                  => 1,
 441                                                    email_subject           => GenericTranslations->get(
 442                                                                                 language_id      => $::form->{language_id},
 443                                                                                 translation_type =>"preset_text_periodic_invoices_email_subject"),
 444                                                    email_body              => GenericTranslations->get(
 445                                                                                 language_id      => $::form->{language_id},
 446                                                                                 translation_type =>"preset_text_periodic_invoices_email_body"),
 447   );
 448   $config->periodicity('m')             if none { $_ eq $config->periodicity             }       @SL::DB::PeriodicInvoicesConfig::PERIODICITIES;
 449   $config->order_value_periodicity('p') if none { $_ eq $config->order_value_periodicity } ('p', @SL::DB::PeriodicInvoicesConfig::ORDER_VALUE_PERIODICITIES);
 450
 451   $::form->get_lists(printers => "ALL_PRINTERS",
 452                      charts   => { key       => 'ALL_CHARTS',
 453                                    transdate => 'current_date' });
 454
 455   $::form->{AR} = [ grep { $_->{link} =~ m/(?:^|:)AR(?::|$)/ } @{ $::form->{ALL_CHARTS} } ];
 456
 457   if ($::form->{customer_id}) {
 458     $::form->{ALL_CONTACTS} = SL::DB::Manager::Contact->get_all_sorted(where => [ cp_cv_id => $::form->{customer_id} ]);
 459   }
 460
 461   $self->render('oe/edit_periodic_invoices_config', { layout => 0 },
 462                 popup_dialog             => 1,
 463                 popup_js_close_function  => 'kivi.Order.close_periodic_invoices_config_dialog()',
 464                 popup_js_assign_function => 'kivi.Order.assign_periodic_invoices_config()',
 465                 config                   => $config,
 466                 %$::form);
 467 }
 468
 469 # assign the values of the periodic invoices config dialog
 470 # as yaml in the hidden tag and set the status.
 471 sub action_assign_periodic_invoices_config {
 472   my ($self) = @_;
 473
 474   $::form->isblank('start_date_as_date', $::locale->text('The start date is missing.'));
 475
 476   my $config = { active                     => $::form->{active}       ? 1 : 0,
 477                  terminated                 => $::form->{terminated}   ? 1 : 0,
 478                  direct_debit               => $::form->{direct_debit} ? 1 : 0,
 479                  periodicity                => (any { $_ eq $::form->{periodicity}             }       @SL::DB::PeriodicInvoicesConfig::PERIODICITIES)              ? $::form->{periodicity}             : 'm',
 480                  order_value_periodicity    => (any { $_ eq $::form->{order_value_periodicity} } ('p', @SL::DB::PeriodicInvoicesConfig::ORDER_VALUE_PERIODICITIES)) ? $::form->{order_value_periodicity} : 'p',
 481                  start_date_as_date         => $::form->{start_date_as_date},
 482                  end_date_as_date           => $::form->{end_date_as_date},
 483                  first_billing_date_as_date => $::form->{first_billing_date_as_date},
 484                  print                      => $::form->{print}      ? 1                         : 0,
 485                  printer_id                 => $::form->{print}      ? $::form->{printer_id} * 1 : undef,
 486                  copies                     => $::form->{copies} * 1 ? $::form->{copies}         : 1,
 487                  extend_automatically_by    => $::form->{extend_automatically_by}    * 1 || undef,
 488                  ar_chart_id                => $::form->{ar_chart_id} * 1,
 489                  send_email                 => $::form->{send_email} ? 1 : 0,
 490                  email_recipient_contact_id => $::form->{email_recipient_contact_id} * 1 || undef,
 491                  email_recipient_address    => $::form->{email_recipient_address},
 492                  email_sender               => $::form->{email_sender},
 493                  email_subject              => $::form->{email_subject},
 494                  email_body                 => $::form->{email_body},
 495                };
 496
 497   my $periodic_invoices_config = YAML::Dump($config);
 498
 499   my $status = $self->get_periodic_invoices_status($config);
 500
 501   $self->js
 502     ->remove('#order_periodic_invoices_config')
 503     ->insertAfter(hidden_tag('order.periodic_invoices_config', $periodic_invoices_config), '#periodic_invoices_status')
 504     ->run('kivi.Order.close_periodic_invoices_config_dialog')
 505     ->html('#periodic_invoices_status', $status)
 506     ->flash('info', t8('The periodic invoices config has been assigned.'))
 507     ->render($self);
 508 }
 509
 510 sub action_get_has_active_periodic_invoices {
 511   my ($self) = @_;
 512
 513   my $config = make_periodic_invoices_config_from_yaml(delete $::form->{config});
 514   $config  ||= SL::DB::Manager::PeriodicInvoicesConfig->find_by(oe_id => $::form->{id}) if $::form->{id};
 515
 516   my $has_active_periodic_invoices =
 517        $self->type eq sales_order_type()
 518     && $config
 519     && $config->active
 520     && (!$config->end_date || ($config->end_date > DateTime->today_local))
 521     && $config->get_previous_billed_period_start_date;
 522
 523   $_[0]->render(\ !!$has_active_periodic_invoices, { type => 'text' });
 524 }
 525
 526 # save the order and redirect to the frontend subroutine for a new
 527 # delivery order
 528 sub action_save_and_delivery_order {
 529   my ($self) = @_;
 530
 531   my $errors = $self->save();
 532
 533   if (scalar @{ $errors }) {
 534     $self->js->flash('error', $_) foreach @{ $errors };
 535     return $self->js->render();
 536   }
 537
 538   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
 539            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
 540            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
 541            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
 542            : '';
 543   flash_later('info', $text);
 544
 545   my @redirect_params = (
 546     controller => 'oe.pl',
 547     action     => 'oe_delivery_order_from_order',
 548     id         => $self->order->id,
 549   );
 550
 551   $self->redirect_to(@redirect_params);
 552 }
 553
 554 # save the order and redirect to the frontend subroutine for a new
 555 # invoice
 556 sub action_save_and_invoice {
 557   my ($self) = @_;
 558
 559   my $errors = $self->save();
 560
 561   if (scalar @{ $errors }) {
 562     $self->js->flash('error', $_) foreach @{ $errors };
 563     return $self->js->render();
 564   }
 565
 566   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
 567            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
 568            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
 569            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
 570            : '';
 571   flash_later('info', $text);
 572
 573   my @redirect_params = (
 574     controller => 'oe.pl',
 575     action     => 'oe_invoice_from_order',
 576     id         => $self->order->id,
 577   );
 578
 579   $self->redirect_to(@redirect_params);
 580 }
 581
 582 # workflow from sales quotation to sales order
 583 sub action_sales_order {
 584   $_[0]->workflow_sales_or_purchase_order();
 585 }
 586
 587 # workflow from rfq to purchase order
 588 sub action_purchase_order {
 589   $_[0]->workflow_sales_or_purchase_order();
 590 }
 591
 592 # set form elements in respect to a changed customer or vendor
 593 #
 594 # This action is called on an change of the customer/vendor picker.
 595 sub action_customer_vendor_changed {
 596   my ($self) = @_;
 597
 598   setup_order_from_cv($self->order);
 599   $self->recalc();
 600
 601   my $cv_method = $self->cv;
 602
 603   if ($self->order->$cv_method->contacts && scalar @{ $self->order->$cv_method->contacts } > 0) {
 604     $self->js->show('#cp_row');
 605   } else {
 606     $self->js->hide('#cp_row');
 607   }
 608
 609   if ($self->order->$cv_method->shipto && scalar @{ $self->order->$cv_method->shipto } > 0) {
 610     $self->js->show('#shipto_row');
 611   } else {
 612     $self->js->hide('#shipto_row');
 613   }
 614
 615   $self->js->val( '#order_salesman_id',      $self->order->salesman_id)        if $self->order->is_sales;
 616
 617   $self->js
 618     ->replaceWith('#order_cp_id',            $self->build_contact_select)
 619     ->replaceWith('#order_shipto_id',        $self->build_shipto_select)
 620     ->replaceWith('#business_info_row',      $self->build_business_info_row)
 621     ->val(        '#order_taxzone_id',       $self->order->taxzone_id)
 622     ->val(        '#order_taxincluded',      $self->order->taxincluded)
 623     ->val(        '#order_payment_id',       $self->order->payment_id)
 624     ->val(        '#order_delivery_term_id', $self->order->delivery_term_id)
 625     ->val(        '#order_intnotes',         $self->order->intnotes)
 626     ->val(        '#language_id',            $self->order->$cv_method->language_id)
 627     ->focus(      '#order_' . $self->cv . '_id');
 628
 629   $self->js_redisplay_amounts_and_taxes;
 630   $self->js->render();
 631 }
 632
 633 # open the dialog for customer/vendor details
 634 sub action_show_customer_vendor_details_dialog {
 635   my ($self) = @_;
 636
 637   my $is_customer = 'customer' eq $::form->{vc};
 638   my $cv;
 639   if ($is_customer) {
 640     $cv = SL::DB::Customer->new(id => $::form->{vc_id})->load;
 641   } else {
 642     $cv = SL::DB::Vendor->new(id => $::form->{vc_id})->load;
 643   }
 644
 645   my %details = map { $_ => $cv->$_ } @{$cv->meta->columns};
 646   $details{discount_as_percent} = $cv->discount_as_percent;
 647   $details{creditlimt}          = $cv->creditlimit_as_number;
 648   $details{business}            = $cv->business->description      if $cv->business;
 649   $details{language}            = $cv->language_obj->description  if $cv->language_obj;
 650   $details{delivery_terms}      = $cv->delivery_term->description if $cv->delivery_term;
 651   $details{payment_terms}       = $cv->payment->description       if $cv->payment;
 652   $details{pricegroup}          = $cv->pricegroup->pricegroup     if $is_customer && $cv->pricegroup;
 653
 654   foreach my $entry (@{ $cv->shipto }) {
 655     push @{ $details{SHIPTO} },   { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 656   }
 657   foreach my $entry (@{ $cv->contacts }) {
 658     push @{ $details{CONTACTS} }, { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 659   }
 660
 661   $_[0]->render('common/show_vc_details', { layout => 0 },
 662                 is_customer => $is_customer,
 663                 %details);
 664
 665 }
 666
 667 # called if a unit in an existing item row is changed
 668 sub action_unit_changed {
 669   my ($self) = @_;
 670
 671   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 672   my $item = $self->order->items_sorted->[$idx];
 673
 674   my $old_unit_obj = SL::DB::Unit->new(name => $::form->{old_unit})->load;
 675   $item->sellprice($item->unit_obj->convert_to($item->sellprice, $old_unit_obj));
 676
 677   $self->recalc();
 678
 679   $self->js
 680     ->run('kivi.Order.update_sellprice', $::form->{item_id}, $item->sellprice_as_number);
 681   $self->js_redisplay_line_values;
 682   $self->js_redisplay_amounts_and_taxes;
 683   $self->js->render();
 684 }
 685
 686 # add an item row for a new item entered in the input row
 687 sub action_add_item {
 688   my ($self) = @_;
 689
 690   my $form_attr = $::form->{add_item};
 691
 692   return unless $form_attr->{parts_id};
 693
 694   my $item = new_item($self->order, $form_attr);
 695
 696   $self->order->add_items($item);
 697
 698   $self->recalc();
 699
 700   my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 701   my $row_as_html = $self->p->render('order/tabs/_row',
 702                                      ITEM              => $item,
 703                                      ID                => $item_id,
 704                                      TYPE              => $self->type,
 705                                      ALL_PRICE_FACTORS => $self->all_price_factors
 706   );
 707
 708   $self->js
 709     ->append('#row_table_id', $row_as_html);
 710
 711   if ( $item->part->is_assortment ) {
 712     $form_attr->{qty_as_number} = 1 unless $form_attr->{qty_as_number};
 713     foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 714       my $attr = { parts_id => $assortment_item->parts_id,
 715                    qty      => $assortment_item->qty * $::form->parse_amount(\%::myconfig, $form_attr->{qty_as_number}), # TODO $form_attr->{unit}
 716                    unit     => $assortment_item->unit,
 717                    description => $assortment_item->part->description,
 718                  };
 719       my $item = new_item($self->order, $attr);
 720
 721       # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 722       $item->discount(1) unless $assortment_item->charge;
 723
 724       $self->order->add_items( $item );
 725       $self->recalc();
 726       my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 727       my $row_as_html = $self->p->render('order/tabs/_row',
 728                                          ITEM              => $item,
 729                                          ID                => $item_id,
 730                                          TYPE              => $self->type,
 731                                          ALL_PRICE_FACTORS => $self->all_price_factors
 732       );
 733       $self->js
 734         ->append('#row_table_id', $row_as_html);
 735     };
 736   };
 737
 738   $self->js
 739     ->val('.add_item_input', '')
 740     ->run('kivi.Order.init_row_handlers')
 741     ->run('kivi.Order.row_table_scroll_down')
 742     ->run('kivi.Order.renumber_positions')
 743     ->focus('#add_item_parts_id_name');
 744
 745   $self->js_redisplay_amounts_and_taxes;
 746   $self->js->render();
 747 }
 748
 749 # open the dialog for entering multiple items at once
 750 sub action_show_multi_items_dialog {
 751   $_[0]->render('order/tabs/_multi_items_dialog', { layout => 0 },
 752                 all_partsgroups => SL::DB::Manager::PartsGroup->get_all);
 753 }
 754
 755 # update the filter results in the multi item dialog
 756 sub action_multi_items_update_result {
 757   my $max_count = 100;
 758
 759   $::form->{multi_items}->{filter}->{obsolete} = 0;
 760
 761   my $count = $_[0]->multi_items_models->count;
 762
 763   if ($count == 0) {
 764     my $text = SL::Presenter::EscapedText->new(text => $::locale->text('No results.'));
 765     $_[0]->render($text, { layout => 0 });
 766   } elsif ($count > $max_count) {
 767     my $text = SL::Presenter::EscapedText->new(text => $::locale->text('Too many results (#1 from #2).', $count, $max_count));
 768     $_[0]->render($text, { layout => 0 });
 769   } else {
 770     my $multi_items = $_[0]->multi_items_models->get;
 771     $_[0]->render('order/tabs/_multi_items_result', { layout => 0 },
 772                   multi_items => $multi_items);
 773   }
 774 }
 775
 776 # add item rows for multiple items at once
 777 sub action_add_multi_items {
 778   my ($self) = @_;
 779
 780   my @form_attr = grep { $_->{qty_as_number} } @{ $::form->{add_multi_items} };
 781   return $self->js->render() unless scalar @form_attr;
 782
 783   my @items;
 784   foreach my $attr (@form_attr) {
 785     my $item = new_item($self->order, $attr);
 786     push @items, $item;
 787     if ( $item->part->is_assortment ) {
 788       foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 789         my $attr = { parts_id => $assortment_item->parts_id,
 790                      qty      => $assortment_item->qty * $item->qty, # TODO $form_attr->{unit}
 791                      unit     => $assortment_item->unit,
 792                      description => $assortment_item->part->description,
 793                    };
 794         my $item = new_item($self->order, $attr);
 795
 796         # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 797         $item->discount(1) unless $assortment_item->charge;
 798         push @items, $item;
 799       }
 800     }
 801   }
 802   $self->order->add_items(@items);
 803
 804   $self->recalc();
 805
 806   foreach my $item (@items) {
 807     my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 808     my $row_as_html = $self->p->render('order/tabs/_row',
 809                                        ITEM              => $item,
 810                                        ID                => $item_id,
 811                                        TYPE              => $self->type,
 812                                        ALL_PRICE_FACTORS => $self->all_price_factors
 813     );
 814
 815     $self->js->append('#row_table_id', $row_as_html);
 816   }
 817
 818   $self->js
 819     ->run('kivi.Order.close_multi_items_dialog')
 820     ->run('kivi.Order.init_row_handlers')
 821     ->run('kivi.Order.row_table_scroll_down')
 822     ->run('kivi.Order.renumber_positions')
 823     ->focus('#add_item_parts_id_name');
 824
 825   $self->js_redisplay_amounts_and_taxes;
 826   $self->js->render();
 827 }
 828
 829 # recalculate all linetotals, amounts and taxes and redisplay them
 830 sub action_recalc_amounts_and_taxes {
 831   my ($self) = @_;
 832
 833   $self->recalc();
 834
 835   $self->js_redisplay_line_values;
 836   $self->js_redisplay_amounts_and_taxes;
 837   $self->js->render();
 838 }
 839
 840 # redisplay item rows if they are sorted by an attribute
 841 sub action_reorder_items {
 842   my ($self) = @_;
 843
 844   my %sort_keys = (
 845     partnumber  => sub { $_[0]->part->partnumber },
 846     description => sub { $_[0]->description },
 847     qty         => sub { $_[0]->qty },
 848     sellprice   => sub { $_[0]->sellprice },
 849     discount    => sub { $_[0]->discount },
 850   );
 851
 852   my $method = $sort_keys{$::form->{order_by}};
 853   my @to_sort = map { { old_pos => $_->position, order_by => $method->($_) } } @{ $self->order->items_sorted };
 854   if ($::form->{sort_dir}) {
 855     @to_sort = sort { $a->{order_by} cmp $b->{order_by} } @to_sort;
 856   } else {
 857     @to_sort = sort { $b->{order_by} cmp $a->{order_by} } @to_sort;
 858   }
 859   $self->js
 860     ->run('kivi.Order.redisplay_items', \@to_sort)
 861     ->render;
 862 }
 863
 864 # show the popup to choose a price/discount source
 865 sub action_price_popup {
 866   my ($self) = @_;
 867
 868   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 869   my $item = $self->order->items_sorted->[$idx];
 870
 871   $self->render_price_dialog($item);
 872 }
 873
 874 # get the longdescription for an item if the dialog to enter/change the
 875 # longdescription was opened and the longdescription is empty
 876 #
 877 # If this item is new, get the longdescription from Part.
 878 # Otherwise get it from OrderItem.
 879 sub action_get_item_longdescription {
 880   my $longdescription;
 881
 882   if ($::form->{item_id}) {
 883     $longdescription = SL::DB::OrderItem->new(id => $::form->{item_id})->load->longdescription;
 884   } elsif ($::form->{parts_id}) {
 885     $longdescription = SL::DB::Part->new(id => $::form->{parts_id})->load->notes;
 886   }
 887   $_[0]->render(\ $longdescription, { type => 'text' });
 888 }
 889
 890 # load the second row for one or more items
 891 #
 892 # This action gets the html code for all items second rows by rendering a template for
 893 # the second row and sets the html code via client js.
 894 sub action_load_second_rows {
 895   my ($self) = @_;
 896
 897   $self->recalc() if $self->order->is_sales; # for margin calculation
 898
 899   foreach my $item_id (@{ $::form->{item_ids} }) {
 900     my $idx  = first_index { $_ eq $item_id } @{ $::form->{orderitem_ids} };
 901     my $item = $self->order->items_sorted->[$idx];
 902
 903     $self->js_load_second_row($item, $item_id, 0);
 904   }
 905
 906   $self->js->run('kivi.Order.init_row_handlers') if $self->order->is_sales; # for lastcosts change-callback
 907
 908   $self->js->render();
 909 }
 910
 911 sub js_load_second_row {
 912   my ($self, $item, $item_id, $do_parse) = @_;
 913
 914   if ($do_parse) {
 915     # Parse values from form (they are formated while rendering (template)).
 916     # Workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
 917     # This parsing is not necessary at all, if we assure that the second row/cvars are only loaded once.
 918     foreach my $var (@{ $item->cvars_by_config }) {
 919       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
 920     }
 921     $item->parse_custom_variable_values;
 922   }
 923
 924   my $row_as_html = $self->p->render('order/tabs/_second_row', ITEM => $item, TYPE => $self->type);
 925
 926   $self->js
 927     ->html('.row_entry:has(#item_' . $item_id . ') [name = "second_row"]', $row_as_html)
 928     ->data('.row_entry:has(#item_' . $item_id . ') [name = "second_row"]', 'loaded', 1);
 929 }
 930
 931 sub js_redisplay_line_values {
 932   my ($self) = @_;
 933
 934   my $is_sales = $self->order->is_sales;
 935
 936   # sales orders with margins
 937   my @data;
 938   if ($is_sales) {
 939     @data = map {
 940       [
 941        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
 942        $::form->format_amount(\%::myconfig, $_->{marge_total},   2, 0),
 943        $::form->format_amount(\%::myconfig, $_->{marge_percent}, 2, 0),
 944       ]} @{ $self->order->items_sorted };
 945   } else {
 946     @data = map {
 947       [
 948        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
 949       ]} @{ $self->order->items_sorted };
 950   }
 951
 952   $self->js
 953     ->run('kivi.Order.redisplay_line_values', $is_sales, \@data);
 954 }
 955
 956 sub js_redisplay_amounts_and_taxes {
 957   my ($self) = @_;
 958
 959   if (scalar @{ $self->{taxes} }) {
 960     $self->js->show('#taxincluded_row_id');
 961   } else {
 962     $self->js->hide('#taxincluded_row_id');
 963   }
 964
 965   if ($self->order->taxincluded) {
 966     $self->js->hide('#subtotal_row_id');
 967   } else {
 968     $self->js->show('#subtotal_row_id');
 969   }
 970
 971   if ($self->order->is_sales) {
 972     my $is_neg = $self->order->marge_total < 0;
 973     $self->js
 974       ->html('#marge_total_id',   $::form->format_amount(\%::myconfig, $self->order->marge_total,   2))
 975       ->html('#marge_percent_id', $::form->format_amount(\%::myconfig, $self->order->marge_percent, 2))
 976       ->action_if( $is_neg, 'addClass',    '#marge_total_id',        'plus0')
 977       ->action_if( $is_neg, 'addClass',    '#marge_percent_id',      'plus0')
 978       ->action_if( $is_neg, 'addClass',    '#marge_percent_sign_id', 'plus0')
 979       ->action_if(!$is_neg, 'removeClass', '#marge_total_id',        'plus0')
 980       ->action_if(!$is_neg, 'removeClass', '#marge_percent_id',      'plus0')
 981       ->action_if(!$is_neg, 'removeClass', '#marge_percent_sign_id', 'plus0');
 982   }
 983
 984   $self->js
 985     ->html('#netamount_id', $::form->format_amount(\%::myconfig, $self->order->netamount, -2))
 986     ->html('#amount_id',    $::form->format_amount(\%::myconfig, $self->order->amount,    -2))
 987     ->remove('.tax_row')
 988     ->insertBefore($self->build_tax_rows, '#amount_row_id');
 989 }
 990
 991 #
 992 # helpers
 993 #
 994
 995 sub init_valid_types {
 996   [ sales_order_type(), purchase_order_type(), sales_quotation_type(), request_quotation_type() ];
 997 }
 998
 999 sub init_type {
1000   my ($self) = @_;
1001
1002   if (none { $::form->{type} eq $_ } @{$self->valid_types}) {
1003     die "Not a valid type for order";
1004   }
1005
1006   $self->type($::form->{type});
1007 }
1008
1009 sub init_cv {
1010   my ($self) = @_;
1011
1012   my $cv = (any { $self->type eq $_ } (sales_order_type(),    sales_quotation_type()))   ? 'customer'
1013          : (any { $self->type eq $_ } (purchase_order_type(), request_quotation_type())) ? 'vendor'
1014          : die "Not a valid type for order";
1015
1016   return $cv;
1017 }
1018
1019 sub init_p {
1020   SL::Presenter->get;
1021 }
1022
1023 sub init_order {
1024   $_[0]->make_order;
1025 }
1026
1027 # model used to filter/display the parts in the multi-items dialog
1028 sub init_multi_items_models {
1029   SL::Controller::Helper::GetModels->new(
1030     controller     => $_[0],
1031     model          => 'Part',
1032     with_objects   => [ qw(unit_obj) ],
1033     disable_plugin => 'paginated',
1034     source         => $::form->{multi_items},
1035     sorted         => {
1036       _default    => {
1037         by  => 'partnumber',
1038         dir => 1,
1039       },
1040       partnumber  => t8('Partnumber'),
1041       description => t8('Description')}
1042   );
1043 }
1044
1045 sub init_all_price_factors {
1046   SL::DB::Manager::PriceFactor->get_all;
1047 }
1048
1049 sub check_auth {
1050   my ($self) = @_;
1051
1052   my $right_for = { map { $_ => $_.'_edit' } @{$self->valid_types} };
1053
1054   my $right   = $right_for->{ $self->type };
1055   $right    ||= 'DOES_NOT_EXIST';
1056
1057   $::auth->assert($right);
1058 }
1059
1060 # build the selection box for contacts
1061 #
1062 # Needed, if customer/vendor changed.
1063 sub build_contact_select {
1064   my ($self) = @_;
1065
1066   select_tag('order.cp_id', [ $self->order->{$self->cv}->contacts ],
1067     value_key  => 'cp_id',
1068     title_key  => 'full_name_dep',
1069     default    => $self->order->cp_id,
1070     with_empty => 1,
1071     style      => 'width: 300px',
1072   );
1073 }
1074
1075 # build the selection box for shiptos
1076 #
1077 # Needed, if customer/vendor changed.
1078 sub build_shipto_select {
1079   my ($self) = @_;
1080
1081   select_tag('order.shipto_id', [ $self->order->{$self->cv}->shipto ],
1082     value_key  => 'shipto_id',
1083     title_key  => 'displayable_id',
1084     default    => $self->order->shipto_id,
1085     with_empty => 1,
1086     style      => 'width: 300px',
1087   );
1088 }
1089
1090 # render the info line for business
1091 #
1092 # Needed, if customer/vendor changed.
1093 sub build_business_info_row
1094 {
1095   $_[0]->p->render('order/tabs/_business_info_row', SELF => $_[0]);
1096 }
1097
1098 # build the rows for displaying taxes
1099 #
1100 # Called if amounts where recalculated and redisplayed.
1101 sub build_tax_rows {
1102   my ($self) = @_;
1103
1104   my $rows_as_html;
1105   foreach my $tax (sort { $a->{tax}->rate cmp $b->{tax}->rate } @{ $self->{taxes} }) {
1106     $rows_as_html .= $self->p->render('order/tabs/_tax_row', TAX => $tax, TAXINCLUDED => $self->order->taxincluded);
1107   }
1108   return $rows_as_html;
1109 }
1110
1111
1112 sub render_price_dialog {
1113   my ($self, $record_item) = @_;
1114
1115   my $price_source = SL::PriceSource->new(record_item => $record_item, record => $self->order);
1116
1117   $self->js
1118     ->run(
1119       'kivi.io.price_chooser_dialog',
1120       t8('Available Prices'),
1121       $self->render('order/tabs/_price_sources_dialog', { output => 0 }, price_source => $price_source)
1122     )
1123     ->reinit_widgets;
1124
1125 #   if (@errors) {
1126 #     $self->js->text('#dialog_flash_error_content', join ' ', @errors);
1127 #     $self->js->show('#dialog_flash_error');
1128 #   }
1129
1130   $self->js->render;
1131 }
1132
1133 sub load_order {
1134   my ($self) = @_;
1135
1136   return if !$::form->{id};
1137
1138   $self->order(SL::DB::Order->new(id => $::form->{id})->load);
1139 }
1140
1141 # load or create a new order object
1142 #
1143 # And assign changes from the form to this object.
1144 # If the order is loaded from db, check if items are deleted in the form,
1145 # remove them form the object and collect them for removing from db on saving.
1146 # Then create/update items from form (via make_item) and add them.
1147 sub make_order {
1148   my ($self) = @_;
1149
1150   # add_items adds items to an order with no items for saving, but they cannot
1151   # be retrieved via items until the order is saved. Adding empty items to new
1152   # order here solves this problem.
1153   my $order;
1154   $order   = SL::DB::Manager::Order->find_by(id => $::form->{id}) if $::form->{id};
1155   $order ||= SL::DB::Order->new(orderitems => [],
1156                                 quotation  => (any { $self->type eq $_ } (sales_quotation_type(), request_quotation_type())));
1157
1158   my $cv_id_method = $self->cv . '_id';
1159   if (!$::form->{id} && $::form->{$cv_id_method}) {
1160     $order->$cv_id_method($::form->{$cv_id_method});
1161     setup_order_from_cv($order);
1162   }
1163
1164   my $form_orderitems               = delete $::form->{order}->{orderitems};
1165   my $form_periodic_invoices_config = delete $::form->{order}->{periodic_invoices_config};
1166
1167   $order->assign_attributes(%{$::form->{order}});
1168
1169   my $periodic_invoices_config = make_periodic_invoices_config_from_yaml($form_periodic_invoices_config);
1170   $order->periodic_invoices_config($periodic_invoices_config) if $periodic_invoices_config;
1171
1172   # remove deleted items
1173   $self->item_ids_to_delete([]);
1174   foreach my $idx (reverse 0..$#{$order->orderitems}) {
1175     my $item = $order->orderitems->[$idx];
1176     if (none { $item->id == $_->{id} } @{$form_orderitems}) {
1177       splice @{$order->orderitems}, $idx, 1;
1178       push @{$self->item_ids_to_delete}, $item->id;
1179     }
1180   }
1181
1182   my @items;
1183   my $pos = 1;
1184   foreach my $form_attr (@{$form_orderitems}) {
1185     my $item = make_item($order, $form_attr);
1186     $item->position($pos);
1187     push @items, $item;
1188     $pos++;
1189   }
1190   $order->add_items(grep {!$_->id} @items);
1191
1192   return $order;
1193 }
1194
1195 # create or update items from form
1196 #
1197 # Make item objects from form values. For items already existing read from db.
1198 # Create a new item else. And assign attributes.
1199 sub make_item {
1200   my ($record, $attr) = @_;
1201
1202   my $item;
1203   $item = first { $_->id == $attr->{id} } @{$record->items} if $attr->{id};
1204
1205   my $is_new = !$item;
1206
1207   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1208   # they cannot be retrieved via custom_variables until the order/orderitem is
1209   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1210   $item ||= SL::DB::OrderItem->new(custom_variables => []);
1211
1212   $item->assign_attributes(%$attr);
1213   $item->longdescription($item->part->notes)                     if $is_new && !defined $attr->{longdescription};
1214   $item->project_id($record->globalproject_id)                   if $is_new && !defined $attr->{project_id};
1215   $item->lastcost($record->is_sales ? $item->part->lastcost : 0) if $is_new && !defined $attr->{lastcost_as_number};
1216
1217   return $item;
1218 }
1219
1220 # create a new item
1221 #
1222 # This is used to add one item
1223 sub new_item {
1224   my ($record, $attr) = @_;
1225
1226   my $item = SL::DB::OrderItem->new;
1227
1228   # Remove attributes where the user left or set the inputs empty.
1229   # So these attributes will be undefined and we can distinguish them
1230   # from zero later on.
1231   for (qw(qty_as_number sellprice_as_number discount_as_percent)) {
1232     delete $attr->{$_} if $attr->{$_} eq '';
1233   }
1234
1235   $item->assign_attributes(%$attr);
1236
1237   my $part         = SL::DB::Part->new(id => $attr->{parts_id})->load;
1238   my $price_source = SL::PriceSource->new(record_item => $item, record => $record);
1239
1240   $item->unit($part->unit) if !$item->unit;
1241
1242   my $price_src;
1243   if ( $part->is_assortment ) {
1244     # add assortment items with price 0, as the components carry the price
1245     $price_src = $price_source->price_from_source("");
1246     $price_src->price(0);
1247   } elsif (defined $item->sellprice) {
1248     $price_src = $price_source->price_from_source("");
1249     $price_src->price($item->sellprice);
1250   } else {
1251     $price_src = $price_source->best_price
1252            ? $price_source->best_price
1253            : $price_source->price_from_source("");
1254     $price_src->price(0) if !$price_source->best_price;
1255   }
1256
1257   my $discount_src;
1258   if (defined $item->discount) {
1259     $discount_src = $price_source->discount_from_source("");
1260     $discount_src->discount($item->discount);
1261   } else {
1262     $discount_src = $price_source->best_discount
1263                   ? $price_source->best_discount
1264                   : $price_source->discount_from_source("");
1265     $discount_src->discount(0) if !$price_source->best_discount;
1266   }
1267
1268   my %new_attr;
1269   $new_attr{part}                   = $part;
1270   $new_attr{description}            = $part->description     if ! $item->description;
1271   $new_attr{qty}                    = 1.0                    if ! $item->qty;
1272   $new_attr{price_factor_id}        = $part->price_factor_id if ! $item->price_factor_id;
1273   $new_attr{sellprice}              = $price_src->price;
1274   $new_attr{discount}               = $discount_src->discount;
1275   $new_attr{active_price_source}    = $price_src;
1276   $new_attr{active_discount_source} = $discount_src;
1277   $new_attr{longdescription}        = $part->notes           if ! defined $attr->{longdescription};
1278   $new_attr{project_id}             = $record->globalproject_id;
1279   $new_attr{lastcost}               = $record->is_sales ? $part->lastcost : 0;
1280
1281   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1282   # they cannot be retrieved via custom_variables until the order/orderitem is
1283   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1284   $new_attr{custom_variables} = [];
1285
1286   $item->assign_attributes(%new_attr);
1287
1288   return $item;
1289 }
1290
1291 sub setup_order_from_cv {
1292   my ($order) = @_;
1293
1294   $order->$_($order->customervendor->$_) for (qw(taxzone_id payment_id delivery_term_id));
1295
1296   $order->intnotes($order->customervendor->notes);
1297
1298   if ($order->is_sales) {
1299     $order->salesman_id($order->customer->salesman_id || SL::DB::Manager::Employee->current->id);
1300     $order->taxincluded(defined($order->customer->taxincluded_checked)
1301                         ? $order->customer->taxincluded_checked
1302                         : $::myconfig{taxincluded_checked});
1303   }
1304
1305 }
1306
1307 # recalculate prices and taxes
1308 #
1309 # Using the PriceTaxCalculator. Store linetotals in the item objects.
1310 sub recalc {
1311   my ($self) = @_;
1312
1313   # bb: todo: currency later
1314   $self->order->currency_id($::instance_conf->get_currency_id());
1315
1316   my %pat = $self->order->calculate_prices_and_taxes();
1317   $self->{taxes} = [];
1318   foreach my $tax_chart_id (keys %{ $pat{taxes} }) {
1319     my $tax = SL::DB::Manager::Tax->find_by(chart_id => $tax_chart_id);
1320
1321     my @amount_keys = grep { $pat{amounts}->{$_}->{tax_id} == $tax->id } keys %{ $pat{amounts} };
1322     push(@{ $self->{taxes} }, { amount    => $pat{taxes}->{$tax_chart_id},
1323                                 netamount => $pat{amounts}->{$amount_keys[0]}->{amount},
1324                                 tax       => $tax });
1325   }
1326
1327   pairwise { $a->{linetotal} = $b->{linetotal} } @{$self->order->items}, @{$pat{items}};
1328 }
1329
1330 # get data for saving, printing, ..., that is not changed in the form
1331 #
1332 # Only cvars for now.
1333 sub get_unalterable_data {
1334   my ($self) = @_;
1335
1336   foreach my $item (@{ $self->order->items }) {
1337     # autovivify all cvars that are not in the form (cvars_by_config can do it).
1338     # workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
1339     foreach my $var (@{ $item->cvars_by_config }) {
1340       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
1341     }
1342     $item->parse_custom_variable_values;
1343   }
1344 }
1345
1346 # delete the order
1347 #
1348 # And remove related files in the spool directory
1349 sub delete {
1350   my ($self) = @_;
1351
1352   my $errors = [];
1353   my $db     = $self->order->db;
1354
1355   $db->with_transaction(
1356     sub {
1357       my @spoolfiles = grep { $_ } map { $_->spoolfile } @{ SL::DB::Manager::Status->get_all(where => [ trans_id => $self->order->id ]) };
1358       $self->order->delete;
1359       my $spool = $::lx_office_conf{paths}->{spool};
1360       unlink map { "$spool/$_" } @spoolfiles if $spool;
1361
1362       1;
1363   }) || push(@{$errors}, $db->error);
1364
1365   return $errors;
1366 }
1367
1368 # save the order
1369 #
1370 # And delete items that are deleted in the form.
1371 sub save {
1372   my ($self) = @_;
1373
1374   my $errors = [];
1375   my $db     = $self->order->db;
1376
1377   $db->with_transaction(sub {
1378     SL::DB::OrderItem->new(id => $_)->delete for @{$self->item_ids_to_delete};
1379     $self->order->save(cascade => 1);
1380
1381     # link records
1382     if ($::form->{converted_from_oe_id}) {
1383       SL::DB::Order->new(id => $::form->{converted_from_oe_id})->load->link_to_record($self->order);
1384
1385       if (scalar @{ $::form->{converted_from_orderitems_ids} || [] }) {
1386         my $idx = 0;
1387         foreach (@{ $self->order->items_sorted }) {
1388           my $from_id = $::form->{converted_from_orderitems_ids}->[$idx];
1389           next if !$from_id;
1390           SL::DB::RecordLink->new(from_table => 'orderitems',
1391                                   from_id    => $from_id,
1392                                   to_table   => 'orderitems',
1393                                   to_id      => $_->id
1394           )->save;
1395           $idx++;
1396         }
1397       }
1398     }
1399     1;
1400   }) || push(@{$errors}, $db->error);
1401
1402   return $errors;
1403 }
1404
1405 sub workflow_sales_or_purchase_order {
1406   my ($self) = @_;
1407
1408   my $destination_type = $::form->{type} eq sales_quotation_type()   ? sales_order_type()
1409                        : $::form->{type} eq request_quotation_type() ? purchase_order_type()
1410                        : $::form->{type} eq purchase_order_type()    ? sales_order_type()
1411                        : $::form->{type} eq sales_order_type()       ? purchase_order_type()
1412                        : '';
1413
1414   $self->order(SL::DB::Order->new_from($self->order, destination_type => $destination_type));
1415   $self->{converted_from_oe_id} = delete $::form->{id};
1416
1417   # set item ids to new fake id, to identify them as new items
1418   foreach my $item (@{$self->order->items_sorted}) {
1419     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1420   }
1421
1422   # change form type
1423   $::form->{type} = $destination_type;
1424   $self->type($self->init_type);
1425   $self->cv  ($self->init_cv);
1426   $self->check_auth;
1427
1428   $self->recalc();
1429   $self->get_unalterable_data();
1430   $self->pre_render();
1431
1432   # trigger rendering values for second row/longdescription as hidden,
1433   # because they are loaded only on demand. So we need to keep the values
1434   # from the source.
1435   $_->{render_second_row}      = 1 for @{ $self->order->items_sorted };
1436   $_->{render_longdescription} = 1 for @{ $self->order->items_sorted };
1437
1438   $self->render(
1439     'order/form',
1440     title => $self->get_title_for('edit'),
1441     %{$self->{template_args}}
1442   );
1443 }
1444
1445
1446 sub pre_render {
1447   my ($self) = @_;
1448
1449   $self->{all_taxzones}             = SL::DB::Manager::TaxZone->get_all_sorted();
1450   $self->{all_departments}          = SL::DB::Manager::Department->get_all_sorted();
1451   $self->{all_employees}            = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->employee_id,
1452                                                                                             deleted => 0 ] ],
1453                                                                          sort_by => 'name');
1454   $self->{all_salesmen}             = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->salesman_id,
1455                                                                                             deleted => 0 ] ],
1456                                                                          sort_by => 'name');
1457   $self->{all_payment_terms}        = SL::DB::Manager::PaymentTerm->get_all_sorted(where => [ or => [ id => $self->order->payment_id,
1458                                                                                                       obsolete => 0 ] ]);
1459   $self->{all_delivery_terms}       = SL::DB::Manager::DeliveryTerm->get_all_sorted();
1460   $self->{current_employee_id}      = SL::DB::Manager::Employee->current->id;
1461   $self->{periodic_invoices_status} = $self->get_periodic_invoices_status($self->order->periodic_invoices_config);
1462   $self->{order_probabilities}      = [ map { { title => ($_ * 10) . '%', id => $_ * 10 } } (0..10) ];
1463
1464   my $print_form = Form->new('');
1465   $print_form->{type}      = $self->type;
1466   $print_form->{printers}  = SL::DB::Manager::Printer->get_all_sorted;
1467   $print_form->{languages} = SL::DB::Manager::Language->get_all_sorted;
1468   $self->{print_options}   = SL::Helper::PrintOptions->get_print_options(
1469     form => $print_form,
1470     options => {dialog_name_prefix => 'print_options.',
1471                 show_headers       => 1,
1472                 no_queue           => 1,
1473                 no_postscript      => 1,
1474                 no_opendocument    => 0,
1475                 no_html            => 1},
1476   );
1477
1478   foreach my $item (@{$self->order->orderitems}) {
1479     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
1480     $item->active_price_source(   $price_source->price_from_source(   $item->active_price_source   ));
1481     $item->active_discount_source($price_source->discount_from_source($item->active_discount_source));
1482   }
1483
1484   if (any { $self->type eq $_ } (sales_order_type(), purchase_order_type())) {
1485     # calculate shipped qtys here to prevent calling calculate for every item via the items method
1486     SL::Helper::ShippedQty->new->calculate($self->order)->write_to_objects;
1487   }
1488
1489   if ($self->order->number && $::instance_conf->get_webdav) {
1490     my $webdav = SL::Webdav->new(
1491       type     => $self->type,
1492       number   => $self->order->number,
1493     );
1494     my @all_objects = $webdav->get_all_objects;
1495     @{ $self->{template_args}->{WEBDAV} } = map { { name => $_->filename,
1496                                                     type => t8('File'),
1497                                                     link => File::Spec->catfile($_->full_filedescriptor),
1498                                                 } } @all_objects;
1499   }
1500
1501   $::request->{layout}->use_javascript("${_}.js") for qw(kivi.SalesPurchase kivi.Order kivi.File ckeditor/ckeditor ckeditor/adapters/jquery edit_periodic_invoices_config calculate_qty);
1502   $self->setup_edit_action_bar;
1503 }
1504
1505 sub setup_edit_action_bar {
1506   my ($self, %params) = @_;
1507
1508   my $deletion_allowed = (any { $self->type eq $_ } (sales_quotation_type(), request_quotation_type()))
1509                       || (($self->type eq sales_order_type())    && $::instance_conf->get_sales_order_show_delete)
1510                       || (($self->type eq purchase_order_type()) && $::instance_conf->get_purchase_order_show_delete);
1511
1512   for my $bar ($::request->layout->get('actionbar')) {
1513     $bar->add(
1514       combobox => [
1515         action => [
1516           t8('Save'),
1517           call      => [ 'kivi.Order.save', 'save', $::instance_conf->get_order_warn_duplicate_parts,
1518                                                     $::instance_conf->get_order_warn_no_deliverydate,
1519                                                                                                       ],
1520           checks    => [ 'kivi.Order.check_save_active_periodic_invoices' ],
1521         ],
1522         action => [
1523           t8('Save as new'),
1524           call      => [ 'kivi.Order.save', 'save_as_new', $::instance_conf->get_order_warn_duplicate_parts ],
1525           checks    => [ 'kivi.Order.check_save_active_periodic_invoices' ],
1526           disabled  => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1527         ],
1528       ], # end of combobox "Save"
1529
1530       combobox => [
1531         action => [
1532           t8('Workflow'),
1533         ],
1534         action => [
1535           t8('Sales Order'),
1536           submit   => [ '#order_form', { action => "Order/sales_order" } ],
1537           only_if  => (any { $self->type eq $_ } (sales_quotation_type(), purchase_order_type())),
1538           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1539         ],
1540         action => [
1541           t8('Purchase Order'),
1542           submit   => [ '#order_form', { action => "Order/purchase_order" } ],
1543           only_if  => (any { $self->type eq $_ } (sales_order_type(), request_quotation_type())),
1544           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1545         ],
1546         action => [
1547           t8('Save and Delivery Order'),
1548           call      => [ 'kivi.Order.save', 'save_and_delivery_order', $::instance_conf->get_order_warn_duplicate_parts,
1549                                                                        $::instance_conf->get_order_warn_no_deliverydate,
1550                                                                                                                         ],
1551           checks    => [ 'kivi.Order.check_save_active_periodic_invoices' ],
1552           only_if   => (any { $self->type eq $_ } (sales_order_type(), purchase_order_type()))
1553         ],
1554         action => [
1555           t8('Save and Invoice'),
1556           call      => [ 'kivi.Order.save', 'save_and_invoice', $::instance_conf->get_order_warn_duplicate_parts ],
1557           checks    => [ 'kivi.Order.check_save_active_periodic_invoices' ],
1558         ],
1559       ], # end of combobox "Workflow"
1560
1561       combobox => [
1562         action => [
1563           t8('Export'),
1564         ],
1565         action => [
1566           t8('Print'),
1567           call => [ 'kivi.Order.show_print_options' ],
1568         ],
1569         action => [
1570           t8('E-mail'),
1571           call => [ 'kivi.Order.email' ],
1572         ],
1573         action => [
1574           t8('Download attachments of all parts'),
1575           call     => [ 'kivi.File.downloadOrderitemsFiles', $::form->{type}, $::form->{id} ],
1576           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1577           only_if  => $::instance_conf->get_doc_storage,
1578         ],
1579       ], # end of combobox "Export"
1580
1581       action => [
1582         t8('Delete'),
1583         call     => [ 'kivi.Order.delete_order' ],
1584         confirm  => $::locale->text('Do you really want to delete this object?'),
1585         disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1586         only_if  => $deletion_allowed,
1587       ],
1588     );
1589   }
1590 }
1591
1592 sub generate_pdf {
1593   my ($order, $pdf_ref, $params) = @_;
1594
1595   my @errors = ();
1596
1597   my $print_form = Form->new('');
1598   $print_form->{type}        = $order->type;
1599   $print_form->{formname}    = $params->{formname} || $order->type;
1600   $print_form->{format}      = $params->{format}   || 'pdf';
1601   $print_form->{media}       = $params->{media}    || 'file';
1602   $print_form->{groupitems}  = $params->{groupitems};
1603   $print_form->{media}       = 'file'                             if $print_form->{media} eq 'screen';
1604
1605   $order->language($params->{language});
1606   $order->flatten_to_form($print_form, format_amounts => 1);
1607
1608   my $template_ext;
1609   my $template_type;
1610   if ($print_form->{format} =~ /(opendocument|oasis)/i) {
1611     $template_ext  = 'odt';
1612     $template_type = 'OpenDocument';
1613   }
1614
1615   # search for the template
1616   my ($template_file, @template_files) = SL::Helper::CreatePDF->find_template(
1617     name        => $print_form->{formname},
1618     extension   => $template_ext,
1619     email       => $print_form->{media} eq 'email',
1620     language    => $params->{language},
1621     printer_id  => $print_form->{printer_id},  # todo
1622   );
1623
1624   if (!defined $template_file) {
1625     push @errors, $::locale->text('Cannot find matching template for this print request. Please contact your template maintainer. I tried these: #1.', join ', ', map { "'$_'"} @template_files);
1626   }
1627
1628   return @errors if scalar @errors;
1629
1630   $print_form->throw_on_error(sub {
1631     eval {
1632       $print_form->prepare_for_printing;
1633
1634       $$pdf_ref = SL::Helper::CreatePDF->create_pdf(
1635         format        => $print_form->{format},
1636         template_type => $template_type,
1637         template      => $template_file,
1638         variables     => $print_form,
1639         variable_content_types => {
1640           longdescription => 'html',
1641           partnotes       => 'html',
1642           notes           => 'html',
1643         },
1644       );
1645       1;
1646     } || push @errors, ref($EVAL_ERROR) eq 'SL::X::FormError' ? $EVAL_ERROR->getMessage : $EVAL_ERROR;
1647   });
1648
1649   return @errors;
1650 }
1651
1652 sub get_files_for_email_dialog {
1653   my ($self) = @_;
1654
1655   my %files = map { ($_ => []) } qw(versions files vc_files part_files);
1656
1657   return %files if !$::instance_conf->get_doc_storage;
1658
1659   if ($self->order->id) {
1660     $files{versions} = [ SL::File->get_all_versions(object_id => $self->order->id,              object_type => $self->order->type, file_type => 'document') ];
1661     $files{files}    = [ SL::File->get_all(         object_id => $self->order->id,              object_type => $self->order->type, file_type => 'attachment') ];
1662     $files{vc_files} = [ SL::File->get_all(         object_id => $self->order->{$self->cv}->id, object_type => $self->cv,          file_type => 'attachment') ];
1663   }
1664
1665   my @parts =
1666     uniq_by { $_->{id} }
1667     map {
1668       +{ id         => $_->part->id,
1669          partnumber => $_->part->partnumber }
1670     } @{$self->order->items_sorted};
1671
1672   foreach my $part (@parts) {
1673     my @pfiles = SL::File->get_all(object_id => $part->{id}, object_type => 'part');
1674     push @{ $files{part_files} }, map { +{ %{ $_ }, partnumber => $part->{partnumber} } } @pfiles;
1675   }
1676
1677   foreach my $key (keys %files) {
1678     $files{$key} = [ sort_by { lc $_->{db_file}->{file_name} } @{ $files{$key} } ];
1679   }
1680
1681   return %files;
1682 }
1683
1684 sub make_periodic_invoices_config_from_yaml {
1685   my ($yaml_config) = @_;
1686
1687   return if !$yaml_config;
1688   my $attr = YAML::Load($yaml_config);
1689   return if 'HASH' ne ref $attr;
1690   return SL::DB::PeriodicInvoicesConfig->new(%$attr);
1691 }
1692
1693
1694 sub get_periodic_invoices_status {
1695   my ($self, $config) = @_;
1696
1697   return                      if $self->type ne sales_order_type();
1698   return t8('not configured') if !$config;
1699
1700   my $active = ('HASH' eq ref $config)                           ? $config->{active}
1701              : ('SL::DB::PeriodicInvoicesConfig' eq ref $config) ? $config->active
1702              :                                                     die "Cannot get status of periodic invoices config";
1703
1704   return $active ? t8('active') : t8('inactive');
1705 }
1706
1707 sub get_title_for {
1708   my ($self, $action) = @_;
1709
1710   return '' if none { lc($action)} qw(add edit);
1711
1712   # for locales:
1713   # $::locale->text("Add Sales Order");
1714   # $::locale->text("Add Purchase Order");
1715   # $::locale->text("Add Quotation");
1716   # $::locale->text("Add Request for Quotation");
1717   # $::locale->text("Edit Sales Order");
1718   # $::locale->text("Edit Purchase Order");
1719   # $::locale->text("Edit Quotation");
1720   # $::locale->text("Edit Request for Quotation");
1721
1722   $action = ucfirst(lc($action));
1723   return $self->type eq sales_order_type()       ? $::locale->text("$action Sales Order")
1724        : $self->type eq purchase_order_type()    ? $::locale->text("$action Purchase Order")
1725        : $self->type eq sales_quotation_type()   ? $::locale->text("$action Quotation")
1726        : $self->type eq request_quotation_type() ? $::locale->text("$action Request for Quotation")
1727        : '';
1728 }
1729
1730 sub sales_order_type {
1731   'sales_order';
1732 }
1733
1734 sub purchase_order_type {
1735   'purchase_order';
1736 }
1737
1738 sub sales_quotation_type {
1739   'sales_quotation';
1740 }
1741
1742 sub request_quotation_type {
1743   'request_quotation';
1744 }
1745
1746 sub nr_key {
1747   return $_[0]->type eq sales_order_type()       ? 'ordnumber'
1748        : $_[0]->type eq purchase_order_type()    ? 'ordnumber'
1749        : $_[0]->type eq sales_quotation_type()   ? 'quonumber'
1750        : $_[0]->type eq request_quotation_type() ? 'quonumber'
1751        : '';
1752 }
1753
1754 1;
1755
1756 __END__
1757
1758 =encoding utf-8
1759
1760 =head1 NAME
1761
1762 SL::Controller::Order - controller for orders
1763
1764 =head1 SYNOPSIS
1765
1766 This is a new form to enter orders, completely rewritten with the use
1767 of controller and java script techniques.
1768
1769 The aim is to provide the user a better expirience and a faster flow
1770 of work. Also the code should be more readable, more reliable and
1771 better to maintain.
1772
1773 =head2 Key Features
1774
1775 =over 4
1776
1777 =item *
1778
1779 One input row, so that input happens every time at the same place.
1780
1781 =item *
1782
1783 Use of pickers where possible.
1784
1785 =item *
1786
1787 Possibility to enter more than one item at once.
1788
1789 =item *
1790
1791 Save order only on "save" (and "save and delivery order"-workflow). No
1792 hidden save on "print" or "email".
1793
1794 =item *
1795
1796 Item list in a scrollable area, so that the workflow buttons stay at
1797 the bottom.
1798
1799 =item *
1800
1801 Reordering item rows with drag and drop is possible. Sorting item rows is
1802 possible (by partnumber, description, qty, sellprice and discount for now).
1803
1804 =item *
1805
1806 No C<update> is necessary. All entries and calculations are managed
1807 with ajax-calls and the page does only reload on C<save>.
1808
1809 =item *
1810
1811 User can see changes immediately, because of the use of java script
1812 and ajax.
1813
1814 =back
1815
1816 =head1 CODE
1817
1818 =head2 Layout
1819
1820 =over 4
1821
1822 =item * C<SL/Controller/Order.pm>
1823
1824 the controller
1825
1826 =item * C<template/webpages/order/form.html>
1827
1828 main form
1829
1830 =item * C<template/webpages/order/tabs/basic_data.html>
1831
1832 Main tab for basic_data.
1833
1834 This is the only tab here for now. "linked records" and "webdav" tabs are
1835 reused from generic code.
1836
1837 =over 4
1838
1839 =item * C<template/webpages/order/tabs/_business_info_row.html>
1840
1841 For displaying information on business type
1842
1843 =item * C<template/webpages/order/tabs/_item_input.html>
1844
1845 The input line for items
1846
1847 =item * C<template/webpages/order/tabs/_row.html>
1848
1849 One row for already entered items
1850
1851 =item * C<template/webpages/order/tabs/_tax_row.html>
1852
1853 Displaying tax information
1854
1855 =item * C<template/webpages/order/tabs/_multi_items_dialog.html>
1856
1857 Dialog for entering more than one item at once
1858
1859 =item * C<template/webpages/order/tabs/_multi_items_result.html>
1860
1861 Results for the filter in the multi items dialog
1862
1863 =item * C<template/webpages/order/tabs/_price_sources_dialog.html>
1864
1865 Dialog for selecting price and discount sources
1866
1867 =back
1868
1869 =item * C<js/kivi.Order.js>
1870
1871 java script functions
1872
1873 =back
1874
1875 =head1 TODO
1876
1877 =over 4
1878
1879 =item * testing
1880
1881 =item * currency
1882
1883 =item * credit limit
1884
1885 =item * more workflows (quotation, rfq)
1886
1887 =item * price sources: little symbols showing better price / better discount
1888
1889 =item * select units in input row?
1890
1891 =item * custom shipto address
1892
1893 =item * check for direct delivery (workflow sales order -> purchase order)
1894
1895 =item * language / part translations
1896
1897 =item * access rights
1898
1899 =item * display weights
1900
1901 =item * history
1902
1903 =item * mtime check
1904
1905 =item * optional client/user behaviour
1906
1907 (transactions has to be set - department has to be set -
1908  force project if enabled in client config - transport cost reminder)
1909
1910 =back
1911
1912 =head1 KNOWN BUGS AND CAVEATS
1913
1914 =over 4
1915
1916 =item *
1917
1918 Customer discount is not displayed as a valid discount in price source popup
1919 (this might be a bug in price sources)
1920
1921 (I cannot reproduce this (Bernd))
1922
1923 =item *
1924
1925 No indication that <shift>-up/down expands/collapses second row.
1926
1927 =item *
1928
1929 Inline creation of parts is not currently supported
1930
1931 =item *
1932
1933 Table header is not sticky in the scrolling area.
1934
1935 =item *
1936
1937 Sorting does not include C<position>, neither does reordering.
1938
1939 This behavior was implemented intentionally. But we can discuss, which behavior
1940 should be implemented.
1941
1942 =item *
1943
1944 C<show_multi_items_dialog> does not use the currently inserted string for
1945 filtering.
1946
1947 =item *
1948
1949 The language selected in print or email dialog is not saved when the order is saved.
1950
1951 =back
1952
1953 =head1 To discuss / Nice to have
1954
1955 =over 4
1956
1957 =item *
1958
1959 How to expand/collapse second row. Now it can be done clicking the icon or
1960 <shift>-up/down.
1961
1962 =item *
1963
1964 Possibility to change longdescription in input row?
1965
1966 =item *
1967
1968 Possibility to select PriceSources in input row?
1969
1970 =item *
1971
1972 This controller uses a (changed) copy of the template for the PriceSource
1973 dialog. Maybe there could be used one code source.
1974
1975 =item *
1976
1977 Rounding-differences between this controller (PriceTaxCalculator) and the old
1978 form. This is not only a problem here, but also in all parts using the PTC.
1979 There exists a ticket and a patch. This patch should be testet.
1980
1981 =item *
1982
1983 An indicator, if the actual inputs are saved (like in an
1984 editor or on text processing application).
1985
1986 =item *
1987
1988 A warning when leaving the page without saveing unchanged inputs.
1989
1990
1991 =back
1992
1993 =head1 AUTHOR
1994
1995 Bernd Bleßmann E<lt>bernd@kivitendo-premium.deE<gt>
1996
1997 =cut