SL/Controller/PaymentTerm.pm

   1 package SL::Controller::PaymentTerm;
   2
   3 use strict;
   4
   5 use parent qw(SL::Controller::Base);
   6
   7 use SL::DB::PaymentTerm;
   8 use SL::DB::Language;
   9 use SL::Helper::Flash;
  10
  11 use Rose::Object::MakeMethods::Generic
  12 (
  13  scalar => [ qw(payment_term languages) ],
  14 );
  15
  16 __PACKAGE__->run_before('load_payment_term', only => [ qw(         edit        update destroy move_up move_down) ]);
  17 __PACKAGE__->run_before('load_languages',    only => [ qw(new list edit create update) ]);
  18
  19 #
  20 # actions
  21 #
  22
  23 sub action_list {
  24   my ($self) = @_;
  25
  26   $self->render('payment_term/list',
  27                 title               => $::locale->text('Payment terms'),
  28                 PAYMENT_TERMS => SL::DB::Manager::PaymentTerm->get_all_sorted);
  29 }
  30
  31 sub action_new {
  32   my ($self) = @_;
  33
  34   $self->{payment_term} = SL::DB::PaymentTerm->new;
  35   $self->render('payment_term/form', title => $::locale->text('Create a new payment term'));
  36 }
  37
  38 sub action_edit {
  39   my ($self) = @_;
  40   $self->render('payment_term/form', title => $::locale->text('Edit payment term'));
  41 }
  42
  43 sub action_create {
  44   my ($self) = @_;
  45
  46   $self->{payment_term} = SL::DB::PaymentTerm->new;
  47   $self->create_or_update;
  48 }
  49
  50 sub action_update {
  51   my ($self) = @_;
  52   $self->create_or_update;
  53 }
  54
  55 sub action_destroy {
  56   my ($self) = @_;
  57
  58   if (eval { $self->{payment_term}->delete; 1; }) {
  59     flash_later('info',  $::locale->text('The payment term has been deleted.'));
  60   } else {
  61     flash_later('error', $::locale->text('The payment term is in use and cannot be deleted.'));
  62   }
  63
  64   $self->redirect_to(action => 'list');
  65 }
  66
  67 sub action_move_up {
  68   my ($self) = @_;
  69   $self->{payment_term}->move_position_up;
  70   $self->redirect_to(action => 'list');
  71 }
  72
  73 sub action_move_down {
  74   my ($self) = @_;
  75   $self->{payment_term}->move_position_down;
  76   $self->redirect_to(action => 'list');
  77 }
  78
  79 #
  80 # helpers
  81 #
  82
  83 sub create_or_update {
  84   my $self   = shift;
  85   my $is_new = !$self->{payment_term}->id;
  86   my $params = delete($::form->{payment_term}) || { };
  87
  88   $self->{payment_term}->assign_attributes(%{ $params });
  89
  90   my @errors = $self->{payment_term}->validate;
  91
  92   if (@errors) {
  93     flash('error', @errors);
  94     $self->render('payment_term/form', title => $is_new ? $::locale->text('Create a new payment term') : $::locale->text('Edit payment term'));
  95     return;
  96   }
  97
  98   $self->{payment_term}->save;
  99   foreach my $language (@{ $self->{languages} }) {
 100     $self->{payment_term}->save_attribute_translation('description_long', $language, $::form->{"translation_" . $language->id});
 101   }
 102
 103   flash_later('info', $is_new ? $::locale->text('The payment term has been created.') : $::locale->text('The payment term has been saved.'));
 104   $self->redirect_to(action => 'list');
 105 }
 106
 107 sub load_payment_term {
 108   my ($self) = @_;
 109   $self->{payment_term} = SL::DB::PaymentTerm->new(id => $::form->{id})->load;
 110 }
 111
 112 sub load_languages {
 113   my ($self) = @_;
 114   $self->{languages} = SL::DB::Manager::Language->get_all_sorted;
 115 }
 116
 117 1;