SL/Controller/RecordLinks.pm

   1 package SL::Controller::RecordLinks;
   2
   3 use strict;
   4
   5 use parent qw(SL::Controller::Base);
   6
   7 use List::Util qw(first);
   8
   9 use SL::DB::Helper::Mappings;
  10 use SL::DB::Order;
  11 use SL::DB::DeliveryOrder;
  12 use SL::DB::Invoice;
  13 use SL::DB::Letter;
  14 use SL::DB::PurchaseInvoice;
  15 use SL::DB::RecordLink;
  16 use SL::DB::RequirementSpec;
  17 use SL::DBUtils qw(like);
  18 use SL::DB::ShopOrder;
  19 use SL::JSON;
  20 use SL::Locale::String;
  21 use SL::Presenter::Record qw(grouped_record_list);
  22
  23 use Rose::Object::MakeMethods::Generic
  24 (
  25   scalar => [ qw(object object_model object_id link_type link_direction link_type_desc) ],
  26 );
  27
  28 __PACKAGE__->run_before('check_auth');
  29 __PACKAGE__->run_before('check_object_params', only => [ qw(ajax_list ajax_delete ajax_add_select_type ajax_add_filter ajax_add_list ajax_add_do) ]);
  30 __PACKAGE__->run_before('check_link_params',   only => [ qw(                                                           ajax_add_list ajax_add_do) ]);
  31
  32 my %link_type_defaults = (
  33   filter            => 'type_filter',
  34   project           => 'globalproject',
  35   description       => 'transaction_description',
  36   description_title => t8('Transaction description'),
  37   date              => 'transdate',
  38 );
  39
  40 my @link_type_specifics = (
  41   { title => t8('Requirement spec'),        type => 'requirement_spec',        model => 'RequirementSpec', number => 'id', project => 'project', description => 'title', date => undef, filter => 'working_copy_filter', },
  42   { title => t8('Shop Order'),              type => 'shop_order',              model => 'ShopOrder',       number => 'shop_ordernumber', date => 'order_date', project => undef, },
  43   { title => t8('Sales quotation'),         type => 'sales_quotation',         model => 'Order',           number => 'quonumber', },
  44   { title => t8('Sales Order'),             type => 'sales_order',             model => 'Order',           number => 'ordnumber', },
  45   { title => t8('Sales delivery order'),    type => 'sales_delivery_order',    model => 'DeliveryOrder',   number => 'donumber',  },
  46   { title => t8('Sales Invoice'),           type => 'invoice',                 model => 'Invoice',         number => 'invnumber', },
  47   { title => t8('Request for Quotation'),   type => 'request_quotation',       model => 'Order',           number => 'quonumber', },
  48   { title => t8('Purchase Order'),          type => 'purchase_order',          model => 'Order',           number => 'ordnumber', },
  49   { title => t8('Purchase delivery order'), type => 'purchase_delivery_order', model => 'DeliveryOrder',   number => 'donumber',  },
  50   { title => t8('Purchase Invoice'),        type => 'purchase_invoice',        model => 'PurchaseInvoice', number => 'invnumber', },
  51   { title => t8('Letter'),                  type => 'letter',                  model => 'Letter',          number => 'letternumber', description => 'subject', description_title => t8('Subject'), date => 'date', project => undef },
  52   { title => t8('Email'),                   type => 'email_journal',           model => 'EmailJournal',    number => 'id', description => 'subject', description_title => t8('Subject'), },
  53   { title => t8('AR Transaction'),          type => 'ar_transaction',          model => 'Invoice',         number => 'invnumber', },
  54   { title => t8('AP Transaction'),          type => 'ap_transaction',          model => 'PurchaseInvoice', number => 'invnumber', },
  55   { title => t8('Dunning'),                 type => 'dunning',                 model => 'Dunning',         number => 'dunning_id', },
  56 );
  57
  58 my @link_types = map { +{ %link_type_defaults, %{ $_ } } } @link_type_specifics;
  59
  60 #
  61 # actions
  62 #
  63
  64 sub action_ajax_list {
  65   my ($self) = @_;
  66
  67   eval {
  68     my $linked_records = ($::instance_conf->get_always_record_links_from_order && ref $self->object ne 'SL::DB::Order')
  69                        ?  $self->get_order_centric_linked_records
  70                        :  $self->object->linked_records(direction => 'both', recursive => 1, save_path => 1);
  71
  72     push @{ $linked_records }, $self->object->sepa_export_items if $self->object->can('sepa_export_items');
  73
  74     my $output         = grouped_record_list(
  75       $linked_records,
  76       with_columns      => [ qw(record_link_direction) ],
  77       edit_record_links => 1,
  78       object_model      => $self->object_model,
  79       object_id         => $self->object_id,
  80     );
  81     $self->render(\$output, { layout => 0, process => 0 });
  82
  83     1;
  84   } or do {
  85     $self->render('generic/error', { layout => 0 }, label_error => $@);
  86   };
  87 }
  88
  89 sub action_ajax_delete {
  90   my ($self) = @_;
  91
  92   foreach my $str (@{ $::form->{record_links_delete} || [] }) {
  93     my ($from_table, $from_id, $to_table, $to_id) = split m/__/, $str, 4;
  94     $from_id *= 1;
  95     $to_id   *= 1;
  96
  97     next if !$from_table || !$from_id || !$to_table || !$to_id;
  98
  99     SL::DB::Manager::RecordLink->delete_all(where => [
 100       from_table => $from_table,
 101       from_id    => $from_id,
 102       to_table   => $to_table,
 103       to_id      => $to_id,
 104     ]);
 105   }
 106
 107   $self->action_ajax_list;
 108 }
 109
 110 sub action_ajax_add_filter {
 111   my ($self) = @_;
 112
 113   my $presenter = $self->presenter;
 114
 115   my @link_type_select = map { [ $_->{type}, $_->{title} ] } @link_types;
 116   my @projects         = map { [ $_->id, $_->presenter->project(display => 'inline', style => 'both', no_link => 1) ] } @{ SL::DB::Manager::Project->get_all_sorted };
 117   my $is_sales         = $self->object->can('customer_id') && $self->object->customer_id;
 118
 119   $self->render(
 120     'record_links/add_filter',
 121     { layout          => 0 },
 122     is_sales          => $is_sales,
 123     DEFAULT_LINK_TYPE => $is_sales ? 'sales_quotation' : 'request_quotation',
 124     LINK_TYPES        => \@link_type_select,
 125     PROJECTS          => \@projects,
 126   );
 127 }
 128
 129 sub action_ajax_add_list {
 130   my ($self) = @_;
 131
 132   my $manager     = 'SL::DB::Manager::' . $self->link_type_desc->{model};
 133   my $vc          = $self->link_type =~ m/shop|sales_|^invoice|requirement_spec|letter|^ar_/ ? 'customer' : 'vendor';
 134   my $project     = $self->link_type_desc->{project};
 135   my $project_id  = "${project}_id";
 136   my $description = $self->link_type_desc->{description};
 137   my $filter      = $self->link_type_desc->{filter};
 138   my $number      = $self->link_type_desc->{number};
 139
 140   my @where = $filter && $manager->can($filter) ? $manager->$filter($self->link_type) : ();
 141   push @where, ("${vc}.${vc}number"     => { ilike => like($::form->{vc_number}) })               if $::form->{vc_number};
 142   push @where, ("${vc}.name"            => { ilike => like($::form->{vc_name}) })                 if $::form->{vc_name};
 143   push @where, ($description            => { ilike => like($::form->{transaction_description}) }) if $::form->{transaction_description};
 144   push @where, ($project_id             => $::form->{globalproject_id})                           if $::form->{globalproject_id} && $manager->can($project_id);
 145
 146   if ($::form->{number}) {
 147     my $class    = 'SL::DB::' . $self->link_type_desc->{model};
 148     my $col_type = ref $class->meta->column($number);
 149     if ($col_type =~ /^Rose::DB::Object::Metadata::Column::(?:Integer|Serial)$/) {
 150       push @where, ($number => $::form->{number});
 151     } elsif ($col_type =~ /^Rose::DB::Object::Metadata::Column::Text$/) {
 152       push @where, ($number => { ilike => like($::form->{number}) });
 153     }
 154   }
 155
 156   my @with_objects = ($vc);
 157   push @with_objects, $project if $manager->can($project_id);
 158
 159   # show the newest records first (should be better for 80% of the cases TODO sortable click
 160   my $objects = $manager->get_all_sorted(where => \@where, with_objects => \@with_objects, sort_by => 'itime',  sort_dir => 'ASC');
 161   my $output  = $self->render(
 162     'record_links/add_list',
 163     { output => 0 },
 164     OBJECTS            => $objects,
 165     vc                 => $vc,
 166     number_column      => $self->link_type_desc->{number},
 167     description_column => $description,
 168     description_title  => $self->link_type_desc->{description_title},
 169     project_column     => $project,
 170     date_column        => $self->link_type_desc->{date},
 171   );
 172
 173   my %result = ( count => scalar(@{ $objects }), html => $output );
 174
 175   $self->render(\to_json(\%result), { type => 'json', process => 0 });
 176 }
 177
 178 sub action_ajax_add_do {
 179   my ($self, %params) = @_;
 180
 181   my $object_side = $self->link_direction eq 'from' ? 'from' : 'to';
 182   my $link_side   = $object_side          eq 'from' ? 'to'   : 'from';
 183   my $link_table  = SL::DB::Helper::Mappings::get_table_for_package($self->link_type_desc->{model});
 184
 185   foreach my $link_id (@{ $::form->{link_id} || [] }) {
 186     # Check for existing reverse connections in order to avoid loops.
 187     my @props = (
 188       "${link_side}_table"   => $self->object->meta->table,
 189       "${link_side}_id"      => $self->object_id,
 190       "${object_side}_table" => $link_table,
 191       "${object_side}_id"    => $link_id,
 192     );
 193
 194     my $existing = SL::DB::Manager::RecordLink->get_all(where => \@props, limit => 1)->[0];
 195     next if $existing;
 196
 197     # Check for existing connections in order to avoid duplicates.
 198     @props = (
 199       "${object_side}_table" => $self->object->meta->table,
 200       "${object_side}_id"    => $self->object_id,
 201       "${link_side}_table"   => $link_table,
 202       "${link_side}_id"      => $link_id,
 203     );
 204
 205     $existing = SL::DB::Manager::RecordLink->get_all(where => \@props, limit => 1)->[0];
 206
 207     SL::DB::RecordLink->new(@props)->save if !$existing;
 208   }
 209
 210   $self->action_ajax_list;
 211 }
 212
 213
 214 #
 215 # filters
 216 #
 217
 218 sub check_object_params {
 219   my ($self) = @_;
 220
 221   my %models = map { ($_->{model} => 1 ) } @link_types;
 222
 223   $self->object_id(   $::form->{object_id});
 224   $self->object_model($::form->{object_model});
 225
 226   die "Invalid object_model or object_id" if !$self->object_id || !$models{$self->object_model};
 227
 228   my $model = 'SL::DB::' . $self->object_model;
 229   $self->object($model->new(id => $self->object_id)->load || die "Record not found");
 230
 231   return 1;
 232 }
 233
 234 sub check_link_params {
 235   my ($self) = @_;
 236
 237   $self->link_type(     $::form->{link_type});
 238   $self->link_type_desc((first { $_->{type} eq $::form->{link_type} } @link_types)                || die "Invalid link_type");
 239   $self->link_direction($::form->{link_direction} =~ m/^(?:from|to)$/ ? $::form->{link_direction} :  die "Invalid link_direction");
 240
 241   return 1;
 242 }
 243
 244 sub check_auth {
 245   $::auth->assert('record_links');
 246 }
 247
 248 # internal
 249
 250 sub get_order_centric_linked_records {
 251   my ($self) = @_;
 252
 253   my $all_linked_records = $self->object->linked_records(direction => 'from', recursive => 1);
 254   my $filtered_orders = [ grep { 'SL::DB::Order' eq ref $_ && $_->is_type('sales_order') } @$all_linked_records ];
 255   my $id_ref = [ map { $_->id } @$filtered_orders ];
 256   my $linked_records = SL::DB::Order->new->linked_records(direction => 'to', recursive => 1, batch => $id_ref);
 257   push @{ $linked_records }, @$filtered_orders;
 258
 259   return $linked_records;
 260 }
 261 1;