SL/Controller/Order.pm

   1 package SL::Controller::Order;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use SL::Helper::Flash;
   7 use SL::Presenter;
   8 use SL::Locale::String;
   9 use SL::SessionFile::Random;
  10 use SL::PriceSource;
  11 use SL::Form;
  12
  13 use SL::DB::Order;
  14 use SL::DB::Customer;
  15 use SL::DB::Vendor;
  16 use SL::DB::TaxZone;
  17 use SL::DB::Employee;
  18 use SL::DB::Project;
  19 use SL::DB::Default;
  20 use SL::DB::Unit;
  21 use SL::DB::Price;
  22
  23 use SL::Helper::DateTime;
  24 use SL::Helper::CreatePDF qw(:all);
  25
  26 use List::Util qw(max first);
  27 use List::MoreUtils qw(none pairwise first_index);
  28 use English qw(-no_match_vars);
  29 use File::Spec;
  30
  31 use Rose::Object::MakeMethods::Generic
  32 (
  33  'scalar --get_set_init' => [ qw(order valid_types type cv p) ],
  34 );
  35
  36
  37 # safety
  38 __PACKAGE__->run_before('_check_auth');
  39
  40 __PACKAGE__->run_before('_recalc',
  41                         only => [ qw(edit update save save_and_delivery_order create_pdf send_email) ]);
  42
  43 __PACKAGE__->run_before('_get_unalterable_data',
  44                         only => [ qw(save save_and_delivery_order create_pdf send_email) ]);
  45
  46 #
  47 # actions
  48 #
  49
  50 sub action_add {
  51   my ($self) = @_;
  52
  53   $self->order->transdate(DateTime->now_local());
  54   $self->order->reqdate(DateTime->today_local->next_workday) if !$self->order->reqdate;
  55
  56   $self->_pre_render();
  57   $self->render(
  58     'order/form',
  59     title => $self->type eq _sales_order_type()    ? $::locale->text('Add Sales Order')
  60            : $self->type eq _purchase_order_type() ? $::locale->text('Add Purchase Order')
  61            : '',
  62     %{$self->{template_args}}
  63   );
  64 }
  65
  66 sub action_edit {
  67   my ($self) = @_;
  68
  69   $self->_pre_render();
  70   $self->render(
  71     'order/form',
  72     title => $self->type eq _sales_order_type()    ? $::locale->text('Edit Sales Order')
  73            : $self->type eq _purchase_order_type() ? $::locale->text('Edit Purchase Order')
  74            : '',
  75     %{$self->{template_args}}
  76   );
  77 }
  78
  79 sub action_update {
  80   my ($self) = @_;
  81
  82   $self->_pre_render();
  83   $self->render(
  84     'order/form',
  85     title => $self->type eq _sales_order_type()    ? $::locale->text('Edit Sales Order')
  86            : $self->type eq _purchase_order_type() ? $::locale->text('Edit Purchase Order')
  87            : '',
  88     %{$self->{template_args}}
  89   );
  90 }
  91
  92 sub action_save {
  93   my ($self) = @_;
  94
  95   my $errors = $self->_save();
  96
  97   if (scalar @{ $errors }) {
  98     $self->js->flash('error', $_) foreach @{ $errors };
  99     return $self->js->render();
 100   }
 101
 102   flash_later('info', $::locale->text('The order has been saved'));
 103   my @redirect_params = (
 104     action => 'edit',
 105     type   => $self->type,
 106     id     => $self->order->id,
 107   );
 108
 109   $self->redirect_to(@redirect_params);
 110 }
 111
 112 sub action_create_pdf {
 113   my ($self) = @_;
 114
 115   my $pdf;
 116   my @errors = _create_pdf($self->order, \$pdf);
 117   if (scalar @errors) {
 118     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render($self);
 119   }
 120
 121   my $sfile = SL::SessionFile::Random->new(mode => "w");
 122   $sfile->fh->print($pdf);
 123   $sfile->fh->close;
 124
 125   my $key = join('_', Time::HiRes::gettimeofday(), int rand 1000000000000);
 126   $::auth->set_session_value("Order::create_pdf-${key}" => $sfile->file_name);
 127
 128   $::form->{formname}  = $self->type;
 129   $::form->{language} = 'de';
 130   my $pdf_filename =  $::form->get_formname_translation . '_' . $self->order->ordnumber . '.pdf';
 131
 132   $self->js
 133     ->run('download_pdf', $pdf_filename, $key)
 134     ->flash('info', t8('The PDF has been created'))->render($self);
 135 }
 136
 137 sub action_download_pdf {
 138   my ($self) = @_;
 139
 140   my $key = $::form->{key};
 141   my $tmp_filename = $::auth->get_session_value("Order::create_pdf-${key}");
 142   return $self->send_file(
 143     $tmp_filename,
 144     type => 'application/pdf',
 145     name => $::form->{pdf_filename},
 146   );
 147 }
 148
 149 sub action_show_email_dialog {
 150   my ($self) = @_;
 151
 152   my $cv_method = $self->cv;
 153
 154   if (!$self->order->$cv_method) {
 155     return $self->js->flash('error', t8('Cannot send E-mail without ' . $self->cv))
 156                     ->render($self);
 157   }
 158
 159   $self->{email}->{to}   = $self->order->contact->cp_email if $self->order->contact;
 160   $self->{email}->{to} ||= $self->order->$cv_method->email;
 161   $self->{email}->{cc}   = $self->order->$cv_method->cc;
 162   $self->{email}->{bcc}  = join ', ', grep $_, $self->order->$cv_method->bcc, SL::DB::Default->get->global_bcc;
 163   # Todo: get addresses from shipto, if any
 164
 165   my $form = Form->new;
 166   $form->{ordnumber} = $self->order->ordnumber;
 167   $form->{formname}  = $self->type;
 168   $form->{type}      = $self->type;
 169   $form->{language} = 'de';
 170   $form->{format}   = 'pdf';
 171
 172   $self->{email}->{subject}             = $form->generate_email_subject();
 173   $self->{email}->{attachment_filename} = $form->generate_attachment_filename();
 174   $self->{email}->{message}             = $form->create_email_signature();
 175
 176   my $dialog_html = $self->render('order/tabs/_email_dialog', { output => 0 });
 177   $self->js
 178       ->run('show_email_dialog', $dialog_html)
 179       ->reinit_widgets
 180       ->render($self);
 181 }
 182
 183 # Todo: handling error messages: flash is not displayed in dialog, but in the main form
 184 sub action_send_email {
 185   my ($self) = @_;
 186
 187   my $mail      = Mailer->new;
 188   $mail->{from} = qq|"$::myconfig{name}" <$::myconfig{email}>|;
 189   $mail->{$_}   = $::form->{email}->{$_} for qw(to cc bcc subject message);
 190
 191   my $pdf;
 192   my @errors = _create_pdf($self->order, \$pdf, {media => 'email'});
 193   if (scalar @errors) {
 194     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render($self);
 195   }
 196
 197   $mail->{attachments} = [{ "content" => $pdf,
 198                             "name"    => $::form->{email}->{attachment_filename} }];
 199
 200   if (my $err = $mail->send) {
 201     return $self->js->flash('error', t8('Sending E-mail: ') . $err)
 202                     ->render($self);
 203   }
 204
 205   # internal notes
 206   my $intnotes = $self->order->intnotes;
 207   $intnotes   .= "\n\n" if $self->order->intnotes;
 208   $intnotes   .= t8('[email]')                                                                                        . "\n";
 209   $intnotes   .= t8('Date')       . ": " . $::locale->format_date_object(DateTime->now_local, precision => 'seconds') . "\n";
 210   $intnotes   .= t8('To (email)') . ": " . $mail->{to}                                                                . "\n";
 211   $intnotes   .= t8('Cc')         . ": " . $mail->{cc}                                                                . "\n"    if $mail->{cc};
 212   $intnotes   .= t8('Bcc')        . ": " . $mail->{bcc}                                                               . "\n"    if $mail->{bcc};
 213   $intnotes   .= t8('Subject')    . ": " . $mail->{subject}                                                           . "\n\n";
 214   $intnotes   .= t8('Message')    . ": " . $mail->{message};
 215
 216   $self->js
 217       ->val('#order_intnotes', $intnotes)
 218       ->run('close_email_dialog')
 219       ->render($self);
 220 }
 221
 222 sub action_save_and_delivery_order {
 223   my ($self) = @_;
 224
 225   my $errors = $self->_save();
 226
 227   if (scalar @{ $errors }) {
 228     $self->js->flash('error', $_) foreach @{ $errors };
 229     return $self->js->render();
 230   }
 231
 232   my $delivery_order = $self->order->convert_to_delivery_order($self->order);
 233
 234   flash_later('info', $::locale->text('The order has been saved'));
 235   my @redirect_params = (
 236     controller => 'do.pl',
 237     action     => 'edit',
 238     type       => $delivery_order->type,
 239     id         => $delivery_order->id,
 240     vc         => $delivery_order->is_sales ? 'customer' : 'vendor',
 241   );
 242
 243   $self->redirect_to(@redirect_params);
 244 }
 245
 246 sub action_customer_vendor_changed {
 247   my ($self) = @_;
 248
 249   my $cv_method = $self->cv;
 250
 251   if ($self->order->$cv_method->contacts && scalar @{ $self->order->$cv_method->contacts } > 0) {
 252     $self->js->show('#cp_row');
 253   } else {
 254     $self->js->hide('#cp_row');
 255   }
 256
 257   if ($self->order->$cv_method->shipto && scalar @{ $self->order->$cv_method->shipto } > 0) {
 258     $self->js->show('#shipto_row');
 259   } else {
 260     $self->js->hide('#shipto_row');
 261   }
 262
 263   $self->order->taxzone_id($self->order->$cv_method->taxzone_id);
 264
 265   if ($self->order->is_sales) {
 266     $self->order->taxincluded(defined($self->order->$cv_method->taxincluded_checked)
 267                               ? $self->order->$cv_method->taxincluded_checked
 268                               : $::myconfig{taxincluded_checked});
 269   }
 270
 271   $self->_recalc();
 272
 273   $self->js
 274     ->replaceWith('#order_cp_id',       $self->build_contact_select)
 275     ->replaceWith('#order_shipto_id',   $self->build_shipto_select)
 276     ->val(        '#order_taxzone_id',  $self->order->taxzone_id)
 277     ->val(        '#order_taxincluded', $self->order->taxincluded)
 278     ->focus(      '#order_' . $self->cv . '_id');
 279
 280   $self->_js_redisplay_amounts_and_taxes;
 281   $self->js->render();
 282 }
 283
 284 sub action_add_item {
 285   my ($self) = @_;
 286
 287   my $form_attr = $::form->{add_item};
 288
 289   return unless $form_attr->{parts_id};
 290
 291   my $item = _make_item($self->order, $form_attr);
 292   $self->order->add_items($item);
 293
 294   $self->_recalc();
 295
 296   my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 297   my $row_as_html = $self->p->render('order/tabs/_row', ITEM => $item, ID => $item_id);
 298
 299   $self->js
 300     ->append('#row_table_id', $row_as_html)
 301     ->val('#add_item_parts_id', '')
 302     ->val('#add_item_parts_id_name', '')
 303     ->val('#add_item_description', '')
 304     ->val('#add_item_qty_as_number', '')
 305     ->val('#add_item_sellprice_as_number', '')
 306     ->val('#add_item_discount_as_percent', '')
 307     ->run('row_table_scroll_down')
 308     ->run('row_set_keyboard_events_by_id', $item_id)
 309     ->on('.recalc', 'change', 'recalc_amounts_and_taxes')
 310     ->on('.reformat_number', 'change', 'reformat_number')
 311     ->focus('#add_item_parts_id_name');
 312
 313   $self->_js_redisplay_amounts_and_taxes;
 314   $self->js->render();
 315 }
 316
 317 sub action_show_multi_items_dialog {
 318   my ($self) = @_;
 319
 320   $self->{multi_items}->{parts} = SL::DB::Manager::Part->get_all_sorted(where => [ obsolete => 0 ]);
 321   my $dialog_html = $self->render('order/tabs/_multi_items_dialog', { output => 0 });
 322
 323   $self->js
 324     ->run('show_multi_items_dialog', $dialog_html, t8('Add multiple parts'))
 325     ->reinit_widgets
 326     ->render();
 327 }
 328
 329 sub action_add_multi_items {
 330   my ($self) = @_;
 331
 332   my @form_attr = grep { $_->{qty} } @{ $::form->{add_multi_items} };
 333   return unless scalar @form_attr;
 334
 335   my @items;
 336   foreach my $attr (@form_attr) {
 337     push @items, _make_item($self->order, $attr);
 338   }
 339   $self->order->add_items(@items);
 340
 341   $self->_recalc();
 342
 343   foreach my $item (@items) {
 344     my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 345     my $row_as_html = $self->p->render('order/tabs/_row', ITEM => $item, ID => $item_id);
 346
 347     $self->js
 348         ->append('#row_table_id', $row_as_html)
 349         ->run('row_set_keyboard_events_by_id', $item_id);
 350   }
 351
 352   $self->js
 353     ->run('close_multi_items_dialog')
 354     ->run('row_table_scroll_down')
 355     ->on('.recalc', 'change', 'recalc_amounts_and_taxes')
 356     ->on('.reformat_number', 'change', 'reformat_number')
 357     ->focus('#add_item_parts_id_name');
 358
 359   $self->_js_redisplay_amounts_and_taxes;
 360   $self->js->render();
 361 }
 362
 363 sub action_recalc_amounts_and_taxes {
 364   my ($self) = @_;
 365
 366   $self->_recalc();
 367
 368   $self->_js_redisplay_linetotals;
 369   $self->_js_redisplay_amounts_and_taxes;
 370   $self->js->render();
 371 }
 372
 373 sub action_price_popup {
 374   my ($self) = @_;
 375
 376   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 377   my $item = $self->order->items->[$idx];
 378
 379   $self->render_price_dialog($item);
 380 }
 381
 382 sub _js_redisplay_linetotals {
 383   my ($self) = @_;
 384
 385   my @data = map {$::form->format_amount(\%::myconfig, $_->{linetotal}, 2, 0)} @{ $self->order->items };
 386   $self->js
 387     ->run('redisplay_linetotals', \@data);
 388 }
 389
 390 sub _js_redisplay_amounts_and_taxes {
 391   my ($self) = @_;
 392
 393   if (scalar @{ $self->{taxes} }) {
 394     $self->js->show('#taxincluded_row_id');
 395   } else {
 396     $self->js->hide('#taxincluded_row_id');
 397   }
 398
 399   if ($self->order->taxincluded) {
 400     $self->js->hide('#subtotal_row_id');
 401   } else {
 402     $self->js->show('#subtotal_row_id');
 403   }
 404
 405   $self->js
 406     ->html('#netamount_id', $::form->format_amount(\%::myconfig, $self->order->netamount, -2))
 407     ->html('#amount_id',    $::form->format_amount(\%::myconfig, $self->order->amount,    -2))
 408     ->remove('.tax_row')
 409     ->insertBefore($self->build_tax_rows, '#amount_row_id');
 410 }
 411
 412 #
 413 # helpers
 414 #
 415
 416 sub init_valid_types {
 417   [ _sales_order_type(), _purchase_order_type() ];
 418 }
 419
 420 sub init_type {
 421   my ($self) = @_;
 422
 423   if (none { $::form->{type} eq $_ } @{$self->valid_types}) {
 424     die "Not a valid type for order";
 425   }
 426
 427   $self->type($::form->{type});
 428 }
 429
 430 sub init_cv {
 431   my ($self) = @_;
 432
 433   my $cv = $self->type eq _sales_order_type()    ? 'customer'
 434          : $self->type eq _purchase_order_type() ? 'vendor'
 435          : die "Not a valid type for order";
 436
 437   return $cv;
 438 }
 439
 440 sub init_p {
 441   SL::Presenter->get;
 442 }
 443
 444 sub init_order {
 445   _make_order();
 446 }
 447
 448 sub _check_auth {
 449   my ($self) = @_;
 450
 451   my $right_for = { map { $_ => $_.'_edit' } @{$self->valid_types} };
 452
 453   my $right   = $right_for->{ $self->type };
 454   $right    ||= 'DOES_NOT_EXIST';
 455
 456   $::auth->assert($right);
 457 }
 458
 459 sub build_contact_select {
 460   my ($self) = @_;
 461
 462   $self->p->select_tag('order.cp_id', [ $self->order->{$self->cv}->contacts ],
 463                        value_key  => 'cp_id',
 464                        title_key  => 'full_name_dep',
 465                        default    => $self->order->cp_id,
 466                        with_empty => 1,
 467                        style      => 'width: 300px',
 468   );
 469 }
 470
 471 sub build_shipto_select {
 472   my ($self) = @_;
 473
 474   $self->p->select_tag('order.shipto_id', [ $self->order->{$self->cv}->shipto ],
 475                        value_key  => 'shipto_id',
 476                        title_key  => 'displayable_id',
 477                        default    => $self->order->shipto_id,
 478                        with_empty => 1,
 479                        style      => 'width: 300px',
 480   );
 481 }
 482
 483 sub build_tax_rows {
 484   my ($self) = @_;
 485
 486   my $rows_as_html;
 487   foreach my $tax (sort { $a->{tax}->rate cmp $b->{tax}->rate } @{ $self->{taxes} }) {
 488     $rows_as_html .= $self->p->render('order/tabs/_tax_row', TAX => $tax, TAXINCLUDED => $self->order->taxincluded);
 489   }
 490   return $rows_as_html;
 491 }
 492
 493
 494 sub render_price_dialog {
 495   my ($self, $record_item) = @_;
 496
 497   my $price_source = SL::PriceSource->new(record_item => $record_item, record => $self->order);
 498
 499   $self->js
 500     ->run(
 501       'kivi.io.price_chooser_dialog',
 502       t8('Available Prices'),
 503       $self->render('order/tabs/_price_sources_dialog', { output => 0 }, price_source => $price_source)
 504     )
 505     ->reinit_widgets;
 506
 507 #   if (@errors) {
 508 #     $self->js->text('#dialog_flash_error_content', join ' ', @errors);
 509 #     $self->js->show('#dialog_flash_error');
 510 #   }
 511
 512   $self->js->render;
 513 }
 514
 515 sub _make_order {
 516   my ($self) = @_;
 517
 518   # add_items adds items to an order with no items for saving, but they cannot
 519   # be retrieved via items until the order is saved. Adding empty items to new
 520   # order here solves this problem.
 521   my $order;
 522   $order   = SL::DB::Manager::Order->find_by(id => $::form->{id}) if $::form->{id};
 523   $order ||= SL::DB::Order->new(orderitems => []);
 524
 525   $order->assign_attributes(%{$::form->{order}});
 526
 527   return $order;
 528 }
 529
 530 sub _make_item {
 531   my ($record, $attr) = @_;
 532
 533   my $item = SL::DB::OrderItem->new;
 534   $item->assign_attributes(%$attr);
 535
 536   my $part         = SL::DB::Part->new(id => $attr->{parts_id})->load;
 537   my $price_source = SL::PriceSource->new(record_item => $item, record => $record);
 538
 539   $item->unit($part->unit) if !$item->unit;
 540
 541   my $price_src;
 542   if ($item->sellprice) {
 543     $price_src = $price_source->price_from_source("");
 544     $price_src->price($item->sellprice);
 545   } else {
 546     $price_src = $price_source->best_price
 547            ? $price_source->best_price
 548            : $price_source->price_from_source("");
 549     $price_src->price(0) if !$price_source->best_price;
 550   }
 551
 552   my $discount_src;
 553   if ($item->discount) {
 554     $discount_src = $price_source->discount_from_source("");
 555     $discount_src->discount($item->discount);
 556   } else {
 557     $discount_src = $price_source->best_discount
 558                   ? $price_source->best_discount
 559                   : $price_source->discount_from_source("");
 560     $discount_src->discount(0) if !$price_source->best_discount;
 561   }
 562
 563   my %new_attr;
 564   $new_attr{part}                   = $part;
 565   $new_attr{description}            = $part->description if ! $item->description;
 566   $new_attr{qty}                    = 1.0                if ! $item->qty;
 567   $new_attr{sellprice}              = $price_src->price;
 568   $new_attr{discount}               = $discount_src->discount;
 569   $new_attr{active_price_source}    = $price_src;
 570   $new_attr{active_discount_source} = $discount_src;
 571
 572   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
 573   # they cannot be retrieved via custom_variables until the order/orderitem is
 574   # saved. Adding empty custom_variables to new orderitem here solves this problem.
 575   $new_attr{custom_variables} = [];
 576
 577   $item->assign_attributes(%new_attr);
 578
 579   return $item;
 580 }
 581
 582 sub _recalc {
 583   my ($self) = @_;
 584
 585   # bb: todo: currency later
 586   $self->order->currency_id($::instance_conf->get_currency_id());
 587
 588   my %pat = $self->order->calculate_prices_and_taxes();
 589   $self->{taxes} = [];
 590   foreach my $tax_chart_id (keys %{ $pat{taxes} }) {
 591     my $tax = SL::DB::Manager::Tax->find_by(chart_id => $tax_chart_id);
 592
 593     my @amount_keys = grep { $pat{amounts}->{$_}->{tax_id} == $tax->id } keys %{ $pat{amounts} };
 594     push(@{ $self->{taxes} }, { amount    => $pat{taxes}->{$tax_chart_id},
 595                                 netamount => $pat{amounts}->{$amount_keys[0]}->{amount},
 596                                 tax       => $tax });
 597   }
 598
 599   pairwise { $a->{linetotal} = $b->{linetotal} } @{$self->order->items}, @{$pat{items}};
 600 }
 601
 602
 603 sub _get_unalterable_data {
 604   my ($self) = @_;
 605
 606   foreach my $item (@{ $self->order->items }) {
 607     if ($item->id) {
 608       # load data from orderitems (db)
 609       my $db_item = SL::DB::OrderItem->new(id => $item->id)->load;
 610       $item->$_($db_item->$_) for qw(longdescription);
 611     } else {
 612       # set data from part (or other sources)
 613       $item->longdescription($item->part->notes);
 614     }
 615
 616     # autovivify all cvars that are not in the form (cvars_by_config can do it).
 617     # workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
 618     foreach my $var (@{ $item->cvars_by_config }) {
 619       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
 620     }
 621     $item->parse_custom_variable_values;
 622   }
 623 }
 624
 625
 626 sub _save {
 627   my ($self) = @_;
 628
 629   my $errors = [];
 630   my $db = $self->order->db;
 631
 632   $db->do_transaction(
 633     sub {
 634       $self->order->save();
 635   }) || push(@{$errors}, $db->error);
 636
 637   return $errors;
 638 }
 639
 640
 641 sub _pre_render {
 642   my ($self) = @_;
 643
 644   $self->{all_taxzones}        = SL::DB::Manager::TaxZone->get_all_sorted();
 645   $self->{all_employees}       = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->employee_id,
 646                                                                                        deleted => 0 ] ],
 647                                                                     sort_by => 'name');
 648   $self->{all_salesmen}        = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->salesman_id,
 649                                                                                        deleted => 0 ] ],
 650                                                                     sort_by => 'name');
 651   $self->{all_projects}        = SL::DB::Manager::Project->get_all(where => [ or => [ id => $self->order->globalproject_id,
 652                                                                                       active => 1 ] ],
 653                                                                    sort_by => 'projectnumber');
 654   $self->{all_payment_terms}   = SL::DB::Manager::PaymentTerm->get_all_sorted();
 655   $self->{all_delivery_terms}  = SL::DB::Manager::DeliveryTerm->get_all_sorted();
 656
 657   $self->{current_employee_id} = SL::DB::Manager::Employee->current->id;
 658
 659   foreach  my $item (@{$self->order->items}) {
 660     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
 661     $item->active_price_source(   $price_source->price_from_source(   $item->active_price_source   ));
 662     $item->active_discount_source($price_source->discount_from_source($item->active_discount_source));
 663
 664   }
 665
 666   $::request->{layout}->use_javascript("${_}.js")  for qw(ckeditor/ckeditor ckeditor/adapters/jquery);
 667 }
 668
 669 sub _create_pdf {
 670   my ($order, $pdf_ref, $params) = @_;
 671
 672   my $print_form = Form->new('');
 673   $print_form->{type}     = $order->type;
 674   $print_form->{formname} = $order->type;
 675   $print_form->{format}   = $params->{format} || 'pdf',
 676   $print_form->{media}    = $params->{media}  || 'file';
 677
 678   $order->flatten_to_form($print_form, format_amounts => 1);
 679   # flatten_to_form sets payment_terms from customer/vendor - we do not want that here
 680   delete $print_form->{payment_terms} if !$print_form->{payment_id};
 681
 682   my @errors = ();
 683   $print_form->throw_on_error(sub {
 684     eval {
 685       $print_form->prepare_for_printing;
 686
 687       $$pdf_ref = SL::Helper::CreatePDF->create_pdf(
 688         template  => SL::Helper::CreatePDF->find_template(name => $print_form->{formname}),
 689         variables => $print_form,
 690         variable_content_types => {
 691           longdescription => 'html',
 692           partnotes       => 'html',
 693           notes           => 'html',
 694         },
 695       );
 696       1;
 697     } || push @errors, ref($EVAL_ERROR) eq 'SL::X::FormError' ? $EVAL_ERROR->getMessage : $EVAL_ERROR;
 698   });
 699
 700   return @errors;
 701 }
 702
 703 sub _sales_order_type {
 704   'sales_order';
 705 }
 706
 707 sub _purchase_order_type {
 708   'purchase_order';
 709 }
 710
 711 1;
 712
 713 __END__
 714
 715 =encoding utf-8
 716
 717 =head1 NAME
 718
 719 SL::Controller::Order - controller for orders
 720
 721 =head1 TODO
 722
 723 Testing, PriceSources, pricefactor, units, currency, delivered, delivery order created, ...
 724
 725 =head1 AUTHOR
 726
 727 Bernd Bleßmann E<lt>bernd@kivitendo-premium.deE<gt>
 728
 729 =cut
 730