SL/Controller/Order.pm

   1 package SL::Controller::Order;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use SL::Helper::Flash;
   7 use SL::Presenter;
   8 use SL::Locale::String;
   9 use SL::SessionFile::Random;
  10 use SL::PriceSource;
  11 use SL::Form;
  12
  13 use SL::DB::Order;
  14 use SL::DB::Customer;
  15 use SL::DB::Vendor;
  16 use SL::DB::TaxZone;
  17 use SL::DB::Employee;
  18 use SL::DB::Project;
  19 use SL::DB::Default;
  20 use SL::DB::Unit;
  21 use SL::DB::Price;
  22
  23 use SL::Helper::DateTime;
  24 use SL::Helper::CreatePDF qw(:all);
  25
  26 use List::Util qw(max first);
  27 use List::MoreUtils qw(none pairwise);
  28 use English qw(-no_match_vars);
  29 use File::Spec;
  30
  31 use Rose::Object::MakeMethods::Generic
  32 (
  33  'scalar --get_set_init' => [ qw(order valid_types type cv p) ],
  34 );
  35
  36
  37 # safety
  38 __PACKAGE__->run_before('_check_auth');
  39
  40 __PACKAGE__->run_before('_recalc',
  41                         only => [ qw(edit update save save_and_delivery_order create_pdf send_email) ]);
  42
  43 __PACKAGE__->run_before('_get_unalterable_data',
  44                         only => [ qw(save save_and_delivery_order create_pdf send_email) ]);
  45
  46 #
  47 # actions
  48 #
  49
  50 sub action_add {
  51   my ($self) = @_;
  52
  53   $self->order->transdate(DateTime->now_local());
  54
  55   $self->_pre_render();
  56   $self->render(
  57     'order/form',
  58     title => $self->type eq _sales_order_type()    ? $::locale->text('Add Sales Order')
  59            : $self->type eq _purchase_order_type() ? $::locale->text('Add Purchase Order')
  60            : '',
  61     %{$self->{template_args}}
  62   );
  63 }
  64
  65 sub action_edit {
  66   my ($self) = @_;
  67
  68   $self->_pre_render();
  69   $self->render(
  70     'order/form',
  71     title => $self->type eq _sales_order_type()    ? $::locale->text('Edit Sales Order')
  72            : $self->type eq _purchase_order_type() ? $::locale->text('Edit Purchase Order')
  73            : '',
  74     %{$self->{template_args}}
  75   );
  76 }
  77
  78 sub action_update {
  79   my ($self) = @_;
  80
  81   $self->_pre_render();
  82   $self->render(
  83     'order/form',
  84     title => $self->type eq _sales_order_type()    ? $::locale->text('Edit Sales Order')
  85            : $self->type eq _purchase_order_type() ? $::locale->text('Edit Purchase Order')
  86            : '',
  87     %{$self->{template_args}}
  88   );
  89 }
  90
  91 sub action_save {
  92   my ($self) = @_;
  93
  94   my $errors = $self->_save();
  95
  96   if (scalar @{ $errors }) {
  97     $self->js->flash('error', $_) foreach @{ $errors };
  98     return $self->js->render();
  99   }
 100
 101   flash_later('info', $::locale->text('The order has been saved'));
 102   my @redirect_params = (
 103     action => 'edit',
 104     type   => $self->type,
 105     id     => $self->order->id,
 106   );
 107
 108   $self->redirect_to(@redirect_params);
 109 }
 110
 111 sub action_create_pdf {
 112   my ($self) = @_;
 113
 114   my $pdf;
 115   my @errors = _create_pdf($self->order, \$pdf);
 116   if (scalar @errors) {
 117     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render($self);
 118   }
 119
 120   my $sfile = SL::SessionFile::Random->new(mode => "w");
 121   $sfile->fh->print($pdf);
 122   $sfile->fh->close;
 123
 124   my $key = join('_', Time::HiRes::gettimeofday(), int rand 1000000000000);
 125   $::auth->set_session_value("Order::create_pdf-${key}" => $sfile->file_name);
 126
 127   my $pdf_filename =  t8('Sales Order') . '_' . $self->order->ordnumber . '.pdf';
 128
 129   $self->js
 130     ->run('download_pdf', $pdf_filename, $key)
 131     ->flash('info', t8('The PDF has been created'))->render($self);
 132 }
 133
 134 sub action_download_pdf {
 135   my ($self) = @_;
 136
 137   my $key = $::form->{key};
 138   my $tmp_filename = $::auth->get_session_value("Order::create_pdf-${key}");
 139   return $self->send_file(
 140     $tmp_filename,
 141     type => 'application/pdf',
 142     name => $::form->{pdf_filename},
 143   );
 144 }
 145
 146 sub action_show_email_dialog {
 147   my ($self) = @_;
 148
 149   my $cv_method = $self->cv;
 150
 151   if (!$self->order->$cv_method) {
 152     return $self->js->flash('error', t8('Cannot send E-mail without ' . $self->cv))
 153                     ->render($self);
 154   }
 155
 156   $self->{email}->{to}   = $self->order->contact->cp_email if $self->order->contact;
 157   $self->{email}->{to} ||= $self->order->$cv_method->email;
 158   $self->{email}->{cc}   = $self->order->$cv_method->cc;
 159   $self->{email}->{bcc}  = join ', ', grep $_, $self->order->$cv_method->bcc, SL::DB::Default->get->global_bcc;
 160   # Todo: get addresses from shipto, if any
 161
 162   my $form = Form->new;
 163   $form->{ordnumber} = $self->order->ordnumber;
 164   $form->{formname}  = $self->type;
 165   $form->{type}      = $self->type;
 166   $form->{language} = 'de';
 167   $form->{format}   = 'pdf';
 168
 169   $self->{email}->{subject}             = $form->generate_email_subject();
 170   $self->{email}->{attachment_filename} = $form->generate_attachment_filename();
 171   $self->{email}->{message}             = $form->create_email_signature();
 172
 173   my $dialog_html = $self->render('order/tabs/_email_dialog', { output => 0 });
 174   $self->js
 175       ->run('show_email_dialog', $dialog_html)
 176       ->reinit_widgets
 177       ->render($self);
 178 }
 179
 180 # Todo: handling error messages: flash is not displayed in dialog, but in the main form
 181 sub action_send_email {
 182   my ($self) = @_;
 183
 184   my $mail      = Mailer->new;
 185   $mail->{from} = qq|"$::myconfig{name}" <$::myconfig{email}>|;
 186   $mail->{$_}   = $::form->{email}->{$_} for qw(to cc bcc subject message);
 187
 188   my $pdf;
 189   my @errors = _create_pdf($self->order, \$pdf, {media => 'email'});
 190   if (scalar @errors) {
 191     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render($self);
 192   }
 193
 194   $mail->{attachments} = [{ "content" => $pdf,
 195                             "name"    => $::form->{email}->{attachment_filename} }];
 196
 197   if (my $err = $mail->send) {
 198     return $self->js->flash('error', t8('Sending E-mail: ') . $err)
 199                     ->render($self);
 200   }
 201
 202   # internal notes
 203   my $intnotes = $self->order->intnotes;
 204   $intnotes   .= "\n\n" if $self->order->intnotes;
 205   $intnotes   .= t8('[email]')                                                                                        . "\n";
 206   $intnotes   .= t8('Date')       . ": " . $::locale->format_date_object(DateTime->now_local, precision => 'seconds') . "\n";
 207   $intnotes   .= t8('To (email)') . ": " . $mail->{to}                                                                . "\n";
 208   $intnotes   .= t8('Cc')         . ": " . $mail->{cc}                                                                . "\n"    if $mail->{cc};
 209   $intnotes   .= t8('Bcc')        . ": " . $mail->{bcc}                                                               . "\n"    if $mail->{bcc};
 210   $intnotes   .= t8('Subject')    . ": " . $mail->{subject}                                                           . "\n\n";
 211   $intnotes   .= t8('Message')    . ": " . $mail->{message};
 212
 213   $self->js
 214       ->val('#order_intnotes', $intnotes)
 215       ->run('close_email_dialog')
 216       ->render($self);
 217 }
 218
 219 sub action_save_and_delivery_order {
 220   my ($self) = @_;
 221
 222   my $errors = $self->_save();
 223
 224   if (scalar @{ $errors }) {
 225     $self->js->flash('error', $_) foreach @{ $errors };
 226     return $self->js->render();
 227   }
 228
 229   my $delivery_order = $self->order->convert_to_delivery_order($self->order);
 230
 231   flash_later('info', $::locale->text('The order has been saved'));
 232   my @redirect_params = (
 233     controller => 'do.pl',
 234     action     => 'edit',
 235     type       => $delivery_order->type,
 236     id         => $delivery_order->id,
 237     vc         => $delivery_order->is_sales ? 'customer' : 'vendor',
 238   );
 239
 240   $self->redirect_to(@redirect_params);
 241 }
 242
 243 sub action_customer_vendor_changed {
 244   my ($self) = @_;
 245
 246   if ($self->cv eq 'customer') {
 247     $self->order->customer(SL::DB::Manager::Customer->find_by_or_create(id => $::form->{cv_id}));
 248
 249   } elsif ($self->cv eq 'vendor') {
 250     $self->order->vendor(SL::DB::Manager::Vendor->find_by_or_create(id => $::form->{cv_id}));
 251   }
 252
 253   if ($self->order->{$self->cv}->contacts && scalar @{ $self->order->{$self->cv}->contacts } > 0) {
 254     $self->js->show('#cp_row');
 255   } else {
 256     $self->js->hide('#cp_row');
 257   }
 258
 259   if ($self->order->{$self->cv}->shipto && scalar @{ $self->order->{$self->cv}->shipto } > 0) {
 260     $self->js->show('#shipto_row');
 261   } else {
 262     $self->js->hide('#shipto_row');
 263   }
 264
 265   $self->js
 266     ->replaceWith('#order_cp_id',     $self->build_contact_select)
 267     ->replaceWith('#order_shipto_id', $self->build_shipto_select)
 268     ->val('#order_taxzone_id', $self->order->{$self->cv}->taxzone_id)
 269     ->focus('#order_' . $self->cv . '_id')
 270     ->render($self);
 271 }
 272
 273 sub action_add_item {
 274   my ($self) = @_;
 275
 276   my $form_attr = $::form->{add_item};
 277
 278   return unless $form_attr->{parts_id};
 279
 280   my $item = SL::DB::OrderItem->new;
 281   $item->assign_attributes(%$form_attr);
 282
 283   my $part        = SL::DB::Part->new(id => $form_attr->{parts_id})->load;
 284   my $cv_method   = $self->cv;
 285   my $cv_discount = $self->order->$cv_method? $self->order->$cv_method->discount : 0.0;
 286
 287   my $price = $item->sellprice;
 288   $price  ||= ($self->order->$cv_method && $self->order->$cv_method->klass)
 289             ? (SL::DB::Manager::Price->find_by(parts_id => $part->id, pricegroup_id => $self->order->$cv_method->klass)->price || $part->sellprice)
 290             : $part->sellprice;
 291
 292   my %new_attr;
 293   $new_attr{part}        = $part;
 294   $new_attr{description} = $part->description if ! $item->description;
 295   $new_attr{qty}         = 1.0                if ! $item->qty;
 296   $new_attr{unit}        = $part->unit;
 297   $new_attr{sellprice}   = $price;
 298   $new_attr{discount}    = $cv_discount       if ! $item->discount;
 299
 300   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
 301   # they cannot be retrieved via custom_variables until the order/orderitem is
 302   # saved. Adding empty custom_variables to new orderitem here solves this problem.
 303   $new_attr{custom_variables} = [];
 304
 305   $item->assign_attributes(%new_attr);
 306
 307   $self->order->add_items($item);
 308
 309   $self->_recalc();
 310
 311   my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 312   my $row_as_html = $self->p->render('order/tabs/_row', ITEM => $item, ID => $item_id);
 313
 314   $self->js
 315     ->append('#row_table_id', $row_as_html)
 316     ->val('#add_item_parts_id', '')
 317     ->val('#add_item_parts_id_name', '')
 318     ->val('#add_item_description', '')
 319     ->val('#add_item_qty_as_number', '')
 320     ->val('#add_item_sellprice_as_number', '')
 321     ->val('#add_item_discount_as_percent', '')
 322     ->run('row_table_scroll_down')
 323     ->run('row_set_keyboard_events_by_id', $item_id)
 324     ->on('.recalc', 'change', 'recalc_amounts_and_taxes')
 325     ->focus('#add_item_parts_id_name');
 326
 327   $self->_js_redisplay_amounts_and_taxes;
 328   $self->js->render();
 329 }
 330
 331 sub action_recalc_amounts_and_taxes {
 332   my ($self) = @_;
 333
 334   $self->_recalc();
 335
 336   $self->_js_redisplay_linetotals;
 337   $self->_js_redisplay_amounts_and_taxes;
 338   $self->js->render();
 339 }
 340
 341 sub _js_redisplay_linetotals {
 342   my ($self) = @_;
 343
 344   my @data = map {$::form->format_amount(\%::myconfig, $_->{linetotal}, 2, 0)} @{ $self->order->items };
 345   $self->js
 346     ->run('redisplay_linetotals', \@data);
 347 }
 348
 349 sub _js_redisplay_amounts_and_taxes {
 350   my ($self) = @_;
 351
 352   if (scalar @{ $self->{taxes} }) {
 353     $self->js->show('#taxincluded_row_id');
 354   } else {
 355     $self->js->hide('#taxincluded_row_id');
 356   }
 357
 358   if ($self->order->taxincluded) {
 359     $self->js->hide('#subtotal_row_id');
 360   } else {
 361     $self->js->show('#subtotal_row_id');
 362   }
 363
 364   $self->js
 365     ->html('#netamount_id', $::form->format_amount(\%::myconfig, $self->order->netamount, -2))
 366     ->html('#amount_id',    $::form->format_amount(\%::myconfig, $self->order->amount,    -2))
 367     ->remove('.tax_row')
 368     ->insertBefore($self->build_tax_rows, '#amount_row_id');
 369 }
 370
 371 #
 372 # helpers
 373 #
 374
 375 sub init_valid_types {
 376   [ _sales_order_type(), _purchase_order_type() ];
 377 }
 378
 379 sub init_type {
 380   my ($self) = @_;
 381
 382   if (none { $::form->{type} eq $_ } @{$self->valid_types}) {
 383     die "Not a valid type for order";
 384   }
 385
 386   $self->type($::form->{type});
 387 }
 388
 389 sub init_cv {
 390   my ($self) = @_;
 391
 392   my $cv = $self->type eq _sales_order_type()    ? 'customer'
 393          : $self->type eq _purchase_order_type() ? 'vendor'
 394          : die "Not a valid type for order";
 395
 396   return $cv;
 397 }
 398
 399 sub init_p {
 400   SL::Presenter->get;
 401 }
 402
 403 sub init_order {
 404   _make_order();
 405 }
 406
 407 sub _check_auth {
 408   my ($self) = @_;
 409
 410   my $right_for = { map { $_ => $_.'_edit' } @{$self->valid_types} };
 411
 412   my $right   = $right_for->{ $self->type };
 413   $right    ||= 'DOES_NOT_EXIST';
 414
 415   $::auth->assert($right);
 416 }
 417
 418 sub build_contact_select {
 419   my ($self) = @_;
 420
 421   $self->p->select_tag('order.cp_id', [ $self->order->{$self->cv}->contacts ],
 422                        value_key  => 'cp_id',
 423                        title_key  => 'full_name_dep',
 424                        default    => $self->order->cp_id,
 425                        with_empty => 1,
 426                        style      => 'width: 300px',
 427   );
 428 }
 429
 430 sub build_shipto_select {
 431   my ($self) = @_;
 432
 433   $self->p->select_tag('order.shipto_id', [ $self->order->{$self->cv}->shipto ],
 434                        value_key  => 'shipto_id',
 435                        title_key  => 'displayable_id',
 436                        default    => $self->order->shipto_id,
 437                        with_empty => 1,
 438                        style      => 'width: 300px',
 439   );
 440 }
 441
 442 sub build_tax_rows {
 443   my ($self) = @_;
 444
 445   my $rows_as_html;
 446   foreach my $tax (@{ $self->{taxes} }) {
 447     $rows_as_html .= $self->p->render('order/tabs/_tax_row', TAX => $tax, TAXINCLUDED => $self->order->taxincluded);
 448   }
 449   return $rows_as_html;
 450 }
 451
 452
 453 sub _make_order {
 454   my ($self) = @_;
 455
 456   # add_items adds items to an order with no items for saving, but they cannot
 457   # be retrieved via items until the order is saved. Adding empty items to new
 458   # order here solves this problem.
 459   my $order;
 460   $order   = SL::DB::Manager::Order->find_by(id => $::form->{id}) if $::form->{id};
 461   $order ||= SL::DB::Order->new(orderitems => []);
 462
 463   $order->assign_attributes(%{$::form->{order}});
 464
 465   return $order;
 466 }
 467
 468
 469 sub _recalc {
 470   my ($self) = @_;
 471
 472   # bb: todo: currency later
 473   $self->order->currency_id($::instance_conf->get_currency_id());
 474
 475   my %pat = $self->order->calculate_prices_and_taxes();
 476   $self->{taxes} = [];
 477   foreach my $tax_chart_id (keys %{ $pat{taxes} }) {
 478     my $tax = SL::DB::Manager::Tax->find_by(chart_id => $tax_chart_id);
 479
 480     my @amount_keys = grep { $pat{amounts}->{$_}->{tax_id} == $tax->id } keys %{ $pat{amounts} };
 481     push(@{ $self->{taxes} }, { amount    => $pat{taxes}->{$tax_chart_id},
 482                                 netamount => $pat{amounts}->{$amount_keys[0]}->{amount},
 483                                 tax       => $tax });
 484   }
 485
 486   pairwise { $a->{linetotal} = $b->{linetotal} } @{$self->order->items}, @{$pat{items}};
 487 }
 488
 489
 490 sub _get_unalterable_data {
 491   my ($self) = @_;
 492
 493   foreach my $item (@{ $self->order->items }) {
 494     if ($item->id) {
 495       # load data from orderitems (db)
 496       my $db_item = SL::DB::OrderItem->new(id => $item->id)->load;
 497       $item->$_($db_item->$_) for qw(active_discount_source active_price_source longdescription);
 498     } else {
 499       # set data from part (or other sources)
 500       $item->longdescription($item->part->notes);
 501       #$item->active_price_source('');
 502       #$item->active_discount_source('');
 503     }
 504
 505     # autovivify all cvars that are not in the form (cvars_by_config can do it).
 506     # workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
 507     foreach my $var (@{ $item->cvars_by_config }) {
 508       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
 509     }
 510     $item->parse_custom_variable_values;
 511   }
 512 }
 513
 514
 515 sub _save {
 516   my ($self) = @_;
 517
 518   my $errors = [];
 519   my $db = $self->order->db;
 520
 521   $db->do_transaction(
 522     sub {
 523       $self->order->save();
 524   }) || push(@{$errors}, $db->error);
 525
 526   return $errors;
 527 }
 528
 529
 530 sub _pre_render {
 531   my ($self) = @_;
 532
 533   $self->{all_taxzones}        = SL::DB::Manager::TaxZone->get_all_sorted();
 534   $self->{all_employees}       = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->employee_id,
 535                                                                                        deleted => 0 ] ],
 536                                                                     sort_by => 'name');
 537   $self->{all_salesmen}        = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->salesman_id,
 538                                                                                        deleted => 0 ] ],
 539                                                                     sort_by => 'name');
 540   $self->{all_projects}        = SL::DB::Manager::Project->get_all(where => [ or => [ id => $self->order->globalproject_id,
 541                                                                                       active => 1 ] ],
 542                                                                    sort_by => 'projectnumber');
 543   $self->{all_payment_terms}   = SL::DB::Manager::PaymentTerm->get_all_sorted();
 544   $self->{all_delivery_terms}  = SL::DB::Manager::DeliveryTerm->get_all_sorted();
 545
 546   $self->{current_employee_id} = SL::DB::Manager::Employee->current->id;
 547
 548   $::request->{layout}->use_javascript("${_}.js")  for qw(ckeditor/ckeditor ckeditor/adapters/jquery);
 549 }
 550
 551 sub _create_pdf {
 552   my ($order, $pdf_ref, $params) = @_;
 553
 554   my $print_form = Form->new('');
 555   $print_form->{type}     = 'sales_order';
 556   $print_form->{formname} = 'sales_order',
 557   $print_form->{format}   = $params->{format} || 'pdf',
 558   $print_form->{media}    = $params->{media}  || 'file';
 559
 560   $order->flatten_to_form($print_form, format_amounts => 1);
 561   # flatten_to_form sets payment_terms from customer/vendor - we do not want that here
 562   delete $print_form->{payment_terms} if !$print_form->{payment_id};
 563
 564   my @errors = ();
 565   $print_form->throw_on_error(sub {
 566     eval {
 567       $print_form->prepare_for_printing;
 568
 569       $$pdf_ref = SL::Helper::CreatePDF->create_pdf(
 570         template  => SL::Helper::CreatePDF->find_template(name => $print_form->{formname}),
 571         variables => $print_form,
 572         variable_content_types => {
 573           longdescription => 'html',
 574           partnotes       => 'html',
 575           notes           => 'html',
 576         },
 577       );
 578       1;
 579     } || push @errors, ref($EVAL_ERROR) eq 'SL::X::FormError' ? $EVAL_ERROR->getMessage : $EVAL_ERROR;
 580   });
 581
 582   return @errors;
 583 }
 584
 585 sub _sales_order_type {
 586   'sales_order';
 587 }
 588
 589 sub _purchase_order_type {
 590   'purchase_order';
 591 }
 592
 593 1;
 594
 595 __END__
 596
 597 =encoding utf-8
 598
 599 =head1 NAME
 600
 601 SL::Controller::Order - controller for orders
 602
 603 =head1 TODO
 604
 605 Testing, PriceSources, pricefactor, units, currency, delivered, delivery order created, ...
 606
 607 =head1 AUTHOR
 608
 609 Bernd Bleßmann E<lt>bernd@kivitendo-premium.deE<gt>
 610
 611 =cut
 612