SL/Controller/RecordLinks.pm

   1 package SL::Controller::RecordLinks;
   2
   3 use strict;
   4
   5 use parent qw(SL::Controller::Base);
   6
   7 use List::Util qw(first);
   8
   9 use SL::DB::Helper::Mappings;
  10 use SL::DB::Order;
  11 use SL::DB::DeliveryOrder;
  12 use SL::DB::Invoice;
  13 use SL::DB::Letter;
  14 use SL::DB::PurchaseInvoice;
  15 use SL::DB::RecordLink;
  16 use SL::DB::RequirementSpec;
  17 use SL::DBUtils qw(like);
  18 use SL::JSON;
  19 use SL::Locale::String;
  20
  21 use Rose::Object::MakeMethods::Generic
  22 (
  23   scalar => [ qw(object object_model object_id link_type link_direction link_type_desc) ],
  24 );
  25
  26 __PACKAGE__->run_before('check_auth');
  27 __PACKAGE__->run_before('check_object_params', only => [ qw(ajax_list ajax_delete ajax_add_select_type ajax_add_filter ajax_add_list ajax_add_do) ]);
  28 __PACKAGE__->run_before('check_link_params',   only => [ qw(                                                           ajax_add_list ajax_add_do) ]);
  29
  30 my %link_type_defaults = (
  31   filter            => 'type_filter',
  32   project           => 'globalproject',
  33   description       => 'transaction_description',
  34   description_title => t8('Transaction description'),
  35   date              => 'transdate',
  36 );
  37
  38 my @link_type_specifics = (
  39   { title => t8('Requirement spec'),        type => 'requirement_spec',        model => 'RequirementSpec', number => 'id',           description => 'title',   description_title => t8('Title'),   date => undef, project => 'project', filter => 'working_copy_filter', },
  40   { title => t8('Sales quotation'),         type => 'sales_quotation',         model => 'Order',           number => 'quonumber', },
  41   { title => t8('Sales Order'),             type => 'sales_order',             model => 'Order',           number => 'ordnumber', },
  42   { title => t8('Sales delivery order'),    type => 'sales_delivery_order',    model => 'DeliveryOrder',   number => 'donumber',  },
  43   { title => t8('Sales Invoice'),           type => 'invoice',                 model => 'Invoice',         number => 'invnumber', },
  44   { title => t8('Request for Quotation'),   type => 'request_quotation',       model => 'Order',           number => 'quonumber', },
  45   { title => t8('Purchase Order'),          type => 'purchase_order',          model => 'Order',           number => 'ordnumber', },
  46   { title => t8('Purchase delivery order'), type => 'purchase_delivery_order', model => 'DeliveryOrder',   number => 'donumber',  },
  47   { title => t8('Purchase Invoice'),        type => 'purchase_invoice',        model => 'PurchaseInvoice', number => 'invnumber', },
  48   { title => t8('Letter'),                  type => 'letter',                  model => 'Letter',          number => 'letternumber', description => 'subject', description_title => t8('Subject'), date => 'date', project => undef },
  49 );
  50
  51 my @link_types = map { +{ %link_type_defaults, %{ $_ } } } @link_type_specifics;
  52
  53 #
  54 # actions
  55 #
  56
  57 sub action_ajax_list {
  58   my ($self) = @_;
  59
  60   eval {
  61     my $linked_records = $self->object->linked_records(direction => 'both', recursive => 1, save_path => 1);
  62     push @{ $linked_records }, $self->object->sepa_export_items if $self->object->can('sepa_export_items');
  63     my $output         = SL::Presenter->get->grouped_record_list(
  64       $linked_records,
  65       with_columns      => [ qw(record_link_direction) ],
  66       edit_record_links => 1,
  67       object_model      => $self->object_model,
  68       object_id         => $self->object_id,
  69     );
  70     $self->render(\$output, { layout => 0, process => 0 });
  71
  72     1;
  73   } or do {
  74     $self->render('generic/error', { layout => 0 }, label_error => $@);
  75   };
  76 }
  77
  78 sub action_ajax_delete {
  79   my ($self) = @_;
  80
  81   foreach my $str (@{ $::form->{record_links_delete} || [] }) {
  82     my ($from_table, $from_id, $to_table, $to_id) = split m/__/, $str, 4;
  83     $from_id *= 1;
  84     $to_id   *= 1;
  85
  86     next if !$from_table || !$from_id || !$to_table || !$to_id;
  87
  88     SL::DB::Manager::RecordLink->delete_all(where => [
  89       from_table => $from_table,
  90       from_id    => $from_id,
  91       to_table   => $to_table,
  92       to_id      => $to_id,
  93     ]);
  94   }
  95
  96   $self->action_ajax_list;
  97 }
  98
  99 sub action_ajax_add_filter {
 100   my ($self) = @_;
 101
 102   my $presenter = $self->presenter;
 103
 104   my @link_type_select = map { [ $_->{type}, $_->{title} ] } @link_types;
 105   my @projects         = map { [ $_->id, $presenter->project($_, display => 'inline', style => 'both', no_link => 1) ] } @{ SL::DB::Manager::Project->get_all_sorted };
 106   my $is_sales         = $self->object->can('customer_id') && $self->object->customer_id;
 107
 108   $self->render(
 109     'record_links/add_filter',
 110     { layout          => 0 },
 111     is_sales          => $is_sales,
 112     DEFAULT_LINK_TYPE => $is_sales ? 'sales_quotation' : 'request_quotation',
 113     LINK_TYPES        => \@link_type_select,
 114     PROJECTS          => \@projects,
 115   );
 116 }
 117
 118 sub action_ajax_add_list {
 119   my ($self) = @_;
 120
 121   my $manager     = 'SL::DB::Manager::' . $self->link_type_desc->{model};
 122   my $vc          = $self->link_type =~ m/sales_|^invoice|requirement_spec|letter/ ? 'customer' : 'vendor';
 123   my $project     = $self->link_type_desc->{project};
 124   my $project_id  = "${project}_id";
 125   my $description = $self->link_type_desc->{description};
 126   my $filter      = $self->link_type_desc->{filter};
 127
 128   my @where = $filter && $manager->can($filter) ? $manager->$filter($self->link_type) : ();
 129   push @where, ("${vc}.${vc}number"     => { ilike => like($::form->{vc_number}) })               if $::form->{vc_number};
 130   push @where, ("${vc}.name"            => { ilike => like($::form->{vc_name}) })                 if $::form->{vc_name};
 131   push @where, ($description            => { ilike => like($::form->{transaction_description}) }) if $::form->{transaction_description};
 132   push @where, ($project_id             => $::form->{globalproject_id})                           if $::form->{globalproject_id} && $manager->can($project_id);
 133
 134   my @with_objects = ($vc);
 135   push @with_objects, $project if $manager->can($project_id);
 136
 137   my $objects = $manager->get_all_sorted(where => \@where, with_objects => \@with_objects);
 138   my $output  = $self->render(
 139     'record_links/add_list',
 140     { output => 0 },
 141     OBJECTS            => $objects,
 142     vc                 => $vc,
 143     number_column      => $self->link_type_desc->{number},
 144     description_column => $description,
 145     description_title  => $self->link_type_desc->{description_title},
 146     project_column     => $project,
 147     date_column        => $self->link_type_desc->{date},
 148   );
 149
 150   my %result = ( count => scalar(@{ $objects }), html => $output );
 151
 152   $self->render(\to_json(\%result), { type => 'json', process => 0 });
 153 }
 154
 155 sub action_ajax_add_do {
 156   my ($self, %params) = @_;
 157
 158   my $object_side = $self->link_direction eq 'from' ? 'from' : 'to';
 159   my $link_side   = $object_side          eq 'from' ? 'to'   : 'from';
 160   my $link_table  = SL::DB::Helper::Mappings::get_table_for_package($self->link_type_desc->{model});
 161
 162   foreach my $link_id (@{ $::form->{link_id} || [] }) {
 163     # Check for existing reverse connections in order to avoid loops.
 164     my @props = (
 165       "${link_side}_table"   => $self->object->meta->table,
 166       "${link_side}_id"      => $self->object_id,
 167       "${object_side}_table" => $link_table,
 168       "${object_side}_id"    => $link_id,
 169     );
 170
 171     my $existing = SL::DB::Manager::RecordLink->get_all(where => \@props, limit => 1)->[0];
 172     next if $existing;
 173
 174     # Check for existing connections in order to avoid duplicates.
 175     @props = (
 176       "${object_side}_table" => $self->object->meta->table,
 177       "${object_side}_id"    => $self->object_id,
 178       "${link_side}_table"   => $link_table,
 179       "${link_side}_id"      => $link_id,
 180     );
 181
 182     $existing = SL::DB::Manager::RecordLink->get_all(where => \@props, limit => 1)->[0];
 183
 184     SL::DB::RecordLink->new(@props)->save if !$existing;
 185   }
 186
 187   $self->action_ajax_list;
 188 }
 189
 190
 191 #
 192 # filters
 193 #
 194
 195 sub check_object_params {
 196   my ($self) = @_;
 197
 198   my %models = map { ($_->{model} => 1 ) } @link_types;
 199
 200   $self->object_id(   $::form->{object_id});
 201   $self->object_model($::form->{object_model});
 202
 203   die "Invalid object_model or object_id" if !$self->object_id || !$models{$self->object_model};
 204
 205   my $model = 'SL::DB::' . $self->object_model;
 206   $self->object($model->new(id => $self->object_id)->load || die "Record not found");
 207
 208   return 1;
 209 }
 210
 211 sub check_link_params {
 212   my ($self) = @_;
 213
 214   $self->link_type(     $::form->{link_type});
 215   $self->link_type_desc((first { $_->{type} eq $::form->{link_type} } @link_types)                || die "Invalid link_type");
 216   $self->link_direction($::form->{link_direction} =~ m/^(?:from|to)$/ ? $::form->{link_direction} :  die "Invalid link_direction");
 217
 218   return 1;
 219 }
 220
 221 sub check_auth {
 222   $::auth->assert('record_links');
 223 }
 224
 225 1;