SL/Controller/RequirementSpec.pm

   1 package SL::Controller::RequirementSpec;
   2
   3 use strict;
   4 use utf8;
   5
   6 use parent qw(SL::Controller::Base);
   7
   8 use SL::ClientJS;
   9 use SL::Controller::Helper::GetModels;
  10 use SL::Controller::Helper::Paginated;
  11 use SL::Controller::Helper::Sorted;
  12 use SL::Controller::Helper::ParseFilter;
  13 use SL::Controller::Helper::ReportGenerator;
  14 use SL::Controller::Helper::RequirementSpec;
  15 use SL::DB::Customer;
  16 use SL::DB::Project;
  17 use SL::DB::RequirementSpecComplexity;
  18 use SL::DB::RequirementSpecRisk;
  19 use SL::DB::RequirementSpecStatus;
  20 use SL::DB::RequirementSpecType;
  21 use SL::DB::RequirementSpec;
  22 use SL::Helper::Flash;
  23 use SL::Locale::String;
  24 use SL::Template::LaTeX;
  25
  26 use Rose::Object::MakeMethods::Generic
  27 (
  28   scalar                  => [ qw(requirement_spec_item customers types statuses db_args flat_filter visible_item visible_section) ],
  29   'scalar --get_set_init' => [ qw(requirement_spec complexities risks projects copy_source js current_text_block_output_position) ],
  30 );
  31
  32 __PACKAGE__->run_before('setup');
  33 __PACKAGE__->run_before('load_select_options',  only => [ qw(new ajax_edit create update list) ]);
  34
  35
  36 __PACKAGE__->get_models_url_params('flat_filter');
  37 __PACKAGE__->make_paginated(
  38   MODEL         => 'RequirementSpec',
  39   PAGINATE_ARGS => 'db_args',
  40   ONLY          => [ qw(list) ],
  41 );
  42
  43 __PACKAGE__->make_sorted(
  44   MODEL         => 'RequirementSpec',
  45   ONLY          => [ qw(list) ],
  46
  47   DEFAULT_BY    => 'customer',
  48   DEFAULT_DIR   => 1,
  49
  50   customer      => t8('Customer'),
  51   title         => t8('Title'),
  52   type          => t8('Requirement Spec Type'),
  53   status        => t8('Requirement Spec Status'),
  54   projectnumber => t8('Project Number'),
  55   version       => t8('Version'),
  56   mtime         => t8('Last modification'),
  57 );
  58
  59 #
  60 # actions
  61 #
  62
  63
  64 sub action_list {
  65   my ($self) = @_;
  66
  67   $self->setup_db_args_from_filter;
  68   $self->flat_filter({ map { $_->{key} => $_->{value} } $::form->flatten_variables('filter') });
  69
  70   $self->prepare_report;
  71
  72   my $requirement_specs = $self->get_models(%{ $self->db_args });
  73
  74   $self->report_generator_list_objects(report => $self->{report}, objects => $requirement_specs);
  75 }
  76
  77 sub action_new {
  78   my ($self) = @_;
  79
  80   $self->requirement_spec(SL::DB::RequirementSpec->new(is_template => $::form->{is_template}));
  81
  82   if ($self->copy_source) {
  83     $self->requirement_spec->$_($self->copy_source->$_) for qw(type_id status_id customer_id title hourly_rate)
  84   }
  85
  86   $self->render('requirement_spec/new', title => $self->requirement_spec->is_template ? t8('Create a new requirement spec template') : t8('Create a new requirement spec'));
  87 }
  88
  89 sub action_ajax_show_basic_settings {
  90   my ($self) = @_;
  91
  92   $self->render('requirement_spec/_show_basic_settings', { layout => 0 });
  93 }
  94
  95 sub action_ajax_edit {
  96   my ($self) = @_;
  97
  98   my $html   = $self->render('requirement_spec/_form', { output => 0 }, submit_as => 'ajax');
  99
 100   $self->js
 101     ->hide('#basic_settings')
 102     ->after('#basic_settings', $html)
 103     ->render($self);
 104 }
 105
 106 sub action_ajax_show_time_and_cost_estimate {
 107   my ($self) = @_;
 108
 109   $self->render('requirement_spec/_show_time_and_cost_estimate', { layout => 0 });
 110 }
 111
 112 sub action_ajax_edit_time_and_cost_estimate {
 113   my ($self) = @_;
 114
 115   my $html   = $self->render('requirement_spec/_edit_time_and_cost_estimate', { output => 0 });
 116
 117   $self->js
 118    ->hide('#time_cost_estimate')
 119    ->after('#time_cost_estimate', $html)
 120    ->on('#time_cost_estimate INPUT[type=text]', 'keydown', 'kivi.requirement_spec.time_cost_estimate_input_key_down')
 121    ->render($self);
 122 }
 123
 124 sub action_ajax_save_time_and_cost_estimate {
 125   my ($self) = @_;
 126
 127   $self->requirement_spec->db->do_transaction(sub {
 128     # Make Emacs happy
 129     1;
 130     foreach my $attributes (@{ $::form->{requirement_spec_items} || [] }) {
 131       SL::DB::RequirementSpecItem
 132         ->new(id => delete $attributes->{id})
 133         ->load
 134         ->update_attributes(%{ $attributes });
 135     }
 136
 137     1;
 138   });
 139
 140   $self->requirement_spec(SL::DB::RequirementSpec->new(id => $self->requirement_spec->id)->load);
 141
 142   my $html = $self->render('requirement_spec/_show_time_and_cost_estimate', { output => 0 });
 143   $self->js->replaceWith('#time_cost_estimate', $html)
 144            ->hide('#time_cost_estimate_form_container');
 145
 146   if ($self->visible_section) {
 147     $html = $self->render('requirement_spec_item/_section', { output => 0 }, requirement_spec_item => $self->visible_section);
 148     $self->js->html('#column-content', $html);
 149   }
 150
 151   $self->js->render($self);
 152 }
 153
 154 sub action_show {
 155   my ($self) = @_;
 156
 157   my $title  = $self->requirement_spec->is_template ? t8('Show requirement spec template') : t8('Show requirement spec');
 158   my $item   = $::form->{requirement_spec_item_id} ? SL::DB::RequirementSpecItem->new(id => $::form->{requirement_spec_item_id})->load : @{ $self->requirement_spec->sections }[0];
 159   $self->requirement_spec_item($item);
 160
 161   $self->render('requirement_spec/show', title => $title);
 162 }
 163
 164 sub action_create {
 165   my ($self) = @_;
 166
 167   $self->requirement_spec(SL::DB::RequirementSpec->new);
 168   $self->create_or_update;
 169 }
 170
 171 sub action_update {
 172   my ($self) = @_;
 173   $self->create_or_update;
 174 }
 175
 176 sub action_destroy {
 177   my ($self) = @_;
 178
 179   if (eval { $self->requirement_spec->delete; 1; }) {
 180     flash_later('info',  t8('The requirement spec has been deleted.'));
 181   } else {
 182     flash_later('error', t8('The requirement spec is in use and cannot be deleted.'));
 183   }
 184
 185   $self->redirect_to(action => 'list');
 186 }
 187
 188 sub action_revert_to {
 189   my ($self, %params) = @_;
 190
 191   return $self->js->error(t8('Cannot revert a versioned copy.'))->render($self) if $self->requirement_spec->working_copy_id;
 192
 193   my $versioned_copy = SL::DB::RequirementSpec->new(id => $::form->{versioned_copy_id})->load;
 194
 195   $self->requirement_spec->copy_from(
 196     $versioned_copy,
 197     version_id => $versioned_copy->version_id,
 198   );
 199
 200   flash_later('info', t8('The requirement spec has been reverted to version #1.', $self->requirement_spec->version->version_number));
 201   $self->js->redirect_to($self->url_for(action => 'show', id => $self->requirement_spec->id))->render($self);
 202 }
 203
 204 sub action_create_pdf {
 205   my ($self, %params) = @_;
 206
 207   my %result = SL::Template::LaTeX->parse_and_create_pdf('requirement_spec.tex', SELF => $self, rspec => $self->requirement_spec);
 208
 209   $::form->error(t8('Conversion to PDF failed: #1', $result{error})) if $result{error};
 210
 211   my $attachment_name  =  $self->requirement_spec->type->description . ' ' . ($self->requirement_spec->working_copy_id || $self->requirement_spec->id);
 212   $attachment_name    .=  ' (v' . $self->requirement_spec->version->version_number . ')' if $self->requirement_spec->version;
 213   $attachment_name    .=  '.pdf';
 214   $attachment_name     =~ s/[^\wäöüÄÖÜß \-\+\(\)\[\]\{\}\.,]+/_/g;
 215
 216   $self->send_file($result{file_name}, type => 'application/pdf', name => $attachment_name);
 217   unlink $result{file_name};
 218 }
 219
 220 sub action_select_template_to_paste {
 221   my ($self) = @_;
 222
 223   my @templates = grep { @{ $_->sections } || @{ $_->text_blocks } } @{ SL::DB::Manager::RequirementSpec->get_all(where => [ is_template => 1 ], sort_by => 'lower(title)') };
 224   $self->render('requirement_spec/select_template_to_paste', { layout => 0 }, TEMPLATES => \@templates);
 225 }
 226
 227 sub action_paste_template {
 228   my ($self, %params) = @_;
 229
 230   my $template = SL::DB::RequirementSpec->new(id => $::form->{template_id})->load;
 231   my %result   = $self->requirement_spec->paste_template($template);
 232
 233   return $self->js->error($self->requirement_spec->error)->render($self) if !%result;
 234
 235   $self->render_pasted_text_block($_) for sort { $a->position <=> $b->position } @{ $result{text_blocks} };
 236   $self->render_pasted_section($_)    for sort { $a->position <=> $b->position } @{ $result{sections}    };
 237
 238   if (@{ $result{sections} } && (($::form->{current_content_type} || 'sections') eq 'sections') && !$::form->{current_content_id}) {
 239     $self->render_first_pasted_section_as_list($result{sections}->[0]);
 240   }
 241
 242   $self->invalidate_version->render($self);
 243 }
 244
 245 #
 246 # filters
 247 #
 248
 249 sub setup {
 250   my ($self) = @_;
 251
 252   $::auth->assert('sales_quotation_edit');
 253   $::request->{layout}->use_stylesheet("${_}.css") for qw(jquery.contextMenu requirement_spec);
 254   $::request->{layout}->use_javascript("${_}.js") for qw(jquery.jstree jquery/jquery.contextMenu client_js requirement_spec);
 255   $self->init_visible_section;
 256
 257   return 1;
 258 }
 259
 260 sub init_complexities {
 261   my ($self) = @_;
 262   return SL::DB::Manager::RequirementSpecComplexity->get_all_sorted;
 263 }
 264
 265 sub init_risks {
 266   my ($self) = @_;
 267   return SL::DB::Manager::RequirementSpecRisk->get_all_sorted;
 268 }
 269
 270 sub init_projects {
 271   my ($self) = @_;
 272   $self->projects(SL::DB::Manager::Project->get_all_sorted);
 273 }
 274
 275 sub init_requirement_spec {
 276   my ($self) = @_;
 277   $self->requirement_spec(SL::DB::RequirementSpec->new(id => $::form->{id})->load || die "No such requirement spec") if $::form->{id};
 278 }
 279
 280 sub init_copy_source {
 281   my ($self) = @_;
 282   $self->copy_source(SL::DB::RequirementSpec->new(id => $::form->{copy_source_id})->load) if $::form->{copy_source_id};
 283 }
 284
 285 sub init_js {
 286   my ($self) = @_;
 287   $self->js(SL::ClientJS->new);
 288 }
 289
 290 sub init_current_text_block_output_position {
 291   my ($self) = @_;
 292   $self->current_text_block_output_position($::form->{current_content_type} !~ m/^(?:text-blocks|tb)-(front|back)/ ? -1 : $1 eq 'front' ? 0 : 1);
 293 }
 294
 295 sub load_select_options {
 296   my ($self) = @_;
 297
 298   my @filter = ('!obsolete' => 1);
 299   @filter    = ( or => [ @filter, id => $self->requirement_spec->customer_id ] ) if $self->requirement_spec && $self->requirement_spec->customer_id;
 300
 301   $self->customers(SL::DB::Manager::Customer->get_all_sorted(where => \@filter));
 302   $self->statuses( SL::DB::Manager::RequirementSpecStatus->get_all_sorted);
 303   $self->types(    SL::DB::Manager::RequirementSpecType->get_all_sorted);
 304 }
 305
 306 #
 307 # helpers
 308 #
 309
 310 sub create_or_update {
 311   my $self   = shift;
 312   my $is_new = !$self->requirement_spec->id;
 313   my $params = delete($::form->{requirement_spec}) || { };
 314
 315   $self->requirement_spec->assign_attributes(%{ $params });
 316
 317   my $title  = $is_new && $self->requirement_spec->is_template ? t8('Create a new requirement spec template')
 318              : $is_new                                         ? t8('Create a new requirement spec')
 319              :            $self->requirement_spec->is_template ? t8('Edit requirement spec template')
 320              :                                                   t8('Edit requirement spec');
 321
 322   my @errors = $self->requirement_spec->validate;
 323
 324   if (@errors) {
 325     return $self->js->error(@errors)->render($self) if $::request->is_ajax;
 326
 327     flash('error', @errors);
 328     $self->render('requirement_spec/new', title => $title);
 329     return;
 330   }
 331
 332   my $db = $self->requirement_spec->db;
 333   if (!$db->do_transaction(sub {
 334     if ($self->copy_source) {
 335       $self->requirement_spec($self->copy_source->create_copy(%{ $params }));
 336     } else {
 337       $self->requirement_spec->save;
 338     }
 339   })) {
 340     $::lxdebug->message(LXDebug::WARN(), "Error: " . $db->error);
 341     @errors = ($::locale->text('Saving failed. Error message from the database: #1'), $db->error);
 342     return $self->js->error(@errors)->render($self) if $::request->is_ajax;
 343
 344     $self->requirement_spec->id(undef) if $is_new;
 345     flash('error', @errors);
 346     return $self->render('requirement_spec/new', title => $title);
 347   }
 348
 349   my $info = $self->requirement_spec->is_template ? t8('The requirement spec template has been saved.') : t8('The requirement spec has been saved.');
 350
 351   if ($::request->is_ajax) {
 352     my $header_html = $self->render('requirement_spec/_header', { output => 0 });
 353     my $basics_html = $self->render('requirement_spec/_show_basic_settings', { output => 0 });
 354     return $self->invalidate_version
 355       ->replaceWith('#requirement-spec-header', $header_html)
 356       ->replaceWith('#basic_settings',          $basics_html)
 357       ->remove('#basic_settings_form')
 358       ->flash('info', $info)
 359       ->render($self);
 360   }
 361
 362   flash_later('info', $info);
 363   $self->redirect_to(action => 'show', id => $self->requirement_spec->id);
 364 }
 365
 366 sub setup_db_args_from_filter {
 367   my ($self) = @_;
 368
 369   $self->{filter} = {};
 370   my %args = parse_filter(
 371     $::form->{filter},
 372     with_objects => [ 'customer', 'type', 'status', 'project' ],
 373     launder_to   => $self->{filter},
 374   );
 375
 376   $args{where} = [
 377     and => [
 378       @{ $args{where} || [] },
 379       working_copy_id => undef,
 380       is_template     => $::form->{is_template} ? 1 : 0,
 381     ]];
 382
 383   $self->db_args(\%args);
 384 }
 385
 386 sub prepare_report {
 387   my ($self)      = @_;
 388
 389   my $callback    = $self->get_callback;
 390
 391   my $is_template = $::form->{is_template};
 392   my $report      = SL::ReportGenerator->new(\%::myconfig, $::form);
 393   $self->{report} = $report;
 394
 395   my @columns     = $is_template ? qw(title mtime) : qw(title customer status type projectnumber mtime version);
 396   my @sortable    = $is_template ? qw(title mtime) : qw(title customer status type projectnumber mtime);
 397
 398   my %column_defs = (
 399     title         => { obj_link => sub { $self->url_for(action => 'show', id => $_[0]->id, callback => $callback) } },
 400     mtime         => { sub      => sub { ($_[0]->mtime || $_[0]->itime)->to_kivitendo(precision => 'minute') } },
 401   );
 402
 403   if (!$is_template) {
 404     %column_defs = (
 405       %column_defs,
 406       customer      => { raw_data => sub { $self->presenter->customer($_[0]->customer, display => 'table-cell', callback => $callback) },
 407                          sub      => sub { $_[0]->customer->name } },
 408       projectnumber => { raw_data => sub { $self->presenter->project($_[0]->project, display => 'table-cell', callback => $callback) },
 409                          sub      => sub { $_[0]->project_id ? $_[0]->project->projectnumber : '' } },
 410       status        => { sub      => sub { $_[0]->status->description } },
 411       type          => { sub      => sub { $_[0]->type->description } },
 412       version       => { sub      => sub { $_[0]->version_id ? $_[0]->version->version_number : t8('Working copy without version') } },
 413     );
 414   }
 415
 416   map { $column_defs{$_}->{text} ||= $::locale->text( $self->get_sort_spec->{$_}->{title} ) } keys %column_defs;
 417
 418   $report->set_options(
 419     std_column_visibility => 1,
 420     controller_class      => 'RequirementSpec',
 421     output_format         => 'HTML',
 422     raw_top_info_text     => $self->render('requirement_spec/report_top',    { output => 0 }, is_template => $is_template),
 423     raw_bottom_info_text  => $self->render('requirement_spec/report_bottom', { output => 0 }),
 424     title                 => $is_template ? t8('Requirement Spec Templates') : t8('Requirement Specs'),
 425     allow_pdf_export      => 1,
 426     allow_csv_export      => 1,
 427   );
 428   $report->set_columns(%column_defs);
 429   $report->set_column_order(@columns);
 430   $report->set_export_options(qw(list filter));
 431   $report->set_options_from_form;
 432   $self->set_report_generator_sort_options(report => $report, sortable_columns => \@sortable);
 433
 434   $self->disable_pagination if $report->{options}{output_format} =~ /^(pdf|csv)$/i;
 435 }
 436
 437 sub invalidate_version {
 438   my ($self) = @_;
 439
 440   my $rspec  = SL::DB::RequirementSpec->new(id => $self->requirement_spec->id)->load;
 441   return $self->js if $rspec->is_template;
 442
 443   $rspec->invalidate_version;
 444
 445   my $html = $self->render('requirement_spec/_version', { output => 0 }, requirement_spec => $rspec);
 446   return $self->js->html('#requirement_spec_version', $html);
 447 }
 448
 449 sub render_pasted_text_block {
 450   my ($self, $text_block, %params) = @_;
 451
 452   if ($self->current_text_block_output_position == $text_block->output_position) {
 453     my $html = $self->render('requirement_spec_text_block/_text_block', { output => 0 }, text_block => $text_block);
 454     $self->js
 455       ->appendTo($html, '#text-block-list')
 456       ->hide('#text-block-list-empty');
 457   }
 458
 459   my $node       = $self->presenter->requirement_spec_text_block_jstree_data($text_block);
 460   my $front_back = $text_block->output_position == 0 ? 'front' : 'back';
 461   $self->js
 462     ->jstree->create_node('#tree', "#tb-${front_back}", 'last', $node)
 463     ->jstree->open_node(  '#tree', "#tb-${front_back}");
 464 }
 465
 466 sub render_pasted_section {
 467   my ($self, $item, $parent_id) = @_;
 468
 469   my $node = $self->presenter->requirement_spec_item_jstree_data($item);
 470   $self->js
 471     ->jstree->create_node('#tree', $parent_id ? "#fb-${parent_id}" : '#sections', 'last', $node)
 472     ->jstree->open_node(  '#tree', $parent_id ? "#fb-${parent_id}" : '#sections');
 473
 474   $self->render_pasted_section($_, $item->id) for @{ $item->children_sorted };
 475 }
 476
 477 sub render_first_pasted_section_as_list {
 478   my ($self, $section, %params) = @_;
 479
 480   my $html = $self->render('requirement_spec_item/_section', { output => 0 }, requirement_spec_item => $section);
 481   $self->js
 482     ->html('#column-content', $html)
 483     ->val( '#current_content_type', $section->item_type)
 484     ->val( '#current_content_id',   $section->id)
 485     ->jstree->select_node('#tree', '#fb-' . $section->id);
 486 }
 487
 488 1;