SL/Controller/Order.pm

   1 package SL::Controller::Order;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use SL::Helper::Flash qw(flash_later);
   7 use SL::Presenter::Tag qw(select_tag hidden_tag);
   8 use SL::Locale::String qw(t8);
   9 use SL::SessionFile::Random;
  10 use SL::PriceSource;
  11 use SL::Webdav;
  12 use SL::File;
  13 use SL::MIME;
  14 use SL::Util qw(trim);
  15 use SL::YAML;
  16 use SL::DB::Order;
  17 use SL::DB::Default;
  18 use SL::DB::Unit;
  19 use SL::DB::Part;
  20 use SL::DB::PartsGroup;
  21 use SL::DB::Printer;
  22 use SL::DB::Language;
  23 use SL::DB::RecordLink;
  24
  25 use SL::Helper::CreatePDF qw(:all);
  26 use SL::Helper::PrintOptions;
  27 use SL::Helper::ShippedQty;
  28 use SL::Helper::UserPreferences::PositionsScrollbar;
  29 use SL::Helper::UserPreferences::UpdatePositions;
  30
  31 use SL::Controller::Helper::GetModels;
  32
  33 use List::Util qw(first);
  34 use List::UtilsBy qw(sort_by uniq_by);
  35 use List::MoreUtils qw(any none pairwise first_index);
  36 use English qw(-no_match_vars);
  37 use File::Spec;
  38 use Cwd;
  39 use Sort::Naturally;
  40
  41 use Rose::Object::MakeMethods::Generic
  42 (
  43  scalar => [ qw(item_ids_to_delete) ],
  44  'scalar --get_set_init' => [ qw(order valid_types type cv p multi_items_models all_price_factors search_cvpartnumber show_update_button) ],
  45 );
  46
  47
  48 # safety
  49 __PACKAGE__->run_before('check_auth');
  50
  51 __PACKAGE__->run_before('recalc',
  52                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice save_and_ap_transaction
  53                                      print send_email) ]);
  54
  55 __PACKAGE__->run_before('get_unalterable_data',
  56                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice save_and_ap_transaction
  57                                      print send_email) ]);
  58
  59 #
  60 # actions
  61 #
  62
  63 # add a new order
  64 sub action_add {
  65   my ($self) = @_;
  66
  67   $self->order->transdate(DateTime->now_local());
  68   my $extra_days = $self->{type} eq 'sales_quotation' ? $::instance_conf->get_reqdate_interval       :
  69                    $self->{type} eq 'sales_order'     ? $::instance_conf->get_delivery_date_interval : 1;
  70   $self->order->reqdate(DateTime->today_local->next_workday(extra_days => $extra_days)) if !$self->order->reqdate;
  71
  72
  73   $self->pre_render();
  74   $self->render(
  75     'order/form',
  76     title => $self->get_title_for('add'),
  77     %{$self->{template_args}}
  78   );
  79 }
  80
  81 # edit an existing order
  82 sub action_edit {
  83   my ($self) = @_;
  84
  85   if ($::form->{id}) {
  86     $self->load_order;
  87
  88   } else {
  89     # this is to edit an order from an unsaved order object
  90
  91     # set item ids to new fake id, to identify them as new items
  92     foreach my $item (@{$self->order->items_sorted}) {
  93       $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
  94     }
  95     # trigger rendering values for second row/longdescription as hidden,
  96     # because they are loaded only on demand. So we need to keep the values
  97     # from the source.
  98     $_->{render_second_row}      = 1 for @{ $self->order->items_sorted };
  99     $_->{render_longdescription} = 1 for @{ $self->order->items_sorted };
 100   }
 101
 102   $self->recalc();
 103   $self->pre_render();
 104   $self->render(
 105     'order/form',
 106     title => $self->get_title_for('edit'),
 107     %{$self->{template_args}}
 108   );
 109 }
 110
 111 # edit a collective order (consisting of one or more existing orders)
 112 sub action_edit_collective {
 113   my ($self) = @_;
 114
 115   # collect order ids
 116   my @multi_ids = map {
 117     $_ =~ m{^multi_id_(\d+)$} && $::form->{'multi_id_' . $1} && $::form->{'trans_id_' . $1} && $::form->{'trans_id_' . $1}
 118   } grep { $_ =~ m{^multi_id_\d+$} } keys %$::form;
 119
 120   # fall back to add if no ids are given
 121   if (scalar @multi_ids == 0) {
 122     $self->action_add();
 123     return;
 124   }
 125
 126   # fall back to save as new if only one id is given
 127   if (scalar @multi_ids == 1) {
 128     $self->order(SL::DB::Order->new(id => $multi_ids[0])->load);
 129     $self->action_save_as_new();
 130     return;
 131   }
 132
 133   # make new order from given orders
 134   my @multi_orders = map { SL::DB::Order->new(id => $_)->load } @multi_ids;
 135   $self->{converted_from_oe_id} = join ' ', map { $_->id } @multi_orders;
 136   $self->order(SL::DB::Order->new_from_multi(\@multi_orders, sort_sources_by => 'transdate'));
 137
 138   $self->action_edit();
 139 }
 140
 141 # delete the order
 142 sub action_delete {
 143   my ($self) = @_;
 144
 145   my $errors = $self->delete();
 146
 147   if (scalar @{ $errors }) {
 148     $self->js->flash('error', $_) foreach @{ $errors };
 149     return $self->js->render();
 150   }
 151
 152   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been deleted')
 153            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been deleted')
 154            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been deleted')
 155            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been deleted')
 156            : '';
 157   flash_later('info', $text);
 158
 159   my @redirect_params = (
 160     action => 'add',
 161     type   => $self->type,
 162   );
 163
 164   $self->redirect_to(@redirect_params);
 165 }
 166
 167 # save the order
 168 sub action_save {
 169   my ($self) = @_;
 170
 171   my $errors = $self->save();
 172
 173   if (scalar @{ $errors }) {
 174     $self->js->flash('error', $_) foreach @{ $errors };
 175     return $self->js->render();
 176   }
 177
 178   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
 179            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
 180            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
 181            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
 182            : '';
 183   flash_later('info', $text);
 184
 185   my @redirect_params = (
 186     action => 'edit',
 187     type   => $self->type,
 188     id     => $self->order->id,
 189   );
 190
 191   $self->redirect_to(@redirect_params);
 192 }
 193
 194 # save the order as new document an open it for edit
 195 sub action_save_as_new {
 196   my ($self) = @_;
 197
 198   my $order = $self->order;
 199
 200   if (!$order->id) {
 201     $self->js->flash('error', t8('This object has not been saved yet.'));
 202     return $self->js->render();
 203   }
 204
 205   # load order from db to check if values changed
 206   my $saved_order = SL::DB::Order->new(id => $order->id)->load;
 207
 208   my %new_attrs;
 209   # Lets assign a new number if the user hasn't changed the previous one.
 210   # If it has been changed manually then use it as-is.
 211   $new_attrs{number}    = (trim($order->number) eq $saved_order->number)
 212                         ? ''
 213                         : trim($order->number);
 214
 215   # Clear transdate unless changed
 216   $new_attrs{transdate} = ($order->transdate == $saved_order->transdate)
 217                         ? DateTime->today_local
 218                         : $order->transdate;
 219
 220   # Set new reqdate unless changed
 221   if ($order->reqdate == $saved_order->reqdate) {
 222     my $extra_days = $self->{type} eq 'sales_quotation' ? $::instance_conf->get_reqdate_interval       :
 223                      $self->{type} eq 'sales_order'     ? $::instance_conf->get_delivery_date_interval : 1;
 224     $new_attrs{reqdate} = DateTime->today_local->next_workday(extra_days => $extra_days);
 225   } else {
 226     $new_attrs{reqdate} = $order->reqdate;
 227   }
 228
 229   # Update employee
 230   $new_attrs{employee}  = SL::DB::Manager::Employee->current;
 231
 232   # Create new record from current one
 233   $self->order(SL::DB::Order->new_from($order, destination_type => $order->type, attributes => \%new_attrs));
 234
 235   # no linked records on save as new
 236   delete $::form->{$_} for qw(converted_from_oe_id converted_from_orderitems_ids);
 237
 238   # save
 239   $self->action_save();
 240 }
 241
 242 # print the order
 243 #
 244 # This is called if "print" is pressed in the print dialog.
 245 # If PDF creation was requested and succeeded, the pdf is offered for download
 246 # via send_file (which uses ajax in this case).
 247 sub action_print {
 248   my ($self) = @_;
 249
 250   my $errors = $self->save();
 251
 252   if (scalar @{ $errors }) {
 253     $self->js->flash('error', $_) foreach @{ $errors };
 254     return $self->js->render();
 255   }
 256
 257   $self->js_reset_order_and_item_ids_after_save;
 258
 259   my $format      = $::form->{print_options}->{format};
 260   my $media       = $::form->{print_options}->{media};
 261   my $formname    = $::form->{print_options}->{formname};
 262   my $copies      = $::form->{print_options}->{copies};
 263   my $groupitems  = $::form->{print_options}->{groupitems};
 264
 265   # only pdf and opendocument by now
 266   if (none { $format eq $_ } qw(pdf opendocument opendocument_pdf)) {
 267     return $self->js->flash('error', t8('Format \'#1\' is not supported yet/anymore.', $format))->render;
 268   }
 269
 270   # only screen or printer by now
 271   if (none { $media eq $_ } qw(screen printer)) {
 272     return $self->js->flash('error', t8('Media \'#1\' is not supported yet/anymore.', $media))->render;
 273   }
 274
 275   my $language;
 276   $language = SL::DB::Language->new(id => $::form->{print_options}->{language_id})->load if $::form->{print_options}->{language_id};
 277
 278   # create a form for generate_attachment_filename
 279   my $form   = Form->new;
 280   $form->{$self->nr_key()}  = $self->order->number;
 281   $form->{type}             = $self->type;
 282   $form->{format}           = $format;
 283   $form->{formname}         = $formname;
 284   $form->{language}         = '_' . $language->template_code if $language;
 285   my $pdf_filename          = $form->generate_attachment_filename();
 286
 287   my $pdf;
 288   my @errors = generate_pdf($self->order, \$pdf, { format     => $format,
 289                                                    formname   => $formname,
 290                                                    language   => $language,
 291                                                    groupitems => $groupitems });
 292   if (scalar @errors) {
 293     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render;
 294   }
 295
 296   if ($media eq 'screen') {
 297     # screen/download
 298     $self->js->flash('info', t8('The PDF has been created'));
 299     $self->send_file(
 300       \$pdf,
 301       type         => SL::MIME->mime_type_from_ext($pdf_filename),
 302       name         => $pdf_filename,
 303       js_no_render => 1,
 304     );
 305
 306   } elsif ($media eq 'printer') {
 307     # printer
 308     my $printer_id = $::form->{print_options}->{printer_id};
 309     SL::DB::Printer->new(id => $printer_id)->load->print_document(
 310       copies  => $copies,
 311       content => $pdf,
 312     );
 313
 314     $self->js->flash('info', t8('The PDF has been printed'));
 315   }
 316
 317   # copy file to webdav folder
 318   if ($self->order->number && $::instance_conf->get_webdav_documents) {
 319     my $webdav = SL::Webdav->new(
 320       type     => $self->type,
 321       number   => $self->order->number,
 322     );
 323     my $webdav_file = SL::Webdav::File->new(
 324       webdav   => $webdav,
 325       filename => $pdf_filename,
 326     );
 327     eval {
 328       $webdav_file->store(data => \$pdf);
 329       1;
 330     } or do {
 331       $self->js->flash('error', t8('Storing PDF to webdav folder failed: #1', $@));
 332     }
 333   }
 334   if ($self->order->number && $::instance_conf->get_doc_storage) {
 335     eval {
 336       SL::File->save(object_id     => $self->order->id,
 337                      object_type   => $self->type,
 338                      mime_type     => 'application/pdf',
 339                      source        => 'created',
 340                      file_type     => 'document',
 341                      file_name     => $pdf_filename,
 342                      file_contents => $pdf);
 343       1;
 344     } or do {
 345       $self->js->flash('error', t8('Storing PDF in storage backend failed: #1', $@));
 346     }
 347   }
 348   $self->js->render;
 349 }
 350
 351 # open the email dialog
 352 sub action_show_email_dialog {
 353   my ($self) = @_;
 354
 355   my $cv_method = $self->cv;
 356
 357   if (!$self->order->$cv_method) {
 358     return $self->js->flash('error', $self->cv eq 'customer' ? t8('Cannot send E-mail without customer given') : t8('Cannot send E-mail without vendor given'))
 359                     ->render($self);
 360   }
 361
 362   my $email_form;
 363   $email_form->{to}   = $self->order->contact->cp_email if $self->order->contact;
 364   $email_form->{to} ||= $self->order->$cv_method->email;
 365   $email_form->{cc}   = $self->order->$cv_method->cc;
 366   $email_form->{bcc}  = join ', ', grep $_, $self->order->$cv_method->bcc, SL::DB::Default->get->global_bcc;
 367   # Todo: get addresses from shipto, if any
 368
 369   my $form = Form->new;
 370   $form->{$self->nr_key()}  = $self->order->number;
 371   $form->{formname}         = $self->type;
 372   $form->{type}             = $self->type;
 373   $form->{language}         = 'de';
 374   $form->{format}           = 'pdf';
 375
 376   $email_form->{subject}             = $form->generate_email_subject();
 377   $email_form->{attachment_filename} = $form->generate_attachment_filename();
 378   $email_form->{message}             = $form->generate_email_body();
 379   $email_form->{js_send_function}    = 'kivi.Order.send_email()';
 380
 381   my %files = $self->get_files_for_email_dialog();
 382   my $dialog_html = $self->render('common/_send_email_dialog', { output => 0 },
 383                                   email_form  => $email_form,
 384                                   show_bcc    => $::auth->assert('email_bcc', 'may fail'),
 385                                   FILES       => \%files,
 386                                   is_customer => $self->cv eq 'customer',
 387   );
 388
 389   $self->js
 390       ->run('kivi.Order.show_email_dialog', $dialog_html)
 391       ->reinit_widgets
 392       ->render($self);
 393 }
 394
 395 # send email
 396 #
 397 # Todo: handling error messages: flash is not displayed in dialog, but in the main form
 398 sub action_send_email {
 399   my ($self) = @_;
 400
 401   my $errors = $self->save();
 402
 403   if (scalar @{ $errors }) {
 404     $self->js->run('kivi.Order.close_email_dialog');
 405     $self->js->flash('error', $_) foreach @{ $errors };
 406     return $self->js->render();
 407   }
 408
 409   $self->js_reset_order_and_item_ids_after_save;
 410
 411   my $email_form  = delete $::form->{email_form};
 412   my %field_names = (to => 'email');
 413
 414   $::form->{ $field_names{$_} // $_ } = $email_form->{$_} for keys %{ $email_form };
 415
 416   # for Form::cleanup which may be called in Form::send_email
 417   $::form->{cwd}    = getcwd();
 418   $::form->{tmpdir} = $::lx_office_conf{paths}->{userspath};
 419
 420   $::form->{$_}     = $::form->{print_options}->{$_} for keys %{ $::form->{print_options} };
 421   $::form->{media}  = 'email';
 422
 423   if (($::form->{attachment_policy} // '') !~ m{^(?:old_file|no_file)$}) {
 424     my $language;
 425     $language = SL::DB::Language->new(id => $::form->{print_options}->{language_id})->load if $::form->{print_options}->{language_id};
 426
 427     my $pdf;
 428     my @errors = generate_pdf($self->order, \$pdf, {media      => $::form->{media},
 429                                                     format     => $::form->{print_options}->{format},
 430                                                     formname   => $::form->{print_options}->{formname},
 431                                                     language   => $language,
 432                                                     groupitems => $::form->{print_options}->{groupitems}});
 433     if (scalar @errors) {
 434       return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render($self);
 435     }
 436
 437     my $sfile = SL::SessionFile::Random->new(mode => "w");
 438     $sfile->fh->print($pdf);
 439     $sfile->fh->close;
 440
 441     $::form->{tmpfile} = $sfile->file_name;
 442     $::form->{tmpdir}  = $sfile->get_path; # for Form::cleanup which may be called in Form::send_email
 443   }
 444
 445   $::form->send_email(\%::myconfig, 'pdf');
 446
 447   # internal notes
 448   my $intnotes = $self->order->intnotes;
 449   $intnotes   .= "\n\n" if $self->order->intnotes;
 450   $intnotes   .= t8('[email]')                                                                                        . "\n";
 451   $intnotes   .= t8('Date')       . ": " . $::locale->format_date_object(DateTime->now_local, precision => 'seconds') . "\n";
 452   $intnotes   .= t8('To (email)') . ": " . $::form->{email}                                                           . "\n";
 453   $intnotes   .= t8('Cc')         . ": " . $::form->{cc}                                                              . "\n"    if $::form->{cc};
 454   $intnotes   .= t8('Bcc')        . ": " . $::form->{bcc}                                                             . "\n"    if $::form->{bcc};
 455   $intnotes   .= t8('Subject')    . ": " . $::form->{subject}                                                         . "\n\n";
 456   $intnotes   .= t8('Message')    . ": " . $::form->{message};
 457
 458   $self->order->update_attributes(intnotes => $intnotes);
 459
 460   $self->js
 461       ->val('#order_intnotes', $intnotes)
 462       ->run('kivi.Order.close_email_dialog')
 463       ->flash('info', t8('The email has been sent.'))
 464       ->render($self);
 465 }
 466
 467 # open the periodic invoices config dialog
 468 #
 469 # If there are values in the form (i.e. dialog was opened before),
 470 # then use this values. Create new ones, else.
 471 sub action_show_periodic_invoices_config_dialog {
 472   my ($self) = @_;
 473
 474   my $config = make_periodic_invoices_config_from_yaml(delete $::form->{config});
 475   $config  ||= SL::DB::Manager::PeriodicInvoicesConfig->find_by(oe_id => $::form->{id}) if $::form->{id};
 476   $config  ||= SL::DB::PeriodicInvoicesConfig->new(periodicity             => 'm',
 477                                                    order_value_periodicity => 'p', # = same as periodicity
 478                                                    start_date_as_date      => $::form->{transdate_as_date} || $::form->current_date,
 479                                                    extend_automatically_by => 12,
 480                                                    active                  => 1,
 481                                                    email_subject           => GenericTranslations->get(
 482                                                                                 language_id      => $::form->{language_id},
 483                                                                                 translation_type =>"preset_text_periodic_invoices_email_subject"),
 484                                                    email_body              => GenericTranslations->get(
 485                                                                                 language_id      => $::form->{language_id},
 486                                                                                 translation_type =>"preset_text_periodic_invoices_email_body"),
 487   );
 488   $config->periodicity('m')             if none { $_ eq $config->periodicity             }       @SL::DB::PeriodicInvoicesConfig::PERIODICITIES;
 489   $config->order_value_periodicity('p') if none { $_ eq $config->order_value_periodicity } ('p', @SL::DB::PeriodicInvoicesConfig::ORDER_VALUE_PERIODICITIES);
 490
 491   $::form->get_lists(printers => "ALL_PRINTERS",
 492                      charts   => { key       => 'ALL_CHARTS',
 493                                    transdate => 'current_date' });
 494
 495   $::form->{AR} = [ grep { $_->{link} =~ m/(?:^|:)AR(?::|$)/ } @{ $::form->{ALL_CHARTS} } ];
 496
 497   if ($::form->{customer_id}) {
 498     $::form->{ALL_CONTACTS} = SL::DB::Manager::Contact->get_all_sorted(where => [ cp_cv_id => $::form->{customer_id} ]);
 499     $::form->{email_recipient_invoice_address} = SL::DB::Manager::Customer->find_by(id => $::form->{customer_id})->invoice_mail;
 500   }
 501
 502   $self->render('oe/edit_periodic_invoices_config', { layout => 0 },
 503                 popup_dialog             => 1,
 504                 popup_js_close_function  => 'kivi.Order.close_periodic_invoices_config_dialog()',
 505                 popup_js_assign_function => 'kivi.Order.assign_periodic_invoices_config()',
 506                 config                   => $config,
 507                 %$::form);
 508 }
 509
 510 # assign the values of the periodic invoices config dialog
 511 # as yaml in the hidden tag and set the status.
 512 sub action_assign_periodic_invoices_config {
 513   my ($self) = @_;
 514
 515   $::form->isblank('start_date_as_date', $::locale->text('The start date is missing.'));
 516
 517   my $config = { active                     => $::form->{active}       ? 1 : 0,
 518                  terminated                 => $::form->{terminated}   ? 1 : 0,
 519                  direct_debit               => $::form->{direct_debit} ? 1 : 0,
 520                  periodicity                => (any { $_ eq $::form->{periodicity}             }       @SL::DB::PeriodicInvoicesConfig::PERIODICITIES)              ? $::form->{periodicity}             : 'm',
 521                  order_value_periodicity    => (any { $_ eq $::form->{order_value_periodicity} } ('p', @SL::DB::PeriodicInvoicesConfig::ORDER_VALUE_PERIODICITIES)) ? $::form->{order_value_periodicity} : 'p',
 522                  start_date_as_date         => $::form->{start_date_as_date},
 523                  end_date_as_date           => $::form->{end_date_as_date},
 524                  first_billing_date_as_date => $::form->{first_billing_date_as_date},
 525                  print                      => $::form->{print}      ? 1                         : 0,
 526                  printer_id                 => $::form->{print}      ? $::form->{printer_id} * 1 : undef,
 527                  copies                     => $::form->{copies} * 1 ? $::form->{copies}         : 1,
 528                  extend_automatically_by    => $::form->{extend_automatically_by}    * 1 || undef,
 529                  ar_chart_id                => $::form->{ar_chart_id} * 1,
 530                  send_email                 => $::form->{send_email} ? 1 : 0,
 531                  email_recipient_contact_id => $::form->{email_recipient_contact_id} * 1 || undef,
 532                  email_recipient_address    => $::form->{email_recipient_address},
 533                  email_sender               => $::form->{email_sender},
 534                  email_subject              => $::form->{email_subject},
 535                  email_body                 => $::form->{email_body},
 536                };
 537
 538   my $periodic_invoices_config = SL::YAML::Dump($config);
 539
 540   my $status = $self->get_periodic_invoices_status($config);
 541
 542   $self->js
 543     ->remove('#order_periodic_invoices_config')
 544     ->insertAfter(hidden_tag('order.periodic_invoices_config', $periodic_invoices_config), '#periodic_invoices_status')
 545     ->run('kivi.Order.close_periodic_invoices_config_dialog')
 546     ->html('#periodic_invoices_status', $status)
 547     ->flash('info', t8('The periodic invoices config has been assigned.'))
 548     ->render($self);
 549 }
 550
 551 sub action_get_has_active_periodic_invoices {
 552   my ($self) = @_;
 553
 554   my $config = make_periodic_invoices_config_from_yaml(delete $::form->{config});
 555   $config  ||= SL::DB::Manager::PeriodicInvoicesConfig->find_by(oe_id => $::form->{id}) if $::form->{id};
 556
 557   my $has_active_periodic_invoices =
 558        $self->type eq sales_order_type()
 559     && $config
 560     && $config->active
 561     && (!$config->end_date || ($config->end_date > DateTime->today_local))
 562     && $config->get_previous_billed_period_start_date;
 563
 564   $_[0]->render(\ !!$has_active_periodic_invoices, { type => 'text' });
 565 }
 566
 567 # save the order and redirect to the frontend subroutine for a new
 568 # delivery order
 569 sub action_save_and_delivery_order {
 570   my ($self) = @_;
 571
 572   my $errors = $self->save();
 573
 574   if (scalar @{ $errors }) {
 575     $self->js->flash('error', $_) foreach @{ $errors };
 576     return $self->js->render();
 577   }
 578
 579   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
 580            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
 581            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
 582            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
 583            : '';
 584   flash_later('info', $text);
 585
 586   my @redirect_params = (
 587     controller => 'oe.pl',
 588     action     => 'oe_delivery_order_from_order',
 589     id         => $self->order->id,
 590   );
 591
 592   $self->redirect_to(@redirect_params);
 593 }
 594
 595 # save the order and redirect to the frontend subroutine for a new
 596 # invoice
 597 sub action_save_and_invoice {
 598   my ($self) = @_;
 599
 600   my $errors = $self->save();
 601
 602   if (scalar @{ $errors }) {
 603     $self->js->flash('error', $_) foreach @{ $errors };
 604     return $self->js->render();
 605   }
 606
 607   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
 608            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
 609            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
 610            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
 611            : '';
 612   flash_later('info', $text);
 613
 614   my @redirect_params = (
 615     controller => 'oe.pl',
 616     action     => 'oe_invoice_from_order',
 617     id         => $self->order->id,
 618   );
 619
 620   $self->redirect_to(@redirect_params);
 621 }
 622
 623 # workflow from sales quotation to sales order
 624 sub action_sales_order {
 625   $_[0]->workflow_sales_or_purchase_order();
 626 }
 627
 628 # workflow from rfq to purchase order
 629 sub action_purchase_order {
 630   $_[0]->workflow_sales_or_purchase_order();
 631 }
 632
 633 # workflow from purchase order to ap transaction
 634 sub action_save_and_ap_transaction {
 635   my ($self) = @_;
 636
 637   my $errors = $self->save();
 638
 639   if (scalar @{ $errors }) {
 640     $self->js->flash('error', $_) foreach @{ $errors };
 641     return $self->js->render();
 642   }
 643
 644   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
 645            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
 646            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
 647            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
 648            : '';
 649   flash_later('info', $text);
 650
 651   my @redirect_params = (
 652     controller => 'ap.pl',
 653     action     => 'add_from_purchase_order',
 654     id         => $self->order->id,
 655   );
 656
 657   $self->redirect_to(@redirect_params);
 658 }
 659
 660 # set form elements in respect to a changed customer or vendor
 661 #
 662 # This action is called on an change of the customer/vendor picker.
 663 sub action_customer_vendor_changed {
 664   my ($self) = @_;
 665
 666   setup_order_from_cv($self->order);
 667   $self->recalc();
 668
 669   my $cv_method = $self->cv;
 670
 671   if ($self->order->$cv_method->contacts && scalar @{ $self->order->$cv_method->contacts } > 0) {
 672     $self->js->show('#cp_row');
 673   } else {
 674     $self->js->hide('#cp_row');
 675   }
 676
 677   if ($self->order->$cv_method->shipto && scalar @{ $self->order->$cv_method->shipto } > 0) {
 678     $self->js->show('#shipto_row');
 679   } else {
 680     $self->js->hide('#shipto_row');
 681   }
 682
 683   $self->js->val( '#order_salesman_id',      $self->order->salesman_id)        if $self->order->is_sales;
 684
 685   $self->js
 686     ->replaceWith('#order_cp_id',            $self->build_contact_select)
 687     ->replaceWith('#order_shipto_id',        $self->build_shipto_select)
 688     ->replaceWith('#business_info_row',      $self->build_business_info_row)
 689     ->val(        '#order_taxzone_id',       $self->order->taxzone_id)
 690     ->val(        '#order_taxincluded',      $self->order->taxincluded)
 691     ->val(        '#order_payment_id',       $self->order->payment_id)
 692     ->val(        '#order_delivery_term_id', $self->order->delivery_term_id)
 693     ->val(        '#order_intnotes',         $self->order->intnotes)
 694     ->val(        '#language_id',            $self->order->$cv_method->language_id)
 695     ->focus(      '#order_' . $self->cv . '_id');
 696
 697   $self->js_redisplay_amounts_and_taxes;
 698   $self->js_redisplay_cvpartnumbers;
 699   $self->js->render();
 700 }
 701
 702 # open the dialog for customer/vendor details
 703 sub action_show_customer_vendor_details_dialog {
 704   my ($self) = @_;
 705
 706   my $is_customer = 'customer' eq $::form->{vc};
 707   my $cv;
 708   if ($is_customer) {
 709     $cv = SL::DB::Customer->new(id => $::form->{vc_id})->load;
 710   } else {
 711     $cv = SL::DB::Vendor->new(id => $::form->{vc_id})->load;
 712   }
 713
 714   my %details = map { $_ => $cv->$_ } @{$cv->meta->columns};
 715   $details{discount_as_percent} = $cv->discount_as_percent;
 716   $details{creditlimt}          = $cv->creditlimit_as_number;
 717   $details{business}            = $cv->business->description      if $cv->business;
 718   $details{language}            = $cv->language_obj->description  if $cv->language_obj;
 719   $details{delivery_terms}      = $cv->delivery_term->description if $cv->delivery_term;
 720   $details{payment_terms}       = $cv->payment->description       if $cv->payment;
 721   $details{pricegroup}          = $cv->pricegroup->pricegroup     if $is_customer && $cv->pricegroup;
 722
 723   foreach my $entry (@{ $cv->shipto }) {
 724     push @{ $details{SHIPTO} },   { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 725   }
 726   foreach my $entry (@{ $cv->contacts }) {
 727     push @{ $details{CONTACTS} }, { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 728   }
 729
 730   $_[0]->render('common/show_vc_details', { layout => 0 },
 731                 is_customer => $is_customer,
 732                 %details);
 733
 734 }
 735
 736 # called if a unit in an existing item row is changed
 737 sub action_unit_changed {
 738   my ($self) = @_;
 739
 740   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 741   my $item = $self->order->items_sorted->[$idx];
 742
 743   my $old_unit_obj = SL::DB::Unit->new(name => $::form->{old_unit})->load;
 744   $item->sellprice($item->unit_obj->convert_to($item->sellprice, $old_unit_obj));
 745
 746   $self->recalc();
 747
 748   $self->js
 749     ->run('kivi.Order.update_sellprice', $::form->{item_id}, $item->sellprice_as_number);
 750   $self->js_redisplay_line_values;
 751   $self->js_redisplay_amounts_and_taxes;
 752   $self->js->render();
 753 }
 754
 755 # add an item row for a new item entered in the input row
 756 sub action_add_item {
 757   my ($self) = @_;
 758
 759   my $form_attr = $::form->{add_item};
 760
 761   return unless $form_attr->{parts_id};
 762
 763   my $item = new_item($self->order, $form_attr);
 764
 765   $self->order->add_items($item);
 766
 767   $self->recalc();
 768
 769   $self->get_item_cvpartnumber($item);
 770
 771   my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 772   my $row_as_html = $self->p->render('order/tabs/_row',
 773                                      ITEM => $item,
 774                                      ID   => $item_id,
 775                                      SELF => $self,
 776   );
 777
 778   $self->js
 779     ->append('#row_table_id', $row_as_html);
 780
 781   if ( $item->part->is_assortment ) {
 782     $form_attr->{qty_as_number} = 1 unless $form_attr->{qty_as_number};
 783     foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 784       my $attr = { parts_id => $assortment_item->parts_id,
 785                    qty      => $assortment_item->qty * $::form->parse_amount(\%::myconfig, $form_attr->{qty_as_number}), # TODO $form_attr->{unit}
 786                    unit     => $assortment_item->unit,
 787                    description => $assortment_item->part->description,
 788                  };
 789       my $item = new_item($self->order, $attr);
 790
 791       # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 792       $item->discount(1) unless $assortment_item->charge;
 793
 794       $self->order->add_items( $item );
 795       $self->recalc();
 796       $self->get_item_cvpartnumber($item);
 797       my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 798       my $row_as_html = $self->p->render('order/tabs/_row',
 799                                          ITEM => $item,
 800                                          ID   => $item_id,
 801                                          SELF => $self,
 802       );
 803       $self->js
 804         ->append('#row_table_id', $row_as_html);
 805     };
 806   };
 807
 808   $self->js
 809     ->val('.add_item_input', '')
 810     ->run('kivi.Order.init_row_handlers')
 811     ->run('kivi.Order.row_table_scroll_down')
 812     ->run('kivi.Order.renumber_positions')
 813     ->focus('#add_item_parts_id_name');
 814
 815   $self->js_redisplay_amounts_and_taxes;
 816   $self->js->render();
 817 }
 818
 819 # open the dialog for entering multiple items at once
 820 sub action_show_multi_items_dialog {
 821   $_[0]->render('order/tabs/_multi_items_dialog', { layout => 0 },
 822                 all_partsgroups => SL::DB::Manager::PartsGroup->get_all);
 823 }
 824
 825 # update the filter results in the multi item dialog
 826 sub action_multi_items_update_result {
 827   my $max_count = 100;
 828
 829   $::form->{multi_items}->{filter}->{obsolete} = 0;
 830
 831   my $count = $_[0]->multi_items_models->count;
 832
 833   if ($count == 0) {
 834     my $text = SL::Presenter::EscapedText->new(text => $::locale->text('No results.'));
 835     $_[0]->render($text, { layout => 0 });
 836   } elsif ($count > $max_count) {
 837     my $text = SL::Presenter::EscapedText->new(text => $::locale->text('Too many results (#1 from #2).', $count, $max_count));
 838     $_[0]->render($text, { layout => 0 });
 839   } else {
 840     my $multi_items = $_[0]->multi_items_models->get;
 841     $_[0]->render('order/tabs/_multi_items_result', { layout => 0 },
 842                   multi_items => $multi_items);
 843   }
 844 }
 845
 846 # add item rows for multiple items at once
 847 sub action_add_multi_items {
 848   my ($self) = @_;
 849
 850   my @form_attr = grep { $_->{qty_as_number} } @{ $::form->{add_multi_items} };
 851   return $self->js->render() unless scalar @form_attr;
 852
 853   my @items;
 854   foreach my $attr (@form_attr) {
 855     my $item = new_item($self->order, $attr);
 856     push @items, $item;
 857     if ( $item->part->is_assortment ) {
 858       foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 859         my $attr = { parts_id => $assortment_item->parts_id,
 860                      qty      => $assortment_item->qty * $item->qty, # TODO $form_attr->{unit}
 861                      unit     => $assortment_item->unit,
 862                      description => $assortment_item->part->description,
 863                    };
 864         my $item = new_item($self->order, $attr);
 865
 866         # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 867         $item->discount(1) unless $assortment_item->charge;
 868         push @items, $item;
 869       }
 870     }
 871   }
 872   $self->order->add_items(@items);
 873
 874   $self->recalc();
 875
 876   foreach my $item (@items) {
 877     $self->get_item_cvpartnumber($item);
 878     my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 879     my $row_as_html = $self->p->render('order/tabs/_row',
 880                                        ITEM => $item,
 881                                        ID   => $item_id,
 882                                        SELF => $self,
 883     );
 884
 885     $self->js->append('#row_table_id', $row_as_html);
 886   }
 887
 888   $self->js
 889     ->run('kivi.Order.close_multi_items_dialog')
 890     ->run('kivi.Order.init_row_handlers')
 891     ->run('kivi.Order.row_table_scroll_down')
 892     ->run('kivi.Order.renumber_positions')
 893     ->focus('#add_item_parts_id_name');
 894
 895   $self->js_redisplay_amounts_and_taxes;
 896   $self->js->render();
 897 }
 898
 899 # recalculate all linetotals, amounts and taxes and redisplay them
 900 sub action_recalc_amounts_and_taxes {
 901   my ($self) = @_;
 902
 903   $self->recalc();
 904
 905   $self->js_redisplay_line_values;
 906   $self->js_redisplay_amounts_and_taxes;
 907   $self->js->render();
 908 }
 909
 910 # redisplay item rows if they are sorted by an attribute
 911 sub action_reorder_items {
 912   my ($self) = @_;
 913
 914   my %sort_keys = (
 915     partnumber   => sub { $_[0]->part->partnumber },
 916     description  => sub { $_[0]->description },
 917     qty          => sub { $_[0]->qty },
 918     sellprice    => sub { $_[0]->sellprice },
 919     discount     => sub { $_[0]->discount },
 920     cvpartnumber => sub { $_[0]->{cvpartnumber} },
 921   );
 922
 923   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
 924
 925   my $method = $sort_keys{$::form->{order_by}};
 926   my @to_sort = map { { old_pos => $_->position, order_by => $method->($_) } } @{ $self->order->items_sorted };
 927   if ($::form->{sort_dir}) {
 928     if ( $::form->{order_by} =~ m/qty|sellprice|discount/ ){
 929       @to_sort = sort { $a->{order_by} <=> $b->{order_by} } @to_sort;
 930     } else {
 931       @to_sort = sort { $a->{order_by} cmp $b->{order_by} } @to_sort;
 932     }
 933   } else {
 934     if ( $::form->{order_by} =~ m/qty|sellprice|discount/ ){
 935       @to_sort = sort { $b->{order_by} <=> $a->{order_by} } @to_sort;
 936     } else {
 937       @to_sort = sort { $b->{order_by} cmp $a->{order_by} } @to_sort;
 938     }
 939   }
 940   $self->js
 941     ->run('kivi.Order.redisplay_items', \@to_sort)
 942     ->render;
 943 }
 944
 945 # show the popup to choose a price/discount source
 946 sub action_price_popup {
 947   my ($self) = @_;
 948
 949   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 950   my $item = $self->order->items_sorted->[$idx];
 951
 952   $self->render_price_dialog($item);
 953 }
 954
 955 # get the longdescription for an item if the dialog to enter/change the
 956 # longdescription was opened and the longdescription is empty
 957 #
 958 # If this item is new, get the longdescription from Part.
 959 # Otherwise get it from OrderItem.
 960 sub action_get_item_longdescription {
 961   my $longdescription;
 962
 963   if ($::form->{item_id}) {
 964     $longdescription = SL::DB::OrderItem->new(id => $::form->{item_id})->load->longdescription;
 965   } elsif ($::form->{parts_id}) {
 966     $longdescription = SL::DB::Part->new(id => $::form->{parts_id})->load->notes;
 967   }
 968   $_[0]->render(\ $longdescription, { type => 'text' });
 969 }
 970
 971 # load the second row for one or more items
 972 #
 973 # This action gets the html code for all items second rows by rendering a template for
 974 # the second row and sets the html code via client js.
 975 sub action_load_second_rows {
 976   my ($self) = @_;
 977
 978   $self->recalc() if $self->order->is_sales; # for margin calculation
 979
 980   foreach my $item_id (@{ $::form->{item_ids} }) {
 981     my $idx  = first_index { $_ eq $item_id } @{ $::form->{orderitem_ids} };
 982     my $item = $self->order->items_sorted->[$idx];
 983
 984     $self->js_load_second_row($item, $item_id, 0);
 985   }
 986
 987   $self->js->run('kivi.Order.init_row_handlers') if $self->order->is_sales; # for lastcosts change-callback
 988
 989   $self->js->render();
 990 }
 991
 992 # update description, notes and sellprice from master data
 993 sub action_update_row_from_master_data {
 994   my ($self) = @_;
 995
 996   foreach my $item_id (@{ $::form->{item_ids} }) {
 997     my $idx  = first_index { $_ eq $item_id } @{ $::form->{orderitem_ids} };
 998     my $item = $self->order->items_sorted->[$idx];
 999
1000     $item->description($item->part->description);
1001     $item->longdescription($item->part->notes);
1002
1003     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
1004
1005     my $price_src;
1006     if ($item->part->is_assortment) {
1007     # add assortment items with price 0, as the components carry the price
1008       $price_src = $price_source->price_from_source("");
1009       $price_src->price(0);
1010     } else {
1011       $price_src = $price_source->best_price
1012                  ? $price_source->best_price
1013                  : $price_source->price_from_source("");
1014       $price_src->price(0) if !$price_source->best_price;
1015     }
1016
1017     $item->sellprice($price_src->price);
1018     $item->active_price_source($price_src);
1019
1020     $self->js
1021       ->run('kivi.Order.update_sellprice', $item_id, $item->sellprice_as_number)
1022       ->val('.row_entry:has(#item_' . $item_id . ') [name = "order.orderitems[].description"]', $item->description)
1023       ->val('.row_entry:has(#item_' . $item_id . ') [name = "order.orderitems[].longdescription"]', $item->longdescription);
1024   }
1025
1026   $self->recalc();
1027   $self->js_redisplay_line_values;
1028   $self->js_redisplay_amounts_and_taxes;
1029
1030   $self->js->render();
1031 }
1032
1033 sub js_load_second_row {
1034   my ($self, $item, $item_id, $do_parse) = @_;
1035
1036   if ($do_parse) {
1037     # Parse values from form (they are formated while rendering (template)).
1038     # Workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
1039     # This parsing is not necessary at all, if we assure that the second row/cvars are only loaded once.
1040     foreach my $var (@{ $item->cvars_by_config }) {
1041       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
1042     }
1043     $item->parse_custom_variable_values;
1044   }
1045
1046   my $row_as_html = $self->p->render('order/tabs/_second_row', ITEM => $item, TYPE => $self->type);
1047
1048   $self->js
1049     ->html('#second_row_' . $item_id, $row_as_html)
1050     ->data('#second_row_' . $item_id, 'loaded', 1);
1051 }
1052
1053 sub js_redisplay_line_values {
1054   my ($self) = @_;
1055
1056   my $is_sales = $self->order->is_sales;
1057
1058   # sales orders with margins
1059   my @data;
1060   if ($is_sales) {
1061     @data = map {
1062       [
1063        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
1064        $::form->format_amount(\%::myconfig, $_->{marge_total},   2, 0),
1065        $::form->format_amount(\%::myconfig, $_->{marge_percent}, 2, 0),
1066       ]} @{ $self->order->items_sorted };
1067   } else {
1068     @data = map {
1069       [
1070        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
1071       ]} @{ $self->order->items_sorted };
1072   }
1073
1074   $self->js
1075     ->run('kivi.Order.redisplay_line_values', $is_sales, \@data);
1076 }
1077
1078 sub js_redisplay_amounts_and_taxes {
1079   my ($self) = @_;
1080
1081   if (scalar @{ $self->{taxes} }) {
1082     $self->js->show('#taxincluded_row_id');
1083   } else {
1084     $self->js->hide('#taxincluded_row_id');
1085   }
1086
1087   if ($self->order->taxincluded) {
1088     $self->js->hide('#subtotal_row_id');
1089   } else {
1090     $self->js->show('#subtotal_row_id');
1091   }
1092
1093   if ($self->order->is_sales) {
1094     my $is_neg = $self->order->marge_total < 0;
1095     $self->js
1096       ->html('#marge_total_id',   $::form->format_amount(\%::myconfig, $self->order->marge_total,   2))
1097       ->html('#marge_percent_id', $::form->format_amount(\%::myconfig, $self->order->marge_percent, 2))
1098       ->action_if( $is_neg, 'addClass',    '#marge_total_id',        'plus0')
1099       ->action_if( $is_neg, 'addClass',    '#marge_percent_id',      'plus0')
1100       ->action_if( $is_neg, 'addClass',    '#marge_percent_sign_id', 'plus0')
1101       ->action_if(!$is_neg, 'removeClass', '#marge_total_id',        'plus0')
1102       ->action_if(!$is_neg, 'removeClass', '#marge_percent_id',      'plus0')
1103       ->action_if(!$is_neg, 'removeClass', '#marge_percent_sign_id', 'plus0');
1104   }
1105
1106   $self->js
1107     ->html('#netamount_id', $::form->format_amount(\%::myconfig, $self->order->netamount, -2))
1108     ->html('#amount_id',    $::form->format_amount(\%::myconfig, $self->order->amount,    -2))
1109     ->remove('.tax_row')
1110     ->insertBefore($self->build_tax_rows, '#amount_row_id');
1111 }
1112
1113 sub js_redisplay_cvpartnumbers {
1114   my ($self) = @_;
1115
1116   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
1117
1118   my @data = map {[$_->{cvpartnumber}]} @{ $self->order->items_sorted };
1119
1120   $self->js
1121     ->run('kivi.Order.redisplay_cvpartnumbers', \@data);
1122 }
1123
1124 sub js_reset_order_and_item_ids_after_save {
1125   my ($self) = @_;
1126
1127   $self->js
1128     ->val('#id', $self->order->id)
1129     ->val('#converted_from_oe_id', '')
1130     ->val('#order_' . $self->nr_key(), $self->order->number);
1131
1132   my $idx = 0;
1133   foreach my $form_item_id (@{ $::form->{orderitem_ids} }) {
1134     next if !$self->order->items_sorted->[$idx]->id;
1135     next if $form_item_id !~ m{^new};
1136     $self->js
1137       ->val ('[name="orderitem_ids[+]"][value="' . $form_item_id . '"]', $self->order->items_sorted->[$idx]->id)
1138       ->val ('#item_' . $form_item_id, $self->order->items_sorted->[$idx]->id)
1139       ->attr('#item_' . $form_item_id, "id", 'item_' . $self->order->items_sorted->[$idx]->id);
1140   } continue {
1141     $idx++;
1142   }
1143   $self->js->val('[name="converted_from_orderitems_ids[+]"]', '');
1144 }
1145
1146 #
1147 # helpers
1148 #
1149
1150 sub init_valid_types {
1151   [ sales_order_type(), purchase_order_type(), sales_quotation_type(), request_quotation_type() ];
1152 }
1153
1154 sub init_type {
1155   my ($self) = @_;
1156
1157   if (none { $::form->{type} eq $_ } @{$self->valid_types}) {
1158     die "Not a valid type for order";
1159   }
1160
1161   $self->type($::form->{type});
1162 }
1163
1164 sub init_cv {
1165   my ($self) = @_;
1166
1167   my $cv = (any { $self->type eq $_ } (sales_order_type(),    sales_quotation_type()))   ? 'customer'
1168          : (any { $self->type eq $_ } (purchase_order_type(), request_quotation_type())) ? 'vendor'
1169          : die "Not a valid type for order";
1170
1171   return $cv;
1172 }
1173
1174 sub init_search_cvpartnumber {
1175   my ($self) = @_;
1176
1177   my $user_prefs = SL::Helper::UserPreferences::PartPickerSearch->new();
1178   my $search_cvpartnumber;
1179   $search_cvpartnumber = !!$user_prefs->get_sales_search_customer_partnumber() if $self->cv eq 'customer';
1180   $search_cvpartnumber = !!$user_prefs->get_purchase_search_makemodel()        if $self->cv eq 'vendor';
1181
1182   return $search_cvpartnumber;
1183 }
1184
1185 sub init_show_update_button {
1186   my ($self) = @_;
1187
1188   !!SL::Helper::UserPreferences::UpdatePositions->new()->get_show_update_button();
1189 }
1190
1191 sub init_p {
1192   SL::Presenter->get;
1193 }
1194
1195 sub init_order {
1196   $_[0]->make_order;
1197 }
1198
1199 # model used to filter/display the parts in the multi-items dialog
1200 sub init_multi_items_models {
1201   SL::Controller::Helper::GetModels->new(
1202     controller     => $_[0],
1203     model          => 'Part',
1204     with_objects   => [ qw(unit_obj) ],
1205     disable_plugin => 'paginated',
1206     source         => $::form->{multi_items},
1207     sorted         => {
1208       _default    => {
1209         by  => 'partnumber',
1210         dir => 1,
1211       },
1212       partnumber  => t8('Partnumber'),
1213       description => t8('Description')}
1214   );
1215 }
1216
1217 sub init_all_price_factors {
1218   SL::DB::Manager::PriceFactor->get_all;
1219 }
1220
1221 sub check_auth {
1222   my ($self) = @_;
1223
1224   my $right_for = { map { $_ => $_.'_edit' } @{$self->valid_types} };
1225
1226   my $right   = $right_for->{ $self->type };
1227   $right    ||= 'DOES_NOT_EXIST';
1228
1229   $::auth->assert($right);
1230 }
1231
1232 # build the selection box for contacts
1233 #
1234 # Needed, if customer/vendor changed.
1235 sub build_contact_select {
1236   my ($self) = @_;
1237
1238   select_tag('order.cp_id', [ $self->order->{$self->cv}->contacts ],
1239     value_key  => 'cp_id',
1240     title_key  => 'full_name_dep',
1241     default    => $self->order->cp_id,
1242     with_empty => 1,
1243     style      => 'width: 300px',
1244   );
1245 }
1246
1247 # build the selection box for shiptos
1248 #
1249 # Needed, if customer/vendor changed.
1250 sub build_shipto_select {
1251   my ($self) = @_;
1252
1253   select_tag('order.shipto_id', [ $self->order->{$self->cv}->shipto ],
1254     value_key  => 'shipto_id',
1255     title_key  => 'displayable_id',
1256     default    => $self->order->shipto_id,
1257     with_empty => 1,
1258     style      => 'width: 300px',
1259   );
1260 }
1261
1262 # render the info line for business
1263 #
1264 # Needed, if customer/vendor changed.
1265 sub build_business_info_row
1266 {
1267   $_[0]->p->render('order/tabs/_business_info_row', SELF => $_[0]);
1268 }
1269
1270 # build the rows for displaying taxes
1271 #
1272 # Called if amounts where recalculated and redisplayed.
1273 sub build_tax_rows {
1274   my ($self) = @_;
1275
1276   my $rows_as_html;
1277   foreach my $tax (sort { $a->{tax}->rate cmp $b->{tax}->rate } @{ $self->{taxes} }) {
1278     $rows_as_html .= $self->p->render('order/tabs/_tax_row', TAX => $tax, TAXINCLUDED => $self->order->taxincluded);
1279   }
1280   return $rows_as_html;
1281 }
1282
1283
1284 sub render_price_dialog {
1285   my ($self, $record_item) = @_;
1286
1287   my $price_source = SL::PriceSource->new(record_item => $record_item, record => $self->order);
1288
1289   $self->js
1290     ->run(
1291       'kivi.io.price_chooser_dialog',
1292       t8('Available Prices'),
1293       $self->render('order/tabs/_price_sources_dialog', { output => 0 }, price_source => $price_source)
1294     )
1295     ->reinit_widgets;
1296
1297 #   if (@errors) {
1298 #     $self->js->text('#dialog_flash_error_content', join ' ', @errors);
1299 #     $self->js->show('#dialog_flash_error');
1300 #   }
1301
1302   $self->js->render;
1303 }
1304
1305 sub load_order {
1306   my ($self) = @_;
1307
1308   return if !$::form->{id};
1309
1310   $self->order(SL::DB::Order->new(id => $::form->{id})->load);
1311 }
1312
1313 # load or create a new order object
1314 #
1315 # And assign changes from the form to this object.
1316 # If the order is loaded from db, check if items are deleted in the form,
1317 # remove them form the object and collect them for removing from db on saving.
1318 # Then create/update items from form (via make_item) and add them.
1319 sub make_order {
1320   my ($self) = @_;
1321
1322   # add_items adds items to an order with no items for saving, but they cannot
1323   # be retrieved via items until the order is saved. Adding empty items to new
1324   # order here solves this problem.
1325   my $order;
1326   $order   = SL::DB::Order->new(id => $::form->{id})->load(with => [ 'orderitems', 'orderitems.part' ]) if $::form->{id};
1327   $order ||= SL::DB::Order->new(orderitems => [],
1328                                 quotation  => (any { $self->type eq $_ } (sales_quotation_type(), request_quotation_type())));
1329
1330   my $cv_id_method = $self->cv . '_id';
1331   if (!$::form->{id} && $::form->{$cv_id_method}) {
1332     $order->$cv_id_method($::form->{$cv_id_method});
1333     setup_order_from_cv($order);
1334   }
1335
1336   my $form_orderitems               = delete $::form->{order}->{orderitems};
1337   my $form_periodic_invoices_config = delete $::form->{order}->{periodic_invoices_config};
1338
1339   $order->assign_attributes(%{$::form->{order}});
1340
1341   if (my $periodic_invoices_config_attrs = $form_periodic_invoices_config ? SL::YAML::Load($form_periodic_invoices_config) : undef) {
1342     my $periodic_invoices_config = $order->periodic_invoices_config || $order->periodic_invoices_config(SL::DB::PeriodicInvoicesConfig->new);
1343     $periodic_invoices_config->assign_attributes(%$periodic_invoices_config_attrs);
1344   }
1345
1346   # remove deleted items
1347   $self->item_ids_to_delete([]);
1348   foreach my $idx (reverse 0..$#{$order->orderitems}) {
1349     my $item = $order->orderitems->[$idx];
1350     if (none { $item->id == $_->{id} } @{$form_orderitems}) {
1351       splice @{$order->orderitems}, $idx, 1;
1352       push @{$self->item_ids_to_delete}, $item->id;
1353     }
1354   }
1355
1356   my @items;
1357   my $pos = 1;
1358   foreach my $form_attr (@{$form_orderitems}) {
1359     my $item = make_item($order, $form_attr);
1360     $item->position($pos);
1361     push @items, $item;
1362     $pos++;
1363   }
1364   $order->add_items(grep {!$_->id} @items);
1365
1366   return $order;
1367 }
1368
1369 # create or update items from form
1370 #
1371 # Make item objects from form values. For items already existing read from db.
1372 # Create a new item else. And assign attributes.
1373 sub make_item {
1374   my ($record, $attr) = @_;
1375
1376   my $item;
1377   $item = first { $_->id == $attr->{id} } @{$record->items} if $attr->{id};
1378
1379   my $is_new = !$item;
1380
1381   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1382   # they cannot be retrieved via custom_variables until the order/orderitem is
1383   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1384   $item ||= SL::DB::OrderItem->new(custom_variables => []);
1385
1386   $item->assign_attributes(%$attr);
1387   $item->longdescription($item->part->notes)                     if $is_new && !defined $attr->{longdescription};
1388   $item->project_id($record->globalproject_id)                   if $is_new && !defined $attr->{project_id};
1389   $item->lastcost($record->is_sales ? $item->part->lastcost : 0) if $is_new && !defined $attr->{lastcost_as_number};
1390
1391   return $item;
1392 }
1393
1394 # create a new item
1395 #
1396 # This is used to add one item
1397 sub new_item {
1398   my ($record, $attr) = @_;
1399
1400   my $item = SL::DB::OrderItem->new;
1401
1402   # Remove attributes where the user left or set the inputs empty.
1403   # So these attributes will be undefined and we can distinguish them
1404   # from zero later on.
1405   for (qw(qty_as_number sellprice_as_number discount_as_percent)) {
1406     delete $attr->{$_} if $attr->{$_} eq '';
1407   }
1408
1409   $item->assign_attributes(%$attr);
1410
1411   my $part         = SL::DB::Part->new(id => $attr->{parts_id})->load;
1412   my $price_source = SL::PriceSource->new(record_item => $item, record => $record);
1413
1414   $item->unit($part->unit) if !$item->unit;
1415
1416   my $price_src;
1417   if ( $part->is_assortment ) {
1418     # add assortment items with price 0, as the components carry the price
1419     $price_src = $price_source->price_from_source("");
1420     $price_src->price(0);
1421   } elsif (defined $item->sellprice) {
1422     $price_src = $price_source->price_from_source("");
1423     $price_src->price($item->sellprice);
1424   } else {
1425     $price_src = $price_source->best_price
1426            ? $price_source->best_price
1427            : $price_source->price_from_source("");
1428     $price_src->price(0) if !$price_source->best_price;
1429   }
1430
1431   my $discount_src;
1432   if (defined $item->discount) {
1433     $discount_src = $price_source->discount_from_source("");
1434     $discount_src->discount($item->discount);
1435   } else {
1436     $discount_src = $price_source->best_discount
1437                   ? $price_source->best_discount
1438                   : $price_source->discount_from_source("");
1439     $discount_src->discount(0) if !$price_source->best_discount;
1440   }
1441
1442   my %new_attr;
1443   $new_attr{part}                   = $part;
1444   $new_attr{description}            = $part->description     if ! $item->description;
1445   $new_attr{qty}                    = 1.0                    if ! $item->qty;
1446   $new_attr{price_factor_id}        = $part->price_factor_id if ! $item->price_factor_id;
1447   $new_attr{sellprice}              = $price_src->price;
1448   $new_attr{discount}               = $discount_src->discount;
1449   $new_attr{active_price_source}    = $price_src;
1450   $new_attr{active_discount_source} = $discount_src;
1451   $new_attr{longdescription}        = $part->notes           if ! defined $attr->{longdescription};
1452   $new_attr{project_id}             = $record->globalproject_id;
1453   $new_attr{lastcost}               = $record->is_sales ? $part->lastcost : 0;
1454
1455   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1456   # they cannot be retrieved via custom_variables until the order/orderitem is
1457   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1458   $new_attr{custom_variables} = [];
1459
1460   $item->assign_attributes(%new_attr);
1461
1462   return $item;
1463 }
1464
1465 sub setup_order_from_cv {
1466   my ($order) = @_;
1467
1468   $order->$_($order->customervendor->$_) for (qw(taxzone_id payment_id delivery_term_id));
1469
1470   $order->intnotes($order->customervendor->notes);
1471
1472   if ($order->is_sales) {
1473     $order->salesman_id($order->customer->salesman_id || SL::DB::Manager::Employee->current->id);
1474     $order->taxincluded(defined($order->customer->taxincluded_checked)
1475                         ? $order->customer->taxincluded_checked
1476                         : $::myconfig{taxincluded_checked});
1477   }
1478
1479 }
1480
1481 # recalculate prices and taxes
1482 #
1483 # Using the PriceTaxCalculator. Store linetotals in the item objects.
1484 sub recalc {
1485   my ($self) = @_;
1486
1487   # bb: todo: currency later
1488   $self->order->currency_id($::instance_conf->get_currency_id());
1489
1490   my %pat = $self->order->calculate_prices_and_taxes();
1491   $self->{taxes} = [];
1492   foreach my $tax_chart_id (keys %{ $pat{taxes} }) {
1493     my $tax = SL::DB::Manager::Tax->find_by(chart_id => $tax_chart_id);
1494
1495     my @amount_keys = grep { $pat{amounts}->{$_}->{tax_id} == $tax->id } keys %{ $pat{amounts} };
1496     push(@{ $self->{taxes} }, { amount    => $pat{taxes}->{$tax_chart_id},
1497                                 netamount => $pat{amounts}->{$amount_keys[0]}->{amount},
1498                                 tax       => $tax });
1499   }
1500
1501   pairwise { $a->{linetotal} = $b->{linetotal} } @{$self->order->items_sorted}, @{$pat{items}};
1502 }
1503
1504 # get data for saving, printing, ..., that is not changed in the form
1505 #
1506 # Only cvars for now.
1507 sub get_unalterable_data {
1508   my ($self) = @_;
1509
1510   foreach my $item (@{ $self->order->items }) {
1511     # autovivify all cvars that are not in the form (cvars_by_config can do it).
1512     # workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
1513     foreach my $var (@{ $item->cvars_by_config }) {
1514       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
1515     }
1516     $item->parse_custom_variable_values;
1517   }
1518 }
1519
1520 # delete the order
1521 #
1522 # And remove related files in the spool directory
1523 sub delete {
1524   my ($self) = @_;
1525
1526   my $errors = [];
1527   my $db     = $self->order->db;
1528
1529   $db->with_transaction(
1530     sub {
1531       my @spoolfiles = grep { $_ } map { $_->spoolfile } @{ SL::DB::Manager::Status->get_all(where => [ trans_id => $self->order->id ]) };
1532       $self->order->delete;
1533       my $spool = $::lx_office_conf{paths}->{spool};
1534       unlink map { "$spool/$_" } @spoolfiles if $spool;
1535
1536       1;
1537   }) || push(@{$errors}, $db->error);
1538
1539   return $errors;
1540 }
1541
1542 # save the order
1543 #
1544 # And delete items that are deleted in the form.
1545 sub save {
1546   my ($self) = @_;
1547
1548   my $errors = [];
1549   my $db     = $self->order->db;
1550
1551   $db->with_transaction(sub {
1552     SL::DB::OrderItem->new(id => $_)->delete for @{$self->item_ids_to_delete || []};
1553     $self->order->save(cascade => 1);
1554
1555     # link records
1556     if ($::form->{converted_from_oe_id}) {
1557       my @converted_from_oe_ids = split ' ', $::form->{converted_from_oe_id};
1558       foreach my $converted_from_oe_id (@converted_from_oe_ids) {
1559         my $src = SL::DB::Order->new(id => $converted_from_oe_id)->load;
1560         $src->update_attributes(closed => 1) if $src->type =~ /_quotation$/;
1561         $src->link_to_record($self->order);
1562       }
1563       if (scalar @{ $::form->{converted_from_orderitems_ids} || [] }) {
1564         my $idx = 0;
1565         foreach (@{ $self->order->items_sorted }) {
1566           my $from_id = $::form->{converted_from_orderitems_ids}->[$idx];
1567           next if !$from_id;
1568           SL::DB::RecordLink->new(from_table => 'orderitems',
1569                                   from_id    => $from_id,
1570                                   to_table   => 'orderitems',
1571                                   to_id      => $_->id
1572           )->save;
1573           $idx++;
1574         }
1575       }
1576     }
1577     1;
1578   }) || push(@{$errors}, $db->error);
1579
1580   return $errors;
1581 }
1582
1583 sub workflow_sales_or_purchase_order {
1584   my ($self) = @_;
1585
1586   # always save
1587   my $errors = $self->save();
1588
1589   if (scalar @{ $errors }) {
1590     $self->js->flash('error', $_) foreach @{ $errors };
1591     return $self->js->render();
1592   }
1593
1594   my $destination_type = $::form->{type} eq sales_quotation_type()   ? sales_order_type()
1595                        : $::form->{type} eq request_quotation_type() ? purchase_order_type()
1596                        : $::form->{type} eq purchase_order_type()    ? sales_order_type()
1597                        : $::form->{type} eq sales_order_type()       ? purchase_order_type()
1598                        : '';
1599
1600   $self->order(SL::DB::Order->new_from($self->order, destination_type => $destination_type));
1601   $self->{converted_from_oe_id} = delete $::form->{id};
1602
1603   # set item ids to new fake id, to identify them as new items
1604   foreach my $item (@{$self->order->items_sorted}) {
1605     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1606   }
1607
1608   # change form type
1609   $::form->{type} = $destination_type;
1610   $self->type($self->init_type);
1611   $self->cv  ($self->init_cv);
1612   $self->check_auth;
1613
1614   $self->recalc();
1615   $self->get_unalterable_data();
1616   $self->pre_render();
1617
1618   # trigger rendering values for second row/longdescription as hidden,
1619   # because they are loaded only on demand. So we need to keep the values
1620   # from the source.
1621   $_->{render_second_row}      = 1 for @{ $self->order->items_sorted };
1622   $_->{render_longdescription} = 1 for @{ $self->order->items_sorted };
1623
1624   $self->render(
1625     'order/form',
1626     title => $self->get_title_for('edit'),
1627     %{$self->{template_args}}
1628   );
1629 }
1630
1631
1632 sub pre_render {
1633   my ($self) = @_;
1634
1635   $self->{all_taxzones}               = SL::DB::Manager::TaxZone->get_all_sorted();
1636   $self->{all_departments}            = SL::DB::Manager::Department->get_all_sorted();
1637   $self->{all_employees}              = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->employee_id,
1638                                                                                               deleted => 0 ] ],
1639                                                                            sort_by => 'name');
1640   $self->{all_salesmen}               = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->salesman_id,
1641                                                                                               deleted => 0 ] ],
1642                                                                            sort_by => 'name');
1643   $self->{all_payment_terms}          = SL::DB::Manager::PaymentTerm->get_all_sorted(where => [ or => [ id => $self->order->payment_id,
1644                                                                                                         obsolete => 0 ] ]);
1645   $self->{all_delivery_terms}         = SL::DB::Manager::DeliveryTerm->get_all_sorted();
1646   $self->{current_employee_id}        = SL::DB::Manager::Employee->current->id;
1647   $self->{periodic_invoices_status}   = $self->get_periodic_invoices_status($self->order->periodic_invoices_config);
1648   $self->{order_probabilities}        = [ map { { title => ($_ * 10) . '%', id => $_ * 10 } } (0..10) ];
1649   $self->{positions_scrollbar_height} = SL::Helper::UserPreferences::PositionsScrollbar->new()->get_height();
1650
1651   my $print_form = Form->new('');
1652   $print_form->{type}        = $self->type;
1653   $print_form->{printers}    = SL::DB::Manager::Printer->get_all_sorted;
1654   $print_form->{languages}   = SL::DB::Manager::Language->get_all_sorted;
1655   $print_form->{language_id} = $self->order->language_id;
1656   $self->{print_options}     = SL::Helper::PrintOptions->get_print_options(
1657     form => $print_form,
1658     options => {dialog_name_prefix => 'print_options.',
1659                 show_headers       => 1,
1660                 no_queue           => 1,
1661                 no_postscript      => 1,
1662                 no_opendocument    => 0,
1663                 no_html            => 1},
1664   );
1665
1666   foreach my $item (@{$self->order->orderitems}) {
1667     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
1668     $item->active_price_source(   $price_source->price_from_source(   $item->active_price_source   ));
1669     $item->active_discount_source($price_source->discount_from_source($item->active_discount_source));
1670   }
1671
1672   if (any { $self->type eq $_ } (sales_order_type(), purchase_order_type())) {
1673     # calculate shipped qtys here to prevent calling calculate for every item via the items method
1674     SL::Helper::ShippedQty->new->calculate($self->order)->write_to_objects;
1675   }
1676
1677   if ($self->order->number && $::instance_conf->get_webdav) {
1678     my $webdav = SL::Webdav->new(
1679       type     => $self->type,
1680       number   => $self->order->number,
1681     );
1682     my @all_objects = $webdav->get_all_objects;
1683     @{ $self->{template_args}->{WEBDAV} } = map { { name => $_->filename,
1684                                                     type => t8('File'),
1685                                                     link => File::Spec->catfile($_->full_filedescriptor),
1686                                                 } } @all_objects;
1687   }
1688
1689   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
1690
1691   $::request->{layout}->use_javascript("${_}.js") for qw(kivi.SalesPurchase kivi.Order kivi.File ckeditor/ckeditor ckeditor/adapters/jquery edit_periodic_invoices_config calculate_qty);
1692   $self->setup_edit_action_bar;
1693 }
1694
1695 sub setup_edit_action_bar {
1696   my ($self, %params) = @_;
1697
1698   my $deletion_allowed = (any { $self->type eq $_ } (sales_quotation_type(), request_quotation_type()))
1699                       || (($self->type eq sales_order_type())    && $::instance_conf->get_sales_order_show_delete)
1700                       || (($self->type eq purchase_order_type()) && $::instance_conf->get_purchase_order_show_delete);
1701
1702   for my $bar ($::request->layout->get('actionbar')) {
1703     $bar->add(
1704       combobox => [
1705         action => [
1706           t8('Save'),
1707           call      => [ 'kivi.Order.save', 'save', $::instance_conf->get_order_warn_duplicate_parts,
1708                                                     $::instance_conf->get_order_warn_no_deliverydate,
1709                                                                                                       ],
1710           checks    => [ 'kivi.Order.check_save_active_periodic_invoices' ],
1711         ],
1712         action => [
1713           t8('Save as new'),
1714           call      => [ 'kivi.Order.save', 'save_as_new', $::instance_conf->get_order_warn_duplicate_parts ],
1715           checks    => [ 'kivi.Order.check_save_active_periodic_invoices' ],
1716           disabled  => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1717         ],
1718       ], # end of combobox "Save"
1719
1720       combobox => [
1721         action => [
1722           t8('Workflow'),
1723         ],
1724         action => [
1725           t8('Save and Sales Order'),
1726           submit   => [ '#order_form', { action => "Order/sales_order" } ],
1727           only_if  => (any { $self->type eq $_ } (sales_quotation_type(), purchase_order_type())),
1728           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1729         ],
1730         action => [
1731           t8('Save and Purchase Order'),
1732           submit   => [ '#order_form', { action => "Order/purchase_order" } ],
1733           only_if  => (any { $self->type eq $_ } (sales_order_type(), request_quotation_type())),
1734           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1735         ],
1736         action => [
1737           t8('Save and Delivery Order'),
1738           call      => [ 'kivi.Order.save', 'save_and_delivery_order', $::instance_conf->get_order_warn_duplicate_parts,
1739                                                                        $::instance_conf->get_order_warn_no_deliverydate,
1740                                                                                                                         ],
1741           checks    => [ 'kivi.Order.check_save_active_periodic_invoices' ],
1742           only_if   => (any { $self->type eq $_ } (sales_order_type(), purchase_order_type()))
1743         ],
1744         action => [
1745           t8('Save and Invoice'),
1746           call      => [ 'kivi.Order.save', 'save_and_invoice', $::instance_conf->get_order_warn_duplicate_parts ],
1747           checks    => [ 'kivi.Order.check_save_active_periodic_invoices' ],
1748         ],
1749         action => [
1750           t8('Save and AP Transaction'),
1751           call      => [ 'kivi.Order.save', 'save_and_ap_transaction', $::instance_conf->get_order_warn_duplicate_parts ],
1752           only_if   => (any { $self->type eq $_ } (purchase_order_type()))
1753         ],
1754
1755       ], # end of combobox "Workflow"
1756
1757       combobox => [
1758         action => [
1759           t8('Export'),
1760         ],
1761         action => [
1762           t8('Save and print'),
1763           call => [ 'kivi.Order.show_print_options', $::instance_conf->get_order_warn_duplicate_parts ],
1764         ],
1765         action => [
1766           t8('Save and E-mail'),
1767           call => [ 'kivi.Order.email', $::instance_conf->get_order_warn_duplicate_parts ],
1768         ],
1769         action => [
1770           t8('Download attachments of all parts'),
1771           call     => [ 'kivi.File.downloadOrderitemsFiles', $::form->{type}, $::form->{id} ],
1772           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1773           only_if  => $::instance_conf->get_doc_storage,
1774         ],
1775       ], # end of combobox "Export"
1776
1777       action => [
1778         t8('Delete'),
1779         call     => [ 'kivi.Order.delete_order' ],
1780         confirm  => $::locale->text('Do you really want to delete this object?'),
1781         disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1782         only_if  => $deletion_allowed,
1783       ],
1784     );
1785   }
1786 }
1787
1788 sub generate_pdf {
1789   my ($order, $pdf_ref, $params) = @_;
1790
1791   my @errors = ();
1792
1793   my $print_form = Form->new('');
1794   $print_form->{type}        = $order->type;
1795   $print_form->{formname}    = $params->{formname} || $order->type;
1796   $print_form->{format}      = $params->{format}   || 'pdf';
1797   $print_form->{media}       = $params->{media}    || 'file';
1798   $print_form->{groupitems}  = $params->{groupitems};
1799   $print_form->{media}       = 'file'                             if $print_form->{media} eq 'screen';
1800
1801   $order->language($params->{language});
1802   $order->flatten_to_form($print_form, format_amounts => 1);
1803
1804   my $template_ext;
1805   my $template_type;
1806   if ($print_form->{format} =~ /(opendocument|oasis)/i) {
1807     $template_ext  = 'odt';
1808     $template_type = 'OpenDocument';
1809   }
1810
1811   # search for the template
1812   my ($template_file, @template_files) = SL::Helper::CreatePDF->find_template(
1813     name        => $print_form->{formname},
1814     extension   => $template_ext,
1815     email       => $print_form->{media} eq 'email',
1816     language    => $params->{language},
1817     printer_id  => $print_form->{printer_id},  # todo
1818   );
1819
1820   if (!defined $template_file) {
1821     push @errors, $::locale->text('Cannot find matching template for this print request. Please contact your template maintainer. I tried these: #1.', join ', ', map { "'$_'"} @template_files);
1822   }
1823
1824   return @errors if scalar @errors;
1825
1826   $print_form->throw_on_error(sub {
1827     eval {
1828       $print_form->prepare_for_printing;
1829
1830       $$pdf_ref = SL::Helper::CreatePDF->create_pdf(
1831         format        => $print_form->{format},
1832         template_type => $template_type,
1833         template      => $template_file,
1834         variables     => $print_form,
1835         variable_content_types => {
1836           longdescription => 'html',
1837           partnotes       => 'html',
1838           notes           => 'html',
1839         },
1840       );
1841       1;
1842     } || push @errors, ref($EVAL_ERROR) eq 'SL::X::FormError' ? $EVAL_ERROR->error : $EVAL_ERROR;
1843   });
1844
1845   return @errors;
1846 }
1847
1848 sub get_files_for_email_dialog {
1849   my ($self) = @_;
1850
1851   my %files = map { ($_ => []) } qw(versions files vc_files part_files);
1852
1853   return %files if !$::instance_conf->get_doc_storage;
1854
1855   if ($self->order->id) {
1856     $files{versions} = [ SL::File->get_all_versions(object_id => $self->order->id,              object_type => $self->order->type, file_type => 'document') ];
1857     $files{files}    = [ SL::File->get_all(         object_id => $self->order->id,              object_type => $self->order->type, file_type => 'attachment') ];
1858     $files{vc_files} = [ SL::File->get_all(         object_id => $self->order->{$self->cv}->id, object_type => $self->cv,          file_type => 'attachment') ];
1859   }
1860
1861   my @parts =
1862     uniq_by { $_->{id} }
1863     map {
1864       +{ id         => $_->part->id,
1865          partnumber => $_->part->partnumber }
1866     } @{$self->order->items_sorted};
1867
1868   foreach my $part (@parts) {
1869     my @pfiles = SL::File->get_all(object_id => $part->{id}, object_type => 'part');
1870     push @{ $files{part_files} }, map { +{ %{ $_ }, partnumber => $part->{partnumber} } } @pfiles;
1871   }
1872
1873   foreach my $key (keys %files) {
1874     $files{$key} = [ sort_by { lc $_->{db_file}->{file_name} } @{ $files{$key} } ];
1875   }
1876
1877   return %files;
1878 }
1879
1880 sub make_periodic_invoices_config_from_yaml {
1881   my ($yaml_config) = @_;
1882
1883   return if !$yaml_config;
1884   my $attr = SL::YAML::Load($yaml_config);
1885   return if 'HASH' ne ref $attr;
1886   return SL::DB::PeriodicInvoicesConfig->new(%$attr);
1887 }
1888
1889
1890 sub get_periodic_invoices_status {
1891   my ($self, $config) = @_;
1892
1893   return                      if $self->type ne sales_order_type();
1894   return t8('not configured') if !$config;
1895
1896   my $active = ('HASH' eq ref $config)                           ? $config->{active}
1897              : ('SL::DB::PeriodicInvoicesConfig' eq ref $config) ? $config->active
1898              :                                                     die "Cannot get status of periodic invoices config";
1899
1900   return $active ? t8('active') : t8('inactive');
1901 }
1902
1903 sub get_title_for {
1904   my ($self, $action) = @_;
1905
1906   return '' if none { lc($action)} qw(add edit);
1907
1908   # for locales:
1909   # $::locale->text("Add Sales Order");
1910   # $::locale->text("Add Purchase Order");
1911   # $::locale->text("Add Quotation");
1912   # $::locale->text("Add Request for Quotation");
1913   # $::locale->text("Edit Sales Order");
1914   # $::locale->text("Edit Purchase Order");
1915   # $::locale->text("Edit Quotation");
1916   # $::locale->text("Edit Request for Quotation");
1917
1918   $action = ucfirst(lc($action));
1919   return $self->type eq sales_order_type()       ? $::locale->text("$action Sales Order")
1920        : $self->type eq purchase_order_type()    ? $::locale->text("$action Purchase Order")
1921        : $self->type eq sales_quotation_type()   ? $::locale->text("$action Quotation")
1922        : $self->type eq request_quotation_type() ? $::locale->text("$action Request for Quotation")
1923        : '';
1924 }
1925
1926 sub get_item_cvpartnumber {
1927   my ($self, $item) = @_;
1928
1929   if ($self->cv eq 'vendor') {
1930     my @mms = grep { $_->make eq $self->order->customervendor->id } @{$item->part->makemodels};
1931     $item->{cvpartnumber} = $mms[0]->model if scalar @mms;
1932   } elsif ($self->cv eq 'customer') {
1933     my @cps = grep { $_->customer_id eq $self->order->customervendor->id } @{$item->part->customerprices};
1934     $item->{cvpartnumber} = $cps[0]->customer_partnumber if scalar @cps;
1935   }
1936 }
1937
1938 sub sales_order_type {
1939   'sales_order';
1940 }
1941
1942 sub purchase_order_type {
1943   'purchase_order';
1944 }
1945
1946 sub sales_quotation_type {
1947   'sales_quotation';
1948 }
1949
1950 sub request_quotation_type {
1951   'request_quotation';
1952 }
1953
1954 sub nr_key {
1955   return $_[0]->type eq sales_order_type()       ? 'ordnumber'
1956        : $_[0]->type eq purchase_order_type()    ? 'ordnumber'
1957        : $_[0]->type eq sales_quotation_type()   ? 'quonumber'
1958        : $_[0]->type eq request_quotation_type() ? 'quonumber'
1959        : '';
1960 }
1961
1962 1;
1963
1964 __END__
1965
1966 =encoding utf-8
1967
1968 =head1 NAME
1969
1970 SL::Controller::Order - controller for orders
1971
1972 =head1 SYNOPSIS
1973
1974 This is a new form to enter orders, completely rewritten with the use
1975 of controller and java script techniques.
1976
1977 The aim is to provide the user a better experience and a faster workflow. Also
1978 the code should be more readable, more reliable and better to maintain.
1979
1980 =head2 Key Features
1981
1982 =over 4
1983
1984 =item *
1985
1986 One input row, so that input happens every time at the same place.
1987
1988 =item *
1989
1990 Use of pickers where possible.
1991
1992 =item *
1993
1994 Possibility to enter more than one item at once.
1995
1996 =item *
1997
1998 Item list in a scrollable area, so that the workflow buttons stay at
1999 the bottom.
2000
2001 =item *
2002
2003 Reordering item rows with drag and drop is possible. Sorting item rows is
2004 possible (by partnumber, description, qty, sellprice and discount for now).
2005
2006 =item *
2007
2008 No C<update> is necessary. All entries and calculations are managed
2009 with ajax-calls and the page only reloads on C<save>.
2010
2011 =item *
2012
2013 User can see changes immediately, because of the use of java script
2014 and ajax.
2015
2016 =back
2017
2018 =head1 CODE
2019
2020 =head2 Layout
2021
2022 =over 4
2023
2024 =item * C<SL/Controller/Order.pm>
2025
2026 the controller
2027
2028 =item * C<template/webpages/order/form.html>
2029
2030 main form
2031
2032 =item * C<template/webpages/order/tabs/basic_data.html>
2033
2034 Main tab for basic_data.
2035
2036 This is the only tab here for now. "linked records" and "webdav" tabs are
2037 reused from generic code.
2038
2039 =over 4
2040
2041 =item * C<template/webpages/order/tabs/_business_info_row.html>
2042
2043 For displaying information on business type
2044
2045 =item * C<template/webpages/order/tabs/_item_input.html>
2046
2047 The input line for items
2048
2049 =item * C<template/webpages/order/tabs/_row.html>
2050
2051 One row for already entered items
2052
2053 =item * C<template/webpages/order/tabs/_tax_row.html>
2054
2055 Displaying tax information
2056
2057 =item * C<template/webpages/order/tabs/_multi_items_dialog.html>
2058
2059 Dialog for entering more than one item at once
2060
2061 =item * C<template/webpages/order/tabs/_multi_items_result.html>
2062
2063 Results for the filter in the multi items dialog
2064
2065 =item * C<template/webpages/order/tabs/_price_sources_dialog.html>
2066
2067 Dialog for selecting price and discount sources
2068
2069 =back
2070
2071 =item * C<js/kivi.Order.js>
2072
2073 java script functions
2074
2075 =back
2076
2077 =head1 TODO
2078
2079 =over 4
2080
2081 =item * testing
2082
2083 =item * currency
2084
2085 =item * credit limit
2086
2087 =item * more workflows (quotation, rfq)
2088
2089 =item * price sources: little symbols showing better price / better discount
2090
2091 =item * select units in input row?
2092
2093 =item * custom shipto address
2094
2095 =item * check for direct delivery (workflow sales order -> purchase order)
2096
2097 =item * language / part translations
2098
2099 =item * access rights
2100
2101 =item * display weights
2102
2103 =item * history
2104
2105 =item * mtime check
2106
2107 =item * optional client/user behaviour
2108
2109 (transactions has to be set - department has to be set -
2110  force project if enabled in client config - transport cost reminder)
2111
2112 =back
2113
2114 =head1 KNOWN BUGS AND CAVEATS
2115
2116 =over 4
2117
2118 =item *
2119
2120 Customer discount is not displayed as a valid discount in price source popup
2121 (this might be a bug in price sources)
2122
2123 (I cannot reproduce this (Bernd))
2124
2125 =item *
2126
2127 No indication that <shift>-up/down expands/collapses second row.
2128
2129 =item *
2130
2131 Inline creation of parts is not currently supported
2132
2133 =item *
2134
2135 Table header is not sticky in the scrolling area.
2136
2137 =item *
2138
2139 Sorting does not include C<position>, neither does reordering.
2140
2141 This behavior was implemented intentionally. But we can discuss, which behavior
2142 should be implemented.
2143
2144 =item *
2145
2146 C<show_multi_items_dialog> does not use the currently inserted string for
2147 filtering.
2148
2149 =back
2150
2151 =head1 To discuss / Nice to have
2152
2153 =over 4
2154
2155 =item *
2156
2157 How to expand/collapse second row. Now it can be done clicking the icon or
2158 <shift>-up/down.
2159
2160 =item *
2161
2162 Possibility to change longdescription in input row?
2163
2164 =item *
2165
2166 Possibility to select PriceSources in input row?
2167
2168 =item *
2169
2170 This controller uses a (changed) copy of the template for the PriceSource
2171 dialog. Maybe there could be used one code source.
2172
2173 =item *
2174
2175 Rounding-differences between this controller (PriceTaxCalculator) and the old
2176 form. This is not only a problem here, but also in all parts using the PTC.
2177 There exists a ticket and a patch. This patch should be testet.
2178
2179 =item *
2180
2181 An indicator, if the actual inputs are saved (like in an
2182 editor or on text processing application).
2183
2184 =item *
2185
2186 A warning when leaving the page without saveing unchanged inputs.
2187
2188
2189 =back
2190
2191 =head1 AUTHOR
2192
2193 Bernd Bleßmann E<lt>bernd@kivitendo-premium.deE<gt>
2194
2195 =cut