SL/Controller/RecordLinks.pm

   1 package SL::Controller::RecordLinks;
   2
   3 use strict;
   4
   5 use parent qw(SL::Controller::Base);
   6
   7 use List::Util qw(first);
   8
   9 use SL::DB::Helper::Mappings;
  10 use SL::DB::Order;
  11 use SL::DB::DeliveryOrder;
  12 use SL::DB::Invoice;
  13 use SL::DB::Letter;
  14 use SL::DB::PurchaseInvoice;
  15 use SL::DB::RecordLink;
  16 use SL::DB::RequirementSpec;
  17 use SL::DBUtils qw(like);
  18 use SL::DB::ShopOrder;
  19 use SL::JSON;
  20 use SL::Locale::String;
  21 use SL::Presenter::Record qw(grouped_record_list);
  22
  23 use Rose::Object::MakeMethods::Generic
  24 (
  25   scalar => [ qw(object object_model object_id link_type link_direction link_type_desc) ],
  26 );
  27
  28 __PACKAGE__->run_before('check_auth');
  29 __PACKAGE__->run_before('check_object_params', only => [ qw(ajax_list ajax_delete ajax_add_select_type ajax_add_filter ajax_add_list ajax_add_do) ]);
  30 __PACKAGE__->run_before('check_link_params',   only => [ qw(                                                           ajax_add_list ajax_add_do) ]);
  31
  32 my %link_type_defaults = (
  33   filter            => 'type_filter',
  34   project           => 'globalproject',
  35   description       => 'transaction_description',
  36   description_title => t8('Transaction description'),
  37   date              => 'transdate',
  38 );
  39
  40 my @link_type_specifics = (
  41   { title => t8('Requirement spec'),        type => 'requirement_spec',        model => 'RequirementSpec', number => 'id', project => 'project', description => 'title', date => undef, filter => 'working_copy_filter', },
  42   { title => t8('Shop Order'),              type => 'shop_order',              model => 'ShopOrder',       number => 'shop_ordernumber', date => 'order_date', project => undef, },
  43   { title => t8('Sales quotation'),         type => 'sales_quotation',         model => 'Order',           number => 'quonumber', },
  44   { title => t8('Sales Order'),             type => 'sales_order',             model => 'Order',           number => 'ordnumber', },
  45   { title => t8('Sales delivery order'),    type => 'sales_delivery_order',    model => 'DeliveryOrder',   number => 'donumber',  },
  46   { title => t8('Sales Invoice'),           type => 'invoice',                 model => 'Invoice',         number => 'invnumber', },
  47   { title => t8('Request for Quotation'),   type => 'request_quotation',       model => 'Order',           number => 'quonumber', },
  48   { title => t8('Purchase Order'),          type => 'purchase_order',          model => 'Order',           number => 'ordnumber', },
  49   { title => t8('Purchase delivery order'), type => 'purchase_delivery_order', model => 'DeliveryOrder',   number => 'donumber',  },
  50   { title => t8('Purchase Invoice'),        type => 'purchase_invoice',        model => 'PurchaseInvoice', number => 'invnumber', },
  51   { title => t8('Letter'),                  type => 'letter',                  model => 'Letter',          number => 'letternumber', description => 'subject', description_title => t8('Subject'), date => 'date', project => undef },
  52   { title => t8('Email'),                   type => 'email_journal',           model => 'EmailJournal',    number => 'id', description => 'subject', description_title => t8('Subject'), },
  53 );
  54
  55 my @link_types = map { +{ %link_type_defaults, %{ $_ } } } @link_type_specifics;
  56
  57 #
  58 # actions
  59 #
  60
  61 sub action_ajax_list {
  62   my ($self) = @_;
  63
  64   eval {
  65     my $linked_records = $self->object->linked_records(direction => 'both', recursive => 1, save_path => 1);
  66     push @{ $linked_records }, $self->object->sepa_export_items if $self->object->can('sepa_export_items');
  67
  68     my $output         = grouped_record_list(
  69       $linked_records,
  70       with_columns      => [ qw(record_link_direction) ],
  71       edit_record_links => 1,
  72       object_model      => $self->object_model,
  73       object_id         => $self->object_id,
  74     );
  75     $self->render(\$output, { layout => 0, process => 0 });
  76
  77     1;
  78   } or do {
  79     $self->render('generic/error', { layout => 0 }, label_error => $@);
  80   };
  81 }
  82
  83 sub action_ajax_delete {
  84   my ($self) = @_;
  85
  86   foreach my $str (@{ $::form->{record_links_delete} || [] }) {
  87     my ($from_table, $from_id, $to_table, $to_id) = split m/__/, $str, 4;
  88     $from_id *= 1;
  89     $to_id   *= 1;
  90
  91     next if !$from_table || !$from_id || !$to_table || !$to_id;
  92
  93     SL::DB::Manager::RecordLink->delete_all(where => [
  94       from_table => $from_table,
  95       from_id    => $from_id,
  96       to_table   => $to_table,
  97       to_id      => $to_id,
  98     ]);
  99   }
 100
 101   $self->action_ajax_list;
 102 }
 103
 104 sub action_ajax_add_filter {
 105   my ($self) = @_;
 106
 107   my $presenter = $self->presenter;
 108
 109   my @link_type_select = map { [ $_->{type}, $_->{title} ] } @link_types;
 110   my @projects         = map { [ $_->id, $_->presenter->project(display => 'inline', style => 'both', no_link => 1) ] } @{ SL::DB::Manager::Project->get_all_sorted };
 111   my $is_sales         = $self->object->can('customer_id') && $self->object->customer_id;
 112
 113   $self->render(
 114     'record_links/add_filter',
 115     { layout          => 0 },
 116     is_sales          => $is_sales,
 117     DEFAULT_LINK_TYPE => $is_sales ? 'sales_quotation' : 'request_quotation',
 118     LINK_TYPES        => \@link_type_select,
 119     PROJECTS          => \@projects,
 120   );
 121 }
 122
 123 sub action_ajax_add_list {
 124   my ($self) = @_;
 125
 126   my $manager     = 'SL::DB::Manager::' . $self->link_type_desc->{model};
 127   my $vc          = $self->link_type =~ m/shop|sales_|^invoice|requirement_spec|letter/ ? 'customer' : 'vendor';
 128   my $project     = $self->link_type_desc->{project};
 129   my $project_id  = "${project}_id";
 130   my $description = $self->link_type_desc->{description};
 131   my $filter      = $self->link_type_desc->{filter};
 132
 133   my @where = $filter && $manager->can($filter) ? $manager->$filter($self->link_type) : ();
 134   push @where, ("${vc}.${vc}number"     => { ilike => like($::form->{vc_number}) })               if $::form->{vc_number};
 135   push @where, ("${vc}.name"            => { ilike => like($::form->{vc_name}) })                 if $::form->{vc_name};
 136   push @where, ($description            => { ilike => like($::form->{transaction_description}) }) if $::form->{transaction_description};
 137   push @where, ($project_id             => $::form->{globalproject_id})                           if $::form->{globalproject_id} && $manager->can($project_id);
 138
 139   my @with_objects = ($vc);
 140   push @with_objects, $project if $manager->can($project_id);
 141
 142   # show the newest records first (should be better for 80% of the cases TODO sortable click
 143   my $objects = $manager->get_all_sorted(where => \@where, with_objects => \@with_objects, sort_by => 'itime',  sort_dir => 'ASC');
 144   my $output  = $self->render(
 145     'record_links/add_list',
 146     { output => 0 },
 147     OBJECTS            => $objects,
 148     vc                 => $vc,
 149     number_column      => $self->link_type_desc->{number},
 150     description_column => $description,
 151     description_title  => $self->link_type_desc->{description_title},
 152     project_column     => $project,
 153     date_column        => $self->link_type_desc->{date},
 154   );
 155
 156   my %result = ( count => scalar(@{ $objects }), html => $output );
 157
 158   $self->render(\to_json(\%result), { type => 'json', process => 0 });
 159 }
 160
 161 sub action_ajax_add_do {
 162   my ($self, %params) = @_;
 163
 164   my $object_side = $self->link_direction eq 'from' ? 'from' : 'to';
 165   my $link_side   = $object_side          eq 'from' ? 'to'   : 'from';
 166   my $link_table  = SL::DB::Helper::Mappings::get_table_for_package($self->link_type_desc->{model});
 167
 168   foreach my $link_id (@{ $::form->{link_id} || [] }) {
 169     # Check for existing reverse connections in order to avoid loops.
 170     my @props = (
 171       "${link_side}_table"   => $self->object->meta->table,
 172       "${link_side}_id"      => $self->object_id,
 173       "${object_side}_table" => $link_table,
 174       "${object_side}_id"    => $link_id,
 175     );
 176
 177     my $existing = SL::DB::Manager::RecordLink->get_all(where => \@props, limit => 1)->[0];
 178     next if $existing;
 179
 180     # Check for existing connections in order to avoid duplicates.
 181     @props = (
 182       "${object_side}_table" => $self->object->meta->table,
 183       "${object_side}_id"    => $self->object_id,
 184       "${link_side}_table"   => $link_table,
 185       "${link_side}_id"      => $link_id,
 186     );
 187
 188     $existing = SL::DB::Manager::RecordLink->get_all(where => \@props, limit => 1)->[0];
 189
 190     SL::DB::RecordLink->new(@props)->save if !$existing;
 191   }
 192
 193   $self->action_ajax_list;
 194 }
 195
 196
 197 #
 198 # filters
 199 #
 200
 201 sub check_object_params {
 202   my ($self) = @_;
 203
 204   my %models = map { ($_->{model} => 1 ) } @link_types;
 205
 206   $self->object_id(   $::form->{object_id});
 207   $self->object_model($::form->{object_model});
 208
 209   die "Invalid object_model or object_id" if !$self->object_id || !$models{$self->object_model};
 210
 211   my $model = 'SL::DB::' . $self->object_model;
 212   $self->object($model->new(id => $self->object_id)->load || die "Record not found");
 213
 214   return 1;
 215 }
 216
 217 sub check_link_params {
 218   my ($self) = @_;
 219
 220   $self->link_type(     $::form->{link_type});
 221   $self->link_type_desc((first { $_->{type} eq $::form->{link_type} } @link_types)                || die "Invalid link_type");
 222   $self->link_direction($::form->{link_direction} =~ m/^(?:from|to)$/ ? $::form->{link_direction} :  die "Invalid link_direction");
 223
 224   return 1;
 225 }
 226
 227 sub check_auth {
 228   $::auth->assert('record_links');
 229 }
 230
 231 1;