SL/Controller/Order.pm

   1 package SL::Controller::Order;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use SL::Helper::Flash qw(flash_later);
   7 use SL::Presenter::Tag qw(select_tag hidden_tag);
   8 use SL::Locale::String qw(t8);
   9 use SL::SessionFile::Random;
  10 use SL::PriceSource;
  11 use SL::Webdav;
  12 use SL::File;
  13 use SL::Util qw(trim);
  14 use SL::DB::Order;
  15 use SL::DB::Default;
  16 use SL::DB::Unit;
  17 use SL::DB::Part;
  18 use SL::DB::PartsGroup;
  19 use SL::DB::Printer;
  20 use SL::DB::Language;
  21 use SL::DB::RecordLink;
  22
  23 use SL::Helper::CreatePDF qw(:all);
  24 use SL::Helper::PrintOptions;
  25 use SL::Helper::ShippedQty;
  26
  27 use SL::Controller::Helper::GetModels;
  28
  29 use List::Util qw(first);
  30 use List::UtilsBy qw(sort_by uniq_by);
  31 use List::MoreUtils qw(any none pairwise first_index);
  32 use English qw(-no_match_vars);
  33 use File::Spec;
  34 use Cwd;
  35 use Sort::Naturally;
  36
  37 use Rose::Object::MakeMethods::Generic
  38 (
  39  scalar => [ qw(item_ids_to_delete) ],
  40  'scalar --get_set_init' => [ qw(order valid_types type cv p multi_items_models all_price_factors) ],
  41 );
  42
  43
  44 # safety
  45 __PACKAGE__->run_before('check_auth');
  46
  47 __PACKAGE__->run_before('recalc',
  48                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice print send_email) ]);
  49
  50 __PACKAGE__->run_before('get_unalterable_data',
  51                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice print send_email) ]);
  52
  53 #
  54 # actions
  55 #
  56
  57 # add a new order
  58 sub action_add {
  59   my ($self) = @_;
  60
  61   $self->order->transdate(DateTime->now_local());
  62   my $extra_days = $self->{type} eq 'sales_quotation' ? $::instance_conf->get_reqdate_interval       :
  63                    $self->{type} eq 'sales_order'     ? $::instance_conf->get_delivery_date_interval : 1;
  64   $self->order->reqdate(DateTime->today_local->next_workday(extra_days => $extra_days)) if !$self->order->reqdate;
  65
  66
  67   $self->pre_render();
  68   $self->render(
  69     'order/form',
  70     title => $self->get_title_for('add'),
  71     %{$self->{template_args}}
  72   );
  73 }
  74
  75 # edit an existing order
  76 sub action_edit {
  77   my ($self) = @_;
  78
  79   if ($::form->{id}) {
  80     $self->load_order;
  81
  82   } else {
  83     # this is to edit an order from an unsaved order object
  84
  85     # set item ids to new fake id, to identify them as new items
  86     foreach my $item (@{$self->order->items_sorted}) {
  87       $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
  88     }
  89     # trigger rendering values for second row/longdescription as hidden,
  90     # because they are loaded only on demand. So we need to keep the values
  91     # from the source.
  92     $_->{render_second_row}      = 1 for @{ $self->order->items_sorted };
  93     $_->{render_longdescription} = 1 for @{ $self->order->items_sorted };
  94   }
  95
  96   $self->recalc();
  97   $self->pre_render();
  98   $self->render(
  99     'order/form',
 100     title => $self->get_title_for('edit'),
 101     %{$self->{template_args}}
 102   );
 103 }
 104
 105 # edit a collective order (consisting of one or more existing orders)
 106 sub action_edit_collective {
 107   my ($self) = @_;
 108
 109   # collect order ids
 110   my @multi_ids = map {
 111     $_ =~ m{^multi_id_(\d+)$} && $::form->{'multi_id_' . $1} && $::form->{'trans_id_' . $1} && $::form->{'trans_id_' . $1}
 112   } grep { $_ =~ m{^multi_id_\d+$} } keys %$::form;
 113
 114   # fall back to add if no ids are given
 115   if (scalar @multi_ids == 0) {
 116     $self->action_add();
 117     return;
 118   }
 119
 120   # fall back to save as new if only one id is given
 121   if (scalar @multi_ids == 1) {
 122     $self->order(SL::DB::Order->new(id => $multi_ids[0])->load);
 123     $self->action_save_as_new();
 124     return;
 125   }
 126
 127   # make new order from given orders
 128   my @multi_orders = map { SL::DB::Order->new(id => $_)->load } @multi_ids;
 129   $self->{converted_from_oe_id} = join ' ', map { $_->id } @multi_orders;
 130   $self->order(SL::DB::Order->new_from_multi(\@multi_orders, sort_sources_by => 'transdate'));
 131
 132   $self->action_edit();
 133 }
 134
 135 # delete the order
 136 sub action_delete {
 137   my ($self) = @_;
 138
 139   my $errors = $self->delete();
 140
 141   if (scalar @{ $errors }) {
 142     $self->js->flash('error', $_) foreach @{ $errors };
 143     return $self->js->render();
 144   }
 145
 146   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been deleted')
 147            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been deleted')
 148            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been deleted')
 149            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been deleted')
 150            : '';
 151   flash_later('info', $text);
 152
 153   my @redirect_params = (
 154     action => 'add',
 155     type   => $self->type,
 156   );
 157
 158   $self->redirect_to(@redirect_params);
 159 }
 160
 161 # save the order
 162 sub action_save {
 163   my ($self) = @_;
 164
 165   my $errors = $self->save();
 166
 167   if (scalar @{ $errors }) {
 168     $self->js->flash('error', $_) foreach @{ $errors };
 169     return $self->js->render();
 170   }
 171
 172   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
 173            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
 174            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
 175            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
 176            : '';
 177   flash_later('info', $text);
 178
 179   my @redirect_params = (
 180     action => 'edit',
 181     type   => $self->type,
 182     id     => $self->order->id,
 183   );
 184
 185   $self->redirect_to(@redirect_params);
 186 }
 187
 188 # save the order as new document an open it for edit
 189 sub action_save_as_new {
 190   my ($self) = @_;
 191
 192   my $order = $self->order;
 193
 194   if (!$order->id) {
 195     $self->js->flash('error', t8('This object has not been saved yet.'));
 196     return $self->js->render();
 197   }
 198
 199   # load order from db to check if values changed
 200   my $saved_order = SL::DB::Order->new(id => $order->id)->load;
 201
 202   my %new_attrs;
 203   # Lets assign a new number if the user hasn't changed the previous one.
 204   # If it has been changed manually then use it as-is.
 205   $new_attrs{number}    = (trim($order->number) eq $saved_order->number)
 206                         ? ''
 207                         : trim($order->number);
 208
 209   # Clear transdate unless changed
 210   $new_attrs{transdate} = ($order->transdate == $saved_order->transdate)
 211                         ? DateTime->today_local
 212                         : $order->transdate;
 213
 214   # Set new reqdate unless changed
 215   if ($order->reqdate == $saved_order->reqdate) {
 216     my $extra_days = $self->{type} eq 'sales_quotation' ? $::instance_conf->get_reqdate_interval       :
 217                      $self->{type} eq 'sales_order'     ? $::instance_conf->get_delivery_date_interval : 1;
 218     $new_attrs{reqdate} = DateTime->today_local->next_workday(extra_days => $extra_days);
 219   } else {
 220     $new_attrs{reqdate} = $order->reqdate;
 221   }
 222
 223   # Update employee
 224   $new_attrs{employee}  = SL::DB::Manager::Employee->current;
 225
 226   # Create new record from current one
 227   $self->order(SL::DB::Order->new_from($order, destination_type => $order->type, attributes => \%new_attrs));
 228
 229   # no linked records on save as new
 230   delete $::form->{$_} for qw(converted_from_oe_id converted_from_orderitems_ids);
 231
 232   # save
 233   $self->action_save();
 234 }
 235
 236 # print the order
 237 #
 238 # This is called if "print" is pressed in the print dialog.
 239 # If PDF creation was requested and succeeded, the pdf is stored in a session
 240 # file and the filename is stored as session value with an unique key. A
 241 # javascript function with this key is then called. This function calls the
 242 # download action below (action_download_pdf), which offers the file for
 243 # download.
 244 sub action_print {
 245   my ($self) = @_;
 246
 247   my $errors = $self->save();
 248
 249   if (scalar @{ $errors }) {
 250     $self->js->flash('error', $_) foreach @{ $errors };
 251     return $self->js->render();
 252   }
 253
 254   $self->js->val('#id', $self->order->id)
 255            ->val('#order_' . $self->nr_key(), $self->order->number);
 256
 257   my $format      = $::form->{print_options}->{format};
 258   my $media       = $::form->{print_options}->{media};
 259   my $formname    = $::form->{print_options}->{formname};
 260   my $copies      = $::form->{print_options}->{copies};
 261   my $groupitems  = $::form->{print_options}->{groupitems};
 262
 263   # only pdf and opendocument by now
 264   if (none { $format eq $_ } qw(pdf opendocument opendocument_pdf)) {
 265     return $self->js->flash('error', t8('Format \'#1\' is not supported yet/anymore.', $format))->render;
 266   }
 267
 268   # only screen or printer by now
 269   if (none { $media eq $_ } qw(screen printer)) {
 270     return $self->js->flash('error', t8('Media \'#1\' is not supported yet/anymore.', $media))->render;
 271   }
 272
 273   my $language;
 274   $language = SL::DB::Language->new(id => $::form->{print_options}->{language_id})->load if $::form->{print_options}->{language_id};
 275
 276   # create a form for generate_attachment_filename
 277   my $form   = Form->new;
 278   $form->{$self->nr_key()}  = $self->order->number;
 279   $form->{type}             = $self->type;
 280   $form->{format}           = $format;
 281   $form->{formname}         = $formname;
 282   $form->{language}         = '_' . $language->template_code if $language;
 283   my $pdf_filename          = $form->generate_attachment_filename();
 284
 285   my $pdf;
 286   my @errors = generate_pdf($self->order, \$pdf, { format     => $format,
 287                                                    formname   => $formname,
 288                                                    language   => $language,
 289                                                    groupitems => $groupitems });
 290   if (scalar @errors) {
 291     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render;
 292   }
 293
 294   if ($media eq 'screen') {
 295     # screen/download
 296     my $sfile = SL::SessionFile::Random->new(mode => "w");
 297     $sfile->fh->print($pdf);
 298     $sfile->fh->close;
 299
 300     my $key = join('_', Time::HiRes::gettimeofday(), int rand 1000000000000);
 301     $::auth->set_session_value("Order::print-${key}" => $sfile->file_name);
 302
 303     $self->js
 304     ->run('kivi.Order.download_pdf', $pdf_filename, $key)
 305     ->flash('info', t8('The PDF has been created'));
 306
 307   } elsif ($media eq 'printer') {
 308     # printer
 309     my $printer_id = $::form->{print_options}->{printer_id};
 310     SL::DB::Printer->new(id => $printer_id)->load->print_document(
 311       copies  => $copies,
 312       content => $pdf,
 313     );
 314
 315     $self->js->flash('info', t8('The PDF has been printed'));
 316   }
 317
 318   # copy file to webdav folder
 319   if ($self->order->number && $::instance_conf->get_webdav_documents) {
 320     my $webdav = SL::Webdav->new(
 321       type     => $self->type,
 322       number   => $self->order->number,
 323     );
 324     my $webdav_file = SL::Webdav::File->new(
 325       webdav   => $webdav,
 326       filename => $pdf_filename,
 327     );
 328     eval {
 329       $webdav_file->store(data => \$pdf);
 330       1;
 331     } or do {
 332       $self->js->flash('error', t8('Storing PDF to webdav folder failed: #1', $@));
 333     }
 334   }
 335   if ($self->order->number && $::instance_conf->get_doc_storage) {
 336     eval {
 337       SL::File->save(object_id     => $self->order->id,
 338                      object_type   => $self->type,
 339                      mime_type     => 'application/pdf',
 340                      source        => 'created',
 341                      file_type     => 'document',
 342                      file_name     => $pdf_filename,
 343                      file_contents => $pdf);
 344       1;
 345     } or do {
 346       $self->js->flash('error', t8('Storing PDF in storage backend failed: #1', $@));
 347     }
 348   }
 349   $self->js->render;
 350 }
 351
 352 # offer pdf for download
 353 #
 354 # It needs to get the key for the session value to get the pdf file.
 355 sub action_download_pdf {
 356   my ($self) = @_;
 357
 358   my $key = $::form->{key};
 359   my $tmp_filename = $::auth->get_session_value("Order::print-${key}");
 360   return $self->send_file(
 361     $tmp_filename,
 362     type => 'application/pdf',
 363     name => $::form->{pdf_filename},
 364   );
 365 }
 366
 367 # open the email dialog
 368 sub action_show_email_dialog {
 369   my ($self) = @_;
 370
 371   my $cv_method = $self->cv;
 372
 373   if (!$self->order->$cv_method) {
 374     return $self->js->flash('error', $self->cv eq 'customer' ? t8('Cannot send E-mail without customer given') : t8('Cannot send E-mail without vendor given'))
 375                     ->render($self);
 376   }
 377
 378   my $email_form;
 379   $email_form->{to}   = $self->order->contact->cp_email if $self->order->contact;
 380   $email_form->{to} ||= $self->order->$cv_method->email;
 381   $email_form->{cc}   = $self->order->$cv_method->cc;
 382   $email_form->{bcc}  = join ', ', grep $_, $self->order->$cv_method->bcc, SL::DB::Default->get->global_bcc;
 383   # Todo: get addresses from shipto, if any
 384
 385   my $form = Form->new;
 386   $form->{$self->nr_key()}  = $self->order->number;
 387   $form->{formname}         = $self->type;
 388   $form->{type}             = $self->type;
 389   $form->{language}         = 'de';
 390   $form->{format}           = 'pdf';
 391
 392   $email_form->{subject}             = $form->generate_email_subject();
 393   $email_form->{attachment_filename} = $form->generate_attachment_filename();
 394   $email_form->{message}             = $form->generate_email_body();
 395   $email_form->{js_send_function}    = 'kivi.Order.send_email()';
 396
 397   my %files = $self->get_files_for_email_dialog();
 398   my $dialog_html = $self->render('common/_send_email_dialog', { output => 0 },
 399                                   email_form  => $email_form,
 400                                   show_bcc    => $::auth->assert('email_bcc', 'may fail'),
 401                                   FILES       => \%files,
 402                                   is_customer => $self->cv eq 'customer',
 403   );
 404
 405   $self->js
 406       ->run('kivi.Order.show_email_dialog', $dialog_html)
 407       ->reinit_widgets
 408       ->render($self);
 409 }
 410
 411 # send email
 412 #
 413 # Todo: handling error messages: flash is not displayed in dialog, but in the main form
 414 sub action_send_email {
 415   my ($self) = @_;
 416
 417   my $errors = $self->save();
 418
 419   if (scalar @{ $errors }) {
 420     $self->js->run('kivi.Order.close_email_dialog');
 421     $self->js->flash('error', $_) foreach @{ $errors };
 422     return $self->js->render();
 423   }
 424
 425   $self->js->val('#id', $self->order->id)
 426            ->val('#order_' . $self->nr_key(), $self->order->number);
 427
 428   my $email_form  = delete $::form->{email_form};
 429   my %field_names = (to => 'email');
 430
 431   $::form->{ $field_names{$_} // $_ } = $email_form->{$_} for keys %{ $email_form };
 432
 433   # for Form::cleanup which may be called in Form::send_email
 434   $::form->{cwd}    = getcwd();
 435   $::form->{tmpdir} = $::lx_office_conf{paths}->{userspath};
 436
 437   $::form->{$_}     = $::form->{print_options}->{$_} for keys %{ $::form->{print_options} };
 438   $::form->{media}  = 'email';
 439
 440   if (($::form->{attachment_policy} // '') !~ m{^(?:old_file|no_file)$}) {
 441     my $language;
 442     $language = SL::DB::Language->new(id => $::form->{print_options}->{language_id})->load if $::form->{print_options}->{language_id};
 443
 444     my $pdf;
 445     my @errors = generate_pdf($self->order, \$pdf, {media      => $::form->{media},
 446                                                     format     => $::form->{print_options}->{format},
 447                                                     formname   => $::form->{print_options}->{formname},
 448                                                     language   => $language,
 449                                                     groupitems => $::form->{print_options}->{groupitems}});
 450     if (scalar @errors) {
 451       return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render($self);
 452     }
 453
 454     my $sfile = SL::SessionFile::Random->new(mode => "w");
 455     $sfile->fh->print($pdf);
 456     $sfile->fh->close;
 457
 458     $::form->{tmpfile} = $sfile->file_name;
 459     $::form->{tmpdir}  = $sfile->get_path; # for Form::cleanup which may be called in Form::send_email
 460   }
 461
 462   $::form->send_email(\%::myconfig, 'pdf');
 463
 464   # internal notes
 465   my $intnotes = $self->order->intnotes;
 466   $intnotes   .= "\n\n" if $self->order->intnotes;
 467   $intnotes   .= t8('[email]')                                                                                        . "\n";
 468   $intnotes   .= t8('Date')       . ": " . $::locale->format_date_object(DateTime->now_local, precision => 'seconds') . "\n";
 469   $intnotes   .= t8('To (email)') . ": " . $::form->{email}                                                           . "\n";
 470   $intnotes   .= t8('Cc')         . ": " . $::form->{cc}                                                              . "\n"    if $::form->{cc};
 471   $intnotes   .= t8('Bcc')        . ": " . $::form->{bcc}                                                             . "\n"    if $::form->{bcc};
 472   $intnotes   .= t8('Subject')    . ": " . $::form->{subject}                                                         . "\n\n";
 473   $intnotes   .= t8('Message')    . ": " . $::form->{message};
 474
 475   $self->order->update_attributes(intnotes => $intnotes);
 476
 477   $self->js
 478       ->val('#order_intnotes', $intnotes)
 479       ->run('kivi.Order.close_email_dialog')
 480       ->flash('info', t8('The email has been sent.'))
 481       ->render($self);
 482 }
 483
 484 # open the periodic invoices config dialog
 485 #
 486 # If there are values in the form (i.e. dialog was opened before),
 487 # then use this values. Create new ones, else.
 488 sub action_show_periodic_invoices_config_dialog {
 489   my ($self) = @_;
 490
 491   my $config = make_periodic_invoices_config_from_yaml(delete $::form->{config});
 492   $config  ||= SL::DB::Manager::PeriodicInvoicesConfig->find_by(oe_id => $::form->{id}) if $::form->{id};
 493   $config  ||= SL::DB::PeriodicInvoicesConfig->new(periodicity             => 'm',
 494                                                    order_value_periodicity => 'p', # = same as periodicity
 495                                                    start_date_as_date      => $::form->{transdate_as_date} || $::form->current_date,
 496                                                    extend_automatically_by => 12,
 497                                                    active                  => 1,
 498                                                    email_subject           => GenericTranslations->get(
 499                                                                                 language_id      => $::form->{language_id},
 500                                                                                 translation_type =>"preset_text_periodic_invoices_email_subject"),
 501                                                    email_body              => GenericTranslations->get(
 502                                                                                 language_id      => $::form->{language_id},
 503                                                                                 translation_type =>"preset_text_periodic_invoices_email_body"),
 504   );
 505   $config->periodicity('m')             if none { $_ eq $config->periodicity             }       @SL::DB::PeriodicInvoicesConfig::PERIODICITIES;
 506   $config->order_value_periodicity('p') if none { $_ eq $config->order_value_periodicity } ('p', @SL::DB::PeriodicInvoicesConfig::ORDER_VALUE_PERIODICITIES);
 507
 508   $::form->get_lists(printers => "ALL_PRINTERS",
 509                      charts   => { key       => 'ALL_CHARTS',
 510                                    transdate => 'current_date' });
 511
 512   $::form->{AR} = [ grep { $_->{link} =~ m/(?:^|:)AR(?::|$)/ } @{ $::form->{ALL_CHARTS} } ];
 513
 514   if ($::form->{customer_id}) {
 515     $::form->{ALL_CONTACTS} = SL::DB::Manager::Contact->get_all_sorted(where => [ cp_cv_id => $::form->{customer_id} ]);
 516     $::form->{email_recipient_invoice_address} = SL::DB::Manager::Customer->find_by(id => $::form->{customer_id})->invoice_mail;
 517   }
 518
 519   $self->render('oe/edit_periodic_invoices_config', { layout => 0 },
 520                 popup_dialog             => 1,
 521                 popup_js_close_function  => 'kivi.Order.close_periodic_invoices_config_dialog()',
 522                 popup_js_assign_function => 'kivi.Order.assign_periodic_invoices_config()',
 523                 config                   => $config,
 524                 %$::form);
 525 }
 526
 527 # assign the values of the periodic invoices config dialog
 528 # as yaml in the hidden tag and set the status.
 529 sub action_assign_periodic_invoices_config {
 530   my ($self) = @_;
 531
 532   $::form->isblank('start_date_as_date', $::locale->text('The start date is missing.'));
 533
 534   my $config = { active                     => $::form->{active}       ? 1 : 0,
 535                  terminated                 => $::form->{terminated}   ? 1 : 0,
 536                  direct_debit               => $::form->{direct_debit} ? 1 : 0,
 537                  periodicity                => (any { $_ eq $::form->{periodicity}             }       @SL::DB::PeriodicInvoicesConfig::PERIODICITIES)              ? $::form->{periodicity}             : 'm',
 538                  order_value_periodicity    => (any { $_ eq $::form->{order_value_periodicity} } ('p', @SL::DB::PeriodicInvoicesConfig::ORDER_VALUE_PERIODICITIES)) ? $::form->{order_value_periodicity} : 'p',
 539                  start_date_as_date         => $::form->{start_date_as_date},
 540                  end_date_as_date           => $::form->{end_date_as_date},
 541                  first_billing_date_as_date => $::form->{first_billing_date_as_date},
 542                  print                      => $::form->{print}      ? 1                         : 0,
 543                  printer_id                 => $::form->{print}      ? $::form->{printer_id} * 1 : undef,
 544                  copies                     => $::form->{copies} * 1 ? $::form->{copies}         : 1,
 545                  extend_automatically_by    => $::form->{extend_automatically_by}    * 1 || undef,
 546                  ar_chart_id                => $::form->{ar_chart_id} * 1,
 547                  send_email                 => $::form->{send_email} ? 1 : 0,
 548                  email_recipient_contact_id => $::form->{email_recipient_contact_id} * 1 || undef,
 549                  email_recipient_address    => $::form->{email_recipient_address},
 550                  email_sender               => $::form->{email_sender},
 551                  email_subject              => $::form->{email_subject},
 552                  email_body                 => $::form->{email_body},
 553                };
 554
 555   my $periodic_invoices_config = YAML::Dump($config);
 556
 557   my $status = $self->get_periodic_invoices_status($config);
 558
 559   $self->js
 560     ->remove('#order_periodic_invoices_config')
 561     ->insertAfter(hidden_tag('order.periodic_invoices_config', $periodic_invoices_config), '#periodic_invoices_status')
 562     ->run('kivi.Order.close_periodic_invoices_config_dialog')
 563     ->html('#periodic_invoices_status', $status)
 564     ->flash('info', t8('The periodic invoices config has been assigned.'))
 565     ->render($self);
 566 }
 567
 568 sub action_get_has_active_periodic_invoices {
 569   my ($self) = @_;
 570
 571   my $config = make_periodic_invoices_config_from_yaml(delete $::form->{config});
 572   $config  ||= SL::DB::Manager::PeriodicInvoicesConfig->find_by(oe_id => $::form->{id}) if $::form->{id};
 573
 574   my $has_active_periodic_invoices =
 575        $self->type eq sales_order_type()
 576     && $config
 577     && $config->active
 578     && (!$config->end_date || ($config->end_date > DateTime->today_local))
 579     && $config->get_previous_billed_period_start_date;
 580
 581   $_[0]->render(\ !!$has_active_periodic_invoices, { type => 'text' });
 582 }
 583
 584 # save the order and redirect to the frontend subroutine for a new
 585 # delivery order
 586 sub action_save_and_delivery_order {
 587   my ($self) = @_;
 588
 589   my $errors = $self->save();
 590
 591   if (scalar @{ $errors }) {
 592     $self->js->flash('error', $_) foreach @{ $errors };
 593     return $self->js->render();
 594   }
 595
 596   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
 597            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
 598            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
 599            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
 600            : '';
 601   flash_later('info', $text);
 602
 603   my @redirect_params = (
 604     controller => 'oe.pl',
 605     action     => 'oe_delivery_order_from_order',
 606     id         => $self->order->id,
 607   );
 608
 609   $self->redirect_to(@redirect_params);
 610 }
 611
 612 # save the order and redirect to the frontend subroutine for a new
 613 # invoice
 614 sub action_save_and_invoice {
 615   my ($self) = @_;
 616
 617   my $errors = $self->save();
 618
 619   if (scalar @{ $errors }) {
 620     $self->js->flash('error', $_) foreach @{ $errors };
 621     return $self->js->render();
 622   }
 623
 624   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
 625            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
 626            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
 627            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
 628            : '';
 629   flash_later('info', $text);
 630
 631   my @redirect_params = (
 632     controller => 'oe.pl',
 633     action     => 'oe_invoice_from_order',
 634     id         => $self->order->id,
 635   );
 636
 637   $self->redirect_to(@redirect_params);
 638 }
 639
 640 # workflow from sales quotation to sales order
 641 sub action_sales_order {
 642   $_[0]->workflow_sales_or_purchase_order();
 643 }
 644
 645 # workflow from rfq to purchase order
 646 sub action_purchase_order {
 647   $_[0]->workflow_sales_or_purchase_order();
 648 }
 649
 650 # set form elements in respect to a changed customer or vendor
 651 #
 652 # This action is called on an change of the customer/vendor picker.
 653 sub action_customer_vendor_changed {
 654   my ($self) = @_;
 655
 656   setup_order_from_cv($self->order);
 657   $self->recalc();
 658
 659   my $cv_method = $self->cv;
 660
 661   if ($self->order->$cv_method->contacts && scalar @{ $self->order->$cv_method->contacts } > 0) {
 662     $self->js->show('#cp_row');
 663   } else {
 664     $self->js->hide('#cp_row');
 665   }
 666
 667   if ($self->order->$cv_method->shipto && scalar @{ $self->order->$cv_method->shipto } > 0) {
 668     $self->js->show('#shipto_row');
 669   } else {
 670     $self->js->hide('#shipto_row');
 671   }
 672
 673   $self->js->val( '#order_salesman_id',      $self->order->salesman_id)        if $self->order->is_sales;
 674
 675   $self->js
 676     ->replaceWith('#order_cp_id',            $self->build_contact_select)
 677     ->replaceWith('#order_shipto_id',        $self->build_shipto_select)
 678     ->replaceWith('#business_info_row',      $self->build_business_info_row)
 679     ->val(        '#order_taxzone_id',       $self->order->taxzone_id)
 680     ->val(        '#order_taxincluded',      $self->order->taxincluded)
 681     ->val(        '#order_payment_id',       $self->order->payment_id)
 682     ->val(        '#order_delivery_term_id', $self->order->delivery_term_id)
 683     ->val(        '#order_intnotes',         $self->order->intnotes)
 684     ->val(        '#language_id',            $self->order->$cv_method->language_id)
 685     ->focus(      '#order_' . $self->cv . '_id');
 686
 687   $self->js_redisplay_amounts_and_taxes;
 688   $self->js->render();
 689 }
 690
 691 # open the dialog for customer/vendor details
 692 sub action_show_customer_vendor_details_dialog {
 693   my ($self) = @_;
 694
 695   my $is_customer = 'customer' eq $::form->{vc};
 696   my $cv;
 697   if ($is_customer) {
 698     $cv = SL::DB::Customer->new(id => $::form->{vc_id})->load;
 699   } else {
 700     $cv = SL::DB::Vendor->new(id => $::form->{vc_id})->load;
 701   }
 702
 703   my %details = map { $_ => $cv->$_ } @{$cv->meta->columns};
 704   $details{discount_as_percent} = $cv->discount_as_percent;
 705   $details{creditlimt}          = $cv->creditlimit_as_number;
 706   $details{business}            = $cv->business->description      if $cv->business;
 707   $details{language}            = $cv->language_obj->description  if $cv->language_obj;
 708   $details{delivery_terms}      = $cv->delivery_term->description if $cv->delivery_term;
 709   $details{payment_terms}       = $cv->payment->description       if $cv->payment;
 710   $details{pricegroup}          = $cv->pricegroup->pricegroup     if $is_customer && $cv->pricegroup;
 711
 712   foreach my $entry (@{ $cv->shipto }) {
 713     push @{ $details{SHIPTO} },   { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 714   }
 715   foreach my $entry (@{ $cv->contacts }) {
 716     push @{ $details{CONTACTS} }, { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 717   }
 718
 719   $_[0]->render('common/show_vc_details', { layout => 0 },
 720                 is_customer => $is_customer,
 721                 %details);
 722
 723 }
 724
 725 # called if a unit in an existing item row is changed
 726 sub action_unit_changed {
 727   my ($self) = @_;
 728
 729   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 730   my $item = $self->order->items_sorted->[$idx];
 731
 732   my $old_unit_obj = SL::DB::Unit->new(name => $::form->{old_unit})->load;
 733   $item->sellprice($item->unit_obj->convert_to($item->sellprice, $old_unit_obj));
 734
 735   $self->recalc();
 736
 737   $self->js
 738     ->run('kivi.Order.update_sellprice', $::form->{item_id}, $item->sellprice_as_number);
 739   $self->js_redisplay_line_values;
 740   $self->js_redisplay_amounts_and_taxes;
 741   $self->js->render();
 742 }
 743
 744 # add an item row for a new item entered in the input row
 745 sub action_add_item {
 746   my ($self) = @_;
 747
 748   my $form_attr = $::form->{add_item};
 749
 750   return unless $form_attr->{parts_id};
 751
 752   my $item = new_item($self->order, $form_attr);
 753
 754   $self->order->add_items($item);
 755
 756   $self->recalc();
 757
 758   my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 759   my $row_as_html = $self->p->render('order/tabs/_row',
 760                                      ITEM              => $item,
 761                                      ID                => $item_id,
 762                                      TYPE              => $self->type,
 763                                      ALL_PRICE_FACTORS => $self->all_price_factors
 764   );
 765
 766   $self->js
 767     ->append('#row_table_id', $row_as_html);
 768
 769   if ( $item->part->is_assortment ) {
 770     $form_attr->{qty_as_number} = 1 unless $form_attr->{qty_as_number};
 771     foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 772       my $attr = { parts_id => $assortment_item->parts_id,
 773                    qty      => $assortment_item->qty * $::form->parse_amount(\%::myconfig, $form_attr->{qty_as_number}), # TODO $form_attr->{unit}
 774                    unit     => $assortment_item->unit,
 775                    description => $assortment_item->part->description,
 776                  };
 777       my $item = new_item($self->order, $attr);
 778
 779       # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 780       $item->discount(1) unless $assortment_item->charge;
 781
 782       $self->order->add_items( $item );
 783       $self->recalc();
 784       my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 785       my $row_as_html = $self->p->render('order/tabs/_row',
 786                                          ITEM              => $item,
 787                                          ID                => $item_id,
 788                                          TYPE              => $self->type,
 789                                          ALL_PRICE_FACTORS => $self->all_price_factors
 790       );
 791       $self->js
 792         ->append('#row_table_id', $row_as_html);
 793     };
 794   };
 795
 796   $self->js
 797     ->val('.add_item_input', '')
 798     ->run('kivi.Order.init_row_handlers')
 799     ->run('kivi.Order.row_table_scroll_down')
 800     ->run('kivi.Order.renumber_positions')
 801     ->focus('#add_item_parts_id_name');
 802
 803   $self->js_redisplay_amounts_and_taxes;
 804   $self->js->render();
 805 }
 806
 807 # open the dialog for entering multiple items at once
 808 sub action_show_multi_items_dialog {
 809   $_[0]->render('order/tabs/_multi_items_dialog', { layout => 0 },
 810                 all_partsgroups => SL::DB::Manager::PartsGroup->get_all);
 811 }
 812
 813 # update the filter results in the multi item dialog
 814 sub action_multi_items_update_result {
 815   my $max_count = 100;
 816
 817   $::form->{multi_items}->{filter}->{obsolete} = 0;
 818
 819   my $count = $_[0]->multi_items_models->count;
 820
 821   if ($count == 0) {
 822     my $text = SL::Presenter::EscapedText->new(text => $::locale->text('No results.'));
 823     $_[0]->render($text, { layout => 0 });
 824   } elsif ($count > $max_count) {
 825     my $text = SL::Presenter::EscapedText->new(text => $::locale->text('Too many results (#1 from #2).', $count, $max_count));
 826     $_[0]->render($text, { layout => 0 });
 827   } else {
 828     my $multi_items = $_[0]->multi_items_models->get;
 829     $_[0]->render('order/tabs/_multi_items_result', { layout => 0 },
 830                   multi_items => $multi_items);
 831   }
 832 }
 833
 834 # add item rows for multiple items at once
 835 sub action_add_multi_items {
 836   my ($self) = @_;
 837
 838   my @form_attr = grep { $_->{qty_as_number} } @{ $::form->{add_multi_items} };
 839   return $self->js->render() unless scalar @form_attr;
 840
 841   my @items;
 842   foreach my $attr (@form_attr) {
 843     my $item = new_item($self->order, $attr);
 844     push @items, $item;
 845     if ( $item->part->is_assortment ) {
 846       foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 847         my $attr = { parts_id => $assortment_item->parts_id,
 848                      qty      => $assortment_item->qty * $item->qty, # TODO $form_attr->{unit}
 849                      unit     => $assortment_item->unit,
 850                      description => $assortment_item->part->description,
 851                    };
 852         my $item = new_item($self->order, $attr);
 853
 854         # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 855         $item->discount(1) unless $assortment_item->charge;
 856         push @items, $item;
 857       }
 858     }
 859   }
 860   $self->order->add_items(@items);
 861
 862   $self->recalc();
 863
 864   foreach my $item (@items) {
 865     my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 866     my $row_as_html = $self->p->render('order/tabs/_row',
 867                                        ITEM              => $item,
 868                                        ID                => $item_id,
 869                                        TYPE              => $self->type,
 870                                        ALL_PRICE_FACTORS => $self->all_price_factors
 871     );
 872
 873     $self->js->append('#row_table_id', $row_as_html);
 874   }
 875
 876   $self->js
 877     ->run('kivi.Order.close_multi_items_dialog')
 878     ->run('kivi.Order.init_row_handlers')
 879     ->run('kivi.Order.row_table_scroll_down')
 880     ->run('kivi.Order.renumber_positions')
 881     ->focus('#add_item_parts_id_name');
 882
 883   $self->js_redisplay_amounts_and_taxes;
 884   $self->js->render();
 885 }
 886
 887 # recalculate all linetotals, amounts and taxes and redisplay them
 888 sub action_recalc_amounts_and_taxes {
 889   my ($self) = @_;
 890
 891   $self->recalc();
 892
 893   $self->js_redisplay_line_values;
 894   $self->js_redisplay_amounts_and_taxes;
 895   $self->js->render();
 896 }
 897
 898 # redisplay item rows if they are sorted by an attribute
 899 sub action_reorder_items {
 900   my ($self) = @_;
 901
 902   my %sort_keys = (
 903     partnumber  => sub { $_[0]->part->partnumber },
 904     description => sub { $_[0]->description },
 905     qty         => sub { $_[0]->qty },
 906     sellprice   => sub { $_[0]->sellprice },
 907     discount    => sub { $_[0]->discount },
 908   );
 909
 910   my $method = $sort_keys{$::form->{order_by}};
 911   my @to_sort = map { { old_pos => $_->position, order_by => $method->($_) } } @{ $self->order->items_sorted };
 912   if ($::form->{sort_dir}) {
 913     if ( $::form->{order_by} =~ m/qty|sellprice|discount/ ){
 914       @to_sort = sort { $a->{order_by} <=> $b->{order_by} } @to_sort;
 915     } else {
 916       @to_sort = sort { $a->{order_by} cmp $b->{order_by} } @to_sort;
 917     }
 918   } else {
 919     if ( $::form->{order_by} =~ m/qty|sellprice|discount/ ){
 920       @to_sort = sort { $b->{order_by} <=> $a->{order_by} } @to_sort;
 921     } else {
 922       @to_sort = sort { $b->{order_by} cmp $a->{order_by} } @to_sort;
 923     }
 924   }
 925   $self->js
 926     ->run('kivi.Order.redisplay_items', \@to_sort)
 927     ->render;
 928 }
 929
 930 # show the popup to choose a price/discount source
 931 sub action_price_popup {
 932   my ($self) = @_;
 933
 934   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 935   my $item = $self->order->items_sorted->[$idx];
 936
 937   $self->render_price_dialog($item);
 938 }
 939
 940 # get the longdescription for an item if the dialog to enter/change the
 941 # longdescription was opened and the longdescription is empty
 942 #
 943 # If this item is new, get the longdescription from Part.
 944 # Otherwise get it from OrderItem.
 945 sub action_get_item_longdescription {
 946   my $longdescription;
 947
 948   if ($::form->{item_id}) {
 949     $longdescription = SL::DB::OrderItem->new(id => $::form->{item_id})->load->longdescription;
 950   } elsif ($::form->{parts_id}) {
 951     $longdescription = SL::DB::Part->new(id => $::form->{parts_id})->load->notes;
 952   }
 953   $_[0]->render(\ $longdescription, { type => 'text' });
 954 }
 955
 956 # load the second row for one or more items
 957 #
 958 # This action gets the html code for all items second rows by rendering a template for
 959 # the second row and sets the html code via client js.
 960 sub action_load_second_rows {
 961   my ($self) = @_;
 962
 963   $self->recalc() if $self->order->is_sales; # for margin calculation
 964
 965   foreach my $item_id (@{ $::form->{item_ids} }) {
 966     my $idx  = first_index { $_ eq $item_id } @{ $::form->{orderitem_ids} };
 967     my $item = $self->order->items_sorted->[$idx];
 968
 969     $self->js_load_second_row($item, $item_id, 0);
 970   }
 971
 972   $self->js->run('kivi.Order.init_row_handlers') if $self->order->is_sales; # for lastcosts change-callback
 973
 974   $self->js->render();
 975 }
 976
 977 sub js_load_second_row {
 978   my ($self, $item, $item_id, $do_parse) = @_;
 979
 980   if ($do_parse) {
 981     # Parse values from form (they are formated while rendering (template)).
 982     # Workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
 983     # This parsing is not necessary at all, if we assure that the second row/cvars are only loaded once.
 984     foreach my $var (@{ $item->cvars_by_config }) {
 985       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
 986     }
 987     $item->parse_custom_variable_values;
 988   }
 989
 990   my $row_as_html = $self->p->render('order/tabs/_second_row', ITEM => $item, TYPE => $self->type);
 991
 992   $self->js
 993     ->html('#second_row_' . $item_id, $row_as_html)
 994     ->data('#second_row_' . $item_id, 'loaded', 1);
 995 }
 996
 997 sub js_redisplay_line_values {
 998   my ($self) = @_;
 999
1000   my $is_sales = $self->order->is_sales;
1001
1002   # sales orders with margins
1003   my @data;
1004   if ($is_sales) {
1005     @data = map {
1006       [
1007        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
1008        $::form->format_amount(\%::myconfig, $_->{marge_total},   2, 0),
1009        $::form->format_amount(\%::myconfig, $_->{marge_percent}, 2, 0),
1010       ]} @{ $self->order->items_sorted };
1011   } else {
1012     @data = map {
1013       [
1014        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
1015       ]} @{ $self->order->items_sorted };
1016   }
1017
1018   $self->js
1019     ->run('kivi.Order.redisplay_line_values', $is_sales, \@data);
1020 }
1021
1022 sub js_redisplay_amounts_and_taxes {
1023   my ($self) = @_;
1024
1025   if (scalar @{ $self->{taxes} }) {
1026     $self->js->show('#taxincluded_row_id');
1027   } else {
1028     $self->js->hide('#taxincluded_row_id');
1029   }
1030
1031   if ($self->order->taxincluded) {
1032     $self->js->hide('#subtotal_row_id');
1033   } else {
1034     $self->js->show('#subtotal_row_id');
1035   }
1036
1037   if ($self->order->is_sales) {
1038     my $is_neg = $self->order->marge_total < 0;
1039     $self->js
1040       ->html('#marge_total_id',   $::form->format_amount(\%::myconfig, $self->order->marge_total,   2))
1041       ->html('#marge_percent_id', $::form->format_amount(\%::myconfig, $self->order->marge_percent, 2))
1042       ->action_if( $is_neg, 'addClass',    '#marge_total_id',        'plus0')
1043       ->action_if( $is_neg, 'addClass',    '#marge_percent_id',      'plus0')
1044       ->action_if( $is_neg, 'addClass',    '#marge_percent_sign_id', 'plus0')
1045       ->action_if(!$is_neg, 'removeClass', '#marge_total_id',        'plus0')
1046       ->action_if(!$is_neg, 'removeClass', '#marge_percent_id',      'plus0')
1047       ->action_if(!$is_neg, 'removeClass', '#marge_percent_sign_id', 'plus0');
1048   }
1049
1050   $self->js
1051     ->html('#netamount_id', $::form->format_amount(\%::myconfig, $self->order->netamount, -2))
1052     ->html('#amount_id',    $::form->format_amount(\%::myconfig, $self->order->amount,    -2))
1053     ->remove('.tax_row')
1054     ->insertBefore($self->build_tax_rows, '#amount_row_id');
1055 }
1056
1057 #
1058 # helpers
1059 #
1060
1061 sub init_valid_types {
1062   [ sales_order_type(), purchase_order_type(), sales_quotation_type(), request_quotation_type() ];
1063 }
1064
1065 sub init_type {
1066   my ($self) = @_;
1067
1068   if (none { $::form->{type} eq $_ } @{$self->valid_types}) {
1069     die "Not a valid type for order";
1070   }
1071
1072   $self->type($::form->{type});
1073 }
1074
1075 sub init_cv {
1076   my ($self) = @_;
1077
1078   my $cv = (any { $self->type eq $_ } (sales_order_type(),    sales_quotation_type()))   ? 'customer'
1079          : (any { $self->type eq $_ } (purchase_order_type(), request_quotation_type())) ? 'vendor'
1080          : die "Not a valid type for order";
1081
1082   return $cv;
1083 }
1084
1085 sub init_p {
1086   SL::Presenter->get;
1087 }
1088
1089 sub init_order {
1090   $_[0]->make_order;
1091 }
1092
1093 # model used to filter/display the parts in the multi-items dialog
1094 sub init_multi_items_models {
1095   SL::Controller::Helper::GetModels->new(
1096     controller     => $_[0],
1097     model          => 'Part',
1098     with_objects   => [ qw(unit_obj) ],
1099     disable_plugin => 'paginated',
1100     source         => $::form->{multi_items},
1101     sorted         => {
1102       _default    => {
1103         by  => 'partnumber',
1104         dir => 1,
1105       },
1106       partnumber  => t8('Partnumber'),
1107       description => t8('Description')}
1108   );
1109 }
1110
1111 sub init_all_price_factors {
1112   SL::DB::Manager::PriceFactor->get_all;
1113 }
1114
1115 sub check_auth {
1116   my ($self) = @_;
1117
1118   my $right_for = { map { $_ => $_.'_edit' } @{$self->valid_types} };
1119
1120   my $right   = $right_for->{ $self->type };
1121   $right    ||= 'DOES_NOT_EXIST';
1122
1123   $::auth->assert($right);
1124 }
1125
1126 # build the selection box for contacts
1127 #
1128 # Needed, if customer/vendor changed.
1129 sub build_contact_select {
1130   my ($self) = @_;
1131
1132   select_tag('order.cp_id', [ $self->order->{$self->cv}->contacts ],
1133     value_key  => 'cp_id',
1134     title_key  => 'full_name_dep',
1135     default    => $self->order->cp_id,
1136     with_empty => 1,
1137     style      => 'width: 300px',
1138   );
1139 }
1140
1141 # build the selection box for shiptos
1142 #
1143 # Needed, if customer/vendor changed.
1144 sub build_shipto_select {
1145   my ($self) = @_;
1146
1147   select_tag('order.shipto_id', [ $self->order->{$self->cv}->shipto ],
1148     value_key  => 'shipto_id',
1149     title_key  => 'displayable_id',
1150     default    => $self->order->shipto_id,
1151     with_empty => 1,
1152     style      => 'width: 300px',
1153   );
1154 }
1155
1156 # render the info line for business
1157 #
1158 # Needed, if customer/vendor changed.
1159 sub build_business_info_row
1160 {
1161   $_[0]->p->render('order/tabs/_business_info_row', SELF => $_[0]);
1162 }
1163
1164 # build the rows for displaying taxes
1165 #
1166 # Called if amounts where recalculated and redisplayed.
1167 sub build_tax_rows {
1168   my ($self) = @_;
1169
1170   my $rows_as_html;
1171   foreach my $tax (sort { $a->{tax}->rate cmp $b->{tax}->rate } @{ $self->{taxes} }) {
1172     $rows_as_html .= $self->p->render('order/tabs/_tax_row', TAX => $tax, TAXINCLUDED => $self->order->taxincluded);
1173   }
1174   return $rows_as_html;
1175 }
1176
1177
1178 sub render_price_dialog {
1179   my ($self, $record_item) = @_;
1180
1181   my $price_source = SL::PriceSource->new(record_item => $record_item, record => $self->order);
1182
1183   $self->js
1184     ->run(
1185       'kivi.io.price_chooser_dialog',
1186       t8('Available Prices'),
1187       $self->render('order/tabs/_price_sources_dialog', { output => 0 }, price_source => $price_source)
1188     )
1189     ->reinit_widgets;
1190
1191 #   if (@errors) {
1192 #     $self->js->text('#dialog_flash_error_content', join ' ', @errors);
1193 #     $self->js->show('#dialog_flash_error');
1194 #   }
1195
1196   $self->js->render;
1197 }
1198
1199 sub load_order {
1200   my ($self) = @_;
1201
1202   return if !$::form->{id};
1203
1204   $self->order(SL::DB::Order->new(id => $::form->{id})->load);
1205 }
1206
1207 # load or create a new order object
1208 #
1209 # And assign changes from the form to this object.
1210 # If the order is loaded from db, check if items are deleted in the form,
1211 # remove them form the object and collect them for removing from db on saving.
1212 # Then create/update items from form (via make_item) and add them.
1213 sub make_order {
1214   my ($self) = @_;
1215
1216   # add_items adds items to an order with no items for saving, but they cannot
1217   # be retrieved via items until the order is saved. Adding empty items to new
1218   # order here solves this problem.
1219   my $order;
1220   $order   = SL::DB::Order->new(id => $::form->{id})->load(with => [ 'orderitems', 'orderitems.part' ]) if $::form->{id};
1221   $order ||= SL::DB::Order->new(orderitems => [],
1222                                 quotation  => (any { $self->type eq $_ } (sales_quotation_type(), request_quotation_type())));
1223
1224   my $cv_id_method = $self->cv . '_id';
1225   if (!$::form->{id} && $::form->{$cv_id_method}) {
1226     $order->$cv_id_method($::form->{$cv_id_method});
1227     setup_order_from_cv($order);
1228   }
1229
1230   my $form_orderitems               = delete $::form->{order}->{orderitems};
1231   my $form_periodic_invoices_config = delete $::form->{order}->{periodic_invoices_config};
1232
1233   $order->assign_attributes(%{$::form->{order}});
1234
1235   if (my $periodic_invoices_config_attrs = $form_periodic_invoices_config ? YAML::Load($form_periodic_invoices_config) : undef) {
1236     my $periodic_invoices_config = $order->periodic_invoices_config || $order->periodic_invoices_config(SL::DB::PeriodicInvoicesConfig->new);
1237     $periodic_invoices_config->assign_attributes(%$periodic_invoices_config_attrs);
1238   }
1239
1240   # remove deleted items
1241   $self->item_ids_to_delete([]);
1242   foreach my $idx (reverse 0..$#{$order->orderitems}) {
1243     my $item = $order->orderitems->[$idx];
1244     if (none { $item->id == $_->{id} } @{$form_orderitems}) {
1245       splice @{$order->orderitems}, $idx, 1;
1246       push @{$self->item_ids_to_delete}, $item->id;
1247     }
1248   }
1249
1250   my @items;
1251   my $pos = 1;
1252   foreach my $form_attr (@{$form_orderitems}) {
1253     my $item = make_item($order, $form_attr);
1254     $item->position($pos);
1255     push @items, $item;
1256     $pos++;
1257   }
1258   $order->add_items(grep {!$_->id} @items);
1259
1260   return $order;
1261 }
1262
1263 # create or update items from form
1264 #
1265 # Make item objects from form values. For items already existing read from db.
1266 # Create a new item else. And assign attributes.
1267 sub make_item {
1268   my ($record, $attr) = @_;
1269
1270   my $item;
1271   $item = first { $_->id == $attr->{id} } @{$record->items} if $attr->{id};
1272
1273   my $is_new = !$item;
1274
1275   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1276   # they cannot be retrieved via custom_variables until the order/orderitem is
1277   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1278   $item ||= SL::DB::OrderItem->new(custom_variables => []);
1279
1280   $item->assign_attributes(%$attr);
1281   $item->longdescription($item->part->notes)                     if $is_new && !defined $attr->{longdescription};
1282   $item->project_id($record->globalproject_id)                   if $is_new && !defined $attr->{project_id};
1283   $item->lastcost($record->is_sales ? $item->part->lastcost : 0) if $is_new && !defined $attr->{lastcost_as_number};
1284
1285   return $item;
1286 }
1287
1288 # create a new item
1289 #
1290 # This is used to add one item
1291 sub new_item {
1292   my ($record, $attr) = @_;
1293
1294   my $item = SL::DB::OrderItem->new;
1295
1296   # Remove attributes where the user left or set the inputs empty.
1297   # So these attributes will be undefined and we can distinguish them
1298   # from zero later on.
1299   for (qw(qty_as_number sellprice_as_number discount_as_percent)) {
1300     delete $attr->{$_} if $attr->{$_} eq '';
1301   }
1302
1303   $item->assign_attributes(%$attr);
1304
1305   my $part         = SL::DB::Part->new(id => $attr->{parts_id})->load;
1306   my $price_source = SL::PriceSource->new(record_item => $item, record => $record);
1307
1308   $item->unit($part->unit) if !$item->unit;
1309
1310   my $price_src;
1311   if ( $part->is_assortment ) {
1312     # add assortment items with price 0, as the components carry the price
1313     $price_src = $price_source->price_from_source("");
1314     $price_src->price(0);
1315   } elsif (defined $item->sellprice) {
1316     $price_src = $price_source->price_from_source("");
1317     $price_src->price($item->sellprice);
1318   } else {
1319     $price_src = $price_source->best_price
1320            ? $price_source->best_price
1321            : $price_source->price_from_source("");
1322     $price_src->price(0) if !$price_source->best_price;
1323   }
1324
1325   my $discount_src;
1326   if (defined $item->discount) {
1327     $discount_src = $price_source->discount_from_source("");
1328     $discount_src->discount($item->discount);
1329   } else {
1330     $discount_src = $price_source->best_discount
1331                   ? $price_source->best_discount
1332                   : $price_source->discount_from_source("");
1333     $discount_src->discount(0) if !$price_source->best_discount;
1334   }
1335
1336   my %new_attr;
1337   $new_attr{part}                   = $part;
1338   $new_attr{description}            = $part->description     if ! $item->description;
1339   $new_attr{qty}                    = 1.0                    if ! $item->qty;
1340   $new_attr{price_factor_id}        = $part->price_factor_id if ! $item->price_factor_id;
1341   $new_attr{sellprice}              = $price_src->price;
1342   $new_attr{discount}               = $discount_src->discount;
1343   $new_attr{active_price_source}    = $price_src;
1344   $new_attr{active_discount_source} = $discount_src;
1345   $new_attr{longdescription}        = $part->notes           if ! defined $attr->{longdescription};
1346   $new_attr{project_id}             = $record->globalproject_id;
1347   $new_attr{lastcost}               = $record->is_sales ? $part->lastcost : 0;
1348
1349   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1350   # they cannot be retrieved via custom_variables until the order/orderitem is
1351   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1352   $new_attr{custom_variables} = [];
1353
1354   $item->assign_attributes(%new_attr);
1355
1356   return $item;
1357 }
1358
1359 sub setup_order_from_cv {
1360   my ($order) = @_;
1361
1362   $order->$_($order->customervendor->$_) for (qw(taxzone_id payment_id delivery_term_id));
1363
1364   $order->intnotes($order->customervendor->notes);
1365
1366   if ($order->is_sales) {
1367     $order->salesman_id($order->customer->salesman_id || SL::DB::Manager::Employee->current->id);
1368     $order->taxincluded(defined($order->customer->taxincluded_checked)
1369                         ? $order->customer->taxincluded_checked
1370                         : $::myconfig{taxincluded_checked});
1371   }
1372
1373 }
1374
1375 # recalculate prices and taxes
1376 #
1377 # Using the PriceTaxCalculator. Store linetotals in the item objects.
1378 sub recalc {
1379   my ($self) = @_;
1380
1381   # bb: todo: currency later
1382   $self->order->currency_id($::instance_conf->get_currency_id());
1383
1384   my %pat = $self->order->calculate_prices_and_taxes();
1385   $self->{taxes} = [];
1386   foreach my $tax_chart_id (keys %{ $pat{taxes} }) {
1387     my $tax = SL::DB::Manager::Tax->find_by(chart_id => $tax_chart_id);
1388
1389     my @amount_keys = grep { $pat{amounts}->{$_}->{tax_id} == $tax->id } keys %{ $pat{amounts} };
1390     push(@{ $self->{taxes} }, { amount    => $pat{taxes}->{$tax_chart_id},
1391                                 netamount => $pat{amounts}->{$amount_keys[0]}->{amount},
1392                                 tax       => $tax });
1393   }
1394
1395   pairwise { $a->{linetotal} = $b->{linetotal} } @{$self->order->items_sorted}, @{$pat{items}};
1396 }
1397
1398 # get data for saving, printing, ..., that is not changed in the form
1399 #
1400 # Only cvars for now.
1401 sub get_unalterable_data {
1402   my ($self) = @_;
1403
1404   foreach my $item (@{ $self->order->items }) {
1405     # autovivify all cvars that are not in the form (cvars_by_config can do it).
1406     # workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
1407     foreach my $var (@{ $item->cvars_by_config }) {
1408       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
1409     }
1410     $item->parse_custom_variable_values;
1411   }
1412 }
1413
1414 # delete the order
1415 #
1416 # And remove related files in the spool directory
1417 sub delete {
1418   my ($self) = @_;
1419
1420   my $errors = [];
1421   my $db     = $self->order->db;
1422
1423   $db->with_transaction(
1424     sub {
1425       my @spoolfiles = grep { $_ } map { $_->spoolfile } @{ SL::DB::Manager::Status->get_all(where => [ trans_id => $self->order->id ]) };
1426       $self->order->delete;
1427       my $spool = $::lx_office_conf{paths}->{spool};
1428       unlink map { "$spool/$_" } @spoolfiles if $spool;
1429
1430       1;
1431   }) || push(@{$errors}, $db->error);
1432
1433   return $errors;
1434 }
1435
1436 # save the order
1437 #
1438 # And delete items that are deleted in the form.
1439 sub save {
1440   my ($self) = @_;
1441
1442   my $errors = [];
1443   my $db     = $self->order->db;
1444
1445   $db->with_transaction(sub {
1446     SL::DB::OrderItem->new(id => $_)->delete for @{$self->item_ids_to_delete || []};
1447     $self->order->save(cascade => 1);
1448
1449     # link records
1450     if ($::form->{converted_from_oe_id}) {
1451       my @converted_from_oe_ids = split ' ', $::form->{converted_from_oe_id};
1452       foreach my $converted_from_oe_id (@converted_from_oe_ids) {
1453         my $src = SL::DB::Order->new(id => $converted_from_oe_id)->load;
1454         $src->update_attributes(closed => 1) if $src->type =~ /_quotation$/;
1455         $src->link_to_record($self->order);
1456       }
1457       if (scalar @{ $::form->{converted_from_orderitems_ids} || [] }) {
1458         my $idx = 0;
1459         foreach (@{ $self->order->items_sorted }) {
1460           my $from_id = $::form->{converted_from_orderitems_ids}->[$idx];
1461           next if !$from_id;
1462           SL::DB::RecordLink->new(from_table => 'orderitems',
1463                                   from_id    => $from_id,
1464                                   to_table   => 'orderitems',
1465                                   to_id      => $_->id
1466           )->save;
1467           $idx++;
1468         }
1469       }
1470     }
1471     1;
1472   }) || push(@{$errors}, $db->error);
1473
1474   return $errors;
1475 }
1476
1477 sub workflow_sales_or_purchase_order {
1478   my ($self) = @_;
1479   # always save
1480   my $errors = $self->save();
1481
1482   if (scalar @{ $errors }) {
1483     $self->js->flash('error', $_) foreach @{ $errors };
1484     return $self->js->render();
1485   }
1486
1487
1488   my $destination_type = $::form->{type} eq sales_quotation_type()   ? sales_order_type()
1489                        : $::form->{type} eq request_quotation_type() ? purchase_order_type()
1490                        : $::form->{type} eq purchase_order_type()    ? sales_order_type()
1491                        : $::form->{type} eq sales_order_type()       ? purchase_order_type()
1492                        : '';
1493
1494   $self->order(SL::DB::Order->new_from($self->order, destination_type => $destination_type));
1495   $self->{converted_from_oe_id} = delete $::form->{id};
1496
1497   # set item ids to new fake id, to identify them as new items
1498   foreach my $item (@{$self->order->items_sorted}) {
1499     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1500   }
1501
1502   # change form type
1503   $::form->{type} = $destination_type;
1504   $self->type($self->init_type);
1505   $self->cv  ($self->init_cv);
1506   $self->check_auth;
1507
1508   $self->recalc();
1509   $self->get_unalterable_data();
1510   $self->pre_render();
1511
1512   # trigger rendering values for second row/longdescription as hidden,
1513   # because they are loaded only on demand. So we need to keep the values
1514   # from the source.
1515   $_->{render_second_row}      = 1 for @{ $self->order->items_sorted };
1516   $_->{render_longdescription} = 1 for @{ $self->order->items_sorted };
1517
1518   $self->render(
1519     'order/form',
1520     title => $self->get_title_for('edit'),
1521     %{$self->{template_args}}
1522   );
1523 }
1524
1525
1526 sub pre_render {
1527   my ($self) = @_;
1528
1529   $self->{all_taxzones}             = SL::DB::Manager::TaxZone->get_all_sorted();
1530   $self->{all_departments}          = SL::DB::Manager::Department->get_all_sorted();
1531   $self->{all_employees}            = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->employee_id,
1532                                                                                             deleted => 0 ] ],
1533                                                                          sort_by => 'name');
1534   $self->{all_salesmen}             = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->salesman_id,
1535                                                                                             deleted => 0 ] ],
1536                                                                          sort_by => 'name');
1537   $self->{all_payment_terms}        = SL::DB::Manager::PaymentTerm->get_all_sorted(where => [ or => [ id => $self->order->payment_id,
1538                                                                                                       obsolete => 0 ] ]);
1539   $self->{all_delivery_terms}       = SL::DB::Manager::DeliveryTerm->get_all_sorted();
1540   $self->{current_employee_id}      = SL::DB::Manager::Employee->current->id;
1541   $self->{periodic_invoices_status} = $self->get_periodic_invoices_status($self->order->periodic_invoices_config);
1542   $self->{order_probabilities}      = [ map { { title => ($_ * 10) . '%', id => $_ * 10 } } (0..10) ];
1543
1544   my $print_form = Form->new('');
1545   $print_form->{type}      = $self->type;
1546   $print_form->{printers}  = SL::DB::Manager::Printer->get_all_sorted;
1547   $print_form->{languages} = SL::DB::Manager::Language->get_all_sorted;
1548   $self->{print_options}   = SL::Helper::PrintOptions->get_print_options(
1549     form => $print_form,
1550     options => {dialog_name_prefix => 'print_options.',
1551                 show_headers       => 1,
1552                 no_queue           => 1,
1553                 no_postscript      => 1,
1554                 no_opendocument    => 0,
1555                 no_html            => 1},
1556   );
1557
1558   foreach my $item (@{$self->order->orderitems}) {
1559     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
1560     $item->active_price_source(   $price_source->price_from_source(   $item->active_price_source   ));
1561     $item->active_discount_source($price_source->discount_from_source($item->active_discount_source));
1562   }
1563
1564   if (any { $self->type eq $_ } (sales_order_type(), purchase_order_type())) {
1565     # calculate shipped qtys here to prevent calling calculate for every item via the items method
1566     SL::Helper::ShippedQty->new->calculate($self->order)->write_to_objects;
1567   }
1568
1569   if ($self->order->number && $::instance_conf->get_webdav) {
1570     my $webdav = SL::Webdav->new(
1571       type     => $self->type,
1572       number   => $self->order->number,
1573     );
1574     my @all_objects = $webdav->get_all_objects;
1575     @{ $self->{template_args}->{WEBDAV} } = map { { name => $_->filename,
1576                                                     type => t8('File'),
1577                                                     link => File::Spec->catfile($_->full_filedescriptor),
1578                                                 } } @all_objects;
1579   }
1580
1581   $::request->{layout}->use_javascript("${_}.js") for qw(kivi.SalesPurchase kivi.Order kivi.File ckeditor/ckeditor ckeditor/adapters/jquery edit_periodic_invoices_config calculate_qty);
1582   $self->setup_edit_action_bar;
1583 }
1584
1585 sub setup_edit_action_bar {
1586   my ($self, %params) = @_;
1587
1588   my $deletion_allowed = (any { $self->type eq $_ } (sales_quotation_type(), request_quotation_type()))
1589                       || (($self->type eq sales_order_type())    && $::instance_conf->get_sales_order_show_delete)
1590                       || (($self->type eq purchase_order_type()) && $::instance_conf->get_purchase_order_show_delete);
1591
1592   for my $bar ($::request->layout->get('actionbar')) {
1593     $bar->add(
1594       combobox => [
1595         action => [
1596           t8('Save'),
1597           call      => [ 'kivi.Order.save', 'save', $::instance_conf->get_order_warn_duplicate_parts,
1598                                                     $::instance_conf->get_order_warn_no_deliverydate,
1599                                                                                                       ],
1600           checks    => [ 'kivi.Order.check_save_active_periodic_invoices' ],
1601         ],
1602         action => [
1603           t8('Save as new'),
1604           call      => [ 'kivi.Order.save', 'save_as_new', $::instance_conf->get_order_warn_duplicate_parts ],
1605           checks    => [ 'kivi.Order.check_save_active_periodic_invoices' ],
1606           disabled  => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1607         ],
1608       ], # end of combobox "Save"
1609
1610       combobox => [
1611         action => [
1612           t8('Workflow'),
1613         ],
1614         action => [
1615           t8('Save and Sales Order'),
1616           submit   => [ '#order_form', { action => "Order/sales_order" } ],
1617           only_if  => (any { $self->type eq $_ } (sales_quotation_type(), purchase_order_type())),
1618           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1619         ],
1620         action => [
1621           t8('Save and Purchase Order'),
1622           submit   => [ '#order_form', { action => "Order/purchase_order" } ],
1623           only_if  => (any { $self->type eq $_ } (sales_order_type(), request_quotation_type())),
1624           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1625         ],
1626         action => [
1627           t8('Save and Delivery Order'),
1628           call      => [ 'kivi.Order.save', 'save_and_delivery_order', $::instance_conf->get_order_warn_duplicate_parts,
1629                                                                        $::instance_conf->get_order_warn_no_deliverydate,
1630                                                                                                                         ],
1631           checks    => [ 'kivi.Order.check_save_active_periodic_invoices' ],
1632           only_if   => (any { $self->type eq $_ } (sales_order_type(), purchase_order_type()))
1633         ],
1634         action => [
1635           t8('Save and Invoice'),
1636           call      => [ 'kivi.Order.save', 'save_and_invoice', $::instance_conf->get_order_warn_duplicate_parts ],
1637           checks    => [ 'kivi.Order.check_save_active_periodic_invoices' ],
1638         ],
1639       ], # end of combobox "Workflow"
1640
1641       combobox => [
1642         action => [
1643           t8('Export'),
1644         ],
1645         action => [
1646           t8('Save and print'),
1647           call => [ 'kivi.Order.show_print_options', $::instance_conf->get_order_warn_duplicate_parts ],
1648         ],
1649         action => [
1650           t8('Save and E-mail'),
1651           call => [ 'kivi.Order.email', $::instance_conf->get_order_warn_duplicate_parts ],
1652         ],
1653         action => [
1654           t8('Download attachments of all parts'),
1655           call     => [ 'kivi.File.downloadOrderitemsFiles', $::form->{type}, $::form->{id} ],
1656           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1657           only_if  => $::instance_conf->get_doc_storage,
1658         ],
1659       ], # end of combobox "Export"
1660
1661       action => [
1662         t8('Delete'),
1663         call     => [ 'kivi.Order.delete_order' ],
1664         confirm  => $::locale->text('Do you really want to delete this object?'),
1665         disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1666         only_if  => $deletion_allowed,
1667       ],
1668     );
1669   }
1670 }
1671
1672 sub generate_pdf {
1673   my ($order, $pdf_ref, $params) = @_;
1674
1675   my @errors = ();
1676
1677   my $print_form = Form->new('');
1678   $print_form->{type}        = $order->type;
1679   $print_form->{formname}    = $params->{formname} || $order->type;
1680   $print_form->{format}      = $params->{format}   || 'pdf';
1681   $print_form->{media}       = $params->{media}    || 'file';
1682   $print_form->{groupitems}  = $params->{groupitems};
1683   $print_form->{media}       = 'file'                             if $print_form->{media} eq 'screen';
1684
1685   $order->language($params->{language});
1686   $order->flatten_to_form($print_form, format_amounts => 1);
1687
1688   my $template_ext;
1689   my $template_type;
1690   if ($print_form->{format} =~ /(opendocument|oasis)/i) {
1691     $template_ext  = 'odt';
1692     $template_type = 'OpenDocument';
1693   }
1694
1695   # search for the template
1696   my ($template_file, @template_files) = SL::Helper::CreatePDF->find_template(
1697     name        => $print_form->{formname},
1698     extension   => $template_ext,
1699     email       => $print_form->{media} eq 'email',
1700     language    => $params->{language},
1701     printer_id  => $print_form->{printer_id},  # todo
1702   );
1703
1704   if (!defined $template_file) {
1705     push @errors, $::locale->text('Cannot find matching template for this print request. Please contact your template maintainer. I tried these: #1.', join ', ', map { "'$_'"} @template_files);
1706   }
1707
1708   return @errors if scalar @errors;
1709
1710   $print_form->throw_on_error(sub {
1711     eval {
1712       $print_form->prepare_for_printing;
1713
1714       $$pdf_ref = SL::Helper::CreatePDF->create_pdf(
1715         format        => $print_form->{format},
1716         template_type => $template_type,
1717         template      => $template_file,
1718         variables     => $print_form,
1719         variable_content_types => {
1720           longdescription => 'html',
1721           partnotes       => 'html',
1722           notes           => 'html',
1723         },
1724       );
1725       1;
1726     } || push @errors, ref($EVAL_ERROR) eq 'SL::X::FormError' ? $EVAL_ERROR->getMessage : $EVAL_ERROR;
1727   });
1728
1729   return @errors;
1730 }
1731
1732 sub get_files_for_email_dialog {
1733   my ($self) = @_;
1734
1735   my %files = map { ($_ => []) } qw(versions files vc_files part_files);
1736
1737   return %files if !$::instance_conf->get_doc_storage;
1738
1739   if ($self->order->id) {
1740     $files{versions} = [ SL::File->get_all_versions(object_id => $self->order->id,              object_type => $self->order->type, file_type => 'document') ];
1741     $files{files}    = [ SL::File->get_all(         object_id => $self->order->id,              object_type => $self->order->type, file_type => 'attachment') ];
1742     $files{vc_files} = [ SL::File->get_all(         object_id => $self->order->{$self->cv}->id, object_type => $self->cv,          file_type => 'attachment') ];
1743   }
1744
1745   my @parts =
1746     uniq_by { $_->{id} }
1747     map {
1748       +{ id         => $_->part->id,
1749          partnumber => $_->part->partnumber }
1750     } @{$self->order->items_sorted};
1751
1752   foreach my $part (@parts) {
1753     my @pfiles = SL::File->get_all(object_id => $part->{id}, object_type => 'part');
1754     push @{ $files{part_files} }, map { +{ %{ $_ }, partnumber => $part->{partnumber} } } @pfiles;
1755   }
1756
1757   foreach my $key (keys %files) {
1758     $files{$key} = [ sort_by { lc $_->{db_file}->{file_name} } @{ $files{$key} } ];
1759   }
1760
1761   return %files;
1762 }
1763
1764 sub make_periodic_invoices_config_from_yaml {
1765   my ($yaml_config) = @_;
1766
1767   return if !$yaml_config;
1768   my $attr = YAML::Load($yaml_config);
1769   return if 'HASH' ne ref $attr;
1770   return SL::DB::PeriodicInvoicesConfig->new(%$attr);
1771 }
1772
1773
1774 sub get_periodic_invoices_status {
1775   my ($self, $config) = @_;
1776
1777   return                      if $self->type ne sales_order_type();
1778   return t8('not configured') if !$config;
1779
1780   my $active = ('HASH' eq ref $config)                           ? $config->{active}
1781              : ('SL::DB::PeriodicInvoicesConfig' eq ref $config) ? $config->active
1782              :                                                     die "Cannot get status of periodic invoices config";
1783
1784   return $active ? t8('active') : t8('inactive');
1785 }
1786
1787 sub get_title_for {
1788   my ($self, $action) = @_;
1789
1790   return '' if none { lc($action)} qw(add edit);
1791
1792   # for locales:
1793   # $::locale->text("Add Sales Order");
1794   # $::locale->text("Add Purchase Order");
1795   # $::locale->text("Add Quotation");
1796   # $::locale->text("Add Request for Quotation");
1797   # $::locale->text("Edit Sales Order");
1798   # $::locale->text("Edit Purchase Order");
1799   # $::locale->text("Edit Quotation");
1800   # $::locale->text("Edit Request for Quotation");
1801
1802   $action = ucfirst(lc($action));
1803   return $self->type eq sales_order_type()       ? $::locale->text("$action Sales Order")
1804        : $self->type eq purchase_order_type()    ? $::locale->text("$action Purchase Order")
1805        : $self->type eq sales_quotation_type()   ? $::locale->text("$action Quotation")
1806        : $self->type eq request_quotation_type() ? $::locale->text("$action Request for Quotation")
1807        : '';
1808 }
1809
1810 sub sales_order_type {
1811   'sales_order';
1812 }
1813
1814 sub purchase_order_type {
1815   'purchase_order';
1816 }
1817
1818 sub sales_quotation_type {
1819   'sales_quotation';
1820 }
1821
1822 sub request_quotation_type {
1823   'request_quotation';
1824 }
1825
1826 sub nr_key {
1827   return $_[0]->type eq sales_order_type()       ? 'ordnumber'
1828        : $_[0]->type eq purchase_order_type()    ? 'ordnumber'
1829        : $_[0]->type eq sales_quotation_type()   ? 'quonumber'
1830        : $_[0]->type eq request_quotation_type() ? 'quonumber'
1831        : '';
1832 }
1833
1834 1;
1835
1836 __END__
1837
1838 =encoding utf-8
1839
1840 =head1 NAME
1841
1842 SL::Controller::Order - controller for orders
1843
1844 =head1 SYNOPSIS
1845
1846 This is a new form to enter orders, completely rewritten with the use
1847 of controller and java script techniques.
1848
1849 The aim is to provide the user a better expirience and a faster flow
1850 of work. Also the code should be more readable, more reliable and
1851 better to maintain.
1852
1853 =head2 Key Features
1854
1855 =over 4
1856
1857 =item *
1858
1859 One input row, so that input happens every time at the same place.
1860
1861 =item *
1862
1863 Use of pickers where possible.
1864
1865 =item *
1866
1867 Possibility to enter more than one item at once.
1868
1869 =item *
1870
1871 Item list in a scrollable area, so that the workflow buttons stay at
1872 the bottom.
1873
1874 =item *
1875
1876 Reordering item rows with drag and drop is possible. Sorting item rows is
1877 possible (by partnumber, description, qty, sellprice and discount for now).
1878
1879 =item *
1880
1881 No C<update> is necessary. All entries and calculations are managed
1882 with ajax-calls and the page does only reload on C<save>.
1883
1884 =item *
1885
1886 User can see changes immediately, because of the use of java script
1887 and ajax.
1888
1889 =back
1890
1891 =head1 CODE
1892
1893 =head2 Layout
1894
1895 =over 4
1896
1897 =item * C<SL/Controller/Order.pm>
1898
1899 the controller
1900
1901 =item * C<template/webpages/order/form.html>
1902
1903 main form
1904
1905 =item * C<template/webpages/order/tabs/basic_data.html>
1906
1907 Main tab for basic_data.
1908
1909 This is the only tab here for now. "linked records" and "webdav" tabs are
1910 reused from generic code.
1911
1912 =over 4
1913
1914 =item * C<template/webpages/order/tabs/_business_info_row.html>
1915
1916 For displaying information on business type
1917
1918 =item * C<template/webpages/order/tabs/_item_input.html>
1919
1920 The input line for items
1921
1922 =item * C<template/webpages/order/tabs/_row.html>
1923
1924 One row for already entered items
1925
1926 =item * C<template/webpages/order/tabs/_tax_row.html>
1927
1928 Displaying tax information
1929
1930 =item * C<template/webpages/order/tabs/_multi_items_dialog.html>
1931
1932 Dialog for entering more than one item at once
1933
1934 =item * C<template/webpages/order/tabs/_multi_items_result.html>
1935
1936 Results for the filter in the multi items dialog
1937
1938 =item * C<template/webpages/order/tabs/_price_sources_dialog.html>
1939
1940 Dialog for selecting price and discount sources
1941
1942 =back
1943
1944 =item * C<js/kivi.Order.js>
1945
1946 java script functions
1947
1948 =back
1949
1950 =head1 TODO
1951
1952 =over 4
1953
1954 =item * testing
1955
1956 =item * currency
1957
1958 =item * credit limit
1959
1960 =item * more workflows (quotation, rfq)
1961
1962 =item * price sources: little symbols showing better price / better discount
1963
1964 =item * select units in input row?
1965
1966 =item * custom shipto address
1967
1968 =item * check for direct delivery (workflow sales order -> purchase order)
1969
1970 =item * language / part translations
1971
1972 =item * access rights
1973
1974 =item * display weights
1975
1976 =item * history
1977
1978 =item * mtime check
1979
1980 =item * optional client/user behaviour
1981
1982 (transactions has to be set - department has to be set -
1983  force project if enabled in client config - transport cost reminder)
1984
1985 =back
1986
1987 =head1 KNOWN BUGS AND CAVEATS
1988
1989 =over 4
1990
1991 =item *
1992
1993 Customer discount is not displayed as a valid discount in price source popup
1994 (this might be a bug in price sources)
1995
1996 (I cannot reproduce this (Bernd))
1997
1998 =item *
1999
2000 No indication that <shift>-up/down expands/collapses second row.
2001
2002 =item *
2003
2004 Inline creation of parts is not currently supported
2005
2006 =item *
2007
2008 Table header is not sticky in the scrolling area.
2009
2010 =item *
2011
2012 Sorting does not include C<position>, neither does reordering.
2013
2014 This behavior was implemented intentionally. But we can discuss, which behavior
2015 should be implemented.
2016
2017 =item *
2018
2019 C<show_multi_items_dialog> does not use the currently inserted string for
2020 filtering.
2021
2022 =item *
2023
2024 The language selected in print or email dialog is not saved when the order is saved.
2025
2026 =back
2027
2028 =head1 To discuss / Nice to have
2029
2030 =over 4
2031
2032 =item *
2033
2034 How to expand/collapse second row. Now it can be done clicking the icon or
2035 <shift>-up/down.
2036
2037 =item *
2038
2039 Possibility to change longdescription in input row?
2040
2041 =item *
2042
2043 Possibility to select PriceSources in input row?
2044
2045 =item *
2046
2047 This controller uses a (changed) copy of the template for the PriceSource
2048 dialog. Maybe there could be used one code source.
2049
2050 =item *
2051
2052 Rounding-differences between this controller (PriceTaxCalculator) and the old
2053 form. This is not only a problem here, but also in all parts using the PTC.
2054 There exists a ticket and a patch. This patch should be testet.
2055
2056 =item *
2057
2058 An indicator, if the actual inputs are saved (like in an
2059 editor or on text processing application).
2060
2061 =item *
2062
2063 A warning when leaving the page without saveing unchanged inputs.
2064
2065
2066 =back
2067
2068 =head1 AUTHOR
2069
2070 Bernd Bleßmann E<lt>bernd@kivitendo-premium.deE<gt>
2071
2072 =cut