SL/Controller/RecordLinks.pm

   1 package SL::Controller::RecordLinks;
   2
   3 use strict;
   4
   5 use parent qw(SL::Controller::Base);
   6
   7 use List::Util qw(first);
   8
   9 use SL::DB::Helper::Mappings;
  10 use SL::DB::Order;
  11 use SL::DB::DeliveryOrder;
  12 use SL::DB::Invoice;
  13 use SL::DB::PurchaseInvoice;
  14 use SL::DB::RecordLink;
  15 use SL::DB::RequirementSpec;
  16 use SL::JSON;
  17 use SL::Locale::String;
  18
  19 use Rose::Object::MakeMethods::Generic
  20 (
  21   scalar => [ qw(object object_model object_id link_type link_direction link_type_desc) ],
  22 );
  23
  24 __PACKAGE__->run_before('check_object_params', only => [ qw(ajax_list ajax_delete ajax_add_select_type ajax_add_filter ajax_add_list ajax_add_do) ]);
  25 __PACKAGE__->run_before('check_link_params',   only => [ qw(                                                           ajax_add_list ajax_add_do) ]);
  26
  27 my %link_type_defaults = (
  28   filter      => 'type_filter',
  29   project     => 'globalproject',
  30   description => 'transaction_description',
  31   date        => 'transdate',
  32 );
  33
  34 my @link_type_specifics = (
  35   { title => t8('Requirement spec'),        type => 'requirement_spec',        model => 'RequirementSpec', number => 'id', project => 'project', description => 'title', date => undef, filter => undef, },
  36   { title => t8('Sales quotation'),         type => 'sales_quotation',         model => 'Order',           number => 'quonumber', },
  37   { title => t8('Sales Order'),             type => 'sales_order',             model => 'Order',           number => 'ordnumber', },
  38   { title => t8('Sales delivery order'),    type => 'sales_delivery_order',    model => 'DeliveryOrder',   number => 'donumber',  },
  39   { title => t8('Sales Invoice'),           type => 'invoice',                 model => 'Invoice',         number => 'invnumber', },
  40   { title => t8('Request for Quotation'),   type => 'request_quotation',       model => 'Order',           number => 'quonumber', },
  41   { title => t8('Purchase Order'),          type => 'purchase_order',          model => 'Order',           number => 'ordnumber', },
  42   { title => t8('Purchase delivery order'), type => 'purchase_delivery_order', model => 'DeliveryOrder',   number => 'donumber',  },
  43   { title => t8('Purchase Invoice'),        type => 'purchase_invoice',        model => 'PurchaseInvoice', number => 'invnumber', },
  44 );
  45
  46 my @link_types = map { +{ %link_type_defaults, %{ $_ } } } @link_type_specifics;
  47
  48 #
  49 # actions
  50 #
  51
  52 sub action_ajax_list {
  53   my ($self) = @_;
  54
  55   eval {
  56     my $linked_records = $self->object->linked_records(direction => 'both');
  57     push @{ $linked_records }, $self->object->sepa_export_items if $self->object->can('sepa_export_items');
  58     my $output         = SL::Presenter->get->grouped_record_list(
  59       $linked_records,
  60       with_columns      => [ qw(record_link_direction) ],
  61       edit_record_links => 1,
  62       object_model      => $self->object_model,
  63       object_id         => $self->object_id,
  64     );
  65     $self->render(\$output, { layout => 0, process => 0 });
  66
  67     1;
  68   } or do {
  69     $self->render('generic/error', { layout => 0 }, label_error => $@);
  70   };
  71 }
  72
  73 sub action_ajax_delete {
  74   my ($self) = @_;
  75
  76   foreach my $str (@{ $::form->{record_links_delete} || [] }) {
  77     my ($from_table, $from_id, $to_table, $to_id) = split m/__/, $str, 4;
  78     $from_id *= 1;
  79     $to_id   *= 1;
  80
  81     next if !$from_table || !$from_id || !$to_table || !$to_id;
  82
  83     SL::DB::Manager::RecordLink->delete_all(where => [
  84       from_table => $from_table,
  85       from_id    => $from_id,
  86       to_table   => $to_table,
  87       to_id      => $to_id,
  88     ]);
  89   }
  90
  91   $self->action_ajax_list;
  92 }
  93
  94 sub action_ajax_add_filter {
  95   my ($self) = @_;
  96
  97   my $presenter = $self->presenter;
  98
  99   my @link_type_select = map { [ $_->{type}, $_->{title} ] } @link_types;
 100   my @projects         = map { [ $_->id, $presenter->project($_, display => 'inline', style => 'both', no_link => 1) ] } @{ SL::DB::Manager::Project->get_all_sorted };
 101   my $is_sales         = $self->object->can('customer_id') && $self->object->customer_id;
 102
 103   $self->render(
 104     'record_links/add_filter',
 105     { layout          => 0 },
 106     is_sales          => $is_sales,
 107     DEFAULT_LINK_TYPE => $is_sales ? 'sales_quotation' : 'request_quotation',
 108     LINK_TYPES        => \@link_type_select,
 109     PROJECTS          => \@projects,
 110   );
 111 }
 112
 113 sub action_ajax_add_list {
 114   my ($self) = @_;
 115
 116   my $manager     = 'SL::DB::Manager::' . $self->link_type_desc->{model};
 117   my $vc          = $self->link_type =~ m/sales_|^invoice|requirement_spec$/ ? 'customer' : 'vendor';
 118   my $project     = $self->link_type_desc->{project};
 119   my $description = $self->link_type_desc->{description};
 120   my $filter      = $self->link_type_desc->{filter};
 121
 122   my @where = $filter ? $manager->$filter($self->link_type) : ();
 123   push @where, ("${vc}.${vc}number"     => { ilike => '%' . $::form->{vc_number} . '%' })               if $::form->{vc_number};
 124   push @where, ("${vc}.name"            => { ilike => '%' . $::form->{vc_name}   . '%' })               if $::form->{vc_name};
 125   push @where, ($description            => { ilike => '%' . $::form->{transaction_description} . '%' }) if $::form->{transaction_description};
 126   push @where, ("${project}_id"         => $::form->{globalproject_id})                                 if $::form->{globalproject_id};
 127
 128   my $objects = $manager->get_all_sorted(where => \@where, with_objects => [ $vc, $project ]);
 129   my $output  = $self->render(
 130     'record_links/add_list',
 131     { output => 0 },
 132     OBJECTS            => $objects,
 133     vc                 => $vc,
 134     number_column      => $self->link_type_desc->{number},
 135     description_column => $description,
 136     project_column     => $project,
 137     date_column        => $self->link_type_desc->{date},
 138   );
 139
 140   my %result = ( count => scalar(@{ $objects }), html => $output );
 141
 142   $self->render(\to_json(\%result), { type => 'json', process => 0 });
 143 }
 144
 145 sub action_ajax_add_do {
 146   my ($self, %params) = @_;
 147
 148   my $object_side = $self->link_direction eq 'from' ? 'from' : 'to';
 149   my $link_side   = $object_side          eq 'from' ? 'to'   : 'from';
 150   my $link_table  = SL::DB::Helper::Mappings::get_table_for_package($self->link_type_desc->{model});
 151
 152   foreach my $link_id (@{ $::form->{link_id} || [] }) {
 153     # Check for existing reverse connections in order to avoid loops.
 154     my @props = (
 155       "${link_side}_table"   => $self->object->meta->table,
 156       "${link_side}_id"      => $self->object_id,
 157       "${object_side}_table" => $link_table,
 158       "${object_side}_id"    => $link_id,
 159     );
 160
 161     my $existing = SL::DB::Manager::RecordLink->get_all(where => \@props, limit => 1)->[0];
 162     next if $existing;
 163
 164     # Check for existing connections in order to avoid duplicates.
 165     @props = (
 166       "${object_side}_table" => $self->object->meta->table,
 167       "${object_side}_id"    => $self->object_id,
 168       "${link_side}_table"   => $link_table,
 169       "${link_side}_id"      => $link_id,
 170     );
 171
 172     $existing = SL::DB::Manager::RecordLink->get_all(where => \@props, limit => 1)->[0];
 173
 174     SL::DB::RecordLink->new(@props)->save if !$existing;
 175   }
 176
 177   $self->action_ajax_list;
 178 }
 179
 180
 181 #
 182 # filters
 183 #
 184
 185 sub check_object_params {
 186   my ($self) = @_;
 187
 188   my %models = map { ($_->{model} => 1 ) } @link_types;
 189
 190   $self->object_id(   $::form->{object_id});
 191   $self->object_model($::form->{object_model});
 192
 193   die "Invalid object_model or object_id" if !$self->object_id || !$models{$self->object_model};
 194
 195   my $model = 'SL::DB::' . $self->object_model;
 196   $self->object($model->new(id => $self->object_id)->load || die "Record not found");
 197
 198   return 1;
 199 }
 200
 201 sub check_link_params {
 202   my ($self) = @_;
 203
 204   $self->link_type(     $::form->{link_type});
 205   $self->link_type_desc((first { $_->{type} eq $::form->{link_type} } @link_types)                || die "Invalid link_type");
 206   $self->link_direction($::form->{link_direction} =~ m/^(?:from|to)$/ ? $::form->{link_direction} :  die "Invalid link_direction");
 207
 208   return 1;
 209 }
 210
 211 1;