SL/Controller/RecordLinks.pm

   1 package SL::Controller::RecordLinks;
   2
   3 use strict;
   4
   5 use parent qw(SL::Controller::Base);
   6
   7 use List::Util qw(first);
   8
   9 use SL::DB::Helper::Mappings;
  10 use SL::DB::Order;
  11 use SL::DB::DeliveryOrder;
  12 use SL::DB::Invoice;
  13 use SL::DB::Letter;
  14 use SL::DB::PurchaseInvoice;
  15 use SL::DB::RecordLink;
  16 use SL::DB::RequirementSpec;
  17 use SL::DBUtils qw(like);
  18 use SL::DB::ShopOrder;
  19 use SL::JSON;
  20 use SL::Locale::String;
  21
  22 use Rose::Object::MakeMethods::Generic
  23 (
  24   scalar => [ qw(object object_model object_id link_type link_direction link_type_desc) ],
  25 );
  26
  27 __PACKAGE__->run_before('check_auth');
  28 __PACKAGE__->run_before('check_object_params', only => [ qw(ajax_list ajax_delete ajax_add_select_type ajax_add_filter ajax_add_list ajax_add_do) ]);
  29 __PACKAGE__->run_before('check_link_params',   only => [ qw(                                                           ajax_add_list ajax_add_do) ]);
  30
  31 my %link_type_defaults = (
  32   filter            => 'type_filter',
  33   project           => 'globalproject',
  34   description       => 'transaction_description',
  35   description_title => t8('Transaction description'),
  36   date              => 'transdate',
  37 );
  38
  39 my @link_type_specifics = (
  40   { title => t8('Requirement spec'),        type => 'requirement_spec',        model => 'RequirementSpec', number => 'id', project => 'project', description => 'title', date => undef, filter => 'working_copy_filter', },
  41   { title => t8('Shop Order'),              type => 'shop_order',              model => 'ShopOrder',       number => 'shop_ordernumber', date => 'order_date', project => undef, },
  42   { title => t8('Sales quotation'),         type => 'sales_quotation',         model => 'Order',           number => 'quonumber', },
  43   { title => t8('Sales Order'),             type => 'sales_order',             model => 'Order',           number => 'ordnumber', },
  44   { title => t8('Sales delivery order'),    type => 'sales_delivery_order',    model => 'DeliveryOrder',   number => 'donumber',  },
  45   { title => t8('Sales Invoice'),           type => 'invoice',                 model => 'Invoice',         number => 'invnumber', },
  46   { title => t8('Request for Quotation'),   type => 'request_quotation',       model => 'Order',           number => 'quonumber', },
  47   { title => t8('Purchase Order'),          type => 'purchase_order',          model => 'Order',           number => 'ordnumber', },
  48   { title => t8('Purchase delivery order'), type => 'purchase_delivery_order', model => 'DeliveryOrder',   number => 'donumber',  },
  49   { title => t8('Purchase Invoice'),        type => 'purchase_invoice',        model => 'PurchaseInvoice', number => 'invnumber', },
  50   { title => t8('Letter'),                  type => 'letter',                  model => 'Letter',          number => 'letternumber', description => 'subject', description_title => t8('Subject'), date => 'date', project => undef },
  51 );
  52
  53 my @link_types = map { +{ %link_type_defaults, %{ $_ } } } @link_type_specifics;
  54
  55 #
  56 # actions
  57 #
  58
  59 sub action_ajax_list {
  60   my ($self) = @_;
  61
  62   eval {
  63     my $linked_records = $self->object->linked_records(direction => 'both', recursive => 1, save_path => 1);
  64     push @{ $linked_records }, $self->object->sepa_export_items if $self->object->can('sepa_export_items');
  65
  66     my $output         = SL::Presenter->get->grouped_record_list(
  67       $linked_records,
  68       with_columns      => [ qw(record_link_direction) ],
  69       edit_record_links => 1,
  70       object_model      => $self->object_model,
  71       object_id         => $self->object_id,
  72     );
  73     $self->render(\$output, { layout => 0, process => 0 });
  74
  75     1;
  76   } or do {
  77     $self->render('generic/error', { layout => 0 }, label_error => $@);
  78   };
  79 }
  80
  81 sub action_ajax_delete {
  82   my ($self) = @_;
  83
  84   foreach my $str (@{ $::form->{record_links_delete} || [] }) {
  85     my ($from_table, $from_id, $to_table, $to_id) = split m/__/, $str, 4;
  86     $from_id *= 1;
  87     $to_id   *= 1;
  88
  89     next if !$from_table || !$from_id || !$to_table || !$to_id;
  90
  91     SL::DB::Manager::RecordLink->delete_all(where => [
  92       from_table => $from_table,
  93       from_id    => $from_id,
  94       to_table   => $to_table,
  95       to_id      => $to_id,
  96     ]);
  97   }
  98
  99   $self->action_ajax_list;
 100 }
 101
 102 sub action_ajax_add_filter {
 103   my ($self) = @_;
 104
 105   my $presenter = $self->presenter;
 106
 107   my @link_type_select = map { [ $_->{type}, $_->{title} ] } @link_types;
 108   my @projects         = map { [ $_->id, $presenter->project($_, display => 'inline', style => 'both', no_link => 1) ] } @{ SL::DB::Manager::Project->get_all_sorted };
 109   my $is_sales         = $self->object->can('customer_id') && $self->object->customer_id;
 110
 111   $self->render(
 112     'record_links/add_filter',
 113     { layout          => 0 },
 114     is_sales          => $is_sales,
 115     DEFAULT_LINK_TYPE => $is_sales ? 'sales_quotation' : 'request_quotation',
 116     LINK_TYPES        => \@link_type_select,
 117     PROJECTS          => \@projects,
 118   );
 119 }
 120
 121 sub action_ajax_add_list {
 122   my ($self) = @_;
 123
 124   my $manager     = 'SL::DB::Manager::' . $self->link_type_desc->{model};
 125   my $vc          = $self->link_type =~ m/shop|sales_|^invoice|requirement_spec|letter/ ? 'customer' : 'vendor';
 126   my $project     = $self->link_type_desc->{project};
 127   my $project_id  = "${project}_id";
 128   my $description = $self->link_type_desc->{description};
 129   my $filter      = $self->link_type_desc->{filter};
 130
 131   my @where = $filter && $manager->can($filter) ? $manager->$filter($self->link_type) : ();
 132   push @where, ("${vc}.${vc}number"     => { ilike => like($::form->{vc_number}) })               if $::form->{vc_number};
 133   push @where, ("${vc}.name"            => { ilike => like($::form->{vc_name}) })                 if $::form->{vc_name};
 134   push @where, ($description            => { ilike => like($::form->{transaction_description}) }) if $::form->{transaction_description};
 135   push @where, ($project_id             => $::form->{globalproject_id})                           if $::form->{globalproject_id} && $manager->can($project_id);
 136
 137   my @with_objects = ($vc);
 138   push @with_objects, $project if $manager->can($project_id);
 139
 140   # show the newest records first (should be better for 80% of the cases TODO sortable click
 141   my $objects = $manager->get_all_sorted(where => \@where, with_objects => \@with_objects, sort_by => 'itime',  sort_dir => 'ASC');
 142   my $output  = $self->render(
 143     'record_links/add_list',
 144     { output => 0 },
 145     OBJECTS            => $objects,
 146     vc                 => $vc,
 147     number_column      => $self->link_type_desc->{number},
 148     description_column => $description,
 149     description_title  => $self->link_type_desc->{description_title},
 150     project_column     => $project,
 151     date_column        => $self->link_type_desc->{date},
 152   );
 153
 154   my %result = ( count => scalar(@{ $objects }), html => $output );
 155
 156   $self->render(\to_json(\%result), { type => 'json', process => 0 });
 157 }
 158
 159 sub action_ajax_add_do {
 160   my ($self, %params) = @_;
 161
 162   my $object_side = $self->link_direction eq 'from' ? 'from' : 'to';
 163   my $link_side   = $object_side          eq 'from' ? 'to'   : 'from';
 164   my $link_table  = SL::DB::Helper::Mappings::get_table_for_package($self->link_type_desc->{model});
 165
 166   foreach my $link_id (@{ $::form->{link_id} || [] }) {
 167     # Check for existing reverse connections in order to avoid loops.
 168     my @props = (
 169       "${link_side}_table"   => $self->object->meta->table,
 170       "${link_side}_id"      => $self->object_id,
 171       "${object_side}_table" => $link_table,
 172       "${object_side}_id"    => $link_id,
 173     );
 174
 175     my $existing = SL::DB::Manager::RecordLink->get_all(where => \@props, limit => 1)->[0];
 176     next if $existing;
 177
 178     # Check for existing connections in order to avoid duplicates.
 179     @props = (
 180       "${object_side}_table" => $self->object->meta->table,
 181       "${object_side}_id"    => $self->object_id,
 182       "${link_side}_table"   => $link_table,
 183       "${link_side}_id"      => $link_id,
 184     );
 185
 186     $existing = SL::DB::Manager::RecordLink->get_all(where => \@props, limit => 1)->[0];
 187
 188     SL::DB::RecordLink->new(@props)->save if !$existing;
 189   }
 190
 191   $self->action_ajax_list;
 192 }
 193
 194
 195 #
 196 # filters
 197 #
 198
 199 sub check_object_params {
 200   my ($self) = @_;
 201
 202   my %models = map { ($_->{model} => 1 ) } @link_types;
 203
 204   $self->object_id(   $::form->{object_id});
 205   $self->object_model($::form->{object_model});
 206
 207   die "Invalid object_model or object_id" if !$self->object_id || !$models{$self->object_model};
 208
 209   my $model = 'SL::DB::' . $self->object_model;
 210   $self->object($model->new(id => $self->object_id)->load || die "Record not found");
 211
 212   return 1;
 213 }
 214
 215 sub check_link_params {
 216   my ($self) = @_;
 217
 218   $self->link_type(     $::form->{link_type});
 219   $self->link_type_desc((first { $_->{type} eq $::form->{link_type} } @link_types)                || die "Invalid link_type");
 220   $self->link_direction($::form->{link_direction} =~ m/^(?:from|to)$/ ? $::form->{link_direction} :  die "Invalid link_direction");
 221
 222   return 1;
 223 }
 224
 225 sub check_auth {
 226   $::auth->assert('record_links');
 227 }
 228
 229 1;