SL/Controller/PriceRule.pm

   1 package SL::Controller::PriceRule;
   2
   3 use strict;
   4
   5 use parent qw(SL::Controller::Base);
   6
   7 use SL::Controller::Helper::GetModels;
   8 use SL::Controller::Helper::ParseFilter;
   9 use SL::Controller::Helper::ReportGenerator;
  10 use SL::DB::PriceRule;
  11 use SL::DB::PriceRuleItem;
  12 use SL::DB::Pricegroup;
  13 use SL::DB::PartsGroup;
  14 use SL::DB::Business;
  15 use SL::Helper::Flash;
  16 use SL::ClientJS;
  17 use SL::Locale::String;
  18
  19 use Rose::Object::MakeMethods::Generic
  20 (
  21  'scalar --get_set_init' => [ qw(models price_rule vc js pricegroups partsgroups businesses) ],
  22 );
  23
  24 # __PACKAGE__->run_before('check_auth');
  25 __PACKAGE__->run_before('add_javascripts');
  26
  27 #
  28 # actions
  29 #
  30
  31 sub action_list {
  32   my ($self) = @_;
  33
  34   $self->make_filter_summary;
  35
  36   my $price_rules = $self->models->get;
  37
  38   $self->prepare_report;
  39
  40   $self->report_generator_list_objects(report => $self->{report}, objects => $price_rules);
  41 }
  42
  43 sub action_new {
  44   my ($self) = @_;
  45
  46   $self->price_rule(SL::DB::PriceRule->new);
  47   $self->price_rule->assign_attributes(%{ $::form->{price_rule} || {} });
  48   $self->display_form;
  49 }
  50
  51 sub action_edit {
  52   my ($self) = @_;
  53
  54   $self->display_form;
  55 }
  56
  57 sub action_create {
  58   my ($self) = @_;
  59
  60   $self->price_rule($self->price_rule->clone_and_reset_deep);
  61   $self->create_or_update;
  62 }
  63
  64 sub action_update {
  65   my ($self) = @_;
  66   $self->create_or_update;
  67 }
  68
  69  #TODO
  70 sub action_destroy {
  71   my ($self) = @_;
  72
  73   $self->price_rule->delete;
  74   flash_later('info',  $::locale->text('The price rule has been deleted.'));
  75
  76   $self->redirect_to($::form->{callback} || (action => 'list'));
  77 }
  78
  79 sub action_add_item_row {
  80   my ($self, %params) = @_;
  81
  82   my $item = SL::DB::PriceRuleItem->new(type => $::form->{type});
  83
  84   my $html = $self->render('price_rule/item', { output => 0 }, item => $item);
  85
  86   $self
  87     ->js
  88     ->before('#price_rule_new_items', $html)
  89     ->reinit_widgets
  90     ->render($self);
  91 }
  92
  93 #
  94 # filters
  95 #
  96
  97 sub check_auth {
  98   $::auth->assert('price_rule_edit');
  99 }
 100
 101 #
 102 # helpers
 103 #
 104
 105 sub display_form {
 106   my ($self, %params) = @_;
 107   my $is_new  = !$self->price_rule->id;
 108   my $title   = $is_new ?
 109     ($self->price_rule->is_sales ? t8('Create a new sales price rule') : t8('Create a new purchase price rule')) :
 110     ($self->price_rule->is_sales ? t8('Edit sales price rule') : t8('Edit purchase price rule'));
 111   $self->render('price_rule/form',
 112     title => $title,
 113     %params
 114   );
 115 }
 116
 117 sub create_or_update {
 118   my $self   = shift;
 119   my $is_new = !$self->price_rule->id;
 120   my $params = delete($::form->{price_rule}) || { };
 121
 122   delete $params->{id};
 123   $self->price_rule->assign_attributes(%{ $params });
 124
 125   my @errors = $self->price_rule->validate;
 126
 127   if (@errors) {
 128     flash('error', @errors);
 129     $self->display_form(callback => $::form->{callback});
 130     return;
 131   }
 132
 133   $self->price_rule->save;
 134
 135   flash_later('info', $is_new ? $::locale->text('The price rule has been created.') : $::locale->text('The price rule has been saved.'));
 136
 137   $self->redirect_to($::form->{callback} || (action => 'list', 'filter.type' => $self->price_rule->type));
 138 }
 139
 140 sub prepare_report {
 141   my ($self)      = @_;
 142
 143   my $callback    = $self->models->get_callback;
 144
 145   my $report      = SL::ReportGenerator->new(\%::myconfig, $::form);
 146   $self->{report} = $report;
 147
 148   my @columns     = qw(name type priority price discount);
 149   my @sortable    = qw(name type priority price discount);
 150
 151   my %column_defs = (
 152     name          => { obj_link => sub { $self->url_for(action => 'edit', 'price_rule.id' => $_[0]->id, callback => $callback) } },
 153     priority      => { sub  => sub { $_[0]->priority_as_text } },
 154     price         => { sub  => sub { $_[0]->price_as_number } },
 155     discount      => { sub  => sub { $_[0]->discount_as_number } },
 156     obsolete      => { sub  => sub { $_[0]->obsolete_as_bool_yn } },
 157   );
 158
 159   map { $column_defs{$_}->{text} ||= $::locale->text( $self->models->get_sort_spec->{$_}->{title} ) } keys %column_defs;
 160
 161   if ( $report->{options}{output_format} =~ /^(pdf|csv)$/i ) {
 162     $self->models->disable_plugin('paginated');
 163   }
 164   $report->set_options(
 165     std_column_visibility => 1,
 166     controller_class      => 'PriceRule',
 167     output_format         => 'HTML',
 168     title                 => ($self->vc eq 'customer' ? t8('Sales Price Rules') : t8('Purchase Price Rules')) ,
 169     allow_pdf_export      => 1,
 170     allow_csv_export      => 1,
 171   );
 172   $report->set_columns(%column_defs);
 173   $report->set_column_order(@columns);
 174   $report->set_export_options(qw(list filter));
 175   $report->set_options_from_form;
 176   $self->models->set_report_generator_sort_options(report => $report, sortable_columns => \@sortable);
 177   $report->set_options(
 178     raw_bottom_info_text  => $self->render('price_rule/report_bottom', { output => 0 }),
 179     raw_top_info_text     => $self->render('price_rule/report_top', { output => 0 }),
 180   );
 181 }
 182
 183 sub make_filter_summary {
 184   my ($self) = @_;
 185
 186   my $filter = $::form->{filter} || {};
 187   my @filter_strings;
 188
 189   my @filters = (
 190     [ $filter->{"name:substr::ilike"}, t8('Name')  ],
 191     [ $filter->{"price:number"},       t8('Price') ],
 192     [ $filter->{"discount:number"},    t8('Discount') ],
 193   );
 194
 195   for (@filters) {
 196     push @filter_strings, "$_->[1]: $_->[0]" if $_->[0];
 197   }
 198
 199   $self->{filter_summary} = join ', ', @filter_strings;
 200 }
 201
 202 sub all_price_rule_item_types {
 203   SL::DB::Manager::PriceRuleItem->get_all_types($_[0]->price_rule->type);
 204 }
 205
 206 sub add_javascripts  {
 207   $::request->{layout}->add_javascripts(qw(kivi.PriceRule.js autocomplete_customer.js autocomplete_vendor.js autocomplete_part.js));
 208 }
 209
 210 sub init_price_rule {
 211   my ($self) = @_;
 212
 213   my $price_rule = $::form->{price_rule}{id} ? SL::DB::PriceRule->new(id => $::form->{price_rule}{id})->load : SL::DB::PriceRule->new;
 214
 215   my $items = delete $::form->{price_rule}{items};
 216
 217   $price_rule->assign_attributes(%{ $::form->{price_rule} || {} });
 218
 219   my %old_items = map { $_->id => $_ } $price_rule->items;
 220
 221   my @items;
 222   for my $raw_item (@$items) {
 223     my $item = $raw_item->{id} ? $old_items{ $raw_item->{id} } || SL::DB::PriceRuleItem->new(id => $raw_item->{id})->load : SL::DB::PriceRuleItem->new;
 224     $item->assign_attributes(%$raw_item);
 225     push @items, $item;
 226   }
 227
 228   $price_rule->items(@items) if @items;
 229
 230   $self->price_rule($price_rule);
 231 }
 232
 233 sub init_vc {
 234   $::form->{filter}{type};
 235 }
 236
 237 sub init_js {
 238   SL::ClientJS->new;
 239 }
 240
 241 sub init_businesses {
 242   SL::DB::Manager::Business->get_all;
 243 }
 244
 245 sub init_pricegroups {
 246   SL::DB::Manager::Pricegroup->get_all;
 247 }
 248
 249 sub init_partsgroups {
 250   SL::DB::Manager::PartsGroup->get_all;
 251 }
 252
 253 sub init_models {
 254   my ($self) = @_;
 255
 256   SL::Controller::Helper::GetModels->new(
 257     controller => $self,
 258     sorted => {
 259       name     => t8('Name'),
 260       type     => t8('Type'),
 261       priority => t8('Priority'),
 262       price    => t8('Price'),
 263       discount => t8('Discount'),
 264       obsolete => t8('Obsolete'),
 265     },
 266   );
 267 }
 268
 269 1;