SL/Controller/Project.pm

   1 package SL::Controller::Project;
   2
   3 use strict;
   4
   5 use parent qw(SL::Controller::Base);
   6
   7 use Clone qw(clone);
   8
   9 use SL::Controller::Helper::GetModels;
  10 use SL::Controller::Helper::ParseFilter;
  11 use SL::Controller::Helper::ReportGenerator;
  12 use SL::CVar;
  13 use SL::DB::Customer;
  14 use SL::DB::DeliveryOrder;
  15 use SL::DB::Invoice;
  16 use SL::DB::Order;
  17 use SL::DB::Project;
  18 use SL::DB::PurchaseInvoice;
  19 use SL::Helper::Flash;
  20 use SL::Locale::String;
  21
  22 use Rose::Object::MakeMethods::Generic
  23 (
  24  scalar => [ qw(project linked_records) ],
  25  'scalar --get_set_init' => [ qw(models) ],
  26 );
  27
  28 __PACKAGE__->run_before('check_auth');
  29 __PACKAGE__->run_before('load_project', only => [ qw(edit update destroy) ]);
  30
  31 #
  32 # actions
  33 #
  34
  35 sub action_search {
  36   my ($self) = @_;
  37
  38   my %params;
  39
  40   $params{CUSTOM_VARIABLES} = CVar->get_configs(module => 'Projects');
  41   ($params{CUSTOM_VARIABLES_FILTER_CODE}, $params{CUSTOM_VARIABLES_INCLUSION_CODE})
  42     = CVar->render_search_options(variables      => $params{CUSTOM_VARIABLES},
  43                                   include_prefix => 'l_',
  44                                   include_value  => 'Y');
  45
  46   $self->render('project/search', %params);
  47 }
  48
  49 sub action_list {
  50   my ($self) = @_;
  51
  52   # $self->make_filter_summary;
  53
  54   my $projects = $self->models->get;
  55
  56   $self->prepare_report;
  57
  58   $self->report_generator_list_objects(report => $self->{report}, objects => $projects);
  59 }
  60
  61 sub action_new {
  62   my ($self) = @_;
  63
  64   $self->project(SL::DB::Project->new);
  65   $self->display_form(title    => $::locale->text('Create a new project'),
  66                       callback => $::form->{callback} || $self->url_for(action => 'new'));
  67 }
  68
  69 sub action_edit {
  70   my ($self) = @_;
  71
  72   $self->linked_records([
  73     map  { @{ $_ } }
  74     grep { $_      } (
  75       SL::DB::Manager::Order->          get_all(where => [ globalproject_id => $self->project->id ], with_objects => [ 'customer', 'vendor' ], sort_by => 'transdate ASC'),
  76       SL::DB::Manager::DeliveryOrder->  get_all(where => [ globalproject_id => $self->project->id ], with_objects => [ 'customer', 'vendor' ], sort_by => 'transdate ASC'),
  77       SL::DB::Manager::Invoice->        get_all(where => [ globalproject_id => $self->project->id ], with_objects => [ 'customer'           ], sort_by => 'transdate ASC'),
  78       SL::DB::Manager::PurchaseInvoice->get_all(where => [ globalproject_id => $self->project->id ], with_objects => [             'vendor' ], sort_by => 'transdate ASC'),
  79     )]);
  80
  81   $self->display_form(title    => $::locale->text('Edit project #1', $self->project->projectnumber),
  82                       callback => $::form->{callback} || $self->url_for(action => 'edit', id => $self->project->id));
  83 }
  84
  85 sub action_create {
  86   my ($self) = @_;
  87
  88   $self->project(SL::DB::Project->new);
  89   $self->create_or_update;
  90 }
  91
  92 sub action_update {
  93   my ($self) = @_;
  94   $self->create_or_update;
  95 }
  96
  97 sub action_destroy {
  98   my ($self) = @_;
  99
 100   if (eval { $self->project->delete; 1; }) {
 101     flash_later('info',  $::locale->text('The project has been deleted.'));
 102   } else {
 103     flash_later('error', $::locale->text('The project is in use and cannot be deleted.'));
 104   }
 105
 106   $self->redirect_to(action => 'search');
 107 }
 108
 109 #
 110 # filters
 111 #
 112
 113 sub check_auth {
 114   $::auth->assert('project_edit');
 115 }
 116
 117 #
 118 # helpers
 119 #
 120
 121 sub display_form {
 122   my ($self, %params) = @_;
 123
 124   $params{ALL_CUSTOMERS}    = SL::DB::Manager::Customer->get_all_sorted(where => [ or => [ obsolete => 0, obsolete => undef, id => $self->project->customer_id ]]);
 125   $params{CUSTOM_VARIABLES} = CVar->get_custom_variables(module => 'Projects', trans_id => $self->project->id);
 126   CVar->render_inputs(variables => $params{CUSTOM_VARIABLES}) if @{ $params{CUSTOM_VARIABLES} };
 127
 128   $self->render('project/form', %params);
 129 }
 130
 131 sub create_or_update {
 132   my $self   = shift;
 133   my $is_new = !$self->project->id;
 134   my $params = delete($::form->{project}) || { };
 135
 136   delete $params->{id};
 137   $self->project->assign_attributes(%{ $params });
 138
 139   my @errors = $self->project->validate;
 140
 141   if (@errors) {
 142     flash('error', @errors);
 143     $self->display_form(title    => $is_new ? $::locale->text('Create a new project') : $::locale->text('Edit project'),
 144                         callback => $::form->{callback});
 145     return;
 146   }
 147
 148   $self->project->save;
 149
 150   CVar->save_custom_variables(
 151     dbh          => $self->project->db->dbh,
 152     module       => 'Projects',
 153     trans_id     => $self->project->id,
 154     variables    => $::form,
 155     always_valid => 1,
 156   );
 157
 158   flash_later('info', $is_new ? $::locale->text('The project has been created.') : $::locale->text('The project has been saved.'));
 159
 160   $self->redirect_to($::form->{callback} || (action => 'search'));
 161 }
 162
 163 sub load_project {
 164   my ($self) = @_;
 165   $self->project(SL::DB::Project->new(id => $::form->{id})->load);
 166 }
 167
 168 sub setup_db_args_from_filter {
 169   my ($self) = @_;
 170
 171   $self->{filter} = {};
 172   my %args = parse_filter(
 173     $self->_pre_parse_filter($::form->{filter}, $self->{filter}),
 174     with_objects => [ 'customer' ],
 175     launder_to   => $self->{filter},
 176   );
 177
 178   $self->db_args(\%args);
 179 }
 180
 181 sub prepare_report {
 182   my ($self)      = @_;
 183
 184   my $callback    = $self->models->get_callback;
 185
 186   my $report      = SL::ReportGenerator->new(\%::myconfig, $::form);
 187   $self->{report} = $report;
 188
 189   my @columns     = qw(projectnumber description customer active valid type);
 190   my @sortable    = qw(projectnumber description customer              type);
 191
 192   my %column_defs = (
 193     projectnumber => { obj_link => sub { $self->url_for(action => 'edit', id => $_[0]->id, callback => $callback) } },
 194     description   => { obj_link => sub { $self->url_for(action => 'edit', id => $_[0]->id, callback => $callback) } },
 195     type          => { },
 196     customer      => { sub  => sub { $_[0]->customer ? $_[0]->customer->name     : '' } },
 197     active        => { sub  => sub { $_[0]->active   ? $::locale->text('Active') : $::locale->text('Inactive') },
 198                        text => $::locale->text('Active') },
 199     valid         => { sub  => sub { $_[0]->valid    ? $::locale->text('Valid')  : $::locale->text('Invalid')  },
 200                        text => $::locale->text('Valid')  },
 201   );
 202
 203   map { $column_defs{$_}->{text} ||= $::locale->text( $self->models->get_sort_spec->{$_}->{title} ) } keys %column_defs;
 204
 205   $report->set_options(
 206     std_column_visibility => 1,
 207     controller_class      => 'Project',
 208     output_format         => 'HTML',
 209     top_info_text         => $::locale->text('Projects'),
 210     title                 => $::locale->text('Projects'),
 211     allow_pdf_export      => 1,
 212     allow_csv_export      => 1,
 213   );
 214   $report->set_columns(%column_defs);
 215   $report->set_column_order(@columns);
 216   $report->set_export_options(qw(list filter));
 217   $report->set_options_from_form;
 218   $self->models->disable_pagination if $report->{options}{output_format} =~ /^(pdf|csv)$/i;
 219   $self->models->set_report_generator_sort_options(report => $report, sortable_columns => \@sortable);
 220   $report->set_options(
 221     raw_bottom_info_text  => $self->render('project/report_bottom', { output => 0 }),
 222   );
 223 }
 224
 225 sub init_models {
 226   my ($self) = @_;
 227
 228   SL::Controller::Helper::GetModels->new(
 229     controller => $self,
 230     model  => 'Project',
 231     sorted => {
 232       _default => {
 233         by    => 'projectnumber',
 234         dir   => 1,
 235       },
 236       customer      => t8('Customer'),
 237       description   => t8('Description'),
 238       projectnumber => t8('Project Number'),
 239       type          => t8('Type'),
 240     },
 241     with_objects => [ 'customer' ],
 242   );
 243 }
 244
 245 1;