SL/Controller/Order.pm

   1 package SL::Controller::Order;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use SL::Helper::Flash;
   7 use SL::Presenter;
   8 use SL::PriceSource;
   9
  10 use SL::DB::Order;
  11 use SL::DB::Customer;
  12 use SL::DB::Vendor;
  13 use SL::DB::TaxZone;
  14 use SL::DB::Employee;
  15 use SL::DB::Project;
  16 use SL::DB::Default;
  17 use SL::DB::Unit;
  18
  19 use SL::Helper::DateTime;
  20
  21 use List::Util qw(max first);
  22 use List::MoreUtils qw(none pairwise);
  23
  24 use Rose::Object::MakeMethods::Generic
  25 (
  26  'scalar --get_set_init' => [ qw(order valid_types type cv p) ],
  27 );
  28
  29
  30 # safety
  31 __PACKAGE__->run_before('_check_auth');
  32
  33 __PACKAGE__->run_before('_recalc',
  34                         only => [ qw(edit update save) ]);
  35
  36 __PACKAGE__->run_before('_get_unalterable_data',
  37                         only => [ qw(save save_and_delivery_order create_pdf send_email) ]);
  38
  39 #
  40 # actions
  41 #
  42
  43 sub action_add {
  44   my ($self) = @_;
  45
  46   $self->order->transdate(DateTime->now_local());
  47
  48   $self->_pre_render();
  49   $self->render(
  50     'order/form',
  51     title => $self->type eq _sales_order_type()    ? $::locale->text('Add Sales Order')
  52            : $self->type eq _purchase_order_type() ? $::locale->text('Add Purchase Order')
  53            : '',
  54     %{$self->{template_args}}
  55   );
  56 }
  57
  58 sub action_edit {
  59   my ($self) = @_;
  60
  61   $self->_pre_render();
  62   $self->render(
  63     'order/form',
  64     title => $self->type eq _sales_order_type()    ? $::locale->text('Edit Sales Order')
  65            : $self->type eq _purchase_order_type() ? $::locale->text('Edit Purchase Order')
  66            : '',
  67     %{$self->{template_args}}
  68   );
  69 }
  70
  71 sub action_update {
  72   my ($self) = @_;
  73
  74   $self->_pre_render();
  75   $self->render(
  76     'order/form',
  77     title => $self->type eq _sales_order_type()    ? $::locale->text('Edit Sales Order')
  78            : $self->type eq _purchase_order_type() ? $::locale->text('Edit Purchase Order')
  79            : '',
  80     %{$self->{template_args}}
  81   );
  82 }
  83
  84 sub action_delete {
  85   my ($self) = @_;
  86
  87   my $errors = $self->_delete();
  88
  89   if (scalar @{ $errors }) {
  90     $self->js->flash('error', $_) foreach @{ $errors };
  91     return $self->js->render();
  92   }
  93
  94   flash_later('info', $::locale->text('The order has been deleted'));
  95   my @redirect_params = (
  96     action => 'edit',
  97     type   => $self->type,
  98   );
  99
 100   $self->redirect_to(@redirect_params);
 101 }
 102
 103 sub action_save {
 104   my ($self) = @_;
 105
 106   my $errors = $self->_save();
 107
 108   if (scalar @{ $errors }) {
 109     $self->js->flash('error', $_) foreach @{ $errors };
 110     return $self->js->render();
 111   }
 112
 113   flash_later('info', $::locale->text('The order has been saved'));
 114   my @redirect_params = (
 115     action => 'edit',
 116     type   => $self->type,
 117     id     => $self->order->id,
 118   );
 119
 120   $self->redirect_to(@redirect_params);
 121 }
 122
 123 sub action_customer_vendor_changed {
 124   my ($self) = @_;
 125
 126   my $cv_method = $self->cv;
 127
 128   if ($self->order->$cv_method->contacts && scalar @{ $self->order->$cv_method->contacts } > 0) {
 129     $self->js->show('#cp_row');
 130   } else {
 131     $self->js->hide('#cp_row');
 132   }
 133
 134   if ($self->order->$cv_method->shipto && scalar @{ $self->order->$cv_method->shipto } > 0) {
 135     $self->js->show('#shipto_row');
 136   } else {
 137     $self->js->hide('#shipto_row');
 138   }
 139
 140   $self->order->taxzone_id($self->order->$cv_method->taxzone_id);
 141
 142   if ($self->order->is_sales) {
 143     $self->order->taxincluded(defined($self->order->$cv_method->taxincluded_checked)
 144                               ? $self->order->$cv_method->taxincluded_checked
 145                               : $::myconfig{taxincluded_checked});
 146   }
 147
 148   $self->order->payment_id($self->order->$cv_method->payment_id);
 149   $self->order->delivery_term_id($self->order->$cv_method->delivery_term_id);
 150
 151   $self->_recalc();
 152
 153   $self->js
 154     ->replaceWith('#order_cp_id',            $self->build_contact_select)
 155     ->replaceWith('#order_shipto_id',        $self->build_shipto_select)
 156     ->val(        '#order_taxzone_id',       $self->order->taxzone_id)
 157     ->val(        '#order_taxincluded',      $self->order->taxincluded)
 158     ->val(        '#order_payment_id',       $self->order->payment_id)
 159     ->val(        '#order_delivery_term_id', $self->order->delivery_term_id)
 160     ->val(        '#order_intnotes',         $self->order->$cv_method->notes)
 161     ->focus(      '#order_' . $self->cv . '_id');
 162
 163   $self->_js_redisplay_amounts_and_taxes;
 164   $self->js->render();
 165 }
 166
 167 sub action_add_item {
 168   my ($self) = @_;
 169
 170   my $form_attr = $::form->{add_item};
 171
 172   return unless $form_attr->{parts_id};
 173
 174   my $item = SL::DB::OrderItem->new;
 175   $item->assign_attributes(%$form_attr);
 176
 177   my $part        = SL::DB::Part->new(id => $form_attr->{parts_id})->load;
 178   my $cv_method   = $self->cv;
 179   my $cv_discount = $self->order->$cv_method? $self->order->$cv_method->discount : 0.0;
 180
 181   my %new_attr;
 182   $new_attr{part}        = $part;
 183   $new_attr{description} = $part->description if ! $item->description;
 184   $new_attr{qty}         = 1.0                if ! $item->qty;
 185   $new_attr{unit}        = $part->unit;
 186   $new_attr{sellprice}   = $part->sellprice   if ! $item->sellprice;
 187   $new_attr{discount}    = $cv_discount       if ! $item->discount;
 188
 189   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
 190   # they cannot be retrieved via custom_variables until the order/orderitem is
 191   # saved. Adding empty custom_variables to new orderitem here solves this problem.
 192   $new_attr{custom_variables} = [];
 193
 194   $item->assign_attributes(%new_attr);
 195
 196   $self->order->add_items($item);
 197
 198   $self->_recalc();
 199
 200   my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 201   my $row_as_html = $self->p->render('order/tabs/_row', ITEM => $item, ID => $item_id);
 202
 203   $self->js
 204     ->append('#row_table_id', $row_as_html)
 205     ->val('.add_item_input', '')
 206     ->run('row_table_scroll_down')
 207     ->run('row_set_keyboard_events_by_id', $item_id)
 208     ->on('.recalc', 'change', 'recalc_amounts_and_taxes')
 209     ->focus('#add_item_parts_id_name');
 210
 211   $self->_js_redisplay_amounts_and_taxes;
 212   $self->js->render();
 213 }
 214
 215 sub action_recalc_amounts_and_taxes {
 216   my ($self) = @_;
 217
 218   $self->_recalc();
 219
 220   $self->_js_redisplay_linetotals;
 221   $self->_js_redisplay_amounts_and_taxes;
 222   $self->js->render();
 223 }
 224
 225 sub _js_redisplay_linetotals {
 226   my ($self) = @_;
 227
 228   my @data = map {$::form->format_amount(\%::myconfig, $_->{linetotal}, 2, 0)} @{ $self->order->items };
 229   $self->js
 230     ->run('redisplay_linetotals', \@data);
 231 }
 232
 233 sub _js_redisplay_amounts_and_taxes {
 234   my ($self) = @_;
 235
 236   if (scalar @{ $self->{taxes} }) {
 237     $self->js->show('#taxincluded_row_id');
 238   } else {
 239     $self->js->hide('#taxincluded_row_id');
 240   }
 241
 242   if ($self->order->taxincluded) {
 243     $self->js->hide('#subtotal_row_id');
 244   } else {
 245     $self->js->show('#subtotal_row_id');
 246   }
 247
 248   $self->js
 249     ->html('#netamount_id', $::form->format_amount(\%::myconfig, $self->order->netamount, -2))
 250     ->html('#amount_id',    $::form->format_amount(\%::myconfig, $self->order->amount,    -2))
 251     ->remove('.tax_row')
 252     ->insertBefore($self->build_tax_rows, '#amount_row_id');
 253 }
 254
 255 #
 256 # helpers
 257 #
 258
 259 sub init_valid_types {
 260   [ _sales_order_type(), _purchase_order_type() ];
 261 }
 262
 263 sub init_type {
 264   my ($self) = @_;
 265
 266   if (none { $::form->{type} eq $_ } @{$self->valid_types}) {
 267     die "Not a valid type for order";
 268   }
 269
 270   $self->type($::form->{type});
 271 }
 272
 273 sub init_cv {
 274   my ($self) = @_;
 275
 276   my $cv = $self->type eq _sales_order_type()    ? 'customer'
 277          : $self->type eq _purchase_order_type() ? 'vendor'
 278          : die "Not a valid type for order";
 279
 280   return $cv;
 281 }
 282
 283 sub init_p {
 284   SL::Presenter->get;
 285 }
 286
 287 sub init_order {
 288   _make_order();
 289 }
 290
 291 sub _check_auth {
 292   my ($self) = @_;
 293
 294   my $right_for = { map { $_ => $_.'_edit' } @{$self->valid_types} };
 295
 296   my $right   = $right_for->{ $self->type };
 297   $right    ||= 'DOES_NOT_EXIST';
 298
 299   $::auth->assert($right);
 300 }
 301
 302 sub build_contact_select {
 303   my ($self) = @_;
 304
 305   $self->p->select_tag('order.cp_id', [ $self->order->{$self->cv}->contacts ],
 306                        value_key  => 'cp_id',
 307                        title_key  => 'full_name_dep',
 308                        default    => $self->order->cp_id,
 309                        with_empty => 1,
 310                        style      => 'width: 300px',
 311   );
 312 }
 313
 314 sub build_shipto_select {
 315   my ($self) = @_;
 316
 317   $self->p->select_tag('order.shipto_id', [ $self->order->{$self->cv}->shipto ],
 318                        value_key  => 'shipto_id',
 319                        title_key  => 'displayable_id',
 320                        default    => $self->order->shipto_id,
 321                        with_empty => 1,
 322                        style      => 'width: 300px',
 323   );
 324 }
 325
 326 sub build_tax_rows {
 327   my ($self) = @_;
 328
 329   my $rows_as_html;
 330   foreach my $tax (sort { $a->{tax}->rate cmp $b->{tax}->rate } @{ $self->{taxes} }) {
 331     $rows_as_html .= $self->p->render('order/tabs/_tax_row', TAX => $tax, TAXINCLUDED => $self->order->taxincluded);
 332   }
 333   return $rows_as_html;
 334 }
 335
 336
 337 sub _make_order {
 338   my ($self) = @_;
 339
 340   # add_items adds items to an order with no items for saving, but they cannot
 341   # be retrieved via items until the order is saved. Adding empty items to new
 342   # order here solves this problem.
 343   my $order;
 344   $order   = SL::DB::Manager::Order->find_by(id => $::form->{id}) if $::form->{id};
 345   $order ||= SL::DB::Order->new(orderitems => []);
 346
 347   $order->assign_attributes(%{$::form->{order}});
 348
 349   return $order;
 350 }
 351
 352
 353 sub _recalc {
 354   my ($self) = @_;
 355
 356   # bb: todo: currency later
 357   $self->order->currency_id($::instance_conf->get_currency_id());
 358
 359   my %pat = $self->order->calculate_prices_and_taxes();
 360   $self->{taxes} = [];
 361   foreach my $tax_chart_id (keys %{ $pat{taxes} }) {
 362     my $tax = SL::DB::Manager::Tax->find_by(chart_id => $tax_chart_id);
 363
 364     my @amount_keys = grep { $pat{amounts}->{$_}->{tax_id} == $tax->id } keys %{ $pat{amounts} };
 365     push(@{ $self->{taxes} }, { amount    => $pat{taxes}->{$tax_chart_id},
 366                                 netamount => $pat{amounts}->{$amount_keys[0]}->{amount},
 367                                 tax       => $tax });
 368   }
 369
 370   pairwise { $a->{linetotal} = $b->{linetotal} } @{$self->order->items}, @{$pat{items}};
 371 }
 372
 373
 374 sub _get_unalterable_data {
 375   my ($self) = @_;
 376
 377   foreach my $item (@{ $self->order->items }) {
 378     if ($item->id) {
 379       # load data from orderitems (db)
 380       my $db_item = SL::DB::OrderItem->new(id => $item->id)->load;
 381       $item->$_($db_item->$_) for qw(active_discount_source active_price_source longdescription);
 382     } else {
 383       # set data from part (or other sources)
 384       $item->longdescription($item->part->notes);
 385       #$item->active_price_source('');
 386       #$item->active_discount_source('');
 387     }
 388
 389     # autovivify all cvars that are not in the form (cvars_by_config can do it).
 390     # workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
 391     foreach my $var (@{ $item->cvars_by_config }) {
 392       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
 393     }
 394     $item->parse_custom_variable_values;
 395   }
 396 }
 397
 398
 399 sub _delete {
 400   my ($self) = @_;
 401
 402   my $errors = [];
 403   my $db = $self->order->db;
 404
 405   $db->do_transaction(
 406     sub {
 407       my @spoolfiles = grep { $_ } map { $_->spoolfile } @{ SL::DB::Manager::Status->get_all(where => [ trans_id => $self->order->id ]) };
 408       $self->order->delete;
 409       my $spool = $::lx_office_conf{paths}->{spool};
 410       unlink map { "$spool/$_" } @spoolfiles if $spool;
 411
 412       1;
 413   }) || push(@{$errors}, $db->error);
 414
 415   return $errors;
 416 }
 417
 418
 419 sub _save {
 420   my ($self) = @_;
 421
 422   my $errors = [];
 423   my $db = $self->order->db;
 424
 425   $db->do_transaction(
 426     sub {
 427       $self->order->save();
 428   }) || push(@{$errors}, $db->error);
 429
 430   return $errors;
 431 }
 432
 433
 434 sub _pre_render {
 435   my ($self) = @_;
 436
 437   $self->{all_taxzones}        = SL::DB::Manager::TaxZone->get_all_sorted();
 438   $self->{all_employees}       = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->employee_id,
 439                                                                                        deleted => 0 ] ],
 440                                                                     sort_by => 'name');
 441   $self->{all_salesmen}        = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->salesman_id,
 442                                                                                        deleted => 0 ] ],
 443                                                                     sort_by => 'name');
 444   $self->{all_projects}        = SL::DB::Manager::Project->get_all(where => [ or => [ id => $self->order->globalproject_id,
 445                                                                                       active => 1 ] ],
 446                                                                    sort_by => 'projectnumber');
 447   $self->{all_payment_terms}   = SL::DB::Manager::PaymentTerm->get_all_sorted();
 448   $self->{all_delivery_terms}  = SL::DB::Manager::DeliveryTerm->get_all_sorted();
 449
 450   $self->{current_employee_id} = SL::DB::Manager::Employee->current->id;
 451
 452   $::request->{layout}->use_javascript("${_}.js")  for qw(ckeditor/ckeditor ckeditor/adapters/jquery);
 453 }
 454
 455 sub _sales_order_type {
 456   'sales_order';
 457 }
 458
 459 sub _purchase_order_type {
 460   'purchase_order';
 461 }
 462
 463 1;