SL/Controller/Order.pm

   1 package SL::Controller::Order;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use SL::Helper::Flash;
   7 use SL::ClientJS;
   8 use SL::Presenter;
   9 use SL::Locale::String;
  10 use SL::SessionFile::Random;
  11 use SL::PriceSource;
  12 use SL::Form;
  13
  14 use SL::DB::Order;
  15 use SL::DB::Customer;
  16 use SL::DB::Vendor;
  17 use SL::DB::TaxZone;
  18 use SL::DB::Employee;
  19 use SL::DB::Project;
  20 use SL::DB::Default;
  21 use SL::DB::Unit;
  22
  23 use SL::Helper::DateTime;
  24 use SL::Helper::CreatePDF qw(:all);
  25
  26 use List::Util qw(max first);
  27 use List::MoreUtils qw(none pairwise);
  28 use English qw(-no_match_vars);
  29
  30 use Rose::Object::MakeMethods::Generic
  31 (
  32  'scalar --get_set_init' => [ qw(order valid_types type cv js p) ],
  33 );
  34
  35
  36 # safety
  37 __PACKAGE__->run_before('_check_auth');
  38
  39 __PACKAGE__->run_before('_recalc',
  40                         only => [ qw(edit update save save_and_delivery_order create_pdf send_email) ]);
  41
  42 __PACKAGE__->run_before('_get_unalterable_data',
  43                         only => [ qw(save save_and_delivery_order create_pdf send_email) ]);
  44
  45 #
  46 # actions
  47 #
  48
  49 sub action_add {
  50   my ($self) = @_;
  51
  52   $self->order->transdate(DateTime->now_local());
  53
  54   $self->_pre_render();
  55   $self->render(
  56     'order/form',
  57     title => $self->type eq _sales_order_type()    ? $::locale->text('Add Sales Order')
  58            : $self->type eq _purchase_order_type() ? $::locale->text('Add Purchase Order')
  59            : '',
  60     %{$self->{template_args}}
  61   );
  62 }
  63
  64 sub action_edit {
  65   my ($self) = @_;
  66
  67   $self->_pre_render();
  68   $self->render(
  69     'order/form',
  70     title => $self->type eq _sales_order_type()    ? $::locale->text('Edit Sales Order')
  71            : $self->type eq _purchase_order_type() ? $::locale->text('Edit Purchase Order')
  72            : '',
  73     %{$self->{template_args}}
  74   );
  75 }
  76
  77 sub action_update {
  78   my ($self) = @_;
  79
  80   $self->_pre_render();
  81   $self->render(
  82     'order/form',
  83     title => $self->type eq _sales_order_type()    ? $::locale->text('Edit Sales Order')
  84            : $self->type eq _purchase_order_type() ? $::locale->text('Edit Purchase Order')
  85            : '',
  86     %{$self->{template_args}}
  87   );
  88 }
  89
  90 sub action_save {
  91   my ($self) = @_;
  92
  93   my $errors = $self->_save();
  94
  95   if (scalar @{ $errors }) {
  96     $self->js->flash('error', $_) foreach @{ $errors };
  97     return $self->js->render($self);
  98   }
  99
 100   flash_later('info', $::locale->text('The order has been saved'));
 101   my @redirect_params = (
 102     action => 'edit',
 103     type   => $self->type,
 104     id     => $self->order->id,
 105   );
 106
 107   $self->redirect_to(@redirect_params);
 108 }
 109
 110 sub action_create_pdf {
 111   my ($self) = @_;
 112
 113   my $pdf;
 114   my @errors = _create_pdf($self->order, \$pdf);
 115   if (scalar @errors) {
 116     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render($self);
 117   }
 118
 119   my $sfile = SL::SessionFile::Random->new(mode => "w");
 120   $sfile->fh->print($pdf);
 121   $sfile->fh->close;
 122
 123   my $tmp_filename = $sfile->file_name;
 124   my $pdf_filename = t8('Sales Order') . '_' . $self->order->ordnumber . '.pdf';
 125
 126   $self->js
 127     ->run('download_pdf', $tmp_filename, $pdf_filename)
 128     ->flash('info', t8('The PDF has been created'))->render($self);
 129 }
 130
 131 sub action_download_pdf {
 132   my ($self) = @_;
 133
 134   return $self->send_file(
 135     $::form->{tmp_filename},
 136     type => 'application/pdf',
 137     name => $::form->{pdf_filename},
 138   );
 139 }
 140
 141 sub action_show_email_dialog {
 142   my ($self) = @_;
 143
 144   my $cv_method = $self->cv;
 145
 146   if (!$self->order->$cv_method) {
 147     return $self->js->flash('error', t8('Cannot send E-mail without ' . $self->cv))
 148                     ->render($self);
 149   }
 150
 151   $self->{email}->{to}   = $self->order->contact->cp_email if $self->order->contact;
 152   $self->{email}->{to} ||= $self->order->$cv_method->email;
 153   $self->{email}->{cc}   = $self->order->$cv_method->cc;
 154   $self->{email}->{bcc}  = join ', ', grep $_, $self->order->$cv_method->bcc, SL::DB::Default->get->global_bcc;
 155   # Todo: get addresses from shipto, if any
 156
 157   my $form = Form->new;
 158   $form->{ordnumber} = $self->order->ordnumber;
 159   $form->{formname}  = $self->type;
 160   $form->{type}      = $self->type;
 161   $form->{language} = 'de';
 162   $form->{format}   = 'pdf';
 163
 164   $self->{email}->{subject}             = $form->generate_email_subject();
 165   $self->{email}->{attachment_filename} = $form->generate_attachment_filename();
 166   $self->{email}->{message}             = $form->create_email_signature();
 167
 168   my $dialog_html = $self->render('order/tabs/_email_dialog', { output => 0 });
 169   $self->js
 170       ->run('show_email_dialog', $dialog_html)
 171       ->reinit_widgets
 172       ->render($self);
 173 }
 174
 175 # Todo: handling error messages: flash is not displayed in dialog, but in the main form
 176 sub action_send_email {
 177   my ($self) = @_;
 178
 179   my $mail      = Mailer->new;
 180   $mail->{from} = qq|"$::myconfig{name}" <$::myconfig{email}>|;
 181   $mail->{$_}   = $::form->{email}->{$_} for qw(to cc bcc subject message);
 182
 183   my $pdf;
 184   my @errors = _create_pdf($self->order, \$pdf, {media => 'email'});
 185   if (scalar @errors) {
 186     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render($self);
 187   }
 188
 189   $mail->{attachments} = [{ "content" => $pdf,
 190                             "name"    => $::form->{email}->{attachment_filename} }];
 191
 192   if (my $err = $mail->send) {
 193     return $self->js->flash('error', t8('Sending E-mail: ') . $err)
 194                     ->render($self);
 195   }
 196
 197   # internal notes
 198   my $intnotes = $self->order->intnotes;
 199   $intnotes   .= "\n\n" if $self->order->intnotes;
 200   $intnotes   .= t8('[email]')                                                                                        . "\n";
 201   $intnotes   .= t8('Date')       . ": " . $::locale->format_date_object(DateTime->now_local, precision => 'seconds') . "\n";
 202   $intnotes   .= t8('To (email)') . ": " . $mail->{to}                                                                . "\n";
 203   $intnotes   .= t8('Cc')         . ": " . $mail->{cc}                                                                . "\n"    if $mail->{cc};
 204   $intnotes   .= t8('Bcc')        . ": " . $mail->{bcc}                                                               . "\n"    if $mail->{bcc};
 205   $intnotes   .= t8('Subject')    . ": " . $mail->{subject}                                                           . "\n\n";
 206   $intnotes   .= t8('Message')    . ": " . $mail->{message};
 207
 208   $self->js
 209       ->val('#order_intnotes', $intnotes)
 210       ->run('close_email_dialog')
 211       ->render($self);
 212 }
 213
 214 sub action_save_and_delivery_order {
 215   my ($self) = @_;
 216
 217   my $errors = $self->_save();
 218
 219   if (scalar @{ $errors }) {
 220     $self->js->flash('error', $_) foreach @{ $errors };
 221     return $self->js->render($self);
 222   }
 223
 224   my $delivery_order = $self->order->convert_to_delivery_order($self->order);
 225
 226   flash_later('info', $::locale->text('The order has been saved'));
 227   my @redirect_params = (
 228     controller => 'do.pl',
 229     action     => 'edit',
 230     type       => $delivery_order->type,
 231     id         => $delivery_order->id,
 232     vc         => $delivery_order->is_sales ? 'customer' : 'vendor',
 233   );
 234
 235   $self->redirect_to(@redirect_params);
 236 }
 237
 238 sub action_customer_vendor_changed {
 239   my ($self) = @_;
 240
 241   if ($self->cv eq 'customer') {
 242     $self->order->customer(SL::DB::Manager::Customer->find_by_or_create(id => $::form->{cv_id}));
 243
 244   } elsif ($self->cv eq 'vendor') {
 245     $self->order->vendor(SL::DB::Manager::Vendor->find_by_or_create(id => $::form->{cv_id}));
 246   }
 247
 248   if ($self->order->{$self->cv}->contacts && scalar @{ $self->order->{$self->cv}->contacts } > 0) {
 249     $self->js->show('#cp_row');
 250   } else {
 251     $self->js->hide('#cp_row');
 252   }
 253
 254   if ($self->order->{$self->cv}->shipto && scalar @{ $self->order->{$self->cv}->shipto } > 0) {
 255     $self->js->show('#shipto_row');
 256   } else {
 257     $self->js->hide('#shipto_row');
 258   }
 259
 260   $self->js
 261     ->replaceWith('#order_cp_id',     $self->build_contact_select)
 262     ->replaceWith('#order_shipto_id', $self->build_shipto_select)
 263     ->val('#order_taxzone_id', $self->order->{$self->cv}->taxzone_id)
 264     ->focus('#order_' . $self->cv . '_id')
 265     ->render($self);
 266 }
 267
 268 sub action_add_item {
 269   my ($self) = @_;
 270
 271   my $form_attr = $::form->{add_item};
 272
 273   return unless $form_attr->{parts_id};
 274
 275   my $item = SL::DB::OrderItem->new;
 276   $item->assign_attributes(%$form_attr);
 277
 278   my $part        = SL::DB::Part->new(id => $form_attr->{parts_id})->load;
 279   my $cv_method   = $self->cv;
 280   my $cv_discount = $self->order->$cv_method? $self->order->$cv_method->discount : 0.0;
 281
 282   my %new_attr;
 283   $new_attr{part}        = $part;
 284   $new_attr{description} = $part->description if ! $item->description;
 285   $new_attr{qty}         = 1.0                if ! $item->qty;
 286   $new_attr{unit}        = $part->unit;
 287   $new_attr{sellprice}   = $part->sellprice   if ! $item->sellprice;
 288   $new_attr{discount}    = $cv_discount       if ! $item->discount;
 289
 290   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
 291   # they cannot be retrieved via custom_variables until the order/orderitem is
 292   # saved. Adding empty custom_variables to new orderitem here solves this problem.
 293   $new_attr{custom_variables} = [];
 294
 295   $item->assign_attributes(%new_attr);
 296
 297   $self->order->add_items($item);
 298
 299   $self->_recalc();
 300
 301   my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 302   my $row_as_html = $self->p->render('order/tabs/_row', ITEM => $item, ID => $item_id);
 303
 304   $self->js
 305     ->append('#row_table_id', $row_as_html)
 306     ->val('#add_item_parts_id', '')
 307     ->val('#add_item_parts_id_name', '')
 308     ->val('#add_item_description', '')
 309     ->val('#add_item_qty_as_number', '')
 310     ->val('#add_item_sellprice_as_number', '')
 311     ->val('#add_item_discount_as_percent', '')
 312     ->run('row_table_scroll_down')
 313     ->run('row_set_keyboard_events_by_id', $item_id)
 314     ->on('.recalc', 'change', 'recalc_amounts_and_taxes')
 315     ->focus('#add_item_parts_id_name');
 316
 317   $self->_js_redisplay_amounts_and_taxes;
 318   $self->js->render($self);
 319 }
 320
 321 sub action_recalc_amounts_and_taxes {
 322   my ($self) = @_;
 323
 324   $self->_recalc();
 325
 326   $self->_js_redisplay_linetotals;
 327   $self->_js_redisplay_amounts_and_taxes;
 328   $self->js->render($self);
 329 }
 330
 331 sub _js_redisplay_linetotals {
 332   my ($self) = @_;
 333
 334   my @data = map {$::form->format_amount(\%::myconfig, $_->{linetotal}, 2, 0)} @{ $self->order->items };
 335   $self->js
 336     ->run('redisplay_linetotals', \@data);
 337 }
 338
 339 sub _js_redisplay_amounts_and_taxes {
 340   my ($self) = @_;
 341
 342   if (scalar @{ $self->{taxes} }) {
 343     $self->js->show('#taxincluded_row_id');
 344   } else {
 345     $self->js->hide('#taxincluded_row_id');
 346   }
 347
 348   if ($self->order->taxincluded) {
 349     $self->js->hide('#subtotal_row_id');
 350   } else {
 351     $self->js->show('#subtotal_row_id');
 352   }
 353
 354   $self->js
 355     ->html('#netamount_id', $::form->format_amount(\%::myconfig, $self->order->netamount, -2))
 356     ->html('#amount_id',    $::form->format_amount(\%::myconfig, $self->order->amount,    -2))
 357     ->remove('.tax_row')
 358     ->insertBefore($self->build_tax_rows, '#amount_row_id');
 359 }
 360
 361 #
 362 # helpers
 363 #
 364
 365 sub init_valid_types {
 366   [ _sales_order_type(), _purchase_order_type() ];
 367 }
 368
 369 sub init_type {
 370   my ($self) = @_;
 371
 372   if (none { $::form->{type} eq $_ } @{$self->valid_types}) {
 373     die "Not a valid type for order";
 374   }
 375
 376   $self->type($::form->{type});
 377 }
 378
 379 sub init_cv {
 380   my ($self) = @_;
 381
 382   my $cv = $self->type eq _sales_order_type()    ? 'customer'
 383          : $self->type eq _purchase_order_type() ? 'vendor'
 384          : die "Not a valid type for order";
 385
 386   return $cv;
 387 }
 388
 389 sub init_js {
 390   SL::ClientJS->new;
 391 }
 392
 393 sub init_p {
 394   SL::Presenter->get;
 395 }
 396
 397 sub init_order {
 398   _make_order();
 399 }
 400
 401 sub _check_auth {
 402   my ($self) = @_;
 403
 404   my $right_for = { map { $_ => $_.'_edit' } @{$self->valid_types} };
 405
 406   my $right   = $right_for->{ $self->type };
 407   $right    ||= 'DOES_NOT_EXIST';
 408
 409   $::auth->assert($right);
 410 }
 411
 412 sub build_contact_select {
 413   my ($self) = @_;
 414
 415   $self->p->select_tag('order.cp_id', [ $self->order->{$self->cv}->contacts ],
 416                        value_key  => 'cp_id',
 417                        title_key  => 'full_name_dep',
 418                        default    => $self->order->cp_id,
 419                        with_empty => 1,
 420                        style      => 'width: 300px',
 421   );
 422 }
 423
 424 sub build_shipto_select {
 425   my ($self) = @_;
 426
 427   $self->p->select_tag('order.shipto_id', [ $self->order->{$self->cv}->shipto ],
 428                        value_key  => 'shipto_id',
 429                        title_key  => 'displayable_id',
 430                        default    => $self->order->shipto_id,
 431                        with_empty => 1,
 432                        style      => 'width: 300px',
 433   );
 434 }
 435
 436 sub build_tax_rows {
 437   my ($self) = @_;
 438
 439   my $rows_as_html;
 440   foreach my $tax (@{ $self->{taxes} }) {
 441     $rows_as_html .= $self->p->render('order/tabs/_tax_row', TAX => $tax, TAXINCLUDED => $self->order->taxincluded);
 442   }
 443   return $rows_as_html;
 444 }
 445
 446
 447 sub _make_order {
 448   my ($self) = @_;
 449
 450   # add_items adds items to an order with no items for saving, but they cannot
 451   # be retrieved via items until the order is saved. Adding empty items to new
 452   # order here solves this problem.
 453   my $order;
 454   $order   = SL::DB::Manager::Order->find_by(id => $::form->{id}) if $::form->{id};
 455   $order ||= SL::DB::Order->new(orderitems => []);
 456
 457   $order->assign_attributes(%{$::form->{order}});
 458
 459   return $order;
 460 }
 461
 462
 463 sub _recalc {
 464   my ($self) = @_;
 465
 466   # bb: todo: currency later
 467   $self->order->currency_id($::instance_conf->get_currency_id());
 468
 469   my %pat = $self->order->calculate_prices_and_taxes();
 470   $self->{taxes} = [];
 471   foreach my $tax_chart_id (keys %{ $pat{taxes} }) {
 472     my $tax = SL::DB::Manager::Tax->find_by(chart_id => $tax_chart_id);
 473
 474     my @amount_keys = grep { $pat{amounts}->{$_}->{tax_id} == $tax->id } keys %{ $pat{amounts} };
 475     push(@{ $self->{taxes} }, { amount    => $pat{taxes}->{$tax_chart_id},
 476                                 netamount => $pat{amounts}->{$amount_keys[0]}->{amount},
 477                                 tax       => $tax });
 478   }
 479
 480   pairwise { $a->{linetotal} = $b->{linetotal} } @{$self->order->items}, @{$pat{items}};
 481 }
 482
 483
 484 sub _get_unalterable_data {
 485   my ($self) = @_;
 486
 487   foreach my $item (@{ $self->order->items }) {
 488     if ($item->id) {
 489       # load data from orderitems (db)
 490       my $db_item = SL::DB::OrderItem->new(id => $item->id)->load;
 491       $item->$_($db_item->$_) for qw(active_discount_source active_price_source longdescription);
 492     } else {
 493       # set data from part (or other sources)
 494       $item->longdescription($item->part->notes);
 495       #$item->active_price_source('');
 496       #$item->active_discount_source('');
 497     }
 498   }
 499 }
 500
 501
 502 sub _save {
 503   my ($self) = @_;
 504
 505   # autovivify all cvars that are not in the form (cvars_by_config can do it)
 506   foreach my $item (@{ $self->order->items }) {
 507     $item->cvars_by_config;
 508   }
 509
 510   my $errors = [];
 511   my $db = $self->order->db;
 512
 513   $db->do_transaction(
 514     sub {
 515       $self->order->save();
 516   }) || push(@{$errors}, $db->error);
 517
 518   return $errors;
 519 }
 520
 521
 522 sub _pre_render {
 523   my ($self) = @_;
 524
 525   $self->{all_taxzones}        = SL::DB::Manager::TaxZone->get_all_sorted();
 526   $self->{all_employees}       = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->employee_id,
 527                                                                                        deleted => 0 ] ],
 528                                                                     sort_by => 'name');
 529   $self->{all_salesmen}        = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->salesman_id,
 530                                                                                        deleted => 0 ] ],
 531                                                                     sort_by => 'name');
 532   $self->{all_projects}        = SL::DB::Manager::Project->get_all(where => [ or => [ id => $self->order->globalproject_id,
 533                                                                                       active => 1 ] ],
 534                                                                    sort_by => 'projectnumber');
 535   $self->{all_payment_terms}   = SL::DB::Manager::PaymentTerm->get_all_sorted();
 536   $self->{all_delivery_terms}  = SL::DB::Manager::DeliveryTerm->get_all_sorted();
 537
 538   $self->{current_employee_id} = SL::DB::Manager::Employee->current->id;
 539
 540   $::request->{layout}->use_javascript("${_}.js")  for qw(ckeditor/ckeditor ckeditor/adapters/jquery);
 541 }
 542
 543 sub _create_pdf {
 544   my ($order, $pdf_ref, $params) = @_;
 545
 546   my $print_form = Form->new('');
 547   $print_form->{type}     = 'sales_order';
 548   $print_form->{formname} = 'sales_order',
 549   $print_form->{format}   = $params->{format} || 'pdf',
 550   $print_form->{media}    = $params->{media}  || 'file';
 551
 552   $order->flatten_to_form($print_form, format_amounts => 1);
 553   # flatten_to_form sets payment_terms from customer/vendor - we do not want that here
 554   delete $print_form->{payment_terms} if !$print_form->{payment_id};
 555
 556   my @errors = ();
 557   $print_form->throw_on_error(sub {
 558     eval {
 559       $print_form->prepare_for_printing;
 560
 561       $$pdf_ref = SL::Helper::CreatePDF->create_pdf(
 562         template  => SL::Helper::CreatePDF->find_template(name => $print_form->{formname}),
 563         variables => $print_form,
 564         variable_content_types => {
 565           longdescription => 'html',
 566           partnotes       => 'html',
 567           notes           => 'html',
 568         },
 569       );
 570       1;
 571     } || push @errors, ref($EVAL_ERROR) eq 'SL::X::FormError' ? $EVAL_ERROR->getMessage : $EVAL_ERROR;
 572   });
 573
 574   return @errors;
 575 }
 576
 577 sub _sales_order_type {
 578   'sales_order';
 579 }
 580
 581 sub _purchase_order_type {
 582   'purchase_order';
 583 }
 584
 585 1;
 586
 587 __END__
 588
 589 =encoding utf-8
 590
 591 =head1 NAME
 592
 593 SL::Controller::Order - controller for orders
 594
 595 =head1 TODO
 596
 597 Testing, PriceSources, pricefactor, units, currency, delivered, delivery order created, ...
 598
 599 =head1 AUTHOR
 600
 601 Bernd Bleßmann E<lt>bernd@kivitendo-premium.deE<gt>
 602
 603 =cut
 604