SL/Controller/Order.pm

   1 package SL::Controller::Order;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use SL::Helper::Flash qw(flash_later);
   7 use SL::Presenter::Tag qw(select_tag hidden_tag div_tag);
   8 use SL::Locale::String qw(t8);
   9 use SL::SessionFile::Random;
  10 use SL::PriceSource;
  11 use SL::Webdav;
  12 use SL::File;
  13 use SL::MIME;
  14 use SL::Util qw(trim);
  15 use SL::YAML;
  16 use SL::DB::History;
  17 use SL::DB::Order;
  18 use SL::DB::Default;
  19 use SL::DB::Unit;
  20 use SL::DB::Part;
  21 use SL::DB::PartClassification;
  22 use SL::DB::PartsGroup;
  23 use SL::DB::Printer;
  24 use SL::DB::Language;
  25 use SL::DB::RecordLink;
  26 use SL::DB::Shipto;
  27 use SL::DB::Translation;
  28
  29 use SL::Helper::CreatePDF qw(:all);
  30 use SL::Helper::PrintOptions;
  31 use SL::Helper::ShippedQty;
  32 use SL::Helper::UserPreferences::PositionsScrollbar;
  33 use SL::Helper::UserPreferences::UpdatePositions;
  34
  35 use SL::Controller::Helper::GetModels;
  36
  37 use List::Util qw(first sum0);
  38 use List::UtilsBy qw(sort_by uniq_by);
  39 use List::MoreUtils qw(any none pairwise first_index);
  40 use English qw(-no_match_vars);
  41 use File::Spec;
  42 use Cwd;
  43 use Sort::Naturally;
  44
  45 use Rose::Object::MakeMethods::Generic
  46 (
  47  scalar => [ qw(item_ids_to_delete is_custom_shipto_to_delete) ],
  48  'scalar --get_set_init' => [ qw(order valid_types type cv p all_price_factors search_cvpartnumber show_update_button part_picker_classification_ids) ],
  49 );
  50
  51
  52 # safety
  53 __PACKAGE__->run_before('check_auth');
  54
  55 __PACKAGE__->run_before('recalc',
  56                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice save_and_ap_transaction
  57                                      print send_email) ]);
  58
  59 __PACKAGE__->run_before('get_unalterable_data',
  60                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice save_and_ap_transaction
  61                                      print send_email) ]);
  62
  63 #
  64 # actions
  65 #
  66
  67 # add a new order
  68 sub action_add {
  69   my ($self) = @_;
  70
  71   $self->order->transdate(DateTime->now_local());
  72   my $extra_days = $self->type eq sales_quotation_type() ? $::instance_conf->get_reqdate_interval       :
  73                    $self->type eq sales_order_type()     ? $::instance_conf->get_delivery_date_interval : 1;
  74
  75   if (   ($self->type eq sales_order_type()     &&  $::instance_conf->get_deliverydate_on)
  76       || ($self->type eq sales_quotation_type() &&  $::instance_conf->get_reqdate_on)
  77       && (!$self->order->reqdate)) {
  78     $self->order->reqdate(DateTime->today_local->next_workday(extra_days => $extra_days));
  79   }
  80
  81
  82   $self->pre_render();
  83   $self->render(
  84     'order/form',
  85     title => $self->get_title_for('add'),
  86     %{$self->{template_args}}
  87   );
  88 }
  89
  90 # edit an existing order
  91 sub action_edit {
  92   my ($self) = @_;
  93
  94   if ($::form->{id}) {
  95     $self->load_order;
  96
  97   } else {
  98     # this is to edit an order from an unsaved order object
  99
 100     # set item ids to new fake id, to identify them as new items
 101     foreach my $item (@{$self->order->items_sorted}) {
 102       $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 103     }
 104     # trigger rendering values for second row as hidden, because they
 105     # are loaded only on demand. So we need to keep the values from
 106     # the source.
 107     $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
 108   }
 109
 110   $self->recalc();
 111   $self->pre_render();
 112   $self->render(
 113     'order/form',
 114     title => $self->get_title_for('edit'),
 115     %{$self->{template_args}}
 116   );
 117 }
 118
 119 # edit a collective order (consisting of one or more existing orders)
 120 sub action_edit_collective {
 121   my ($self) = @_;
 122
 123   # collect order ids
 124   my @multi_ids = map {
 125     $_ =~ m{^multi_id_(\d+)$} && $::form->{'multi_id_' . $1} && $::form->{'trans_id_' . $1} && $::form->{'trans_id_' . $1}
 126   } grep { $_ =~ m{^multi_id_\d+$} } keys %$::form;
 127
 128   # fall back to add if no ids are given
 129   if (scalar @multi_ids == 0) {
 130     $self->action_add();
 131     return;
 132   }
 133
 134   # fall back to save as new if only one id is given
 135   if (scalar @multi_ids == 1) {
 136     $self->order(SL::DB::Order->new(id => $multi_ids[0])->load);
 137     $self->action_save_as_new();
 138     return;
 139   }
 140
 141   # make new order from given orders
 142   my @multi_orders = map { SL::DB::Order->new(id => $_)->load } @multi_ids;
 143   $self->{converted_from_oe_id} = join ' ', map { $_->id } @multi_orders;
 144   $self->order(SL::DB::Order->new_from_multi(\@multi_orders, sort_sources_by => 'transdate'));
 145
 146   $self->action_edit();
 147 }
 148
 149 # delete the order
 150 sub action_delete {
 151   my ($self) = @_;
 152
 153   my $errors = $self->delete();
 154
 155   if (scalar @{ $errors }) {
 156     $self->js->flash('error', $_) foreach @{ $errors };
 157     return $self->js->render();
 158   }
 159
 160   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been deleted')
 161            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been deleted')
 162            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been deleted')
 163            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been deleted')
 164            : '';
 165   flash_later('info', $text);
 166
 167   my @redirect_params = (
 168     action => 'add',
 169     type   => $self->type,
 170   );
 171
 172   $self->redirect_to(@redirect_params);
 173 }
 174
 175 # save the order
 176 sub action_save {
 177   my ($self) = @_;
 178
 179   my $errors = $self->save();
 180
 181   if (scalar @{ $errors }) {
 182     $self->js->flash('error', $_) foreach @{ $errors };
 183     return $self->js->render();
 184   }
 185
 186   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
 187            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
 188            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
 189            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
 190            : '';
 191   flash_later('info', $text);
 192
 193   my @redirect_params = (
 194     action => 'edit',
 195     type   => $self->type,
 196     id     => $self->order->id,
 197   );
 198
 199   $self->redirect_to(@redirect_params);
 200 }
 201
 202 # save the order as new document an open it for edit
 203 sub action_save_as_new {
 204   my ($self) = @_;
 205
 206   my $order = $self->order;
 207
 208   if (!$order->id) {
 209     $self->js->flash('error', t8('This object has not been saved yet.'));
 210     return $self->js->render();
 211   }
 212
 213   # load order from db to check if values changed
 214   my $saved_order = SL::DB::Order->new(id => $order->id)->load;
 215
 216   my %new_attrs;
 217   # Lets assign a new number if the user hasn't changed the previous one.
 218   # If it has been changed manually then use it as-is.
 219   $new_attrs{number}    = (trim($order->number) eq $saved_order->number)
 220                         ? ''
 221                         : trim($order->number);
 222
 223   # Clear transdate unless changed
 224   $new_attrs{transdate} = ($order->transdate == $saved_order->transdate)
 225                         ? DateTime->today_local
 226                         : $order->transdate;
 227
 228   # Set new reqdate unless changed if it is enabled in client config
 229   if ($order->reqdate == $saved_order->reqdate) {
 230     my $extra_days = $self->type eq sales_quotation_type() ? $::instance_conf->get_reqdate_interval       :
 231                      $self->type eq sales_order_type()     ? $::instance_conf->get_delivery_date_interval : 1;
 232
 233     if (   ($self->type eq sales_order_type()     &&  !$::instance_conf->get_deliverydate_on)
 234         || ($self->type eq sales_quotation_type() &&  !$::instance_conf->get_reqdate_on)) {
 235       $new_attrs{reqdate} = '';
 236     } else {
 237       $new_attrs{reqdate} = DateTime->today_local->next_workday(extra_days => $extra_days);
 238     }
 239   } else {
 240     $new_attrs{reqdate} = $order->reqdate;
 241   }
 242
 243   # Update employee
 244   $new_attrs{employee}  = SL::DB::Manager::Employee->current;
 245
 246   # Create new record from current one
 247   $self->order(SL::DB::Order->new_from($order, destination_type => $order->type, attributes => \%new_attrs));
 248
 249   # no linked records on save as new
 250   delete $::form->{$_} for qw(converted_from_oe_id converted_from_orderitems_ids);
 251
 252   # save
 253   $self->action_save();
 254 }
 255
 256 # print the order
 257 #
 258 # This is called if "print" is pressed in the print dialog.
 259 # If PDF creation was requested and succeeded, the pdf is offered for download
 260 # via send_file (which uses ajax in this case).
 261 sub action_print {
 262   my ($self) = @_;
 263
 264   my $errors = $self->save();
 265
 266   if (scalar @{ $errors }) {
 267     $self->js->flash('error', $_) foreach @{ $errors };
 268     return $self->js->render();
 269   }
 270
 271   $self->js_reset_order_and_item_ids_after_save;
 272
 273   my $format      = $::form->{print_options}->{format};
 274   my $media       = $::form->{print_options}->{media};
 275   my $formname    = $::form->{print_options}->{formname};
 276   my $copies      = $::form->{print_options}->{copies};
 277   my $groupitems  = $::form->{print_options}->{groupitems};
 278   my $printer_id  = $::form->{print_options}->{printer_id};
 279
 280   # only pdf and opendocument by now
 281   if (none { $format eq $_ } qw(pdf opendocument opendocument_pdf)) {
 282     return $self->js->flash('error', t8('Format \'#1\' is not supported yet/anymore.', $format))->render;
 283   }
 284
 285   # only screen or printer by now
 286   if (none { $media eq $_ } qw(screen printer)) {
 287     return $self->js->flash('error', t8('Media \'#1\' is not supported yet/anymore.', $media))->render;
 288   }
 289
 290   # create a form for generate_attachment_filename
 291   my $form   = Form->new;
 292   $form->{$self->nr_key()}  = $self->order->number;
 293   $form->{type}             = $self->type;
 294   $form->{format}           = $format;
 295   $form->{formname}         = $formname;
 296   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 297   my $pdf_filename          = $form->generate_attachment_filename();
 298
 299   my $pdf;
 300   my @errors = generate_pdf($self->order, \$pdf, { format     => $format,
 301                                                    formname   => $formname,
 302                                                    language   => $self->order->language,
 303                                                    printer_id => $printer_id,
 304                                                    groupitems => $groupitems });
 305   if (scalar @errors) {
 306     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render;
 307   }
 308
 309   if ($media eq 'screen') {
 310     # screen/download
 311     $self->js->flash('info', t8('The PDF has been created'));
 312     $self->send_file(
 313       \$pdf,
 314       type         => SL::MIME->mime_type_from_ext($pdf_filename),
 315       name         => $pdf_filename,
 316       js_no_render => 1,
 317     );
 318
 319   } elsif ($media eq 'printer') {
 320     # printer
 321     my $printer_id = $::form->{print_options}->{printer_id};
 322     SL::DB::Printer->new(id => $printer_id)->load->print_document(
 323       copies  => $copies,
 324       content => $pdf,
 325     );
 326
 327     $self->js->flash('info', t8('The PDF has been printed'));
 328   }
 329
 330   my @warnings = store_pdf_to_webdav_and_filemanagement($self->order, $pdf, $pdf_filename);
 331   if (scalar @warnings) {
 332     $self->js->flash('warning', $_) for @warnings;
 333   }
 334
 335   $self->save_history('PRINTED');
 336
 337   $self->js
 338     ->run('kivi.ActionBar.setEnabled', '#save_and_email_action')
 339     ->render;
 340 }
 341 sub action_preview_pdf {
 342   my ($self) = @_;
 343
 344   my $errors = $self->save();
 345   if (scalar @{ $errors }) {
 346     $self->js->flash('error', $_) foreach @{ $errors };
 347     return $self->js->render();
 348   }
 349
 350   $self->js_reset_order_and_item_ids_after_save;
 351
 352   my $format      = 'pdf';
 353   my $media       = 'screen';
 354   my $formname    = $self->type;
 355
 356   # only pdf
 357   # create a form for generate_attachment_filename
 358   my $form   = Form->new;
 359   $form->{$self->nr_key()}  = $self->order->number;
 360   $form->{type}             = $self->type;
 361   $form->{format}           = $format;
 362   $form->{formname}         = $formname;
 363   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 364   my $pdf_filename          = $form->generate_attachment_filename();
 365
 366   my $pdf;
 367   my @errors = generate_pdf($self->order, \$pdf, { format     => $format,
 368                                                    formname   => $formname,
 369                                                    language   => $self->order->language,
 370                                                  });
 371   if (scalar @errors) {
 372     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render;
 373   }
 374   $self->save_history('PREVIEWED');
 375   $self->js->flash('info', t8('The PDF has been previewed'));
 376   # screen/download
 377   $self->send_file(
 378     \$pdf,
 379     type         => SL::MIME->mime_type_from_ext($pdf_filename),
 380     name         => $pdf_filename,
 381     js_no_render => 0,
 382   );
 383 }
 384
 385 # open the email dialog
 386 sub action_save_and_show_email_dialog {
 387   my ($self) = @_;
 388
 389   my $errors = $self->save();
 390
 391   if (scalar @{ $errors }) {
 392     $self->js->flash('error', $_) foreach @{ $errors };
 393     return $self->js->render();
 394   }
 395
 396   my $cv_method = $self->cv;
 397
 398   if (!$self->order->$cv_method) {
 399     return $self->js->flash('error', $self->cv eq 'customer' ? t8('Cannot send E-mail without customer given') : t8('Cannot send E-mail without vendor given'))
 400                     ->render($self);
 401   }
 402
 403   my $email_form;
 404   $email_form->{to}   = $self->order->contact->cp_email if $self->order->contact;
 405   $email_form->{to} ||= $self->order->$cv_method->email;
 406   $email_form->{cc}   = $self->order->$cv_method->cc;
 407   $email_form->{bcc}  = join ', ', grep $_, $self->order->$cv_method->bcc, SL::DB::Default->get->global_bcc;
 408   # Todo: get addresses from shipto, if any
 409
 410   my $form = Form->new;
 411   $form->{$self->nr_key()}  = $self->order->number;
 412   $form->{cusordnumber}     = $self->order->cusordnumber;
 413   $form->{formname}         = $self->type;
 414   $form->{type}             = $self->type;
 415   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 416   $form->{language_id}      = $self->order->language->id                  if $self->order->language;
 417   $form->{format}           = 'pdf';
 418   $form->{cp_id}            = $self->order->contact->cp_id if $self->order->contact;
 419
 420   $email_form->{subject}             = $form->generate_email_subject();
 421   $email_form->{attachment_filename} = $form->generate_attachment_filename();
 422   $email_form->{message}             = $form->generate_email_body();
 423   $email_form->{js_send_function}    = 'kivi.Order.send_email()';
 424
 425   my %files = $self->get_files_for_email_dialog();
 426   $self->{all_employees} = SL::DB::Manager::Employee->get_all(query => [ deleted => 0 ]);
 427   my $dialog_html = $self->render('common/_send_email_dialog', { output => 0 },
 428                                   email_form  => $email_form,
 429                                   show_bcc    => $::auth->assert('email_bcc', 'may fail'),
 430                                   FILES       => \%files,
 431                                   is_customer => $self->cv eq 'customer',
 432                                   ALL_EMPLOYEES => $self->{all_employees},
 433   );
 434
 435   $self->js
 436       ->run('kivi.Order.show_email_dialog', $dialog_html)
 437       ->reinit_widgets
 438       ->render($self);
 439 }
 440
 441 # send email
 442 #
 443 # Todo: handling error messages: flash is not displayed in dialog, but in the main form
 444 sub action_send_email {
 445   my ($self) = @_;
 446
 447   my $errors = $self->save();
 448
 449   if (scalar @{ $errors }) {
 450     $self->js->run('kivi.Order.close_email_dialog');
 451     $self->js->flash('error', $_) foreach @{ $errors };
 452     return $self->js->render();
 453   }
 454
 455   $self->js_reset_order_and_item_ids_after_save;
 456
 457   my $email_form  = delete $::form->{email_form};
 458   my %field_names = (to => 'email');
 459
 460   $::form->{ $field_names{$_} // $_ } = $email_form->{$_} for keys %{ $email_form };
 461
 462   # for Form::cleanup which may be called in Form::send_email
 463   $::form->{cwd}    = getcwd();
 464   $::form->{tmpdir} = $::lx_office_conf{paths}->{userspath};
 465
 466   $::form->{$_}     = $::form->{print_options}->{$_} for keys %{ $::form->{print_options} };
 467   $::form->{media}  = 'email';
 468
 469   if (($::form->{attachment_policy} // '') !~ m{^(?:old_file|no_file)$}) {
 470     my $pdf;
 471     my @errors = generate_pdf($self->order, \$pdf, {media      => $::form->{media},
 472                                                     format     => $::form->{print_options}->{format},
 473                                                     formname   => $::form->{print_options}->{formname},
 474                                                     language   => $self->order->language,
 475                                                     printer_id => $::form->{print_options}->{printer_id},
 476                                                     groupitems => $::form->{print_options}->{groupitems}});
 477     if (scalar @errors) {
 478       return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render($self);
 479     }
 480
 481     my @warnings = store_pdf_to_webdav_and_filemanagement($self->order, $pdf, $::form->{attachment_filename});
 482     if (scalar @warnings) {
 483       flash_later('warning', $_) for @warnings;
 484     }
 485
 486     my $sfile = SL::SessionFile::Random->new(mode => "w");
 487     $sfile->fh->print($pdf);
 488     $sfile->fh->close;
 489
 490     $::form->{tmpfile} = $sfile->file_name;
 491     $::form->{tmpdir}  = $sfile->get_path; # for Form::cleanup which may be called in Form::send_email
 492   }
 493
 494   $::form->{id} = $self->order->id; # this is used in SL::Mailer to create a linked record to the mail
 495   $::form->send_email(\%::myconfig, 'pdf');
 496
 497   # internal notes
 498   my $intnotes = $self->order->intnotes;
 499   $intnotes   .= "\n\n" if $self->order->intnotes;
 500   $intnotes   .= t8('[email]')                                                                                        . "\n";
 501   $intnotes   .= t8('Date')       . ": " . $::locale->format_date_object(DateTime->now_local, precision => 'seconds') . "\n";
 502   $intnotes   .= t8('To (email)') . ": " . $::form->{email}                                                           . "\n";
 503   $intnotes   .= t8('Cc')         . ": " . $::form->{cc}                                                              . "\n"    if $::form->{cc};
 504   $intnotes   .= t8('Bcc')        . ": " . $::form->{bcc}                                                             . "\n"    if $::form->{bcc};
 505   $intnotes   .= t8('Subject')    . ": " . $::form->{subject}                                                         . "\n\n";
 506   $intnotes   .= t8('Message')    . ": " . $::form->{message};
 507
 508   $self->order->update_attributes(intnotes => $intnotes);
 509
 510   $self->save_history('MAILED');
 511
 512   flash_later('info', t8('The email has been sent.'));
 513
 514   my @redirect_params = (
 515     action => 'edit',
 516     type   => $self->type,
 517     id     => $self->order->id,
 518   );
 519
 520   $self->redirect_to(@redirect_params);
 521 }
 522
 523 # open the periodic invoices config dialog
 524 #
 525 # If there are values in the form (i.e. dialog was opened before),
 526 # then use this values. Create new ones, else.
 527 sub action_show_periodic_invoices_config_dialog {
 528   my ($self) = @_;
 529
 530   my $config = make_periodic_invoices_config_from_yaml(delete $::form->{config});
 531   $config  ||= SL::DB::Manager::PeriodicInvoicesConfig->find_by(oe_id => $::form->{id}) if $::form->{id};
 532   $config  ||= SL::DB::PeriodicInvoicesConfig->new(periodicity             => 'm',
 533                                                    order_value_periodicity => 'p', # = same as periodicity
 534                                                    start_date_as_date      => $::form->{transdate_as_date} || $::form->current_date,
 535                                                    extend_automatically_by => 12,
 536                                                    active                  => 1,
 537                                                    email_subject           => GenericTranslations->get(
 538                                                                                 language_id      => $::form->{language_id},
 539                                                                                 translation_type =>"preset_text_periodic_invoices_email_subject"),
 540                                                    email_body              => GenericTranslations->get(
 541                                                                                 language_id      => $::form->{language_id},
 542                                                                                 translation_type =>"preset_text_periodic_invoices_email_body"),
 543   );
 544   $config->periodicity('m')             if none { $_ eq $config->periodicity             }       @SL::DB::PeriodicInvoicesConfig::PERIODICITIES;
 545   $config->order_value_periodicity('p') if none { $_ eq $config->order_value_periodicity } ('p', @SL::DB::PeriodicInvoicesConfig::ORDER_VALUE_PERIODICITIES);
 546
 547   $::form->get_lists(printers => "ALL_PRINTERS",
 548                      charts   => { key       => 'ALL_CHARTS',
 549                                    transdate => 'current_date' });
 550
 551   $::form->{AR} = [ grep { $_->{link} =~ m/(?:^|:)AR(?::|$)/ } @{ $::form->{ALL_CHARTS} } ];
 552
 553   if ($::form->{customer_id}) {
 554     $::form->{ALL_CONTACTS} = SL::DB::Manager::Contact->get_all_sorted(where => [ cp_cv_id => $::form->{customer_id} ]);
 555     my $customer_object = SL::DB::Manager::Customer->find_by(id => $::form->{customer_id});
 556     $::form->{postal_invoice}                  = $customer_object->postal_invoice;
 557     $::form->{email_recipient_invoice_address} = $::form->{postal_invoice} ? '' : $customer_object->invoice_mail;
 558     $config->send_email(0) if $::form->{postal_invoice};
 559   }
 560
 561   $self->render('oe/edit_periodic_invoices_config', { layout => 0 },
 562                 popup_dialog             => 1,
 563                 popup_js_close_function  => 'kivi.Order.close_periodic_invoices_config_dialog()',
 564                 popup_js_assign_function => 'kivi.Order.assign_periodic_invoices_config()',
 565                 config                   => $config,
 566                 %$::form);
 567 }
 568
 569 # assign the values of the periodic invoices config dialog
 570 # as yaml in the hidden tag and set the status.
 571 sub action_assign_periodic_invoices_config {
 572   my ($self) = @_;
 573
 574   $::form->isblank('start_date_as_date', $::locale->text('The start date is missing.'));
 575
 576   my $config = { active                     => $::form->{active}       ? 1 : 0,
 577                  terminated                 => $::form->{terminated}   ? 1 : 0,
 578                  direct_debit               => $::form->{direct_debit} ? 1 : 0,
 579                  periodicity                => (any { $_ eq $::form->{periodicity}             }       @SL::DB::PeriodicInvoicesConfig::PERIODICITIES)              ? $::form->{periodicity}             : 'm',
 580                  order_value_periodicity    => (any { $_ eq $::form->{order_value_periodicity} } ('p', @SL::DB::PeriodicInvoicesConfig::ORDER_VALUE_PERIODICITIES)) ? $::form->{order_value_periodicity} : 'p',
 581                  start_date_as_date         => $::form->{start_date_as_date},
 582                  end_date_as_date           => $::form->{end_date_as_date},
 583                  first_billing_date_as_date => $::form->{first_billing_date_as_date},
 584                  print                      => $::form->{print}      ? 1                         : 0,
 585                  printer_id                 => $::form->{print}      ? $::form->{printer_id} * 1 : undef,
 586                  copies                     => $::form->{copies} * 1 ? $::form->{copies}         : 1,
 587                  extend_automatically_by    => $::form->{extend_automatically_by}    * 1 || undef,
 588                  ar_chart_id                => $::form->{ar_chart_id} * 1,
 589                  send_email                 => $::form->{send_email} ? 1 : 0,
 590                  email_recipient_contact_id => $::form->{email_recipient_contact_id} * 1 || undef,
 591                  email_recipient_address    => $::form->{email_recipient_address},
 592                  email_sender               => $::form->{email_sender},
 593                  email_subject              => $::form->{email_subject},
 594                  email_body                 => $::form->{email_body},
 595                };
 596
 597   my $periodic_invoices_config = SL::YAML::Dump($config);
 598
 599   my $status = $self->get_periodic_invoices_status($config);
 600
 601   $self->js
 602     ->remove('#order_periodic_invoices_config')
 603     ->insertAfter(hidden_tag('order.periodic_invoices_config', $periodic_invoices_config), '#periodic_invoices_status')
 604     ->run('kivi.Order.close_periodic_invoices_config_dialog')
 605     ->html('#periodic_invoices_status', $status)
 606     ->flash('info', t8('The periodic invoices config has been assigned.'))
 607     ->render($self);
 608 }
 609
 610 sub action_get_has_active_periodic_invoices {
 611   my ($self) = @_;
 612
 613   my $config = make_periodic_invoices_config_from_yaml(delete $::form->{config});
 614   $config  ||= SL::DB::Manager::PeriodicInvoicesConfig->find_by(oe_id => $::form->{id}) if $::form->{id};
 615
 616   my $has_active_periodic_invoices =
 617        $self->type eq sales_order_type()
 618     && $config
 619     && $config->active
 620     && (!$config->end_date || ($config->end_date > DateTime->today_local))
 621     && $config->get_previous_billed_period_start_date;
 622
 623   $_[0]->render(\ !!$has_active_periodic_invoices, { type => 'text' });
 624 }
 625
 626 # save the order and redirect to the frontend subroutine for a new
 627 # delivery order
 628 sub action_save_and_delivery_order {
 629   my ($self) = @_;
 630
 631   $self->save_and_redirect_to(
 632     controller => 'oe.pl',
 633     action     => 'oe_delivery_order_from_order',
 634   );
 635 }
 636
 637 # save the order and redirect to the frontend subroutine for a new
 638 # invoice
 639 sub action_save_and_invoice {
 640   my ($self) = @_;
 641
 642   $self->save_and_redirect_to(
 643     controller => 'oe.pl',
 644     action     => 'oe_invoice_from_order',
 645   );
 646 }
 647
 648 # workflow from sales order to sales quotation
 649 sub action_sales_quotation {
 650   $_[0]->workflow_sales_or_request_for_quotation();
 651 }
 652
 653 # workflow from sales order to sales quotation
 654 sub action_request_for_quotation {
 655   $_[0]->workflow_sales_or_request_for_quotation();
 656 }
 657
 658 # workflow from sales quotation to sales order
 659 sub action_sales_order {
 660   $_[0]->workflow_sales_or_purchase_order();
 661 }
 662
 663 # workflow from rfq to purchase order
 664 sub action_purchase_order {
 665   $_[0]->workflow_sales_or_purchase_order();
 666 }
 667
 668 # workflow from purchase order to ap transaction
 669 sub action_save_and_ap_transaction {
 670   my ($self) = @_;
 671
 672   $self->save_and_redirect_to(
 673     controller => 'ap.pl',
 674     action     => 'add_from_purchase_order',
 675   );
 676 }
 677
 678 # set form elements in respect to a changed customer or vendor
 679 #
 680 # This action is called on an change of the customer/vendor picker.
 681 sub action_customer_vendor_changed {
 682   my ($self) = @_;
 683
 684   setup_order_from_cv($self->order);
 685   $self->recalc();
 686
 687   my $cv_method = $self->cv;
 688
 689   if ($self->order->$cv_method->contacts && scalar @{ $self->order->$cv_method->contacts } > 0) {
 690     $self->js->show('#cp_row');
 691   } else {
 692     $self->js->hide('#cp_row');
 693   }
 694
 695   if ($self->order->$cv_method->shipto && scalar @{ $self->order->$cv_method->shipto } > 0) {
 696     $self->js->show('#shipto_selection');
 697   } else {
 698     $self->js->hide('#shipto_selection');
 699   }
 700
 701   $self->js->val( '#order_salesman_id',      $self->order->salesman_id)        if $self->order->is_sales;
 702
 703   $self->js
 704     ->replaceWith('#order_cp_id',            $self->build_contact_select)
 705     ->replaceWith('#order_shipto_id',        $self->build_shipto_select)
 706     ->replaceWith('#shipto_inputs  ',        $self->build_shipto_inputs)
 707     ->replaceWith('#business_info_row',      $self->build_business_info_row)
 708     ->val(        '#order_taxzone_id',       $self->order->taxzone_id)
 709     ->val(        '#order_taxincluded',      $self->order->taxincluded)
 710     ->val(        '#order_currency_id',      $self->order->currency_id)
 711     ->val(        '#order_payment_id',       $self->order->payment_id)
 712     ->val(        '#order_delivery_term_id', $self->order->delivery_term_id)
 713     ->val(        '#order_intnotes',         $self->order->intnotes)
 714     ->val(        '#order_language_id',      $self->order->$cv_method->language_id)
 715     ->focus(      '#order_' . $self->cv . '_id')
 716     ->run('kivi.Order.update_exchangerate');
 717
 718   $self->js_redisplay_amounts_and_taxes;
 719   $self->js_redisplay_cvpartnumbers;
 720   $self->js->render();
 721 }
 722
 723 # open the dialog for customer/vendor details
 724 sub action_show_customer_vendor_details_dialog {
 725   my ($self) = @_;
 726
 727   my $is_customer = 'customer' eq $::form->{vc};
 728   my $cv;
 729   if ($is_customer) {
 730     $cv = SL::DB::Customer->new(id => $::form->{vc_id})->load;
 731   } else {
 732     $cv = SL::DB::Vendor->new(id => $::form->{vc_id})->load;
 733   }
 734
 735   my %details = map { $_ => $cv->$_ } @{$cv->meta->columns};
 736   $details{discount_as_percent} = $cv->discount_as_percent;
 737   $details{creditlimt}          = $cv->creditlimit_as_number;
 738   $details{business}            = $cv->business->description      if $cv->business;
 739   $details{language}            = $cv->language_obj->description  if $cv->language_obj;
 740   $details{delivery_terms}      = $cv->delivery_term->description if $cv->delivery_term;
 741   $details{payment_terms}       = $cv->payment->description       if $cv->payment;
 742   $details{pricegroup}          = $cv->pricegroup->pricegroup     if $is_customer && $cv->pricegroup;
 743
 744   foreach my $entry (@{ $cv->shipto }) {
 745     push @{ $details{SHIPTO} },   { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 746   }
 747   foreach my $entry (@{ $cv->contacts }) {
 748     push @{ $details{CONTACTS} }, { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 749   }
 750
 751   $_[0]->render('common/show_vc_details', { layout => 0 },
 752                 is_customer => $is_customer,
 753                 %details);
 754
 755 }
 756
 757 # called if a unit in an existing item row is changed
 758 sub action_unit_changed {
 759   my ($self) = @_;
 760
 761   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 762   my $item = $self->order->items_sorted->[$idx];
 763
 764   my $old_unit_obj = SL::DB::Unit->new(name => $::form->{old_unit})->load;
 765   $item->sellprice($item->unit_obj->convert_to($item->sellprice, $old_unit_obj));
 766
 767   $self->recalc();
 768
 769   $self->js
 770     ->run('kivi.Order.update_sellprice', $::form->{item_id}, $item->sellprice_as_number);
 771   $self->js_redisplay_line_values;
 772   $self->js_redisplay_amounts_and_taxes;
 773   $self->js->render();
 774 }
 775
 776 # add an item row for a new item entered in the input row
 777 sub action_add_item {
 778   my ($self) = @_;
 779
 780   delete $::form->{add_item}->{create_part_type};
 781
 782   my $form_attr = $::form->{add_item};
 783
 784   return unless $form_attr->{parts_id};
 785
 786   my $item = new_item($self->order, $form_attr);
 787
 788   $self->order->add_items($item);
 789
 790   $self->recalc();
 791
 792   $self->get_item_cvpartnumber($item);
 793
 794   my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 795   my $row_as_html = $self->p->render('order/tabs/_row',
 796                                      ITEM => $item,
 797                                      ID   => $item_id,
 798                                      SELF => $self,
 799   );
 800
 801   if ($::form->{insert_before_item_id}) {
 802     $self->js
 803       ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 804   } else {
 805     $self->js
 806       ->append('#row_table_id', $row_as_html);
 807   }
 808
 809   if ( $item->part->is_assortment ) {
 810     $form_attr->{qty_as_number} = 1 unless $form_attr->{qty_as_number};
 811     foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 812       my $attr = { parts_id => $assortment_item->parts_id,
 813                    qty      => $assortment_item->qty * $::form->parse_amount(\%::myconfig, $form_attr->{qty_as_number}), # TODO $form_attr->{unit}
 814                    unit     => $assortment_item->unit,
 815                    description => $assortment_item->part->description,
 816                  };
 817       my $item = new_item($self->order, $attr);
 818
 819       # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 820       $item->discount(1) unless $assortment_item->charge;
 821
 822       $self->order->add_items( $item );
 823       $self->recalc();
 824       $self->get_item_cvpartnumber($item);
 825       my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 826       my $row_as_html = $self->p->render('order/tabs/_row',
 827                                          ITEM => $item,
 828                                          ID   => $item_id,
 829                                          SELF => $self,
 830       );
 831       if ($::form->{insert_before_item_id}) {
 832         $self->js
 833           ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 834       } else {
 835         $self->js
 836           ->append('#row_table_id', $row_as_html);
 837       }
 838     };
 839   };
 840
 841   $self->js
 842     ->val('.add_item_input', '')
 843     ->run('kivi.Order.init_row_handlers')
 844     ->run('kivi.Order.renumber_positions')
 845     ->focus('#add_item_parts_id_name');
 846
 847   $self->js->run('kivi.Order.row_table_scroll_down') if !$::form->{insert_before_item_id};
 848
 849   $self->js_redisplay_amounts_and_taxes;
 850   $self->js->render();
 851 }
 852
 853 # add item rows for multiple items at once
 854 sub action_add_multi_items {
 855   my ($self) = @_;
 856
 857   my @form_attr = grep { $_->{qty_as_number} } @{ $::form->{add_items} };
 858   return $self->js->render() unless scalar @form_attr;
 859
 860   my @items;
 861   foreach my $attr (@form_attr) {
 862     my $item = new_item($self->order, $attr);
 863     push @items, $item;
 864     if ( $item->part->is_assortment ) {
 865       foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 866         my $attr = { parts_id => $assortment_item->parts_id,
 867                      qty      => $assortment_item->qty * $item->qty, # TODO $form_attr->{unit}
 868                      unit     => $assortment_item->unit,
 869                      description => $assortment_item->part->description,
 870                    };
 871         my $item = new_item($self->order, $attr);
 872
 873         # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 874         $item->discount(1) unless $assortment_item->charge;
 875         push @items, $item;
 876       }
 877     }
 878   }
 879   $self->order->add_items(@items);
 880
 881   $self->recalc();
 882
 883   foreach my $item (@items) {
 884     $self->get_item_cvpartnumber($item);
 885     my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 886     my $row_as_html = $self->p->render('order/tabs/_row',
 887                                        ITEM => $item,
 888                                        ID   => $item_id,
 889                                        SELF => $self,
 890     );
 891
 892     if ($::form->{insert_before_item_id}) {
 893       $self->js
 894         ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 895     } else {
 896       $self->js
 897         ->append('#row_table_id', $row_as_html);
 898     }
 899   }
 900
 901   $self->js
 902     ->run('kivi.Part.close_picker_dialogs')
 903     ->run('kivi.Order.init_row_handlers')
 904     ->run('kivi.Order.renumber_positions')
 905     ->focus('#add_item_parts_id_name');
 906
 907   $self->js->run('kivi.Order.row_table_scroll_down') if !$::form->{insert_before_item_id};
 908
 909   $self->js_redisplay_amounts_and_taxes;
 910   $self->js->render();
 911 }
 912
 913 # recalculate all linetotals, amounts and taxes and redisplay them
 914 sub action_recalc_amounts_and_taxes {
 915   my ($self) = @_;
 916
 917   $self->recalc();
 918
 919   $self->js_redisplay_line_values;
 920   $self->js_redisplay_amounts_and_taxes;
 921   $self->js->render();
 922 }
 923
 924 sub action_update_exchangerate {
 925   my ($self) = @_;
 926
 927   my $data = {
 928     is_standard   => $self->order->currency_id == $::instance_conf->get_currency_id,
 929     currency_name => $self->order->currency->name,
 930     exchangerate  => $self->order->daily_exchangerate_as_null_number,
 931   };
 932
 933   $self->render(\SL::JSON::to_json($data), { type => 'json', process => 0 });
 934 }
 935
 936 # redisplay item rows if they are sorted by an attribute
 937 sub action_reorder_items {
 938   my ($self) = @_;
 939
 940   my %sort_keys = (
 941     partnumber   => sub { $_[0]->part->partnumber },
 942     description  => sub { $_[0]->description },
 943     qty          => sub { $_[0]->qty },
 944     sellprice    => sub { $_[0]->sellprice },
 945     discount     => sub { $_[0]->discount },
 946     cvpartnumber => sub { $_[0]->{cvpartnumber} },
 947   );
 948
 949   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
 950
 951   my $method = $sort_keys{$::form->{order_by}};
 952   my @to_sort = map { { old_pos => $_->position, order_by => $method->($_) } } @{ $self->order->items_sorted };
 953   if ($::form->{sort_dir}) {
 954     if ( $::form->{order_by} =~ m/qty|sellprice|discount/ ){
 955       @to_sort = sort { $a->{order_by} <=> $b->{order_by} } @to_sort;
 956     } else {
 957       @to_sort = sort { $a->{order_by} cmp $b->{order_by} } @to_sort;
 958     }
 959   } else {
 960     if ( $::form->{order_by} =~ m/qty|sellprice|discount/ ){
 961       @to_sort = sort { $b->{order_by} <=> $a->{order_by} } @to_sort;
 962     } else {
 963       @to_sort = sort { $b->{order_by} cmp $a->{order_by} } @to_sort;
 964     }
 965   }
 966   $self->js
 967     ->run('kivi.Order.redisplay_items', \@to_sort)
 968     ->render;
 969 }
 970
 971 # show the popup to choose a price/discount source
 972 sub action_price_popup {
 973   my ($self) = @_;
 974
 975   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 976   my $item = $self->order->items_sorted->[$idx];
 977
 978   $self->render_price_dialog($item);
 979 }
 980
 981 # save the order in a session variable and redirect to the part controller
 982 sub action_create_part {
 983   my ($self) = @_;
 984
 985   my $previousform = $::auth->save_form_in_session(non_scalars => 1);
 986
 987   my $callback     = $self->url_for(
 988     action       => 'return_from_create_part',
 989     type         => $self->type, # type is needed for check_auth on return
 990     previousform => $previousform,
 991   );
 992
 993   flash_later('info', t8('You are adding a new part while you are editing another document. You will be redirected to your document when saving the new part or aborting this form.'));
 994
 995   my @redirect_params = (
 996     controller => 'Part',
 997     action     => 'add',
 998     part_type  => $::form->{add_item}->{create_part_type},
 999     callback   => $callback,
1000     show_abort => 1,
1001   );
1002
1003   $self->redirect_to(@redirect_params);
1004 }
1005
1006 sub action_return_from_create_part {
1007   my ($self) = @_;
1008
1009   $self->{created_part} = SL::DB::Part->new(id => delete $::form->{new_parts_id})->load if $::form->{new_parts_id};
1010
1011   $::auth->restore_form_from_session(delete $::form->{previousform});
1012
1013   # set item ids to new fake id, to identify them as new items
1014   foreach my $item (@{$self->order->items_sorted}) {
1015     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1016   }
1017
1018   $self->recalc();
1019   $self->get_unalterable_data();
1020   $self->pre_render();
1021
1022   # trigger rendering values for second row/longdescription as hidden,
1023   # because they are loaded only on demand. So we need to keep the values
1024   # from the source.
1025   $_->{render_second_row}      = 1 for @{ $self->order->items_sorted };
1026   $_->{render_longdescription} = 1 for @{ $self->order->items_sorted };
1027
1028   $self->render(
1029     'order/form',
1030     title => $self->get_title_for('edit'),
1031     %{$self->{template_args}}
1032   );
1033
1034 }
1035
1036 # load the second row for one or more items
1037 #
1038 # This action gets the html code for all items second rows by rendering a template for
1039 # the second row and sets the html code via client js.
1040 sub action_load_second_rows {
1041   my ($self) = @_;
1042
1043   $self->recalc() if $self->order->is_sales; # for margin calculation
1044
1045   foreach my $item_id (@{ $::form->{item_ids} }) {
1046     my $idx  = first_index { $_ eq $item_id } @{ $::form->{orderitem_ids} };
1047     my $item = $self->order->items_sorted->[$idx];
1048
1049     $self->js_load_second_row($item, $item_id, 0);
1050   }
1051
1052   $self->js->run('kivi.Order.init_row_handlers') if $self->order->is_sales; # for lastcosts change-callback
1053
1054   $self->js->render();
1055 }
1056
1057 # update description, notes and sellprice from master data
1058 sub action_update_row_from_master_data {
1059   my ($self) = @_;
1060
1061   foreach my $item_id (@{ $::form->{item_ids} }) {
1062     my $idx   = first_index { $_ eq $item_id } @{ $::form->{orderitem_ids} };
1063     my $item  = $self->order->items_sorted->[$idx];
1064     my $texts = get_part_texts($item->part, $self->order->language_id);
1065
1066     $item->description($texts->{description});
1067     $item->longdescription($texts->{longdescription});
1068
1069     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
1070
1071     my $price_src;
1072     if ($item->part->is_assortment) {
1073     # add assortment items with price 0, as the components carry the price
1074       $price_src = $price_source->price_from_source("");
1075       $price_src->price(0);
1076     } else {
1077       $price_src = $price_source->best_price
1078                  ? $price_source->best_price
1079                  : $price_source->price_from_source("");
1080       $price_src->price($::form->round_amount($price_src->price / $self->order->exchangerate, 5)) if $self->order->exchangerate;
1081       $price_src->price(0) if !$price_source->best_price;
1082     }
1083
1084
1085     $item->sellprice($price_src->price);
1086     $item->active_price_source($price_src);
1087
1088     $self->js
1089       ->run('kivi.Order.update_sellprice', $item_id, $item->sellprice_as_number)
1090       ->html('.row_entry:has(#item_' . $item_id . ') [name = "partnumber"] a', $item->part->partnumber)
1091       ->val ('.row_entry:has(#item_' . $item_id . ') [name = "order.orderitems[].description"]', $item->description)
1092       ->val ('.row_entry:has(#item_' . $item_id . ') [name = "order.orderitems[].longdescription"]', $item->longdescription);
1093
1094     if ($self->search_cvpartnumber) {
1095       $self->get_item_cvpartnumber($item);
1096       $self->js->html('.row_entry:has(#item_' . $item_id . ') [name = "cvpartnumber"]', $item->{cvpartnumber});
1097     }
1098   }
1099
1100   $self->recalc();
1101   $self->js_redisplay_line_values;
1102   $self->js_redisplay_amounts_and_taxes;
1103
1104   $self->js->render();
1105 }
1106
1107 sub js_load_second_row {
1108   my ($self, $item, $item_id, $do_parse) = @_;
1109
1110   if ($do_parse) {
1111     # Parse values from form (they are formated while rendering (template)).
1112     # Workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
1113     # This parsing is not necessary at all, if we assure that the second row/cvars are only loaded once.
1114     foreach my $var (@{ $item->cvars_by_config }) {
1115       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
1116     }
1117     $item->parse_custom_variable_values;
1118   }
1119
1120   my $row_as_html = $self->p->render('order/tabs/_second_row', ITEM => $item, TYPE => $self->type);
1121
1122   $self->js
1123     ->html('#second_row_' . $item_id, $row_as_html)
1124     ->data('#second_row_' . $item_id, 'loaded', 1);
1125 }
1126
1127 sub js_redisplay_line_values {
1128   my ($self) = @_;
1129
1130   my $is_sales = $self->order->is_sales;
1131
1132   # sales orders with margins
1133   my @data;
1134   if ($is_sales) {
1135     @data = map {
1136       [
1137        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
1138        $::form->format_amount(\%::myconfig, $_->{marge_total},   2, 0),
1139        $::form->format_amount(\%::myconfig, $_->{marge_percent}, 2, 0),
1140       ]} @{ $self->order->items_sorted };
1141   } else {
1142     @data = map {
1143       [
1144        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
1145       ]} @{ $self->order->items_sorted };
1146   }
1147
1148   $self->js
1149     ->run('kivi.Order.redisplay_line_values', $is_sales, \@data);
1150 }
1151
1152 sub js_redisplay_amounts_and_taxes {
1153   my ($self) = @_;
1154
1155   if (scalar @{ $self->{taxes} }) {
1156     $self->js->show('#taxincluded_row_id');
1157   } else {
1158     $self->js->hide('#taxincluded_row_id');
1159   }
1160
1161   if ($self->order->taxincluded) {
1162     $self->js->hide('#subtotal_row_id');
1163   } else {
1164     $self->js->show('#subtotal_row_id');
1165   }
1166
1167   if ($self->order->is_sales) {
1168     my $is_neg = $self->order->marge_total < 0;
1169     $self->js
1170       ->html('#marge_total_id',   $::form->format_amount(\%::myconfig, $self->order->marge_total,   2))
1171       ->html('#marge_percent_id', $::form->format_amount(\%::myconfig, $self->order->marge_percent, 2))
1172       ->action_if( $is_neg, 'addClass',    '#marge_total_id',        'plus0')
1173       ->action_if( $is_neg, 'addClass',    '#marge_percent_id',      'plus0')
1174       ->action_if( $is_neg, 'addClass',    '#marge_percent_sign_id', 'plus0')
1175       ->action_if(!$is_neg, 'removeClass', '#marge_total_id',        'plus0')
1176       ->action_if(!$is_neg, 'removeClass', '#marge_percent_id',      'plus0')
1177       ->action_if(!$is_neg, 'removeClass', '#marge_percent_sign_id', 'plus0');
1178   }
1179
1180   $self->js
1181     ->html('#netamount_id', $::form->format_amount(\%::myconfig, $self->order->netamount, -2))
1182     ->html('#amount_id',    $::form->format_amount(\%::myconfig, $self->order->amount,    -2))
1183     ->remove('.tax_row')
1184     ->insertBefore($self->build_tax_rows, '#amount_row_id');
1185 }
1186
1187 sub js_redisplay_cvpartnumbers {
1188   my ($self) = @_;
1189
1190   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
1191
1192   my @data = map {[$_->{cvpartnumber}]} @{ $self->order->items_sorted };
1193
1194   $self->js
1195     ->run('kivi.Order.redisplay_cvpartnumbers', \@data);
1196 }
1197
1198 sub js_reset_order_and_item_ids_after_save {
1199   my ($self) = @_;
1200
1201   $self->js
1202     ->val('#id', $self->order->id)
1203     ->val('#converted_from_oe_id', '')
1204     ->val('#order_' . $self->nr_key(), $self->order->number);
1205
1206   my $idx = 0;
1207   foreach my $form_item_id (@{ $::form->{orderitem_ids} }) {
1208     next if !$self->order->items_sorted->[$idx]->id;
1209     next if $form_item_id !~ m{^new};
1210     $self->js
1211       ->val ('[name="orderitem_ids[+]"][value="' . $form_item_id . '"]', $self->order->items_sorted->[$idx]->id)
1212       ->val ('#item_' . $form_item_id, $self->order->items_sorted->[$idx]->id)
1213       ->attr('#item_' . $form_item_id, "id", 'item_' . $self->order->items_sorted->[$idx]->id);
1214   } continue {
1215     $idx++;
1216   }
1217   $self->js->val('[name="converted_from_orderitems_ids[+]"]', '');
1218 }
1219
1220 #
1221 # helpers
1222 #
1223
1224 sub init_valid_types {
1225   [ sales_order_type(), purchase_order_type(), sales_quotation_type(), request_quotation_type() ];
1226 }
1227
1228 sub init_type {
1229   my ($self) = @_;
1230
1231   if (none { $::form->{type} eq $_ } @{$self->valid_types}) {
1232     die "Not a valid type for order";
1233   }
1234
1235   $self->type($::form->{type});
1236 }
1237
1238 sub init_cv {
1239   my ($self) = @_;
1240
1241   my $cv = (any { $self->type eq $_ } (sales_order_type(),    sales_quotation_type()))   ? 'customer'
1242          : (any { $self->type eq $_ } (purchase_order_type(), request_quotation_type())) ? 'vendor'
1243          : die "Not a valid type for order";
1244
1245   return $cv;
1246 }
1247
1248 sub init_search_cvpartnumber {
1249   my ($self) = @_;
1250
1251   my $user_prefs = SL::Helper::UserPreferences::PartPickerSearch->new();
1252   my $search_cvpartnumber;
1253   $search_cvpartnumber = !!$user_prefs->get_sales_search_customer_partnumber() if $self->cv eq 'customer';
1254   $search_cvpartnumber = !!$user_prefs->get_purchase_search_makemodel()        if $self->cv eq 'vendor';
1255
1256   return $search_cvpartnumber;
1257 }
1258
1259 sub init_show_update_button {
1260   my ($self) = @_;
1261
1262   !!SL::Helper::UserPreferences::UpdatePositions->new()->get_show_update_button();
1263 }
1264
1265 sub init_p {
1266   SL::Presenter->get;
1267 }
1268
1269 sub init_order {
1270   $_[0]->make_order;
1271 }
1272
1273 sub init_all_price_factors {
1274   SL::DB::Manager::PriceFactor->get_all;
1275 }
1276
1277 sub init_part_picker_classification_ids {
1278   my ($self)    = @_;
1279   my $attribute = 'used_for_' . ($self->type =~ m{sales} ? 'sale' : 'purchase');
1280
1281   return [ map { $_->id } @{ SL::DB::Manager::PartClassification->get_all(where => [ $attribute => 1 ]) } ];
1282 }
1283
1284 sub check_auth {
1285   my ($self) = @_;
1286
1287   my $right_for = { map { $_ => $_.'_edit' } @{$self->valid_types} };
1288
1289   my $right   = $right_for->{ $self->type };
1290   $right    ||= 'DOES_NOT_EXIST';
1291
1292   $::auth->assert($right);
1293 }
1294
1295 # build the selection box for contacts
1296 #
1297 # Needed, if customer/vendor changed.
1298 sub build_contact_select {
1299   my ($self) = @_;
1300
1301   select_tag('order.cp_id', [ $self->order->{$self->cv}->contacts ],
1302     value_key  => 'cp_id',
1303     title_key  => 'full_name_dep',
1304     default    => $self->order->cp_id,
1305     with_empty => 1,
1306     style      => 'width: 300px',
1307   );
1308 }
1309
1310 # build the selection box for shiptos
1311 #
1312 # Needed, if customer/vendor changed.
1313 sub build_shipto_select {
1314   my ($self) = @_;
1315
1316   select_tag('order.shipto_id',
1317              [ {displayable_id => t8("No/individual shipping address"), shipto_id => ''}, $self->order->{$self->cv}->shipto ],
1318              value_key  => 'shipto_id',
1319              title_key  => 'displayable_id',
1320              default    => $self->order->shipto_id,
1321              with_empty => 0,
1322              style      => 'width: 300px',
1323   );
1324 }
1325
1326 # build the inputs for the cusom shipto dialog
1327 #
1328 # Needed, if customer/vendor changed.
1329 sub build_shipto_inputs {
1330   my ($self) = @_;
1331
1332   my $content = $self->p->render('common/_ship_to_dialog',
1333                                  vc_obj      => $self->order->customervendor,
1334                                  cs_obj      => $self->order->custom_shipto,
1335                                  cvars       => $self->order->custom_shipto->cvars_by_config,
1336                                  id_selector => '#order_shipto_id');
1337
1338   div_tag($content, id => 'shipto_inputs');
1339 }
1340
1341 # render the info line for business
1342 #
1343 # Needed, if customer/vendor changed.
1344 sub build_business_info_row
1345 {
1346   $_[0]->p->render('order/tabs/_business_info_row', SELF => $_[0]);
1347 }
1348
1349 # build the rows for displaying taxes
1350 #
1351 # Called if amounts where recalculated and redisplayed.
1352 sub build_tax_rows {
1353   my ($self) = @_;
1354
1355   my $rows_as_html;
1356   foreach my $tax (sort { $a->{tax}->rate cmp $b->{tax}->rate } @{ $self->{taxes} }) {
1357     $rows_as_html .= $self->p->render('order/tabs/_tax_row', TAX => $tax, TAXINCLUDED => $self->order->taxincluded);
1358   }
1359   return $rows_as_html;
1360 }
1361
1362
1363 sub render_price_dialog {
1364   my ($self, $record_item) = @_;
1365
1366   my $price_source = SL::PriceSource->new(record_item => $record_item, record => $self->order);
1367
1368   $self->js
1369     ->run(
1370       'kivi.io.price_chooser_dialog',
1371       t8('Available Prices'),
1372       $self->render('order/tabs/_price_sources_dialog', { output => 0 }, price_source => $price_source)
1373     )
1374     ->reinit_widgets;
1375
1376 #   if (@errors) {
1377 #     $self->js->text('#dialog_flash_error_content', join ' ', @errors);
1378 #     $self->js->show('#dialog_flash_error');
1379 #   }
1380
1381   $self->js->render;
1382 }
1383
1384 sub load_order {
1385   my ($self) = @_;
1386
1387   return if !$::form->{id};
1388
1389   $self->order(SL::DB::Order->new(id => $::form->{id})->load);
1390
1391   # Add an empty custom shipto to the order, so that the dialog can render the cvar inputs.
1392   # You need a custom shipto object to call cvars_by_config to get the cvars.
1393   $self->order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => [])) if !$self->order->custom_shipto;
1394
1395   return $self->order;
1396 }
1397
1398 # load or create a new order object
1399 #
1400 # And assign changes from the form to this object.
1401 # If the order is loaded from db, check if items are deleted in the form,
1402 # remove them form the object and collect them for removing from db on saving.
1403 # Then create/update items from form (via make_item) and add them.
1404 sub make_order {
1405   my ($self) = @_;
1406
1407   # add_items adds items to an order with no items for saving, but they cannot
1408   # be retrieved via items until the order is saved. Adding empty items to new
1409   # order here solves this problem.
1410   my $order;
1411   $order   = SL::DB::Order->new(id => $::form->{id})->load(with => [ 'orderitems', 'orderitems.part' ]) if $::form->{id};
1412   $order ||= SL::DB::Order->new(orderitems  => [],
1413                                 quotation   => (any { $self->type eq $_ } (sales_quotation_type(), request_quotation_type())),
1414                                 currency_id => $::instance_conf->get_currency_id(),);
1415
1416   my $cv_id_method = $self->cv . '_id';
1417   if (!$::form->{id} && $::form->{$cv_id_method}) {
1418     $order->$cv_id_method($::form->{$cv_id_method});
1419     setup_order_from_cv($order);
1420   }
1421
1422   my $form_orderitems                  = delete $::form->{order}->{orderitems};
1423   my $form_periodic_invoices_config    = delete $::form->{order}->{periodic_invoices_config};
1424
1425   $order->assign_attributes(%{$::form->{order}});
1426
1427   $self->setup_custom_shipto_from_form($order, $::form);
1428
1429   if (my $periodic_invoices_config_attrs = $form_periodic_invoices_config ? SL::YAML::Load($form_periodic_invoices_config) : undef) {
1430     my $periodic_invoices_config = $order->periodic_invoices_config || $order->periodic_invoices_config(SL::DB::PeriodicInvoicesConfig->new);
1431     $periodic_invoices_config->assign_attributes(%$periodic_invoices_config_attrs);
1432   }
1433
1434   # remove deleted items
1435   $self->item_ids_to_delete([]);
1436   foreach my $idx (reverse 0..$#{$order->orderitems}) {
1437     my $item = $order->orderitems->[$idx];
1438     if (none { $item->id == $_->{id} } @{$form_orderitems}) {
1439       splice @{$order->orderitems}, $idx, 1;
1440       push @{$self->item_ids_to_delete}, $item->id;
1441     }
1442   }
1443
1444   my @items;
1445   my $pos = 1;
1446   foreach my $form_attr (@{$form_orderitems}) {
1447     my $item = make_item($order, $form_attr);
1448     $item->position($pos);
1449     push @items, $item;
1450     $pos++;
1451   }
1452   $order->add_items(grep {!$_->id} @items);
1453
1454   return $order;
1455 }
1456
1457 # create or update items from form
1458 #
1459 # Make item objects from form values. For items already existing read from db.
1460 # Create a new item else. And assign attributes.
1461 sub make_item {
1462   my ($record, $attr) = @_;
1463
1464   my $item;
1465   $item = first { $_->id == $attr->{id} } @{$record->items} if $attr->{id};
1466
1467   my $is_new = !$item;
1468
1469   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1470   # they cannot be retrieved via custom_variables until the order/orderitem is
1471   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1472   $item ||= SL::DB::OrderItem->new(custom_variables => []);
1473
1474   $item->assign_attributes(%$attr);
1475
1476   if ($is_new) {
1477     my $texts = get_part_texts($item->part, $record->language_id);
1478     $item->longdescription($texts->{longdescription})              if !defined $attr->{longdescription};
1479     $item->project_id($record->globalproject_id)                   if !defined $attr->{project_id};
1480     $item->lastcost($record->is_sales ? $item->part->lastcost : 0) if !defined $attr->{lastcost_as_number};
1481   }
1482
1483   return $item;
1484 }
1485
1486 # create a new item
1487 #
1488 # This is used to add one item
1489 sub new_item {
1490   my ($record, $attr) = @_;
1491
1492   my $item = SL::DB::OrderItem->new;
1493
1494   # Remove attributes where the user left or set the inputs empty.
1495   # So these attributes will be undefined and we can distinguish them
1496   # from zero later on.
1497   for (qw(qty_as_number sellprice_as_number discount_as_percent)) {
1498     delete $attr->{$_} if $attr->{$_} eq '';
1499   }
1500
1501   $item->assign_attributes(%$attr);
1502
1503   my $part         = SL::DB::Part->new(id => $attr->{parts_id})->load;
1504   my $price_source = SL::PriceSource->new(record_item => $item, record => $record);
1505
1506   $item->unit($part->unit) if !$item->unit;
1507
1508   my $price_src;
1509   if ( $part->is_assortment ) {
1510     # add assortment items with price 0, as the components carry the price
1511     $price_src = $price_source->price_from_source("");
1512     $price_src->price(0);
1513   } elsif (defined $item->sellprice) {
1514     $price_src = $price_source->price_from_source("");
1515     $price_src->price($item->sellprice);
1516   } else {
1517     $price_src = $price_source->best_price
1518                ? $price_source->best_price
1519                : $price_source->price_from_source("");
1520     $price_src->price($::form->round_amount($price_src->price / $record->exchangerate, 5)) if $record->exchangerate;
1521     $price_src->price(0) if !$price_source->best_price;
1522   }
1523
1524   my $discount_src;
1525   if (defined $item->discount) {
1526     $discount_src = $price_source->discount_from_source("");
1527     $discount_src->discount($item->discount);
1528   } else {
1529     $discount_src = $price_source->best_discount
1530                   ? $price_source->best_discount
1531                   : $price_source->discount_from_source("");
1532     $discount_src->discount(0) if !$price_source->best_discount;
1533   }
1534
1535   my %new_attr;
1536   $new_attr{part}                   = $part;
1537   $new_attr{description}            = $part->description     if ! $item->description;
1538   $new_attr{qty}                    = 1.0                    if ! $item->qty;
1539   $new_attr{price_factor_id}        = $part->price_factor_id if ! $item->price_factor_id;
1540   $new_attr{sellprice}              = $price_src->price;
1541   $new_attr{discount}               = $discount_src->discount;
1542   $new_attr{active_price_source}    = $price_src;
1543   $new_attr{active_discount_source} = $discount_src;
1544   $new_attr{longdescription}        = $part->notes           if ! defined $attr->{longdescription};
1545   $new_attr{project_id}             = $record->globalproject_id;
1546   $new_attr{lastcost}               = $record->is_sales ? $part->lastcost : 0;
1547
1548   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1549   # they cannot be retrieved via custom_variables until the order/orderitem is
1550   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1551   $new_attr{custom_variables} = [];
1552
1553   my $texts = get_part_texts($part, $record->language_id, description => $new_attr{description}, longdescription => $new_attr{longdescription});
1554
1555   $item->assign_attributes(%new_attr, %{ $texts });
1556
1557   return $item;
1558 }
1559
1560 sub setup_order_from_cv {
1561   my ($order) = @_;
1562
1563   $order->$_($order->customervendor->$_) for (qw(taxzone_id payment_id delivery_term_id currency_id));
1564
1565   $order->intnotes($order->customervendor->notes);
1566
1567   if ($order->is_sales) {
1568     $order->salesman_id($order->customer->salesman_id || SL::DB::Manager::Employee->current->id);
1569     $order->taxincluded(defined($order->customer->taxincluded_checked)
1570                         ? $order->customer->taxincluded_checked
1571                         : $::myconfig{taxincluded_checked});
1572   }
1573
1574 }
1575
1576 # setup custom shipto from form
1577 #
1578 # The dialog returns form variables starting with 'shipto' and cvars starting
1579 # with 'shiptocvar_'.
1580 # Mark it to be deleted if a shipto from master data is selected
1581 # (i.e. order has a shipto).
1582 # Else, update or create a new custom shipto. If the fields are empty, it
1583 # will not be saved on save.
1584 sub setup_custom_shipto_from_form {
1585   my ($self, $order, $form) = @_;
1586
1587   if ($order->shipto) {
1588     $self->is_custom_shipto_to_delete(1);
1589   } else {
1590     my $custom_shipto = $order->custom_shipto || $order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => []));
1591
1592     my $shipto_cvars  = {map { my ($key) = m{^shiptocvar_(.+)}; $key => delete $form->{$_}} grep { m{^shiptocvar_} } keys %$form};
1593     my $shipto_attrs  = {map {                                  $_   => delete $form->{$_}} grep { m{^shipto}      } keys %$form};
1594
1595     $custom_shipto->assign_attributes(%$shipto_attrs);
1596     $custom_shipto->cvar_by_name($_)->value($shipto_cvars->{$_}) for keys %$shipto_cvars;
1597   }
1598 }
1599
1600 # recalculate prices and taxes
1601 #
1602 # Using the PriceTaxCalculator. Store linetotals in the item objects.
1603 sub recalc {
1604   my ($self) = @_;
1605
1606   my %pat = $self->order->calculate_prices_and_taxes();
1607
1608   $self->{taxes} = [];
1609   foreach my $tax_id (keys %{ $pat{taxes_by_tax_id} }) {
1610     my $netamount = sum0 map { $pat{amounts}->{$_}->{amount} } grep { $pat{amounts}->{$_}->{tax_id} == $tax_id } keys %{ $pat{amounts} };
1611
1612     push(@{ $self->{taxes} }, { amount    => $pat{taxes_by_tax_id}->{$tax_id},
1613                                 netamount => $netamount,
1614                                 tax       => SL::DB::Tax->new(id => $tax_id)->load });
1615   }
1616   pairwise { $a->{linetotal} = $b->{linetotal} } @{$self->order->items_sorted}, @{$pat{items}};
1617 }
1618
1619 # get data for saving, printing, ..., that is not changed in the form
1620 #
1621 # Only cvars for now.
1622 sub get_unalterable_data {
1623   my ($self) = @_;
1624
1625   foreach my $item (@{ $self->order->items }) {
1626     # autovivify all cvars that are not in the form (cvars_by_config can do it).
1627     # workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
1628     foreach my $var (@{ $item->cvars_by_config }) {
1629       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
1630     }
1631     $item->parse_custom_variable_values;
1632   }
1633 }
1634
1635 # delete the order
1636 #
1637 # And remove related files in the spool directory
1638 sub delete {
1639   my ($self) = @_;
1640
1641   my $errors = [];
1642   my $db     = $self->order->db;
1643
1644   $db->with_transaction(
1645     sub {
1646       my @spoolfiles = grep { $_ } map { $_->spoolfile } @{ SL::DB::Manager::Status->get_all(where => [ trans_id => $self->order->id ]) };
1647       $self->order->delete;
1648       my $spool = $::lx_office_conf{paths}->{spool};
1649       unlink map { "$spool/$_" } @spoolfiles if $spool;
1650
1651       $self->save_history('DELETED');
1652
1653       1;
1654   }) || push(@{$errors}, $db->error);
1655
1656   return $errors;
1657 }
1658
1659 # save the order
1660 #
1661 # And delete items that are deleted in the form.
1662 sub save {
1663   my ($self) = @_;
1664
1665   my $errors = [];
1666   my $db     = $self->order->db;
1667
1668   $db->with_transaction(sub {
1669     # delete custom shipto if it is to be deleted or if it is empty
1670     if ($self->order->custom_shipto && ($self->is_custom_shipto_to_delete || $self->order->custom_shipto->is_empty)) {
1671       $self->order->custom_shipto->delete if $self->order->custom_shipto->shipto_id;
1672       $self->order->custom_shipto(undef);
1673     }
1674
1675     SL::DB::OrderItem->new(id => $_)->delete for @{$self->item_ids_to_delete || []};
1676     $self->order->save(cascade => 1);
1677
1678     # link records
1679     if ($::form->{converted_from_oe_id}) {
1680       my @converted_from_oe_ids = split ' ', $::form->{converted_from_oe_id};
1681       foreach my $converted_from_oe_id (@converted_from_oe_ids) {
1682         my $src = SL::DB::Order->new(id => $converted_from_oe_id)->load;
1683         $src->update_attributes(closed => 1) if $src->type =~ /_quotation$/;
1684         $src->link_to_record($self->order);
1685       }
1686       if (scalar @{ $::form->{converted_from_orderitems_ids} || [] }) {
1687         my $idx = 0;
1688         foreach (@{ $self->order->items_sorted }) {
1689           my $from_id = $::form->{converted_from_orderitems_ids}->[$idx];
1690           next if !$from_id;
1691           SL::DB::RecordLink->new(from_table => 'orderitems',
1692                                   from_id    => $from_id,
1693                                   to_table   => 'orderitems',
1694                                   to_id      => $_->id
1695           )->save;
1696           $idx++;
1697         }
1698       }
1699     }
1700
1701     $self->save_history('SAVED');
1702
1703     1;
1704   }) || push(@{$errors}, $db->error);
1705
1706   return $errors;
1707 }
1708
1709 sub workflow_sales_or_request_for_quotation {
1710   my ($self) = @_;
1711
1712   # always save
1713   my $errors = $self->save();
1714
1715   if (scalar @{ $errors }) {
1716     $self->js->flash('error', $_) for @{ $errors };
1717     return $self->js->render();
1718   }
1719
1720   my $destination_type = $::form->{type} eq sales_order_type() ? sales_quotation_type() : request_quotation_type();
1721
1722   $self->order(SL::DB::Order->new_from($self->order, destination_type => $destination_type));
1723   $self->{converted_from_oe_id} = delete $::form->{id};
1724
1725   # set item ids to new fake id, to identify them as new items
1726   foreach my $item (@{$self->order->items_sorted}) {
1727     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1728   }
1729
1730   # change form type
1731   $::form->{type} = $destination_type;
1732   $self->type($self->init_type);
1733   $self->cv  ($self->init_cv);
1734   $self->check_auth;
1735
1736   $self->recalc();
1737   $self->get_unalterable_data();
1738   $self->pre_render();
1739
1740   # trigger rendering values for second row as hidden, because they
1741   # are loaded only on demand. So we need to keep the values from the
1742   # source.
1743   $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
1744
1745   $self->render(
1746     'order/form',
1747     title => $self->get_title_for('edit'),
1748     %{$self->{template_args}}
1749   );
1750 }
1751
1752 sub workflow_sales_or_purchase_order {
1753   my ($self) = @_;
1754
1755   # always save
1756   my $errors = $self->save();
1757
1758   if (scalar @{ $errors }) {
1759     $self->js->flash('error', $_) foreach @{ $errors };
1760     return $self->js->render();
1761   }
1762
1763   my $destination_type = $::form->{type} eq sales_quotation_type()   ? sales_order_type()
1764                        : $::form->{type} eq request_quotation_type() ? purchase_order_type()
1765                        : $::form->{type} eq purchase_order_type()    ? sales_order_type()
1766                        : $::form->{type} eq sales_order_type()       ? purchase_order_type()
1767                        : '';
1768
1769   # check for direct delivery
1770   # copy shipto in custom shipto (custom shipto will be copied by new_from() in case)
1771   my $custom_shipto;
1772   if (   $::form->{type} eq sales_order_type() && $destination_type eq purchase_order_type()
1773       && $::form->{use_shipto} && $self->order->shipto) {
1774     $custom_shipto = $self->order->shipto->clone('SL::DB::Order');
1775   }
1776
1777   $self->order(SL::DB::Order->new_from($self->order, destination_type => $destination_type));
1778   $self->{converted_from_oe_id} = delete $::form->{id};
1779
1780   # set item ids to new fake id, to identify them as new items
1781   foreach my $item (@{$self->order->items_sorted}) {
1782     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1783   }
1784
1785   if ($::form->{type} eq sales_order_type() && $destination_type eq purchase_order_type()) {
1786     if ($::form->{use_shipto}) {
1787       $self->order->custom_shipto($custom_shipto) if $custom_shipto;
1788     } else {
1789       # remove any custom shipto if not wanted
1790       $self->order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => []));
1791     }
1792   }
1793
1794   # change form type
1795   $::form->{type} = $destination_type;
1796   $self->type($self->init_type);
1797   $self->cv  ($self->init_cv);
1798   $self->check_auth;
1799
1800   $self->recalc();
1801   $self->get_unalterable_data();
1802   $self->pre_render();
1803
1804   # trigger rendering values for second row as hidden, because they
1805   # are loaded only on demand. So we need to keep the values from the
1806   # source.
1807   $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
1808
1809   $self->render(
1810     'order/form',
1811     title => $self->get_title_for('edit'),
1812     %{$self->{template_args}}
1813   );
1814 }
1815
1816
1817 sub pre_render {
1818   my ($self) = @_;
1819
1820   $self->{all_taxzones}               = SL::DB::Manager::TaxZone->get_all_sorted();
1821   $self->{all_currencies}             = SL::DB::Manager::Currency->get_all_sorted();
1822   $self->{all_departments}            = SL::DB::Manager::Department->get_all_sorted();
1823   $self->{all_languages}              = SL::DB::Manager::Language->get_all_sorted();
1824   $self->{all_employees}              = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->employee_id,
1825                                                                                               deleted => 0 ] ],
1826                                                                            sort_by => 'name');
1827   $self->{all_salesmen}               = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->salesman_id,
1828                                                                                               deleted => 0 ] ],
1829                                                                            sort_by => 'name');
1830   $self->{all_payment_terms}          = SL::DB::Manager::PaymentTerm->get_all_sorted(where => [ or => [ id => $self->order->payment_id,
1831                                                                                                         obsolete => 0 ] ]);
1832   $self->{all_delivery_terms}         = SL::DB::Manager::DeliveryTerm->get_all_sorted();
1833   $self->{current_employee_id}        = SL::DB::Manager::Employee->current->id;
1834   $self->{periodic_invoices_status}   = $self->get_periodic_invoices_status($self->order->periodic_invoices_config);
1835   $self->{order_probabilities}        = [ map { { title => ($_ * 10) . '%', id => $_ * 10 } } (0..10) ];
1836   $self->{positions_scrollbar_height} = SL::Helper::UserPreferences::PositionsScrollbar->new()->get_height();
1837
1838   my $print_form = Form->new('');
1839   $print_form->{type}        = $self->type;
1840   $print_form->{printers}    = SL::DB::Manager::Printer->get_all_sorted;
1841   $self->{print_options}     = SL::Helper::PrintOptions->get_print_options(
1842     form => $print_form,
1843     options => {dialog_name_prefix => 'print_options.',
1844                 show_headers       => 1,
1845                 no_queue           => 1,
1846                 no_postscript      => 1,
1847                 no_opendocument    => 0,
1848                 no_html            => 1},
1849   );
1850
1851   foreach my $item (@{$self->order->orderitems}) {
1852     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
1853     $item->active_price_source(   $price_source->price_from_source(   $item->active_price_source   ));
1854     $item->active_discount_source($price_source->discount_from_source($item->active_discount_source));
1855   }
1856
1857   if (any { $self->type eq $_ } (sales_order_type(), purchase_order_type())) {
1858     # Calculate shipped qtys here to prevent calling calculate for every item via the items method.
1859     # Do not use write_to_objects to prevent order->delivered to be set, because this should be
1860     # the value from db, which can be set manually or is set when linked delivery orders are saved.
1861     SL::Helper::ShippedQty->new->calculate($self->order)->write_to(\@{$self->order->items});
1862   }
1863
1864   if ($self->order->number && $::instance_conf->get_webdav) {
1865     my $webdav = SL::Webdav->new(
1866       type     => $self->type,
1867       number   => $self->order->number,
1868     );
1869     my @all_objects = $webdav->get_all_objects;
1870     @{ $self->{template_args}->{WEBDAV} } = map { { name => $_->filename,
1871                                                     type => t8('File'),
1872                                                     link => File::Spec->catfile($_->full_filedescriptor),
1873                                                 } } @all_objects;
1874   }
1875
1876   if (   (any { $self->type eq $_ } (sales_quotation_type(), sales_order_type()))
1877       && $::instance_conf->get_transport_cost_reminder_article_number_id ) {
1878     $self->{template_args}->{transport_cost_reminder_article} = SL::DB::Part->new(id => $::instance_conf->get_transport_cost_reminder_article_number_id)->load;
1879   }
1880
1881   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
1882
1883   $::request->{layout}->use_javascript("${_}.js") for qw(kivi.SalesPurchase kivi.Order kivi.File ckeditor/ckeditor ckeditor/adapters/jquery
1884                                                          edit_periodic_invoices_config calculate_qty kivi.Validator follow_up show_history);
1885   $self->setup_edit_action_bar;
1886 }
1887
1888 sub setup_edit_action_bar {
1889   my ($self, %params) = @_;
1890
1891   my $deletion_allowed = (any { $self->type eq $_ } (sales_quotation_type(), request_quotation_type()))
1892                       || (($self->type eq sales_order_type())    && $::instance_conf->get_sales_order_show_delete)
1893                       || (($self->type eq purchase_order_type()) && $::instance_conf->get_purchase_order_show_delete);
1894
1895   my @req_trans_cost_art = qw(kivi.Order.check_transport_cost_article_presence) x!!$::instance_conf->get_transport_cost_reminder_article_number_id;
1896   my @req_cusordnumber   = qw(kivi.Order.check_cusordnumber_presence)           x($self->type eq sales_order_type() && $::instance_conf->get_order_warn_no_cusordnumber);
1897
1898   for my $bar ($::request->layout->get('actionbar')) {
1899     $bar->add(
1900       combobox => [
1901         action => [
1902           t8('Save'),
1903           call      => [ 'kivi.Order.save', 'save', $::instance_conf->get_order_warn_duplicate_parts,
1904                                                     $::instance_conf->get_order_warn_no_deliverydate,
1905           ],
1906           checks    => [ 'kivi.Order.check_save_active_periodic_invoices', ['kivi.validate_form','#order_form'],
1907                          @req_trans_cost_art, @req_cusordnumber,
1908           ],
1909         ],
1910         action => [
1911           t8('Save as new'),
1912           call      => [ 'kivi.Order.save', 'save_as_new', $::instance_conf->get_order_warn_duplicate_parts ],
1913           checks    => [ 'kivi.Order.check_save_active_periodic_invoices',
1914                          @req_trans_cost_art, @req_cusordnumber,
1915           ],
1916           disabled  => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1917         ],
1918       ], # end of combobox "Save"
1919
1920       combobox => [
1921         action => [
1922           t8('Workflow'),
1923         ],
1924         action => [
1925           t8('Save and Quotation'),
1926           submit   => [ '#order_form', { action => "Order/sales_quotation" } ],
1927           checks   => [ @req_trans_cost_art, @req_cusordnumber ],
1928           only_if  => (any { $self->type eq $_ } (sales_order_type())),
1929         ],
1930         action => [
1931           t8('Save and RFQ'),
1932           submit   => [ '#order_form', { action => "Order/request_for_quotation" } ],
1933           only_if  => (any { $self->type eq $_ } (purchase_order_type())),
1934         ],
1935         action => [
1936           t8('Save and Sales Order'),
1937           submit   => [ '#order_form', { action => "Order/sales_order" } ],
1938           checks   => [ @req_trans_cost_art ],
1939           only_if  => (any { $self->type eq $_ } (sales_quotation_type(), purchase_order_type())),
1940         ],
1941         action => [
1942           t8('Save and Purchase Order'),
1943           call      => [ 'kivi.Order.purchase_order_check_for_direct_delivery' ],
1944           checks    => [ @req_trans_cost_art, @req_cusordnumber ],
1945           only_if   => (any { $self->type eq $_ } (sales_order_type(), request_quotation_type())),
1946         ],
1947         action => [
1948           t8('Save and Delivery Order'),
1949           call      => [ 'kivi.Order.save', 'save_and_delivery_order', $::instance_conf->get_order_warn_duplicate_parts,
1950                                                                        $::instance_conf->get_order_warn_no_deliverydate,
1951                                                                                                                         ],
1952           checks    => [ 'kivi.Order.check_save_active_periodic_invoices',
1953                          @req_trans_cost_art, @req_cusordnumber,
1954           ],
1955           only_if   => (any { $self->type eq $_ } (sales_order_type(), purchase_order_type()))
1956         ],
1957         action => [
1958           t8('Save and Invoice'),
1959           call      => [ 'kivi.Order.save', 'save_and_invoice', $::instance_conf->get_order_warn_duplicate_parts ],
1960           checks    => [ 'kivi.Order.check_save_active_periodic_invoices',
1961                          @req_trans_cost_art, @req_cusordnumber,
1962           ],
1963         ],
1964         action => [
1965           t8('Save and AP Transaction'),
1966           call      => [ 'kivi.Order.save', 'save_and_ap_transaction', $::instance_conf->get_order_warn_duplicate_parts ],
1967           only_if   => (any { $self->type eq $_ } (purchase_order_type()))
1968         ],
1969
1970       ], # end of combobox "Workflow"
1971
1972       combobox => [
1973         action => [
1974           t8('Export'),
1975         ],
1976         action => [
1977           t8('Save and preview PDF'),
1978           call   => [ 'kivi.Order.save', 'preview_pdf', $::instance_conf->get_order_warn_duplicate_parts,
1979                                                         $::instance_conf->get_order_warn_no_deliverydate,
1980                     ],
1981           checks => [ @req_trans_cost_art, @req_cusordnumber ],
1982         ],
1983         action => [
1984           t8('Save and print'),
1985           call   => [ 'kivi.Order.show_print_options', $::instance_conf->get_order_warn_duplicate_parts,
1986                                                        $::instance_conf->get_order_warn_no_deliverydate,
1987                     ],
1988           checks => [ @req_trans_cost_art, @req_cusordnumber ],
1989         ],
1990         action => [
1991           t8('Save and E-mail'),
1992           id   => 'save_and_email_action',
1993           call => [ 'kivi.Order.save', 'save_and_show_email_dialog', $::instance_conf->get_order_warn_duplicate_parts,
1994                                                                      $::instance_conf->get_order_warn_no_deliverydate,
1995                   ],
1996           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1997         ],
1998         action => [
1999           t8('Download attachments of all parts'),
2000           call     => [ 'kivi.File.downloadOrderitemsFiles', $::form->{type}, $::form->{id} ],
2001           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
2002           only_if  => $::instance_conf->get_doc_storage,
2003         ],
2004       ], # end of combobox "Export"
2005
2006       action => [
2007         t8('Delete'),
2008         call     => [ 'kivi.Order.delete_order' ],
2009         confirm  => $::locale->text('Do you really want to delete this object?'),
2010         disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
2011         only_if  => $deletion_allowed,
2012       ],
2013
2014       combobox => [
2015         action => [
2016           t8('more')
2017         ],
2018         action => [
2019           t8('History'),
2020           call     => [ 'set_history_window', $self->order->id, 'id' ],
2021           disabled => !$self->order->id ? t8('This record has not been saved yet.') : undef,
2022         ],
2023         action => [
2024           t8('Follow-Up'),
2025           call     => [ 'kivi.Order.follow_up_window' ],
2026           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
2027           only_if  => $::auth->assert('productivity', 1),
2028         ],
2029       ], # end of combobox "more"
2030     );
2031   }
2032 }
2033
2034 sub generate_pdf {
2035   my ($order, $pdf_ref, $params) = @_;
2036
2037   my @errors = ();
2038
2039   my $print_form = Form->new('');
2040   $print_form->{type}        = $order->type;
2041   $print_form->{formname}    = $params->{formname} || $order->type;
2042   $print_form->{format}      = $params->{format}   || 'pdf';
2043   $print_form->{media}       = $params->{media}    || 'file';
2044   $print_form->{groupitems}  = $params->{groupitems};
2045   $print_form->{printer_id}  = $params->{printer_id};
2046   $print_form->{media}       = 'file'                             if $print_form->{media} eq 'screen';
2047
2048   $order->language($params->{language});
2049   $order->flatten_to_form($print_form, format_amounts => 1);
2050
2051   my $template_ext;
2052   my $template_type;
2053   if ($print_form->{format} =~ /(opendocument|oasis)/i) {
2054     $template_ext  = 'odt';
2055     $template_type = 'OpenDocument';
2056   }
2057
2058   # search for the template
2059   my ($template_file, @template_files) = SL::Helper::CreatePDF->find_template(
2060     name        => $print_form->{formname},
2061     extension   => $template_ext,
2062     email       => $print_form->{media} eq 'email',
2063     language    => $params->{language},
2064     printer_id  => $print_form->{printer_id},
2065   );
2066
2067   if (!defined $template_file) {
2068     push @errors, $::locale->text('Cannot find matching template for this print request. Please contact your template maintainer. I tried these: #1.', join ', ', map { "'$_'"} @template_files);
2069   }
2070
2071   return @errors if scalar @errors;
2072
2073   $print_form->throw_on_error(sub {
2074     eval {
2075       $print_form->prepare_for_printing;
2076
2077       $$pdf_ref = SL::Helper::CreatePDF->create_pdf(
2078         format        => $print_form->{format},
2079         template_type => $template_type,
2080         template      => $template_file,
2081         variables     => $print_form,
2082         variable_content_types => {
2083           longdescription => 'html',
2084           partnotes       => 'html',
2085           notes           => 'html',
2086         },
2087       );
2088       1;
2089     } || push @errors, ref($EVAL_ERROR) eq 'SL::X::FormError' ? $EVAL_ERROR->error : $EVAL_ERROR;
2090   });
2091
2092   return @errors;
2093 }
2094
2095 sub get_files_for_email_dialog {
2096   my ($self) = @_;
2097
2098   my %files = map { ($_ => []) } qw(versions files vc_files part_files);
2099
2100   return %files if !$::instance_conf->get_doc_storage;
2101
2102   if ($self->order->id) {
2103     $files{versions} = [ SL::File->get_all_versions(object_id => $self->order->id,              object_type => $self->order->type, file_type => 'document') ];
2104     $files{files}    = [ SL::File->get_all(         object_id => $self->order->id,              object_type => $self->order->type, file_type => 'attachment') ];
2105     $files{vc_files} = [ SL::File->get_all(         object_id => $self->order->{$self->cv}->id, object_type => $self->cv,          file_type => 'attachment') ];
2106     $files{project_files} = [ SL::File->get_all(    object_id => $self->order->globalproject_id, object_type => 'project',         file_type => 'attachment') ];
2107   }
2108
2109   my @parts =
2110     uniq_by { $_->{id} }
2111     map {
2112       +{ id         => $_->part->id,
2113          partnumber => $_->part->partnumber }
2114     } @{$self->order->items_sorted};
2115
2116   foreach my $part (@parts) {
2117     my @pfiles = SL::File->get_all(object_id => $part->{id}, object_type => 'part');
2118     push @{ $files{part_files} }, map { +{ %{ $_ }, partnumber => $part->{partnumber} } } @pfiles;
2119   }
2120
2121   foreach my $key (keys %files) {
2122     $files{$key} = [ sort_by { lc $_->{db_file}->{file_name} } @{ $files{$key} } ];
2123   }
2124
2125   return %files;
2126 }
2127
2128 sub make_periodic_invoices_config_from_yaml {
2129   my ($yaml_config) = @_;
2130
2131   return if !$yaml_config;
2132   my $attr = SL::YAML::Load($yaml_config);
2133   return if 'HASH' ne ref $attr;
2134   return SL::DB::PeriodicInvoicesConfig->new(%$attr);
2135 }
2136
2137
2138 sub get_periodic_invoices_status {
2139   my ($self, $config) = @_;
2140
2141   return                      if $self->type ne sales_order_type();
2142   return t8('not configured') if !$config;
2143
2144   my $active = ('HASH' eq ref $config)                           ? $config->{active}
2145              : ('SL::DB::PeriodicInvoicesConfig' eq ref $config) ? $config->active
2146              :                                                     die "Cannot get status of periodic invoices config";
2147
2148   return $active ? t8('active') : t8('inactive');
2149 }
2150
2151 sub get_title_for {
2152   my ($self, $action) = @_;
2153
2154   return '' if none { lc($action)} qw(add edit);
2155
2156   # for locales:
2157   # $::locale->text("Add Sales Order");
2158   # $::locale->text("Add Purchase Order");
2159   # $::locale->text("Add Quotation");
2160   # $::locale->text("Add Request for Quotation");
2161   # $::locale->text("Edit Sales Order");
2162   # $::locale->text("Edit Purchase Order");
2163   # $::locale->text("Edit Quotation");
2164   # $::locale->text("Edit Request for Quotation");
2165
2166   $action = ucfirst(lc($action));
2167   return $self->type eq sales_order_type()       ? $::locale->text("$action Sales Order")
2168        : $self->type eq purchase_order_type()    ? $::locale->text("$action Purchase Order")
2169        : $self->type eq sales_quotation_type()   ? $::locale->text("$action Quotation")
2170        : $self->type eq request_quotation_type() ? $::locale->text("$action Request for Quotation")
2171        : '';
2172 }
2173
2174 sub get_item_cvpartnumber {
2175   my ($self, $item) = @_;
2176
2177   return if !$self->search_cvpartnumber;
2178   return if !$self->order->customervendor;
2179
2180   if ($self->cv eq 'vendor') {
2181     my @mms = grep { $_->make eq $self->order->customervendor->id } @{$item->part->makemodels};
2182     $item->{cvpartnumber} = $mms[0]->model if scalar @mms;
2183   } elsif ($self->cv eq 'customer') {
2184     my @cps = grep { $_->customer_id eq $self->order->customervendor->id } @{$item->part->customerprices};
2185     $item->{cvpartnumber} = $cps[0]->customer_partnumber if scalar @cps;
2186   }
2187 }
2188
2189 sub get_part_texts {
2190   my ($part_or_id, $language_or_id, %defaults) = @_;
2191
2192   my $part        = ref($part_or_id)     ? $part_or_id         : SL::DB::Part->load_cached($part_or_id);
2193   my $language_id = ref($language_or_id) ? $language_or_id->id : $language_or_id;
2194   my $texts       = {
2195     description     => $defaults{description}     // $part->description,
2196     longdescription => $defaults{longdescription} // $part->notes,
2197   };
2198
2199   return $texts unless $language_id;
2200
2201   my $translation = SL::DB::Manager::Translation->get_first(
2202     where => [
2203       parts_id    => $part->id,
2204       language_id => $language_id,
2205     ]);
2206
2207   $texts->{description}     = $translation->translation     if $translation && $translation->translation;
2208   $texts->{longdescription} = $translation->longdescription if $translation && $translation->longdescription;
2209
2210   return $texts;
2211 }
2212
2213 sub sales_order_type {
2214   'sales_order';
2215 }
2216
2217 sub purchase_order_type {
2218   'purchase_order';
2219 }
2220
2221 sub sales_quotation_type {
2222   'sales_quotation';
2223 }
2224
2225 sub request_quotation_type {
2226   'request_quotation';
2227 }
2228
2229 sub nr_key {
2230   return $_[0]->type eq sales_order_type()       ? 'ordnumber'
2231        : $_[0]->type eq purchase_order_type()    ? 'ordnumber'
2232        : $_[0]->type eq sales_quotation_type()   ? 'quonumber'
2233        : $_[0]->type eq request_quotation_type() ? 'quonumber'
2234        : '';
2235 }
2236
2237 sub save_and_redirect_to {
2238   my ($self, %params) = @_;
2239
2240   my $errors = $self->save();
2241
2242   if (scalar @{ $errors }) {
2243     $self->js->flash('error', $_) foreach @{ $errors };
2244     return $self->js->render();
2245   }
2246
2247   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
2248            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
2249            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
2250            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
2251            : '';
2252   flash_later('info', $text);
2253
2254   $self->redirect_to(%params, id => $self->order->id);
2255 }
2256
2257 sub save_history {
2258   my ($self, $addition) = @_;
2259
2260   my $number_type = $self->order->type =~ m{order} ? 'ordnumber' : 'quonumber';
2261   my $snumbers    = $number_type . '_' . $self->order->$number_type;
2262
2263   SL::DB::History->new(
2264     trans_id    => $self->order->id,
2265     employee_id => SL::DB::Manager::Employee->current->id,
2266     what_done   => $self->order->type,
2267     snumbers    => $snumbers,
2268     addition    => $addition,
2269   )->save;
2270 }
2271
2272 sub store_pdf_to_webdav_and_filemanagement {
2273   my($order, $content, $filename) = @_;
2274
2275   my @errors;
2276
2277   # copy file to webdav folder
2278   if ($order->number && $::instance_conf->get_webdav_documents) {
2279     my $webdav = SL::Webdav->new(
2280       type     => $order->type,
2281       number   => $order->number,
2282     );
2283     my $webdav_file = SL::Webdav::File->new(
2284       webdav   => $webdav,
2285       filename => $filename,
2286     );
2287     eval {
2288       $webdav_file->store(data => \$content);
2289       1;
2290     } or do {
2291       push @errors, t8('Storing PDF to webdav folder failed: #1', $@);
2292     };
2293   }
2294   if ($order->id && $::instance_conf->get_doc_storage) {
2295     eval {
2296       SL::File->save(object_id     => $order->id,
2297                      object_type   => $order->type,
2298                      mime_type     => 'application/pdf',
2299                      source        => 'created',
2300                      file_type     => 'document',
2301                      file_name     => $filename,
2302                      file_contents => $content);
2303       1;
2304     } or do {
2305       push @errors, t8('Storing PDF in storage backend failed: #1', $@);
2306     };
2307   }
2308
2309   return @errors;
2310 }
2311
2312 1;
2313
2314 __END__
2315
2316 =encoding utf-8
2317
2318 =head1 NAME
2319
2320 SL::Controller::Order - controller for orders
2321
2322 =head1 SYNOPSIS
2323
2324 This is a new form to enter orders, completely rewritten with the use
2325 of controller and java script techniques.
2326
2327 The aim is to provide the user a better experience and a faster workflow. Also
2328 the code should be more readable, more reliable and better to maintain.
2329
2330 =head2 Key Features
2331
2332 =over 4
2333
2334 =item *
2335
2336 One input row, so that input happens every time at the same place.
2337
2338 =item *
2339
2340 Use of pickers where possible.
2341
2342 =item *
2343
2344 Possibility to enter more than one item at once.
2345
2346 =item *
2347
2348 Item list in a scrollable area, so that the workflow buttons stay at
2349 the bottom.
2350
2351 =item *
2352
2353 Reordering item rows with drag and drop is possible. Sorting item rows is
2354 possible (by partnumber, description, qty, sellprice and discount for now).
2355
2356 =item *
2357
2358 No C<update> is necessary. All entries and calculations are managed
2359 with ajax-calls and the page only reloads on C<save>.
2360
2361 =item *
2362
2363 User can see changes immediately, because of the use of java script
2364 and ajax.
2365
2366 =back
2367
2368 =head1 CODE
2369
2370 =head2 Layout
2371
2372 =over 4
2373
2374 =item * C<SL/Controller/Order.pm>
2375
2376 the controller
2377
2378 =item * C<template/webpages/order/form.html>
2379
2380 main form
2381
2382 =item * C<template/webpages/order/tabs/basic_data.html>
2383
2384 Main tab for basic_data.
2385
2386 This is the only tab here for now. "linked records" and "webdav" tabs are
2387 reused from generic code.
2388
2389 =over 4
2390
2391 =item * C<template/webpages/order/tabs/_business_info_row.html>
2392
2393 For displaying information on business type
2394
2395 =item * C<template/webpages/order/tabs/_item_input.html>
2396
2397 The input line for items
2398
2399 =item * C<template/webpages/order/tabs/_row.html>
2400
2401 One row for already entered items
2402
2403 =item * C<template/webpages/order/tabs/_tax_row.html>
2404
2405 Displaying tax information
2406
2407 =item * C<template/webpages/order/tabs/_price_sources_dialog.html>
2408
2409 Dialog for selecting price and discount sources
2410
2411 =back
2412
2413 =item * C<js/kivi.Order.js>
2414
2415 java script functions
2416
2417 =back
2418
2419 =head1 TODO
2420
2421 =over 4
2422
2423 =item * testing
2424
2425 =item * price sources: little symbols showing better price / better discount
2426
2427 =item * select units in input row?
2428
2429 =item * check for direct delivery (workflow sales order -> purchase order)
2430
2431 =item * access rights
2432
2433 =item * display weights
2434
2435 =item * mtime check
2436
2437 =item * optional client/user behaviour
2438
2439 (transactions has to be set - department has to be set -
2440  force project if enabled in client config)
2441
2442 =back
2443
2444 =head1 KNOWN BUGS AND CAVEATS
2445
2446 =over 4
2447
2448 =item *
2449
2450 Customer discount is not displayed as a valid discount in price source popup
2451 (this might be a bug in price sources)
2452
2453 (I cannot reproduce this (Bernd))
2454
2455 =item *
2456
2457 No indication that <shift>-up/down expands/collapses second row.
2458
2459 =item *
2460
2461 Inline creation of parts is not currently supported
2462
2463 =item *
2464
2465 Table header is not sticky in the scrolling area.
2466
2467 =item *
2468
2469 Sorting does not include C<position>, neither does reordering.
2470
2471 This behavior was implemented intentionally. But we can discuss, which behavior
2472 should be implemented.
2473
2474 =back
2475
2476 =head1 To discuss / Nice to have
2477
2478 =over 4
2479
2480 =item *
2481
2482 How to expand/collapse second row. Now it can be done clicking the icon or
2483 <shift>-up/down.
2484
2485 =item *
2486
2487 Possibility to select PriceSources in input row?
2488
2489 =item *
2490
2491 This controller uses a (changed) copy of the template for the PriceSource
2492 dialog. Maybe there could be used one code source.
2493
2494 =item *
2495
2496 Rounding-differences between this controller (PriceTaxCalculator) and the old
2497 form. This is not only a problem here, but also in all parts using the PTC.
2498 There exists a ticket and a patch. This patch should be testet.
2499
2500 =item *
2501
2502 An indicator, if the actual inputs are saved (like in an
2503 editor or on text processing application).
2504
2505 =item *
2506
2507 A warning when leaving the page without saveing unchanged inputs.
2508
2509
2510 =back
2511
2512 =head1 AUTHOR
2513
2514 Bernd Bleßmann E<lt>bernd@kivitendo-premium.deE<gt>
2515
2516 =cut