SL/Controller/Order.pm

   1 package SL::Controller::Order;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use SL::Helper::Flash qw(flash_later);
   7 use SL::Presenter::Tag qw(select_tag hidden_tag div_tag);
   8 use SL::Locale::String qw(t8);
   9 use SL::SessionFile::Random;
  10 use SL::PriceSource;
  11 use SL::Webdav;
  12 use SL::File;
  13 use SL::MIME;
  14 use SL::Util qw(trim);
  15 use SL::YAML;
  16 use SL::DB::History;
  17 use SL::DB::Order;
  18 use SL::DB::Default;
  19 use SL::DB::Unit;
  20 use SL::DB::Part;
  21 use SL::DB::PartClassification;
  22 use SL::DB::PartsGroup;
  23 use SL::DB::Printer;
  24 use SL::DB::Language;
  25 use SL::DB::RecordLink;
  26 use SL::DB::Shipto;
  27 use SL::DB::Translation;
  28
  29 use SL::Helper::CreatePDF qw(:all);
  30 use SL::Helper::PrintOptions;
  31 use SL::Helper::ShippedQty;
  32 use SL::Helper::UserPreferences::PositionsScrollbar;
  33 use SL::Helper::UserPreferences::UpdatePositions;
  34
  35 use SL::Controller::Helper::GetModels;
  36
  37 use List::Util qw(first sum0);
  38 use List::UtilsBy qw(sort_by uniq_by);
  39 use List::MoreUtils qw(any none pairwise first_index);
  40 use English qw(-no_match_vars);
  41 use File::Spec;
  42 use Cwd;
  43 use Sort::Naturally;
  44
  45 use Rose::Object::MakeMethods::Generic
  46 (
  47  scalar => [ qw(item_ids_to_delete is_custom_shipto_to_delete) ],
  48  'scalar --get_set_init' => [ qw(order valid_types type cv p all_price_factors search_cvpartnumber show_update_button part_picker_classification_ids) ],
  49 );
  50
  51
  52 # safety
  53 __PACKAGE__->run_before('check_auth');
  54
  55 __PACKAGE__->run_before('recalc',
  56                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice save_and_ap_transaction
  57                                      print send_email) ]);
  58
  59 __PACKAGE__->run_before('get_unalterable_data',
  60                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice save_and_ap_transaction
  61                                      print send_email) ]);
  62
  63 #
  64 # actions
  65 #
  66
  67 # add a new order
  68 sub action_add {
  69   my ($self) = @_;
  70
  71   $self->order->transdate(DateTime->now_local());
  72   my $extra_days = $self->type eq sales_quotation_type() ? $::instance_conf->get_reqdate_interval       :
  73                    $self->type eq sales_order_type()     ? $::instance_conf->get_delivery_date_interval : 1;
  74
  75   if (   ($self->type eq sales_order_type()     &&  $::instance_conf->get_deliverydate_on)
  76       || ($self->type eq sales_quotation_type() &&  $::instance_conf->get_reqdate_on)
  77       && (!$self->order->reqdate)) {
  78     $self->order->reqdate(DateTime->today_local->next_workday(extra_days => $extra_days));
  79   }
  80
  81
  82   $self->pre_render();
  83   $self->render(
  84     'order/form',
  85     title => $self->get_title_for('add'),
  86     %{$self->{template_args}}
  87   );
  88 }
  89
  90 # edit an existing order
  91 sub action_edit {
  92   my ($self) = @_;
  93
  94   if ($::form->{id}) {
  95     $self->load_order;
  96
  97   } else {
  98     # this is to edit an order from an unsaved order object
  99
 100     # set item ids to new fake id, to identify them as new items
 101     foreach my $item (@{$self->order->items_sorted}) {
 102       $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 103     }
 104     # trigger rendering values for second row as hidden, because they
 105     # are loaded only on demand. So we need to keep the values from
 106     # the source.
 107     $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
 108   }
 109
 110   $self->recalc();
 111   $self->pre_render();
 112   $self->render(
 113     'order/form',
 114     title => $self->get_title_for('edit'),
 115     %{$self->{template_args}}
 116   );
 117 }
 118
 119 # edit a collective order (consisting of one or more existing orders)
 120 sub action_edit_collective {
 121   my ($self) = @_;
 122
 123   # collect order ids
 124   my @multi_ids = map {
 125     $_ =~ m{^multi_id_(\d+)$} && $::form->{'multi_id_' . $1} && $::form->{'trans_id_' . $1} && $::form->{'trans_id_' . $1}
 126   } grep { $_ =~ m{^multi_id_\d+$} } keys %$::form;
 127
 128   # fall back to add if no ids are given
 129   if (scalar @multi_ids == 0) {
 130     $self->action_add();
 131     return;
 132   }
 133
 134   # fall back to save as new if only one id is given
 135   if (scalar @multi_ids == 1) {
 136     $self->order(SL::DB::Order->new(id => $multi_ids[0])->load);
 137     $self->action_save_as_new();
 138     return;
 139   }
 140
 141   # make new order from given orders
 142   my @multi_orders = map { SL::DB::Order->new(id => $_)->load } @multi_ids;
 143   $self->{converted_from_oe_id} = join ' ', map { $_->id } @multi_orders;
 144   $self->order(SL::DB::Order->new_from_multi(\@multi_orders, sort_sources_by => 'transdate'));
 145
 146   $self->action_edit();
 147 }
 148
 149 # delete the order
 150 sub action_delete {
 151   my ($self) = @_;
 152
 153   my $errors = $self->delete();
 154
 155   if (scalar @{ $errors }) {
 156     $self->js->flash('error', $_) foreach @{ $errors };
 157     return $self->js->render();
 158   }
 159
 160   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been deleted')
 161            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been deleted')
 162            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been deleted')
 163            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been deleted')
 164            : '';
 165   flash_later('info', $text);
 166
 167   my @redirect_params = (
 168     action => 'add',
 169     type   => $self->type,
 170   );
 171
 172   $self->redirect_to(@redirect_params);
 173 }
 174
 175 # save the order
 176 sub action_save {
 177   my ($self) = @_;
 178
 179   my $errors = $self->save();
 180
 181   if (scalar @{ $errors }) {
 182     $self->js->flash('error', $_) foreach @{ $errors };
 183     return $self->js->render();
 184   }
 185
 186   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
 187            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
 188            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
 189            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
 190            : '';
 191   flash_later('info', $text);
 192
 193   my @redirect_params = (
 194     action => 'edit',
 195     type   => $self->type,
 196     id     => $self->order->id,
 197   );
 198
 199   $self->redirect_to(@redirect_params);
 200 }
 201
 202 # save the order as new document an open it for edit
 203 sub action_save_as_new {
 204   my ($self) = @_;
 205
 206   my $order = $self->order;
 207
 208   if (!$order->id) {
 209     $self->js->flash('error', t8('This object has not been saved yet.'));
 210     return $self->js->render();
 211   }
 212
 213   # load order from db to check if values changed
 214   my $saved_order = SL::DB::Order->new(id => $order->id)->load;
 215
 216   my %new_attrs;
 217   # Lets assign a new number if the user hasn't changed the previous one.
 218   # If it has been changed manually then use it as-is.
 219   $new_attrs{number}    = (trim($order->number) eq $saved_order->number)
 220                         ? ''
 221                         : trim($order->number);
 222
 223   # Clear transdate unless changed
 224   $new_attrs{transdate} = ($order->transdate == $saved_order->transdate)
 225                         ? DateTime->today_local
 226                         : $order->transdate;
 227
 228   # Set new reqdate unless changed if it is enabled in client config
 229   if ($order->reqdate == $saved_order->reqdate) {
 230     my $extra_days = $self->type eq sales_quotation_type() ? $::instance_conf->get_reqdate_interval       :
 231                      $self->type eq sales_order_type()     ? $::instance_conf->get_delivery_date_interval : 1;
 232
 233     if (   ($self->type eq sales_order_type()     &&  !$::instance_conf->get_deliverydate_on)
 234         || ($self->type eq sales_quotation_type() &&  !$::instance_conf->get_reqdate_on)) {
 235       $new_attrs{reqdate} = '';
 236     } else {
 237       $new_attrs{reqdate} = DateTime->today_local->next_workday(extra_days => $extra_days);
 238     }
 239   } else {
 240     $new_attrs{reqdate} = $order->reqdate;
 241   }
 242
 243   # Update employee
 244   $new_attrs{employee}  = SL::DB::Manager::Employee->current;
 245
 246   # Create new record from current one
 247   $self->order(SL::DB::Order->new_from($order, destination_type => $order->type, attributes => \%new_attrs));
 248
 249   # no linked records on save as new
 250   delete $::form->{$_} for qw(converted_from_oe_id converted_from_orderitems_ids);
 251
 252   # save
 253   $self->action_save();
 254 }
 255
 256 # print the order
 257 #
 258 # This is called if "print" is pressed in the print dialog.
 259 # If PDF creation was requested and succeeded, the pdf is offered for download
 260 # via send_file (which uses ajax in this case).
 261 sub action_print {
 262   my ($self) = @_;
 263
 264   my $errors = $self->save();
 265
 266   if (scalar @{ $errors }) {
 267     $self->js->flash('error', $_) foreach @{ $errors };
 268     return $self->js->render();
 269   }
 270
 271   $self->js_reset_order_and_item_ids_after_save;
 272
 273   my $format      = $::form->{print_options}->{format};
 274   my $media       = $::form->{print_options}->{media};
 275   my $formname    = $::form->{print_options}->{formname};
 276   my $copies      = $::form->{print_options}->{copies};
 277   my $groupitems  = $::form->{print_options}->{groupitems};
 278   my $printer_id  = $::form->{print_options}->{printer_id};
 279
 280   # only pdf and opendocument by now
 281   if (none { $format eq $_ } qw(pdf opendocument opendocument_pdf)) {
 282     return $self->js->flash('error', t8('Format \'#1\' is not supported yet/anymore.', $format))->render;
 283   }
 284
 285   # only screen or printer by now
 286   if (none { $media eq $_ } qw(screen printer)) {
 287     return $self->js->flash('error', t8('Media \'#1\' is not supported yet/anymore.', $media))->render;
 288   }
 289
 290   # create a form for generate_attachment_filename
 291   my $form   = Form->new;
 292   $form->{$self->nr_key()}  = $self->order->number;
 293   $form->{type}             = $self->type;
 294   $form->{format}           = $format;
 295   $form->{formname}         = $formname;
 296   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 297   my $pdf_filename          = $form->generate_attachment_filename();
 298
 299   my $pdf;
 300   my @errors = generate_pdf($self->order, \$pdf, { format     => $format,
 301                                                    formname   => $formname,
 302                                                    language   => $self->order->language,
 303                                                    printer_id => $printer_id,
 304                                                    groupitems => $groupitems });
 305   if (scalar @errors) {
 306     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render;
 307   }
 308
 309   if ($media eq 'screen') {
 310     # screen/download
 311     $self->js->flash('info', t8('The PDF has been created'));
 312     $self->send_file(
 313       \$pdf,
 314       type         => SL::MIME->mime_type_from_ext($pdf_filename),
 315       name         => $pdf_filename,
 316       js_no_render => 1,
 317     );
 318
 319   } elsif ($media eq 'printer') {
 320     # printer
 321     my $printer_id = $::form->{print_options}->{printer_id};
 322     SL::DB::Printer->new(id => $printer_id)->load->print_document(
 323       copies  => $copies,
 324       content => $pdf,
 325     );
 326
 327     $self->js->flash('info', t8('The PDF has been printed'));
 328   }
 329
 330   my @warnings = store_pdf_to_webdav_and_filemanagement($self->order, $pdf, $pdf_filename);
 331   if (scalar @warnings) {
 332     $self->js->flash('warning', $_) for @warnings;
 333   }
 334
 335   $self->save_history('PRINTED');
 336
 337   $self->js
 338     ->run('kivi.ActionBar.setEnabled', '#save_and_email_action')
 339     ->render;
 340 }
 341 sub action_preview_pdf {
 342   my ($self) = @_;
 343
 344   my $errors = $self->save();
 345   if (scalar @{ $errors }) {
 346     $self->js->flash('error', $_) foreach @{ $errors };
 347     return $self->js->render();
 348   }
 349
 350   $self->js_reset_order_and_item_ids_after_save;
 351
 352   my $format      = 'pdf';
 353   my $media       = 'screen';
 354   my $formname    = $self->type;
 355
 356   # only pdf
 357   # create a form for generate_attachment_filename
 358   my $form   = Form->new;
 359   $form->{$self->nr_key()}  = $self->order->number;
 360   $form->{type}             = $self->type;
 361   $form->{format}           = $format;
 362   $form->{formname}         = $formname;
 363   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 364   my $pdf_filename          = $form->generate_attachment_filename();
 365
 366   my $pdf;
 367   my @errors = generate_pdf($self->order, \$pdf, { format     => $format,
 368                                                    formname   => $formname,
 369                                                    language   => $self->order->language,
 370                                                  });
 371   if (scalar @errors) {
 372     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render;
 373   }
 374   $self->save_history('PREVIEWED');
 375   $self->js->flash('info', t8('The PDF has been previewed'));
 376   # screen/download
 377   $self->send_file(
 378     \$pdf,
 379     type         => SL::MIME->mime_type_from_ext($pdf_filename),
 380     name         => $pdf_filename,
 381     js_no_render => 0,
 382   );
 383 }
 384
 385 # open the email dialog
 386 sub action_save_and_show_email_dialog {
 387   my ($self) = @_;
 388
 389   my $errors = $self->save();
 390
 391   if (scalar @{ $errors }) {
 392     $self->js->flash('error', $_) foreach @{ $errors };
 393     return $self->js->render();
 394   }
 395
 396   my $cv_method = $self->cv;
 397
 398   if (!$self->order->$cv_method) {
 399     return $self->js->flash('error', $self->cv eq 'customer' ? t8('Cannot send E-mail without customer given') : t8('Cannot send E-mail without vendor given'))
 400                     ->render($self);
 401   }
 402
 403   my $email_form;
 404   $email_form->{to}   = $self->order->contact->cp_email if $self->order->contact;
 405   $email_form->{to} ||= $self->order->$cv_method->email;
 406   $email_form->{cc}   = $self->order->$cv_method->cc;
 407   $email_form->{bcc}  = join ', ', grep $_, $self->order->$cv_method->bcc, SL::DB::Default->get->global_bcc;
 408   # Todo: get addresses from shipto, if any
 409
 410   my $form = Form->new;
 411   $form->{$self->nr_key()}  = $self->order->number;
 412   $form->{cusordnumber}     = $self->order->cusordnumber;
 413   $form->{formname}         = $self->type;
 414   $form->{type}             = $self->type;
 415   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 416   $form->{language_id}      = $self->order->language->id                  if $self->order->language;
 417   $form->{format}           = 'pdf';
 418   $form->{cp_id}            = $self->order->contact->cp_id if $self->order->contact;
 419
 420   $email_form->{subject}             = $form->generate_email_subject();
 421   $email_form->{attachment_filename} = $form->generate_attachment_filename();
 422   $email_form->{message}             = $form->generate_email_body();
 423   $email_form->{js_send_function}    = 'kivi.Order.send_email()';
 424
 425   my %files = $self->get_files_for_email_dialog();
 426   $self->{all_employees} = SL::DB::Manager::Employee->get_all(query => [ deleted => 0 ]);
 427   my $dialog_html = $self->render('common/_send_email_dialog', { output => 0 },
 428                                   email_form  => $email_form,
 429                                   show_bcc    => $::auth->assert('email_bcc', 'may fail'),
 430                                   FILES       => \%files,
 431                                   is_customer => $self->cv eq 'customer',
 432                                   ALL_EMPLOYEES => $self->{all_employees},
 433   );
 434
 435   $self->js
 436       ->run('kivi.Order.show_email_dialog', $dialog_html)
 437       ->reinit_widgets
 438       ->render($self);
 439 }
 440
 441 # send email
 442 #
 443 # Todo: handling error messages: flash is not displayed in dialog, but in the main form
 444 sub action_send_email {
 445   my ($self) = @_;
 446
 447   my $errors = $self->save();
 448
 449   if (scalar @{ $errors }) {
 450     $self->js->run('kivi.Order.close_email_dialog');
 451     $self->js->flash('error', $_) foreach @{ $errors };
 452     return $self->js->render();
 453   }
 454
 455   $self->js_reset_order_and_item_ids_after_save;
 456
 457   my $email_form  = delete $::form->{email_form};
 458   my %field_names = (to => 'email');
 459
 460   $::form->{ $field_names{$_} // $_ } = $email_form->{$_} for keys %{ $email_form };
 461
 462   # for Form::cleanup which may be called in Form::send_email
 463   $::form->{cwd}    = getcwd();
 464   $::form->{tmpdir} = $::lx_office_conf{paths}->{userspath};
 465
 466   $::form->{$_}     = $::form->{print_options}->{$_} for keys %{ $::form->{print_options} };
 467   $::form->{media}  = 'email';
 468
 469   if (($::form->{attachment_policy} // '') !~ m{^(?:old_file|no_file)$}) {
 470     my $pdf;
 471     my @errors = generate_pdf($self->order, \$pdf, {media      => $::form->{media},
 472                                                     format     => $::form->{print_options}->{format},
 473                                                     formname   => $::form->{print_options}->{formname},
 474                                                     language   => $self->order->language,
 475                                                     printer_id => $::form->{print_options}->{printer_id},
 476                                                     groupitems => $::form->{print_options}->{groupitems}});
 477     if (scalar @errors) {
 478       return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render($self);
 479     }
 480
 481     my @warnings = store_pdf_to_webdav_and_filemanagement($self->order, $pdf, $::form->{attachment_filename});
 482     if (scalar @warnings) {
 483       flash_later('warning', $_) for @warnings;
 484     }
 485
 486     my $sfile = SL::SessionFile::Random->new(mode => "w");
 487     $sfile->fh->print($pdf);
 488     $sfile->fh->close;
 489
 490     $::form->{tmpfile} = $sfile->file_name;
 491     $::form->{tmpdir}  = $sfile->get_path; # for Form::cleanup which may be called in Form::send_email
 492   }
 493
 494   $::form->{id} = $self->order->id; # this is used in SL::Mailer to create a linked record to the mail
 495   $::form->send_email(\%::myconfig, 'pdf');
 496
 497   # internal notes
 498   my $intnotes = $self->order->intnotes;
 499   $intnotes   .= "\n\n" if $self->order->intnotes;
 500   $intnotes   .= t8('[email]')                                                                                        . "\n";
 501   $intnotes   .= t8('Date')       . ": " . $::locale->format_date_object(DateTime->now_local, precision => 'seconds') . "\n";
 502   $intnotes   .= t8('To (email)') . ": " . $::form->{email}                                                           . "\n";
 503   $intnotes   .= t8('Cc')         . ": " . $::form->{cc}                                                              . "\n"    if $::form->{cc};
 504   $intnotes   .= t8('Bcc')        . ": " . $::form->{bcc}                                                             . "\n"    if $::form->{bcc};
 505   $intnotes   .= t8('Subject')    . ": " . $::form->{subject}                                                         . "\n\n";
 506   $intnotes   .= t8('Message')    . ": " . $::form->{message};
 507
 508   $self->order->update_attributes(intnotes => $intnotes);
 509
 510   $self->save_history('MAILED');
 511
 512   flash_later('info', t8('The email has been sent.'));
 513
 514   my @redirect_params = (
 515     action => 'edit',
 516     type   => $self->type,
 517     id     => $self->order->id,
 518   );
 519
 520   $self->redirect_to(@redirect_params);
 521 }
 522
 523 # open the periodic invoices config dialog
 524 #
 525 # If there are values in the form (i.e. dialog was opened before),
 526 # then use this values. Create new ones, else.
 527 sub action_show_periodic_invoices_config_dialog {
 528   my ($self) = @_;
 529
 530   my $config = make_periodic_invoices_config_from_yaml(delete $::form->{config});
 531   $config  ||= SL::DB::Manager::PeriodicInvoicesConfig->find_by(oe_id => $::form->{id}) if $::form->{id};
 532   $config  ||= SL::DB::PeriodicInvoicesConfig->new(periodicity             => 'm',
 533                                                    order_value_periodicity => 'p', # = same as periodicity
 534                                                    start_date_as_date      => $::form->{transdate_as_date} || $::form->current_date,
 535                                                    extend_automatically_by => 12,
 536                                                    active                  => 1,
 537                                                    email_subject           => GenericTranslations->get(
 538                                                                                 language_id      => $::form->{language_id},
 539                                                                                 translation_type =>"preset_text_periodic_invoices_email_subject"),
 540                                                    email_body              => GenericTranslations->get(
 541                                                                                 language_id      => $::form->{language_id},
 542                                                                                 translation_type =>"preset_text_periodic_invoices_email_body"),
 543   );
 544   $config->periodicity('m')             if none { $_ eq $config->periodicity             }       @SL::DB::PeriodicInvoicesConfig::PERIODICITIES;
 545   $config->order_value_periodicity('p') if none { $_ eq $config->order_value_periodicity } ('p', @SL::DB::PeriodicInvoicesConfig::ORDER_VALUE_PERIODICITIES);
 546
 547   $::form->get_lists(printers => "ALL_PRINTERS",
 548                      charts   => { key       => 'ALL_CHARTS',
 549                                    transdate => 'current_date' });
 550
 551   $::form->{AR} = [ grep { $_->{link} =~ m/(?:^|:)AR(?::|$)/ } @{ $::form->{ALL_CHARTS} } ];
 552
 553   if ($::form->{customer_id}) {
 554     $::form->{ALL_CONTACTS} = SL::DB::Manager::Contact->get_all_sorted(where => [ cp_cv_id => $::form->{customer_id} ]);
 555     my $customer_object = SL::DB::Manager::Customer->find_by(id => $::form->{customer_id});
 556     $::form->{postal_invoice}                  = $customer_object->postal_invoice;
 557     $::form->{email_recipient_invoice_address} = $::form->{postal_invoice} ? '' : $customer_object->invoice_mail;
 558     $config->send_email(0) if $::form->{postal_invoice};
 559   }
 560
 561   $self->render('oe/edit_periodic_invoices_config', { layout => 0 },
 562                 popup_dialog             => 1,
 563                 popup_js_close_function  => 'kivi.Order.close_periodic_invoices_config_dialog()',
 564                 popup_js_assign_function => 'kivi.Order.assign_periodic_invoices_config()',
 565                 config                   => $config,
 566                 %$::form);
 567 }
 568
 569 # assign the values of the periodic invoices config dialog
 570 # as yaml in the hidden tag and set the status.
 571 sub action_assign_periodic_invoices_config {
 572   my ($self) = @_;
 573
 574   $::form->isblank('start_date_as_date', $::locale->text('The start date is missing.'));
 575
 576   my $config = { active                     => $::form->{active}       ? 1 : 0,
 577                  terminated                 => $::form->{terminated}   ? 1 : 0,
 578                  direct_debit               => $::form->{direct_debit} ? 1 : 0,
 579                  periodicity                => (any { $_ eq $::form->{periodicity}             }       @SL::DB::PeriodicInvoicesConfig::PERIODICITIES)              ? $::form->{periodicity}             : 'm',
 580                  order_value_periodicity    => (any { $_ eq $::form->{order_value_periodicity} } ('p', @SL::DB::PeriodicInvoicesConfig::ORDER_VALUE_PERIODICITIES)) ? $::form->{order_value_periodicity} : 'p',
 581                  start_date_as_date         => $::form->{start_date_as_date},
 582                  end_date_as_date           => $::form->{end_date_as_date},
 583                  first_billing_date_as_date => $::form->{first_billing_date_as_date},
 584                  print                      => $::form->{print}      ? 1                         : 0,
 585                  printer_id                 => $::form->{print}      ? $::form->{printer_id} * 1 : undef,
 586                  copies                     => $::form->{copies} * 1 ? $::form->{copies}         : 1,
 587                  extend_automatically_by    => $::form->{extend_automatically_by}    * 1 || undef,
 588                  ar_chart_id                => $::form->{ar_chart_id} * 1,
 589                  send_email                 => $::form->{send_email} ? 1 : 0,
 590                  email_recipient_contact_id => $::form->{email_recipient_contact_id} * 1 || undef,
 591                  email_recipient_address    => $::form->{email_recipient_address},
 592                  email_sender               => $::form->{email_sender},
 593                  email_subject              => $::form->{email_subject},
 594                  email_body                 => $::form->{email_body},
 595                };
 596
 597   my $periodic_invoices_config = SL::YAML::Dump($config);
 598
 599   my $status = $self->get_periodic_invoices_status($config);
 600
 601   $self->js
 602     ->remove('#order_periodic_invoices_config')
 603     ->insertAfter(hidden_tag('order.periodic_invoices_config', $periodic_invoices_config), '#periodic_invoices_status')
 604     ->run('kivi.Order.close_periodic_invoices_config_dialog')
 605     ->html('#periodic_invoices_status', $status)
 606     ->flash('info', t8('The periodic invoices config has been assigned.'))
 607     ->render($self);
 608 }
 609
 610 sub action_get_has_active_periodic_invoices {
 611   my ($self) = @_;
 612
 613   my $config = make_periodic_invoices_config_from_yaml(delete $::form->{config});
 614   $config  ||= SL::DB::Manager::PeriodicInvoicesConfig->find_by(oe_id => $::form->{id}) if $::form->{id};
 615
 616   my $has_active_periodic_invoices =
 617        $self->type eq sales_order_type()
 618     && $config
 619     && $config->active
 620     && (!$config->end_date || ($config->end_date > DateTime->today_local))
 621     && $config->get_previous_billed_period_start_date;
 622
 623   $_[0]->render(\ !!$has_active_periodic_invoices, { type => 'text' });
 624 }
 625
 626 # save the order and redirect to the frontend subroutine for a new
 627 # delivery order
 628 sub action_save_and_delivery_order {
 629   my ($self) = @_;
 630
 631   $self->save_and_redirect_to(
 632     controller => 'oe.pl',
 633     action     => 'oe_delivery_order_from_order',
 634   );
 635 }
 636
 637 # save the order and redirect to the frontend subroutine for a new
 638 # invoice
 639 sub action_save_and_invoice {
 640   my ($self) = @_;
 641
 642   $self->save_and_redirect_to(
 643     controller => 'oe.pl',
 644     action     => 'oe_invoice_from_order',
 645   );
 646 }
 647
 648 # workflow from sales order to sales quotation
 649 sub action_sales_quotation {
 650   $_[0]->workflow_sales_or_request_for_quotation();
 651 }
 652
 653 # workflow from sales order to sales quotation
 654 sub action_request_for_quotation {
 655   $_[0]->workflow_sales_or_request_for_quotation();
 656 }
 657
 658 # workflow from sales quotation to sales order
 659 sub action_sales_order {
 660   $_[0]->workflow_sales_or_purchase_order();
 661 }
 662
 663 # workflow from rfq to purchase order
 664 sub action_purchase_order {
 665   $_[0]->workflow_sales_or_purchase_order();
 666 }
 667
 668 # workflow from purchase order to ap transaction
 669 sub action_save_and_ap_transaction {
 670   my ($self) = @_;
 671
 672   $self->save_and_redirect_to(
 673     controller => 'ap.pl',
 674     action     => 'add_from_purchase_order',
 675   );
 676 }
 677
 678 # set form elements in respect to a changed customer or vendor
 679 #
 680 # This action is called on an change of the customer/vendor picker.
 681 sub action_customer_vendor_changed {
 682   my ($self) = @_;
 683
 684   setup_order_from_cv($self->order);
 685   $self->recalc();
 686
 687   my $cv_method = $self->cv;
 688
 689   if ($self->order->$cv_method->contacts && scalar @{ $self->order->$cv_method->contacts } > 0) {
 690     $self->js->show('#cp_row');
 691   } else {
 692     $self->js->hide('#cp_row');
 693   }
 694
 695   if ($self->order->$cv_method->shipto && scalar @{ $self->order->$cv_method->shipto } > 0) {
 696     $self->js->show('#shipto_selection');
 697   } else {
 698     $self->js->hide('#shipto_selection');
 699   }
 700
 701   $self->js->val( '#order_salesman_id',      $self->order->salesman_id)        if $self->order->is_sales;
 702
 703   $self->js
 704     ->replaceWith('#order_cp_id',            $self->build_contact_select)
 705     ->replaceWith('#order_shipto_id',        $self->build_shipto_select)
 706     ->replaceWith('#shipto_inputs  ',        $self->build_shipto_inputs)
 707     ->replaceWith('#business_info_row',      $self->build_business_info_row)
 708     ->val(        '#order_taxzone_id',       $self->order->taxzone_id)
 709     ->val(        '#order_taxincluded',      $self->order->taxincluded)
 710     ->val(        '#order_currency_id',      $self->order->currency_id)
 711     ->val(        '#order_payment_id',       $self->order->payment_id)
 712     ->val(        '#order_delivery_term_id', $self->order->delivery_term_id)
 713     ->val(        '#order_intnotes',         $self->order->intnotes)
 714     ->val(        '#order_language_id',      $self->order->$cv_method->language_id)
 715     ->focus(      '#order_' . $self->cv . '_id')
 716     ->run('kivi.Order.update_exchangerate');
 717
 718   $self->js_redisplay_amounts_and_taxes;
 719   $self->js_redisplay_cvpartnumbers;
 720   $self->js->render();
 721 }
 722
 723 # open the dialog for customer/vendor details
 724 sub action_show_customer_vendor_details_dialog {
 725   my ($self) = @_;
 726
 727   my $is_customer = 'customer' eq $::form->{vc};
 728   my $cv;
 729   if ($is_customer) {
 730     $cv = SL::DB::Customer->new(id => $::form->{vc_id})->load;
 731   } else {
 732     $cv = SL::DB::Vendor->new(id => $::form->{vc_id})->load;
 733   }
 734
 735   my %details = map { $_ => $cv->$_ } @{$cv->meta->columns};
 736   $details{discount_as_percent} = $cv->discount_as_percent;
 737   $details{creditlimt}          = $cv->creditlimit_as_number;
 738   $details{business}            = $cv->business->description      if $cv->business;
 739   $details{language}            = $cv->language_obj->description  if $cv->language_obj;
 740   $details{delivery_terms}      = $cv->delivery_term->description if $cv->delivery_term;
 741   $details{payment_terms}       = $cv->payment->description       if $cv->payment;
 742   $details{pricegroup}          = $cv->pricegroup->pricegroup     if $is_customer && $cv->pricegroup;
 743
 744   foreach my $entry (@{ $cv->shipto }) {
 745     push @{ $details{SHIPTO} },   { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 746   }
 747   foreach my $entry (@{ $cv->contacts }) {
 748     push @{ $details{CONTACTS} }, { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 749   }
 750
 751   $_[0]->render('common/show_vc_details', { layout => 0 },
 752                 is_customer => $is_customer,
 753                 %details);
 754
 755 }
 756
 757 # called if a unit in an existing item row is changed
 758 sub action_unit_changed {
 759   my ($self) = @_;
 760
 761   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 762   my $item = $self->order->items_sorted->[$idx];
 763
 764   my $old_unit_obj = SL::DB::Unit->new(name => $::form->{old_unit})->load;
 765   $item->sellprice($item->unit_obj->convert_to($item->sellprice, $old_unit_obj));
 766
 767   $self->recalc();
 768
 769   $self->js
 770     ->run('kivi.Order.update_sellprice', $::form->{item_id}, $item->sellprice_as_number);
 771   $self->js_redisplay_line_values;
 772   $self->js_redisplay_amounts_and_taxes;
 773   $self->js->render();
 774 }
 775
 776 # add an item row for a new item entered in the input row
 777 sub action_add_item {
 778   my ($self) = @_;
 779
 780   my $form_attr = $::form->{add_item};
 781
 782   return unless $form_attr->{parts_id};
 783
 784   my $item = new_item($self->order, $form_attr);
 785
 786   $self->order->add_items($item);
 787
 788   $self->recalc();
 789
 790   $self->get_item_cvpartnumber($item);
 791
 792   my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 793   my $row_as_html = $self->p->render('order/tabs/_row',
 794                                      ITEM => $item,
 795                                      ID   => $item_id,
 796                                      SELF => $self,
 797   );
 798
 799   if ($::form->{insert_before_item_id}) {
 800     $self->js
 801       ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 802   } else {
 803     $self->js
 804       ->append('#row_table_id', $row_as_html);
 805   }
 806
 807   if ( $item->part->is_assortment ) {
 808     $form_attr->{qty_as_number} = 1 unless $form_attr->{qty_as_number};
 809     foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 810       my $attr = { parts_id => $assortment_item->parts_id,
 811                    qty      => $assortment_item->qty * $::form->parse_amount(\%::myconfig, $form_attr->{qty_as_number}), # TODO $form_attr->{unit}
 812                    unit     => $assortment_item->unit,
 813                    description => $assortment_item->part->description,
 814                  };
 815       my $item = new_item($self->order, $attr);
 816
 817       # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 818       $item->discount(1) unless $assortment_item->charge;
 819
 820       $self->order->add_items( $item );
 821       $self->recalc();
 822       $self->get_item_cvpartnumber($item);
 823       my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 824       my $row_as_html = $self->p->render('order/tabs/_row',
 825                                          ITEM => $item,
 826                                          ID   => $item_id,
 827                                          SELF => $self,
 828       );
 829       if ($::form->{insert_before_item_id}) {
 830         $self->js
 831           ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 832       } else {
 833         $self->js
 834           ->append('#row_table_id', $row_as_html);
 835       }
 836     };
 837   };
 838
 839   $self->js
 840     ->val('.add_item_input', '')
 841     ->run('kivi.Order.init_row_handlers')
 842     ->run('kivi.Order.renumber_positions')
 843     ->focus('#add_item_parts_id_name');
 844
 845   $self->js->run('kivi.Order.row_table_scroll_down') if !$::form->{insert_before_item_id};
 846
 847   $self->js_redisplay_amounts_and_taxes;
 848   $self->js->render();
 849 }
 850
 851 # add item rows for multiple items at once
 852 sub action_add_multi_items {
 853   my ($self) = @_;
 854
 855   my @form_attr = grep { $_->{qty_as_number} } @{ $::form->{add_items} };
 856   return $self->js->render() unless scalar @form_attr;
 857
 858   my @items;
 859   foreach my $attr (@form_attr) {
 860     my $item = new_item($self->order, $attr);
 861     push @items, $item;
 862     if ( $item->part->is_assortment ) {
 863       foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 864         my $attr = { parts_id => $assortment_item->parts_id,
 865                      qty      => $assortment_item->qty * $item->qty, # TODO $form_attr->{unit}
 866                      unit     => $assortment_item->unit,
 867                      description => $assortment_item->part->description,
 868                    };
 869         my $item = new_item($self->order, $attr);
 870
 871         # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 872         $item->discount(1) unless $assortment_item->charge;
 873         push @items, $item;
 874       }
 875     }
 876   }
 877   $self->order->add_items(@items);
 878
 879   $self->recalc();
 880
 881   foreach my $item (@items) {
 882     $self->get_item_cvpartnumber($item);
 883     my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 884     my $row_as_html = $self->p->render('order/tabs/_row',
 885                                        ITEM => $item,
 886                                        ID   => $item_id,
 887                                        SELF => $self,
 888     );
 889
 890     if ($::form->{insert_before_item_id}) {
 891       $self->js
 892         ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 893     } else {
 894       $self->js
 895         ->append('#row_table_id', $row_as_html);
 896     }
 897   }
 898
 899   $self->js
 900     ->run('kivi.Part.close_picker_dialogs')
 901     ->run('kivi.Order.init_row_handlers')
 902     ->run('kivi.Order.renumber_positions')
 903     ->focus('#add_item_parts_id_name');
 904
 905   $self->js->run('kivi.Order.row_table_scroll_down') if !$::form->{insert_before_item_id};
 906
 907   $self->js_redisplay_amounts_and_taxes;
 908   $self->js->render();
 909 }
 910
 911 # recalculate all linetotals, amounts and taxes and redisplay them
 912 sub action_recalc_amounts_and_taxes {
 913   my ($self) = @_;
 914
 915   $self->recalc();
 916
 917   $self->js_redisplay_line_values;
 918   $self->js_redisplay_amounts_and_taxes;
 919   $self->js->render();
 920 }
 921
 922 sub action_update_exchangerate {
 923   my ($self) = @_;
 924
 925   my $data = {
 926     is_standard   => $self->order->currency_id == $::instance_conf->get_currency_id,
 927     currency_name => $self->order->currency->name,
 928     exchangerate  => $self->order->daily_exchangerate_as_null_number,
 929   };
 930
 931   $self->render(\SL::JSON::to_json($data), { type => 'json', process => 0 });
 932 }
 933
 934 # redisplay item rows if they are sorted by an attribute
 935 sub action_reorder_items {
 936   my ($self) = @_;
 937
 938   my %sort_keys = (
 939     partnumber   => sub { $_[0]->part->partnumber },
 940     description  => sub { $_[0]->description },
 941     qty          => sub { $_[0]->qty },
 942     sellprice    => sub { $_[0]->sellprice },
 943     discount     => sub { $_[0]->discount },
 944     cvpartnumber => sub { $_[0]->{cvpartnumber} },
 945   );
 946
 947   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
 948
 949   my $method = $sort_keys{$::form->{order_by}};
 950   my @to_sort = map { { old_pos => $_->position, order_by => $method->($_) } } @{ $self->order->items_sorted };
 951   if ($::form->{sort_dir}) {
 952     if ( $::form->{order_by} =~ m/qty|sellprice|discount/ ){
 953       @to_sort = sort { $a->{order_by} <=> $b->{order_by} } @to_sort;
 954     } else {
 955       @to_sort = sort { $a->{order_by} cmp $b->{order_by} } @to_sort;
 956     }
 957   } else {
 958     if ( $::form->{order_by} =~ m/qty|sellprice|discount/ ){
 959       @to_sort = sort { $b->{order_by} <=> $a->{order_by} } @to_sort;
 960     } else {
 961       @to_sort = sort { $b->{order_by} cmp $a->{order_by} } @to_sort;
 962     }
 963   }
 964   $self->js
 965     ->run('kivi.Order.redisplay_items', \@to_sort)
 966     ->render;
 967 }
 968
 969 # show the popup to choose a price/discount source
 970 sub action_price_popup {
 971   my ($self) = @_;
 972
 973   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 974   my $item = $self->order->items_sorted->[$idx];
 975
 976   $self->render_price_dialog($item);
 977 }
 978
 979 # load the second row for one or more items
 980 #
 981 # This action gets the html code for all items second rows by rendering a template for
 982 # the second row and sets the html code via client js.
 983 sub action_load_second_rows {
 984   my ($self) = @_;
 985
 986   $self->recalc() if $self->order->is_sales; # for margin calculation
 987
 988   foreach my $item_id (@{ $::form->{item_ids} }) {
 989     my $idx  = first_index { $_ eq $item_id } @{ $::form->{orderitem_ids} };
 990     my $item = $self->order->items_sorted->[$idx];
 991
 992     $self->js_load_second_row($item, $item_id, 0);
 993   }
 994
 995   $self->js->run('kivi.Order.init_row_handlers') if $self->order->is_sales; # for lastcosts change-callback
 996
 997   $self->js->render();
 998 }
 999
1000 # update description, notes and sellprice from master data
1001 sub action_update_row_from_master_data {
1002   my ($self) = @_;
1003
1004   foreach my $item_id (@{ $::form->{item_ids} }) {
1005     my $idx   = first_index { $_ eq $item_id } @{ $::form->{orderitem_ids} };
1006     my $item  = $self->order->items_sorted->[$idx];
1007     my $texts = get_part_texts($item->part, $self->order->language_id);
1008
1009     $item->description($texts->{description});
1010     $item->longdescription($texts->{longdescription});
1011
1012     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
1013
1014     my $price_src;
1015     if ($item->part->is_assortment) {
1016     # add assortment items with price 0, as the components carry the price
1017       $price_src = $price_source->price_from_source("");
1018       $price_src->price(0);
1019     } else {
1020       $price_src = $price_source->best_price
1021                  ? $price_source->best_price
1022                  : $price_source->price_from_source("");
1023       $price_src->price($::form->round_amount($price_src->price / $self->order->exchangerate, 5)) if $self->order->exchangerate;
1024       $price_src->price(0) if !$price_source->best_price;
1025     }
1026
1027
1028     $item->sellprice($price_src->price);
1029     $item->active_price_source($price_src);
1030
1031     $self->js
1032       ->run('kivi.Order.update_sellprice', $item_id, $item->sellprice_as_number)
1033       ->html('.row_entry:has(#item_' . $item_id . ') [name = "partnumber"] a', $item->part->partnumber)
1034       ->val ('.row_entry:has(#item_' . $item_id . ') [name = "order.orderitems[].description"]', $item->description)
1035       ->val ('.row_entry:has(#item_' . $item_id . ') [name = "order.orderitems[].longdescription"]', $item->longdescription);
1036
1037     if ($self->search_cvpartnumber) {
1038       $self->get_item_cvpartnumber($item);
1039       $self->js->html('.row_entry:has(#item_' . $item_id . ') [name = "cvpartnumber"]', $item->{cvpartnumber});
1040     }
1041   }
1042
1043   $self->recalc();
1044   $self->js_redisplay_line_values;
1045   $self->js_redisplay_amounts_and_taxes;
1046
1047   $self->js->render();
1048 }
1049
1050 sub js_load_second_row {
1051   my ($self, $item, $item_id, $do_parse) = @_;
1052
1053   if ($do_parse) {
1054     # Parse values from form (they are formated while rendering (template)).
1055     # Workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
1056     # This parsing is not necessary at all, if we assure that the second row/cvars are only loaded once.
1057     foreach my $var (@{ $item->cvars_by_config }) {
1058       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
1059     }
1060     $item->parse_custom_variable_values;
1061   }
1062
1063   my $row_as_html = $self->p->render('order/tabs/_second_row', ITEM => $item, TYPE => $self->type);
1064
1065   $self->js
1066     ->html('#second_row_' . $item_id, $row_as_html)
1067     ->data('#second_row_' . $item_id, 'loaded', 1);
1068 }
1069
1070 sub js_redisplay_line_values {
1071   my ($self) = @_;
1072
1073   my $is_sales = $self->order->is_sales;
1074
1075   # sales orders with margins
1076   my @data;
1077   if ($is_sales) {
1078     @data = map {
1079       [
1080        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
1081        $::form->format_amount(\%::myconfig, $_->{marge_total},   2, 0),
1082        $::form->format_amount(\%::myconfig, $_->{marge_percent}, 2, 0),
1083       ]} @{ $self->order->items_sorted };
1084   } else {
1085     @data = map {
1086       [
1087        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
1088       ]} @{ $self->order->items_sorted };
1089   }
1090
1091   $self->js
1092     ->run('kivi.Order.redisplay_line_values', $is_sales, \@data);
1093 }
1094
1095 sub js_redisplay_amounts_and_taxes {
1096   my ($self) = @_;
1097
1098   if (scalar @{ $self->{taxes} }) {
1099     $self->js->show('#taxincluded_row_id');
1100   } else {
1101     $self->js->hide('#taxincluded_row_id');
1102   }
1103
1104   if ($self->order->taxincluded) {
1105     $self->js->hide('#subtotal_row_id');
1106   } else {
1107     $self->js->show('#subtotal_row_id');
1108   }
1109
1110   if ($self->order->is_sales) {
1111     my $is_neg = $self->order->marge_total < 0;
1112     $self->js
1113       ->html('#marge_total_id',   $::form->format_amount(\%::myconfig, $self->order->marge_total,   2))
1114       ->html('#marge_percent_id', $::form->format_amount(\%::myconfig, $self->order->marge_percent, 2))
1115       ->action_if( $is_neg, 'addClass',    '#marge_total_id',        'plus0')
1116       ->action_if( $is_neg, 'addClass',    '#marge_percent_id',      'plus0')
1117       ->action_if( $is_neg, 'addClass',    '#marge_percent_sign_id', 'plus0')
1118       ->action_if(!$is_neg, 'removeClass', '#marge_total_id',        'plus0')
1119       ->action_if(!$is_neg, 'removeClass', '#marge_percent_id',      'plus0')
1120       ->action_if(!$is_neg, 'removeClass', '#marge_percent_sign_id', 'plus0');
1121   }
1122
1123   $self->js
1124     ->html('#netamount_id', $::form->format_amount(\%::myconfig, $self->order->netamount, -2))
1125     ->html('#amount_id',    $::form->format_amount(\%::myconfig, $self->order->amount,    -2))
1126     ->remove('.tax_row')
1127     ->insertBefore($self->build_tax_rows, '#amount_row_id');
1128 }
1129
1130 sub js_redisplay_cvpartnumbers {
1131   my ($self) = @_;
1132
1133   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
1134
1135   my @data = map {[$_->{cvpartnumber}]} @{ $self->order->items_sorted };
1136
1137   $self->js
1138     ->run('kivi.Order.redisplay_cvpartnumbers', \@data);
1139 }
1140
1141 sub js_reset_order_and_item_ids_after_save {
1142   my ($self) = @_;
1143
1144   $self->js
1145     ->val('#id', $self->order->id)
1146     ->val('#converted_from_oe_id', '')
1147     ->val('#order_' . $self->nr_key(), $self->order->number);
1148
1149   my $idx = 0;
1150   foreach my $form_item_id (@{ $::form->{orderitem_ids} }) {
1151     next if !$self->order->items_sorted->[$idx]->id;
1152     next if $form_item_id !~ m{^new};
1153     $self->js
1154       ->val ('[name="orderitem_ids[+]"][value="' . $form_item_id . '"]', $self->order->items_sorted->[$idx]->id)
1155       ->val ('#item_' . $form_item_id, $self->order->items_sorted->[$idx]->id)
1156       ->attr('#item_' . $form_item_id, "id", 'item_' . $self->order->items_sorted->[$idx]->id);
1157   } continue {
1158     $idx++;
1159   }
1160   $self->js->val('[name="converted_from_orderitems_ids[+]"]', '');
1161 }
1162
1163 #
1164 # helpers
1165 #
1166
1167 sub init_valid_types {
1168   [ sales_order_type(), purchase_order_type(), sales_quotation_type(), request_quotation_type() ];
1169 }
1170
1171 sub init_type {
1172   my ($self) = @_;
1173
1174   if (none { $::form->{type} eq $_ } @{$self->valid_types}) {
1175     die "Not a valid type for order";
1176   }
1177
1178   $self->type($::form->{type});
1179 }
1180
1181 sub init_cv {
1182   my ($self) = @_;
1183
1184   my $cv = (any { $self->type eq $_ } (sales_order_type(),    sales_quotation_type()))   ? 'customer'
1185          : (any { $self->type eq $_ } (purchase_order_type(), request_quotation_type())) ? 'vendor'
1186          : die "Not a valid type for order";
1187
1188   return $cv;
1189 }
1190
1191 sub init_search_cvpartnumber {
1192   my ($self) = @_;
1193
1194   my $user_prefs = SL::Helper::UserPreferences::PartPickerSearch->new();
1195   my $search_cvpartnumber;
1196   $search_cvpartnumber = !!$user_prefs->get_sales_search_customer_partnumber() if $self->cv eq 'customer';
1197   $search_cvpartnumber = !!$user_prefs->get_purchase_search_makemodel()        if $self->cv eq 'vendor';
1198
1199   return $search_cvpartnumber;
1200 }
1201
1202 sub init_show_update_button {
1203   my ($self) = @_;
1204
1205   !!SL::Helper::UserPreferences::UpdatePositions->new()->get_show_update_button();
1206 }
1207
1208 sub init_p {
1209   SL::Presenter->get;
1210 }
1211
1212 sub init_order {
1213   $_[0]->make_order;
1214 }
1215
1216 sub init_all_price_factors {
1217   SL::DB::Manager::PriceFactor->get_all;
1218 }
1219
1220 sub init_part_picker_classification_ids {
1221   my ($self)    = @_;
1222   my $attribute = 'used_for_' . ($self->type =~ m{sales} ? 'sale' : 'purchase');
1223
1224   return [ map { $_->id } @{ SL::DB::Manager::PartClassification->get_all(where => [ $attribute => 1 ]) } ];
1225 }
1226
1227 sub check_auth {
1228   my ($self) = @_;
1229
1230   my $right_for = { map { $_ => $_.'_edit' } @{$self->valid_types} };
1231
1232   my $right   = $right_for->{ $self->type };
1233   $right    ||= 'DOES_NOT_EXIST';
1234
1235   $::auth->assert($right);
1236 }
1237
1238 # build the selection box for contacts
1239 #
1240 # Needed, if customer/vendor changed.
1241 sub build_contact_select {
1242   my ($self) = @_;
1243
1244   select_tag('order.cp_id', [ $self->order->{$self->cv}->contacts ],
1245     value_key  => 'cp_id',
1246     title_key  => 'full_name_dep',
1247     default    => $self->order->cp_id,
1248     with_empty => 1,
1249     style      => 'width: 300px',
1250   );
1251 }
1252
1253 # build the selection box for shiptos
1254 #
1255 # Needed, if customer/vendor changed.
1256 sub build_shipto_select {
1257   my ($self) = @_;
1258
1259   select_tag('order.shipto_id',
1260              [ {displayable_id => t8("No/individual shipping address"), shipto_id => ''}, $self->order->{$self->cv}->shipto ],
1261              value_key  => 'shipto_id',
1262              title_key  => 'displayable_id',
1263              default    => $self->order->shipto_id,
1264              with_empty => 0,
1265              style      => 'width: 300px',
1266   );
1267 }
1268
1269 # build the inputs for the cusom shipto dialog
1270 #
1271 # Needed, if customer/vendor changed.
1272 sub build_shipto_inputs {
1273   my ($self) = @_;
1274
1275   my $content = $self->p->render('common/_ship_to_dialog',
1276                                  vc_obj      => $self->order->customervendor,
1277                                  cs_obj      => $self->order->custom_shipto,
1278                                  cvars       => $self->order->custom_shipto->cvars_by_config,
1279                                  id_selector => '#order_shipto_id');
1280
1281   div_tag($content, id => 'shipto_inputs');
1282 }
1283
1284 # render the info line for business
1285 #
1286 # Needed, if customer/vendor changed.
1287 sub build_business_info_row
1288 {
1289   $_[0]->p->render('order/tabs/_business_info_row', SELF => $_[0]);
1290 }
1291
1292 # build the rows for displaying taxes
1293 #
1294 # Called if amounts where recalculated and redisplayed.
1295 sub build_tax_rows {
1296   my ($self) = @_;
1297
1298   my $rows_as_html;
1299   foreach my $tax (sort { $a->{tax}->rate cmp $b->{tax}->rate } @{ $self->{taxes} }) {
1300     $rows_as_html .= $self->p->render('order/tabs/_tax_row', TAX => $tax, TAXINCLUDED => $self->order->taxincluded);
1301   }
1302   return $rows_as_html;
1303 }
1304
1305
1306 sub render_price_dialog {
1307   my ($self, $record_item) = @_;
1308
1309   my $price_source = SL::PriceSource->new(record_item => $record_item, record => $self->order);
1310
1311   $self->js
1312     ->run(
1313       'kivi.io.price_chooser_dialog',
1314       t8('Available Prices'),
1315       $self->render('order/tabs/_price_sources_dialog', { output => 0 }, price_source => $price_source)
1316     )
1317     ->reinit_widgets;
1318
1319 #   if (@errors) {
1320 #     $self->js->text('#dialog_flash_error_content', join ' ', @errors);
1321 #     $self->js->show('#dialog_flash_error');
1322 #   }
1323
1324   $self->js->render;
1325 }
1326
1327 sub load_order {
1328   my ($self) = @_;
1329
1330   return if !$::form->{id};
1331
1332   $self->order(SL::DB::Order->new(id => $::form->{id})->load);
1333
1334   # Add an empty custom shipto to the order, so that the dialog can render the cvar inputs.
1335   # You need a custom shipto object to call cvars_by_config to get the cvars.
1336   $self->order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => [])) if !$self->order->custom_shipto;
1337
1338   return $self->order;
1339 }
1340
1341 # load or create a new order object
1342 #
1343 # And assign changes from the form to this object.
1344 # If the order is loaded from db, check if items are deleted in the form,
1345 # remove them form the object and collect them for removing from db on saving.
1346 # Then create/update items from form (via make_item) and add them.
1347 sub make_order {
1348   my ($self) = @_;
1349
1350   # add_items adds items to an order with no items for saving, but they cannot
1351   # be retrieved via items until the order is saved. Adding empty items to new
1352   # order here solves this problem.
1353   my $order;
1354   $order   = SL::DB::Order->new(id => $::form->{id})->load(with => [ 'orderitems', 'orderitems.part' ]) if $::form->{id};
1355   $order ||= SL::DB::Order->new(orderitems  => [],
1356                                 quotation   => (any { $self->type eq $_ } (sales_quotation_type(), request_quotation_type())),
1357                                 currency_id => $::instance_conf->get_currency_id(),);
1358
1359   my $cv_id_method = $self->cv . '_id';
1360   if (!$::form->{id} && $::form->{$cv_id_method}) {
1361     $order->$cv_id_method($::form->{$cv_id_method});
1362     setup_order_from_cv($order);
1363   }
1364
1365   my $form_orderitems                  = delete $::form->{order}->{orderitems};
1366   my $form_periodic_invoices_config    = delete $::form->{order}->{periodic_invoices_config};
1367
1368   $order->assign_attributes(%{$::form->{order}});
1369
1370   $self->setup_custom_shipto_from_form($order, $::form);
1371
1372   if (my $periodic_invoices_config_attrs = $form_periodic_invoices_config ? SL::YAML::Load($form_periodic_invoices_config) : undef) {
1373     my $periodic_invoices_config = $order->periodic_invoices_config || $order->periodic_invoices_config(SL::DB::PeriodicInvoicesConfig->new);
1374     $periodic_invoices_config->assign_attributes(%$periodic_invoices_config_attrs);
1375   }
1376
1377   # remove deleted items
1378   $self->item_ids_to_delete([]);
1379   foreach my $idx (reverse 0..$#{$order->orderitems}) {
1380     my $item = $order->orderitems->[$idx];
1381     if (none { $item->id == $_->{id} } @{$form_orderitems}) {
1382       splice @{$order->orderitems}, $idx, 1;
1383       push @{$self->item_ids_to_delete}, $item->id;
1384     }
1385   }
1386
1387   my @items;
1388   my $pos = 1;
1389   foreach my $form_attr (@{$form_orderitems}) {
1390     my $item = make_item($order, $form_attr);
1391     $item->position($pos);
1392     push @items, $item;
1393     $pos++;
1394   }
1395   $order->add_items(grep {!$_->id} @items);
1396
1397   return $order;
1398 }
1399
1400 # create or update items from form
1401 #
1402 # Make item objects from form values. For items already existing read from db.
1403 # Create a new item else. And assign attributes.
1404 sub make_item {
1405   my ($record, $attr) = @_;
1406
1407   my $item;
1408   $item = first { $_->id == $attr->{id} } @{$record->items} if $attr->{id};
1409
1410   my $is_new = !$item;
1411
1412   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1413   # they cannot be retrieved via custom_variables until the order/orderitem is
1414   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1415   $item ||= SL::DB::OrderItem->new(custom_variables => []);
1416
1417   $item->assign_attributes(%$attr);
1418
1419   if ($is_new) {
1420     my $texts = get_part_texts($item->part, $record->language_id);
1421     $item->longdescription($texts->{longdescription})              if !defined $attr->{longdescription};
1422     $item->project_id($record->globalproject_id)                   if !defined $attr->{project_id};
1423     $item->lastcost($record->is_sales ? $item->part->lastcost : 0) if !defined $attr->{lastcost_as_number};
1424   }
1425
1426   return $item;
1427 }
1428
1429 # create a new item
1430 #
1431 # This is used to add one item
1432 sub new_item {
1433   my ($record, $attr) = @_;
1434
1435   my $item = SL::DB::OrderItem->new;
1436
1437   # Remove attributes where the user left or set the inputs empty.
1438   # So these attributes will be undefined and we can distinguish them
1439   # from zero later on.
1440   for (qw(qty_as_number sellprice_as_number discount_as_percent)) {
1441     delete $attr->{$_} if $attr->{$_} eq '';
1442   }
1443
1444   $item->assign_attributes(%$attr);
1445
1446   my $part         = SL::DB::Part->new(id => $attr->{parts_id})->load;
1447   my $price_source = SL::PriceSource->new(record_item => $item, record => $record);
1448
1449   $item->unit($part->unit) if !$item->unit;
1450
1451   my $price_src;
1452   if ( $part->is_assortment ) {
1453     # add assortment items with price 0, as the components carry the price
1454     $price_src = $price_source->price_from_source("");
1455     $price_src->price(0);
1456   } elsif (defined $item->sellprice) {
1457     $price_src = $price_source->price_from_source("");
1458     $price_src->price($item->sellprice);
1459   } else {
1460     $price_src = $price_source->best_price
1461                ? $price_source->best_price
1462                : $price_source->price_from_source("");
1463     $price_src->price($::form->round_amount($price_src->price / $record->exchangerate, 5)) if $record->exchangerate;
1464     $price_src->price(0) if !$price_source->best_price;
1465   }
1466
1467   my $discount_src;
1468   if (defined $item->discount) {
1469     $discount_src = $price_source->discount_from_source("");
1470     $discount_src->discount($item->discount);
1471   } else {
1472     $discount_src = $price_source->best_discount
1473                   ? $price_source->best_discount
1474                   : $price_source->discount_from_source("");
1475     $discount_src->discount(0) if !$price_source->best_discount;
1476   }
1477
1478   my %new_attr;
1479   $new_attr{part}                   = $part;
1480   $new_attr{description}            = $part->description     if ! $item->description;
1481   $new_attr{qty}                    = 1.0                    if ! $item->qty;
1482   $new_attr{price_factor_id}        = $part->price_factor_id if ! $item->price_factor_id;
1483   $new_attr{sellprice}              = $price_src->price;
1484   $new_attr{discount}               = $discount_src->discount;
1485   $new_attr{active_price_source}    = $price_src;
1486   $new_attr{active_discount_source} = $discount_src;
1487   $new_attr{longdescription}        = $part->notes           if ! defined $attr->{longdescription};
1488   $new_attr{project_id}             = $record->globalproject_id;
1489   $new_attr{lastcost}               = $record->is_sales ? $part->lastcost : 0;
1490
1491   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1492   # they cannot be retrieved via custom_variables until the order/orderitem is
1493   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1494   $new_attr{custom_variables} = [];
1495
1496   my $texts = get_part_texts($part, $record->language_id, description => $new_attr{description}, longdescription => $new_attr{longdescription});
1497
1498   $item->assign_attributes(%new_attr, %{ $texts });
1499
1500   return $item;
1501 }
1502
1503 sub setup_order_from_cv {
1504   my ($order) = @_;
1505
1506   $order->$_($order->customervendor->$_) for (qw(taxzone_id payment_id delivery_term_id currency_id));
1507
1508   $order->intnotes($order->customervendor->notes);
1509
1510   if ($order->is_sales) {
1511     $order->salesman_id($order->customer->salesman_id || SL::DB::Manager::Employee->current->id);
1512     $order->taxincluded(defined($order->customer->taxincluded_checked)
1513                         ? $order->customer->taxincluded_checked
1514                         : $::myconfig{taxincluded_checked});
1515   }
1516
1517 }
1518
1519 # setup custom shipto from form
1520 #
1521 # The dialog returns form variables starting with 'shipto' and cvars starting
1522 # with 'shiptocvar_'.
1523 # Mark it to be deleted if a shipto from master data is selected
1524 # (i.e. order has a shipto).
1525 # Else, update or create a new custom shipto. If the fields are empty, it
1526 # will not be saved on save.
1527 sub setup_custom_shipto_from_form {
1528   my ($self, $order, $form) = @_;
1529
1530   if ($order->shipto) {
1531     $self->is_custom_shipto_to_delete(1);
1532   } else {
1533     my $custom_shipto = $order->custom_shipto || $order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => []));
1534
1535     my $shipto_cvars  = {map { my ($key) = m{^shiptocvar_(.+)}; $key => delete $form->{$_}} grep { m{^shiptocvar_} } keys %$form};
1536     my $shipto_attrs  = {map {                                  $_   => delete $form->{$_}} grep { m{^shipto}      } keys %$form};
1537
1538     $custom_shipto->assign_attributes(%$shipto_attrs);
1539     $custom_shipto->cvar_by_name($_)->value($shipto_cvars->{$_}) for keys %$shipto_cvars;
1540   }
1541 }
1542
1543 # recalculate prices and taxes
1544 #
1545 # Using the PriceTaxCalculator. Store linetotals in the item objects.
1546 sub recalc {
1547   my ($self) = @_;
1548
1549   my %pat = $self->order->calculate_prices_and_taxes();
1550
1551   $self->{taxes} = [];
1552   foreach my $tax_id (keys %{ $pat{taxes_by_tax_id} }) {
1553     my $netamount = sum0 map { $pat{amounts}->{$_}->{amount} } grep { $pat{amounts}->{$_}->{tax_id} == $tax_id } keys %{ $pat{amounts} };
1554
1555     push(@{ $self->{taxes} }, { amount    => $pat{taxes_by_tax_id}->{$tax_id},
1556                                 netamount => $netamount,
1557                                 tax       => SL::DB::Tax->new(id => $tax_id)->load });
1558   }
1559   pairwise { $a->{linetotal} = $b->{linetotal} } @{$self->order->items_sorted}, @{$pat{items}};
1560 }
1561
1562 # get data for saving, printing, ..., that is not changed in the form
1563 #
1564 # Only cvars for now.
1565 sub get_unalterable_data {
1566   my ($self) = @_;
1567
1568   foreach my $item (@{ $self->order->items }) {
1569     # autovivify all cvars that are not in the form (cvars_by_config can do it).
1570     # workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
1571     foreach my $var (@{ $item->cvars_by_config }) {
1572       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
1573     }
1574     $item->parse_custom_variable_values;
1575   }
1576 }
1577
1578 # delete the order
1579 #
1580 # And remove related files in the spool directory
1581 sub delete {
1582   my ($self) = @_;
1583
1584   my $errors = [];
1585   my $db     = $self->order->db;
1586
1587   $db->with_transaction(
1588     sub {
1589       my @spoolfiles = grep { $_ } map { $_->spoolfile } @{ SL::DB::Manager::Status->get_all(where => [ trans_id => $self->order->id ]) };
1590       $self->order->delete;
1591       my $spool = $::lx_office_conf{paths}->{spool};
1592       unlink map { "$spool/$_" } @spoolfiles if $spool;
1593
1594       $self->save_history('DELETED');
1595
1596       1;
1597   }) || push(@{$errors}, $db->error);
1598
1599   return $errors;
1600 }
1601
1602 # save the order
1603 #
1604 # And delete items that are deleted in the form.
1605 sub save {
1606   my ($self) = @_;
1607
1608   my $errors = [];
1609   my $db     = $self->order->db;
1610
1611   $db->with_transaction(sub {
1612     # delete custom shipto if it is to be deleted or if it is empty
1613     if ($self->order->custom_shipto && ($self->is_custom_shipto_to_delete || $self->order->custom_shipto->is_empty)) {
1614       $self->order->custom_shipto->delete if $self->order->custom_shipto->shipto_id;
1615       $self->order->custom_shipto(undef);
1616     }
1617
1618     SL::DB::OrderItem->new(id => $_)->delete for @{$self->item_ids_to_delete || []};
1619     $self->order->save(cascade => 1);
1620
1621     # link records
1622     if ($::form->{converted_from_oe_id}) {
1623       my @converted_from_oe_ids = split ' ', $::form->{converted_from_oe_id};
1624       foreach my $converted_from_oe_id (@converted_from_oe_ids) {
1625         my $src = SL::DB::Order->new(id => $converted_from_oe_id)->load;
1626         $src->update_attributes(closed => 1) if $src->type =~ /_quotation$/;
1627         $src->link_to_record($self->order);
1628       }
1629       if (scalar @{ $::form->{converted_from_orderitems_ids} || [] }) {
1630         my $idx = 0;
1631         foreach (@{ $self->order->items_sorted }) {
1632           my $from_id = $::form->{converted_from_orderitems_ids}->[$idx];
1633           next if !$from_id;
1634           SL::DB::RecordLink->new(from_table => 'orderitems',
1635                                   from_id    => $from_id,
1636                                   to_table   => 'orderitems',
1637                                   to_id      => $_->id
1638           )->save;
1639           $idx++;
1640         }
1641       }
1642     }
1643
1644     $self->save_history('SAVED');
1645
1646     1;
1647   }) || push(@{$errors}, $db->error);
1648
1649   return $errors;
1650 }
1651
1652 sub workflow_sales_or_request_for_quotation {
1653   my ($self) = @_;
1654
1655   # always save
1656   my $errors = $self->save();
1657
1658   if (scalar @{ $errors }) {
1659     $self->js->flash('error', $_) for @{ $errors };
1660     return $self->js->render();
1661   }
1662
1663   my $destination_type = $::form->{type} eq sales_order_type() ? sales_quotation_type() : request_quotation_type();
1664
1665   $self->order(SL::DB::Order->new_from($self->order, destination_type => $destination_type));
1666   $self->{converted_from_oe_id} = delete $::form->{id};
1667
1668   # set item ids to new fake id, to identify them as new items
1669   foreach my $item (@{$self->order->items_sorted}) {
1670     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1671   }
1672
1673   # change form type
1674   $::form->{type} = $destination_type;
1675   $self->type($self->init_type);
1676   $self->cv  ($self->init_cv);
1677   $self->check_auth;
1678
1679   $self->recalc();
1680   $self->get_unalterable_data();
1681   $self->pre_render();
1682
1683   # trigger rendering values for second row as hidden, because they
1684   # are loaded only on demand. So we need to keep the values from the
1685   # source.
1686   $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
1687
1688   $self->render(
1689     'order/form',
1690     title => $self->get_title_for('edit'),
1691     %{$self->{template_args}}
1692   );
1693 }
1694
1695 sub workflow_sales_or_purchase_order {
1696   my ($self) = @_;
1697
1698   # always save
1699   my $errors = $self->save();
1700
1701   if (scalar @{ $errors }) {
1702     $self->js->flash('error', $_) foreach @{ $errors };
1703     return $self->js->render();
1704   }
1705
1706   my $destination_type = $::form->{type} eq sales_quotation_type()   ? sales_order_type()
1707                        : $::form->{type} eq request_quotation_type() ? purchase_order_type()
1708                        : $::form->{type} eq purchase_order_type()    ? sales_order_type()
1709                        : $::form->{type} eq sales_order_type()       ? purchase_order_type()
1710                        : '';
1711
1712   # check for direct delivery
1713   # copy shipto in custom shipto (custom shipto will be copied by new_from() in case)
1714   my $custom_shipto;
1715   if (   $::form->{type} eq sales_order_type() && $destination_type eq purchase_order_type()
1716       && $::form->{use_shipto} && $self->order->shipto) {
1717     $custom_shipto = $self->order->shipto->clone('SL::DB::Order');
1718   }
1719
1720   $self->order(SL::DB::Order->new_from($self->order, destination_type => $destination_type));
1721   $self->{converted_from_oe_id} = delete $::form->{id};
1722
1723   # set item ids to new fake id, to identify them as new items
1724   foreach my $item (@{$self->order->items_sorted}) {
1725     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1726   }
1727
1728   if ($::form->{type} eq sales_order_type() && $destination_type eq purchase_order_type()) {
1729     if ($::form->{use_shipto}) {
1730       $self->order->custom_shipto($custom_shipto) if $custom_shipto;
1731     } else {
1732       # remove any custom shipto if not wanted
1733       $self->order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => []));
1734     }
1735   }
1736
1737   # change form type
1738   $::form->{type} = $destination_type;
1739   $self->type($self->init_type);
1740   $self->cv  ($self->init_cv);
1741   $self->check_auth;
1742
1743   $self->recalc();
1744   $self->get_unalterable_data();
1745   $self->pre_render();
1746
1747   # trigger rendering values for second row as hidden, because they
1748   # are loaded only on demand. So we need to keep the values from the
1749   # source.
1750   $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
1751
1752   $self->render(
1753     'order/form',
1754     title => $self->get_title_for('edit'),
1755     %{$self->{template_args}}
1756   );
1757 }
1758
1759
1760 sub pre_render {
1761   my ($self) = @_;
1762
1763   $self->{all_taxzones}               = SL::DB::Manager::TaxZone->get_all_sorted();
1764   $self->{all_currencies}             = SL::DB::Manager::Currency->get_all_sorted();
1765   $self->{all_departments}            = SL::DB::Manager::Department->get_all_sorted();
1766   $self->{all_languages}              = SL::DB::Manager::Language->get_all_sorted();
1767   $self->{all_employees}              = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->employee_id,
1768                                                                                               deleted => 0 ] ],
1769                                                                            sort_by => 'name');
1770   $self->{all_salesmen}               = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->salesman_id,
1771                                                                                               deleted => 0 ] ],
1772                                                                            sort_by => 'name');
1773   $self->{all_payment_terms}          = SL::DB::Manager::PaymentTerm->get_all_sorted(where => [ or => [ id => $self->order->payment_id,
1774                                                                                                         obsolete => 0 ] ]);
1775   $self->{all_delivery_terms}         = SL::DB::Manager::DeliveryTerm->get_all_sorted();
1776   $self->{current_employee_id}        = SL::DB::Manager::Employee->current->id;
1777   $self->{periodic_invoices_status}   = $self->get_periodic_invoices_status($self->order->periodic_invoices_config);
1778   $self->{order_probabilities}        = [ map { { title => ($_ * 10) . '%', id => $_ * 10 } } (0..10) ];
1779   $self->{positions_scrollbar_height} = SL::Helper::UserPreferences::PositionsScrollbar->new()->get_height();
1780
1781   my $print_form = Form->new('');
1782   $print_form->{type}        = $self->type;
1783   $print_form->{printers}    = SL::DB::Manager::Printer->get_all_sorted;
1784   $self->{print_options}     = SL::Helper::PrintOptions->get_print_options(
1785     form => $print_form,
1786     options => {dialog_name_prefix => 'print_options.',
1787                 show_headers       => 1,
1788                 no_queue           => 1,
1789                 no_postscript      => 1,
1790                 no_opendocument    => 0,
1791                 no_html            => 1},
1792   );
1793
1794   foreach my $item (@{$self->order->orderitems}) {
1795     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
1796     $item->active_price_source(   $price_source->price_from_source(   $item->active_price_source   ));
1797     $item->active_discount_source($price_source->discount_from_source($item->active_discount_source));
1798   }
1799
1800   if (any { $self->type eq $_ } (sales_order_type(), purchase_order_type())) {
1801     # Calculate shipped qtys here to prevent calling calculate for every item via the items method.
1802     # Do not use write_to_objects to prevent order->delivered to be set, because this should be
1803     # the value from db, which can be set manually or is set when linked delivery orders are saved.
1804     SL::Helper::ShippedQty->new->calculate($self->order)->write_to(\@{$self->order->items});
1805   }
1806
1807   if ($self->order->number && $::instance_conf->get_webdav) {
1808     my $webdav = SL::Webdav->new(
1809       type     => $self->type,
1810       number   => $self->order->number,
1811     );
1812     my @all_objects = $webdav->get_all_objects;
1813     @{ $self->{template_args}->{WEBDAV} } = map { { name => $_->filename,
1814                                                     type => t8('File'),
1815                                                     link => File::Spec->catfile($_->full_filedescriptor),
1816                                                 } } @all_objects;
1817   }
1818
1819   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
1820
1821   $::request->{layout}->use_javascript("${_}.js") for qw(kivi.SalesPurchase kivi.Order kivi.File ckeditor/ckeditor ckeditor/adapters/jquery
1822                                                          edit_periodic_invoices_config calculate_qty kivi.Validator follow_up show_history);
1823   $self->setup_edit_action_bar;
1824 }
1825
1826 sub setup_edit_action_bar {
1827   my ($self, %params) = @_;
1828
1829   my $deletion_allowed = (any { $self->type eq $_ } (sales_quotation_type(), request_quotation_type()))
1830                       || (($self->type eq sales_order_type())    && $::instance_conf->get_sales_order_show_delete)
1831                       || (($self->type eq purchase_order_type()) && $::instance_conf->get_purchase_order_show_delete);
1832
1833   for my $bar ($::request->layout->get('actionbar')) {
1834     $bar->add(
1835       combobox => [
1836         action => [
1837           t8('Save'),
1838           call      => [ 'kivi.Order.save', 'save', $::instance_conf->get_order_warn_duplicate_parts,
1839                                                     $::instance_conf->get_order_warn_no_deliverydate,
1840                                                                                                       ],
1841           checks    => [ 'kivi.Order.check_save_active_periodic_invoices', ['kivi.validate_form','#order_form'] ],
1842         ],
1843         action => [
1844           t8('Save as new'),
1845           call      => [ 'kivi.Order.save', 'save_as_new', $::instance_conf->get_order_warn_duplicate_parts ],
1846           checks    => [ 'kivi.Order.check_save_active_periodic_invoices' ],
1847           disabled  => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1848         ],
1849       ], # end of combobox "Save"
1850
1851       combobox => [
1852         action => [
1853           t8('Workflow'),
1854         ],
1855         action => [
1856           t8('Save and Quotation'),
1857           submit   => [ '#order_form', { action => "Order/sales_quotation" } ],
1858           only_if  => (any { $self->type eq $_ } (sales_order_type())),
1859         ],
1860         action => [
1861           t8('Save and RFQ'),
1862           submit   => [ '#order_form', { action => "Order/request_for_quotation" } ],
1863           only_if  => (any { $self->type eq $_ } (purchase_order_type())),
1864         ],
1865         action => [
1866           t8('Save and Sales Order'),
1867           submit   => [ '#order_form', { action => "Order/sales_order" } ],
1868           only_if  => (any { $self->type eq $_ } (sales_quotation_type(), purchase_order_type())),
1869         ],
1870         action => [
1871           t8('Save and Purchase Order'),
1872           call      => [ 'kivi.Order.purchase_order_check_for_direct_delivery' ],
1873           only_if   => (any { $self->type eq $_ } (sales_order_type(), request_quotation_type())),
1874         ],
1875         action => [
1876           t8('Save and Delivery Order'),
1877           call      => [ 'kivi.Order.save', 'save_and_delivery_order', $::instance_conf->get_order_warn_duplicate_parts,
1878                                                                        $::instance_conf->get_order_warn_no_deliverydate,
1879                                                                                                                         ],
1880           checks    => [ 'kivi.Order.check_save_active_periodic_invoices' ],
1881           only_if   => (any { $self->type eq $_ } (sales_order_type(), purchase_order_type()))
1882         ],
1883         action => [
1884           t8('Save and Invoice'),
1885           call      => [ 'kivi.Order.save', 'save_and_invoice', $::instance_conf->get_order_warn_duplicate_parts ],
1886           checks    => [ 'kivi.Order.check_save_active_periodic_invoices' ],
1887         ],
1888         action => [
1889           t8('Save and AP Transaction'),
1890           call      => [ 'kivi.Order.save', 'save_and_ap_transaction', $::instance_conf->get_order_warn_duplicate_parts ],
1891           only_if   => (any { $self->type eq $_ } (purchase_order_type()))
1892         ],
1893
1894       ], # end of combobox "Workflow"
1895
1896       combobox => [
1897         action => [
1898           t8('Export'),
1899         ],
1900         action => [
1901           t8('Save and preview PDF'),
1902            call => [ 'kivi.Order.save', 'preview_pdf', $::instance_conf->get_order_warn_duplicate_parts,
1903                                                        $::instance_conf->get_order_warn_no_deliverydate,
1904                                                                                                          ],
1905         ],
1906         action => [
1907           t8('Save and print'),
1908           call => [ 'kivi.Order.show_print_options', $::instance_conf->get_order_warn_duplicate_parts,
1909                                                      $::instance_conf->get_order_warn_no_deliverydate,
1910                                                                                                       ],
1911         ],
1912         action => [
1913           t8('Save and E-mail'),
1914           id   => 'save_and_email_action',
1915           call => [ 'kivi.Order.save', 'save_and_show_email_dialog', $::instance_conf->get_order_warn_duplicate_parts,
1916                                                                      $::instance_conf->get_order_warn_no_deliverydate,
1917                   ],
1918           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1919         ],
1920         action => [
1921           t8('Download attachments of all parts'),
1922           call     => [ 'kivi.File.downloadOrderitemsFiles', $::form->{type}, $::form->{id} ],
1923           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1924           only_if  => $::instance_conf->get_doc_storage,
1925         ],
1926       ], # end of combobox "Export"
1927
1928       action => [
1929         t8('Delete'),
1930         call     => [ 'kivi.Order.delete_order' ],
1931         confirm  => $::locale->text('Do you really want to delete this object?'),
1932         disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1933         only_if  => $deletion_allowed,
1934       ],
1935
1936       combobox => [
1937         action => [
1938           t8('more')
1939         ],
1940         action => [
1941           t8('Follow-Up'),
1942           call     => [ 'kivi.Order.follow_up_window' ],
1943           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1944           only_if  => $::auth->assert('productivity', 1),
1945         ],
1946         action => [
1947           t8('History'),
1948           call     => [ 'set_history_window', $self->order->id, 'id' ],
1949           disabled => !$self->order->id ? t8('This record has not been saved yet.') : undef,
1950         ],
1951       ], # end of combobox "more"
1952     );
1953   }
1954 }
1955
1956 sub generate_pdf {
1957   my ($order, $pdf_ref, $params) = @_;
1958
1959   my @errors = ();
1960
1961   my $print_form = Form->new('');
1962   $print_form->{type}        = $order->type;
1963   $print_form->{formname}    = $params->{formname} || $order->type;
1964   $print_form->{format}      = $params->{format}   || 'pdf';
1965   $print_form->{media}       = $params->{media}    || 'file';
1966   $print_form->{groupitems}  = $params->{groupitems};
1967   $print_form->{printer_id}  = $params->{printer_id};
1968   $print_form->{media}       = 'file'                             if $print_form->{media} eq 'screen';
1969
1970   $order->language($params->{language});
1971   $order->flatten_to_form($print_form, format_amounts => 1);
1972
1973   my $template_ext;
1974   my $template_type;
1975   if ($print_form->{format} =~ /(opendocument|oasis)/i) {
1976     $template_ext  = 'odt';
1977     $template_type = 'OpenDocument';
1978   }
1979
1980   # search for the template
1981   my ($template_file, @template_files) = SL::Helper::CreatePDF->find_template(
1982     name        => $print_form->{formname},
1983     extension   => $template_ext,
1984     email       => $print_form->{media} eq 'email',
1985     language    => $params->{language},
1986     printer_id  => $print_form->{printer_id},
1987   );
1988
1989   if (!defined $template_file) {
1990     push @errors, $::locale->text('Cannot find matching template for this print request. Please contact your template maintainer. I tried these: #1.', join ', ', map { "'$_'"} @template_files);
1991   }
1992
1993   return @errors if scalar @errors;
1994
1995   $print_form->throw_on_error(sub {
1996     eval {
1997       $print_form->prepare_for_printing;
1998
1999       $$pdf_ref = SL::Helper::CreatePDF->create_pdf(
2000         format        => $print_form->{format},
2001         template_type => $template_type,
2002         template      => $template_file,
2003         variables     => $print_form,
2004         variable_content_types => {
2005           longdescription => 'html',
2006           partnotes       => 'html',
2007           notes           => 'html',
2008         },
2009       );
2010       1;
2011     } || push @errors, ref($EVAL_ERROR) eq 'SL::X::FormError' ? $EVAL_ERROR->error : $EVAL_ERROR;
2012   });
2013
2014   return @errors;
2015 }
2016
2017 sub get_files_for_email_dialog {
2018   my ($self) = @_;
2019
2020   my %files = map { ($_ => []) } qw(versions files vc_files part_files);
2021
2022   return %files if !$::instance_conf->get_doc_storage;
2023
2024   if ($self->order->id) {
2025     $files{versions} = [ SL::File->get_all_versions(object_id => $self->order->id,              object_type => $self->order->type, file_type => 'document') ];
2026     $files{files}    = [ SL::File->get_all(         object_id => $self->order->id,              object_type => $self->order->type, file_type => 'attachment') ];
2027     $files{vc_files} = [ SL::File->get_all(         object_id => $self->order->{$self->cv}->id, object_type => $self->cv,          file_type => 'attachment') ];
2028     $files{project_files} = [ SL::File->get_all(    object_id => $self->order->globalproject_id, object_type => 'project',         file_type => 'attachment') ];
2029   }
2030
2031   my @parts =
2032     uniq_by { $_->{id} }
2033     map {
2034       +{ id         => $_->part->id,
2035          partnumber => $_->part->partnumber }
2036     } @{$self->order->items_sorted};
2037
2038   foreach my $part (@parts) {
2039     my @pfiles = SL::File->get_all(object_id => $part->{id}, object_type => 'part');
2040     push @{ $files{part_files} }, map { +{ %{ $_ }, partnumber => $part->{partnumber} } } @pfiles;
2041   }
2042
2043   foreach my $key (keys %files) {
2044     $files{$key} = [ sort_by { lc $_->{db_file}->{file_name} } @{ $files{$key} } ];
2045   }
2046
2047   return %files;
2048 }
2049
2050 sub make_periodic_invoices_config_from_yaml {
2051   my ($yaml_config) = @_;
2052
2053   return if !$yaml_config;
2054   my $attr = SL::YAML::Load($yaml_config);
2055   return if 'HASH' ne ref $attr;
2056   return SL::DB::PeriodicInvoicesConfig->new(%$attr);
2057 }
2058
2059
2060 sub get_periodic_invoices_status {
2061   my ($self, $config) = @_;
2062
2063   return                      if $self->type ne sales_order_type();
2064   return t8('not configured') if !$config;
2065
2066   my $active = ('HASH' eq ref $config)                           ? $config->{active}
2067              : ('SL::DB::PeriodicInvoicesConfig' eq ref $config) ? $config->active
2068              :                                                     die "Cannot get status of periodic invoices config";
2069
2070   return $active ? t8('active') : t8('inactive');
2071 }
2072
2073 sub get_title_for {
2074   my ($self, $action) = @_;
2075
2076   return '' if none { lc($action)} qw(add edit);
2077
2078   # for locales:
2079   # $::locale->text("Add Sales Order");
2080   # $::locale->text("Add Purchase Order");
2081   # $::locale->text("Add Quotation");
2082   # $::locale->text("Add Request for Quotation");
2083   # $::locale->text("Edit Sales Order");
2084   # $::locale->text("Edit Purchase Order");
2085   # $::locale->text("Edit Quotation");
2086   # $::locale->text("Edit Request for Quotation");
2087
2088   $action = ucfirst(lc($action));
2089   return $self->type eq sales_order_type()       ? $::locale->text("$action Sales Order")
2090        : $self->type eq purchase_order_type()    ? $::locale->text("$action Purchase Order")
2091        : $self->type eq sales_quotation_type()   ? $::locale->text("$action Quotation")
2092        : $self->type eq request_quotation_type() ? $::locale->text("$action Request for Quotation")
2093        : '';
2094 }
2095
2096 sub get_item_cvpartnumber {
2097   my ($self, $item) = @_;
2098
2099   return if !$self->search_cvpartnumber;
2100   return if !$self->order->customervendor;
2101
2102   if ($self->cv eq 'vendor') {
2103     my @mms = grep { $_->make eq $self->order->customervendor->id } @{$item->part->makemodels};
2104     $item->{cvpartnumber} = $mms[0]->model if scalar @mms;
2105   } elsif ($self->cv eq 'customer') {
2106     my @cps = grep { $_->customer_id eq $self->order->customervendor->id } @{$item->part->customerprices};
2107     $item->{cvpartnumber} = $cps[0]->customer_partnumber if scalar @cps;
2108   }
2109 }
2110
2111 sub get_part_texts {
2112   my ($part_or_id, $language_or_id, %defaults) = @_;
2113
2114   my $part        = ref($part_or_id)     ? $part_or_id         : SL::DB::Part->load_cached($part_or_id);
2115   my $language_id = ref($language_or_id) ? $language_or_id->id : $language_or_id;
2116   my $texts       = {
2117     description     => $defaults{description}     // $part->description,
2118     longdescription => $defaults{longdescription} // $part->notes,
2119   };
2120
2121   return $texts unless $language_id;
2122
2123   my $translation = SL::DB::Manager::Translation->get_first(
2124     where => [
2125       parts_id    => $part->id,
2126       language_id => $language_id,
2127     ]);
2128
2129   $texts->{description}     = $translation->translation     if $translation && $translation->translation;
2130   $texts->{longdescription} = $translation->longdescription if $translation && $translation->longdescription;
2131
2132   return $texts;
2133 }
2134
2135 sub sales_order_type {
2136   'sales_order';
2137 }
2138
2139 sub purchase_order_type {
2140   'purchase_order';
2141 }
2142
2143 sub sales_quotation_type {
2144   'sales_quotation';
2145 }
2146
2147 sub request_quotation_type {
2148   'request_quotation';
2149 }
2150
2151 sub nr_key {
2152   return $_[0]->type eq sales_order_type()       ? 'ordnumber'
2153        : $_[0]->type eq purchase_order_type()    ? 'ordnumber'
2154        : $_[0]->type eq sales_quotation_type()   ? 'quonumber'
2155        : $_[0]->type eq request_quotation_type() ? 'quonumber'
2156        : '';
2157 }
2158
2159 sub save_and_redirect_to {
2160   my ($self, %params) = @_;
2161
2162   my $errors = $self->save();
2163
2164   if (scalar @{ $errors }) {
2165     $self->js->flash('error', $_) foreach @{ $errors };
2166     return $self->js->render();
2167   }
2168
2169   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
2170            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
2171            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
2172            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
2173            : '';
2174   flash_later('info', $text);
2175
2176   $self->redirect_to(%params, id => $self->order->id);
2177 }
2178
2179 sub save_history {
2180   my ($self, $addition) = @_;
2181
2182   my $number_type = $self->order->type =~ m{order} ? 'ordnumber' : 'quonumber';
2183   my $snumbers    = $number_type . '_' . $self->order->$number_type;
2184
2185   SL::DB::History->new(
2186     trans_id    => $self->order->id,
2187     employee_id => SL::DB::Manager::Employee->current->id,
2188     what_done   => $self->order->type,
2189     snumbers    => $snumbers,
2190     addition    => $addition,
2191   )->save;
2192 }
2193
2194 sub store_pdf_to_webdav_and_filemanagement {
2195   my($order, $content, $filename) = @_;
2196
2197   my @errors;
2198
2199   # copy file to webdav folder
2200   if ($order->number && $::instance_conf->get_webdav_documents) {
2201     my $webdav = SL::Webdav->new(
2202       type     => $order->type,
2203       number   => $order->number,
2204     );
2205     my $webdav_file = SL::Webdav::File->new(
2206       webdav   => $webdav,
2207       filename => $filename,
2208     );
2209     eval {
2210       $webdav_file->store(data => \$content);
2211       1;
2212     } or do {
2213       push @errors, t8('Storing PDF to webdav folder failed: #1', $@);
2214     };
2215   }
2216   if ($order->id && $::instance_conf->get_doc_storage) {
2217     eval {
2218       SL::File->save(object_id     => $order->id,
2219                      object_type   => $order->type,
2220                      mime_type     => 'application/pdf',
2221                      source        => 'created',
2222                      file_type     => 'document',
2223                      file_name     => $filename,
2224                      file_contents => $content);
2225       1;
2226     } or do {
2227       push @errors, t8('Storing PDF in storage backend failed: #1', $@);
2228     };
2229   }
2230
2231   return @errors;
2232 }
2233
2234 1;
2235
2236 __END__
2237
2238 =encoding utf-8
2239
2240 =head1 NAME
2241
2242 SL::Controller::Order - controller for orders
2243
2244 =head1 SYNOPSIS
2245
2246 This is a new form to enter orders, completely rewritten with the use
2247 of controller and java script techniques.
2248
2249 The aim is to provide the user a better experience and a faster workflow. Also
2250 the code should be more readable, more reliable and better to maintain.
2251
2252 =head2 Key Features
2253
2254 =over 4
2255
2256 =item *
2257
2258 One input row, so that input happens every time at the same place.
2259
2260 =item *
2261
2262 Use of pickers where possible.
2263
2264 =item *
2265
2266 Possibility to enter more than one item at once.
2267
2268 =item *
2269
2270 Item list in a scrollable area, so that the workflow buttons stay at
2271 the bottom.
2272
2273 =item *
2274
2275 Reordering item rows with drag and drop is possible. Sorting item rows is
2276 possible (by partnumber, description, qty, sellprice and discount for now).
2277
2278 =item *
2279
2280 No C<update> is necessary. All entries and calculations are managed
2281 with ajax-calls and the page only reloads on C<save>.
2282
2283 =item *
2284
2285 User can see changes immediately, because of the use of java script
2286 and ajax.
2287
2288 =back
2289
2290 =head1 CODE
2291
2292 =head2 Layout
2293
2294 =over 4
2295
2296 =item * C<SL/Controller/Order.pm>
2297
2298 the controller
2299
2300 =item * C<template/webpages/order/form.html>
2301
2302 main form
2303
2304 =item * C<template/webpages/order/tabs/basic_data.html>
2305
2306 Main tab for basic_data.
2307
2308 This is the only tab here for now. "linked records" and "webdav" tabs are
2309 reused from generic code.
2310
2311 =over 4
2312
2313 =item * C<template/webpages/order/tabs/_business_info_row.html>
2314
2315 For displaying information on business type
2316
2317 =item * C<template/webpages/order/tabs/_item_input.html>
2318
2319 The input line for items
2320
2321 =item * C<template/webpages/order/tabs/_row.html>
2322
2323 One row for already entered items
2324
2325 =item * C<template/webpages/order/tabs/_tax_row.html>
2326
2327 Displaying tax information
2328
2329 =item * C<template/webpages/order/tabs/_price_sources_dialog.html>
2330
2331 Dialog for selecting price and discount sources
2332
2333 =back
2334
2335 =item * C<js/kivi.Order.js>
2336
2337 java script functions
2338
2339 =back
2340
2341 =head1 TODO
2342
2343 =over 4
2344
2345 =item * testing
2346
2347 =item * price sources: little symbols showing better price / better discount
2348
2349 =item * select units in input row?
2350
2351 =item * check for direct delivery (workflow sales order -> purchase order)
2352
2353 =item * access rights
2354
2355 =item * display weights
2356
2357 =item * mtime check
2358
2359 =item * optional client/user behaviour
2360
2361 (transactions has to be set - department has to be set -
2362  force project if enabled in client config - transport cost reminder)
2363
2364 =back
2365
2366 =head1 KNOWN BUGS AND CAVEATS
2367
2368 =over 4
2369
2370 =item *
2371
2372 Customer discount is not displayed as a valid discount in price source popup
2373 (this might be a bug in price sources)
2374
2375 (I cannot reproduce this (Bernd))
2376
2377 =item *
2378
2379 No indication that <shift>-up/down expands/collapses second row.
2380
2381 =item *
2382
2383 Inline creation of parts is not currently supported
2384
2385 =item *
2386
2387 Table header is not sticky in the scrolling area.
2388
2389 =item *
2390
2391 Sorting does not include C<position>, neither does reordering.
2392
2393 This behavior was implemented intentionally. But we can discuss, which behavior
2394 should be implemented.
2395
2396 =back
2397
2398 =head1 To discuss / Nice to have
2399
2400 =over 4
2401
2402 =item *
2403
2404 How to expand/collapse second row. Now it can be done clicking the icon or
2405 <shift>-up/down.
2406
2407 =item *
2408
2409 Possibility to select PriceSources in input row?
2410
2411 =item *
2412
2413 This controller uses a (changed) copy of the template for the PriceSource
2414 dialog. Maybe there could be used one code source.
2415
2416 =item *
2417
2418 Rounding-differences between this controller (PriceTaxCalculator) and the old
2419 form. This is not only a problem here, but also in all parts using the PTC.
2420 There exists a ticket and a patch. This patch should be testet.
2421
2422 =item *
2423
2424 An indicator, if the actual inputs are saved (like in an
2425 editor or on text processing application).
2426
2427 =item *
2428
2429 A warning when leaving the page without saveing unchanged inputs.
2430
2431
2432 =back
2433
2434 =head1 AUTHOR
2435
2436 Bernd Bleßmann E<lt>bernd@kivitendo-premium.deE<gt>
2437
2438 =cut