SL/Controller/PriceRule.pm

   1 package SL::Controller::PriceRule;
   2
   3 use strict;
   4
   5 use parent qw(SL::Controller::Base);
   6
   7 use SL::Controller::Helper::GetModels;
   8 use SL::Controller::Helper::ParseFilter;
   9 use SL::Controller::Helper::ReportGenerator;
  10 use SL::DB::PriceRule;
  11 use SL::DB::PriceRuleItem;
  12 use SL::DB::Pricegroup;
  13 use SL::DB::PartsGroup;
  14 use SL::DB::Business;
  15 use SL::Helper::Flash;
  16 use SL::ClientJS;
  17 use SL::Locale::String;
  18
  19 use Rose::Object::MakeMethods::Generic
  20 (
  21  'scalar --get_set_init' => [ qw(models price_rule vc js pricegroups partsgroups businesses) ],
  22 );
  23
  24 # __PACKAGE__->run_before('check_auth');
  25 __PACKAGE__->run_before('add_javascripts');
  26
  27 #
  28 # actions
  29 #
  30
  31 sub action_list {
  32   my ($self) = @_;
  33
  34   $self->make_filter_summary;
  35
  36   my $price_rules = $self->models->get;
  37
  38   $self->prepare_report;
  39
  40   $self->report_generator_list_objects(report => $self->{report}, objects => $price_rules);
  41 }
  42
  43 sub action_new {
  44   my ($self) = @_;
  45
  46   $self->price_rule(SL::DB::PriceRule->new);
  47   $self->price_rule->assign_attributes(%{ $::form->{price_rule} || {} });
  48   $self->display_form;
  49 }
  50
  51 sub action_edit {
  52   my ($self) = @_;
  53
  54   $self->display_form;
  55 }
  56
  57 sub action_create {
  58   my ($self) = @_;
  59
  60   $self->price_rule($self->price_rule->clone_and_reset_deep);
  61   $self->create_or_update;
  62 }
  63
  64 sub action_update {
  65   my ($self) = @_;
  66   $self->create_or_update;
  67 }
  68
  69  #TODO
  70 sub action_destroy {
  71   my ($self) = @_;
  72
  73   $self->price_rule->obsolete(1);
  74   $self->price_rule->save;
  75   flash_later('info',  $::locale->text('The price rule has been obsoleted.'));
  76
  77   $self->redirect_to(action => 'list');
  78 }
  79
  80 sub action_add_item_row {
  81   my ($self, %params) = @_;
  82
  83   my $item = SL::DB::PriceRuleItem->new(type => $::form->{type});
  84
  85   my $html = $self->render('price_rule/item', { output => 0 }, item => $item);
  86
  87   $self
  88     ->js
  89     ->before('#price_rule_new_items', $html)
  90     ->reinit_widgets
  91     ->render($self);
  92 }
  93
  94 #
  95 # filters
  96 #
  97
  98 sub check_auth {
  99   $::auth->assert('price_rule_edit');
 100 }
 101
 102 #
 103 # helpers
 104 #
 105
 106 sub display_form {
 107   my ($self, %params) = @_;
 108   my $is_new  = !$self->price_rule->id;
 109   my $title   = $is_new ? t8('Create a new price rule') : t8('Edit price rule');
 110   $self->render('price_rule/form',
 111     title => $title,
 112     %params
 113   );
 114 }
 115
 116 sub create_or_update {
 117   my $self   = shift;
 118   my $is_new = !$self->price_rule->id;
 119   my $params = delete($::form->{price_rule}) || { };
 120
 121   delete $params->{id};
 122   $self->price_rule->assign_attributes(%{ $params });
 123
 124   my @errors = $self->price_rule->validate;
 125
 126   if (@errors) {
 127     flash('error', @errors);
 128     $self->display_form(callback => $::form->{callback});
 129     return;
 130   }
 131
 132   $self->price_rule->save;
 133
 134   flash_later('info', $is_new ? $::locale->text('The price rule has been created.') : $::locale->text('The price rule has been saved.'));
 135
 136   $self->redirect_to($::form->{callback} || (action => 'list', 'filter.type' => $self->price_rule->type));
 137 }
 138
 139 sub prepare_report {
 140   my ($self)      = @_;
 141
 142   my $callback    = $self->models->get_callback;
 143
 144   my $report      = SL::ReportGenerator->new(\%::myconfig, $::form);
 145   $self->{report} = $report;
 146
 147   my @columns     = qw(name type priority price discount);
 148   my @sortable    = qw(name type priority price discount);
 149
 150   my %column_defs = (
 151     name          => { obj_link => sub { $self->url_for(action => 'edit', 'price_rule.id' => $_[0]->id, callback => $callback) } },
 152     priority      => { sub  => sub { $_[0]->priority } },
 153     price         => { sub  => sub { $_[0]->price_as_number } },
 154     discount      => { sub  => sub { $_[0]->discount_as_number } },
 155     obsolete      => { sub  => sub { $_[0]->obsolete_as_bool_yn } },
 156   );
 157
 158   map { $column_defs{$_}->{text} ||= $::locale->text( $self->models->get_sort_spec->{$_}->{title} ) } keys %column_defs;
 159
 160   if ( $report->{options}{output_format} =~ /^(pdf|csv)$/i ) {
 161     $self->models->disable_plugin('paginated');
 162   }
 163   $report->set_options(
 164     std_column_visibility => 1,
 165     controller_class      => 'PriceRule',
 166     output_format         => 'HTML',
 167     title                 => $::locale->text('Price Rules'),
 168     allow_pdf_export      => 1,
 169     allow_csv_export      => 1,
 170   );
 171   $report->set_columns(%column_defs);
 172   $report->set_column_order(@columns);
 173   $report->set_export_options(qw(list filter));
 174   $report->set_options_from_form;
 175   $self->models->set_report_generator_sort_options(report => $report, sortable_columns => \@sortable);
 176   $report->set_options(
 177     raw_bottom_info_text  => $self->render('price_rule/report_bottom', { output => 0 }),
 178     raw_top_info_text     => $self->render('price_rule/report_top', { output => 0 }),
 179   );
 180 }
 181
 182 sub make_filter_summary {
 183   my ($self) = @_;
 184
 185   my $filter = $::form->{filter} || {};
 186   my @filter_strings;
 187
 188   my @filters = (
 189     [ $filter->{"name:substr::ilike"}, t8('Name')  ],
 190     [ $filter->{"price:number"},       t8('Price') ],
 191     [ $filter->{"discount:number"},    t8('Discount') ],
 192   );
 193
 194   for (@filters) {
 195     push @filter_strings, "$_->[1]: $_->[0]" if $_->[0];
 196   }
 197
 198   $self->{filter_summary} = join ', ', @filter_strings;
 199 }
 200
 201 sub all_price_rule_item_types {
 202   SL::DB::Manager::PriceRuleItem->get_all_types($_[0]->price_rule->type);
 203 }
 204
 205 sub add_javascripts  {
 206   $::request->{layout}->add_javascripts(qw(kivi.PriceRule.js autocomplete_customer.js autocomplete_vendor.js));
 207 }
 208
 209 sub init_price_rule {
 210   my ($self) = @_;
 211
 212   my $price_rule = $::form->{price_rule}{id} ? SL::DB::PriceRule->new(id => $::form->{price_rule}{id})->load : SL::DB::PriceRule->new;
 213
 214   my $items = delete $::form->{price_rule}{items};
 215
 216   $price_rule->assign_attributes(%{ $::form->{price_rule} || {} });
 217
 218   my %old_items = map { $_->id => $_ } $price_rule->items;
 219
 220   my @items;
 221   for my $raw_item (@$items) {
 222     my $item = $raw_item->{id} ? $old_items{ $raw_item->{id} } || SL::DB::PriceRuleItem->new(id => $raw_item->{id})->load : SL::DB::PriceRuleItem->new;
 223     $item->assign_attributes(%$raw_item);
 224     push @items, $item;
 225   }
 226
 227   $price_rule->items(@items) if @items;
 228
 229   $self->price_rule($price_rule);
 230 }
 231
 232 sub init_vc {
 233   $::form->{filter}{type};
 234 }
 235
 236 sub init_js {
 237   SL::ClientJS->new;
 238 }
 239
 240 sub init_businesses {
 241   SL::DB::Manager::Business->get_all;
 242 }
 243
 244 sub init_pricegroups {
 245   SL::DB::Manager::Pricegroup->get_all;
 246 }
 247
 248 sub init_partsgroups {
 249   SL::DB::Manager::PartsGroup->get_all;
 250 }
 251
 252 sub init_models {
 253   my ($self) = @_;
 254
 255   SL::Controller::Helper::GetModels->new(
 256     controller => $self,
 257     sorted => {
 258       name     => t8('Name'),
 259       type     => t8('Type'),
 260       priority => t8('Priority'),
 261       price    => t8('Price'),
 262       discount => t8('Discount'),
 263       obsolete => t8('Obsolete'),
 264     },
 265   );
 266 }
 267
 268 1;