SL/Controller/Order.pm

   1 package SL::Controller::Order;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use SL::Helper::Flash qw(flash_later);
   7 use SL::Presenter::Tag qw(select_tag hidden_tag div_tag);
   8 use SL::Locale::String qw(t8);
   9 use SL::SessionFile::Random;
  10 use SL::PriceSource;
  11 use SL::Webdav;
  12 use SL::File;
  13 use SL::MIME;
  14 use SL::Util qw(trim);
  15 use SL::YAML;
  16 use SL::DB::History;
  17 use SL::DB::Order;
  18 use SL::DB::Default;
  19 use SL::DB::Unit;
  20 use SL::DB::Part;
  21 use SL::DB::PartClassification;
  22 use SL::DB::PartsGroup;
  23 use SL::DB::Printer;
  24 use SL::DB::Language;
  25 use SL::DB::RecordLink;
  26 use SL::DB::RequirementSpec;
  27 use SL::DB::Shipto;
  28 use SL::DB::Translation;
  29
  30 use SL::Helper::CreatePDF qw(:all);
  31 use SL::Helper::PrintOptions;
  32 use SL::Helper::ShippedQty;
  33 use SL::Helper::UserPreferences::PositionsScrollbar;
  34 use SL::Helper::UserPreferences::UpdatePositions;
  35
  36 use SL::Controller::Helper::GetModels;
  37
  38 use List::Util qw(first sum0);
  39 use List::UtilsBy qw(sort_by uniq_by);
  40 use List::MoreUtils qw(any none pairwise first_index);
  41 use English qw(-no_match_vars);
  42 use File::Spec;
  43 use Cwd;
  44 use Sort::Naturally;
  45
  46 use Rose::Object::MakeMethods::Generic
  47 (
  48  scalar => [ qw(item_ids_to_delete is_custom_shipto_to_delete) ],
  49  'scalar --get_set_init' => [ qw(order valid_types type cv p all_price_factors search_cvpartnumber show_update_button part_picker_classification_ids) ],
  50 );
  51
  52
  53 # safety
  54 __PACKAGE__->run_before('check_auth');
  55
  56 __PACKAGE__->run_before('recalc',
  57                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice save_and_ap_transaction
  58                                      print send_email) ]);
  59
  60 __PACKAGE__->run_before('get_unalterable_data',
  61                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice save_and_ap_transaction
  62                                      print send_email) ]);
  63
  64 #
  65 # actions
  66 #
  67
  68 # add a new order
  69 sub action_add {
  70   my ($self) = @_;
  71
  72   $self->order->transdate(DateTime->now_local());
  73   my $extra_days = $self->type eq sales_quotation_type() ? $::instance_conf->get_reqdate_interval       :
  74                    $self->type eq sales_order_type()     ? $::instance_conf->get_delivery_date_interval : 1;
  75
  76   if (   ($self->type eq sales_order_type()     &&  $::instance_conf->get_deliverydate_on)
  77       || ($self->type eq sales_quotation_type() &&  $::instance_conf->get_reqdate_on)
  78       && (!$self->order->reqdate)) {
  79     $self->order->reqdate(DateTime->today_local->next_workday(extra_days => $extra_days));
  80   }
  81
  82
  83   $self->pre_render();
  84   $self->render(
  85     'order/form',
  86     title => $self->get_title_for('add'),
  87     %{$self->{template_args}}
  88   );
  89 }
  90
  91 # edit an existing order
  92 sub action_edit {
  93   my ($self) = @_;
  94
  95   if ($::form->{id}) {
  96     $self->load_order;
  97
  98   } else {
  99     # this is to edit an order from an unsaved order object
 100
 101     # set item ids to new fake id, to identify them as new items
 102     foreach my $item (@{$self->order->items_sorted}) {
 103       $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 104     }
 105     # trigger rendering values for second row as hidden, because they
 106     # are loaded only on demand. So we need to keep the values from
 107     # the source.
 108     $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
 109   }
 110
 111   $self->recalc();
 112   $self->pre_render();
 113   $self->render(
 114     'order/form',
 115     title => $self->get_title_for('edit'),
 116     %{$self->{template_args}}
 117   );
 118 }
 119
 120 # edit a collective order (consisting of one or more existing orders)
 121 sub action_edit_collective {
 122   my ($self) = @_;
 123
 124   # collect order ids
 125   my @multi_ids = map {
 126     $_ =~ m{^multi_id_(\d+)$} && $::form->{'multi_id_' . $1} && $::form->{'trans_id_' . $1} && $::form->{'trans_id_' . $1}
 127   } grep { $_ =~ m{^multi_id_\d+$} } keys %$::form;
 128
 129   # fall back to add if no ids are given
 130   if (scalar @multi_ids == 0) {
 131     $self->action_add();
 132     return;
 133   }
 134
 135   # fall back to save as new if only one id is given
 136   if (scalar @multi_ids == 1) {
 137     $self->order(SL::DB::Order->new(id => $multi_ids[0])->load);
 138     $self->action_save_as_new();
 139     return;
 140   }
 141
 142   # make new order from given orders
 143   my @multi_orders = map { SL::DB::Order->new(id => $_)->load } @multi_ids;
 144   $self->{converted_from_oe_id} = join ' ', map { $_->id } @multi_orders;
 145   $self->order(SL::DB::Order->new_from_multi(\@multi_orders, sort_sources_by => 'transdate'));
 146
 147   $self->action_edit();
 148 }
 149
 150 # delete the order
 151 sub action_delete {
 152   my ($self) = @_;
 153
 154   my $errors = $self->delete();
 155
 156   if (scalar @{ $errors }) {
 157     $self->js->flash('error', $_) foreach @{ $errors };
 158     return $self->js->render();
 159   }
 160
 161   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been deleted')
 162            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been deleted')
 163            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been deleted')
 164            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been deleted')
 165            : '';
 166   flash_later('info', $text);
 167
 168   my @redirect_params = (
 169     action => 'add',
 170     type   => $self->type,
 171   );
 172
 173   $self->redirect_to(@redirect_params);
 174 }
 175
 176 # save the order
 177 sub action_save {
 178   my ($self) = @_;
 179
 180   my $errors = $self->save();
 181
 182   if (scalar @{ $errors }) {
 183     $self->js->flash('error', $_) foreach @{ $errors };
 184     return $self->js->render();
 185   }
 186
 187   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
 188            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
 189            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
 190            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
 191            : '';
 192   flash_later('info', $text);
 193
 194   my @redirect_params = (
 195     action => 'edit',
 196     type   => $self->type,
 197     id     => $self->order->id,
 198   );
 199
 200   $self->redirect_to(@redirect_params);
 201 }
 202
 203 # save the order as new document an open it for edit
 204 sub action_save_as_new {
 205   my ($self) = @_;
 206
 207   my $order = $self->order;
 208
 209   if (!$order->id) {
 210     $self->js->flash('error', t8('This object has not been saved yet.'));
 211     return $self->js->render();
 212   }
 213
 214   # load order from db to check if values changed
 215   my $saved_order = SL::DB::Order->new(id => $order->id)->load;
 216
 217   my %new_attrs;
 218   # Lets assign a new number if the user hasn't changed the previous one.
 219   # If it has been changed manually then use it as-is.
 220   $new_attrs{number}    = (trim($order->number) eq $saved_order->number)
 221                         ? ''
 222                         : trim($order->number);
 223
 224   # Clear transdate unless changed
 225   $new_attrs{transdate} = ($order->transdate == $saved_order->transdate)
 226                         ? DateTime->today_local
 227                         : $order->transdate;
 228
 229   # Set new reqdate unless changed if it is enabled in client config
 230   if ($order->reqdate == $saved_order->reqdate) {
 231     my $extra_days = $self->type eq sales_quotation_type() ? $::instance_conf->get_reqdate_interval       :
 232                      $self->type eq sales_order_type()     ? $::instance_conf->get_delivery_date_interval : 1;
 233
 234     if (   ($self->type eq sales_order_type()     &&  !$::instance_conf->get_deliverydate_on)
 235         || ($self->type eq sales_quotation_type() &&  !$::instance_conf->get_reqdate_on)) {
 236       $new_attrs{reqdate} = '';
 237     } else {
 238       $new_attrs{reqdate} = DateTime->today_local->next_workday(extra_days => $extra_days);
 239     }
 240   } else {
 241     $new_attrs{reqdate} = $order->reqdate;
 242   }
 243
 244   # Update employee
 245   $new_attrs{employee}  = SL::DB::Manager::Employee->current;
 246
 247   # Create new record from current one
 248   $self->order(SL::DB::Order->new_from($order, destination_type => $order->type, attributes => \%new_attrs));
 249
 250   # no linked records on save as new
 251   delete $::form->{$_} for qw(converted_from_oe_id converted_from_orderitems_ids);
 252
 253   # save
 254   $self->action_save();
 255 }
 256
 257 # print the order
 258 #
 259 # This is called if "print" is pressed in the print dialog.
 260 # If PDF creation was requested and succeeded, the pdf is offered for download
 261 # via send_file (which uses ajax in this case).
 262 sub action_print {
 263   my ($self) = @_;
 264
 265   my $errors = $self->save();
 266
 267   if (scalar @{ $errors }) {
 268     $self->js->flash('error', $_) foreach @{ $errors };
 269     return $self->js->render();
 270   }
 271
 272   $self->js_reset_order_and_item_ids_after_save;
 273
 274   my $format      = $::form->{print_options}->{format};
 275   my $media       = $::form->{print_options}->{media};
 276   my $formname    = $::form->{print_options}->{formname};
 277   my $copies      = $::form->{print_options}->{copies};
 278   my $groupitems  = $::form->{print_options}->{groupitems};
 279   my $printer_id  = $::form->{print_options}->{printer_id};
 280
 281   # only pdf and opendocument by now
 282   if (none { $format eq $_ } qw(pdf opendocument opendocument_pdf)) {
 283     return $self->js->flash('error', t8('Format \'#1\' is not supported yet/anymore.', $format))->render;
 284   }
 285
 286   # only screen or printer by now
 287   if (none { $media eq $_ } qw(screen printer)) {
 288     return $self->js->flash('error', t8('Media \'#1\' is not supported yet/anymore.', $media))->render;
 289   }
 290
 291   # create a form for generate_attachment_filename
 292   my $form   = Form->new;
 293   $form->{$self->nr_key()}  = $self->order->number;
 294   $form->{type}             = $self->type;
 295   $form->{format}           = $format;
 296   $form->{formname}         = $formname;
 297   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 298   my $pdf_filename          = $form->generate_attachment_filename();
 299
 300   my $pdf;
 301   my @errors = generate_pdf($self->order, \$pdf, { format     => $format,
 302                                                    formname   => $formname,
 303                                                    language   => $self->order->language,
 304                                                    printer_id => $printer_id,
 305                                                    groupitems => $groupitems });
 306   if (scalar @errors) {
 307     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render;
 308   }
 309
 310   if ($media eq 'screen') {
 311     # screen/download
 312     $self->js->flash('info', t8('The PDF has been created'));
 313     $self->send_file(
 314       \$pdf,
 315       type         => SL::MIME->mime_type_from_ext($pdf_filename),
 316       name         => $pdf_filename,
 317       js_no_render => 1,
 318     );
 319
 320   } elsif ($media eq 'printer') {
 321     # printer
 322     my $printer_id = $::form->{print_options}->{printer_id};
 323     SL::DB::Printer->new(id => $printer_id)->load->print_document(
 324       copies  => $copies,
 325       content => $pdf,
 326     );
 327
 328     $self->js->flash('info', t8('The PDF has been printed'));
 329   }
 330
 331   my @warnings = store_pdf_to_webdav_and_filemanagement($self->order, $pdf, $pdf_filename);
 332   if (scalar @warnings) {
 333     $self->js->flash('warning', $_) for @warnings;
 334   }
 335
 336   $self->save_history('PRINTED');
 337
 338   $self->js
 339     ->run('kivi.ActionBar.setEnabled', '#save_and_email_action')
 340     ->render;
 341 }
 342 sub action_preview_pdf {
 343   my ($self) = @_;
 344
 345   my $errors = $self->save();
 346   if (scalar @{ $errors }) {
 347     $self->js->flash('error', $_) foreach @{ $errors };
 348     return $self->js->render();
 349   }
 350
 351   $self->js_reset_order_and_item_ids_after_save;
 352
 353   my $format      = 'pdf';
 354   my $media       = 'screen';
 355   my $formname    = $self->type;
 356
 357   # only pdf
 358   # create a form for generate_attachment_filename
 359   my $form   = Form->new;
 360   $form->{$self->nr_key()}  = $self->order->number;
 361   $form->{type}             = $self->type;
 362   $form->{format}           = $format;
 363   $form->{formname}         = $formname;
 364   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 365   my $pdf_filename          = $form->generate_attachment_filename();
 366
 367   my $pdf;
 368   my @errors = generate_pdf($self->order, \$pdf, { format     => $format,
 369                                                    formname   => $formname,
 370                                                    language   => $self->order->language,
 371                                                  });
 372   if (scalar @errors) {
 373     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render;
 374   }
 375   $self->save_history('PREVIEWED');
 376   $self->js->flash('info', t8('The PDF has been previewed'));
 377   # screen/download
 378   $self->send_file(
 379     \$pdf,
 380     type         => SL::MIME->mime_type_from_ext($pdf_filename),
 381     name         => $pdf_filename,
 382     js_no_render => 0,
 383   );
 384 }
 385
 386 # open the email dialog
 387 sub action_save_and_show_email_dialog {
 388   my ($self) = @_;
 389
 390   my $errors = $self->save();
 391
 392   if (scalar @{ $errors }) {
 393     $self->js->flash('error', $_) foreach @{ $errors };
 394     return $self->js->render();
 395   }
 396
 397   my $cv_method = $self->cv;
 398
 399   if (!$self->order->$cv_method) {
 400     return $self->js->flash('error', $self->cv eq 'customer' ? t8('Cannot send E-mail without customer given') : t8('Cannot send E-mail without vendor given'))
 401                     ->render($self);
 402   }
 403
 404   my $email_form;
 405   $email_form->{to}   = $self->order->contact->cp_email if $self->order->contact;
 406   $email_form->{to} ||= $self->order->$cv_method->email;
 407   $email_form->{cc}   = $self->order->$cv_method->cc;
 408   $email_form->{bcc}  = join ', ', grep $_, $self->order->$cv_method->bcc, SL::DB::Default->get->global_bcc;
 409   # Todo: get addresses from shipto, if any
 410
 411   my $form = Form->new;
 412   $form->{$self->nr_key()}  = $self->order->number;
 413   $form->{cusordnumber}     = $self->order->cusordnumber;
 414   $form->{formname}         = $self->type;
 415   $form->{type}             = $self->type;
 416   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 417   $form->{language_id}      = $self->order->language->id                  if $self->order->language;
 418   $form->{format}           = 'pdf';
 419   $form->{cp_id}            = $self->order->contact->cp_id if $self->order->contact;
 420
 421   $email_form->{subject}             = $form->generate_email_subject();
 422   $email_form->{attachment_filename} = $form->generate_attachment_filename();
 423   $email_form->{message}             = $form->generate_email_body();
 424   $email_form->{js_send_function}    = 'kivi.Order.send_email()';
 425
 426   my %files = $self->get_files_for_email_dialog();
 427   $self->{all_employees} = SL::DB::Manager::Employee->get_all(query => [ deleted => 0 ]);
 428   my $dialog_html = $self->render('common/_send_email_dialog', { output => 0 },
 429                                   email_form  => $email_form,
 430                                   show_bcc    => $::auth->assert('email_bcc', 'may fail'),
 431                                   FILES       => \%files,
 432                                   is_customer => $self->cv eq 'customer',
 433                                   ALL_EMPLOYEES => $self->{all_employees},
 434   );
 435
 436   $self->js
 437       ->run('kivi.Order.show_email_dialog', $dialog_html)
 438       ->reinit_widgets
 439       ->render($self);
 440 }
 441
 442 # send email
 443 #
 444 # Todo: handling error messages: flash is not displayed in dialog, but in the main form
 445 sub action_send_email {
 446   my ($self) = @_;
 447
 448   my $errors = $self->save();
 449
 450   if (scalar @{ $errors }) {
 451     $self->js->run('kivi.Order.close_email_dialog');
 452     $self->js->flash('error', $_) foreach @{ $errors };
 453     return $self->js->render();
 454   }
 455
 456   $self->js_reset_order_and_item_ids_after_save;
 457
 458   my $email_form  = delete $::form->{email_form};
 459   my %field_names = (to => 'email');
 460
 461   $::form->{ $field_names{$_} // $_ } = $email_form->{$_} for keys %{ $email_form };
 462
 463   # for Form::cleanup which may be called in Form::send_email
 464   $::form->{cwd}    = getcwd();
 465   $::form->{tmpdir} = $::lx_office_conf{paths}->{userspath};
 466
 467   $::form->{$_}     = $::form->{print_options}->{$_} for keys %{ $::form->{print_options} };
 468   $::form->{media}  = 'email';
 469
 470   if (($::form->{attachment_policy} // '') !~ m{^(?:old_file|no_file)$}) {
 471     my $pdf;
 472     my @errors = generate_pdf($self->order, \$pdf, {media      => $::form->{media},
 473                                                     format     => $::form->{print_options}->{format},
 474                                                     formname   => $::form->{print_options}->{formname},
 475                                                     language   => $self->order->language,
 476                                                     printer_id => $::form->{print_options}->{printer_id},
 477                                                     groupitems => $::form->{print_options}->{groupitems}});
 478     if (scalar @errors) {
 479       return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render($self);
 480     }
 481
 482     my @warnings = store_pdf_to_webdav_and_filemanagement($self->order, $pdf, $::form->{attachment_filename});
 483     if (scalar @warnings) {
 484       flash_later('warning', $_) for @warnings;
 485     }
 486
 487     my $sfile = SL::SessionFile::Random->new(mode => "w");
 488     $sfile->fh->print($pdf);
 489     $sfile->fh->close;
 490
 491     $::form->{tmpfile} = $sfile->file_name;
 492     $::form->{tmpdir}  = $sfile->get_path; # for Form::cleanup which may be called in Form::send_email
 493   }
 494
 495   $::form->{id} = $self->order->id; # this is used in SL::Mailer to create a linked record to the mail
 496   $::form->send_email(\%::myconfig, 'pdf');
 497
 498   # internal notes
 499   my $intnotes = $self->order->intnotes;
 500   $intnotes   .= "\n\n" if $self->order->intnotes;
 501   $intnotes   .= t8('[email]')                                                                                        . "\n";
 502   $intnotes   .= t8('Date')       . ": " . $::locale->format_date_object(DateTime->now_local, precision => 'seconds') . "\n";
 503   $intnotes   .= t8('To (email)') . ": " . $::form->{email}                                                           . "\n";
 504   $intnotes   .= t8('Cc')         . ": " . $::form->{cc}                                                              . "\n"    if $::form->{cc};
 505   $intnotes   .= t8('Bcc')        . ": " . $::form->{bcc}                                                             . "\n"    if $::form->{bcc};
 506   $intnotes   .= t8('Subject')    . ": " . $::form->{subject}                                                         . "\n\n";
 507   $intnotes   .= t8('Message')    . ": " . $::form->{message};
 508
 509   $self->order->update_attributes(intnotes => $intnotes);
 510
 511   $self->save_history('MAILED');
 512
 513   flash_later('info', t8('The email has been sent.'));
 514
 515   my @redirect_params = (
 516     action => 'edit',
 517     type   => $self->type,
 518     id     => $self->order->id,
 519   );
 520
 521   $self->redirect_to(@redirect_params);
 522 }
 523
 524 # open the periodic invoices config dialog
 525 #
 526 # If there are values in the form (i.e. dialog was opened before),
 527 # then use this values. Create new ones, else.
 528 sub action_show_periodic_invoices_config_dialog {
 529   my ($self) = @_;
 530
 531   my $config = make_periodic_invoices_config_from_yaml(delete $::form->{config});
 532   $config  ||= SL::DB::Manager::PeriodicInvoicesConfig->find_by(oe_id => $::form->{id}) if $::form->{id};
 533   $config  ||= SL::DB::PeriodicInvoicesConfig->new(periodicity             => 'm',
 534                                                    order_value_periodicity => 'p', # = same as periodicity
 535                                                    start_date_as_date      => $::form->{transdate_as_date} || $::form->current_date,
 536                                                    extend_automatically_by => 12,
 537                                                    active                  => 1,
 538                                                    email_subject           => GenericTranslations->get(
 539                                                                                 language_id      => $::form->{language_id},
 540                                                                                 translation_type =>"preset_text_periodic_invoices_email_subject"),
 541                                                    email_body              => GenericTranslations->get(
 542                                                                                 language_id      => $::form->{language_id},
 543                                                                                 translation_type =>"preset_text_periodic_invoices_email_body"),
 544   );
 545   $config->periodicity('m')             if none { $_ eq $config->periodicity             }       @SL::DB::PeriodicInvoicesConfig::PERIODICITIES;
 546   $config->order_value_periodicity('p') if none { $_ eq $config->order_value_periodicity } ('p', @SL::DB::PeriodicInvoicesConfig::ORDER_VALUE_PERIODICITIES);
 547
 548   $::form->get_lists(printers => "ALL_PRINTERS",
 549                      charts   => { key       => 'ALL_CHARTS',
 550                                    transdate => 'current_date' });
 551
 552   $::form->{AR} = [ grep { $_->{link} =~ m/(?:^|:)AR(?::|$)/ } @{ $::form->{ALL_CHARTS} } ];
 553
 554   if ($::form->{customer_id}) {
 555     $::form->{ALL_CONTACTS} = SL::DB::Manager::Contact->get_all_sorted(where => [ cp_cv_id => $::form->{customer_id} ]);
 556     my $customer_object = SL::DB::Manager::Customer->find_by(id => $::form->{customer_id});
 557     $::form->{postal_invoice}                  = $customer_object->postal_invoice;
 558     $::form->{email_recipient_invoice_address} = $::form->{postal_invoice} ? '' : $customer_object->invoice_mail;
 559     $config->send_email(0) if $::form->{postal_invoice};
 560   }
 561
 562   $self->render('oe/edit_periodic_invoices_config', { layout => 0 },
 563                 popup_dialog             => 1,
 564                 popup_js_close_function  => 'kivi.Order.close_periodic_invoices_config_dialog()',
 565                 popup_js_assign_function => 'kivi.Order.assign_periodic_invoices_config()',
 566                 config                   => $config,
 567                 %$::form);
 568 }
 569
 570 # assign the values of the periodic invoices config dialog
 571 # as yaml in the hidden tag and set the status.
 572 sub action_assign_periodic_invoices_config {
 573   my ($self) = @_;
 574
 575   $::form->isblank('start_date_as_date', $::locale->text('The start date is missing.'));
 576
 577   my $config = { active                     => $::form->{active}       ? 1 : 0,
 578                  terminated                 => $::form->{terminated}   ? 1 : 0,
 579                  direct_debit               => $::form->{direct_debit} ? 1 : 0,
 580                  periodicity                => (any { $_ eq $::form->{periodicity}             }       @SL::DB::PeriodicInvoicesConfig::PERIODICITIES)              ? $::form->{periodicity}             : 'm',
 581                  order_value_periodicity    => (any { $_ eq $::form->{order_value_periodicity} } ('p', @SL::DB::PeriodicInvoicesConfig::ORDER_VALUE_PERIODICITIES)) ? $::form->{order_value_periodicity} : 'p',
 582                  start_date_as_date         => $::form->{start_date_as_date},
 583                  end_date_as_date           => $::form->{end_date_as_date},
 584                  first_billing_date_as_date => $::form->{first_billing_date_as_date},
 585                  print                      => $::form->{print}      ? 1                         : 0,
 586                  printer_id                 => $::form->{print}      ? $::form->{printer_id} * 1 : undef,
 587                  copies                     => $::form->{copies} * 1 ? $::form->{copies}         : 1,
 588                  extend_automatically_by    => $::form->{extend_automatically_by}    * 1 || undef,
 589                  ar_chart_id                => $::form->{ar_chart_id} * 1,
 590                  send_email                 => $::form->{send_email} ? 1 : 0,
 591                  email_recipient_contact_id => $::form->{email_recipient_contact_id} * 1 || undef,
 592                  email_recipient_address    => $::form->{email_recipient_address},
 593                  email_sender               => $::form->{email_sender},
 594                  email_subject              => $::form->{email_subject},
 595                  email_body                 => $::form->{email_body},
 596                };
 597
 598   my $periodic_invoices_config = SL::YAML::Dump($config);
 599
 600   my $status = $self->get_periodic_invoices_status($config);
 601
 602   $self->js
 603     ->remove('#order_periodic_invoices_config')
 604     ->insertAfter(hidden_tag('order.periodic_invoices_config', $periodic_invoices_config), '#periodic_invoices_status')
 605     ->run('kivi.Order.close_periodic_invoices_config_dialog')
 606     ->html('#periodic_invoices_status', $status)
 607     ->flash('info', t8('The periodic invoices config has been assigned.'))
 608     ->render($self);
 609 }
 610
 611 sub action_get_has_active_periodic_invoices {
 612   my ($self) = @_;
 613
 614   my $config = make_periodic_invoices_config_from_yaml(delete $::form->{config});
 615   $config  ||= SL::DB::Manager::PeriodicInvoicesConfig->find_by(oe_id => $::form->{id}) if $::form->{id};
 616
 617   my $has_active_periodic_invoices =
 618        $self->type eq sales_order_type()
 619     && $config
 620     && $config->active
 621     && (!$config->end_date || ($config->end_date > DateTime->today_local))
 622     && $config->get_previous_billed_period_start_date;
 623
 624   $_[0]->render(\ !!$has_active_periodic_invoices, { type => 'text' });
 625 }
 626
 627 # save the order and redirect to the frontend subroutine for a new
 628 # delivery order
 629 sub action_save_and_delivery_order {
 630   my ($self) = @_;
 631
 632   $self->save_and_redirect_to(
 633     controller => 'oe.pl',
 634     action     => 'oe_delivery_order_from_order',
 635   );
 636 }
 637
 638 # save the order and redirect to the frontend subroutine for a new
 639 # invoice
 640 sub action_save_and_invoice {
 641   my ($self) = @_;
 642
 643   $self->save_and_redirect_to(
 644     controller => 'oe.pl',
 645     action     => 'oe_invoice_from_order',
 646   );
 647 }
 648
 649 # workflow from sales order to sales quotation
 650 sub action_sales_quotation {
 651   $_[0]->workflow_sales_or_request_for_quotation();
 652 }
 653
 654 # workflow from sales order to sales quotation
 655 sub action_request_for_quotation {
 656   $_[0]->workflow_sales_or_request_for_quotation();
 657 }
 658
 659 # workflow from sales quotation to sales order
 660 sub action_sales_order {
 661   $_[0]->workflow_sales_or_purchase_order();
 662 }
 663
 664 # workflow from rfq to purchase order
 665 sub action_purchase_order {
 666   $_[0]->workflow_sales_or_purchase_order();
 667 }
 668
 669 # workflow from purchase order to ap transaction
 670 sub action_save_and_ap_transaction {
 671   my ($self) = @_;
 672
 673   $self->save_and_redirect_to(
 674     controller => 'ap.pl',
 675     action     => 'add_from_purchase_order',
 676   );
 677 }
 678
 679 # set form elements in respect to a changed customer or vendor
 680 #
 681 # This action is called on an change of the customer/vendor picker.
 682 sub action_customer_vendor_changed {
 683   my ($self) = @_;
 684
 685   setup_order_from_cv($self->order);
 686   $self->recalc();
 687
 688   my $cv_method = $self->cv;
 689
 690   if ($self->order->$cv_method->contacts && scalar @{ $self->order->$cv_method->contacts } > 0) {
 691     $self->js->show('#cp_row');
 692   } else {
 693     $self->js->hide('#cp_row');
 694   }
 695
 696   if ($self->order->$cv_method->shipto && scalar @{ $self->order->$cv_method->shipto } > 0) {
 697     $self->js->show('#shipto_selection');
 698   } else {
 699     $self->js->hide('#shipto_selection');
 700   }
 701
 702   $self->js->val( '#order_salesman_id',      $self->order->salesman_id)        if $self->order->is_sales;
 703
 704   $self->js
 705     ->replaceWith('#order_cp_id',            $self->build_contact_select)
 706     ->replaceWith('#order_shipto_id',        $self->build_shipto_select)
 707     ->replaceWith('#shipto_inputs  ',        $self->build_shipto_inputs)
 708     ->replaceWith('#business_info_row',      $self->build_business_info_row)
 709     ->val(        '#order_taxzone_id',       $self->order->taxzone_id)
 710     ->val(        '#order_taxincluded',      $self->order->taxincluded)
 711     ->val(        '#order_currency_id',      $self->order->currency_id)
 712     ->val(        '#order_payment_id',       $self->order->payment_id)
 713     ->val(        '#order_delivery_term_id', $self->order->delivery_term_id)
 714     ->val(        '#order_intnotes',         $self->order->intnotes)
 715     ->val(        '#order_language_id',      $self->order->$cv_method->language_id)
 716     ->focus(      '#order_' . $self->cv . '_id')
 717     ->run('kivi.Order.update_exchangerate');
 718
 719   $self->js_redisplay_amounts_and_taxes;
 720   $self->js_redisplay_cvpartnumbers;
 721   $self->js->render();
 722 }
 723
 724 # open the dialog for customer/vendor details
 725 sub action_show_customer_vendor_details_dialog {
 726   my ($self) = @_;
 727
 728   my $is_customer = 'customer' eq $::form->{vc};
 729   my $cv;
 730   if ($is_customer) {
 731     $cv = SL::DB::Customer->new(id => $::form->{vc_id})->load;
 732   } else {
 733     $cv = SL::DB::Vendor->new(id => $::form->{vc_id})->load;
 734   }
 735
 736   my %details = map { $_ => $cv->$_ } @{$cv->meta->columns};
 737   $details{discount_as_percent} = $cv->discount_as_percent;
 738   $details{creditlimt}          = $cv->creditlimit_as_number;
 739   $details{business}            = $cv->business->description      if $cv->business;
 740   $details{language}            = $cv->language_obj->description  if $cv->language_obj;
 741   $details{delivery_terms}      = $cv->delivery_term->description if $cv->delivery_term;
 742   $details{payment_terms}       = $cv->payment->description       if $cv->payment;
 743   $details{pricegroup}          = $cv->pricegroup->pricegroup     if $is_customer && $cv->pricegroup;
 744
 745   foreach my $entry (@{ $cv->shipto }) {
 746     push @{ $details{SHIPTO} },   { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 747   }
 748   foreach my $entry (@{ $cv->contacts }) {
 749     push @{ $details{CONTACTS} }, { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 750   }
 751
 752   $_[0]->render('common/show_vc_details', { layout => 0 },
 753                 is_customer => $is_customer,
 754                 %details);
 755
 756 }
 757
 758 # called if a unit in an existing item row is changed
 759 sub action_unit_changed {
 760   my ($self) = @_;
 761
 762   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 763   my $item = $self->order->items_sorted->[$idx];
 764
 765   my $old_unit_obj = SL::DB::Unit->new(name => $::form->{old_unit})->load;
 766   $item->sellprice($item->unit_obj->convert_to($item->sellprice, $old_unit_obj));
 767
 768   $self->recalc();
 769
 770   $self->js
 771     ->run('kivi.Order.update_sellprice', $::form->{item_id}, $item->sellprice_as_number);
 772   $self->js_redisplay_line_values;
 773   $self->js_redisplay_amounts_and_taxes;
 774   $self->js->render();
 775 }
 776
 777 # add an item row for a new item entered in the input row
 778 sub action_add_item {
 779   my ($self) = @_;
 780
 781   delete $::form->{add_item}->{create_part_type};
 782
 783   my $form_attr = $::form->{add_item};
 784
 785   return unless $form_attr->{parts_id};
 786
 787   my $item = new_item($self->order, $form_attr);
 788
 789   $self->order->add_items($item);
 790
 791   $self->recalc();
 792
 793   $self->get_item_cvpartnumber($item);
 794
 795   my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 796   my $row_as_html = $self->p->render('order/tabs/_row',
 797                                      ITEM => $item,
 798                                      ID   => $item_id,
 799                                      SELF => $self,
 800   );
 801
 802   if ($::form->{insert_before_item_id}) {
 803     $self->js
 804       ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 805   } else {
 806     $self->js
 807       ->append('#row_table_id', $row_as_html);
 808   }
 809
 810   if ( $item->part->is_assortment ) {
 811     $form_attr->{qty_as_number} = 1 unless $form_attr->{qty_as_number};
 812     foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 813       my $attr = { parts_id => $assortment_item->parts_id,
 814                    qty      => $assortment_item->qty * $::form->parse_amount(\%::myconfig, $form_attr->{qty_as_number}), # TODO $form_attr->{unit}
 815                    unit     => $assortment_item->unit,
 816                    description => $assortment_item->part->description,
 817                  };
 818       my $item = new_item($self->order, $attr);
 819
 820       # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 821       $item->discount(1) unless $assortment_item->charge;
 822
 823       $self->order->add_items( $item );
 824       $self->recalc();
 825       $self->get_item_cvpartnumber($item);
 826       my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 827       my $row_as_html = $self->p->render('order/tabs/_row',
 828                                          ITEM => $item,
 829                                          ID   => $item_id,
 830                                          SELF => $self,
 831       );
 832       if ($::form->{insert_before_item_id}) {
 833         $self->js
 834           ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 835       } else {
 836         $self->js
 837           ->append('#row_table_id', $row_as_html);
 838       }
 839     };
 840   };
 841
 842   $self->js
 843     ->val('.add_item_input', '')
 844     ->run('kivi.Order.init_row_handlers')
 845     ->run('kivi.Order.renumber_positions')
 846     ->focus('#add_item_parts_id_name');
 847
 848   $self->js->run('kivi.Order.row_table_scroll_down') if !$::form->{insert_before_item_id};
 849
 850   $self->js_redisplay_amounts_and_taxes;
 851   $self->js->render();
 852 }
 853
 854 # add item rows for multiple items at once
 855 sub action_add_multi_items {
 856   my ($self) = @_;
 857
 858   my @form_attr = grep { $_->{qty_as_number} } @{ $::form->{add_items} };
 859   return $self->js->render() unless scalar @form_attr;
 860
 861   my @items;
 862   foreach my $attr (@form_attr) {
 863     my $item = new_item($self->order, $attr);
 864     push @items, $item;
 865     if ( $item->part->is_assortment ) {
 866       foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 867         my $attr = { parts_id => $assortment_item->parts_id,
 868                      qty      => $assortment_item->qty * $item->qty, # TODO $form_attr->{unit}
 869                      unit     => $assortment_item->unit,
 870                      description => $assortment_item->part->description,
 871                    };
 872         my $item = new_item($self->order, $attr);
 873
 874         # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 875         $item->discount(1) unless $assortment_item->charge;
 876         push @items, $item;
 877       }
 878     }
 879   }
 880   $self->order->add_items(@items);
 881
 882   $self->recalc();
 883
 884   foreach my $item (@items) {
 885     $self->get_item_cvpartnumber($item);
 886     my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 887     my $row_as_html = $self->p->render('order/tabs/_row',
 888                                        ITEM => $item,
 889                                        ID   => $item_id,
 890                                        SELF => $self,
 891     );
 892
 893     if ($::form->{insert_before_item_id}) {
 894       $self->js
 895         ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 896     } else {
 897       $self->js
 898         ->append('#row_table_id', $row_as_html);
 899     }
 900   }
 901
 902   $self->js
 903     ->run('kivi.Part.close_picker_dialogs')
 904     ->run('kivi.Order.init_row_handlers')
 905     ->run('kivi.Order.renumber_positions')
 906     ->focus('#add_item_parts_id_name');
 907
 908   $self->js->run('kivi.Order.row_table_scroll_down') if !$::form->{insert_before_item_id};
 909
 910   $self->js_redisplay_amounts_and_taxes;
 911   $self->js->render();
 912 }
 913
 914 # recalculate all linetotals, amounts and taxes and redisplay them
 915 sub action_recalc_amounts_and_taxes {
 916   my ($self) = @_;
 917
 918   $self->recalc();
 919
 920   $self->js_redisplay_line_values;
 921   $self->js_redisplay_amounts_and_taxes;
 922   $self->js->render();
 923 }
 924
 925 sub action_update_exchangerate {
 926   my ($self) = @_;
 927
 928   my $data = {
 929     is_standard   => $self->order->currency_id == $::instance_conf->get_currency_id,
 930     currency_name => $self->order->currency->name,
 931     exchangerate  => $self->order->daily_exchangerate_as_null_number,
 932   };
 933
 934   $self->render(\SL::JSON::to_json($data), { type => 'json', process => 0 });
 935 }
 936
 937 # redisplay item rows if they are sorted by an attribute
 938 sub action_reorder_items {
 939   my ($self) = @_;
 940
 941   my %sort_keys = (
 942     partnumber   => sub { $_[0]->part->partnumber },
 943     description  => sub { $_[0]->description },
 944     qty          => sub { $_[0]->qty },
 945     sellprice    => sub { $_[0]->sellprice },
 946     discount     => sub { $_[0]->discount },
 947     cvpartnumber => sub { $_[0]->{cvpartnumber} },
 948   );
 949
 950   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
 951
 952   my $method = $sort_keys{$::form->{order_by}};
 953   my @to_sort = map { { old_pos => $_->position, order_by => $method->($_) } } @{ $self->order->items_sorted };
 954   if ($::form->{sort_dir}) {
 955     if ( $::form->{order_by} =~ m/qty|sellprice|discount/ ){
 956       @to_sort = sort { $a->{order_by} <=> $b->{order_by} } @to_sort;
 957     } else {
 958       @to_sort = sort { $a->{order_by} cmp $b->{order_by} } @to_sort;
 959     }
 960   } else {
 961     if ( $::form->{order_by} =~ m/qty|sellprice|discount/ ){
 962       @to_sort = sort { $b->{order_by} <=> $a->{order_by} } @to_sort;
 963     } else {
 964       @to_sort = sort { $b->{order_by} cmp $a->{order_by} } @to_sort;
 965     }
 966   }
 967   $self->js
 968     ->run('kivi.Order.redisplay_items', \@to_sort)
 969     ->render;
 970 }
 971
 972 # show the popup to choose a price/discount source
 973 sub action_price_popup {
 974   my ($self) = @_;
 975
 976   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 977   my $item = $self->order->items_sorted->[$idx];
 978
 979   $self->render_price_dialog($item);
 980 }
 981
 982 # save the order in a session variable and redirect to the part controller
 983 sub action_create_part {
 984   my ($self) = @_;
 985
 986   my $previousform = $::auth->save_form_in_session(non_scalars => 1);
 987
 988   my $callback     = $self->url_for(
 989     action       => 'return_from_create_part',
 990     type         => $self->type, # type is needed for check_auth on return
 991     previousform => $previousform,
 992   );
 993
 994   flash_later('info', t8('You are adding a new part while you are editing another document. You will be redirected to your document when saving the new part or aborting this form.'));
 995
 996   my @redirect_params = (
 997     controller => 'Part',
 998     action     => 'add',
 999     part_type  => $::form->{add_item}->{create_part_type},
1000     callback   => $callback,
1001     show_abort => 1,
1002   );
1003
1004   $self->redirect_to(@redirect_params);
1005 }
1006
1007 sub action_return_from_create_part {
1008   my ($self) = @_;
1009
1010   $self->{created_part} = SL::DB::Part->new(id => delete $::form->{new_parts_id})->load if $::form->{new_parts_id};
1011
1012   $::auth->restore_form_from_session(delete $::form->{previousform});
1013
1014   # set item ids to new fake id, to identify them as new items
1015   foreach my $item (@{$self->order->items_sorted}) {
1016     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1017   }
1018
1019   $self->recalc();
1020   $self->get_unalterable_data();
1021   $self->pre_render();
1022
1023   # trigger rendering values for second row/longdescription as hidden,
1024   # because they are loaded only on demand. So we need to keep the values
1025   # from the source.
1026   $_->{render_second_row}      = 1 for @{ $self->order->items_sorted };
1027   $_->{render_longdescription} = 1 for @{ $self->order->items_sorted };
1028
1029   $self->render(
1030     'order/form',
1031     title => $self->get_title_for('edit'),
1032     %{$self->{template_args}}
1033   );
1034
1035 }
1036
1037 # load the second row for one or more items
1038 #
1039 # This action gets the html code for all items second rows by rendering a template for
1040 # the second row and sets the html code via client js.
1041 sub action_load_second_rows {
1042   my ($self) = @_;
1043
1044   $self->recalc() if $self->order->is_sales; # for margin calculation
1045
1046   foreach my $item_id (@{ $::form->{item_ids} }) {
1047     my $idx  = first_index { $_ eq $item_id } @{ $::form->{orderitem_ids} };
1048     my $item = $self->order->items_sorted->[$idx];
1049
1050     $self->js_load_second_row($item, $item_id, 0);
1051   }
1052
1053   $self->js->run('kivi.Order.init_row_handlers') if $self->order->is_sales; # for lastcosts change-callback
1054
1055   $self->js->render();
1056 }
1057
1058 # update description, notes and sellprice from master data
1059 sub action_update_row_from_master_data {
1060   my ($self) = @_;
1061
1062   foreach my $item_id (@{ $::form->{item_ids} }) {
1063     my $idx   = first_index { $_ eq $item_id } @{ $::form->{orderitem_ids} };
1064     my $item  = $self->order->items_sorted->[$idx];
1065     my $texts = get_part_texts($item->part, $self->order->language_id);
1066
1067     $item->description($texts->{description});
1068     $item->longdescription($texts->{longdescription});
1069
1070     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
1071
1072     my $price_src;
1073     if ($item->part->is_assortment) {
1074     # add assortment items with price 0, as the components carry the price
1075       $price_src = $price_source->price_from_source("");
1076       $price_src->price(0);
1077     } else {
1078       $price_src = $price_source->best_price
1079                  ? $price_source->best_price
1080                  : $price_source->price_from_source("");
1081       $price_src->price($::form->round_amount($price_src->price / $self->order->exchangerate, 5)) if $self->order->exchangerate;
1082       $price_src->price(0) if !$price_source->best_price;
1083     }
1084
1085
1086     $item->sellprice($price_src->price);
1087     $item->active_price_source($price_src);
1088
1089     $self->js
1090       ->run('kivi.Order.update_sellprice', $item_id, $item->sellprice_as_number)
1091       ->html('.row_entry:has(#item_' . $item_id . ') [name = "partnumber"] a', $item->part->partnumber)
1092       ->val ('.row_entry:has(#item_' . $item_id . ') [name = "order.orderitems[].description"]', $item->description)
1093       ->val ('.row_entry:has(#item_' . $item_id . ') [name = "order.orderitems[].longdescription"]', $item->longdescription);
1094
1095     if ($self->search_cvpartnumber) {
1096       $self->get_item_cvpartnumber($item);
1097       $self->js->html('.row_entry:has(#item_' . $item_id . ') [name = "cvpartnumber"]', $item->{cvpartnumber});
1098     }
1099   }
1100
1101   $self->recalc();
1102   $self->js_redisplay_line_values;
1103   $self->js_redisplay_amounts_and_taxes;
1104
1105   $self->js->render();
1106 }
1107
1108 sub js_load_second_row {
1109   my ($self, $item, $item_id, $do_parse) = @_;
1110
1111   if ($do_parse) {
1112     # Parse values from form (they are formated while rendering (template)).
1113     # Workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
1114     # This parsing is not necessary at all, if we assure that the second row/cvars are only loaded once.
1115     foreach my $var (@{ $item->cvars_by_config }) {
1116       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
1117     }
1118     $item->parse_custom_variable_values;
1119   }
1120
1121   my $row_as_html = $self->p->render('order/tabs/_second_row', ITEM => $item, TYPE => $self->type);
1122
1123   $self->js
1124     ->html('#second_row_' . $item_id, $row_as_html)
1125     ->data('#second_row_' . $item_id, 'loaded', 1);
1126 }
1127
1128 sub js_redisplay_line_values {
1129   my ($self) = @_;
1130
1131   my $is_sales = $self->order->is_sales;
1132
1133   # sales orders with margins
1134   my @data;
1135   if ($is_sales) {
1136     @data = map {
1137       [
1138        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
1139        $::form->format_amount(\%::myconfig, $_->{marge_total},   2, 0),
1140        $::form->format_amount(\%::myconfig, $_->{marge_percent}, 2, 0),
1141       ]} @{ $self->order->items_sorted };
1142   } else {
1143     @data = map {
1144       [
1145        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
1146       ]} @{ $self->order->items_sorted };
1147   }
1148
1149   $self->js
1150     ->run('kivi.Order.redisplay_line_values', $is_sales, \@data);
1151 }
1152
1153 sub js_redisplay_amounts_and_taxes {
1154   my ($self) = @_;
1155
1156   if (scalar @{ $self->{taxes} }) {
1157     $self->js->show('#taxincluded_row_id');
1158   } else {
1159     $self->js->hide('#taxincluded_row_id');
1160   }
1161
1162   if ($self->order->taxincluded) {
1163     $self->js->hide('#subtotal_row_id');
1164   } else {
1165     $self->js->show('#subtotal_row_id');
1166   }
1167
1168   if ($self->order->is_sales) {
1169     my $is_neg = $self->order->marge_total < 0;
1170     $self->js
1171       ->html('#marge_total_id',   $::form->format_amount(\%::myconfig, $self->order->marge_total,   2))
1172       ->html('#marge_percent_id', $::form->format_amount(\%::myconfig, $self->order->marge_percent, 2))
1173       ->action_if( $is_neg, 'addClass',    '#marge_total_id',        'plus0')
1174       ->action_if( $is_neg, 'addClass',    '#marge_percent_id',      'plus0')
1175       ->action_if( $is_neg, 'addClass',    '#marge_percent_sign_id', 'plus0')
1176       ->action_if(!$is_neg, 'removeClass', '#marge_total_id',        'plus0')
1177       ->action_if(!$is_neg, 'removeClass', '#marge_percent_id',      'plus0')
1178       ->action_if(!$is_neg, 'removeClass', '#marge_percent_sign_id', 'plus0');
1179   }
1180
1181   $self->js
1182     ->html('#netamount_id', $::form->format_amount(\%::myconfig, $self->order->netamount, -2))
1183     ->html('#amount_id',    $::form->format_amount(\%::myconfig, $self->order->amount,    -2))
1184     ->remove('.tax_row')
1185     ->insertBefore($self->build_tax_rows, '#amount_row_id');
1186 }
1187
1188 sub js_redisplay_cvpartnumbers {
1189   my ($self) = @_;
1190
1191   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
1192
1193   my @data = map {[$_->{cvpartnumber}]} @{ $self->order->items_sorted };
1194
1195   $self->js
1196     ->run('kivi.Order.redisplay_cvpartnumbers', \@data);
1197 }
1198
1199 sub js_reset_order_and_item_ids_after_save {
1200   my ($self) = @_;
1201
1202   $self->js
1203     ->val('#id', $self->order->id)
1204     ->val('#converted_from_oe_id', '')
1205     ->val('#order_' . $self->nr_key(), $self->order->number);
1206
1207   my $idx = 0;
1208   foreach my $form_item_id (@{ $::form->{orderitem_ids} }) {
1209     next if !$self->order->items_sorted->[$idx]->id;
1210     next if $form_item_id !~ m{^new};
1211     $self->js
1212       ->val ('[name="orderitem_ids[+]"][value="' . $form_item_id . '"]', $self->order->items_sorted->[$idx]->id)
1213       ->val ('#item_' . $form_item_id, $self->order->items_sorted->[$idx]->id)
1214       ->attr('#item_' . $form_item_id, "id", 'item_' . $self->order->items_sorted->[$idx]->id);
1215   } continue {
1216     $idx++;
1217   }
1218   $self->js->val('[name="converted_from_orderitems_ids[+]"]', '');
1219 }
1220
1221 #
1222 # helpers
1223 #
1224
1225 sub init_valid_types {
1226   [ sales_order_type(), purchase_order_type(), sales_quotation_type(), request_quotation_type() ];
1227 }
1228
1229 sub init_type {
1230   my ($self) = @_;
1231
1232   if (none { $::form->{type} eq $_ } @{$self->valid_types}) {
1233     die "Not a valid type for order";
1234   }
1235
1236   $self->type($::form->{type});
1237 }
1238
1239 sub init_cv {
1240   my ($self) = @_;
1241
1242   my $cv = (any { $self->type eq $_ } (sales_order_type(),    sales_quotation_type()))   ? 'customer'
1243          : (any { $self->type eq $_ } (purchase_order_type(), request_quotation_type())) ? 'vendor'
1244          : die "Not a valid type for order";
1245
1246   return $cv;
1247 }
1248
1249 sub init_search_cvpartnumber {
1250   my ($self) = @_;
1251
1252   my $user_prefs = SL::Helper::UserPreferences::PartPickerSearch->new();
1253   my $search_cvpartnumber;
1254   $search_cvpartnumber = !!$user_prefs->get_sales_search_customer_partnumber() if $self->cv eq 'customer';
1255   $search_cvpartnumber = !!$user_prefs->get_purchase_search_makemodel()        if $self->cv eq 'vendor';
1256
1257   return $search_cvpartnumber;
1258 }
1259
1260 sub init_show_update_button {
1261   my ($self) = @_;
1262
1263   !!SL::Helper::UserPreferences::UpdatePositions->new()->get_show_update_button();
1264 }
1265
1266 sub init_p {
1267   SL::Presenter->get;
1268 }
1269
1270 sub init_order {
1271   $_[0]->make_order;
1272 }
1273
1274 sub init_all_price_factors {
1275   SL::DB::Manager::PriceFactor->get_all;
1276 }
1277
1278 sub init_part_picker_classification_ids {
1279   my ($self)    = @_;
1280   my $attribute = 'used_for_' . ($self->type =~ m{sales} ? 'sale' : 'purchase');
1281
1282   return [ map { $_->id } @{ SL::DB::Manager::PartClassification->get_all(where => [ $attribute => 1 ]) } ];
1283 }
1284
1285 sub check_auth {
1286   my ($self) = @_;
1287
1288   my $right_for = { map { $_ => $_.'_edit' } @{$self->valid_types} };
1289
1290   my $right   = $right_for->{ $self->type };
1291   $right    ||= 'DOES_NOT_EXIST';
1292
1293   $::auth->assert($right);
1294 }
1295
1296 # build the selection box for contacts
1297 #
1298 # Needed, if customer/vendor changed.
1299 sub build_contact_select {
1300   my ($self) = @_;
1301
1302   select_tag('order.cp_id', [ $self->order->{$self->cv}->contacts ],
1303     value_key  => 'cp_id',
1304     title_key  => 'full_name_dep',
1305     default    => $self->order->cp_id,
1306     with_empty => 1,
1307     style      => 'width: 300px',
1308   );
1309 }
1310
1311 # build the selection box for shiptos
1312 #
1313 # Needed, if customer/vendor changed.
1314 sub build_shipto_select {
1315   my ($self) = @_;
1316
1317   select_tag('order.shipto_id',
1318              [ {displayable_id => t8("No/individual shipping address"), shipto_id => ''}, $self->order->{$self->cv}->shipto ],
1319              value_key  => 'shipto_id',
1320              title_key  => 'displayable_id',
1321              default    => $self->order->shipto_id,
1322              with_empty => 0,
1323              style      => 'width: 300px',
1324   );
1325 }
1326
1327 # build the inputs for the cusom shipto dialog
1328 #
1329 # Needed, if customer/vendor changed.
1330 sub build_shipto_inputs {
1331   my ($self) = @_;
1332
1333   my $content = $self->p->render('common/_ship_to_dialog',
1334                                  vc_obj      => $self->order->customervendor,
1335                                  cs_obj      => $self->order->custom_shipto,
1336                                  cvars       => $self->order->custom_shipto->cvars_by_config,
1337                                  id_selector => '#order_shipto_id');
1338
1339   div_tag($content, id => 'shipto_inputs');
1340 }
1341
1342 # render the info line for business
1343 #
1344 # Needed, if customer/vendor changed.
1345 sub build_business_info_row
1346 {
1347   $_[0]->p->render('order/tabs/_business_info_row', SELF => $_[0]);
1348 }
1349
1350 # build the rows for displaying taxes
1351 #
1352 # Called if amounts where recalculated and redisplayed.
1353 sub build_tax_rows {
1354   my ($self) = @_;
1355
1356   my $rows_as_html;
1357   foreach my $tax (sort { $a->{tax}->rate cmp $b->{tax}->rate } @{ $self->{taxes} }) {
1358     $rows_as_html .= $self->p->render('order/tabs/_tax_row', TAX => $tax, TAXINCLUDED => $self->order->taxincluded);
1359   }
1360   return $rows_as_html;
1361 }
1362
1363
1364 sub render_price_dialog {
1365   my ($self, $record_item) = @_;
1366
1367   my $price_source = SL::PriceSource->new(record_item => $record_item, record => $self->order);
1368
1369   $self->js
1370     ->run(
1371       'kivi.io.price_chooser_dialog',
1372       t8('Available Prices'),
1373       $self->render('order/tabs/_price_sources_dialog', { output => 0 }, price_source => $price_source)
1374     )
1375     ->reinit_widgets;
1376
1377 #   if (@errors) {
1378 #     $self->js->text('#dialog_flash_error_content', join ' ', @errors);
1379 #     $self->js->show('#dialog_flash_error');
1380 #   }
1381
1382   $self->js->render;
1383 }
1384
1385 sub load_order {
1386   my ($self) = @_;
1387
1388   return if !$::form->{id};
1389
1390   $self->order(SL::DB::Order->new(id => $::form->{id})->load);
1391
1392   # Add an empty custom shipto to the order, so that the dialog can render the cvar inputs.
1393   # You need a custom shipto object to call cvars_by_config to get the cvars.
1394   $self->order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => [])) if !$self->order->custom_shipto;
1395
1396   return $self->order;
1397 }
1398
1399 # load or create a new order object
1400 #
1401 # And assign changes from the form to this object.
1402 # If the order is loaded from db, check if items are deleted in the form,
1403 # remove them form the object and collect them for removing from db on saving.
1404 # Then create/update items from form (via make_item) and add them.
1405 sub make_order {
1406   my ($self) = @_;
1407
1408   # add_items adds items to an order with no items for saving, but they cannot
1409   # be retrieved via items until the order is saved. Adding empty items to new
1410   # order here solves this problem.
1411   my $order;
1412   $order   = SL::DB::Order->new(id => $::form->{id})->load(with => [ 'orderitems', 'orderitems.part' ]) if $::form->{id};
1413   $order ||= SL::DB::Order->new(orderitems  => [],
1414                                 quotation   => (any { $self->type eq $_ } (sales_quotation_type(), request_quotation_type())),
1415                                 currency_id => $::instance_conf->get_currency_id(),);
1416
1417   my $cv_id_method = $self->cv . '_id';
1418   if (!$::form->{id} && $::form->{$cv_id_method}) {
1419     $order->$cv_id_method($::form->{$cv_id_method});
1420     setup_order_from_cv($order);
1421   }
1422
1423   my $form_orderitems                  = delete $::form->{order}->{orderitems};
1424   my $form_periodic_invoices_config    = delete $::form->{order}->{periodic_invoices_config};
1425
1426   $order->assign_attributes(%{$::form->{order}});
1427
1428   $self->setup_custom_shipto_from_form($order, $::form);
1429
1430   if (my $periodic_invoices_config_attrs = $form_periodic_invoices_config ? SL::YAML::Load($form_periodic_invoices_config) : undef) {
1431     my $periodic_invoices_config = $order->periodic_invoices_config || $order->periodic_invoices_config(SL::DB::PeriodicInvoicesConfig->new);
1432     $periodic_invoices_config->assign_attributes(%$periodic_invoices_config_attrs);
1433   }
1434
1435   # remove deleted items
1436   $self->item_ids_to_delete([]);
1437   foreach my $idx (reverse 0..$#{$order->orderitems}) {
1438     my $item = $order->orderitems->[$idx];
1439     if (none { $item->id == $_->{id} } @{$form_orderitems}) {
1440       splice @{$order->orderitems}, $idx, 1;
1441       push @{$self->item_ids_to_delete}, $item->id;
1442     }
1443   }
1444
1445   my @items;
1446   my $pos = 1;
1447   foreach my $form_attr (@{$form_orderitems}) {
1448     my $item = make_item($order, $form_attr);
1449     $item->position($pos);
1450     push @items, $item;
1451     $pos++;
1452   }
1453   $order->add_items(grep {!$_->id} @items);
1454
1455   return $order;
1456 }
1457
1458 # create or update items from form
1459 #
1460 # Make item objects from form values. For items already existing read from db.
1461 # Create a new item else. And assign attributes.
1462 sub make_item {
1463   my ($record, $attr) = @_;
1464
1465   my $item;
1466   $item = first { $_->id == $attr->{id} } @{$record->items} if $attr->{id};
1467
1468   my $is_new = !$item;
1469
1470   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1471   # they cannot be retrieved via custom_variables until the order/orderitem is
1472   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1473   $item ||= SL::DB::OrderItem->new(custom_variables => []);
1474
1475   $item->assign_attributes(%$attr);
1476
1477   if ($is_new) {
1478     my $texts = get_part_texts($item->part, $record->language_id);
1479     $item->longdescription($texts->{longdescription})              if !defined $attr->{longdescription};
1480     $item->project_id($record->globalproject_id)                   if !defined $attr->{project_id};
1481     $item->lastcost($record->is_sales ? $item->part->lastcost : 0) if !defined $attr->{lastcost_as_number};
1482   }
1483
1484   return $item;
1485 }
1486
1487 # create a new item
1488 #
1489 # This is used to add one item
1490 sub new_item {
1491   my ($record, $attr) = @_;
1492
1493   my $item = SL::DB::OrderItem->new;
1494
1495   # Remove attributes where the user left or set the inputs empty.
1496   # So these attributes will be undefined and we can distinguish them
1497   # from zero later on.
1498   for (qw(qty_as_number sellprice_as_number discount_as_percent)) {
1499     delete $attr->{$_} if $attr->{$_} eq '';
1500   }
1501
1502   $item->assign_attributes(%$attr);
1503
1504   my $part         = SL::DB::Part->new(id => $attr->{parts_id})->load;
1505   my $price_source = SL::PriceSource->new(record_item => $item, record => $record);
1506
1507   $item->unit($part->unit) if !$item->unit;
1508
1509   my $price_src;
1510   if ( $part->is_assortment ) {
1511     # add assortment items with price 0, as the components carry the price
1512     $price_src = $price_source->price_from_source("");
1513     $price_src->price(0);
1514   } elsif (defined $item->sellprice) {
1515     $price_src = $price_source->price_from_source("");
1516     $price_src->price($item->sellprice);
1517   } else {
1518     $price_src = $price_source->best_price
1519                ? $price_source->best_price
1520                : $price_source->price_from_source("");
1521     $price_src->price($::form->round_amount($price_src->price / $record->exchangerate, 5)) if $record->exchangerate;
1522     $price_src->price(0) if !$price_source->best_price;
1523   }
1524
1525   my $discount_src;
1526   if (defined $item->discount) {
1527     $discount_src = $price_source->discount_from_source("");
1528     $discount_src->discount($item->discount);
1529   } else {
1530     $discount_src = $price_source->best_discount
1531                   ? $price_source->best_discount
1532                   : $price_source->discount_from_source("");
1533     $discount_src->discount(0) if !$price_source->best_discount;
1534   }
1535
1536   my %new_attr;
1537   $new_attr{part}                   = $part;
1538   $new_attr{description}            = $part->description     if ! $item->description;
1539   $new_attr{qty}                    = 1.0                    if ! $item->qty;
1540   $new_attr{price_factor_id}        = $part->price_factor_id if ! $item->price_factor_id;
1541   $new_attr{sellprice}              = $price_src->price;
1542   $new_attr{discount}               = $discount_src->discount;
1543   $new_attr{active_price_source}    = $price_src;
1544   $new_attr{active_discount_source} = $discount_src;
1545   $new_attr{longdescription}        = $part->notes           if ! defined $attr->{longdescription};
1546   $new_attr{project_id}             = $record->globalproject_id;
1547   $new_attr{lastcost}               = $record->is_sales ? $part->lastcost : 0;
1548
1549   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1550   # they cannot be retrieved via custom_variables until the order/orderitem is
1551   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1552   $new_attr{custom_variables} = [];
1553
1554   my $texts = get_part_texts($part, $record->language_id, description => $new_attr{description}, longdescription => $new_attr{longdescription});
1555
1556   $item->assign_attributes(%new_attr, %{ $texts });
1557
1558   return $item;
1559 }
1560
1561 sub setup_order_from_cv {
1562   my ($order) = @_;
1563
1564   $order->$_($order->customervendor->$_) for (qw(taxzone_id payment_id delivery_term_id currency_id));
1565
1566   $order->intnotes($order->customervendor->notes);
1567
1568   if ($order->is_sales) {
1569     $order->salesman_id($order->customer->salesman_id || SL::DB::Manager::Employee->current->id);
1570     $order->taxincluded(defined($order->customer->taxincluded_checked)
1571                         ? $order->customer->taxincluded_checked
1572                         : $::myconfig{taxincluded_checked});
1573   }
1574
1575 }
1576
1577 # setup custom shipto from form
1578 #
1579 # The dialog returns form variables starting with 'shipto' and cvars starting
1580 # with 'shiptocvar_'.
1581 # Mark it to be deleted if a shipto from master data is selected
1582 # (i.e. order has a shipto).
1583 # Else, update or create a new custom shipto. If the fields are empty, it
1584 # will not be saved on save.
1585 sub setup_custom_shipto_from_form {
1586   my ($self, $order, $form) = @_;
1587
1588   if ($order->shipto) {
1589     $self->is_custom_shipto_to_delete(1);
1590   } else {
1591     my $custom_shipto = $order->custom_shipto || $order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => []));
1592
1593     my $shipto_cvars  = {map { my ($key) = m{^shiptocvar_(.+)}; $key => delete $form->{$_}} grep { m{^shiptocvar_} } keys %$form};
1594     my $shipto_attrs  = {map {                                  $_   => delete $form->{$_}} grep { m{^shipto}      } keys %$form};
1595
1596     $custom_shipto->assign_attributes(%$shipto_attrs);
1597     $custom_shipto->cvar_by_name($_)->value($shipto_cvars->{$_}) for keys %$shipto_cvars;
1598   }
1599 }
1600
1601 # recalculate prices and taxes
1602 #
1603 # Using the PriceTaxCalculator. Store linetotals in the item objects.
1604 sub recalc {
1605   my ($self) = @_;
1606
1607   my %pat = $self->order->calculate_prices_and_taxes();
1608
1609   $self->{taxes} = [];
1610   foreach my $tax_id (keys %{ $pat{taxes_by_tax_id} }) {
1611     my $netamount = sum0 map { $pat{amounts}->{$_}->{amount} } grep { $pat{amounts}->{$_}->{tax_id} == $tax_id } keys %{ $pat{amounts} };
1612
1613     push(@{ $self->{taxes} }, { amount    => $pat{taxes_by_tax_id}->{$tax_id},
1614                                 netamount => $netamount,
1615                                 tax       => SL::DB::Tax->new(id => $tax_id)->load });
1616   }
1617   pairwise { $a->{linetotal} = $b->{linetotal} } @{$self->order->items_sorted}, @{$pat{items}};
1618 }
1619
1620 # get data for saving, printing, ..., that is not changed in the form
1621 #
1622 # Only cvars for now.
1623 sub get_unalterable_data {
1624   my ($self) = @_;
1625
1626   foreach my $item (@{ $self->order->items }) {
1627     # autovivify all cvars that are not in the form (cvars_by_config can do it).
1628     # workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
1629     foreach my $var (@{ $item->cvars_by_config }) {
1630       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
1631     }
1632     $item->parse_custom_variable_values;
1633   }
1634 }
1635
1636 # delete the order
1637 #
1638 # And remove related files in the spool directory
1639 sub delete {
1640   my ($self) = @_;
1641
1642   my $errors = [];
1643   my $db     = $self->order->db;
1644
1645   $db->with_transaction(
1646     sub {
1647       my @spoolfiles = grep { $_ } map { $_->spoolfile } @{ SL::DB::Manager::Status->get_all(where => [ trans_id => $self->order->id ]) };
1648       $self->order->delete;
1649       my $spool = $::lx_office_conf{paths}->{spool};
1650       unlink map { "$spool/$_" } @spoolfiles if $spool;
1651
1652       $self->save_history('DELETED');
1653
1654       1;
1655   }) || push(@{$errors}, $db->error);
1656
1657   return $errors;
1658 }
1659
1660 # save the order
1661 #
1662 # And delete items that are deleted in the form.
1663 sub save {
1664   my ($self) = @_;
1665
1666   my $errors = [];
1667   my $db     = $self->order->db;
1668
1669   $db->with_transaction(sub {
1670     # delete custom shipto if it is to be deleted or if it is empty
1671     if ($self->order->custom_shipto && ($self->is_custom_shipto_to_delete || $self->order->custom_shipto->is_empty)) {
1672       $self->order->custom_shipto->delete if $self->order->custom_shipto->shipto_id;
1673       $self->order->custom_shipto(undef);
1674     }
1675
1676     SL::DB::OrderItem->new(id => $_)->delete for @{$self->item_ids_to_delete || []};
1677     $self->order->save(cascade => 1);
1678
1679     # link records
1680     if ($::form->{converted_from_oe_id}) {
1681       my @converted_from_oe_ids = split ' ', $::form->{converted_from_oe_id};
1682
1683       foreach my $converted_from_oe_id (@converted_from_oe_ids) {
1684         my $src = SL::DB::Order->new(id => $converted_from_oe_id)->load;
1685         $src->update_attributes(closed => 1) if $src->type =~ /_quotation$/;
1686         $src->link_to_record($self->order);
1687       }
1688       if (scalar @{ $::form->{converted_from_orderitems_ids} || [] }) {
1689         my $idx = 0;
1690         foreach (@{ $self->order->items_sorted }) {
1691           my $from_id = $::form->{converted_from_orderitems_ids}->[$idx];
1692           next if !$from_id;
1693           SL::DB::RecordLink->new(from_table => 'orderitems',
1694                                   from_id    => $from_id,
1695                                   to_table   => 'orderitems',
1696                                   to_id      => $_->id
1697           )->save;
1698           $idx++;
1699         }
1700       }
1701
1702       $self->link_requirement_specs_linking_to_created_from_objects(@converted_from_oe_ids);
1703     }
1704
1705     $self->save_history('SAVED');
1706
1707     1;
1708   }) || push(@{$errors}, $db->error);
1709
1710   return $errors;
1711 }
1712
1713 sub workflow_sales_or_request_for_quotation {
1714   my ($self) = @_;
1715
1716   # always save
1717   my $errors = $self->save();
1718
1719   if (scalar @{ $errors }) {
1720     $self->js->flash('error', $_) for @{ $errors };
1721     return $self->js->render();
1722   }
1723
1724   my $destination_type = $::form->{type} eq sales_order_type() ? sales_quotation_type() : request_quotation_type();
1725
1726   $self->order(SL::DB::Order->new_from($self->order, destination_type => $destination_type));
1727   $self->{converted_from_oe_id} = delete $::form->{id};
1728
1729   # set item ids to new fake id, to identify them as new items
1730   foreach my $item (@{$self->order->items_sorted}) {
1731     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1732   }
1733
1734   # change form type
1735   $::form->{type} = $destination_type;
1736   $self->type($self->init_type);
1737   $self->cv  ($self->init_cv);
1738   $self->check_auth;
1739
1740   $self->recalc();
1741   $self->get_unalterable_data();
1742   $self->pre_render();
1743
1744   # trigger rendering values for second row as hidden, because they
1745   # are loaded only on demand. So we need to keep the values from the
1746   # source.
1747   $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
1748
1749   $self->render(
1750     'order/form',
1751     title => $self->get_title_for('edit'),
1752     %{$self->{template_args}}
1753   );
1754 }
1755
1756 sub workflow_sales_or_purchase_order {
1757   my ($self) = @_;
1758
1759   # always save
1760   my $errors = $self->save();
1761
1762   if (scalar @{ $errors }) {
1763     $self->js->flash('error', $_) foreach @{ $errors };
1764     return $self->js->render();
1765   }
1766
1767   my $destination_type = $::form->{type} eq sales_quotation_type()   ? sales_order_type()
1768                        : $::form->{type} eq request_quotation_type() ? purchase_order_type()
1769                        : $::form->{type} eq purchase_order_type()    ? sales_order_type()
1770                        : $::form->{type} eq sales_order_type()       ? purchase_order_type()
1771                        : '';
1772
1773   # check for direct delivery
1774   # copy shipto in custom shipto (custom shipto will be copied by new_from() in case)
1775   my $custom_shipto;
1776   if (   $::form->{type} eq sales_order_type() && $destination_type eq purchase_order_type()
1777       && $::form->{use_shipto} && $self->order->shipto) {
1778     $custom_shipto = $self->order->shipto->clone('SL::DB::Order');
1779   }
1780
1781   $self->order(SL::DB::Order->new_from($self->order, destination_type => $destination_type));
1782   $self->{converted_from_oe_id} = delete $::form->{id};
1783
1784   # set item ids to new fake id, to identify them as new items
1785   foreach my $item (@{$self->order->items_sorted}) {
1786     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1787   }
1788
1789   if ($::form->{type} eq sales_order_type() && $destination_type eq purchase_order_type()) {
1790     if ($::form->{use_shipto}) {
1791       $self->order->custom_shipto($custom_shipto) if $custom_shipto;
1792     } else {
1793       # remove any custom shipto if not wanted
1794       $self->order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => []));
1795     }
1796   }
1797
1798   # change form type
1799   $::form->{type} = $destination_type;
1800   $self->type($self->init_type);
1801   $self->cv  ($self->init_cv);
1802   $self->check_auth;
1803
1804   $self->recalc();
1805   $self->get_unalterable_data();
1806   $self->pre_render();
1807
1808   # trigger rendering values for second row as hidden, because they
1809   # are loaded only on demand. So we need to keep the values from the
1810   # source.
1811   $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
1812
1813   $self->render(
1814     'order/form',
1815     title => $self->get_title_for('edit'),
1816     %{$self->{template_args}}
1817   );
1818 }
1819
1820
1821 sub pre_render {
1822   my ($self) = @_;
1823
1824   $self->{all_taxzones}               = SL::DB::Manager::TaxZone->get_all_sorted();
1825   $self->{all_currencies}             = SL::DB::Manager::Currency->get_all_sorted();
1826   $self->{all_departments}            = SL::DB::Manager::Department->get_all_sorted();
1827   $self->{all_languages}              = SL::DB::Manager::Language->get_all_sorted();
1828   $self->{all_employees}              = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->employee_id,
1829                                                                                               deleted => 0 ] ],
1830                                                                            sort_by => 'name');
1831   $self->{all_salesmen}               = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->salesman_id,
1832                                                                                               deleted => 0 ] ],
1833                                                                            sort_by => 'name');
1834   $self->{all_payment_terms}          = SL::DB::Manager::PaymentTerm->get_all_sorted(where => [ or => [ id => $self->order->payment_id,
1835                                                                                                         obsolete => 0 ] ]);
1836   $self->{all_delivery_terms}         = SL::DB::Manager::DeliveryTerm->get_all_sorted();
1837   $self->{current_employee_id}        = SL::DB::Manager::Employee->current->id;
1838   $self->{periodic_invoices_status}   = $self->get_periodic_invoices_status($self->order->periodic_invoices_config);
1839   $self->{order_probabilities}        = [ map { { title => ($_ * 10) . '%', id => $_ * 10 } } (0..10) ];
1840   $self->{positions_scrollbar_height} = SL::Helper::UserPreferences::PositionsScrollbar->new()->get_height();
1841
1842   my $print_form = Form->new('');
1843   $print_form->{type}        = $self->type;
1844   $print_form->{printers}    = SL::DB::Manager::Printer->get_all_sorted;
1845   $self->{print_options}     = SL::Helper::PrintOptions->get_print_options(
1846     form => $print_form,
1847     options => {dialog_name_prefix => 'print_options.',
1848                 show_headers       => 1,
1849                 no_queue           => 1,
1850                 no_postscript      => 1,
1851                 no_opendocument    => 0,
1852                 no_html            => 1},
1853   );
1854
1855   foreach my $item (@{$self->order->orderitems}) {
1856     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
1857     $item->active_price_source(   $price_source->price_from_source(   $item->active_price_source   ));
1858     $item->active_discount_source($price_source->discount_from_source($item->active_discount_source));
1859   }
1860
1861   if (any { $self->type eq $_ } (sales_order_type(), purchase_order_type())) {
1862     # Calculate shipped qtys here to prevent calling calculate for every item via the items method.
1863     # Do not use write_to_objects to prevent order->delivered to be set, because this should be
1864     # the value from db, which can be set manually or is set when linked delivery orders are saved.
1865     SL::Helper::ShippedQty->new->calculate($self->order)->write_to(\@{$self->order->items});
1866   }
1867
1868   if ($self->order->number && $::instance_conf->get_webdav) {
1869     my $webdav = SL::Webdav->new(
1870       type     => $self->type,
1871       number   => $self->order->number,
1872     );
1873     my @all_objects = $webdav->get_all_objects;
1874     @{ $self->{template_args}->{WEBDAV} } = map { { name => $_->filename,
1875                                                     type => t8('File'),
1876                                                     link => File::Spec->catfile($_->full_filedescriptor),
1877                                                 } } @all_objects;
1878   }
1879
1880   if (   (any { $self->type eq $_ } (sales_quotation_type(), sales_order_type()))
1881       && $::instance_conf->get_transport_cost_reminder_article_number_id ) {
1882     $self->{template_args}->{transport_cost_reminder_article} = SL::DB::Part->new(id => $::instance_conf->get_transport_cost_reminder_article_number_id)->load;
1883   }
1884
1885   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
1886
1887   $::request->{layout}->use_javascript("${_}.js") for qw(kivi.SalesPurchase kivi.Order kivi.File ckeditor/ckeditor ckeditor/adapters/jquery
1888                                                          edit_periodic_invoices_config calculate_qty kivi.Validator follow_up show_history);
1889   $self->setup_edit_action_bar;
1890 }
1891
1892 sub setup_edit_action_bar {
1893   my ($self, %params) = @_;
1894
1895   my $deletion_allowed = (any { $self->type eq $_ } (sales_quotation_type(), request_quotation_type()))
1896                       || (($self->type eq sales_order_type())    && $::instance_conf->get_sales_order_show_delete)
1897                       || (($self->type eq purchase_order_type()) && $::instance_conf->get_purchase_order_show_delete);
1898
1899   my @req_trans_cost_art = qw(kivi.Order.check_transport_cost_article_presence) x!!$::instance_conf->get_transport_cost_reminder_article_number_id;
1900   my @req_cusordnumber   = qw(kivi.Order.check_cusordnumber_presence)           x($self->type eq sales_order_type() && $::instance_conf->get_order_warn_no_cusordnumber);
1901
1902   for my $bar ($::request->layout->get('actionbar')) {
1903     $bar->add(
1904       combobox => [
1905         action => [
1906           t8('Save'),
1907           call      => [ 'kivi.Order.save', 'save', $::instance_conf->get_order_warn_duplicate_parts,
1908                                                     $::instance_conf->get_order_warn_no_deliverydate,
1909           ],
1910           checks    => [ 'kivi.Order.check_save_active_periodic_invoices', ['kivi.validate_form','#order_form'],
1911                          @req_trans_cost_art, @req_cusordnumber,
1912           ],
1913         ],
1914         action => [
1915           t8('Save as new'),
1916           call      => [ 'kivi.Order.save', 'save_as_new', $::instance_conf->get_order_warn_duplicate_parts ],
1917           checks    => [ 'kivi.Order.check_save_active_periodic_invoices',
1918                          @req_trans_cost_art, @req_cusordnumber,
1919           ],
1920           disabled  => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1921         ],
1922       ], # end of combobox "Save"
1923
1924       combobox => [
1925         action => [
1926           t8('Workflow'),
1927         ],
1928         action => [
1929           t8('Save and Quotation'),
1930           submit   => [ '#order_form', { action => "Order/sales_quotation" } ],
1931           checks   => [ @req_trans_cost_art, @req_cusordnumber ],
1932           only_if  => (any { $self->type eq $_ } (sales_order_type())),
1933         ],
1934         action => [
1935           t8('Save and RFQ'),
1936           submit   => [ '#order_form', { action => "Order/request_for_quotation" } ],
1937           only_if  => (any { $self->type eq $_ } (purchase_order_type())),
1938         ],
1939         action => [
1940           t8('Save and Sales Order'),
1941           submit   => [ '#order_form', { action => "Order/sales_order" } ],
1942           checks   => [ @req_trans_cost_art ],
1943           only_if  => (any { $self->type eq $_ } (sales_quotation_type(), purchase_order_type())),
1944         ],
1945         action => [
1946           t8('Save and Purchase Order'),
1947           call      => [ 'kivi.Order.purchase_order_check_for_direct_delivery' ],
1948           checks    => [ @req_trans_cost_art, @req_cusordnumber ],
1949           only_if   => (any { $self->type eq $_ } (sales_order_type(), request_quotation_type())),
1950         ],
1951         action => [
1952           t8('Save and Delivery Order'),
1953           call      => [ 'kivi.Order.save', 'save_and_delivery_order', $::instance_conf->get_order_warn_duplicate_parts,
1954                                                                        $::instance_conf->get_order_warn_no_deliverydate,
1955                                                                                                                         ],
1956           checks    => [ 'kivi.Order.check_save_active_periodic_invoices',
1957                          @req_trans_cost_art, @req_cusordnumber,
1958           ],
1959           only_if   => (any { $self->type eq $_ } (sales_order_type(), purchase_order_type()))
1960         ],
1961         action => [
1962           t8('Save and Invoice'),
1963           call      => [ 'kivi.Order.save', 'save_and_invoice', $::instance_conf->get_order_warn_duplicate_parts ],
1964           checks    => [ 'kivi.Order.check_save_active_periodic_invoices',
1965                          @req_trans_cost_art, @req_cusordnumber,
1966           ],
1967         ],
1968         action => [
1969           t8('Save and AP Transaction'),
1970           call      => [ 'kivi.Order.save', 'save_and_ap_transaction', $::instance_conf->get_order_warn_duplicate_parts ],
1971           only_if   => (any { $self->type eq $_ } (purchase_order_type()))
1972         ],
1973
1974       ], # end of combobox "Workflow"
1975
1976       combobox => [
1977         action => [
1978           t8('Export'),
1979         ],
1980         action => [
1981           t8('Save and preview PDF'),
1982           call   => [ 'kivi.Order.save', 'preview_pdf', $::instance_conf->get_order_warn_duplicate_parts,
1983                                                         $::instance_conf->get_order_warn_no_deliverydate,
1984                     ],
1985           checks => [ @req_trans_cost_art, @req_cusordnumber ],
1986         ],
1987         action => [
1988           t8('Save and print'),
1989           call   => [ 'kivi.Order.show_print_options', $::instance_conf->get_order_warn_duplicate_parts,
1990                                                        $::instance_conf->get_order_warn_no_deliverydate,
1991                     ],
1992           checks => [ @req_trans_cost_art, @req_cusordnumber ],
1993         ],
1994         action => [
1995           t8('Save and E-mail'),
1996           id   => 'save_and_email_action',
1997           call => [ 'kivi.Order.save', 'save_and_show_email_dialog', $::instance_conf->get_order_warn_duplicate_parts,
1998                                                                      $::instance_conf->get_order_warn_no_deliverydate,
1999                   ],
2000           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
2001         ],
2002         action => [
2003           t8('Download attachments of all parts'),
2004           call     => [ 'kivi.File.downloadOrderitemsFiles', $::form->{type}, $::form->{id} ],
2005           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
2006           only_if  => $::instance_conf->get_doc_storage,
2007         ],
2008       ], # end of combobox "Export"
2009
2010       action => [
2011         t8('Delete'),
2012         call     => [ 'kivi.Order.delete_order' ],
2013         confirm  => $::locale->text('Do you really want to delete this object?'),
2014         disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
2015         only_if  => $deletion_allowed,
2016       ],
2017
2018       combobox => [
2019         action => [
2020           t8('more')
2021         ],
2022         action => [
2023           t8('History'),
2024           call     => [ 'set_history_window', $self->order->id, 'id' ],
2025           disabled => !$self->order->id ? t8('This record has not been saved yet.') : undef,
2026         ],
2027         action => [
2028           t8('Follow-Up'),
2029           call     => [ 'kivi.Order.follow_up_window' ],
2030           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
2031           only_if  => $::auth->assert('productivity', 1),
2032         ],
2033       ], # end of combobox "more"
2034     );
2035   }
2036 }
2037
2038 sub generate_pdf {
2039   my ($order, $pdf_ref, $params) = @_;
2040
2041   my @errors = ();
2042
2043   my $print_form = Form->new('');
2044   $print_form->{type}        = $order->type;
2045   $print_form->{formname}    = $params->{formname} || $order->type;
2046   $print_form->{format}      = $params->{format}   || 'pdf';
2047   $print_form->{media}       = $params->{media}    || 'file';
2048   $print_form->{groupitems}  = $params->{groupitems};
2049   $print_form->{printer_id}  = $params->{printer_id};
2050   $print_form->{media}       = 'file'                             if $print_form->{media} eq 'screen';
2051
2052   $order->language($params->{language});
2053   $order->flatten_to_form($print_form, format_amounts => 1);
2054
2055   my $template_ext;
2056   my $template_type;
2057   if ($print_form->{format} =~ /(opendocument|oasis)/i) {
2058     $template_ext  = 'odt';
2059     $template_type = 'OpenDocument';
2060   }
2061
2062   # search for the template
2063   my ($template_file, @template_files) = SL::Helper::CreatePDF->find_template(
2064     name        => $print_form->{formname},
2065     extension   => $template_ext,
2066     email       => $print_form->{media} eq 'email',
2067     language    => $params->{language},
2068     printer_id  => $print_form->{printer_id},
2069   );
2070
2071   if (!defined $template_file) {
2072     push @errors, $::locale->text('Cannot find matching template for this print request. Please contact your template maintainer. I tried these: #1.', join ', ', map { "'$_'"} @template_files);
2073   }
2074
2075   return @errors if scalar @errors;
2076
2077   $print_form->throw_on_error(sub {
2078     eval {
2079       $print_form->prepare_for_printing;
2080
2081       $$pdf_ref = SL::Helper::CreatePDF->create_pdf(
2082         format        => $print_form->{format},
2083         template_type => $template_type,
2084         template      => $template_file,
2085         variables     => $print_form,
2086         variable_content_types => {
2087           longdescription => 'html',
2088           partnotes       => 'html',
2089           notes           => 'html',
2090         },
2091       );
2092       1;
2093     } || push @errors, ref($EVAL_ERROR) eq 'SL::X::FormError' ? $EVAL_ERROR->error : $EVAL_ERROR;
2094   });
2095
2096   return @errors;
2097 }
2098
2099 sub get_files_for_email_dialog {
2100   my ($self) = @_;
2101
2102   my %files = map { ($_ => []) } qw(versions files vc_files part_files);
2103
2104   return %files if !$::instance_conf->get_doc_storage;
2105
2106   if ($self->order->id) {
2107     $files{versions} = [ SL::File->get_all_versions(object_id => $self->order->id,              object_type => $self->order->type, file_type => 'document') ];
2108     $files{files}    = [ SL::File->get_all(         object_id => $self->order->id,              object_type => $self->order->type, file_type => 'attachment') ];
2109     $files{vc_files} = [ SL::File->get_all(         object_id => $self->order->{$self->cv}->id, object_type => $self->cv,          file_type => 'attachment') ];
2110     $files{project_files} = [ SL::File->get_all(    object_id => $self->order->globalproject_id, object_type => 'project',         file_type => 'attachment') ];
2111   }
2112
2113   my @parts =
2114     uniq_by { $_->{id} }
2115     map {
2116       +{ id         => $_->part->id,
2117          partnumber => $_->part->partnumber }
2118     } @{$self->order->items_sorted};
2119
2120   foreach my $part (@parts) {
2121     my @pfiles = SL::File->get_all(object_id => $part->{id}, object_type => 'part');
2122     push @{ $files{part_files} }, map { +{ %{ $_ }, partnumber => $part->{partnumber} } } @pfiles;
2123   }
2124
2125   foreach my $key (keys %files) {
2126     $files{$key} = [ sort_by { lc $_->{db_file}->{file_name} } @{ $files{$key} } ];
2127   }
2128
2129   return %files;
2130 }
2131
2132 sub make_periodic_invoices_config_from_yaml {
2133   my ($yaml_config) = @_;
2134
2135   return if !$yaml_config;
2136   my $attr = SL::YAML::Load($yaml_config);
2137   return if 'HASH' ne ref $attr;
2138   return SL::DB::PeriodicInvoicesConfig->new(%$attr);
2139 }
2140
2141
2142 sub get_periodic_invoices_status {
2143   my ($self, $config) = @_;
2144
2145   return                      if $self->type ne sales_order_type();
2146   return t8('not configured') if !$config;
2147
2148   my $active = ('HASH' eq ref $config)                           ? $config->{active}
2149              : ('SL::DB::PeriodicInvoicesConfig' eq ref $config) ? $config->active
2150              :                                                     die "Cannot get status of periodic invoices config";
2151
2152   return $active ? t8('active') : t8('inactive');
2153 }
2154
2155 sub get_title_for {
2156   my ($self, $action) = @_;
2157
2158   return '' if none { lc($action)} qw(add edit);
2159
2160   # for locales:
2161   # $::locale->text("Add Sales Order");
2162   # $::locale->text("Add Purchase Order");
2163   # $::locale->text("Add Quotation");
2164   # $::locale->text("Add Request for Quotation");
2165   # $::locale->text("Edit Sales Order");
2166   # $::locale->text("Edit Purchase Order");
2167   # $::locale->text("Edit Quotation");
2168   # $::locale->text("Edit Request for Quotation");
2169
2170   $action = ucfirst(lc($action));
2171   return $self->type eq sales_order_type()       ? $::locale->text("$action Sales Order")
2172        : $self->type eq purchase_order_type()    ? $::locale->text("$action Purchase Order")
2173        : $self->type eq sales_quotation_type()   ? $::locale->text("$action Quotation")
2174        : $self->type eq request_quotation_type() ? $::locale->text("$action Request for Quotation")
2175        : '';
2176 }
2177
2178 sub get_item_cvpartnumber {
2179   my ($self, $item) = @_;
2180
2181   return if !$self->search_cvpartnumber;
2182   return if !$self->order->customervendor;
2183
2184   if ($self->cv eq 'vendor') {
2185     my @mms = grep { $_->make eq $self->order->customervendor->id } @{$item->part->makemodels};
2186     $item->{cvpartnumber} = $mms[0]->model if scalar @mms;
2187   } elsif ($self->cv eq 'customer') {
2188     my @cps = grep { $_->customer_id eq $self->order->customervendor->id } @{$item->part->customerprices};
2189     $item->{cvpartnumber} = $cps[0]->customer_partnumber if scalar @cps;
2190   }
2191 }
2192
2193 sub get_part_texts {
2194   my ($part_or_id, $language_or_id, %defaults) = @_;
2195
2196   my $part        = ref($part_or_id)     ? $part_or_id         : SL::DB::Part->load_cached($part_or_id);
2197   my $language_id = ref($language_or_id) ? $language_or_id->id : $language_or_id;
2198   my $texts       = {
2199     description     => $defaults{description}     // $part->description,
2200     longdescription => $defaults{longdescription} // $part->notes,
2201   };
2202
2203   return $texts unless $language_id;
2204
2205   my $translation = SL::DB::Manager::Translation->get_first(
2206     where => [
2207       parts_id    => $part->id,
2208       language_id => $language_id,
2209     ]);
2210
2211   $texts->{description}     = $translation->translation     if $translation && $translation->translation;
2212   $texts->{longdescription} = $translation->longdescription if $translation && $translation->longdescription;
2213
2214   return $texts;
2215 }
2216
2217 sub sales_order_type {
2218   'sales_order';
2219 }
2220
2221 sub purchase_order_type {
2222   'purchase_order';
2223 }
2224
2225 sub sales_quotation_type {
2226   'sales_quotation';
2227 }
2228
2229 sub request_quotation_type {
2230   'request_quotation';
2231 }
2232
2233 sub nr_key {
2234   return $_[0]->type eq sales_order_type()       ? 'ordnumber'
2235        : $_[0]->type eq purchase_order_type()    ? 'ordnumber'
2236        : $_[0]->type eq sales_quotation_type()   ? 'quonumber'
2237        : $_[0]->type eq request_quotation_type() ? 'quonumber'
2238        : '';
2239 }
2240
2241 sub save_and_redirect_to {
2242   my ($self, %params) = @_;
2243
2244   my $errors = $self->save();
2245
2246   if (scalar @{ $errors }) {
2247     $self->js->flash('error', $_) foreach @{ $errors };
2248     return $self->js->render();
2249   }
2250
2251   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
2252            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
2253            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
2254            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
2255            : '';
2256   flash_later('info', $text);
2257
2258   $self->redirect_to(%params, id => $self->order->id);
2259 }
2260
2261 sub save_history {
2262   my ($self, $addition) = @_;
2263
2264   my $number_type = $self->order->type =~ m{order} ? 'ordnumber' : 'quonumber';
2265   my $snumbers    = $number_type . '_' . $self->order->$number_type;
2266
2267   SL::DB::History->new(
2268     trans_id    => $self->order->id,
2269     employee_id => SL::DB::Manager::Employee->current->id,
2270     what_done   => $self->order->type,
2271     snumbers    => $snumbers,
2272     addition    => $addition,
2273   )->save;
2274 }
2275
2276 sub store_pdf_to_webdav_and_filemanagement {
2277   my($order, $content, $filename) = @_;
2278
2279   my @errors;
2280
2281   # copy file to webdav folder
2282   if ($order->number && $::instance_conf->get_webdav_documents) {
2283     my $webdav = SL::Webdav->new(
2284       type     => $order->type,
2285       number   => $order->number,
2286     );
2287     my $webdav_file = SL::Webdav::File->new(
2288       webdav   => $webdav,
2289       filename => $filename,
2290     );
2291     eval {
2292       $webdav_file->store(data => \$content);
2293       1;
2294     } or do {
2295       push @errors, t8('Storing PDF to webdav folder failed: #1', $@);
2296     };
2297   }
2298   if ($order->id && $::instance_conf->get_doc_storage) {
2299     eval {
2300       SL::File->save(object_id     => $order->id,
2301                      object_type   => $order->type,
2302                      mime_type     => 'application/pdf',
2303                      source        => 'created',
2304                      file_type     => 'document',
2305                      file_name     => $filename,
2306                      file_contents => $content);
2307       1;
2308     } or do {
2309       push @errors, t8('Storing PDF in storage backend failed: #1', $@);
2310     };
2311   }
2312
2313   return @errors;
2314 }
2315
2316 sub link_requirement_specs_linking_to_created_from_objects {
2317   my ($self, @converted_from_oe_ids) = @_;
2318
2319   return unless @converted_from_oe_ids;
2320
2321   my $rs_orders = SL::DB::Manager::RequirementSpecOrder->get_all(where => [ order_id => \@converted_from_oe_ids ]);
2322   foreach my $rs_order (@{ $rs_orders }) {
2323     SL::DB::RequirementSpecOrder->new(
2324       order_id            => $self->order->id,
2325       requirement_spec_id => $rs_order->requirement_spec_id,
2326       version_id          => $rs_order->version_id,
2327     )->save;
2328   }
2329 }
2330
2331 1;
2332
2333 __END__
2334
2335 =encoding utf-8
2336
2337 =head1 NAME
2338
2339 SL::Controller::Order - controller for orders
2340
2341 =head1 SYNOPSIS
2342
2343 This is a new form to enter orders, completely rewritten with the use
2344 of controller and java script techniques.
2345
2346 The aim is to provide the user a better experience and a faster workflow. Also
2347 the code should be more readable, more reliable and better to maintain.
2348
2349 =head2 Key Features
2350
2351 =over 4
2352
2353 =item *
2354
2355 One input row, so that input happens every time at the same place.
2356
2357 =item *
2358
2359 Use of pickers where possible.
2360
2361 =item *
2362
2363 Possibility to enter more than one item at once.
2364
2365 =item *
2366
2367 Item list in a scrollable area, so that the workflow buttons stay at
2368 the bottom.
2369
2370 =item *
2371
2372 Reordering item rows with drag and drop is possible. Sorting item rows is
2373 possible (by partnumber, description, qty, sellprice and discount for now).
2374
2375 =item *
2376
2377 No C<update> is necessary. All entries and calculations are managed
2378 with ajax-calls and the page only reloads on C<save>.
2379
2380 =item *
2381
2382 User can see changes immediately, because of the use of java script
2383 and ajax.
2384
2385 =back
2386
2387 =head1 CODE
2388
2389 =head2 Layout
2390
2391 =over 4
2392
2393 =item * C<SL/Controller/Order.pm>
2394
2395 the controller
2396
2397 =item * C<template/webpages/order/form.html>
2398
2399 main form
2400
2401 =item * C<template/webpages/order/tabs/basic_data.html>
2402
2403 Main tab for basic_data.
2404
2405 This is the only tab here for now. "linked records" and "webdav" tabs are
2406 reused from generic code.
2407
2408 =over 4
2409
2410 =item * C<template/webpages/order/tabs/_business_info_row.html>
2411
2412 For displaying information on business type
2413
2414 =item * C<template/webpages/order/tabs/_item_input.html>
2415
2416 The input line for items
2417
2418 =item * C<template/webpages/order/tabs/_row.html>
2419
2420 One row for already entered items
2421
2422 =item * C<template/webpages/order/tabs/_tax_row.html>
2423
2424 Displaying tax information
2425
2426 =item * C<template/webpages/order/tabs/_price_sources_dialog.html>
2427
2428 Dialog for selecting price and discount sources
2429
2430 =back
2431
2432 =item * C<js/kivi.Order.js>
2433
2434 java script functions
2435
2436 =back
2437
2438 =head1 TODO
2439
2440 =over 4
2441
2442 =item * testing
2443
2444 =item * price sources: little symbols showing better price / better discount
2445
2446 =item * select units in input row?
2447
2448 =item * check for direct delivery (workflow sales order -> purchase order)
2449
2450 =item * access rights
2451
2452 =item * display weights
2453
2454 =item * mtime check
2455
2456 =item * optional client/user behaviour
2457
2458 (transactions has to be set - department has to be set -
2459  force project if enabled in client config)
2460
2461 =back
2462
2463 =head1 KNOWN BUGS AND CAVEATS
2464
2465 =over 4
2466
2467 =item *
2468
2469 Customer discount is not displayed as a valid discount in price source popup
2470 (this might be a bug in price sources)
2471
2472 (I cannot reproduce this (Bernd))
2473
2474 =item *
2475
2476 No indication that <shift>-up/down expands/collapses second row.
2477
2478 =item *
2479
2480 Inline creation of parts is not currently supported
2481
2482 =item *
2483
2484 Table header is not sticky in the scrolling area.
2485
2486 =item *
2487
2488 Sorting does not include C<position>, neither does reordering.
2489
2490 This behavior was implemented intentionally. But we can discuss, which behavior
2491 should be implemented.
2492
2493 =back
2494
2495 =head1 To discuss / Nice to have
2496
2497 =over 4
2498
2499 =item *
2500
2501 How to expand/collapse second row. Now it can be done clicking the icon or
2502 <shift>-up/down.
2503
2504 =item *
2505
2506 Possibility to select PriceSources in input row?
2507
2508 =item *
2509
2510 This controller uses a (changed) copy of the template for the PriceSource
2511 dialog. Maybe there could be used one code source.
2512
2513 =item *
2514
2515 Rounding-differences between this controller (PriceTaxCalculator) and the old
2516 form. This is not only a problem here, but also in all parts using the PTC.
2517 There exists a ticket and a patch. This patch should be testet.
2518
2519 =item *
2520
2521 An indicator, if the actual inputs are saved (like in an
2522 editor or on text processing application).
2523
2524 =item *
2525
2526 A warning when leaving the page without saveing unchanged inputs.
2527
2528
2529 =back
2530
2531 =head1 AUTHOR
2532
2533 Bernd Bleßmann E<lt>bernd@kivitendo-premium.deE<gt>
2534
2535 =cut