SL/Controller/RequirementSpec.pm

   1 package SL::Controller::RequirementSpec;
   2
   3 use strict;
   4 use utf8;
   5
   6 use parent qw(SL::Controller::Base);
   7
   8 use SL::ClientJS;
   9 use SL::Controller::Helper::GetModels;
  10 use SL::Controller::Helper::Paginated;
  11 use SL::Controller::Helper::Sorted;
  12 use SL::Controller::Helper::ParseFilter;
  13 use SL::Controller::Helper::ReportGenerator;
  14 use SL::Controller::Helper::RequirementSpec;
  15 use SL::DB::Customer;
  16 use SL::DB::Project;
  17 use SL::DB::RequirementSpecComplexity;
  18 use SL::DB::RequirementSpecRisk;
  19 use SL::DB::RequirementSpecStatus;
  20 use SL::DB::RequirementSpecType;
  21 use SL::DB::RequirementSpec;
  22 use SL::Helper::Flash;
  23 use SL::Locale::String;
  24 use SL::Template::LaTeX;
  25
  26 use Rose::Object::MakeMethods::Generic
  27 (
  28   scalar                  => [ qw(requirement_spec_item customers types statuses db_args flat_filter visible_item visible_section) ],
  29   'scalar --get_set_init' => [ qw(requirement_spec complexities risks projects copy_source js current_text_block_output_position) ],
  30 );
  31
  32 __PACKAGE__->run_before('setup');
  33 __PACKAGE__->run_before('load_select_options',  only => [ qw(new ajax_edit create update list) ]);
  34
  35
  36 __PACKAGE__->get_models_url_params('flat_filter');
  37 __PACKAGE__->make_paginated(
  38   MODEL         => 'RequirementSpec',
  39   PAGINATE_ARGS => 'db_args',
  40   ONLY          => [ qw(list) ],
  41 );
  42
  43 __PACKAGE__->make_sorted(
  44   MODEL         => 'RequirementSpec',
  45   ONLY          => [ qw(list) ],
  46
  47   DEFAULT_BY    => 'customer',
  48   DEFAULT_DIR   => 1,
  49
  50   customer      => t8('Customer'),
  51   title         => t8('Title'),
  52   type          => t8('Requirement Spec Type'),
  53   status        => t8('Requirement Spec Status'),
  54   projectnumber => t8('Project Number'),
  55   version       => t8('Version'),
  56   mtime         => t8('Last modification'),
  57 );
  58
  59 #
  60 # actions
  61 #
  62
  63
  64 sub action_list {
  65   my ($self) = @_;
  66
  67   $self->setup_db_args_from_filter;
  68   $self->flat_filter({ map { $_->{key} => $_->{value} } $::form->flatten_variables('filter') });
  69
  70   $self->prepare_report;
  71
  72   my $requirement_specs = $self->get_models(%{ $self->db_args });
  73
  74   $self->report_generator_list_objects(report => $self->{report}, objects => $requirement_specs);
  75 }
  76
  77 sub action_new {
  78   my ($self) = @_;
  79
  80   $self->requirement_spec(SL::DB::RequirementSpec->new(is_template => $::form->{is_template}));
  81
  82   if ($self->copy_source) {
  83     $self->requirement_spec->$_($self->copy_source->$_) for qw(type_id status_id customer_id title hourly_rate)
  84   }
  85
  86   $self->render('requirement_spec/new', title => $self->requirement_spec->is_template ? t8('Create a new requirement spec template') : t8('Create a new requirement spec'));
  87 }
  88
  89 sub action_ajax_edit {
  90   my ($self) = @_;
  91
  92   $self->render('requirement_spec/_form', { layout => 0 }, submit_as => 'ajax');
  93 }
  94
  95 sub action_ajax_show_time_and_cost_estimate {
  96   my ($self) = @_;
  97
  98   $self->render('requirement_spec/_show_time_and_cost_estimate', { layout => 0 });
  99 }
 100
 101 sub action_ajax_cancel_time_and_cost_estimate {
 102   my ($self) = @_;
 103
 104   my $html   = $self->render('requirement_spec/_show_time_and_cost_estimate', { output => 0 });
 105
 106   $self->js
 107    ->replaceWith('#time_cost_estimate', $html)
 108    ->render($self);
 109 }
 110
 111 sub action_ajax_edit_time_and_cost_estimate {
 112   my ($self) = @_;
 113
 114   my $html   = $self->render('requirement_spec/_edit_time_and_cost_estimate', { output => 0 });
 115
 116   $self->js
 117    ->replaceWith('#time_cost_estimate', $html)
 118    ->on('#time_cost_estimate INPUT[type=text]', 'keydown', 'kivi.requirement_spec.time_cost_estimate_input_key_down')
 119    ->render($self);
 120 }
 121
 122 sub action_ajax_save_time_and_cost_estimate {
 123   my ($self) = @_;
 124
 125   $self->requirement_spec->db->do_transaction(sub {
 126     # Make Emacs happy
 127     1;
 128     foreach my $attributes (@{ $::form->{requirement_spec_items} || [] }) {
 129       SL::DB::RequirementSpecItem
 130         ->new(id => delete $attributes->{id})
 131         ->load
 132         ->update_attributes(%{ $attributes });
 133     }
 134
 135     1;
 136   });
 137
 138   $self->requirement_spec(SL::DB::RequirementSpec->new(id => $self->requirement_spec->id)->load);
 139
 140   my $html = $self->render('requirement_spec/_show_time_and_cost_estimate', { output => 0 });
 141   $self->js->replaceWith('#time_cost_estimate', $html);
 142
 143   if ($self->visible_section) {
 144     $html = $self->render('requirement_spec_item/_section', { output => 0 }, requirement_spec_item => $self->visible_section);
 145     $self->js->html('#column-content', $html);
 146   }
 147
 148   $self->js->render($self);
 149 }
 150
 151 sub action_show {
 152   my ($self) = @_;
 153
 154   my $title  = $self->requirement_spec->is_template ? t8('Show requirement spec template') : t8('Show requirement spec');
 155   my $item   = $::form->{requirement_spec_item_id} ? SL::DB::RequirementSpecItem->new(id => $::form->{requirement_spec_item_id})->load : @{ $self->requirement_spec->sections }[0];
 156   $self->requirement_spec_item($item);
 157
 158   $self->render('requirement_spec/show', title => $title);
 159 }
 160
 161 sub action_create {
 162   my ($self) = @_;
 163
 164   $self->requirement_spec(SL::DB::RequirementSpec->new);
 165   $self->create_or_update;
 166 }
 167
 168 sub action_update {
 169   my ($self) = @_;
 170   $self->create_or_update;
 171 }
 172
 173 sub action_destroy {
 174   my ($self) = @_;
 175
 176   if (eval { $self->requirement_spec->delete; 1; }) {
 177     flash_later('info',  t8('The requirement spec has been deleted.'));
 178   } else {
 179     flash_later('error', t8('The requirement spec is in use and cannot be deleted.'));
 180   }
 181
 182   $self->redirect_to(action => 'list');
 183 }
 184
 185 sub action_revert_to {
 186   my ($self, %params) = @_;
 187
 188   return $self->js->error(t8('Cannot revert a versioned copy.'))->render($self) if $self->requirement_spec->working_copy_id;
 189
 190   my $versioned_copy = SL::DB::RequirementSpec->new(id => $::form->{versioned_copy_id})->load;
 191
 192   $self->requirement_spec->copy_from(
 193     $versioned_copy,
 194     version_id => $versioned_copy->version_id,
 195   );
 196
 197   flash_later('info', t8('The requirement spec has been reverted to version #1.', $self->requirement_spec->version->version_number));
 198   $self->js->redirect_to($self->url_for(action => 'show', id => $self->requirement_spec->id))->render($self);
 199 }
 200
 201 sub action_create_pdf {
 202   my ($self, %params) = @_;
 203
 204   my %result = SL::Template::LaTeX->parse_and_create_pdf('requirement_spec.tex', SELF => $self, rspec => $self->requirement_spec);
 205
 206   $::form->error(t8('Conversion to PDF failed: #1', $result{error})) if $result{error};
 207
 208   my $attachment_name  =  $self->requirement_spec->type->description . ' ' . ($self->requirement_spec->working_copy_id || $self->requirement_spec->id);
 209   $attachment_name    .=  ' (v' . $self->requirement_spec->version->version_number . ')' if $self->requirement_spec->version;
 210   $attachment_name    .=  '.pdf';
 211   $attachment_name     =~ s/[^\wäöüÄÖÜß \-\+\(\)\[\]\{\}\.,]+/_/g;
 212
 213   $self->send_file($result{file_name}, type => 'application/pdf', name => $attachment_name);
 214   unlink $result{file_name};
 215 }
 216
 217 sub action_select_template_to_paste {
 218   my ($self) = @_;
 219
 220   my @templates = grep { @{ $_->sections } || @{ $_->text_blocks } } @{ SL::DB::Manager::RequirementSpec->get_all(where => [ is_template => 1 ], sort_by => 'lower(title)') };
 221   $self->render('requirement_spec/select_template_to_paste', { layout => 0 }, TEMPLATES => \@templates);
 222 }
 223
 224 sub action_paste_template {
 225   my ($self, %params) = @_;
 226
 227   my $template = SL::DB::RequirementSpec->new(id => $::form->{template_id})->load;
 228   my %result   = $self->requirement_spec->paste_template($template);
 229
 230   return $self->js->error($self->requirement_spec->error)->render($self) if !%result;
 231
 232   $self->render_pasted_text_block($_) for sort { $a->position <=> $b->position } @{ $result{text_blocks} };
 233   $self->render_pasted_section($_)    for sort { $a->position <=> $b->position } @{ $result{sections}    };
 234
 235   if (@{ $result{sections} } && (($::form->{current_content_type} || 'sections') eq 'sections') && !$::form->{current_content_id}) {
 236     $self->render_first_pasted_section_as_list($result{sections}->[0]);
 237   }
 238
 239   $self->invalidate_version->render($self);
 240 }
 241
 242 #
 243 # filters
 244 #
 245
 246 sub setup {
 247   my ($self) = @_;
 248
 249   $::auth->assert('sales_quotation_edit');
 250   $::request->{layout}->use_stylesheet("${_}.css") for qw(jquery.contextMenu requirement_spec);
 251   $::request->{layout}->use_javascript("${_}.js") for qw(jquery.jstree jquery/jquery.contextMenu client_js requirement_spec);
 252   $self->init_visible_section;
 253
 254   return 1;
 255 }
 256
 257 sub init_complexities {
 258   my ($self) = @_;
 259   return SL::DB::Manager::RequirementSpecComplexity->get_all_sorted;
 260 }
 261
 262 sub init_risks {
 263   my ($self) = @_;
 264   return SL::DB::Manager::RequirementSpecRisk->get_all_sorted;
 265 }
 266
 267 sub init_projects {
 268   my ($self) = @_;
 269   $self->projects(SL::DB::Manager::Project->get_all_sorted);
 270 }
 271
 272 sub init_requirement_spec {
 273   my ($self) = @_;
 274   $self->requirement_spec(SL::DB::RequirementSpec->new(id => $::form->{id})->load || die "No such requirement spec") if $::form->{id};
 275 }
 276
 277 sub init_copy_source {
 278   my ($self) = @_;
 279   $self->copy_source(SL::DB::RequirementSpec->new(id => $::form->{copy_source_id})->load) if $::form->{copy_source_id};
 280 }
 281
 282 sub init_js {
 283   my ($self) = @_;
 284   $self->js(SL::ClientJS->new);
 285 }
 286
 287 sub init_current_text_block_output_position {
 288   my ($self) = @_;
 289   $self->current_text_block_output_position($::form->{current_content_type} !~ m/^(?:text-blocks|tb)-(front|back)/ ? -1 : $1 eq 'front' ? 0 : 1);
 290 }
 291
 292 sub load_select_options {
 293   my ($self) = @_;
 294
 295   my @filter = ('!obsolete' => 1);
 296   @filter    = ( or => [ @filter, id => $self->requirement_spec->customer_id ] ) if $self->requirement_spec && $self->requirement_spec->customer_id;
 297
 298   $self->customers(SL::DB::Manager::Customer->get_all_sorted(where => \@filter));
 299   $self->statuses( SL::DB::Manager::RequirementSpecStatus->get_all_sorted);
 300   $self->types(    SL::DB::Manager::RequirementSpecType->get_all_sorted);
 301 }
 302
 303 #
 304 # helpers
 305 #
 306
 307 sub create_or_update {
 308   my $self   = shift;
 309   my $is_new = !$self->requirement_spec->id;
 310   my $params = delete($::form->{requirement_spec}) || { };
 311
 312   $self->requirement_spec->assign_attributes(%{ $params });
 313
 314   my $title  = $is_new && $self->requirement_spec->is_template ? t8('Create a new requirement spec template')
 315              : $is_new                                         ? t8('Create a new requirement spec')
 316              :            $self->requirement_spec->is_template ? t8('Edit requirement spec template')
 317              :                                                   t8('Edit requirement spec');
 318
 319   my @errors = $self->requirement_spec->validate;
 320
 321   if (@errors) {
 322     return $self->js->error(@errors)->render($self) if $::request->is_ajax;
 323
 324     flash('error', @errors);
 325     $self->render('requirement_spec/new', title => $title);
 326     return;
 327   }
 328
 329   my $db = $self->requirement_spec->db;
 330   if (!$db->do_transaction(sub {
 331     if ($self->copy_source) {
 332       $self->requirement_spec($self->copy_source->create_copy(%{ $params }));
 333     } else {
 334       $self->requirement_spec->save;
 335     }
 336   })) {
 337     $::lxdebug->message(LXDebug::WARN(), "Error: " . $db->error);
 338     @errors = ($::locale->text('Saving failed. Error message from the database: #1'), $db->error);
 339     return $self->js->error(@errors)->render($self) if $::request->is_ajax;
 340
 341     $self->requirement_spec->id(undef) if $is_new;
 342     flash('error', @errors);
 343     return $self->render('requirement_spec/new', title => $title);
 344   }
 345
 346   my $info = $self->requirement_spec->is_template ? t8('The requirement spec template has been saved.') : t8('The requirement spec has been saved.');
 347
 348   if ($::request->is_ajax) {
 349     my $html = $self->render('requirement_spec/_header', { output => 0 });
 350     return $self->invalidate_version
 351       ->replaceWith('#requirement-spec-header', $html)
 352       ->flash('info', $info)
 353       ->render($self);
 354   }
 355
 356   flash_later('info', $info);
 357   $self->redirect_to(action => 'show', id => $self->requirement_spec->id);
 358 }
 359
 360 sub setup_db_args_from_filter {
 361   my ($self) = @_;
 362
 363   $self->{filter} = {};
 364   my %args = parse_filter(
 365     $::form->{filter},
 366     with_objects => [ 'customer', 'type', 'status', 'project' ],
 367     launder_to   => $self->{filter},
 368   );
 369
 370   $args{where} = [
 371     and => [
 372       @{ $args{where} || [] },
 373       working_copy_id => undef,
 374       is_template     => $::form->{is_template} ? 1 : 0,
 375     ]];
 376
 377   $self->db_args(\%args);
 378 }
 379
 380 sub prepare_report {
 381   my ($self)      = @_;
 382
 383   my $callback    = $self->get_callback;
 384
 385   my $is_template = $::form->{is_template};
 386   my $report      = SL::ReportGenerator->new(\%::myconfig, $::form);
 387   $self->{report} = $report;
 388
 389   my @columns     = $is_template ? qw(title mtime) : qw(title customer status type projectnumber mtime version);
 390   my @sortable    = $is_template ? qw(title mtime) : qw(title customer status type projectnumber mtime);
 391
 392   my %column_defs = (
 393     title         => { obj_link => sub { $self->url_for(action => 'show', id => $_[0]->id, callback => $callback) } },
 394     mtime         => { sub      => sub { ($_[0]->mtime || $_[0]->itime)->to_kivitendo(precision => 'minute') } },
 395   );
 396
 397   if (!$is_template) {
 398     %column_defs = (
 399       %column_defs,
 400       customer      => { raw_data => sub { $self->presenter->customer($_[0]->customer, display => 'table-cell', callback => $callback) },
 401                          sub      => sub { $_[0]->customer->name } },
 402       projectnumber => { raw_data => sub { $self->presenter->project($_[0]->project, display => 'table-cell', callback => $callback) },
 403                          sub      => sub { $_[0]->project_id ? $_[0]->project->projectnumber : '' } },
 404       status        => { sub      => sub { $_[0]->status->description } },
 405       type          => { sub      => sub { $_[0]->type->description } },
 406       version       => { sub      => sub { $_[0]->version_id ? $_[0]->version->version_number : t8('Working copy without version') } },
 407     );
 408   }
 409
 410   map { $column_defs{$_}->{text} ||= $::locale->text( $self->get_sort_spec->{$_}->{title} ) } keys %column_defs;
 411
 412   $report->set_options(
 413     std_column_visibility => 1,
 414     controller_class      => 'RequirementSpec',
 415     output_format         => 'HTML',
 416     raw_top_info_text     => $self->render('requirement_spec/report_top',    { output => 0 }, is_template => $is_template),
 417     raw_bottom_info_text  => $self->render('requirement_spec/report_bottom', { output => 0 }),
 418     title                 => $is_template ? t8('Requirement Spec Templates') : t8('Requirement Specs'),
 419     allow_pdf_export      => 1,
 420     allow_csv_export      => 1,
 421   );
 422   $report->set_columns(%column_defs);
 423   $report->set_column_order(@columns);
 424   $report->set_export_options(qw(list filter));
 425   $report->set_options_from_form;
 426   $self->set_report_generator_sort_options(report => $report, sortable_columns => \@sortable);
 427
 428   $self->disable_pagination if $report->{options}{output_format} =~ /^(pdf|csv)$/i;
 429 }
 430
 431 sub invalidate_version {
 432   my ($self) = @_;
 433
 434   my $rspec  = SL::DB::RequirementSpec->new(id => $self->requirement_spec->id)->load;
 435   return $self->js if $rspec->is_template;
 436
 437   $rspec->invalidate_version;
 438
 439   my $html = $self->render('requirement_spec/_version', { output => 0 }, requirement_spec => $rspec);
 440   return $self->js->html('#requirement_spec_version', $html);
 441 }
 442
 443 sub render_pasted_text_block {
 444   my ($self, $text_block, %params) = @_;
 445
 446   if ($self->current_text_block_output_position == $text_block->output_position) {
 447     my $html = $self->render('requirement_spec_text_block/_text_block', { output => 0 }, text_block => $text_block);
 448     $self->js
 449       ->appendTo($html, '#text-block-list')
 450       ->hide('#text-block-list-empty');
 451   }
 452
 453   my $node       = $self->presenter->requirement_spec_text_block_jstree_data($text_block);
 454   my $front_back = $text_block->output_position == 0 ? 'front' : 'back';
 455   $self->js
 456     ->jstree->create_node('#tree', "#tb-${front_back}", 'last', $node)
 457     ->jstree->open_node(  '#tree', "#tb-${front_back}");
 458 }
 459
 460 sub render_pasted_section {
 461   my ($self, $item, $parent_id) = @_;
 462
 463   my $node = $self->presenter->requirement_spec_item_jstree_data($item);
 464   $self->js
 465     ->jstree->create_node('#tree', $parent_id ? "#fb-${parent_id}" : '#sections', 'last', $node)
 466     ->jstree->open_node(  '#tree', $parent_id ? "#fb-${parent_id}" : '#sections');
 467
 468   $self->render_pasted_section($_, $item->id) for @{ $item->children_sorted };
 469 }
 470
 471 sub render_first_pasted_section_as_list {
 472   my ($self, $section, %params) = @_;
 473
 474   my $html = $self->render('requirement_spec_item/_section', { output => 0 }, requirement_spec_item => $section);
 475   $self->js
 476     ->html('#column-content', $html)
 477     ->val( '#current_content_type', $section->item_type)
 478     ->val( '#current_content_id',   $section->id)
 479     ->jstree->select_node('#tree', '#fb-' . $section->id);
 480 }
 481
 482 1;