SL/Controller/RecordLinks.pm

   1 package SL::Controller::RecordLinks;
   2
   3 use strict;
   4
   5 use parent qw(SL::Controller::Base);
   6
   7 use List::Util qw(first);
   8
   9 use SL::DB::Helper::Mappings;
  10 use SL::DB::Order;
  11 use SL::DB::DeliveryOrder;
  12 use SL::DB::Invoice;
  13 use SL::DB::Letter;
  14 use SL::DB::PurchaseInvoice;
  15 use SL::DB::RecordLink;
  16 use SL::DB::RequirementSpec;
  17 use SL::DBUtils qw(like);
  18 use SL::DB::ShopOrder;
  19 use SL::JSON;
  20 use SL::Locale::String;
  21 use SL::Presenter::Record qw(grouped_record_list);
  22
  23 use Rose::Object::MakeMethods::Generic
  24 (
  25   scalar => [ qw(object object_model object_id link_type link_direction link_type_desc) ],
  26 );
  27
  28 __PACKAGE__->run_before('check_auth');
  29 __PACKAGE__->run_before('check_object_params', only => [ qw(ajax_list ajax_delete ajax_add_select_type ajax_add_filter ajax_add_list ajax_add_do) ]);
  30 __PACKAGE__->run_before('check_link_params',   only => [ qw(                                                           ajax_add_list ajax_add_do) ]);
  31
  32 my %link_type_defaults = (
  33   filter            => 'type_filter',
  34   project           => 'globalproject',
  35   description       => 'transaction_description',
  36   description_title => t8('Transaction description'),
  37   date              => 'transdate',
  38 );
  39
  40 my @link_type_specifics = (
  41   { title => t8('Requirement spec'),        type => 'requirement_spec',        model => 'RequirementSpec', number => 'id', project => 'project', description => 'title', date => undef, filter => 'working_copy_filter', },
  42   { title => t8('Shop Order'),              type => 'shop_order',              model => 'ShopOrder',       number => 'shop_ordernumber', date => 'order_date', project => undef, },
  43   { title => t8('Sales quotation'),         type => 'sales_quotation',         model => 'Order',           number => 'quonumber', },
  44   { title => t8('Sales Order'),             type => 'sales_order',             model => 'Order',           number => 'ordnumber', },
  45   { title => t8('Sales delivery order'),    type => 'sales_delivery_order',    model => 'DeliveryOrder',   number => 'donumber',  },
  46   { title => t8('RMA delivery order'),      type => 'rma_delivery_order',      model => 'DeliveryOrder',   number => 'rdonumber', },
  47   { title => t8('Sales Invoice'),           type => 'invoice',                 model => 'Invoice',         number => 'invnumber', },
  48   { title => t8('Request for Quotation'),   type => 'request_quotation',       model => 'Order',           number => 'quonumber', },
  49   { title => t8('Purchase Order'),          type => 'purchase_order',          model => 'Order',           number => 'ordnumber', },
  50   { title => t8('Purchase delivery order'), type => 'purchase_delivery_order', model => 'DeliveryOrder',   number => 'donumber',  },
  51   { title => t8('Supplier delivery order'), type => 'supplier_delivery_order', model => 'DeliveryOrder',   number => 'sdonumber', },
  52   { title => t8('Purchase Invoice'),        type => 'purchase_invoice',        model => 'PurchaseInvoice', number => 'invnumber', },
  53   { title => t8('Letter'),                  type => 'letter',                  model => 'Letter',          number => 'letternumber', description => 'subject', description_title => t8('Subject'), date => 'date', project => undef },
  54   { title => t8('Email'),                   type => 'email_journal',           model => 'EmailJournal',    number => 'id', description => 'subject', description_title => t8('Subject'), },
  55   { title => t8('AR Transaction'),          type => 'ar_transaction',          model => 'Invoice',         number => 'invnumber', },
  56   { title => t8('AP Transaction'),          type => 'ap_transaction',          model => 'PurchaseInvoice', number => 'invnumber', },
  57   { title => t8('Dunning'),                 type => 'dunning',                 model => 'Dunning',         number => 'dunning_id', },
  58 );
  59
  60 my @link_types = map { +{ %link_type_defaults, %{ $_ } } } @link_type_specifics;
  61
  62 #
  63 # actions
  64 #
  65
  66 sub action_ajax_list {
  67   my ($self) = @_;
  68
  69   eval {
  70     my $linked_records = ($::instance_conf->get_always_record_links_from_order && ref $self->object ne 'SL::DB::Order')
  71                        ?  $self->get_order_centric_linked_records
  72                        :  $self->object->linked_records(direction => 'both', recursive => 1, save_path => 1);
  73
  74     push @{ $linked_records }, $self->object->sepa_export_items if $self->object->can('sepa_export_items');
  75
  76     my $output         = grouped_record_list(
  77       $linked_records,
  78       with_columns      => [ qw(record_link_direction) ],
  79       edit_record_links => 1,
  80       object_model      => $self->object_model,
  81       object_id         => $self->object_id,
  82     );
  83     $self->render(\$output, { layout => 0, process => 0 });
  84
  85     1;
  86   } or do {
  87     $self->render('generic/error', { layout => 0 }, label_error => $@);
  88   };
  89 }
  90
  91 sub action_ajax_delete {
  92   my ($self) = @_;
  93
  94   foreach my $str (@{ $::form->{record_links_delete} || [] }) {
  95     my ($from_table, $from_id, $to_table, $to_id) = split m/__/, $str, 4;
  96     $from_id *= 1;
  97     $to_id   *= 1;
  98
  99     next if !$from_table || !$from_id || !$to_table || !$to_id;
 100
 101     SL::DB::Manager::RecordLink->delete_all(where => [
 102       from_table => $from_table,
 103       from_id    => $from_id,
 104       to_table   => $to_table,
 105       to_id      => $to_id,
 106     ]);
 107   }
 108
 109   $self->action_ajax_list;
 110 }
 111
 112 sub action_ajax_add_filter {
 113   my ($self) = @_;
 114
 115   my $presenter = $self->presenter;
 116
 117   my @link_type_select = map { [ $_->{type}, $_->{title} ] } @link_types;
 118   my @projects         = map { [ $_->id, $_->presenter->project(display => 'inline', style => 'both', no_link => 1) ] } @{ SL::DB::Manager::Project->get_all_sorted };
 119   my $is_sales         = $self->object->can('customer_id') && $self->object->customer_id;
 120
 121   $self->render(
 122     'record_links/add_filter',
 123     { layout          => 0 },
 124     is_sales          => $is_sales,
 125     DEFAULT_LINK_TYPE => $is_sales ? 'sales_quotation' : 'request_quotation',
 126     LINK_TYPES        => \@link_type_select,
 127     PROJECTS          => \@projects,
 128   );
 129 }
 130
 131 sub action_ajax_add_list {
 132   my ($self) = @_;
 133
 134   my $manager     = 'SL::DB::Manager::' . $self->link_type_desc->{model};
 135   my $vc          = $self->link_type =~ m/shop|sales_|^invoice|requirement_spec|letter|^ar_/ ? 'customer' : 'vendor';
 136   my $project     = $self->link_type_desc->{project};
 137   my $project_id  = "${project}_id";
 138   my $description = $self->link_type_desc->{description};
 139   my $filter      = $self->link_type_desc->{filter};
 140   my $number      = $self->link_type_desc->{number};
 141
 142   my @where = $filter && $manager->can($filter) ? $manager->$filter($self->link_type) : ();
 143   push @where, ("${vc}.${vc}number"     => { ilike => like($::form->{vc_number}) })               if $::form->{vc_number};
 144   push @where, ("${vc}.name"            => { ilike => like($::form->{vc_name}) })                 if $::form->{vc_name};
 145   push @where, ($description            => { ilike => like($::form->{transaction_description}) }) if $::form->{transaction_description};
 146   push @where, ($project_id             => $::form->{globalproject_id})                           if $::form->{globalproject_id} && $manager->can($project_id);
 147
 148   if ($::form->{number}) {
 149     my $class    = 'SL::DB::' . $self->link_type_desc->{model};
 150     my $col_type = ref $class->meta->column($number);
 151     if ($col_type =~ /^Rose::DB::Object::Metadata::Column::(?:Integer|Serial)$/) {
 152       push @where, ($number => $::form->{number});
 153     } elsif ($col_type =~ /^Rose::DB::Object::Metadata::Column::Text$/) {
 154       push @where, ($number => { ilike => like($::form->{number}) });
 155     }
 156   }
 157
 158   my @with_objects = ($vc);
 159   push @with_objects, $project if $manager->can($project_id);
 160
 161   # show the newest records first (should be better for 80% of the cases TODO sortable click
 162   my $objects = $manager->get_all_sorted(where => \@where, with_objects => \@with_objects, sort_by => 'itime',  sort_dir => 'ASC');
 163   my $output  = $self->render(
 164     'record_links/add_list',
 165     { output => 0 },
 166     OBJECTS            => $objects,
 167     vc                 => $vc,
 168     number_column      => $self->link_type_desc->{number},
 169     description_column => $description,
 170     description_title  => $self->link_type_desc->{description_title},
 171     project_column     => $project,
 172     date_column        => $self->link_type_desc->{date},
 173   );
 174
 175   my %result = ( count => scalar(@{ $objects }), html => $output );
 176
 177   $self->render(\to_json(\%result), { type => 'json', process => 0 });
 178 }
 179
 180 sub action_ajax_add_do {
 181   my ($self, %params) = @_;
 182
 183   my $object_side = $self->link_direction eq 'from' ? 'from' : 'to';
 184   my $link_side   = $object_side          eq 'from' ? 'to'   : 'from';
 185   my $link_table  = SL::DB::Helper::Mappings::get_table_for_package($self->link_type_desc->{model});
 186
 187   foreach my $link_id (@{ $::form->{link_id} || [] }) {
 188     # Check for existing reverse connections in order to avoid loops.
 189     my @props = (
 190       "${link_side}_table"   => $self->object->meta->table,
 191       "${link_side}_id"      => $self->object_id,
 192       "${object_side}_table" => $link_table,
 193       "${object_side}_id"    => $link_id,
 194     );
 195
 196     my $existing = SL::DB::Manager::RecordLink->get_all(where => \@props, limit => 1)->[0];
 197     next if $existing;
 198
 199     # Check for existing connections in order to avoid duplicates.
 200     @props = (
 201       "${object_side}_table" => $self->object->meta->table,
 202       "${object_side}_id"    => $self->object_id,
 203       "${link_side}_table"   => $link_table,
 204       "${link_side}_id"      => $link_id,
 205     );
 206
 207     $existing = SL::DB::Manager::RecordLink->get_all(where => \@props, limit => 1)->[0];
 208
 209     SL::DB::RecordLink->new(@props)->save if !$existing;
 210   }
 211
 212   $self->action_ajax_list;
 213 }
 214
 215
 216 #
 217 # filters
 218 #
 219
 220 sub check_object_params {
 221   my ($self) = @_;
 222
 223   my %models = map { ($_->{model} => 1 ) } @link_types;
 224
 225   $self->object_id(   $::form->{object_id});
 226   $self->object_model($::form->{object_model});
 227
 228   die "Invalid object_model or object_id" if !$self->object_id || !$models{$self->object_model};
 229
 230   my $model = 'SL::DB::' . $self->object_model;
 231   $self->object($model->new(id => $self->object_id)->load || die "Record not found");
 232
 233   return 1;
 234 }
 235
 236 sub check_link_params {
 237   my ($self) = @_;
 238
 239   $self->link_type(     $::form->{link_type});
 240   $self->link_type_desc((first { $_->{type} eq $::form->{link_type} } @link_types)                || die "Invalid link_type");
 241   $self->link_direction($::form->{link_direction} =~ m/^(?:from|to)$/ ? $::form->{link_direction} :  die "Invalid link_direction");
 242
 243   return 1;
 244 }
 245
 246 sub check_auth {
 247   $::auth->assert('record_links');
 248 }
 249
 250 # internal
 251
 252 sub get_order_centric_linked_records {
 253   my ($self) = @_;
 254
 255   my $all_linked_records = $self->object->linked_records(direction => 'from', recursive => 1);
 256   my $filtered_orders = [ grep { 'SL::DB::Order' eq ref $_ && $_->is_type('sales_order') } @$all_linked_records ];
 257
 258   # no orders no call to linked_records via batch mode
 259   # but instead return default list
 260   return $self->object->linked_records(direction => 'both', recursive => 1, save_path => 1)
 261     unless scalar @$filtered_orders;
 262
 263   # we have a order, therefore get the tree view from the top (order)
 264   my $id_ref = [ map { $_->id } @$filtered_orders ];
 265   my $linked_records = SL::DB::Order->new->linked_records(direction => 'to', recursive => 1, batch => $id_ref);
 266   push @{ $linked_records }, @$filtered_orders;
 267
 268   return $linked_records;
 269 }
 270 1;